git.oblomov.eu Git - linux-2.6/blob - arch/i386/kernel/vmlinux.lds.S

   1 /* ld script to make i386 Linux kernel
   2  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>;
   3  */
   4
   5 #define LOAD_OFFSET __PAGE_OFFSET
   6
   7 #include <asm-generic/vmlinux.lds.h>
   8 #include <asm/thread_info.h>
   9 #include <asm/page.h>
  10 #include <asm/cache.h>
  11
  12 OUTPUT_FORMAT("elf32-i386", "elf32-i386", "elf32-i386")
  13 OUTPUT_ARCH(i386)
  14 ENTRY(phys_startup_32)
  15 jiffies = jiffies_64;
  16
  17 PHDRS {
  18         text PT_LOAD FLAGS(5);  /* R_E */
  19         data PT_LOAD FLAGS(7);  /* RWE */
  20         note PT_NOTE FLAGS(4);  /* R__ */
  21 }
  22 SECTIONS
  23 {
  24   . = __KERNEL_START;
  25   phys_startup_32 = startup_32 - LOAD_OFFSET;
  26   /* read-only */
  27   _text = .;                    /* Text and read-only data */
  28   .text : AT(ADDR(.text) - LOAD_OFFSET) {
  29         *(.text)
  30         SCHED_TEXT
  31         LOCK_TEXT
  32         KPROBES_TEXT
  33         *(.fixup)
  34         *(.gnu.warning)
  35         } :text = 0x9090
  36
  37   _etext = .;                   /* End of text section */
  38
  39   . = ALIGN(16);                /* Exception table */
  40   __start___ex_table = .;
  41   __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { *(__ex_table) }
  42   __stop___ex_table = .;
  43
  44   RODATA
  45
  46   . = ALIGN(4);
  47   __tracedata_start = .;
  48   .tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) {
  49         *(.tracedata)
  50   }
  51   __tracedata_end = .;
  52
  53   /* writeable */
  54   .data : AT(ADDR(.data) - LOAD_OFFSET) {       /* Data */
  55         *(.data)
  56         CONSTRUCTORS
  57         } :data
  58
  59   . = ALIGN(4096);
  60   __nosave_begin = .;
  61   .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) { *(.data.nosave) }
  62   . = ALIGN(4096);
  63   __nosave_end = .;
  64
  65   . = ALIGN(4096);
  66   .data.page_aligned : AT(ADDR(.data.page_aligned) - LOAD_OFFSET) {
  67         *(.data.idt)
  68   }
  69
  70   . = ALIGN(32);
  71   .data.cacheline_aligned : AT(ADDR(.data.cacheline_aligned) - LOAD_OFFSET) {
  72         *(.data.cacheline_aligned)
  73   }
  74
  75   /* rarely changed data like cpu maps */
  76   . = ALIGN(32);
  77   .data.read_mostly : AT(ADDR(.data.read_mostly) - LOAD_OFFSET) { *(.data.read_mostly) }
  78   _edata = .;                   /* End of data section */
  79
  80 #ifdef CONFIG_STACK_UNWIND
  81   . = ALIGN(4);
  82   .eh_frame : AT(ADDR(.eh_frame) - LOAD_OFFSET) {
  83         __start_unwind = .;
  84         *(.eh_frame)
  85         __end_unwind = .;
  86   }
  87 #endif
  88
  89   . = ALIGN(THREAD_SIZE);       /* init_task */
  90   .data.init_task : AT(ADDR(.data.init_task) - LOAD_OFFSET) {
  91         *(.data.init_task)
  92   }
  93
  94   /* might get freed after init */
  95   . = ALIGN(4096);
  96   __smp_alt_begin = .;
  97   __smp_alt_instructions = .;
  98   .smp_altinstructions : AT(ADDR(.smp_altinstructions) - LOAD_OFFSET) {
  99         *(.smp_altinstructions)
 100   }
 101   __smp_alt_instructions_end = .;
 102   . = ALIGN(4);
 103   __smp_locks = .;
 104   .smp_locks : AT(ADDR(.smp_locks) - LOAD_OFFSET) {
 105         *(.smp_locks)
 106   }
 107   __smp_locks_end = .;
 108   .smp_altinstr_replacement : AT(ADDR(.smp_altinstr_replacement) - LOAD_OFFSET) {
 109         *(.smp_altinstr_replacement)
 110   }
 111   . = ALIGN(4096);
 112   __smp_alt_end = .;
 113
 114   /* will be freed after init */
 115   . = ALIGN(4096);              /* Init code and data */
 116   __init_begin = .;
 117   .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {
 118         _sinittext = .;
 119         *(.init.text)
 120         _einittext = .;
 121   }
 122   .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { *(.init.data) }
 123   . = ALIGN(16);
 124   __setup_start = .;
 125   .init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) { *(.init.setup) }
 126   __setup_end = .;
 127   __initcall_start = .;
 128   .initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET) {
 129         *(.initcall1.init)
 130         *(.initcall2.init)
 131         *(.initcall3.init)
 132         *(.initcall4.init)
 133         *(.initcall5.init)
 134         *(.initcall6.init)
 135         *(.initcall7.init)
 136   }
 137   __initcall_end = .;
 138   __con_initcall_start = .;
 139   .con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) {
 140         *(.con_initcall.init)
 141   }
 142   __con_initcall_end = .;
 143   SECURITY_INIT
 144   . = ALIGN(4);
 145   __alt_instructions = .;
 146   .altinstructions : AT(ADDR(.altinstructions) - LOAD_OFFSET) {
 147         *(.altinstructions)
 148   }
 149   __alt_instructions_end = .;
 150   .altinstr_replacement : AT(ADDR(.altinstr_replacement) - LOAD_OFFSET) {
 151         *(.altinstr_replacement)
 152   }
 153   /* .exit.text is discard at runtime, not link time, to deal with references
 154      from .altinstructions and .eh_frame */
 155   .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) { *(.exit.text) }
 156   .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) { *(.exit.data) }
 157   . = ALIGN(4096);
 158   __initramfs_start = .;
 159   .init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET) { *(.init.ramfs) }
 160   __initramfs_end = .;
 161   . = ALIGN(L1_CACHE_BYTES);
 162   __per_cpu_start = .;
 163   .data.percpu  : AT(ADDR(.data.percpu) - LOAD_OFFSET) { *(.data.percpu) }
 164   __per_cpu_end = .;
 165   . = ALIGN(4096);
 166   __init_end = .;
 167   /* freed after init ends here */
 168
 169   __bss_start = .;              /* BSS */
 170   .bss.page_aligned : AT(ADDR(.bss.page_aligned) - LOAD_OFFSET) {
 171         *(.bss.page_aligned)
 172   }
 173   .bss : AT(ADDR(.bss) - LOAD_OFFSET) {
 174         *(.bss)
 175   }
 176   . = ALIGN(4);
 177   __bss_stop = .;
 178
 179   _end = . ;
 180
 181   /* This is where the kernel creates the early boot page tables */
 182   . = ALIGN(4096);
 183   pg0 = .;
 184
 185   /* Sections to be discarded */
 186   /DISCARD/ : {
 187         *(.exitcall.exit)
 188         }
 189
 190   STABS_DEBUG
 191
 192   DWARF_DEBUG
 193
 194   NOTES
 195 }