git.oblomov.eu Git - linux-2.6/blob - arch/ia64/kernel/head.S

   1 /*
   2  * Here is where the ball gets rolling as far as the kernel is concerned.
   3  * When control is transferred to _start, the bootload has already
   4  * loaded us to the correct address.  All that's left to do here is
   5  * to set up the kernel's global pointer and jump to the kernel
   6  * entry point.
   7  *
   8  * Copyright (C) 1998-2001, 2003, 2005 Hewlett-Packard Co
   9  *      David Mosberger-Tang <davidm@hpl.hp.com>
  10  *      Stephane Eranian <eranian@hpl.hp.com>
  11  * Copyright (C) 1999 VA Linux Systems
  12  * Copyright (C) 1999 Walt Drummond <drummond@valinux.com>
  13  * Copyright (C) 1999 Intel Corp.
  14  * Copyright (C) 1999 Asit Mallick <Asit.K.Mallick@intel.com>
  15  * Copyright (C) 1999 Don Dugger <Don.Dugger@intel.com>
  16  * Copyright (C) 2002 Fenghua Yu <fenghua.yu@intel.com>
  17  *   -Optimize __ia64_save_fpu() and __ia64_load_fpu() for Itanium 2.
  18  * Copyright (C) 2004 Ashok Raj <ashok.raj@intel.com>
  19  *   Support for CPU Hotplug
  20  */
  21
  22 #include <linux/config.h>
  23
  24 #include <asm/asmmacro.h>
  25 #include <asm/fpu.h>
  26 #include <asm/kregs.h>
  27 #include <asm/mmu_context.h>
  28 #include <asm/asm-offsets.h>
  29 #include <asm/pal.h>
  30 #include <asm/pgtable.h>
  31 #include <asm/processor.h>
  32 #include <asm/ptrace.h>
  33 #include <asm/system.h>
  34 #include <asm/mca_asm.h>
  35
  36 #ifdef CONFIG_HOTPLUG_CPU
  37 #define SAL_PSR_BITS_TO_SET                             \
  38         (IA64_PSR_AC | IA64_PSR_BN | IA64_PSR_MFH | IA64_PSR_MFL)
  39
  40 #define SAVE_FROM_REG(src, ptr, dest)   \
  41         mov dest=src;;                                          \
  42         st8 [ptr]=dest,0x08
  43
  44 #define RESTORE_REG(reg, ptr, _tmp)             \
  45         ld8 _tmp=[ptr],0x08;;                           \
  46         mov reg=_tmp
  47
  48 #define SAVE_BREAK_REGS(ptr, _idx, _breg, _dest)\
  49         mov ar.lc=IA64_NUM_DBG_REGS-1;;                         \
  50         mov _idx=0;;                                                            \
  51 1:                                                                                              \
  52         SAVE_FROM_REG(_breg[_idx], ptr, _dest);;        \
  53         add _idx=1,_idx;;                                                       \
  54         br.cloop.sptk.many 1b
  55
  56 #define RESTORE_BREAK_REGS(ptr, _idx, _breg, _tmp, _lbl)\
  57         mov ar.lc=IA64_NUM_DBG_REGS-1;;                 \
  58         mov _idx=0;;                                                    \
  59 _lbl:  RESTORE_REG(_breg[_idx], ptr, _tmp);;    \
  60         add _idx=1, _idx;;                                              \
  61         br.cloop.sptk.many _lbl
  62
  63 #define SAVE_ONE_RR(num, _reg, _tmp) \
  64         movl _tmp=(num<<61);;   \
  65         mov _reg=rr[_tmp]
  66
  67 #define SAVE_REGION_REGS(_tmp, _r0, _r1, _r2, _r3, _r4, _r5, _r6, _r7) \
  68         SAVE_ONE_RR(0,_r0, _tmp);; \
  69         SAVE_ONE_RR(1,_r1, _tmp);; \
  70         SAVE_ONE_RR(2,_r2, _tmp);; \
  71         SAVE_ONE_RR(3,_r3, _tmp);; \
  72         SAVE_ONE_RR(4,_r4, _tmp);; \
  73         SAVE_ONE_RR(5,_r5, _tmp);; \
  74         SAVE_ONE_RR(6,_r6, _tmp);; \
  75         SAVE_ONE_RR(7,_r7, _tmp);;
  76
  77 #define STORE_REGION_REGS(ptr, _r0, _r1, _r2, _r3, _r4, _r5, _r6, _r7) \
  78         st8 [ptr]=_r0, 8;; \
  79         st8 [ptr]=_r1, 8;; \
  80         st8 [ptr]=_r2, 8;; \
  81         st8 [ptr]=_r3, 8;; \
  82         st8 [ptr]=_r4, 8;; \
  83         st8 [ptr]=_r5, 8;; \
  84         st8 [ptr]=_r6, 8;; \
  85         st8 [ptr]=_r7, 8;;
  86
  87 #define RESTORE_REGION_REGS(ptr, _idx1, _idx2, _tmp) \
  88         mov             ar.lc=0x08-1;;                                          \
  89         movl    _idx1=0x00;;                                            \
  90 RestRR:                                                                                 \
  91         dep.z   _idx2=_idx1,61,3;;                                      \
  92         ld8             _tmp=[ptr],8;;                                          \
  93         mov             rr[_idx2]=_tmp;;                                        \
  94         srlz.d;;                                                                        \
  95         add             _idx1=1,_idx1;;                                         \
  96         br.cloop.sptk.few       RestRR
  97
  98 #define SET_AREA_FOR_BOOTING_CPU(reg1, reg2) \
  99         movl reg1=sal_state_for_booting_cpu;;   \
 100         ld8 reg2=[reg1];;
 101
 102 /*
 103  * Adjust region registers saved before starting to save
 104  * break regs and rest of the states that need to be preserved.
 105  */
 106 #define SAL_TO_OS_BOOT_HANDOFF_STATE_SAVE(_reg1,_reg2,_pred)  \
 107         SAVE_FROM_REG(b0,_reg1,_reg2);;                                         \
 108         SAVE_FROM_REG(b1,_reg1,_reg2);;                                         \
 109         SAVE_FROM_REG(b2,_reg1,_reg2);;                                         \
 110         SAVE_FROM_REG(b3,_reg1,_reg2);;                                         \
 111         SAVE_FROM_REG(b4,_reg1,_reg2);;                                         \
 112         SAVE_FROM_REG(b5,_reg1,_reg2);;                                         \
 113         st8 [_reg1]=r1,0x08;;                                                           \
 114         st8 [_reg1]=r12,0x08;;                                                          \
 115         st8 [_reg1]=r13,0x08;;                                                          \
 116         SAVE_FROM_REG(ar.fpsr,_reg1,_reg2);;                            \
 117         SAVE_FROM_REG(ar.pfs,_reg1,_reg2);;                                     \
 118         SAVE_FROM_REG(ar.rnat,_reg1,_reg2);;                            \
 119         SAVE_FROM_REG(ar.unat,_reg1,_reg2);;                            \
 120         SAVE_FROM_REG(ar.bspstore,_reg1,_reg2);;                        \
 121         SAVE_FROM_REG(cr.dcr,_reg1,_reg2);;                                     \
 122         SAVE_FROM_REG(cr.iva,_reg1,_reg2);;                                     \
 123         SAVE_FROM_REG(cr.pta,_reg1,_reg2);;                                     \
 124         SAVE_FROM_REG(cr.itv,_reg1,_reg2);;                                     \
 125         SAVE_FROM_REG(cr.pmv,_reg1,_reg2);;                                     \
 126         SAVE_FROM_REG(cr.cmcv,_reg1,_reg2);;                            \
 127         SAVE_FROM_REG(cr.lrr0,_reg1,_reg2);;                            \
 128         SAVE_FROM_REG(cr.lrr1,_reg1,_reg2);;                            \
 129         st8 [_reg1]=r4,0x08;;                                                           \
 130         st8 [_reg1]=r5,0x08;;                                                           \
 131         st8 [_reg1]=r6,0x08;;                                                           \
 132         st8 [_reg1]=r7,0x08;;                                                           \
 133         st8 [_reg1]=_pred,0x08;;                                                        \
 134         SAVE_FROM_REG(ar.lc, _reg1, _reg2);;                            \
 135         stf.spill.nta [_reg1]=f2,16;;                                           \
 136         stf.spill.nta [_reg1]=f3,16;;                                           \
 137         stf.spill.nta [_reg1]=f4,16;;                                           \
 138         stf.spill.nta [_reg1]=f5,16;;                                           \
 139         stf.spill.nta [_reg1]=f16,16;;                                          \
 140         stf.spill.nta [_reg1]=f17,16;;                                          \
 141         stf.spill.nta [_reg1]=f18,16;;                                          \
 142         stf.spill.nta [_reg1]=f19,16;;                                          \
 143         stf.spill.nta [_reg1]=f20,16;;                                          \
 144         stf.spill.nta [_reg1]=f21,16;;                                          \
 145         stf.spill.nta [_reg1]=f22,16;;                                          \
 146         stf.spill.nta [_reg1]=f23,16;;                                          \
 147         stf.spill.nta [_reg1]=f24,16;;                                          \
 148         stf.spill.nta [_reg1]=f25,16;;                                          \
 149         stf.spill.nta [_reg1]=f26,16;;                                          \
 150         stf.spill.nta [_reg1]=f27,16;;                                          \
 151         stf.spill.nta [_reg1]=f28,16;;                                          \
 152         stf.spill.nta [_reg1]=f29,16;;                                          \
 153         stf.spill.nta [_reg1]=f30,16;;                                          \
 154         stf.spill.nta [_reg1]=f31,16;;
 155
 156 #else
 157 #define SET_AREA_FOR_BOOTING_CPU(a1, a2)
 158 #define SAL_TO_OS_BOOT_HANDOFF_STATE_SAVE(a1,a2, a3)
 159 #define SAVE_REGION_REGS(_tmp, _r0, _r1, _r2, _r3, _r4, _r5, _r6, _r7)
 160 #define STORE_REGION_REGS(ptr, _r0, _r1, _r2, _r3, _r4, _r5, _r6, _r7)
 161 #endif
 162
 163 #define SET_ONE_RR(num, pgsize, _tmp1, _tmp2, vhpt) \
 164         movl _tmp1=(num << 61);;        \
 165         mov _tmp2=((ia64_rid(IA64_REGION_ID_KERNEL, (num<<61)) << 8) | (pgsize << 2) | vhpt);; \
 166         mov rr[_tmp1]=_tmp2
 167
 168         .section __special_page_section,"ax"
 169
 170         .global empty_zero_page
 171 empty_zero_page:
 172         .skip PAGE_SIZE
 173
 174         .global swapper_pg_dir
 175 swapper_pg_dir:
 176         .skip PAGE_SIZE
 177
 178         .rodata
 179 halt_msg:
 180         stringz "Halting kernel\n"
 181
 182         .text
 183
 184         .global start_ap
 185
 186         /*
 187          * Start the kernel.  When the bootloader passes control to _start(), r28
 188          * points to the address of the boot parameter area.  Execution reaches
 189          * here in physical mode.
 190          */
 191 GLOBAL_ENTRY(_start)
 192 start_ap:
 193         .prologue
 194         .save rp, r0            // terminate unwind chain with a NULL rp
 195         .body
 196
 197         rsm psr.i | psr.ic
 198         ;;
 199         srlz.i
 200         ;;
 201         /*
 202          * Save the region registers, predicate before they get clobbered
 203          */
 204         SAVE_REGION_REGS(r2, r8,r9,r10,r11,r12,r13,r14,r15);
 205         mov r25=pr;;
 206
 207         /*
 208          * Initialize kernel region registers:
 209          *      rr[0]: VHPT enabled, page size = PAGE_SHIFT
 210          *      rr[1]: VHPT enabled, page size = PAGE_SHIFT
 211          *      rr[2]: VHPT enabled, page size = PAGE_SHIFT
 212          *      rr[3]: VHPT enabled, page size = PAGE_SHIFT
 213          *      rr[4]: VHPT enabled, page size = PAGE_SHIFT
 214          *      rr[5]: VHPT enabled, page size = PAGE_SHIFT
 215          *      rr[6]: VHPT disabled, page size = IA64_GRANULE_SHIFT
 216          *      rr[7]: VHPT disabled, page size = IA64_GRANULE_SHIFT
 217          * We initialize all of them to prevent inadvertently assuming
 218          * something about the state of address translation early in boot.
 219          */
 220         SET_ONE_RR(0, PAGE_SHIFT, r2, r16, 1);;
 221         SET_ONE_RR(1, PAGE_SHIFT, r2, r16, 1);;
 222         SET_ONE_RR(2, PAGE_SHIFT, r2, r16, 1);;
 223         SET_ONE_RR(3, PAGE_SHIFT, r2, r16, 1);;
 224         SET_ONE_RR(4, PAGE_SHIFT, r2, r16, 1);;
 225         SET_ONE_RR(5, PAGE_SHIFT, r2, r16, 1);;
 226         SET_ONE_RR(6, IA64_GRANULE_SHIFT, r2, r16, 0);;
 227         SET_ONE_RR(7, IA64_GRANULE_SHIFT, r2, r16, 0);;
 228         /*
 229          * Now pin mappings into the TLB for kernel text and data
 230          */
 231         mov r18=KERNEL_TR_PAGE_SHIFT<<2
 232         movl r17=KERNEL_START
 233         ;;
 234         mov cr.itir=r18
 235         mov cr.ifa=r17
 236         mov r16=IA64_TR_KERNEL
 237         mov r3=ip
 238         movl r18=PAGE_KERNEL
 239         ;;
 240         dep r2=0,r3,0,KERNEL_TR_PAGE_SHIFT
 241         ;;
 242         or r18=r2,r18
 243         ;;
 244         srlz.i
 245         ;;
 246         itr.i itr[r16]=r18
 247         ;;
 248         itr.d dtr[r16]=r18
 249         ;;
 250         srlz.i
 251
 252         /*
 253          * Switch into virtual mode:
 254          */
 255         movl r16=(IA64_PSR_IT|IA64_PSR_IC|IA64_PSR_DT|IA64_PSR_RT|IA64_PSR_DFH|IA64_PSR_BN \
 256                   |IA64_PSR_DI)
 257         ;;
 258         mov cr.ipsr=r16
 259         movl r17=1f
 260         ;;
 261         mov cr.iip=r17
 262         mov cr.ifs=r0
 263         ;;
 264         rfi
 265         ;;
 266 1:      // now we are in virtual mode
 267
 268         SET_AREA_FOR_BOOTING_CPU(r2, r16);
 269
 270         STORE_REGION_REGS(r16, r8,r9,r10,r11,r12,r13,r14,r15);
 271         SAL_TO_OS_BOOT_HANDOFF_STATE_SAVE(r16,r17,r25)
 272         ;;
 273
 274         // set IVT entry point---can't access I/O ports without it
 275         movl r3=ia64_ivt
 276         ;;
 277         mov cr.iva=r3
 278         movl r2=FPSR_DEFAULT
 279         ;;
 280         srlz.i
 281         movl gp=__gp
 282
 283         mov ar.fpsr=r2
 284         ;;
 285
 286 #define isAP    p2      // are we an Application Processor?
 287 #define isBP    p3      // are we the Bootstrap Processor?
 288
 289 #ifdef CONFIG_SMP
 290         /*
 291          * Find the init_task for the currently booting CPU.  At poweron, and in
 292          * UP mode, task_for_booting_cpu is NULL.
 293          */
 294         movl r3=task_for_booting_cpu
 295         ;;
 296         ld8 r3=[r3]
 297         movl r2=init_task
 298         ;;
 299         cmp.eq isBP,isAP=r3,r0
 300         ;;
 301 (isAP)  mov r2=r3
 302 #else
 303         movl r2=init_task
 304         cmp.eq isBP,isAP=r0,r0
 305 #endif
 306         ;;
 307         tpa r3=r2               // r3 == phys addr of task struct
 308         mov r16=-1
 309 (isBP)  br.cond.dpnt .load_current // BP stack is on region 5 --- no need to map it
 310
 311         // load mapping for stack (virtaddr in r2, physaddr in r3)
 312         rsm psr.ic
 313         movl r17=PAGE_KERNEL
 314         ;;
 315         srlz.d
 316         dep r18=0,r3,0,12
 317         ;;
 318         or r18=r17,r18
 319         dep r2=-1,r3,61,3       // IMVA of task
 320         ;;
 321         mov r17=rr[r2]
 322         shr.u r16=r3,IA64_GRANULE_SHIFT
 323         ;;
 324         dep r17=0,r17,8,24
 325         ;;
 326         mov cr.itir=r17
 327         mov cr.ifa=r2
 328
 329         mov r19=IA64_TR_CURRENT_STACK
 330         ;;
 331         itr.d dtr[r19]=r18
 332         ;;
 333         ssm psr.ic
 334         srlz.d
 335         ;;
 336
 337 .load_current:
 338         // load the "current" pointer (r13) and ar.k6 with the current task
 339         mov IA64_KR(CURRENT)=r2         // virtual address
 340         mov IA64_KR(CURRENT_STACK)=r16
 341         mov r13=r2
 342         /*
 343          * Reserve space at the top of the stack for "struct pt_regs".  Kernel
 344          * threads don't store interesting values in that structure, but the space
 345          * still needs to be there because time-critical stuff such as the context
 346          * switching can be implemented more efficiently (for example, __switch_to()
 347          * always sets the psr.dfh bit of the task it is switching to).
 348          */
 349
 350         addl r12=IA64_STK_OFFSET-IA64_PT_REGS_SIZE-16,r2
 351         addl r2=IA64_RBS_OFFSET,r2      // initialize the RSE
 352         mov ar.rsc=0            // place RSE in enforced lazy mode
 353         ;;
 354         loadrs                  // clear the dirty partition
 355         mov IA64_KR(PER_CPU_DATA)=r0    // clear physical per-CPU base
 356         ;;
 357         mov ar.bspstore=r2      // establish the new RSE stack
 358         ;;
 359         mov ar.rsc=0x3          // place RSE in eager mode
 360
 361 (isBP)  dep r28=-1,r28,61,3     // make address virtual
 362 (isBP)  movl r2=ia64_boot_param
 363         ;;
 364 (isBP)  st8 [r2]=r28            // save the address of the boot param area passed by the bootloader
 365
 366 #ifdef CONFIG_SMP
 367 (isAP)  br.call.sptk.many rp=start_secondary
 368 .ret0:
 369 (isAP)  br.cond.sptk self
 370 #endif
 371
 372         // This is executed by the bootstrap processor (bsp) only:
 373
 374 #ifdef CONFIG_IA64_FW_EMU
 375         // initialize PAL & SAL emulator:
 376         br.call.sptk.many rp=sys_fw_init
 377 .ret1:
 378 #endif
 379         br.call.sptk.many rp=start_kernel
 380 .ret2:  addl r3=@ltoff(halt_msg),gp
 381         ;;
 382         alloc r2=ar.pfs,8,0,2,0
 383         ;;
 384         ld8 out0=[r3]
 385         br.call.sptk.many b0=console_print
 386
 387 self:   hint @pause
 388         br.sptk.many self               // endless loop
 389 END(_start)
 390
 391 GLOBAL_ENTRY(ia64_save_debug_regs)
 392         alloc r16=ar.pfs,1,0,0,0
 393         mov r20=ar.lc                   // preserve ar.lc
 394         mov ar.lc=IA64_NUM_DBG_REGS-1
 395         mov r18=0
 396         add r19=IA64_NUM_DBG_REGS*8,in0
 397         ;;
 398 1:      mov r16=dbr[r18]
 399 #ifdef CONFIG_ITANIUM
 400         ;;
 401         srlz.d
 402 #endif
 403         mov r17=ibr[r18]
 404         add r18=1,r18
 405         ;;
 406         st8.nta [in0]=r16,8
 407         st8.nta [r19]=r17,8
 408         br.cloop.sptk.many 1b
 409         ;;
 410         mov ar.lc=r20                   // restore ar.lc
 411         br.ret.sptk.many rp
 412 END(ia64_save_debug_regs)
 413
 414 GLOBAL_ENTRY(ia64_load_debug_regs)
 415         alloc r16=ar.pfs,1,0,0,0
 416         lfetch.nta [in0]
 417         mov r20=ar.lc                   // preserve ar.lc
 418         add r19=IA64_NUM_DBG_REGS*8,in0
 419         mov ar.lc=IA64_NUM_DBG_REGS-1
 420         mov r18=-1
 421         ;;
 422 1:      ld8.nta r16=[in0],8
 423         ld8.nta r17=[r19],8
 424         add r18=1,r18
 425         ;;
 426         mov dbr[r18]=r16
 427 #ifdef CONFIG_ITANIUM
 428         ;;
 429         srlz.d                          // Errata 132 (NoFix status)
 430 #endif
 431         mov ibr[r18]=r17
 432         br.cloop.sptk.many 1b
 433         ;;
 434         mov ar.lc=r20                   // restore ar.lc
 435         br.ret.sptk.many rp
 436 END(ia64_load_debug_regs)
 437
 438 GLOBAL_ENTRY(__ia64_save_fpu)
 439         alloc r2=ar.pfs,1,4,0,0
 440         adds loc0=96*16-16,in0
 441         adds loc1=96*16-16-128,in0
 442         ;;
 443         stf.spill.nta [loc0]=f127,-256
 444         stf.spill.nta [loc1]=f119,-256
 445         ;;
 446         stf.spill.nta [loc0]=f111,-256
 447         stf.spill.nta [loc1]=f103,-256
 448         ;;
 449         stf.spill.nta [loc0]=f95,-256
 450         stf.spill.nta [loc1]=f87,-256
 451         ;;
 452         stf.spill.nta [loc0]=f79,-256
 453         stf.spill.nta [loc1]=f71,-256
 454         ;;
 455         stf.spill.nta [loc0]=f63,-256
 456         stf.spill.nta [loc1]=f55,-256
 457         adds loc2=96*16-32,in0
 458         ;;
 459         stf.spill.nta [loc0]=f47,-256
 460         stf.spill.nta [loc1]=f39,-256
 461         adds loc3=96*16-32-128,in0
 462         ;;
 463         stf.spill.nta [loc2]=f126,-256
 464         stf.spill.nta [loc3]=f118,-256
 465         ;;
 466         stf.spill.nta [loc2]=f110,-256
 467         stf.spill.nta [loc3]=f102,-256
 468         ;;
 469         stf.spill.nta [loc2]=f94,-256
 470         stf.spill.nta [loc3]=f86,-256
 471         ;;
 472         stf.spill.nta [loc2]=f78,-256
 473         stf.spill.nta [loc3]=f70,-256
 474         ;;
 475         stf.spill.nta [loc2]=f62,-256
 476         stf.spill.nta [loc3]=f54,-256
 477         adds loc0=96*16-48,in0
 478         ;;
 479         stf.spill.nta [loc2]=f46,-256
 480         stf.spill.nta [loc3]=f38,-256
 481         adds loc1=96*16-48-128,in0
 482         ;;
 483         stf.spill.nta [loc0]=f125,-256
 484         stf.spill.nta [loc1]=f117,-256
 485         ;;
 486         stf.spill.nta [loc0]=f109,-256
 487         stf.spill.nta [loc1]=f101,-256
 488         ;;
 489         stf.spill.nta [loc0]=f93,-256
 490         stf.spill.nta [loc1]=f85,-256
 491         ;;
 492         stf.spill.nta [loc0]=f77,-256
 493         stf.spill.nta [loc1]=f69,-256
 494         ;;
 495         stf.spill.nta [loc0]=f61,-256
 496         stf.spill.nta [loc1]=f53,-256
 497         adds loc2=96*16-64,in0
 498         ;;
 499         stf.spill.nta [loc0]=f45,-256
 500         stf.spill.nta [loc1]=f37,-256
 501         adds loc3=96*16-64-128,in0
 502         ;;
 503         stf.spill.nta [loc2]=f124,-256
 504         stf.spill.nta [loc3]=f116,-256
 505         ;;
 506         stf.spill.nta [loc2]=f108,-256
 507         stf.spill.nta [loc3]=f100,-256
 508         ;;
 509         stf.spill.nta [loc2]=f92,-256
 510         stf.spill.nta [loc3]=f84,-256
 511         ;;
 512         stf.spill.nta [loc2]=f76,-256
 513         stf.spill.nta [loc3]=f68,-256
 514         ;;
 515         stf.spill.nta [loc2]=f60,-256
 516         stf.spill.nta [loc3]=f52,-256
 517         adds loc0=96*16-80,in0
 518         ;;
 519         stf.spill.nta [loc2]=f44,-256
 520         stf.spill.nta [loc3]=f36,-256
 521         adds loc1=96*16-80-128,in0
 522         ;;
 523         stf.spill.nta [loc0]=f123,-256
 524         stf.spill.nta [loc1]=f115,-256
 525         ;;
 526         stf.spill.nta [loc0]=f107,-256
 527         stf.spill.nta [loc1]=f99,-256
 528         ;;
 529         stf.spill.nta [loc0]=f91,-256
 530         stf.spill.nta [loc1]=f83,-256
 531         ;;
 532         stf.spill.nta [loc0]=f75,-256
 533         stf.spill.nta [loc1]=f67,-256
 534         ;;
 535         stf.spill.nta [loc0]=f59,-256
 536         stf.spill.nta [loc1]=f51,-256
 537         adds loc2=96*16-96,in0
 538         ;;
 539         stf.spill.nta [loc0]=f43,-256
 540         stf.spill.nta [loc1]=f35,-256
 541         adds loc3=96*16-96-128,in0
 542         ;;
 543         stf.spill.nta [loc2]=f122,-256
 544         stf.spill.nta [loc3]=f114,-256
 545         ;;
 546         stf.spill.nta [loc2]=f106,-256
 547         stf.spill.nta [loc3]=f98,-256
 548         ;;
 549         stf.spill.nta [loc2]=f90,-256
 550         stf.spill.nta [loc3]=f82,-256
 551         ;;
 552         stf.spill.nta [loc2]=f74,-256
 553         stf.spill.nta [loc3]=f66,-256
 554         ;;
 555         stf.spill.nta [loc2]=f58,-256
 556         stf.spill.nta [loc3]=f50,-256
 557         adds loc0=96*16-112,in0
 558         ;;
 559         stf.spill.nta [loc2]=f42,-256
 560         stf.spill.nta [loc3]=f34,-256
 561         adds loc1=96*16-112-128,in0
 562         ;;
 563         stf.spill.nta [loc0]=f121,-256
 564         stf.spill.nta [loc1]=f113,-256
 565         ;;
 566         stf.spill.nta [loc0]=f105,-256
 567         stf.spill.nta [loc1]=f97,-256
 568         ;;
 569         stf.spill.nta [loc0]=f89,-256
 570         stf.spill.nta [loc1]=f81,-256
 571         ;;
 572         stf.spill.nta [loc0]=f73,-256
 573         stf.spill.nta [loc1]=f65,-256
 574         ;;
 575         stf.spill.nta [loc0]=f57,-256
 576         stf.spill.nta [loc1]=f49,-256
 577         adds loc2=96*16-128,in0
 578         ;;
 579         stf.spill.nta [loc0]=f41,-256
 580         stf.spill.nta [loc1]=f33,-256
 581         adds loc3=96*16-128-128,in0
 582         ;;
 583         stf.spill.nta [loc2]=f120,-256
 584         stf.spill.nta [loc3]=f112,-256
 585         ;;
 586         stf.spill.nta [loc2]=f104,-256
 587         stf.spill.nta [loc3]=f96,-256
 588         ;;
 589         stf.spill.nta [loc2]=f88,-256
 590         stf.spill.nta [loc3]=f80,-256
 591         ;;
 592         stf.spill.nta [loc2]=f72,-256
 593         stf.spill.nta [loc3]=f64,-256
 594         ;;
 595         stf.spill.nta [loc2]=f56,-256
 596         stf.spill.nta [loc3]=f48,-256
 597         ;;
 598         stf.spill.nta [loc2]=f40
 599         stf.spill.nta [loc3]=f32
 600         br.ret.sptk.many rp
 601 END(__ia64_save_fpu)
 602
 603 GLOBAL_ENTRY(__ia64_load_fpu)
 604         alloc r2=ar.pfs,1,2,0,0
 605         adds r3=128,in0
 606         adds r14=256,in0
 607         adds r15=384,in0
 608         mov loc0=512
 609         mov loc1=-1024+16
 610         ;;
 611         ldf.fill.nta f32=[in0],loc0
 612         ldf.fill.nta f40=[ r3],loc0
 613         ldf.fill.nta f48=[r14],loc0
 614         ldf.fill.nta f56=[r15],loc0
 615         ;;
 616         ldf.fill.nta f64=[in0],loc0
 617         ldf.fill.nta f72=[ r3],loc0
 618         ldf.fill.nta f80=[r14],loc0
 619         ldf.fill.nta f88=[r15],loc0
 620         ;;
 621         ldf.fill.nta f96=[in0],loc1
 622         ldf.fill.nta f104=[ r3],loc1
 623         ldf.fill.nta f112=[r14],loc1
 624         ldf.fill.nta f120=[r15],loc1
 625         ;;
 626         ldf.fill.nta f33=[in0],loc0
 627         ldf.fill.nta f41=[ r3],loc0
 628         ldf.fill.nta f49=[r14],loc0
 629         ldf.fill.nta f57=[r15],loc0
 630         ;;
 631         ldf.fill.nta f65=[in0],loc0
 632         ldf.fill.nta f73=[ r3],loc0
 633         ldf.fill.nta f81=[r14],loc0
 634         ldf.fill.nta f89=[r15],loc0
 635         ;;
 636         ldf.fill.nta f97=[in0],loc1
 637         ldf.fill.nta f105=[ r3],loc1
 638         ldf.fill.nta f113=[r14],loc1
 639         ldf.fill.nta f121=[r15],loc1
 640         ;;
 641         ldf.fill.nta f34=[in0],loc0
 642         ldf.fill.nta f42=[ r3],loc0
 643         ldf.fill.nta f50=[r14],loc0
 644         ldf.fill.nta f58=[r15],loc0
 645         ;;
 646         ldf.fill.nta f66=[in0],loc0
 647         ldf.fill.nta f74=[ r3],loc0
 648         ldf.fill.nta f82=[r14],loc0
 649         ldf.fill.nta f90=[r15],loc0
 650         ;;
 651         ldf.fill.nta f98=[in0],loc1
 652         ldf.fill.nta f106=[ r3],loc1
 653         ldf.fill.nta f114=[r14],loc1
 654         ldf.fill.nta f122=[r15],loc1
 655         ;;
 656         ldf.fill.nta f35=[in0],loc0
 657         ldf.fill.nta f43=[ r3],loc0
 658         ldf.fill.nta f51=[r14],loc0
 659         ldf.fill.nta f59=[r15],loc0
 660         ;;
 661         ldf.fill.nta f67=[in0],loc0
 662         ldf.fill.nta f75=[ r3],loc0
 663         ldf.fill.nta f83=[r14],loc0
 664         ldf.fill.nta f91=[r15],loc0
 665         ;;
 666         ldf.fill.nta f99=[in0],loc1
 667         ldf.fill.nta f107=[ r3],loc1
 668         ldf.fill.nta f115=[r14],loc1
 669         ldf.fill.nta f123=[r15],loc1
 670         ;;
 671         ldf.fill.nta f36=[in0],loc0
 672         ldf.fill.nta f44=[ r3],loc0
 673         ldf.fill.nta f52=[r14],loc0
 674         ldf.fill.nta f60=[r15],loc0
 675         ;;
 676         ldf.fill.nta f68=[in0],loc0
 677         ldf.fill.nta f76=[ r3],loc0
 678         ldf.fill.nta f84=[r14],loc0
 679         ldf.fill.nta f92=[r15],loc0
 680         ;;
 681         ldf.fill.nta f100=[in0],loc1
 682         ldf.fill.nta f108=[ r3],loc1
 683         ldf.fill.nta f116=[r14],loc1
 684         ldf.fill.nta f124=[r15],loc1
 685         ;;
 686         ldf.fill.nta f37=[in0],loc0
 687         ldf.fill.nta f45=[ r3],loc0
 688         ldf.fill.nta f53=[r14],loc0
 689         ldf.fill.nta f61=[r15],loc0
 690         ;;
 691         ldf.fill.nta f69=[in0],loc0
 692         ldf.fill.nta f77=[ r3],loc0
 693         ldf.fill.nta f85=[r14],loc0
 694         ldf.fill.nta f93=[r15],loc0
 695         ;;
 696         ldf.fill.nta f101=[in0],loc1
 697         ldf.fill.nta f109=[ r3],loc1
 698         ldf.fill.nta f117=[r14],loc1
 699         ldf.fill.nta f125=[r15],loc1
 700         ;;
 701         ldf.fill.nta f38 =[in0],loc0
 702         ldf.fill.nta f46 =[ r3],loc0
 703         ldf.fill.nta f54 =[r14],loc0
 704         ldf.fill.nta f62 =[r15],loc0
 705         ;;
 706         ldf.fill.nta f70 =[in0],loc0
 707         ldf.fill.nta f78 =[ r3],loc0
 708         ldf.fill.nta f86 =[r14],loc0
 709         ldf.fill.nta f94 =[r15],loc0
 710         ;;
 711         ldf.fill.nta f102=[in0],loc1
 712         ldf.fill.nta f110=[ r3],loc1
 713         ldf.fill.nta f118=[r14],loc1
 714         ldf.fill.nta f126=[r15],loc1
 715         ;;
 716         ldf.fill.nta f39 =[in0],loc0
 717         ldf.fill.nta f47 =[ r3],loc0
 718         ldf.fill.nta f55 =[r14],loc0
 719         ldf.fill.nta f63 =[r15],loc0
 720         ;;
 721         ldf.fill.nta f71 =[in0],loc0
 722         ldf.fill.nta f79 =[ r3],loc0
 723         ldf.fill.nta f87 =[r14],loc0
 724         ldf.fill.nta f95 =[r15],loc0
 725         ;;
 726         ldf.fill.nta f103=[in0]
 727         ldf.fill.nta f111=[ r3]
 728         ldf.fill.nta f119=[r14]
 729         ldf.fill.nta f127=[r15]
 730         br.ret.sptk.many rp
 731 END(__ia64_load_fpu)
 732
 733 GLOBAL_ENTRY(__ia64_init_fpu)
 734         stf.spill [sp]=f0               // M3
 735         mov      f32=f0                 // F
 736         nop.b    0
 737
 738         ldfps    f33,f34=[sp]           // M0
 739         ldfps    f35,f36=[sp]           // M1
 740         mov      f37=f0                 // F
 741         ;;
 742
 743         setf.s   f38=r0                 // M2
 744         setf.s   f39=r0                 // M3
 745         mov      f40=f0                 // F
 746
 747         ldfps    f41,f42=[sp]           // M0
 748         ldfps    f43,f44=[sp]           // M1
 749         mov      f45=f0                 // F
 750
 751         setf.s   f46=r0                 // M2
 752         setf.s   f47=r0                 // M3
 753         mov      f48=f0                 // F
 754
 755         ldfps    f49,f50=[sp]           // M0
 756         ldfps    f51,f52=[sp]           // M1
 757         mov      f53=f0                 // F
 758
 759         setf.s   f54=r0                 // M2
 760         setf.s   f55=r0                 // M3
 761         mov      f56=f0                 // F
 762
 763         ldfps    f57,f58=[sp]           // M0
 764         ldfps    f59,f60=[sp]           // M1
 765         mov      f61=f0                 // F
 766
 767         setf.s   f62=r0                 // M2
 768         setf.s   f63=r0                 // M3
 769         mov      f64=f0                 // F
 770
 771         ldfps    f65,f66=[sp]           // M0
 772         ldfps    f67,f68=[sp]           // M1
 773         mov      f69=f0                 // F
 774
 775         setf.s   f70=r0                 // M2
 776         setf.s   f71=r0                 // M3
 777         mov      f72=f0                 // F
 778
 779         ldfps    f73,f74=[sp]           // M0
 780         ldfps    f75,f76=[sp]           // M1
 781         mov      f77=f0                 // F
 782
 783         setf.s   f78=r0                 // M2
 784         setf.s   f79=r0                 // M3
 785         mov      f80=f0                 // F
 786
 787         ldfps    f81,f82=[sp]           // M0
 788         ldfps    f83,f84=[sp]           // M1
 789         mov      f85=f0                 // F
 790
 791         setf.s   f86=r0                 // M2
 792         setf.s   f87=r0                 // M3
 793         mov      f88=f0                 // F
 794
 795         /*
 796          * When the instructions are cached, it would be faster to initialize
 797          * the remaining registers with simply mov instructions (F-unit).
 798          * This gets the time down to ~29 cycles.  However, this would use up
 799          * 33 bundles, whereas continuing with the above pattern yields
 800          * 10 bundles and ~30 cycles.
 801          */
 802
 803         ldfps    f89,f90=[sp]           // M0
 804         ldfps    f91,f92=[sp]           // M1
 805         mov      f93=f0                 // F
 806
 807         setf.s   f94=r0                 // M2
 808         setf.s   f95=r0                 // M3
 809         mov      f96=f0                 // F
 810
 811         ldfps    f97,f98=[sp]           // M0
 812         ldfps    f99,f100=[sp]          // M1
 813         mov      f101=f0                // F
 814
 815         setf.s   f102=r0                // M2
 816         setf.s   f103=r0                // M3
 817         mov      f104=f0                // F
 818
 819         ldfps    f105,f106=[sp]         // M0
 820         ldfps    f107,f108=[sp]         // M1
 821         mov      f109=f0                // F
 822
 823         setf.s   f110=r0                // M2
 824         setf.s   f111=r0                // M3
 825         mov      f112=f0                // F
 826
 827         ldfps    f113,f114=[sp]         // M0
 828         ldfps    f115,f116=[sp]         // M1
 829         mov      f117=f0                // F
 830
 831         setf.s   f118=r0                // M2
 832         setf.s   f119=r0                // M3
 833         mov      f120=f0                // F
 834
 835         ldfps    f121,f122=[sp]         // M0
 836         ldfps    f123,f124=[sp]         // M1
 837         mov      f125=f0                // F
 838
 839         setf.s   f126=r0                // M2
 840         setf.s   f127=r0                // M3
 841         br.ret.sptk.many rp             // F
 842 END(__ia64_init_fpu)
 843
 844 /*
 845  * Switch execution mode from virtual to physical
 846  *
 847  * Inputs:
 848  *      r16 = new psr to establish
 849  * Output:
 850  *      r19 = old virtual address of ar.bsp
 851  *      r20 = old virtual address of sp
 852  *
 853  * Note: RSE must already be in enforced lazy mode
 854  */
 855 GLOBAL_ENTRY(ia64_switch_mode_phys)
 856  {
 857         alloc r2=ar.pfs,0,0,0,0
 858         rsm psr.i | psr.ic              // disable interrupts and interrupt collection
 859         mov r15=ip
 860  }
 861         ;;
 862  {
 863         flushrs                         // must be first insn in group
 864         srlz.i
 865  }
 866         ;;
 867         mov cr.ipsr=r16                 // set new PSR
 868         add r3=1f-ia64_switch_mode_phys,r15
 869
 870         mov r19=ar.bsp
 871         mov r20=sp
 872         mov r14=rp                      // get return address into a general register
 873         ;;
 874
 875         // going to physical mode, use tpa to translate virt->phys
 876         tpa r17=r19
 877         tpa r3=r3
 878         tpa sp=sp
 879         tpa r14=r14
 880         ;;
 881
 882         mov r18=ar.rnat                 // save ar.rnat
 883         mov ar.bspstore=r17             // this steps on ar.rnat
 884         mov cr.iip=r3
 885         mov cr.ifs=r0
 886         ;;
 887         mov ar.rnat=r18                 // restore ar.rnat
 888         rfi                             // must be last insn in group
 889         ;;
 890 1:      mov rp=r14
 891         br.ret.sptk.many rp
 892 END(ia64_switch_mode_phys)
 893
 894 /*
 895  * Switch execution mode from physical to virtual
 896  *
 897  * Inputs:
 898  *      r16 = new psr to establish
 899  *      r19 = new bspstore to establish
 900  *      r20 = new sp to establish
 901  *
 902  * Note: RSE must already be in enforced lazy mode
 903  */
 904 GLOBAL_ENTRY(ia64_switch_mode_virt)
 905  {
 906         alloc r2=ar.pfs,0,0,0,0
 907         rsm psr.i | psr.ic              // disable interrupts and interrupt collection
 908         mov r15=ip
 909  }
 910         ;;
 911  {
 912         flushrs                         // must be first insn in group
 913         srlz.i
 914  }
 915         ;;
 916         mov cr.ipsr=r16                 // set new PSR
 917         add r3=1f-ia64_switch_mode_virt,r15
 918
 919         mov r14=rp                      // get return address into a general register
 920         ;;
 921
 922         // going to virtual
 923         //   - for code addresses, set upper bits of addr to KERNEL_START
 924         //   - for stack addresses, copy from input argument
 925         movl r18=KERNEL_START
 926         dep r3=0,r3,KERNEL_TR_PAGE_SHIFT,64-KERNEL_TR_PAGE_SHIFT
 927         dep r14=0,r14,KERNEL_TR_PAGE_SHIFT,64-KERNEL_TR_PAGE_SHIFT
 928         mov sp=r20
 929         ;;
 930         or r3=r3,r18
 931         or r14=r14,r18
 932         ;;
 933
 934         mov r18=ar.rnat                 // save ar.rnat
 935         mov ar.bspstore=r19             // this steps on ar.rnat
 936         mov cr.iip=r3
 937         mov cr.ifs=r0
 938         ;;
 939         mov ar.rnat=r18                 // restore ar.rnat
 940         rfi                             // must be last insn in group
 941         ;;
 942 1:      mov rp=r14
 943         br.ret.sptk.many rp
 944 END(ia64_switch_mode_virt)
 945
 946 GLOBAL_ENTRY(ia64_delay_loop)
 947         .prologue
 948 {       nop 0                   // work around GAS unwind info generation bug...
 949         .save ar.lc,r2
 950         mov r2=ar.lc
 951         .body
 952         ;;
 953         mov ar.lc=r32
 954 }
 955         ;;
 956         // force loop to be 32-byte aligned (GAS bug means we cannot use .align
 957         // inside function body without corrupting unwind info).
 958 {       nop 0 }
 959 1:      br.cloop.sptk.few 1b
 960         ;;
 961         mov ar.lc=r2
 962         br.ret.sptk.many rp
 963 END(ia64_delay_loop)
 964
 965 /*
 966  * Return a CPU-local timestamp in nano-seconds.  This timestamp is
 967  * NOT synchronized across CPUs its return value must never be
 968  * compared against the values returned on another CPU.  The usage in
 969  * kernel/sched.c ensures that.
 970  *
 971  * The return-value of sched_clock() is NOT supposed to wrap-around.
 972  * If it did, it would cause some scheduling hiccups (at the worst).
 973  * Fortunately, with a 64-bit cycle-counter ticking at 100GHz, even
 974  * that would happen only once every 5+ years.
 975  *
 976  * The code below basically calculates:
 977  *
 978  *   (ia64_get_itc() * local_cpu_data->nsec_per_cyc) >> IA64_NSEC_PER_CYC_SHIFT
 979  *
 980  * except that the multiplication and the shift are done with 128-bit
 981  * intermediate precision so that we can produce a full 64-bit result.
 982  */
 983 GLOBAL_ENTRY(sched_clock)
 984         addl r8=THIS_CPU(cpu_info) + IA64_CPUINFO_NSEC_PER_CYC_OFFSET,r0
 985         mov.m r9=ar.itc         // fetch cycle-counter                          (35 cyc)
 986         ;;
 987         ldf8 f8=[r8]
 988         ;;
 989         setf.sig f9=r9          // certain to stall, so issue it _after_ ldf8...
 990         ;;
 991         xmpy.lu f10=f9,f8       // calculate low 64 bits of 128-bit product     (4 cyc)
 992         xmpy.hu f11=f9,f8       // calculate high 64 bits of 128-bit product
 993         ;;
 994         getf.sig r8=f10         //                                              (5 cyc)
 995         getf.sig r9=f11
 996         ;;
 997         shrp r8=r9,r8,IA64_NSEC_PER_CYC_SHIFT
 998         br.ret.sptk.many rp
 999 END(sched_clock)
1000
1001 GLOBAL_ENTRY(start_kernel_thread)
1002         .prologue
1003         .save rp, r0                            // this is the end of the call-chain
1004         .body
1005         alloc r2 = ar.pfs, 0, 0, 2, 0
1006         mov out0 = r9
1007         mov out1 = r11;;
1008         br.call.sptk.many rp = kernel_thread_helper;;
1009         mov out0 = r8
1010         br.call.sptk.many rp = sys_exit;;
1011 1:      br.sptk.few 1b                          // not reached
1012 END(start_kernel_thread)
1013
1014 #ifdef CONFIG_IA64_BRL_EMU
1015
1016 /*
1017  *  Assembly routines used by brl_emu.c to set preserved register state.
1018  */
1019
1020 #define SET_REG(reg)                            \
1021  GLOBAL_ENTRY(ia64_set_##reg);                  \
1022         alloc r16=ar.pfs,1,0,0,0;               \
1023         mov reg=r32;                            \
1024         ;;                                      \
1025         br.ret.sptk.many rp;                    \
1026  END(ia64_set_##reg)
1027
1028 SET_REG(b1);
1029 SET_REG(b2);
1030 SET_REG(b3);
1031 SET_REG(b4);
1032 SET_REG(b5);
1033
1034 #endif /* CONFIG_IA64_BRL_EMU */
1035
1036 #ifdef CONFIG_SMP
1037         /*
1038          * This routine handles spinlock contention.  It uses a non-standard calling
1039          * convention to avoid converting leaf routines into interior routines.  Because
1040          * of this special convention, there are several restrictions:
1041          *
1042          * - do not use gp relative variables, this code is called from the kernel
1043          *   and from modules, r1 is undefined.
1044          * - do not use stacked registers, the caller owns them.
1045          * - do not use the scratch stack space, the caller owns it.
1046          * - do not use any registers other than the ones listed below
1047          *
1048          * Inputs:
1049          *   ar.pfs - saved CFM of caller
1050          *   ar.ccv - 0 (and available for use)
1051          *   r27    - flags from spin_lock_irqsave or 0.  Must be preserved.
1052          *   r28    - available for use.
1053          *   r29    - available for use.
1054          *   r30    - available for use.
1055          *   r31    - address of lock, available for use.
1056          *   b6     - return address
1057          *   p14    - available for use.
1058          *   p15    - used to track flag status.
1059          *
1060          * If you patch this code to use more registers, do not forget to update
1061          * the clobber lists for spin_lock() in include/asm-ia64/spinlock.h.
1062          */
1063
1064 #if (__GNUC__ == 3 && __GNUC_MINOR__ < 3)
1065
1066 GLOBAL_ENTRY(ia64_spinlock_contention_pre3_4)
1067         .prologue
1068         .save ar.pfs, r0        // this code effectively has a zero frame size
1069         .save rp, r28
1070         .body
1071         nop 0
1072         tbit.nz p15,p0=r27,IA64_PSR_I_BIT
1073         .restore sp             // pop existing prologue after next insn
1074         mov b6 = r28
1075         .prologue
1076         .save ar.pfs, r0
1077         .altrp b6
1078         .body
1079         ;;
1080 (p15)   ssm psr.i               // reenable interrupts if they were on
1081                                 // DavidM says that srlz.d is slow and is not required in this case
1082 .wait:
1083         // exponential backoff, kdb, lockmeter etc. go in here
1084         hint @pause
1085         ld4 r30=[r31]           // don't use ld4.bias; if it's contended, we won't write the word
1086         nop 0
1087         ;;
1088         cmp4.ne p14,p0=r30,r0
1089 (p14)   br.cond.sptk.few .wait
1090 (p15)   rsm psr.i               // disable interrupts if we reenabled them
1091         br.cond.sptk.few b6     // lock is now free, try to acquire
1092         .global ia64_spinlock_contention_pre3_4_end     // for kernprof
1093 ia64_spinlock_contention_pre3_4_end:
1094 END(ia64_spinlock_contention_pre3_4)
1095
1096 #else
1097
1098 GLOBAL_ENTRY(ia64_spinlock_contention)
1099         .prologue
1100         .altrp b6
1101         .body
1102         tbit.nz p15,p0=r27,IA64_PSR_I_BIT
1103         ;;
1104 .wait:
1105 (p15)   ssm psr.i               // reenable interrupts if they were on
1106                                 // DavidM says that srlz.d is slow and is not required in this case
1107 .wait2:
1108         // exponential backoff, kdb, lockmeter etc. go in here
1109         hint @pause
1110         ld4 r30=[r31]           // don't use ld4.bias; if it's contended, we won't write the word
1111         ;;
1112         cmp4.ne p14,p0=r30,r0
1113         mov r30 = 1
1114 (p14)   br.cond.sptk.few .wait2
1115 (p15)   rsm psr.i               // disable interrupts if we reenabled them
1116         ;;
1117         cmpxchg4.acq r30=[r31], r30, ar.ccv
1118         ;;
1119         cmp4.ne p14,p0=r0,r30
1120 (p14)   br.cond.sptk.few .wait
1121
1122         br.ret.sptk.many b6     // lock is now taken
1123 END(ia64_spinlock_contention)
1124
1125 #endif
1126
1127 #ifdef CONFIG_HOTPLUG_CPU
1128 GLOBAL_ENTRY(ia64_jump_to_sal)
1129         alloc r16=ar.pfs,1,0,0,0;;
1130         rsm psr.i  | psr.ic
1131 {
1132         flushrs
1133         srlz.i
1134 }
1135         tpa r25=in0
1136         movl r18=tlb_purge_done;;
1137         DATA_VA_TO_PA(r18);;
1138         mov b1=r18      // Return location
1139         movl r18=ia64_do_tlb_purge;;
1140         DATA_VA_TO_PA(r18);;
1141         mov b2=r18      // doing tlb_flush work
1142         mov ar.rsc=0  // Put RSE  in enforced lazy, LE mode
1143         movl r17=1f;;
1144         DATA_VA_TO_PA(r17);;
1145         mov cr.iip=r17
1146         movl r16=SAL_PSR_BITS_TO_SET;;
1147         mov cr.ipsr=r16
1148         mov cr.ifs=r0;;
1149         rfi;;
1150 1:
1151         /*
1152          * Invalidate all TLB data/inst
1153          */
1154         br.sptk.many b2;; // jump to tlb purge code
1155
1156 tlb_purge_done:
1157         RESTORE_REGION_REGS(r25, r17,r18,r19);;
1158         RESTORE_REG(b0, r25, r17);;
1159         RESTORE_REG(b1, r25, r17);;
1160         RESTORE_REG(b2, r25, r17);;
1161         RESTORE_REG(b3, r25, r17);;
1162         RESTORE_REG(b4, r25, r17);;
1163         RESTORE_REG(b5, r25, r17);;
1164         ld8 r1=[r25],0x08;;
1165         ld8 r12=[r25],0x08;;
1166         ld8 r13=[r25],0x08;;
1167         RESTORE_REG(ar.fpsr, r25, r17);;
1168         RESTORE_REG(ar.pfs, r25, r17);;
1169         RESTORE_REG(ar.rnat, r25, r17);;
1170         RESTORE_REG(ar.unat, r25, r17);;
1171         RESTORE_REG(ar.bspstore, r25, r17);;
1172         RESTORE_REG(cr.dcr, r25, r17);;
1173         RESTORE_REG(cr.iva, r25, r17);;
1174         RESTORE_REG(cr.pta, r25, r17);;
1175         RESTORE_REG(cr.itv, r25, r17);;
1176         RESTORE_REG(cr.pmv, r25, r17);;
1177         RESTORE_REG(cr.cmcv, r25, r17);;
1178         RESTORE_REG(cr.lrr0, r25, r17);;
1179         RESTORE_REG(cr.lrr1, r25, r17);;
1180         ld8 r4=[r25],0x08;;
1181         ld8 r5=[r25],0x08;;
1182         ld8 r6=[r25],0x08;;
1183         ld8 r7=[r25],0x08;;
1184         ld8 r17=[r25],0x08;;
1185         mov pr=r17,-1;;
1186         RESTORE_REG(ar.lc, r25, r17);;
1187         /*
1188          * Now Restore floating point regs
1189          */
1190         ldf.fill.nta f2=[r25],16;;
1191         ldf.fill.nta f3=[r25],16;;
1192         ldf.fill.nta f4=[r25],16;;
1193         ldf.fill.nta f5=[r25],16;;
1194         ldf.fill.nta f16=[r25],16;;
1195         ldf.fill.nta f17=[r25],16;;
1196         ldf.fill.nta f18=[r25],16;;
1197         ldf.fill.nta f19=[r25],16;;
1198         ldf.fill.nta f20=[r25],16;;
1199         ldf.fill.nta f21=[r25],16;;
1200         ldf.fill.nta f22=[r25],16;;
1201         ldf.fill.nta f23=[r25],16;;
1202         ldf.fill.nta f24=[r25],16;;
1203         ldf.fill.nta f25=[r25],16;;
1204         ldf.fill.nta f26=[r25],16;;
1205         ldf.fill.nta f27=[r25],16;;
1206         ldf.fill.nta f28=[r25],16;;
1207         ldf.fill.nta f29=[r25],16;;
1208         ldf.fill.nta f30=[r25],16;;
1209         ldf.fill.nta f31=[r25],16;;
1210
1211         /*
1212          * Now that we have done all the register restores
1213          * we are now ready for the big DIVE to SAL Land
1214          */
1215         ssm psr.ic;;
1216         srlz.d;;
1217         br.ret.sptk.many b0;;
1218 END(ia64_jump_to_sal)
1219 #endif /* CONFIG_HOTPLUG_CPU */
1220
1221 #endif /* CONFIG_SMP */