git.oblomov.eu Git - linux-2.6/blob - arch/i386/kernel/vmlinux.lds.S

   1 /* ld script to make i386 Linux kernel
   2  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>;
   3  */
   4
   5 #define LOAD_OFFSET __PAGE_OFFSET
   6
   7 #include <asm-generic/vmlinux.lds.h>
   8 #include <asm/thread_info.h>
   9 #include <asm/page.h>
  10
  11 OUTPUT_FORMAT("elf32-i386", "elf32-i386", "elf32-i386")
  12 OUTPUT_ARCH(i386)
  13 ENTRY(phys_startup_32)
  14 jiffies = jiffies_64;
  15 SECTIONS
  16 {
  17   . = __KERNEL_START;
  18   phys_startup_32 = startup_32 - LOAD_OFFSET;
  19   /* read-only */
  20   _text = .;                    /* Text and read-only data */
  21   .text : AT(ADDR(.text) - LOAD_OFFSET) {
  22         *(.text)
  23         SCHED_TEXT
  24         LOCK_TEXT
  25         *(.fixup)
  26         *(.gnu.warning)
  27         } = 0x9090
  28
  29   _etext = .;                   /* End of text section */
  30
  31   . = ALIGN(16);                /* Exception table */
  32   __start___ex_table = .;
  33   __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { *(__ex_table) }
  34   __stop___ex_table = .;
  35
  36   RODATA
  37
  38   /* writeable */
  39   .data : AT(ADDR(.data) - LOAD_OFFSET) {       /* Data */
  40         *(.data)
  41         CONSTRUCTORS
  42         }
  43
  44   . = ALIGN(4096);
  45   __nosave_begin = .;
  46   .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) { *(.data.nosave) }
  47   . = ALIGN(4096);
  48   __nosave_end = .;
  49
  50   . = ALIGN(4096);
  51   .data.page_aligned : AT(ADDR(.data.page_aligned) - LOAD_OFFSET) {
  52         *(.data.idt)
  53   }
  54
  55   . = ALIGN(32);
  56   .data.cacheline_aligned : AT(ADDR(.data.cacheline_aligned) - LOAD_OFFSET) {
  57         *(.data.cacheline_aligned)
  58   }
  59
  60   _edata = .;                   /* End of data section */
  61
  62   . = ALIGN(THREAD_SIZE);       /* init_task */
  63   .data.init_task : AT(ADDR(.data.init_task) - LOAD_OFFSET) {
  64         *(.data.init_task)
  65   }
  66
  67   /* will be freed after init */
  68   . = ALIGN(4096);              /* Init code and data */
  69   __init_begin = .;
  70   .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {
  71         _sinittext = .;
  72         *(.init.text)
  73         _einittext = .;
  74   }
  75   .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { *(.init.data) }
  76   . = ALIGN(16);
  77   __setup_start = .;
  78   .init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) { *(.init.setup) }
  79   __setup_end = .;
  80   __initcall_start = .;
  81   .initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET) {
  82         *(.initcall1.init)
  83         *(.initcall2.init)
  84         *(.initcall3.init)
  85         *(.initcall4.init)
  86         *(.initcall5.init)
  87         *(.initcall6.init)
  88         *(.initcall7.init)
  89   }
  90   __initcall_end = .;
  91   __con_initcall_start = .;
  92   .con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) {
  93         *(.con_initcall.init)
  94   }
  95   __con_initcall_end = .;
  96   SECURITY_INIT
  97   . = ALIGN(4);
  98   __alt_instructions = .;
  99   .altinstructions : AT(ADDR(.altinstructions) - LOAD_OFFSET) {
 100         *(.altinstructions)
 101   }
 102   __alt_instructions_end = .;
 103   .altinstr_replacement : AT(ADDR(.altinstr_replacement) - LOAD_OFFSET) {
 104         *(.altinstr_replacement)
 105   }
 106   /* .exit.text is discard at runtime, not link time, to deal with references
 107      from .altinstructions and .eh_frame */
 108   .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) { *(.exit.text) }
 109   .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) { *(.exit.data) }
 110   . = ALIGN(4096);
 111   __initramfs_start = .;
 112   .init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET) { *(.init.ramfs) }
 113   __initramfs_end = .;
 114   . = ALIGN(32);
 115   __per_cpu_start = .;
 116   .data.percpu  : AT(ADDR(.data.percpu) - LOAD_OFFSET) { *(.data.percpu) }
 117   __per_cpu_end = .;
 118   . = ALIGN(4096);
 119   __init_end = .;
 120   /* freed after init ends here */
 121
 122   __bss_start = .;              /* BSS */
 123   .bss.page_aligned : AT(ADDR(.bss.page_aligned) - LOAD_OFFSET) {
 124         *(.bss.page_aligned)
 125   }
 126   .bss : AT(ADDR(.bss) - LOAD_OFFSET) {
 127         *(.bss)
 128   }
 129   . = ALIGN(4);
 130   __bss_stop = .;
 131
 132   _end = . ;
 133
 134   /* This is where the kernel creates the early boot page tables */
 135   . = ALIGN(4096);
 136   pg0 = .;
 137
 138   /* Sections to be discarded */
 139   /DISCARD/ : {
 140         *(.exitcall.exit)
 141         }
 142
 143   /* Stabs debugging sections.  */
 144   .stab 0 : { *(.stab) }
 145   .stabstr 0 : { *(.stabstr) }
 146   .stab.excl 0 : { *(.stab.excl) }
 147   .stab.exclstr 0 : { *(.stab.exclstr) }
 148   .stab.index 0 : { *(.stab.index) }
 149   .stab.indexstr 0 : { *(.stab.indexstr) }
 150   .comment 0 : { *(.comment) }
 151 }