git.oblomov.eu Git - linux-2.6/blob - arch/x86_64/ia32/ia32entry.S

   1 /*
   2  * Compatibility mode system call entry point for x86-64.
   3  *
   4  * Copyright 2000-2002 Andi Kleen, SuSE Labs.
   5  */
   6
   7 #include <asm/dwarf2.h>
   8 #include <asm/calling.h>
   9 #include <asm/asm-offsets.h>
  10 #include <asm/current.h>
  11 #include <asm/errno.h>
  12 #include <asm/ia32_unistd.h>
  13 #include <asm/thread_info.h>
  14 #include <asm/segment.h>
  15 #include <asm/vsyscall32.h>
  16 #include <asm/irqflags.h>
  17 #include <linux/linkage.h>
  18
  19 #define IA32_NR_syscalls ((ia32_syscall_end - ia32_sys_call_table)/8)
  20
  21         .macro IA32_ARG_FIXUP noebp=0
  22         movl    %edi,%r8d
  23         .if \noebp
  24         .else
  25         movl    %ebp,%r9d
  26         .endif
  27         xchg    %ecx,%esi
  28         movl    %ebx,%edi
  29         movl    %edx,%edx       /* zero extension */
  30         .endm
  31
  32         /* clobbers %eax */
  33         .macro  CLEAR_RREGS
  34         xorl    %eax,%eax
  35         movq    %rax,R11(%rsp)
  36         movq    %rax,R10(%rsp)
  37         movq    %rax,R9(%rsp)
  38         movq    %rax,R8(%rsp)
  39         .endm
  40
  41         .macro CFI_STARTPROC32 simple
  42         CFI_STARTPROC   \simple
  43         CFI_UNDEFINED   r8
  44         CFI_UNDEFINED   r9
  45         CFI_UNDEFINED   r10
  46         CFI_UNDEFINED   r11
  47         CFI_UNDEFINED   r12
  48         CFI_UNDEFINED   r13
  49         CFI_UNDEFINED   r14
  50         CFI_UNDEFINED   r15
  51         .endm
  52
  53 /*
  54  * 32bit SYSENTER instruction entry.
  55  *
  56  * Arguments:
  57  * %eax System call number.
  58  * %ebx Arg1
  59  * %ecx Arg2
  60  * %edx Arg3
  61  * %esi Arg4
  62  * %edi Arg5
  63  * %ebp user stack
  64  * 0(%ebp) Arg6
  65  *
  66  * Interrupts off.
  67  *
  68  * This is purely a fast path. For anything complicated we use the int 0x80
  69  * path below.  Set up a complete hardware stack frame to share code
  70  * with the int 0x80 path.
  71  */
  72 ENTRY(ia32_sysenter_target)
  73         CFI_STARTPROC32 simple
  74         CFI_DEF_CFA     rsp,0
  75         CFI_REGISTER    rsp,rbp
  76         swapgs
  77         movq    %gs:pda_kernelstack, %rsp
  78         addq    $(PDA_STACKOFFSET),%rsp
  79         /*
  80          * No need to follow this irqs on/off section: the syscall
  81          * disabled irqs, here we enable it straight after entry:
  82          */
  83         sti
  84         movl    %ebp,%ebp               /* zero extension */
  85         pushq   $__USER32_DS
  86         CFI_ADJUST_CFA_OFFSET 8
  87         /*CFI_REL_OFFSET ss,0*/
  88         pushq   %rbp
  89         CFI_ADJUST_CFA_OFFSET 8
  90         CFI_REL_OFFSET rsp,0
  91         pushfq
  92         CFI_ADJUST_CFA_OFFSET 8
  93         /*CFI_REL_OFFSET rflags,0*/
  94         movl    $VSYSCALL32_SYSEXIT, %r10d
  95         CFI_REGISTER rip,r10
  96         pushq   $__USER32_CS
  97         CFI_ADJUST_CFA_OFFSET 8
  98         /*CFI_REL_OFFSET cs,0*/
  99         movl    %eax, %eax
 100         pushq   %r10
 101         CFI_ADJUST_CFA_OFFSET 8
 102         CFI_REL_OFFSET rip,0
 103         pushq   %rax
 104         CFI_ADJUST_CFA_OFFSET 8
 105         cld
 106         SAVE_ARGS 0,0,0
 107         /* no need to do an access_ok check here because rbp has been
 108            32bit zero extended */
 109 1:      movl    (%rbp),%r9d
 110         .section __ex_table,"a"
 111         .quad 1b,ia32_badarg
 112         .previous
 113         GET_THREAD_INFO(%r10)
 114         orl    $TS_COMPAT,threadinfo_status(%r10)
 115         testl  $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SECCOMP),threadinfo_flags(%r10)
 116         CFI_REMEMBER_STATE
 117         jnz  sysenter_tracesys
 118 sysenter_do_call:
 119         cmpl    $(IA32_NR_syscalls-1),%eax
 120         ja      ia32_badsys
 121         IA32_ARG_FIXUP 1
 122         call    *ia32_sys_call_table(,%rax,8)
 123         movq    %rax,RAX-ARGOFFSET(%rsp)
 124         GET_THREAD_INFO(%r10)
 125         cli
 126         TRACE_IRQS_OFF
 127         testl   $_TIF_ALLWORK_MASK,threadinfo_flags(%r10)
 128         jnz     int_ret_from_sys_call
 129         andl    $~TS_COMPAT,threadinfo_status(%r10)
 130         /* clear IF, that popfq doesn't enable interrupts early */
 131         andl  $~0x200,EFLAGS-R11(%rsp)
 132         RESTORE_ARGS 1,24,1,1,1,1
 133         popfq
 134         CFI_ADJUST_CFA_OFFSET -8
 135         /*CFI_RESTORE rflags*/
 136         popq    %rcx                            /* User %esp */
 137         CFI_ADJUST_CFA_OFFSET -8
 138         CFI_REGISTER rsp,rcx
 139         movl    $VSYSCALL32_SYSEXIT,%edx        /* User %eip */
 140         CFI_REGISTER rip,rdx
 141         TRACE_IRQS_ON
 142         swapgs
 143         sti             /* sti only takes effect after the next instruction */
 144         /* sysexit */
 145         .byte   0xf, 0x35
 146
 147 sysenter_tracesys:
 148         CFI_RESTORE_STATE
 149         SAVE_REST
 150         CLEAR_RREGS
 151         movq    $-ENOSYS,RAX(%rsp)      /* really needed? */
 152         movq    %rsp,%rdi        /* &pt_regs -> arg1 */
 153         call    syscall_trace_enter
 154         LOAD_ARGS ARGOFFSET  /* reload args from stack in case ptrace changed it */
 155         RESTORE_REST
 156         movl    %ebp, %ebp
 157         /* no need to do an access_ok check here because rbp has been
 158            32bit zero extended */
 159 1:      movl    (%rbp),%r9d
 160         .section __ex_table,"a"
 161         .quad 1b,ia32_badarg
 162         .previous
 163         jmp     sysenter_do_call
 164         CFI_ENDPROC
 165 ENDPROC(ia32_sysenter_target)
 166
 167 /*
 168  * 32bit SYSCALL instruction entry.
 169  *
 170  * Arguments:
 171  * %eax System call number.
 172  * %ebx Arg1
 173  * %ecx return EIP
 174  * %edx Arg3
 175  * %esi Arg4
 176  * %edi Arg5
 177  * %ebp Arg2    [note: not saved in the stack frame, should not be touched]
 178  * %esp user stack
 179  * 0(%esp) Arg6
 180  *
 181  * Interrupts off.
 182  *
 183  * This is purely a fast path. For anything complicated we use the int 0x80
 184  * path below.  Set up a complete hardware stack frame to share code
 185  * with the int 0x80 path.
 186  */
 187 ENTRY(ia32_cstar_target)
 188         CFI_STARTPROC32 simple
 189         CFI_DEF_CFA     rsp,PDA_STACKOFFSET
 190         CFI_REGISTER    rip,rcx
 191         /*CFI_REGISTER  rflags,r11*/
 192         swapgs
 193         movl    %esp,%r8d
 194         CFI_REGISTER    rsp,r8
 195         movq    %gs:pda_kernelstack,%rsp
 196         /*
 197          * No need to follow this irqs on/off section: the syscall
 198          * disabled irqs and here we enable it straight after entry:
 199          */
 200         sti
 201         SAVE_ARGS 8,1,1
 202         movl    %eax,%eax       /* zero extension */
 203         movq    %rax,ORIG_RAX-ARGOFFSET(%rsp)
 204         movq    %rcx,RIP-ARGOFFSET(%rsp)
 205         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 206         movq    %rbp,RCX-ARGOFFSET(%rsp) /* this lies slightly to ptrace */
 207         movl    %ebp,%ecx
 208         movq    $__USER32_CS,CS-ARGOFFSET(%rsp)
 209         movq    $__USER32_DS,SS-ARGOFFSET(%rsp)
 210         movq    %r11,EFLAGS-ARGOFFSET(%rsp)
 211         /*CFI_REL_OFFSET rflags,EFLAGS-ARGOFFSET*/
 212         movq    %r8,RSP-ARGOFFSET(%rsp)
 213         CFI_REL_OFFSET rsp,RSP-ARGOFFSET
 214         /* no need to do an access_ok check here because r8 has been
 215            32bit zero extended */
 216         /* hardware stack frame is complete now */
 217 1:      movl    (%r8),%r9d
 218         .section __ex_table,"a"
 219         .quad 1b,ia32_badarg
 220         .previous
 221         GET_THREAD_INFO(%r10)
 222         orl   $TS_COMPAT,threadinfo_status(%r10)
 223         testl $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SECCOMP),threadinfo_flags(%r10)
 224         CFI_REMEMBER_STATE
 225         jnz   cstar_tracesys
 226 cstar_do_call:
 227         cmpl $IA32_NR_syscalls-1,%eax
 228         ja  ia32_badsys
 229         IA32_ARG_FIXUP 1
 230         call *ia32_sys_call_table(,%rax,8)
 231         movq %rax,RAX-ARGOFFSET(%rsp)
 232         GET_THREAD_INFO(%r10)
 233         cli
 234         TRACE_IRQS_OFF
 235         testl $_TIF_ALLWORK_MASK,threadinfo_flags(%r10)
 236         jnz  int_ret_from_sys_call
 237         andl $~TS_COMPAT,threadinfo_status(%r10)
 238         RESTORE_ARGS 1,-ARG_SKIP,1,1,1
 239         movl RIP-ARGOFFSET(%rsp),%ecx
 240         CFI_REGISTER rip,rcx
 241         movl EFLAGS-ARGOFFSET(%rsp),%r11d
 242         /*CFI_REGISTER rflags,r11*/
 243         TRACE_IRQS_ON
 244         movl RSP-ARGOFFSET(%rsp),%esp
 245         CFI_RESTORE rsp
 246         swapgs
 247         sysretl
 248
 249 cstar_tracesys:
 250         CFI_RESTORE_STATE
 251         SAVE_REST
 252         CLEAR_RREGS
 253         movq $-ENOSYS,RAX(%rsp) /* really needed? */
 254         movq %rsp,%rdi        /* &pt_regs -> arg1 */
 255         call syscall_trace_enter
 256         LOAD_ARGS ARGOFFSET  /* reload args from stack in case ptrace changed it */
 257         RESTORE_REST
 258         movl RSP-ARGOFFSET(%rsp), %r8d
 259         /* no need to do an access_ok check here because r8 has been
 260            32bit zero extended */
 261 1:      movl    (%r8),%r9d
 262         .section __ex_table,"a"
 263         .quad 1b,ia32_badarg
 264         .previous
 265         jmp cstar_do_call
 266 END(ia32_cstar_target)
 267
 268 ia32_badarg:
 269         movq $-EFAULT,%rax
 270         jmp ia32_sysret
 271         CFI_ENDPROC
 272
 273 /*
 274  * Emulated IA32 system calls via int 0x80.
 275  *
 276  * Arguments:
 277  * %eax System call number.
 278  * %ebx Arg1
 279  * %ecx Arg2
 280  * %edx Arg3
 281  * %esi Arg4
 282  * %edi Arg5
 283  * %ebp Arg6    [note: not saved in the stack frame, should not be touched]
 284  *
 285  * Notes:
 286  * Uses the same stack frame as the x86-64 version.
 287  * All registers except %eax must be saved (but ptrace may violate that)
 288  * Arguments are zero extended. For system calls that want sign extension and
 289  * take long arguments a wrapper is needed. Most calls can just be called
 290  * directly.
 291  * Assumes it is only called from user space and entered with interrupts off.
 292  */
 293
 294 ENTRY(ia32_syscall)
 295         CFI_STARTPROC   simple
 296         CFI_DEF_CFA     rsp,SS+8-RIP
 297         /*CFI_REL_OFFSET        ss,SS-RIP*/
 298         CFI_REL_OFFSET  rsp,RSP-RIP
 299         /*CFI_REL_OFFSET        rflags,EFLAGS-RIP*/
 300         /*CFI_REL_OFFSET        cs,CS-RIP*/
 301         CFI_REL_OFFSET  rip,RIP-RIP
 302         swapgs
 303         /*
 304          * No need to follow this irqs on/off section: the syscall
 305          * disabled irqs and here we enable it straight after entry:
 306          */
 307         sti
 308         movl %eax,%eax
 309         pushq %rax
 310         CFI_ADJUST_CFA_OFFSET 8
 311         cld
 312         /* note the registers are not zero extended to the sf.
 313            this could be a problem. */
 314         SAVE_ARGS 0,0,1
 315         GET_THREAD_INFO(%r10)
 316         orl   $TS_COMPAT,threadinfo_status(%r10)
 317         testl $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SECCOMP),threadinfo_flags(%r10)
 318         jnz ia32_tracesys
 319 ia32_do_syscall:
 320         cmpl $(IA32_NR_syscalls-1),%eax
 321         ja  ia32_badsys
 322         IA32_ARG_FIXUP
 323         call *ia32_sys_call_table(,%rax,8) # xxx: rip relative
 324 ia32_sysret:
 325         movq %rax,RAX-ARGOFFSET(%rsp)
 326         jmp int_ret_from_sys_call
 327
 328 ia32_tracesys:
 329         SAVE_REST
 330         movq $-ENOSYS,RAX(%rsp) /* really needed? */
 331         movq %rsp,%rdi        /* &pt_regs -> arg1 */
 332         call syscall_trace_enter
 333         LOAD_ARGS ARGOFFSET  /* reload args from stack in case ptrace changed it */
 334         RESTORE_REST
 335         jmp ia32_do_syscall
 336 END(ia32_syscall)
 337
 338 ia32_badsys:
 339         movq $0,ORIG_RAX-ARGOFFSET(%rsp)
 340         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 341         jmp int_ret_from_sys_call
 342
 343 quiet_ni_syscall:
 344         movq $-ENOSYS,%rax
 345         ret
 346         CFI_ENDPROC
 347
 348         .macro PTREGSCALL label, func, arg
 349         .globl \label
 350 \label:
 351         leaq \func(%rip),%rax
 352         leaq -ARGOFFSET+8(%rsp),\arg    /* 8 for return address */
 353         jmp  ia32_ptregs_common
 354         .endm
 355
 356         CFI_STARTPROC32
 357
 358         PTREGSCALL stub32_rt_sigreturn, sys32_rt_sigreturn, %rdi
 359         PTREGSCALL stub32_sigreturn, sys32_sigreturn, %rdi
 360         PTREGSCALL stub32_sigaltstack, sys32_sigaltstack, %rdx
 361         PTREGSCALL stub32_sigsuspend, sys32_sigsuspend, %rcx
 362         PTREGSCALL stub32_execve, sys32_execve, %rcx
 363         PTREGSCALL stub32_fork, sys_fork, %rdi
 364         PTREGSCALL stub32_clone, sys32_clone, %rdx
 365         PTREGSCALL stub32_vfork, sys_vfork, %rdi
 366         PTREGSCALL stub32_iopl, sys_iopl, %rsi
 367         PTREGSCALL stub32_rt_sigsuspend, sys_rt_sigsuspend, %rdx
 368
 369 ENTRY(ia32_ptregs_common)
 370         popq %r11
 371         CFI_ENDPROC
 372         CFI_STARTPROC32 simple
 373         CFI_DEF_CFA     rsp,SS+8-ARGOFFSET
 374         CFI_REL_OFFSET  rax,RAX-ARGOFFSET
 375         CFI_REL_OFFSET  rcx,RCX-ARGOFFSET
 376         CFI_REL_OFFSET  rdx,RDX-ARGOFFSET
 377         CFI_REL_OFFSET  rsi,RSI-ARGOFFSET
 378         CFI_REL_OFFSET  rdi,RDI-ARGOFFSET
 379         CFI_REL_OFFSET  rip,RIP-ARGOFFSET
 380 /*      CFI_REL_OFFSET  cs,CS-ARGOFFSET*/
 381 /*      CFI_REL_OFFSET  rflags,EFLAGS-ARGOFFSET*/
 382         CFI_REL_OFFSET  rsp,RSP-ARGOFFSET
 383 /*      CFI_REL_OFFSET  ss,SS-ARGOFFSET*/
 384         SAVE_REST
 385         call *%rax
 386         RESTORE_REST
 387         jmp  ia32_sysret        /* misbalances the return cache */
 388         CFI_ENDPROC
 389 END(ia32_ptregs_common)
 390
 391         .section .rodata,"a"
 392         .align 8
 393 ia32_sys_call_table:
 394         .quad sys_restart_syscall
 395         .quad sys_exit
 396         .quad stub32_fork
 397         .quad sys_read
 398         .quad sys_write
 399         .quad compat_sys_open           /* 5 */
 400         .quad sys_close
 401         .quad sys32_waitpid
 402         .quad sys_creat
 403         .quad sys_link
 404         .quad sys_unlink                /* 10 */
 405         .quad stub32_execve
 406         .quad sys_chdir
 407         .quad compat_sys_time
 408         .quad sys_mknod
 409         .quad sys_chmod         /* 15 */
 410         .quad sys_lchown16
 411         .quad quiet_ni_syscall                  /* old break syscall holder */
 412         .quad sys_stat
 413         .quad sys32_lseek
 414         .quad sys_getpid                /* 20 */
 415         .quad compat_sys_mount  /* mount  */
 416         .quad sys_oldumount     /* old_umount  */
 417         .quad sys_setuid16
 418         .quad sys_getuid16
 419         .quad compat_sys_stime  /* stime */             /* 25 */
 420         .quad sys32_ptrace      /* ptrace */
 421         .quad sys_alarm
 422         .quad sys_fstat /* (old)fstat */
 423         .quad sys_pause
 424         .quad compat_sys_utime  /* 30 */
 425         .quad quiet_ni_syscall  /* old stty syscall holder */
 426         .quad quiet_ni_syscall  /* old gtty syscall holder */
 427         .quad sys_access
 428         .quad sys_nice
 429         .quad quiet_ni_syscall  /* 35 */        /* old ftime syscall holder */
 430         .quad sys_sync
 431         .quad sys32_kill
 432         .quad sys_rename
 433         .quad sys_mkdir
 434         .quad sys_rmdir         /* 40 */
 435         .quad sys_dup
 436         .quad sys32_pipe
 437         .quad compat_sys_times
 438         .quad quiet_ni_syscall                  /* old prof syscall holder */
 439         .quad sys_brk           /* 45 */
 440         .quad sys_setgid16
 441         .quad sys_getgid16
 442         .quad sys_signal
 443         .quad sys_geteuid16
 444         .quad sys_getegid16     /* 50 */
 445         .quad sys_acct
 446         .quad sys_umount                        /* new_umount */
 447         .quad quiet_ni_syscall                  /* old lock syscall holder */
 448         .quad compat_sys_ioctl
 449         .quad compat_sys_fcntl64                /* 55 */
 450         .quad quiet_ni_syscall                  /* old mpx syscall holder */
 451         .quad sys_setpgid
 452         .quad quiet_ni_syscall                  /* old ulimit syscall holder */
 453         .quad sys32_olduname
 454         .quad sys_umask         /* 60 */
 455         .quad sys_chroot
 456         .quad sys32_ustat
 457         .quad sys_dup2
 458         .quad sys_getppid
 459         .quad sys_getpgrp               /* 65 */
 460         .quad sys_setsid
 461         .quad sys32_sigaction
 462         .quad sys_sgetmask
 463         .quad sys_ssetmask
 464         .quad sys_setreuid16    /* 70 */
 465         .quad sys_setregid16
 466         .quad stub32_sigsuspend
 467         .quad compat_sys_sigpending
 468         .quad sys_sethostname
 469         .quad compat_sys_setrlimit      /* 75 */
 470         .quad compat_sys_old_getrlimit  /* old_getrlimit */
 471         .quad compat_sys_getrusage
 472         .quad sys32_gettimeofday
 473         .quad sys32_settimeofday
 474         .quad sys_getgroups16   /* 80 */
 475         .quad sys_setgroups16
 476         .quad sys32_old_select
 477         .quad sys_symlink
 478         .quad sys_lstat
 479         .quad sys_readlink              /* 85 */
 480 #ifdef CONFIG_IA32_AOUT
 481         .quad sys_uselib
 482 #else
 483         .quad quiet_ni_syscall
 484 #endif
 485         .quad sys_swapon
 486         .quad sys_reboot
 487         .quad compat_sys_old_readdir
 488         .quad sys32_mmap                /* 90 */
 489         .quad sys_munmap
 490         .quad sys_truncate
 491         .quad sys_ftruncate
 492         .quad sys_fchmod
 493         .quad sys_fchown16              /* 95 */
 494         .quad sys_getpriority
 495         .quad sys_setpriority
 496         .quad quiet_ni_syscall                  /* old profil syscall holder */
 497         .quad compat_sys_statfs
 498         .quad compat_sys_fstatfs                /* 100 */
 499         .quad sys_ioperm
 500         .quad compat_sys_socketcall
 501         .quad sys_syslog
 502         .quad compat_sys_setitimer
 503         .quad compat_sys_getitimer      /* 105 */
 504         .quad compat_sys_newstat
 505         .quad compat_sys_newlstat
 506         .quad compat_sys_newfstat
 507         .quad sys32_uname
 508         .quad stub32_iopl               /* 110 */
 509         .quad sys_vhangup
 510         .quad quiet_ni_syscall  /* old "idle" system call */
 511         .quad sys32_vm86_warning        /* vm86old */
 512         .quad compat_sys_wait4
 513         .quad sys_swapoff               /* 115 */
 514         .quad sys32_sysinfo
 515         .quad sys32_ipc
 516         .quad sys_fsync
 517         .quad stub32_sigreturn
 518         .quad stub32_clone              /* 120 */
 519         .quad sys_setdomainname
 520         .quad sys_uname
 521         .quad sys_modify_ldt
 522         .quad compat_sys_adjtimex
 523         .quad sys32_mprotect            /* 125 */
 524         .quad compat_sys_sigprocmask
 525         .quad quiet_ni_syscall          /* create_module */
 526         .quad sys_init_module
 527         .quad sys_delete_module
 528         .quad quiet_ni_syscall          /* 130  get_kernel_syms */
 529         .quad sys_quotactl
 530         .quad sys_getpgid
 531         .quad sys_fchdir
 532         .quad quiet_ni_syscall  /* bdflush */
 533         .quad sys_sysfs         /* 135 */
 534         .quad sys_personality
 535         .quad quiet_ni_syscall  /* for afs_syscall */
 536         .quad sys_setfsuid16
 537         .quad sys_setfsgid16
 538         .quad sys_llseek                /* 140 */
 539         .quad compat_sys_getdents
 540         .quad compat_sys_select
 541         .quad sys_flock
 542         .quad sys_msync
 543         .quad compat_sys_readv          /* 145 */
 544         .quad compat_sys_writev
 545         .quad sys_getsid
 546         .quad sys_fdatasync
 547         .quad sys32_sysctl      /* sysctl */
 548         .quad sys_mlock         /* 150 */
 549         .quad sys_munlock
 550         .quad sys_mlockall
 551         .quad sys_munlockall
 552         .quad sys_sched_setparam
 553         .quad sys_sched_getparam   /* 155 */
 554         .quad sys_sched_setscheduler
 555         .quad sys_sched_getscheduler
 556         .quad sys_sched_yield
 557         .quad sys_sched_get_priority_max
 558         .quad sys_sched_get_priority_min  /* 160 */
 559         .quad sys_sched_rr_get_interval
 560         .quad compat_sys_nanosleep
 561         .quad sys_mremap
 562         .quad sys_setresuid16
 563         .quad sys_getresuid16   /* 165 */
 564         .quad sys32_vm86_warning        /* vm86 */
 565         .quad quiet_ni_syscall  /* query_module */
 566         .quad sys_poll
 567         .quad compat_sys_nfsservctl
 568         .quad sys_setresgid16   /* 170 */
 569         .quad sys_getresgid16
 570         .quad sys_prctl
 571         .quad stub32_rt_sigreturn
 572         .quad sys32_rt_sigaction
 573         .quad sys32_rt_sigprocmask      /* 175 */
 574         .quad sys32_rt_sigpending
 575         .quad compat_sys_rt_sigtimedwait
 576         .quad sys32_rt_sigqueueinfo
 577         .quad stub32_rt_sigsuspend
 578         .quad sys32_pread               /* 180 */
 579         .quad sys32_pwrite
 580         .quad sys_chown16
 581         .quad sys_getcwd
 582         .quad sys_capget
 583         .quad sys_capset
 584         .quad stub32_sigaltstack
 585         .quad sys32_sendfile
 586         .quad quiet_ni_syscall          /* streams1 */
 587         .quad quiet_ni_syscall          /* streams2 */
 588         .quad stub32_vfork            /* 190 */
 589         .quad compat_sys_getrlimit
 590         .quad sys32_mmap2
 591         .quad sys32_truncate64
 592         .quad sys32_ftruncate64
 593         .quad sys32_stat64              /* 195 */
 594         .quad sys32_lstat64
 595         .quad sys32_fstat64
 596         .quad sys_lchown
 597         .quad sys_getuid
 598         .quad sys_getgid                /* 200 */
 599         .quad sys_geteuid
 600         .quad sys_getegid
 601         .quad sys_setreuid
 602         .quad sys_setregid
 603         .quad sys_getgroups     /* 205 */
 604         .quad sys_setgroups
 605         .quad sys_fchown
 606         .quad sys_setresuid
 607         .quad sys_getresuid
 608         .quad sys_setresgid     /* 210 */
 609         .quad sys_getresgid
 610         .quad sys_chown
 611         .quad sys_setuid
 612         .quad sys_setgid
 613         .quad sys_setfsuid              /* 215 */
 614         .quad sys_setfsgid
 615         .quad sys_pivot_root
 616         .quad sys_mincore
 617         .quad sys_madvise
 618         .quad compat_sys_getdents64     /* 220 getdents64 */
 619         .quad compat_sys_fcntl64
 620         .quad quiet_ni_syscall          /* tux */
 621         .quad quiet_ni_syscall          /* security */
 622         .quad sys_gettid
 623         .quad sys_readahead     /* 225 */
 624         .quad sys_setxattr
 625         .quad sys_lsetxattr
 626         .quad sys_fsetxattr
 627         .quad sys_getxattr
 628         .quad sys_lgetxattr     /* 230 */
 629         .quad sys_fgetxattr
 630         .quad sys_listxattr
 631         .quad sys_llistxattr
 632         .quad sys_flistxattr
 633         .quad sys_removexattr   /* 235 */
 634         .quad sys_lremovexattr
 635         .quad sys_fremovexattr
 636         .quad sys_tkill
 637         .quad sys_sendfile64
 638         .quad compat_sys_futex          /* 240 */
 639         .quad compat_sys_sched_setaffinity
 640         .quad compat_sys_sched_getaffinity
 641         .quad sys32_set_thread_area
 642         .quad sys32_get_thread_area
 643         .quad compat_sys_io_setup       /* 245 */
 644         .quad sys_io_destroy
 645         .quad compat_sys_io_getevents
 646         .quad compat_sys_io_submit
 647         .quad sys_io_cancel
 648         .quad sys_fadvise64             /* 250 */
 649         .quad quiet_ni_syscall  /* free_huge_pages */
 650         .quad sys_exit_group
 651         .quad sys32_lookup_dcookie
 652         .quad sys_epoll_create
 653         .quad sys_epoll_ctl             /* 255 */
 654         .quad sys_epoll_wait
 655         .quad sys_remap_file_pages
 656         .quad sys_set_tid_address
 657         .quad compat_sys_timer_create
 658         .quad compat_sys_timer_settime  /* 260 */
 659         .quad compat_sys_timer_gettime
 660         .quad sys_timer_getoverrun
 661         .quad sys_timer_delete
 662         .quad compat_sys_clock_settime
 663         .quad compat_sys_clock_gettime  /* 265 */
 664         .quad compat_sys_clock_getres
 665         .quad compat_sys_clock_nanosleep
 666         .quad compat_sys_statfs64
 667         .quad compat_sys_fstatfs64
 668         .quad sys_tgkill                /* 270 */
 669         .quad compat_sys_utimes
 670         .quad sys32_fadvise64_64
 671         .quad quiet_ni_syscall  /* sys_vserver */
 672         .quad sys_mbind
 673         .quad compat_sys_get_mempolicy  /* 275 */
 674         .quad sys_set_mempolicy
 675         .quad compat_sys_mq_open
 676         .quad sys_mq_unlink
 677         .quad compat_sys_mq_timedsend
 678         .quad compat_sys_mq_timedreceive        /* 280 */
 679         .quad compat_sys_mq_notify
 680         .quad compat_sys_mq_getsetattr
 681         .quad compat_sys_kexec_load     /* reserved for kexec */
 682         .quad compat_sys_waitid
 683         .quad quiet_ni_syscall          /* 285: sys_altroot */
 684         .quad sys_add_key
 685         .quad sys_request_key
 686         .quad sys_keyctl
 687         .quad sys_ioprio_set
 688         .quad sys_ioprio_get            /* 290 */
 689         .quad sys_inotify_init
 690         .quad sys_inotify_add_watch
 691         .quad sys_inotify_rm_watch
 692         .quad sys_migrate_pages
 693         .quad compat_sys_openat         /* 295 */
 694         .quad sys_mkdirat
 695         .quad sys_mknodat
 696         .quad sys_fchownat
 697         .quad compat_sys_futimesat
 698         .quad sys32_fstatat             /* 300 */
 699         .quad sys_unlinkat
 700         .quad sys_renameat
 701         .quad sys_linkat
 702         .quad sys_symlinkat
 703         .quad sys_readlinkat            /* 305 */
 704         .quad sys_fchmodat
 705         .quad sys_faccessat
 706         .quad quiet_ni_syscall          /* pselect6 for now */
 707         .quad quiet_ni_syscall          /* ppoll for now */
 708         .quad sys_unshare               /* 310 */
 709         .quad compat_sys_set_robust_list
 710         .quad compat_sys_get_robust_list
 711         .quad sys_splice
 712         .quad sys_sync_file_range
 713         .quad sys_tee
 714         .quad compat_sys_vmsplice
 715         .quad compat_sys_move_pages
 716 ia32_syscall_end: