git.oblomov.eu Git - linux-2.6/blob - arch/i386/kernel/vmlinux.lds.S

   1 /* ld script to make i386 Linux kernel
   2  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>;
   3  */
   4
   5 #define LOAD_OFFSET __PAGE_OFFSET
   6
   7 #include <asm-generic/vmlinux.lds.h>
   8 #include <asm/thread_info.h>
   9 #include <asm/page.h>
  10
  11 OUTPUT_FORMAT("elf32-i386", "elf32-i386", "elf32-i386")
  12 OUTPUT_ARCH(i386)
  13 ENTRY(phys_startup_32)
  14 jiffies = jiffies_64;
  15 SECTIONS
  16 {
  17   . = __KERNEL_START;
  18   phys_startup_32 = startup_32 - LOAD_OFFSET;
  19   /* read-only */
  20   _text = .;                    /* Text and read-only data */
  21   .text : AT(ADDR(.text) - LOAD_OFFSET) {
  22         *(.text)
  23         SCHED_TEXT
  24         LOCK_TEXT
  25         *(.fixup)
  26         *(.gnu.warning)
  27         } = 0x9090
  28
  29   _etext = .;                   /* End of text section */
  30
  31   . = ALIGN(16);                /* Exception table */
  32   __start___ex_table = .;
  33   __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { *(__ex_table) }
  34   __stop___ex_table = .;
  35
  36   RODATA
  37
  38   /* writeable */
  39   .data : AT(ADDR(.data) - LOAD_OFFSET) {       /* Data */
  40         *(.data)
  41         CONSTRUCTORS
  42         }
  43
  44   . = ALIGN(4096);
  45   __nosave_begin = .;
  46   .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) { *(.data.nosave) }
  47   . = ALIGN(4096);
  48   __nosave_end = .;
  49
  50   . = ALIGN(4096);
  51   .data.page_aligned : AT(ADDR(.data.page_aligned) - LOAD_OFFSET) {
  52         *(.data.idt)
  53   }
  54
  55   . = ALIGN(32);
  56   .data.cacheline_aligned : AT(ADDR(.data.cacheline_aligned) - LOAD_OFFSET) {
  57         *(.data.cacheline_aligned)
  58   }
  59
  60   /* rarely changed data like cpu maps */
  61   . = ALIGN(32);
  62   .data.read_mostly : AT(ADDR(.data.read_mostly) - LOAD_OFFSET) { *(.data.read_mostly) }
  63   _edata = .;                   /* End of data section */
  64
  65   . = ALIGN(THREAD_SIZE);       /* init_task */
  66   .data.init_task : AT(ADDR(.data.init_task) - LOAD_OFFSET) {
  67         *(.data.init_task)
  68   }
  69
  70   /* will be freed after init */
  71   . = ALIGN(4096);              /* Init code and data */
  72   __init_begin = .;
  73   .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {
  74         _sinittext = .;
  75         *(.init.text)
  76         _einittext = .;
  77   }
  78   .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { *(.init.data) }
  79   . = ALIGN(16);
  80   __setup_start = .;
  81   .init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) { *(.init.setup) }
  82   __setup_end = .;
  83   __initcall_start = .;
  84   .initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET) {
  85         *(.initcall1.init)
  86         *(.initcall2.init)
  87         *(.initcall3.init)
  88         *(.initcall4.init)
  89         *(.initcall5.init)
  90         *(.initcall6.init)
  91         *(.initcall7.init)
  92   }
  93   __initcall_end = .;
  94   __con_initcall_start = .;
  95   .con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) {
  96         *(.con_initcall.init)
  97   }
  98   __con_initcall_end = .;
  99   SECURITY_INIT
 100   . = ALIGN(4);
 101   __alt_instructions = .;
 102   .altinstructions : AT(ADDR(.altinstructions) - LOAD_OFFSET) {
 103         *(.altinstructions)
 104   }
 105   __alt_instructions_end = .;
 106   .altinstr_replacement : AT(ADDR(.altinstr_replacement) - LOAD_OFFSET) {
 107         *(.altinstr_replacement)
 108   }
 109   /* .exit.text is discard at runtime, not link time, to deal with references
 110      from .altinstructions and .eh_frame */
 111   .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) { *(.exit.text) }
 112   .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) { *(.exit.data) }
 113   . = ALIGN(4096);
 114   __initramfs_start = .;
 115   .init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET) { *(.init.ramfs) }
 116   __initramfs_end = .;
 117   . = ALIGN(32);
 118   __per_cpu_start = .;
 119   .data.percpu  : AT(ADDR(.data.percpu) - LOAD_OFFSET) { *(.data.percpu) }
 120   __per_cpu_end = .;
 121   . = ALIGN(4096);
 122   __init_end = .;
 123   /* freed after init ends here */
 124
 125   __bss_start = .;              /* BSS */
 126   .bss.page_aligned : AT(ADDR(.bss.page_aligned) - LOAD_OFFSET) {
 127         *(.bss.page_aligned)
 128   }
 129   .bss : AT(ADDR(.bss) - LOAD_OFFSET) {
 130         *(.bss)
 131   }
 132   . = ALIGN(4);
 133   __bss_stop = .;
 134
 135   _end = . ;
 136
 137   /* This is where the kernel creates the early boot page tables */
 138   . = ALIGN(4096);
 139   pg0 = .;
 140
 141   /* Sections to be discarded */
 142   /DISCARD/ : {
 143         *(.exitcall.exit)
 144         }
 145
 146   /* Stabs debugging sections.  */
 147   .stab 0 : { *(.stab) }
 148   .stabstr 0 : { *(.stabstr) }
 149   .stab.excl 0 : { *(.stab.excl) }
 150   .stab.exclstr 0 : { *(.stab.exclstr) }
 151   .stab.index 0 : { *(.stab.index) }
 152   .stab.indexstr 0 : { *(.stab.indexstr) }
 153   .comment 0 : { *(.comment) }
 154 }