git.oblomov.eu Git - linux-2.6/blob - scripts/checkstack.pl

   1 #!/usr/bin/perl
   2
   3 #       Check the stack usage of functions
   4 #
   5 #       Copyright Joern Engel <joern@wh.fh-wedel.de>
   6 #       Inspired by Linus Torvalds
   7 #       Original idea maybe from Keith Owens
   8 #       s390 port and big speedup by Arnd Bergmann <arnd@bergmann-dalldorf.de>
   9 #       Mips port by Juan Quintela <quintela@mandrakesoft.com>
  10 #       IA64 port via Andreas Dilger
  11 #       Arm port by Holger Schurig
  12 #       sh64 port by Paul Mundt
  13 #       Random bits by Matt Mackall <mpm@selenic.com>
  14 #       M68k port by Geert Uytterhoeven and Andreas Schwab
  15 #       AVR32 port by Haavard Skinnemoen <hskinnemoen@atmel.com>
  16 #
  17 #       Usage:
  18 #       objdump -d vmlinux | stackcheck.pl [arch]
  19 #
  20 #       TODO :  Port to all architectures (one regex per arch)
  21
  22 # check for arch
  23 #
  24 # $re is used for two matches:
  25 # $& (whole re) matches the complete objdump line with the stack growth
  26 # $1 (first bracket) matches the size of the stack growth
  27 #
  28 # use anything else and feel the pain ;)
  29 my (@stack, $re, $x, $xs);
  30 {
  31         my $arch = shift;
  32         if ($arch eq "") {
  33                 $arch = `uname -m`;
  34         }
  35
  36         $x      = "[0-9a-f]";   # hex character
  37         $xs     = "[0-9a-f ]";  # hex character or space
  38         if ($arch eq 'arm') {
  39                 #c0008ffc:      e24dd064        sub     sp, sp, #100    ; 0x64
  40                 $re = qr/.*sub.*sp, sp, #(([0-9]{2}|[3-9])[0-9]{2})/o;
  41         } elsif ($arch eq 'avr32') {
  42                 #8000008a:       20 1d           sub sp,4
  43                 #80000ca8:       fa cd 05 b0     sub sp,sp,1456
  44                 $re = qr/^.*sub.*sp.*,([0-9]{1,8})/o;
  45         } elsif ($arch =~ /^i[3456]86$/) {
  46                 #c0105234:       81 ec ac 05 00 00       sub    $0x5ac,%esp
  47                 $re = qr/^.*[as][du][db]    \$(0x$x{1,8}),\%esp$/o;
  48         } elsif ($arch eq 'x86_64') {
  49                 #    2f60:      48 81 ec e8 05 00 00    sub    $0x5e8,%rsp
  50                 $re = qr/^.*[as][du][db]    \$(0x$x{1,8}),\%rsp$/o;
  51         } elsif ($arch eq 'ia64') {
  52                 #e0000000044011fc:       01 0f fc 8c     adds r12=-384,r12
  53                 $re = qr/.*adds.*r12=-(([0-9]{2}|[3-9])[0-9]{2}),r12/o;
  54         } elsif ($arch eq 'm68k') {
  55                 #    2b6c:       4e56 fb70       linkw %fp,#-1168
  56                 #  1df770:       defc ffe4       addaw #-28,%sp
  57                 $re = qr/.*(?:linkw %fp,|addaw )#-([0-9]{1,4})(?:,%sp)?$/o;
  58         } elsif ($arch eq 'mips64') {
  59                 #8800402c:       67bdfff0        daddiu  sp,sp,-16
  60                 $re = qr/.*daddiu.*sp,sp,-(([0-9]{2}|[3-9])[0-9]{2})/o;
  61         } elsif ($arch eq 'mips') {
  62                 #88003254:       27bdffe0        addiu   sp,sp,-32
  63                 $re = qr/.*addiu.*sp,sp,-(([0-9]{2}|[3-9])[0-9]{2})/o;
  64         } elsif ($arch eq 'ppc') {
  65                 #c00029f4:       94 21 ff 30     stwu    r1,-208(r1)
  66                 $re = qr/.*stwu.*r1,-($x{1,8})\(r1\)/o;
  67         } elsif ($arch eq 'ppc64') {
  68                 #XXX
  69                 $re = qr/.*stdu.*r1,-($x{1,8})\(r1\)/o;
  70         } elsif ($arch eq 'powerpc') {
  71                 $re = qr/.*st[dw]u.*r1,-($x{1,8})\(r1\)/o;
  72         } elsif ($arch =~ /^s390x?$/) {
  73                 #   11160:       a7 fb ff 60             aghi   %r15,-160
  74                 $re = qr/.*ag?hi.*\%r15,-(([0-9]{2}|[3-9])[0-9]{2})/o;
  75         } elsif ($arch =~ /^sh64$/) {
  76                 #XXX: we only check for the immediate case presently,
  77                 #     though we will want to check for the movi/sub
  78                 #     pair for larger users. -- PFM.
  79                 #a00048e0:       d4fc40f0        addi.l  r15,-240,r15
  80                 $re = qr/.*addi\.l.*r15,-(([0-9]{2}|[3-9])[0-9]{2}),r15/o;
  81         } elsif ($arch =~ /^blackfin$/) {
  82                 #   0:   00 e8 38 01     LINK 0x4e0;
  83                 $re = qr/.*[[:space:]]LINK[[:space:]]*(0x$x{1,8})/o;
  84         } else {
  85                 print("wrong or unknown architecture\n");
  86                 exit
  87         }
  88 }
  89
  90 sub bysize($) {
  91         my ($asize, $bsize);
  92         ($asize = $a) =~ s/.*:  *(.*)$/$1/;
  93         ($bsize = $b) =~ s/.*:  *(.*)$/$1/;
  94         $bsize <=> $asize
  95 }
  96
  97 #
  98 # main()
  99 #
 100 my $funcre = qr/^$x* <(.*)>:$/;
 101 my $func;
 102 my $file, $lastslash;
 103
 104 while (my $line = <STDIN>) {
 105         if ($line =~ m/$funcre/) {
 106                 $func = $1;
 107         }
 108         elsif ($line =~ m/(.*):\s*file format/) {
 109                 $file = $1;
 110                 $file =~ s/\.ko//;
 111                 $lastslash = rindex($file, "/");
 112                 if ($lastslash != -1) {
 113                         $file = substr($file, $lastslash + 1);
 114                 }
 115         }
 116         elsif ($line =~ m/$re/) {
 117                 my $size = $1;
 118                 $size = hex($size) if ($size =~ /^0x/);
 119
 120                 if ($size > 0xf0000000) {
 121                         $size = - $size;
 122                         $size += 0x80000000;
 123                         $size += 0x80000000;
 124                 }
 125                 next if ($size > 0x10000000);
 126
 127                 next if $line !~ m/^($xs*)/;
 128                 my $addr = $1;
 129                 $addr =~ s/ /0/g;
 130                 $addr = "0x$addr";
 131
 132                 my $intro = "$addr $func [$file]:";
 133                 my $padlen = 56 - length($intro);
 134                 while ($padlen > 0) {
 135                         $intro .= '     ';
 136                         $padlen -= 8;
 137                 }
 138                 next if ($size < 100);
 139                 push @stack, "$intro$size\n";
 140         }
 141 }
 142
 143 print sort bysize @stack;