git.oblomov.eu Git - linux-2.6/blob - scripts/checkpatch.pl

   1 #!/usr/bin/perl -w
   2 # (c) 2001, Dave Jones. <davej@codemonkey.org.uk> (the file handling bit)
   3 # (c) 2005, Joel Schopp <jschopp@austin.ibm.com> (the ugly bit)
   4 # (c) 2007, Andy Whitcroft <apw@uk.ibm.com> (new conditions, test suite, etc)
   5 # Licensed under the terms of the GNU GPL License version 2
   6
   7 use strict;
   8
   9 my $P = $0;
  10 $P =~ s@.*/@@g;
  11
  12 my $V = '0.23';
  13
  14 use Getopt::Long qw(:config no_auto_abbrev);
  15
  16 my $quiet = 0;
  17 my $tree = 1;
  18 my $chk_signoff = 1;
  19 my $chk_patch = 1;
  20 my $tst_only;
  21 my $emacs = 0;
  22 my $terse = 0;
  23 my $file = 0;
  24 my $check = 0;
  25 my $summary = 1;
  26 my $mailback = 0;
  27 my $summary_file = 0;
  28 my $root;
  29 my %debug;
  30 GetOptions(
  31         'q|quiet+'      => \$quiet,
  32         'tree!'         => \$tree,
  33         'signoff!'      => \$chk_signoff,
  34         'patch!'        => \$chk_patch,
  35         'emacs!'        => \$emacs,
  36         'terse!'        => \$terse,
  37         'file!'         => \$file,
  38         'subjective!'   => \$check,
  39         'strict!'       => \$check,
  40         'root=s'        => \$root,
  41         'summary!'      => \$summary,
  42         'mailback!'     => \$mailback,
  43         'summary-file!' => \$summary_file,
  44
  45         'debug=s'       => \%debug,
  46         'test-only=s'   => \$tst_only,
  47 ) or exit;
  48
  49 my $exit = 0;
  50
  51 if ($#ARGV < 0) {
  52         print "usage: $P [options] patchfile\n";
  53         print "version: $V\n";
  54         print "options: -q               => quiet\n";
  55         print "         --no-tree        => run without a kernel tree\n";
  56         print "         --terse          => one line per report\n";
  57         print "         --emacs          => emacs compile window format\n";
  58         print "         --file           => check a source file\n";
  59         print "         --strict         => enable more subjective tests\n";
  60         print "         --root           => path to the kernel tree root\n";
  61         print "         --no-summary     => suppress the per-file summary\n";
  62         print "         --summary-file   => include the filename in summary\n";
  63         exit(1);
  64 }
  65
  66 my $dbg_values = 0;
  67 my $dbg_possible = 0;
  68 my $dbg_type = 0;
  69 my $dbg_attr = 0;
  70 for my $key (keys %debug) {
  71         eval "\${dbg_$key} = '$debug{$key}';"
  72 }
  73
  74 if ($terse) {
  75         $emacs = 1;
  76         $quiet++;
  77 }
  78
  79 if ($tree) {
  80         if (defined $root) {
  81                 if (!top_of_kernel_tree($root)) {
  82                         die "$P: $root: --root does not point at a valid tree\n";
  83                 }
  84         } else {
  85                 if (top_of_kernel_tree('.')) {
  86                         $root = '.';
  87                 } elsif ($0 =~ m@(.*)/scripts/[^/]*$@ &&
  88                                                 top_of_kernel_tree($1)) {
  89                         $root = $1;
  90                 }
  91         }
  92
  93         if (!defined $root) {
  94                 print "Must be run from the top-level dir. of a kernel tree\n";
  95                 exit(2);
  96         }
  97 }
  98
  99 my $emitted_corrupt = 0;
 100
 101 our $Ident       = qr{[A-Za-z_][A-Za-z\d_]*};
 102 our $Storage    = qr{extern|static|asmlinkage};
 103 our $Sparse     = qr{
 104                         __user|
 105                         __kernel|
 106                         __force|
 107                         __iomem|
 108                         __must_check|
 109                         __init_refok|
 110                         __kprobes
 111                 }x;
 112 our $Attribute  = qr{
 113                         const|
 114                         __read_mostly|
 115                         __kprobes|
 116                         __(?:mem|cpu|dev|)(?:initdata|init)|
 117                         ____cacheline_aligned|
 118                         ____cacheline_aligned_in_smp|
 119                         ____cacheline_internodealigned_in_smp
 120                   }x;
 121 our $Modifier;
 122 our $Inline     = qr{inline|__always_inline|noinline};
 123 our $Member     = qr{->$Ident|\.$Ident|\[[^]]*\]};
 124 our $Lval       = qr{$Ident(?:$Member)*};
 125
 126 our $Constant   = qr{(?:[0-9]+|0x[0-9a-fA-F]+)[UL]*};
 127 our $Assignment = qr{(?:\*\=|/=|%=|\+=|-=|<<=|>>=|&=|\^=|\|=|=)};
 128 our $Operators  = qr{
 129                         <=|>=|==|!=|
 130                         =>|->|<<|>>|<|>|!|~|
 131                         &&|\|\||,|\^|\+\+|--|&|\||\+|-|\*|\/|%
 132                   }x;
 133
 134 our $NonptrType;
 135 our $Type;
 136 our $Declare;
 137
 138 our $UTF8       = qr {
 139         [\x09\x0A\x0D\x20-\x7E]              # ASCII
 140         | [\xC2-\xDF][\x80-\xBF]             # non-overlong 2-byte
 141         |  \xE0[\xA0-\xBF][\x80-\xBF]        # excluding overlongs
 142         | [\xE1-\xEC\xEE\xEF][\x80-\xBF]{2}  # straight 3-byte
 143         |  \xED[\x80-\x9F][\x80-\xBF]        # excluding surrogates
 144         |  \xF0[\x90-\xBF][\x80-\xBF]{2}     # planes 1-3
 145         | [\xF1-\xF3][\x80-\xBF]{3}          # planes 4-15
 146         |  \xF4[\x80-\x8F][\x80-\xBF]{2}     # plane 16
 147 }x;
 148
 149 our @typeList = (
 150         qr{void},
 151         qr{(?:unsigned\s+)?char},
 152         qr{(?:unsigned\s+)?short},
 153         qr{(?:unsigned\s+)?int},
 154         qr{(?:unsigned\s+)?long},
 155         qr{(?:unsigned\s+)?long\s+int},
 156         qr{(?:unsigned\s+)?long\s+long},
 157         qr{(?:unsigned\s+)?long\s+long\s+int},
 158         qr{unsigned},
 159         qr{float},
 160         qr{double},
 161         qr{bool},
 162         qr{(?:__)?(?:u|s|be|le)(?:\d|\d\d)},
 163         qr{struct\s+$Ident},
 164         qr{union\s+$Ident},
 165         qr{enum\s+$Ident},
 166         qr{${Ident}_t},
 167         qr{${Ident}_handler},
 168         qr{${Ident}_handler_fn},
 169 );
 170 our @modifierList = (
 171         qr{fastcall},
 172 );
 173
 174 sub build_types {
 175         my $mods = "(?x:  \n" . join("|\n  ", @modifierList) . "\n)";
 176         my $all = "(?x:  \n" . join("|\n  ", @typeList) . "\n)";
 177         $Modifier       = qr{(?:$Attribute|$Sparse|$mods)};
 178         $NonptrType     = qr{
 179                         (?:$Modifier\s+|const\s+)*
 180                         (?:
 181                                 (?:typeof|__typeof__)\s*\(\s*\**\s*$Ident\s*\)|
 182                                 (?:${all}\b)
 183                         )
 184                         (?:\s+$Modifier|\s+const)*
 185                   }x;
 186         $Type   = qr{
 187                         $NonptrType
 188                         (?:\s*\*+\s*const|\s*\*+|(?:\s*\[\s*\])+)?
 189                         (?:\s+$Inline|\s+$Modifier)*
 190                   }x;
 191         $Declare        = qr{(?:$Storage\s+)?$Type};
 192 }
 193 build_types();
 194
 195 $chk_signoff = 0 if ($file);
 196
 197 my @dep_includes = ();
 198 my @dep_functions = ();
 199 my $removal = "Documentation/feature-removal-schedule.txt";
 200 if ($tree && -f "$root/$removal") {
 201         open(REMOVE, "<$root/$removal") ||
 202                                 die "$P: $removal: open failed - $!\n";
 203         while (<REMOVE>) {
 204                 if (/^Check:\s+(.*\S)/) {
 205                         for my $entry (split(/[, ]+/, $1)) {
 206                                 if ($entry =~ m@include/(.*)@) {
 207                                         push(@dep_includes, $1);
 208
 209                                 } elsif ($entry !~ m@/@) {
 210                                         push(@dep_functions, $entry);
 211                                 }
 212                         }
 213                 }
 214         }
 215 }
 216
 217 my @rawlines = ();
 218 my @lines = ();
 219 my $vname;
 220 for my $filename (@ARGV) {
 221         if ($file) {
 222                 open(FILE, "diff -u /dev/null $filename|") ||
 223                         die "$P: $filename: diff failed - $!\n";
 224         } else {
 225                 open(FILE, "<$filename") ||
 226                         die "$P: $filename: open failed - $!\n";
 227         }
 228         if ($filename eq '-') {
 229                 $vname = 'Your patch';
 230         } else {
 231                 $vname = $filename;
 232         }
 233         while (<FILE>) {
 234                 chomp;
 235                 push(@rawlines, $_);
 236         }
 237         close(FILE);
 238         if (!process($filename)) {
 239                 $exit = 1;
 240         }
 241         @rawlines = ();
 242         @lines = ();
 243 }
 244
 245 exit($exit);
 246
 247 sub top_of_kernel_tree {
 248         my ($root) = @_;
 249
 250         my @tree_check = (
 251                 "COPYING", "CREDITS", "Kbuild", "MAINTAINERS", "Makefile",
 252                 "README", "Documentation", "arch", "include", "drivers",
 253                 "fs", "init", "ipc", "kernel", "lib", "scripts",
 254         );
 255
 256         foreach my $check (@tree_check) {
 257                 if (! -e $root . '/' . $check) {
 258                         return 0;
 259                 }
 260         }
 261         return 1;
 262 }
 263
 264 sub expand_tabs {
 265         my ($str) = @_;
 266
 267         my $res = '';
 268         my $n = 0;
 269         for my $c (split(//, $str)) {
 270                 if ($c eq "\t") {
 271                         $res .= ' ';
 272                         $n++;
 273                         for (; ($n % 8) != 0; $n++) {
 274                                 $res .= ' ';
 275                         }
 276                         next;
 277                 }
 278                 $res .= $c;
 279                 $n++;
 280         }
 281
 282         return $res;
 283 }
 284 sub copy_spacing {
 285         (my $res = shift) =~ tr/\t/ /c;
 286         return $res;
 287 }
 288
 289 sub line_stats {
 290         my ($line) = @_;
 291
 292         # Drop the diff line leader and expand tabs
 293         $line =~ s/^.//;
 294         $line = expand_tabs($line);
 295
 296         # Pick the indent from the front of the line.
 297         my ($white) = ($line =~ /^(\s*)/);
 298
 299         return (length($line), length($white));
 300 }
 301
 302 my $sanitise_quote = '';
 303
 304 sub sanitise_line_reset {
 305         my ($in_comment) = @_;
 306
 307         if ($in_comment) {
 308                 $sanitise_quote = '*/';
 309         } else {
 310                 $sanitise_quote = '';
 311         }
 312 }
 313 sub sanitise_line {
 314         my ($line) = @_;
 315
 316         my $res = '';
 317         my $l = '';
 318
 319         my $qlen = 0;
 320         my $off = 0;
 321         my $c;
 322
 323         # Always copy over the diff marker.
 324         $res = substr($line, 0, 1);
 325
 326         for ($off = 1; $off < length($line); $off++) {
 327                 $c = substr($line, $off, 1);
 328
 329                 # Comments we are wacking completly including the begin
 330                 # and end, all to $;.
 331                 if ($sanitise_quote eq '' && substr($line, $off, 2) eq '/*') {
 332                         $sanitise_quote = '*/';
 333
 334                         substr($res, $off, 2, "$;$;");
 335                         $off++;
 336                         next;
 337                 }
 338                 if ($sanitise_quote eq '*/' && substr($line, $off, 2) eq '*/') {
 339                         $sanitise_quote = '';
 340                         substr($res, $off, 2, "$;$;");
 341                         $off++;
 342                         next;
 343                 }
 344
 345                 # A \ in a string means ignore the next character.
 346                 if (($sanitise_quote eq "'" || $sanitise_quote eq '"') &&
 347                     $c eq "\\") {
 348                         substr($res, $off, 2, 'XX');
 349                         $off++;
 350                         next;
 351                 }
 352                 # Regular quotes.
 353                 if ($c eq "'" || $c eq '"') {
 354                         if ($sanitise_quote eq '') {
 355                                 $sanitise_quote = $c;
 356
 357                                 substr($res, $off, 1, $c);
 358                                 next;
 359                         } elsif ($sanitise_quote eq $c) {
 360                                 $sanitise_quote = '';
 361                         }
 362                 }
 363
 364                 #print "SQ:$sanitise_quote\n";
 365                 if ($off != 0 && $sanitise_quote eq '*/' && $c ne "\t") {
 366                         substr($res, $off, 1, $;);
 367                 } elsif ($off != 0 && $sanitise_quote && $c ne "\t") {
 368                         substr($res, $off, 1, 'X');
 369                 } else {
 370                         substr($res, $off, 1, $c);
 371                 }
 372         }
 373
 374         # The pathname on a #include may be surrounded by '<' and '>'.
 375         if ($res =~ /^.\s*\#\s*include\s+\<(.*)\>/) {
 376                 my $clean = 'X' x length($1);
 377                 $res =~ s@\<.*\>@<$clean>@;
 378
 379         # The whole of a #error is a string.
 380         } elsif ($res =~ /^.\s*\#\s*(?:error|warning)\s+(.*)\b/) {
 381                 my $clean = 'X' x length($1);
 382                 $res =~ s@(\#\s*(?:error|warning)\s+).*@$1$clean@;
 383         }
 384
 385         return $res;
 386 }
 387
 388 sub ctx_statement_block {
 389         my ($linenr, $remain, $off) = @_;
 390         my $line = $linenr - 1;
 391         my $blk = '';
 392         my $soff = $off;
 393         my $coff = $off - 1;
 394         my $coff_set = 0;
 395
 396         my $loff = 0;
 397
 398         my $type = '';
 399         my $level = 0;
 400         my $p;
 401         my $c;
 402         my $len = 0;
 403
 404         my $remainder;
 405         while (1) {
 406                 #warn "CSB: blk<$blk> remain<$remain>\n";
 407                 # If we are about to drop off the end, pull in more
 408                 # context.
 409                 if ($off >= $len) {
 410                         for (; $remain > 0; $line++) {
 411                                 last if (!defined $lines[$line]);
 412                                 next if ($lines[$line] =~ /^-/);
 413                                 $remain--;
 414                                 $loff = $len;
 415                                 $blk .= $lines[$line] . "\n";
 416                                 $len = length($blk);
 417                                 $line++;
 418                                 last;
 419                         }
 420                         # Bail if there is no further context.
 421                         #warn "CSB: blk<$blk> off<$off> len<$len>\n";
 422                         if ($off >= $len) {
 423                                 last;
 424                         }
 425                 }
 426                 $p = $c;
 427                 $c = substr($blk, $off, 1);
 428                 $remainder = substr($blk, $off);
 429
 430                 #warn "CSB: c<$c> type<$type> level<$level> remainder<$remainder> coff_set<$coff_set>\n";
 431                 # Statement ends at the ';' or a close '}' at the
 432                 # outermost level.
 433                 if ($level == 0 && $c eq ';') {
 434                         last;
 435                 }
 436
 437                 # An else is really a conditional as long as its not else if
 438                 if ($level == 0 && $coff_set == 0 &&
 439                                 (!defined($p) || $p =~ /(?:\s|\}|\+)/) &&
 440                                 $remainder =~ /^(else)(?:\s|{)/ &&
 441                                 $remainder !~ /^else\s+if\b/) {
 442                         $coff = $off + length($1) - 1;
 443                         $coff_set = 1;
 444                         #warn "CSB: mark coff<$coff> soff<$soff> 1<$1>\n";
 445                         #warn "[" . substr($blk, $soff, $coff - $soff + 1) . "]\n";
 446                 }
 447
 448                 if (($type eq '' || $type eq '(') && $c eq '(') {
 449                         $level++;
 450                         $type = '(';
 451                 }
 452                 if ($type eq '(' && $c eq ')') {
 453                         $level--;
 454                         $type = ($level != 0)? '(' : '';
 455
 456                         if ($level == 0 && $coff < $soff) {
 457                                 $coff = $off;
 458                                 $coff_set = 1;
 459                                 #warn "CSB: mark coff<$coff>\n";
 460                         }
 461                 }
 462                 if (($type eq '' || $type eq '{') && $c eq '{') {
 463                         $level++;
 464                         $type = '{';
 465                 }
 466                 if ($type eq '{' && $c eq '}') {
 467                         $level--;
 468                         $type = ($level != 0)? '{' : '';
 469
 470                         if ($level == 0) {
 471                                 last;
 472                         }
 473                 }
 474                 $off++;
 475         }
 476         # We are truly at the end, so shuffle to the next line.
 477         if ($off == $len) {
 478                 $loff = $len + 1;
 479                 $line++;
 480                 $remain--;
 481         }
 482
 483         my $statement = substr($blk, $soff, $off - $soff + 1);
 484         my $condition = substr($blk, $soff, $coff - $soff + 1);
 485
 486         #warn "STATEMENT<$statement>\n";
 487         #warn "CONDITION<$condition>\n";
 488
 489         #print "coff<$coff> soff<$off> loff<$loff>\n";
 490
 491         return ($statement, $condition,
 492                         $line, $remain + 1, $off - $loff + 1, $level);
 493 }
 494
 495 sub statement_lines {
 496         my ($stmt) = @_;
 497
 498         # Strip the diff line prefixes and rip blank lines at start and end.
 499         $stmt =~ s/(^|\n)./$1/g;
 500         $stmt =~ s/^\s*//;
 501         $stmt =~ s/\s*$//;
 502
 503         my @stmt_lines = ($stmt =~ /\n/g);
 504
 505         return $#stmt_lines + 2;
 506 }
 507
 508 sub statement_rawlines {
 509         my ($stmt) = @_;
 510
 511         my @stmt_lines = ($stmt =~ /\n/g);
 512
 513         return $#stmt_lines + 2;
 514 }
 515
 516 sub statement_block_size {
 517         my ($stmt) = @_;
 518
 519         $stmt =~ s/(^|\n)./$1/g;
 520         $stmt =~ s/^\s*{//;
 521         $stmt =~ s/}\s*$//;
 522         $stmt =~ s/^\s*//;
 523         $stmt =~ s/\s*$//;
 524
 525         my @stmt_lines = ($stmt =~ /\n/g);
 526         my @stmt_statements = ($stmt =~ /;/g);
 527
 528         my $stmt_lines = $#stmt_lines + 2;
 529         my $stmt_statements = $#stmt_statements + 1;
 530
 531         if ($stmt_lines > $stmt_statements) {
 532                 return $stmt_lines;
 533         } else {
 534                 return $stmt_statements;
 535         }
 536 }
 537
 538 sub ctx_statement_full {
 539         my ($linenr, $remain, $off) = @_;
 540         my ($statement, $condition, $level);
 541
 542         my (@chunks);
 543
 544         # Grab the first conditional/block pair.
 545         ($statement, $condition, $linenr, $remain, $off, $level) =
 546                                 ctx_statement_block($linenr, $remain, $off);
 547         #print "F: c<$condition> s<$statement> remain<$remain>\n";
 548         push(@chunks, [ $condition, $statement ]);
 549         if (!($remain > 0 && $condition =~ /^\s*(?:\n[+-])?\s*(?:if|else|do)\b/s)) {
 550                 return ($level, $linenr, @chunks);
 551         }
 552
 553         # Pull in the following conditional/block pairs and see if they
 554         # could continue the statement.
 555         for (;;) {
 556                 ($statement, $condition, $linenr, $remain, $off, $level) =
 557                                 ctx_statement_block($linenr, $remain, $off);
 558                 #print "C: c<$condition> s<$statement> remain<$remain>\n";
 559                 last if (!($remain > 0 && $condition =~ /^(?:\s*\n[+-])*\s*(?:else|do)\b/s));
 560                 #print "C: push\n";
 561                 push(@chunks, [ $condition, $statement ]);
 562         }
 563
 564         return ($level, $linenr, @chunks);
 565 }
 566
 567 sub ctx_block_get {
 568         my ($linenr, $remain, $outer, $open, $close, $off) = @_;
 569         my $line;
 570         my $start = $linenr - 1;
 571         my $blk = '';
 572         my @o;
 573         my @c;
 574         my @res = ();
 575
 576         my $level = 0;
 577         for ($line = $start; $remain > 0; $line++) {
 578                 next if ($rawlines[$line] =~ /^-/);
 579                 $remain--;
 580
 581                 $blk .= $rawlines[$line];
 582                 foreach my $c (split(//, $rawlines[$line])) {
 583                         ##print "C<$c>L<$level><$open$close>O<$off>\n";
 584                         if ($off > 0) {
 585                                 $off--;
 586                                 next;
 587                         }
 588
 589                         if ($c eq $close && $level > 0) {
 590                                 $level--;
 591                                 last if ($level == 0);
 592                         } elsif ($c eq $open) {
 593                                 $level++;
 594                         }
 595                 }
 596
 597                 if (!$outer || $level <= 1) {
 598                         push(@res, $rawlines[$line]);
 599                 }
 600
 601                 last if ($level == 0);
 602         }
 603
 604         return ($level, @res);
 605 }
 606 sub ctx_block_outer {
 607         my ($linenr, $remain) = @_;
 608
 609         my ($level, @r) = ctx_block_get($linenr, $remain, 1, '{', '}', 0);
 610         return @r;
 611 }
 612 sub ctx_block {
 613         my ($linenr, $remain) = @_;
 614
 615         my ($level, @r) = ctx_block_get($linenr, $remain, 0, '{', '}', 0);
 616         return @r;
 617 }
 618 sub ctx_statement {
 619         my ($linenr, $remain, $off) = @_;
 620
 621         my ($level, @r) = ctx_block_get($linenr, $remain, 0, '(', ')', $off);
 622         return @r;
 623 }
 624 sub ctx_block_level {
 625         my ($linenr, $remain) = @_;
 626
 627         return ctx_block_get($linenr, $remain, 0, '{', '}', 0);
 628 }
 629 sub ctx_statement_level {
 630         my ($linenr, $remain, $off) = @_;
 631
 632         return ctx_block_get($linenr, $remain, 0, '(', ')', $off);
 633 }
 634
 635 sub ctx_locate_comment {
 636         my ($first_line, $end_line) = @_;
 637
 638         # Catch a comment on the end of the line itself.
 639         my ($current_comment) = ($rawlines[$end_line - 1] =~ m@.*(/\*.*\*/)\s*(?:\\\s*)?$@);
 640         return $current_comment if (defined $current_comment);
 641
 642         # Look through the context and try and figure out if there is a
 643         # comment.
 644         my $in_comment = 0;
 645         $current_comment = '';
 646         for (my $linenr = $first_line; $linenr < $end_line; $linenr++) {
 647                 my $line = $rawlines[$linenr - 1];
 648                 #warn "           $line\n";
 649                 if ($linenr == $first_line and $line =~ m@^.\s*\*@) {
 650                         $in_comment = 1;
 651                 }
 652                 if ($line =~ m@/\*@) {
 653                         $in_comment = 1;
 654                 }
 655                 if (!$in_comment && $current_comment ne '') {
 656                         $current_comment = '';
 657                 }
 658                 $current_comment .= $line . "\n" if ($in_comment);
 659                 if ($line =~ m@\*/@) {
 660                         $in_comment = 0;
 661                 }
 662         }
 663
 664         chomp($current_comment);
 665         return($current_comment);
 666 }
 667 sub ctx_has_comment {
 668         my ($first_line, $end_line) = @_;
 669         my $cmt = ctx_locate_comment($first_line, $end_line);
 670
 671         ##print "LINE: $rawlines[$end_line - 1 ]\n";
 672         ##print "CMMT: $cmt\n";
 673
 674         return ($cmt ne '');
 675 }
 676
 677 sub raw_line {
 678         my ($linenr, $cnt) = @_;
 679
 680         my $offset = $linenr - 1;
 681         $cnt++;
 682
 683         my $line;
 684         while ($cnt) {
 685                 $line = $rawlines[$offset++];
 686                 next if (defined($line) && $line =~ /^-/);
 687                 $cnt--;
 688         }
 689
 690         return $line;
 691 }
 692
 693 sub cat_vet {
 694         my ($vet) = @_;
 695         my ($res, $coded);
 696
 697         $res = '';
 698         while ($vet =~ /([^[:cntrl:]]*)([[:cntrl:]]|$)/g) {
 699                 $res .= $1;
 700                 if ($2 ne '') {
 701                         $coded = sprintf("^%c", unpack('C', $2) + 64);
 702                         $res .= $coded;
 703                 }
 704         }
 705         $res =~ s/$/\$/;
 706
 707         return $res;
 708 }
 709
 710 my $av_preprocessor = 0;
 711 my $av_pending;
 712 my @av_paren_type;
 713 my $av_pend_colon;
 714
 715 sub annotate_reset {
 716         $av_preprocessor = 0;
 717         $av_pending = '_';
 718         @av_paren_type = ('E');
 719         $av_pend_colon = 'O';
 720 }
 721
 722 sub annotate_values {
 723         my ($stream, $type) = @_;
 724
 725         my $res;
 726         my $var = '_' x length($stream);
 727         my $cur = $stream;
 728
 729         print "$stream\n" if ($dbg_values > 1);
 730
 731         while (length($cur)) {
 732                 @av_paren_type = ('E') if ($#av_paren_type < 0);
 733                 print " <" . join('', @av_paren_type) .
 734                                 "> <$type> <$av_pending>" if ($dbg_values > 1);
 735                 if ($cur =~ /^(\s+)/o) {
 736                         print "WS($1)\n" if ($dbg_values > 1);
 737                         if ($1 =~ /\n/ && $av_preprocessor) {
 738                                 $type = pop(@av_paren_type);
 739                                 $av_preprocessor = 0;
 740                         }
 741
 742                 } elsif ($cur =~ /^($Type)\s*(?:$Ident|,|\)|\()/) {
 743                         print "DECLARE($1)\n" if ($dbg_values > 1);
 744                         $type = 'T';
 745
 746                 } elsif ($cur =~ /^($Modifier)\s*/) {
 747                         print "MODIFIER($1)\n" if ($dbg_values > 1);
 748                         $type = 'T';
 749
 750                 } elsif ($cur =~ /^(\#\s*define\s*$Ident)(\(?)/o) {
 751                         print "DEFINE($1,$2)\n" if ($dbg_values > 1);
 752                         $av_preprocessor = 1;
 753                         push(@av_paren_type, $type);
 754                         if ($2 ne '') {
 755                                 $av_pending = 'N';
 756                         }
 757                         $type = 'E';
 758
 759                 } elsif ($cur =~ /^(\#\s*(?:undef\s*$Ident|include\b))/o) {
 760                         print "UNDEF($1)\n" if ($dbg_values > 1);
 761                         $av_preprocessor = 1;
 762                         push(@av_paren_type, $type);
 763
 764                 } elsif ($cur =~ /^(\#\s*(?:ifdef|ifndef|if))/o) {
 765                         print "PRE_START($1)\n" if ($dbg_values > 1);
 766                         $av_preprocessor = 1;
 767
 768                         push(@av_paren_type, $type);
 769                         push(@av_paren_type, $type);
 770                         $type = 'E';
 771
 772                 } elsif ($cur =~ /^(\#\s*(?:else|elif))/o) {
 773                         print "PRE_RESTART($1)\n" if ($dbg_values > 1);
 774                         $av_preprocessor = 1;
 775
 776                         push(@av_paren_type, $av_paren_type[$#av_paren_type]);
 777
 778                         $type = 'E';
 779
 780                 } elsif ($cur =~ /^(\#\s*(?:endif))/o) {
 781                         print "PRE_END($1)\n" if ($dbg_values > 1);
 782
 783                         $av_preprocessor = 1;
 784
 785                         # Assume all arms of the conditional end as this
 786                         # one does, and continue as if the #endif was not here.
 787                         pop(@av_paren_type);
 788                         push(@av_paren_type, $type);
 789                         $type = 'E';
 790
 791                 } elsif ($cur =~ /^(\\\n)/o) {
 792                         print "PRECONT($1)\n" if ($dbg_values > 1);
 793
 794                 } elsif ($cur =~ /^(__attribute__)\s*\(?/o) {
 795                         print "ATTR($1)\n" if ($dbg_values > 1);
 796                         $av_pending = $type;
 797                         $type = 'N';
 798
 799                 } elsif ($cur =~ /^(sizeof)\s*(\()?/o) {
 800                         print "SIZEOF($1)\n" if ($dbg_values > 1);
 801                         if (defined $2) {
 802                                 $av_pending = 'V';
 803                         }
 804                         $type = 'N';
 805
 806                 } elsif ($cur =~ /^(if|while|for)\b/o) {
 807                         print "COND($1)\n" if ($dbg_values > 1);
 808                         $av_pending = 'E';
 809                         $type = 'N';
 810
 811                 } elsif ($cur =~/^(case)/o) {
 812                         print "CASE($1)\n" if ($dbg_values > 1);
 813                         $av_pend_colon = 'C';
 814                         $type = 'N';
 815
 816                 } elsif ($cur =~/^(return|else|goto|typeof|__typeof__)\b/o) {
 817                         print "KEYWORD($1)\n" if ($dbg_values > 1);
 818                         $type = 'N';
 819
 820                 } elsif ($cur =~ /^(\()/o) {
 821                         print "PAREN('$1')\n" if ($dbg_values > 1);
 822                         push(@av_paren_type, $av_pending);
 823                         $av_pending = '_';
 824                         $type = 'N';
 825
 826                 } elsif ($cur =~ /^(\))/o) {
 827                         my $new_type = pop(@av_paren_type);
 828                         if ($new_type ne '_') {
 829                                 $type = $new_type;
 830                                 print "PAREN('$1') -> $type\n"
 831                                                         if ($dbg_values > 1);
 832                         } else {
 833                                 print "PAREN('$1')\n" if ($dbg_values > 1);
 834                         }
 835
 836                 } elsif ($cur =~ /^($Ident)\s*\(/o) {
 837                         print "FUNC($1)\n" if ($dbg_values > 1);
 838                         $type = 'V';
 839                         $av_pending = 'V';
 840
 841                 } elsif ($cur =~ /^($Ident\s*):/) {
 842                         if ($type eq 'E') {
 843                                 $av_pend_colon = 'L';
 844                         } elsif ($type eq 'T') {
 845                                 $av_pend_colon = 'B';
 846                         }
 847                         print "IDENT_COLON($1,$type>$av_pend_colon)\n" if ($dbg_values > 1);
 848                         $type = 'V';
 849
 850                 } elsif ($cur =~ /^($Ident|$Constant)/o) {
 851                         print "IDENT($1)\n" if ($dbg_values > 1);
 852                         $type = 'V';
 853
 854                 } elsif ($cur =~ /^($Assignment)/o) {
 855                         print "ASSIGN($1)\n" if ($dbg_values > 1);
 856                         $type = 'N';
 857
 858                 } elsif ($cur =~/^(;|{|})/) {
 859                         print "END($1)\n" if ($dbg_values > 1);
 860                         $type = 'E';
 861                         $av_pend_colon = 'O';
 862
 863                 } elsif ($cur =~ /^(\?)/o) {
 864                         print "QUESTION($1)\n" if ($dbg_values > 1);
 865                         $type = 'N';
 866
 867                 } elsif ($cur =~ /^(:)/o) {
 868                         print "COLON($1,$av_pend_colon)\n" if ($dbg_values > 1);
 869
 870                         substr($var, length($res), 1, $av_pend_colon);
 871                         if ($av_pend_colon eq 'C' || $av_pend_colon eq 'L') {
 872                                 $type = 'E';
 873                         } else {
 874                                 $type = 'N';
 875                         }
 876                         $av_pend_colon = 'O';
 877
 878                 } elsif ($cur =~ /^(;|\[)/o) {
 879                         print "CLOSE($1)\n" if ($dbg_values > 1);
 880                         $type = 'N';
 881
 882                 } elsif ($cur =~ /^(-(?![->])|\+(?!\+)|\*|\&\&|\&)/o) {
 883                         my $variant;
 884
 885                         print "OPV($1)\n" if ($dbg_values > 1);
 886                         if ($type eq 'V') {
 887                                 $variant = 'B';
 888                         } else {
 889                                 $variant = 'U';
 890                         }
 891
 892                         substr($var, length($res), 1, $variant);
 893                         $type = 'N';
 894
 895                 } elsif ($cur =~ /^($Operators)/o) {
 896                         print "OP($1)\n" if ($dbg_values > 1);
 897                         if ($1 ne '++' && $1 ne '--') {
 898                                 $type = 'N';
 899                         }
 900
 901                 } elsif ($cur =~ /(^.)/o) {
 902                         print "C($1)\n" if ($dbg_values > 1);
 903                 }
 904                 if (defined $1) {
 905                         $cur = substr($cur, length($1));
 906                         $res .= $type x length($1);
 907                 }
 908         }
 909
 910         return ($res, $var);
 911 }
 912
 913 sub possible {
 914         my ($possible, $line) = @_;
 915
 916         print "CHECK<$possible> ($line)\n" if ($dbg_possible > 2);
 917         if ($possible !~ /(?:
 918                 ^(?:
 919                         $Modifier|
 920                         $Storage|
 921                         $Type|
 922                         DEFINE_\S+|
 923                         goto|
 924                         return|
 925                         case|
 926                         else|
 927                         asm|__asm__|
 928                         do
 929                 )$|
 930                 ^(?:typedef|struct|enum)\b
 931             )/x) {
 932                 # Check for modifiers.
 933                 $possible =~ s/\s*$Storage\s*//g;
 934                 $possible =~ s/\s*$Sparse\s*//g;
 935                 if ($possible =~ /^\s*$/) {
 936
 937                 } elsif ($possible =~ /\s/) {
 938                         $possible =~ s/\s*$Type\s*//g;
 939                         for my $modifier (split(' ', $possible)) {
 940                                 warn "MODIFIER: $modifier ($possible) ($line)\n" if ($dbg_possible);
 941                                 push(@modifierList, $modifier);
 942                         }
 943
 944                 } else {
 945                         warn "POSSIBLE: $possible ($line)\n" if ($dbg_possible);
 946                         push(@typeList, $possible);
 947                 }
 948                 build_types();
 949         } else {
 950                 warn "NOTPOSS: $possible ($line)\n" if ($dbg_possible > 1);
 951         }
 952 }
 953
 954 my $prefix = '';
 955
 956 sub report {
 957         if (defined $tst_only && $_[0] !~ /\Q$tst_only\E/) {
 958                 return 0;
 959         }
 960         my $line = $prefix . $_[0];
 961
 962         $line = (split('\n', $line))[0] . "\n" if ($terse);
 963
 964         push(our @report, $line);
 965
 966         return 1;
 967 }
 968 sub report_dump {
 969         our @report;
 970 }
 971 sub ERROR {
 972         if (report("ERROR: $_[0]\n")) {
 973                 our $clean = 0;
 974                 our $cnt_error++;
 975         }
 976 }
 977 sub WARN {
 978         if (report("WARNING: $_[0]\n")) {
 979                 our $clean = 0;
 980                 our $cnt_warn++;
 981         }
 982 }
 983 sub CHK {
 984         if ($check && report("CHECK: $_[0]\n")) {
 985                 our $clean = 0;
 986                 our $cnt_chk++;
 987         }
 988 }
 989
 990 sub check_absolute_file {
 991         my ($absolute, $herecurr) = @_;
 992         my $file = $absolute;
 993
 994         ##print "absolute<$absolute>\n";
 995
 996         # See if any suffix of this path is a path within the tree.
 997         while ($file =~ s@^[^/]*/@@) {
 998                 if (-f "$root/$file") {
 999                         ##print "file<$file>\n";
1000                         last;
1001                 }
1002         }
1003         if (! -f _)  {
1004                 return 0;
1005         }
1006
1007         # It is, so see if the prefix is acceptable.
1008         my $prefix = $absolute;
1009         substr($prefix, -length($file)) = '';
1010
1011         ##print "prefix<$prefix>\n";
1012         if ($prefix ne ".../") {
1013                 WARN("use relative pathname instead of absolute in changelog text\n" . $herecurr);
1014         }
1015 }
1016
1017 sub process {
1018         my $filename = shift;
1019
1020         my $linenr=0;
1021         my $prevline="";
1022         my $prevrawline="";
1023         my $stashline="";
1024         my $stashrawline="";
1025
1026         my $length;
1027         my $indent;
1028         my $previndent=0;
1029         my $stashindent=0;
1030
1031         our $clean = 1;
1032         my $signoff = 0;
1033         my $is_patch = 0;
1034
1035         our @report = ();
1036         our $cnt_lines = 0;
1037         our $cnt_error = 0;
1038         our $cnt_warn = 0;
1039         our $cnt_chk = 0;
1040
1041         # Trace the real file/line as we go.
1042         my $realfile = '';
1043         my $realline = 0;
1044         my $realcnt = 0;
1045         my $here = '';
1046         my $in_comment = 0;
1047         my $comment_edge = 0;
1048         my $first_line = 0;
1049
1050         my $prev_values = 'E';
1051
1052         # suppression flags
1053         my %suppress_ifbraces;
1054         my %suppress_whiletrailers;
1055
1056         # Pre-scan the patch sanitizing the lines.
1057         # Pre-scan the patch looking for any __setup documentation.
1058         #
1059         my @setup_docs = ();
1060         my $setup_docs = 0;
1061
1062         sanitise_line_reset();
1063         my $line;
1064         foreach my $rawline (@rawlines) {
1065                 $linenr++;
1066                 $line = $rawline;
1067
1068                 if ($rawline=~/^\+\+\+\s+(\S+)/) {
1069                         $setup_docs = 0;
1070                         if ($1 =~ m@Documentation/kernel-parameters.txt$@) {
1071                                 $setup_docs = 1;
1072                         }
1073                         #next;
1074                 }
1075                 if ($rawline=~/^\@\@ -\d+(?:,\d+)? \+(\d+)(,(\d+))? \@\@/) {
1076                         $realline=$1-1;
1077                         if (defined $2) {
1078                                 $realcnt=$3+1;
1079                         } else {
1080                                 $realcnt=1+1;
1081                         }
1082                         $in_comment = 0;
1083
1084                         # Guestimate if this is a continuing comment.  Run
1085                         # the context looking for a comment "edge".  If this
1086                         # edge is a close comment then we must be in a comment
1087                         # at context start.
1088                         my $edge;
1089                         my $cnt = $realcnt;
1090                         for (my $ln = $linenr + 1; $cnt > 0; $ln++) {
1091                                 next if (defined $rawlines[$ln - 1] &&
1092                                          $rawlines[$ln - 1] =~ /^-/);
1093                                 $cnt--;
1094                                 #print "RAW<$rawlines[$ln - 1]>\n";
1095                                 ($edge) = (defined $rawlines[$ln - 1] &&
1096                                         $rawlines[$ln - 1] =~ m@(/\*|\*/)@);
1097                                 last if (defined $edge);
1098                         }
1099                         if (defined $edge && $edge eq '*/') {
1100                                 $in_comment = 1;
1101                         }
1102
1103                         # Guestimate if this is a continuing comment.  If this
1104                         # is the start of a diff block and this line starts
1105                         # ' *' then it is very likely a comment.
1106                         if (!defined $edge &&
1107                             $rawlines[$linenr] =~ m@^.\s* \*(?:\s|$)@)
1108                         {
1109                                 $in_comment = 1;
1110                         }
1111
1112                         ##print "COMMENT:$in_comment edge<$edge> $rawline\n";
1113                         sanitise_line_reset($in_comment);
1114
1115                 } elsif ($realcnt && $rawline =~ /^(?:\+| |$)/) {
1116                         # Standardise the strings and chars within the input to
1117                         # simplify matching -- only bother with positive lines.
1118                         $line = sanitise_line($rawline);
1119                 }
1120                 push(@lines, $line);
1121
1122                 if ($realcnt > 1) {
1123                         $realcnt-- if ($line =~ /^(?:\+| |$)/);
1124                 } else {
1125                         $realcnt = 0;
1126                 }
1127
1128                 #print "==>$rawline\n";
1129                 #print "-->$line\n";
1130
1131                 if ($setup_docs && $line =~ /^\+/) {
1132                         push(@setup_docs, $line);
1133                 }
1134         }
1135
1136         $prefix = '';
1137
1138         $realcnt = 0;
1139         $linenr = 0;
1140         foreach my $line (@lines) {
1141                 $linenr++;
1142
1143                 my $rawline = $rawlines[$linenr - 1];
1144                 my $hunk_line = ($realcnt != 0);
1145
1146 #extract the line range in the file after the patch is applied
1147                 if ($line=~/^\@\@ -\d+(?:,\d+)? \+(\d+)(,(\d+))? \@\@/) {
1148                         $is_patch = 1;
1149                         $first_line = $linenr + 1;
1150                         $realline=$1-1;
1151                         if (defined $2) {
1152                                 $realcnt=$3+1;
1153                         } else {
1154                                 $realcnt=1+1;
1155                         }
1156                         annotate_reset();
1157                         $prev_values = 'E';
1158
1159                         %suppress_ifbraces = ();
1160                         %suppress_whiletrailers = ();
1161                         next;
1162
1163 # track the line number as we move through the hunk, note that
1164 # new versions of GNU diff omit the leading space on completely
1165 # blank context lines so we need to count that too.
1166                 } elsif ($line =~ /^( |\+|$)/) {
1167                         $realline++;
1168                         $realcnt-- if ($realcnt != 0);
1169
1170                         # Measure the line length and indent.
1171                         ($length, $indent) = line_stats($rawline);
1172
1173                         # Track the previous line.
1174                         ($prevline, $stashline) = ($stashline, $line);
1175                         ($previndent, $stashindent) = ($stashindent, $indent);
1176                         ($prevrawline, $stashrawline) = ($stashrawline, $rawline);
1177
1178                         #warn "line<$line>\n";
1179
1180                 } elsif ($realcnt == 1) {
1181                         $realcnt--;
1182                 }
1183
1184 #make up the handle for any error we report on this line
1185                 $prefix = "$filename:$realline: " if ($emacs && $file);
1186                 $prefix = "$filename:$linenr: " if ($emacs && !$file);
1187
1188                 $here = "#$linenr: " if (!$file);
1189                 $here = "#$realline: " if ($file);
1190
1191                 # extract the filename as it passes
1192                 if ($line=~/^\+\+\+\s+(\S+)/) {
1193                         $realfile = $1;
1194                         $realfile =~ s@^[^/]*/@@;
1195
1196                         if ($realfile =~ m@^include/asm/@) {
1197                                 ERROR("do not modify files in include/asm, change architecture specific files in include/asm-<architecture>\n" . "$here$rawline\n");
1198                         }
1199                         next;
1200                 }
1201
1202                 $here .= "FILE: $realfile:$realline:" if ($realcnt != 0);
1203
1204                 my $hereline = "$here\n$rawline\n";
1205                 my $herecurr = "$here\n$rawline\n";
1206                 my $hereprev = "$here\n$prevrawline\n$rawline\n";
1207
1208                 $cnt_lines++ if ($realcnt != 0);
1209
1210 #check the patch for a signoff:
1211                 if ($line =~ /^\s*signed-off-by:/i) {
1212                         # This is a signoff, if ugly, so do not double report.
1213                         $signoff++;
1214                         if (!($line =~ /^\s*Signed-off-by:/)) {
1215                                 WARN("Signed-off-by: is the preferred form\n" .
1216                                         $herecurr);
1217                         }
1218                         if ($line =~ /^\s*signed-off-by:\S/i) {
1219                                 WARN("space required after Signed-off-by:\n" .
1220                                         $herecurr);
1221                         }
1222                 }
1223
1224 # Check for wrappage within a valid hunk of the file
1225                 if ($realcnt != 0 && $line !~ m{^(?:\+|-| |\\ No newline|$)}) {
1226                         ERROR("patch seems to be corrupt (line wrapped?)\n" .
1227                                 $herecurr) if (!$emitted_corrupt++);
1228                 }
1229
1230 # Check for absolute kernel paths.
1231                 if ($tree) {
1232                         while ($line =~ m{(?:^|\s)(/\S*)}g) {
1233                                 my $file = $1;
1234
1235                                 if ($file =~ m{^(.*?)(?::\d+)+:?$} &&
1236                                     check_absolute_file($1, $herecurr)) {
1237                                         #
1238                                 } else {
1239                                         check_absolute_file($file, $herecurr);
1240                                 }
1241                         }
1242                 }
1243
1244 # UTF-8 regex found at http://www.w3.org/International/questions/qa-forms-utf-8.en.php
1245                 if (($realfile =~ /^$/ || $line =~ /^\+/) &&
1246                     $rawline !~ m/^$UTF8*$/) {
1247                         my ($utf8_prefix) = ($rawline =~ /^($UTF8*)/);
1248
1249                         my $blank = copy_spacing($rawline);
1250                         my $ptr = substr($blank, 0, length($utf8_prefix)) . "^";
1251                         my $hereptr = "$hereline$ptr\n";
1252
1253                         ERROR("Invalid UTF-8, patch and commit message should be encoded in UTF-8\n" . $hereptr);
1254                 }
1255
1256 # ignore non-hunk lines and lines being removed
1257                 next if (!$hunk_line || $line =~ /^-/);
1258
1259 #trailing whitespace
1260                 if ($line =~ /^\+.*\015/) {
1261                         my $herevet = "$here\n" . cat_vet($rawline) . "\n";
1262                         ERROR("DOS line endings\n" . $herevet);
1263
1264                 } elsif ($rawline =~ /^\+.*\S\s+$/ || $rawline =~ /^\+\s+$/) {
1265                         my $herevet = "$here\n" . cat_vet($rawline) . "\n";
1266                         ERROR("trailing whitespace\n" . $herevet);
1267                 }
1268
1269 # check we are in a valid source file if not then ignore this hunk
1270                 next if ($realfile !~ /\.(h|c|s|S|pl|sh)$/);
1271
1272 #80 column limit
1273                 if ($line =~ /^\+/ && $prevrawline !~ /\/\*\*/ &&
1274                     $rawline !~ /^.\s*\*\s*\@$Ident\s/ &&
1275                     $line !~ /^\+\s*printk\s*\(\s*(?:KERN_\S+\s*)?"[X\t]*"\s*(?:,|\)\s*;)\s*$/ &&
1276                     $length > 80)
1277                 {
1278                         WARN("line over 80 characters\n" . $herecurr);
1279                 }
1280
1281 # check for adding lines without a newline.
1282                 if ($line =~ /^\+/ && defined $lines[$linenr] && $lines[$linenr] =~ /^\\ No newline at end of file/) {
1283                         WARN("adding a line without newline at end of file\n" . $herecurr);
1284                 }
1285
1286 # check we are in a valid source file C or perl if not then ignore this hunk
1287                 next if ($realfile !~ /\.(h|c|pl)$/);
1288
1289 # at the beginning of a line any tabs must come first and anything
1290 # more than 8 must use tabs.
1291                 if ($rawline =~ /^\+\s* \t\s*\S/ ||
1292                     $rawline =~ /^\+\s*        \s*/) {
1293                         my $herevet = "$here\n" . cat_vet($rawline) . "\n";
1294                         ERROR("code indent should use tabs where possible\n" . $herevet);
1295                 }
1296
1297 # check we are in a valid C source file if not then ignore this hunk
1298                 next if ($realfile !~ /\.(h|c)$/);
1299
1300 # check for RCS/CVS revision markers
1301                 if ($rawline =~ /^\+.*\$(Revision|Log|Id)(?:\$|)/) {
1302                         WARN("CVS style keyword markers, these will _not_ be updated\n". $herecurr);
1303                 }
1304
1305 # Check for potential 'bare' types
1306                 my ($stat, $cond, $line_nr_next, $remain_next, $off_next);
1307                 if ($realcnt && $line =~ /.\s*\S/) {
1308                         ($stat, $cond, $line_nr_next, $remain_next, $off_next) =
1309                                 ctx_statement_block($linenr, $realcnt, 0);
1310                         $stat =~ s/\n./\n /g;
1311                         $cond =~ s/\n./\n /g;
1312
1313                         my $s = $stat;
1314                         $s =~ s/{.*$//s;
1315
1316                         # Ignore goto labels.
1317                         if ($s =~ /$Ident:\*$/s) {
1318
1319                         # Ignore functions being called
1320                         } elsif ($s =~ /^.\s*$Ident\s*\(/s) {
1321
1322                         # declarations always start with types
1323                         } elsif ($prev_values eq 'E' && $s =~ /^.\s*(?:$Storage\s+)?(?:$Inline\s+)?(?:const\s+)?((?:\s*$Ident)+?)\b(?:\s+$Sparse)?\s*\**\s*(?:$Ident|\(\*[^\)]*\))(?:\s*$Modifier)?\s*(?:;|=|,|\()/s) {
1324                                 my $type = $1;
1325                                 $type =~ s/\s+/ /g;
1326                                 possible($type, "A:" . $s);
1327
1328                         # definitions in global scope can only start with types
1329                         } elsif ($s =~ /^.(?:$Storage\s+)?(?:$Inline\s+)?(?:const\s+)?($Ident)\b\s*(?!:)/s) {
1330                                 possible($1, "B:" . $s);
1331                         }
1332
1333                         # any (foo ... *) is a pointer cast, and foo is a type
1334                         while ($s =~ /\(($Ident)(?:\s+$Sparse)*\s*\*+\s*\)/sg) {
1335                                 possible($1, "C:" . $s);
1336                         }
1337
1338                         # Check for any sort of function declaration.
1339                         # int foo(something bar, other baz);
1340                         # void (*store_gdt)(x86_descr_ptr *);
1341                         if ($prev_values eq 'E' && $s =~ /^(.(?:typedef\s*)?(?:(?:$Storage|$Inline)\s*)*\s*$Type\s*(?:\b$Ident|\(\*\s*$Ident\))\s*)\(/s) {
1342                                 my ($name_len) = length($1);
1343
1344                                 my $ctx = $s;
1345                                 substr($ctx, 0, $name_len + 1, '');
1346                                 $ctx =~ s/\)[^\)]*$//;
1347
1348                                 for my $arg (split(/\s*,\s*/, $ctx)) {
1349                                         if ($arg =~ /^(?:const\s+)?($Ident)(?:\s+$Sparse)*\s*\**\s*(:?\b$Ident)?$/s || $arg =~ /^($Ident)$/s) {
1350
1351                                                 possible($1, "D:" . $s);
1352                                         }
1353                                 }
1354                         }
1355
1356                 }
1357
1358 #
1359 # Checks which may be anchored in the context.
1360 #
1361
1362 # Check for switch () and associated case and default
1363 # statements should be at the same indent.
1364                 if ($line=~/\bswitch\s*\(.*\)/) {
1365                         my $err = '';
1366                         my $sep = '';
1367                         my @ctx = ctx_block_outer($linenr, $realcnt);
1368                         shift(@ctx);
1369                         for my $ctx (@ctx) {
1370                                 my ($clen, $cindent) = line_stats($ctx);
1371                                 if ($ctx =~ /^\+\s*(case\s+|default:)/ &&
1372                                                         $indent != $cindent) {
1373                                         $err .= "$sep$ctx\n";
1374                                         $sep = '';
1375                                 } else {
1376                                         $sep = "[...]\n";
1377                                 }
1378                         }
1379                         if ($err ne '') {
1380                                 ERROR("switch and case should be at the same indent\n$hereline$err");
1381                         }
1382                 }
1383
1384 # if/while/etc brace do not go on next line, unless defining a do while loop,
1385 # or if that brace on the next line is for something else
1386                 if ($line =~ /(.*)\b((?:if|while|for|switch)\s*\(|do\b|else\b)/ && $line !~ /^.\s*\#/) {
1387                         my $pre_ctx = "$1$2";
1388
1389                         my ($level, @ctx) = ctx_statement_level($linenr, $realcnt, 0);
1390                         my $ctx_cnt = $realcnt - $#ctx - 1;
1391                         my $ctx = join("\n", @ctx);
1392
1393                         my $ctx_ln = $linenr;
1394                         my $ctx_skip = $realcnt;
1395
1396                         while ($ctx_skip > $ctx_cnt || ($ctx_skip == $ctx_cnt &&
1397                                         defined $lines[$ctx_ln - 1] &&
1398                                         $lines[$ctx_ln - 1] =~ /^-/)) {
1399                                 ##print "SKIP<$ctx_skip> CNT<$ctx_cnt>\n";
1400                                 $ctx_skip-- if (!defined $lines[$ctx_ln - 1] || $lines[$ctx_ln - 1] !~ /^-/);
1401                                 $ctx_ln++;
1402                         }
1403
1404                         #print "realcnt<$realcnt> ctx_cnt<$ctx_cnt>\n";
1405                         #print "pre<$pre_ctx>\nline<$line>\nctx<$ctx>\nnext<$lines[$ctx_ln - 1]>\n";
1406
1407                         if ($ctx !~ /{\s*/ && defined($lines[$ctx_ln -1]) && $lines[$ctx_ln - 1] =~ /^\+\s*{/) {
1408                                 ERROR("that open brace { should be on the previous line\n" .
1409                                         "$here\n$ctx\n$lines[$ctx_ln - 1]\n");
1410                         }
1411                         if ($level == 0 && $pre_ctx !~ /}\s*while\s*\($/ &&
1412                             $ctx =~ /\)\s*\;\s*$/ &&
1413                             defined $lines[$ctx_ln - 1])
1414                         {
1415                                 my ($nlength, $nindent) = line_stats($lines[$ctx_ln - 1]);
1416                                 if ($nindent > $indent) {
1417                                         WARN("trailing semicolon indicates no statements, indent implies otherwise\n" .
1418                                                 "$here\n$ctx\n$lines[$ctx_ln - 1]\n");
1419                                 }
1420                         }
1421                 }
1422
1423 # Check relative indent for conditionals and blocks.
1424                 if ($line =~ /\b(?:(?:if|while|for)\s*\(|do\b)/ && $line !~ /^.\s*#/ && $line !~ /\}\s*while\s*/) {
1425                         my ($s, $c) = ($stat, $cond);
1426
1427                         substr($s, 0, length($c), '');
1428
1429                         # Make sure we remove the line prefixes as we have
1430                         # none on the first line, and are going to readd them
1431                         # where necessary.
1432                         $s =~ s/\n./\n/gs;
1433
1434                         # Find out how long the conditional actually is.
1435                         my @newlines = ($c =~ /\n/gs);
1436                         my $cond_lines = 1 + $#newlines;
1437
1438                         # We want to check the first line inside the block
1439                         # starting at the end of the conditional, so remove:
1440                         #  1) any blank line termination
1441                         #  2) any opening brace { on end of the line
1442                         #  3) any do (...) {
1443                         my $continuation = 0;
1444                         my $check = 0;
1445                         $s =~ s/^.*\bdo\b//;
1446                         $s =~ s/^\s*{//;
1447                         if ($s =~ s/^\s*\\//) {
1448                                 $continuation = 1;
1449                         }
1450                         if ($s =~ s/^\s*?\n//) {
1451                                 $check = 1;
1452                                 $cond_lines++;
1453                         }
1454
1455                         # Also ignore a loop construct at the end of a
1456                         # preprocessor statement.
1457                         if (($prevline =~ /^.\s*#\s*define\s/ ||
1458                             $prevline =~ /\\\s*$/) && $continuation == 0) {
1459                                 $check = 0;
1460                         }
1461
1462                         my $cond_ptr = -1;
1463                         while ($cond_ptr != $cond_lines) {
1464                                 $cond_ptr = $cond_lines;
1465
1466                                 # Ignore:
1467                                 #  1) blank lines, they should be at 0,
1468                                 #  2) preprocessor lines, and
1469                                 #  3) labels.
1470                                 if ($s =~ /^\s*?\n/ ||
1471                                     $s =~ /^\s*#\s*?/ ||
1472                                     $s =~ /^\s*$Ident\s*:/) {
1473                                         $s =~ s/^.*?\n//;
1474                                         $cond_lines++;
1475                                 }
1476                         }
1477
1478                         my (undef, $sindent) = line_stats("+" . $s);
1479                         my $stat_real = raw_line($linenr, $cond_lines);
1480
1481                         # Check if either of these lines are modified, else
1482                         # this is not this patch's fault.
1483                         if (!defined($stat_real) ||
1484                             $stat !~ /^\+/ && $stat_real !~ /^\+/) {
1485                                 $check = 0;
1486                         }
1487                         if (defined($stat_real) && $cond_lines > 1) {
1488                                 $stat_real = "[...]\n$stat_real";
1489                         }
1490
1491                         #print "line<$line> prevline<$prevline> indent<$indent> sindent<$sindent> check<$check> continuation<$continuation> s<$s> cond_lines<$cond_lines> stat_real<$stat_real> stat<$stat>\n";
1492
1493                         if ($check && (($sindent % 8) != 0 ||
1494                             ($sindent <= $indent && $s ne ''))) {
1495                                 WARN("suspect code indent for conditional statements ($indent, $sindent)\n" . $herecurr . "$stat_real\n");
1496                         }
1497                 }
1498
1499                 # Track the 'values' across context and added lines.
1500                 my $opline = $line; $opline =~ s/^./ /;
1501                 my ($curr_values, $curr_vars) =
1502                                 annotate_values($opline . "\n", $prev_values);
1503                 $curr_values = $prev_values . $curr_values;
1504                 if ($dbg_values) {
1505                         my $outline = $opline; $outline =~ s/\t/ /g;
1506                         print "$linenr > .$outline\n";
1507                         print "$linenr > $curr_values\n";
1508                         print "$linenr >  $curr_vars\n";
1509                 }
1510                 $prev_values = substr($curr_values, -1);
1511
1512 #ignore lines not being added
1513                 if ($line=~/^[^\+]/) {next;}
1514
1515 # TEST: allow direct testing of the type matcher.
1516                 if ($dbg_type) {
1517                         if ($line =~ /^.\s*$Declare\s*$/) {
1518                                 ERROR("TEST: is type\n" . $herecurr);
1519                         } elsif ($dbg_type > 1 && $line =~ /^.+($Declare)/) {
1520                                 ERROR("TEST: is not type ($1 is)\n". $herecurr);
1521                         }
1522                         next;
1523                 }
1524 # TEST: allow direct testing of the attribute matcher.
1525                 if ($dbg_attr) {
1526                         if ($line =~ /^.\s*$Attribute\s*$/) {
1527                                 ERROR("TEST: is attr\n" . $herecurr);
1528                         } elsif ($dbg_attr > 1 && $line =~ /^.+($Attribute)/) {
1529                                 ERROR("TEST: is not attr ($1 is)\n". $herecurr);
1530                         }
1531                         next;
1532                 }
1533
1534 # check for initialisation to aggregates open brace on the next line
1535                 if ($prevline =~ /$Declare\s*$Ident\s*=\s*$/ &&
1536                     $line =~ /^.\s*{/) {
1537                         ERROR("that open brace { should be on the previous line\n" . $hereprev);
1538                 }
1539
1540 #
1541 # Checks which are anchored on the added line.
1542 #
1543
1544 # check for malformed paths in #include statements (uses RAW line)
1545                 if ($rawline =~ m{^.\s*\#\s*include\s+[<"](.*)[">]}) {
1546                         my $path = $1;
1547                         if ($path =~ m{//}) {
1548                                 ERROR("malformed #include filename\n" .
1549                                         $herecurr);
1550                         }
1551                 }
1552
1553 # no C99 // comments
1554                 if ($line =~ m{//}) {
1555                         ERROR("do not use C99 // comments\n" . $herecurr);
1556                 }
1557                 # Remove C99 comments.
1558                 $line =~ s@//.*@@;
1559                 $opline =~ s@//.*@@;
1560
1561 #EXPORT_SYMBOL should immediately follow its function closing }.
1562                 if (($line =~ /EXPORT_SYMBOL.*\((.*)\)/) ||
1563                     ($line =~ /EXPORT_UNUSED_SYMBOL.*\((.*)\)/)) {
1564                         my $name = $1;
1565                         if (($prevline !~ /^}/) &&
1566                            ($prevline !~ /^\+}/) &&
1567                            ($prevline !~ /^ }/) &&
1568                            ($prevline !~ /^.DECLARE_$Ident\(\Q$name\E\)/) &&
1569                            ($prevline !~ /^.LIST_HEAD\(\Q$name\E\)/) &&
1570                            ($prevline !~ /^.$Type\s*\(\s*\*\s*\Q$name\E\s*\)\s*\(/) &&
1571                            ($prevline !~ /\b\Q$name\E(?:\s+$Attribute)?\s*(?:;|=|\[)/)) {
1572                                 WARN("EXPORT_SYMBOL(foo); should immediately follow its function/variable\n" . $herecurr);
1573                         }
1574                 }
1575
1576 # check for external initialisers.
1577                 if ($line =~ /^.$Type\s*$Ident\s*(?:\s+$Modifier)*\s*=\s*(0|NULL|false)\s*;/) {
1578                         ERROR("do not initialise externals to 0 or NULL\n" .
1579                                 $herecurr);
1580                 }
1581 # check for static initialisers.
1582                 if ($line =~ /\s*static\s.*=\s*(0|NULL|false)\s*;/) {
1583                         ERROR("do not initialise statics to 0 or NULL\n" .
1584                                 $herecurr);
1585                 }
1586
1587 # check for new typedefs, only function parameters and sparse annotations
1588 # make sense.
1589                 if ($line =~ /\btypedef\s/ &&
1590                     $line !~ /\btypedef\s+$Type\s+\(\s*\*?$Ident\s*\)\s*\(/ &&
1591                     $line !~ /\btypedef\s+$Type\s+$Ident\s*\(/ &&
1592                     $line !~ /\b__bitwise(?:__|)\b/) {
1593                         WARN("do not add new typedefs\n" . $herecurr);
1594                 }
1595
1596 # * goes on variable not on type
1597                 if ($line =~ m{\($NonptrType(\*+)(?:\s+const)?\)}) {
1598                         ERROR("\"(foo$1)\" should be \"(foo $1)\"\n" .
1599                                 $herecurr);
1600
1601                 } elsif ($line =~ m{\($NonptrType\s+(\*+)(?!\s+const)\s+\)}) {
1602                         ERROR("\"(foo $1 )\" should be \"(foo $1)\"\n" .
1603                                 $herecurr);
1604
1605                 } elsif ($line =~ m{\b$NonptrType(\*+)(?:\s+(?:$Attribute|$Sparse))?\s+[A-Za-z\d_]+}) {
1606                         ERROR("\"foo$1 bar\" should be \"foo $1bar\"\n" .
1607                                 $herecurr);
1608
1609                 } elsif ($line =~ m{\b$NonptrType\s+(\*+)(?!\s+(?:$Attribute|$Sparse))\s+[A-Za-z\d_]+}) {
1610                         ERROR("\"foo $1 bar\" should be \"foo $1bar\"\n" .
1611                                 $herecurr);
1612                 }
1613
1614 # # no BUG() or BUG_ON()
1615 #               if ($line =~ /\b(BUG|BUG_ON)\b/) {
1616 #                       print "Try to use WARN_ON & Recovery code rather than BUG() or BUG_ON()\n";
1617 #                       print "$herecurr";
1618 #                       $clean = 0;
1619 #               }
1620
1621                 if ($line =~ /\bLINUX_VERSION_CODE\b/) {
1622                         WARN("LINUX_VERSION_CODE should be avoided, code should be for the version to which it is merged\n" . $herecurr);
1623                 }
1624
1625 # printk should use KERN_* levels.  Note that follow on printk's on the
1626 # same line do not need a level, so we use the current block context
1627 # to try and find and validate the current printk.  In summary the current
1628 # printk includes all preceeding printk's which have no newline on the end.
1629 # we assume the first bad printk is the one to report.
1630                 if ($line =~ /\bprintk\((?!KERN_)\s*"/) {
1631                         my $ok = 0;
1632                         for (my $ln = $linenr - 1; $ln >= $first_line; $ln--) {
1633                                 #print "CHECK<$lines[$ln - 1]\n";
1634                                 # we have a preceeding printk if it ends
1635                                 # with "\n" ignore it, else it is to blame
1636                                 if ($lines[$ln - 1] =~ m{\bprintk\(}) {
1637                                         if ($rawlines[$ln - 1] !~ m{\\n"}) {
1638                                                 $ok = 1;
1639                                         }
1640                                         last;
1641                                 }
1642                         }
1643                         if ($ok == 0) {
1644                                 WARN("printk() should include KERN_ facility level\n" . $herecurr);
1645                         }
1646                 }
1647
1648 # function brace can't be on same line, except for #defines of do while,
1649 # or if closed on same line
1650                 if (($line=~/$Type\s*$Ident\(.*\).*\s{/) and
1651                     !($line=~/\#\s*define.*do\s{/) and !($line=~/}/)) {
1652                         ERROR("open brace '{' following function declarations go on the next line\n" . $herecurr);
1653                 }
1654
1655 # open braces for enum, union and struct go on the same line.
1656                 if ($line =~ /^.\s*{/ &&
1657                     $prevline =~ /^.\s*(?:typedef\s+)?(enum|union|struct)(?:\s+$Ident)?\s*$/) {
1658                         ERROR("open brace '{' following $1 go on the same line\n" . $hereprev);
1659                 }
1660
1661 # check for spacing round square brackets; allowed:
1662 #  1. with a type on the left -- int [] a;
1663 #  2. at the beginning of a line for slice initialisers -- [0...10] = 5,
1664 #  3. inside a curly brace -- = { [0...10] = 5 }
1665                 while ($line =~ /(.*?\s)\[/g) {
1666                         my ($where, $prefix) = ($-[1], $1);
1667                         if ($prefix !~ /$Type\s+$/ &&
1668                             ($where != 0 || $prefix !~ /^.\s+$/) &&
1669                             $prefix !~ /{\s+$/) {
1670                                 ERROR("space prohibited before open square bracket '['\n" . $herecurr);
1671                         }
1672                 }
1673
1674 # check for spaces between functions and their parentheses.
1675                 while ($line =~ /($Ident)\s+\(/g) {
1676                         my $name = $1;
1677                         my $ctx_before = substr($line, 0, $-[1]);
1678                         my $ctx = "$ctx_before$name";
1679
1680                         # Ignore those directives where spaces _are_ permitted.
1681                         if ($name =~ /^(?:
1682                                 if|for|while|switch|return|case|
1683                                 volatile|__volatile__|
1684                                 __attribute__|format|__extension__|
1685                                 asm|__asm__)$/x)
1686                         {
1687
1688                         # cpp #define statements have non-optional spaces, ie
1689                         # if there is a space between the name and the open
1690                         # parenthesis it is simply not a parameter group.
1691                         } elsif ($ctx_before =~ /^.\s*\#\s*define\s*$/) {
1692
1693                         # cpp #elif statement condition may start with a (
1694                         } elsif ($ctx =~ /^.\s*\#\s*elif\s*$/) {
1695
1696                         # If this whole things ends with a type its most
1697                         # likely a typedef for a function.
1698                         } elsif ($ctx =~ /$Type$/) {
1699
1700                         } else {
1701                                 WARN("space prohibited between function name and open parenthesis '('\n" . $herecurr);
1702                         }
1703                 }
1704 # Check operator spacing.
1705                 if (!($line=~/\#\s*include/)) {
1706                         my $ops = qr{
1707                                 <<=|>>=|<=|>=|==|!=|
1708                                 \+=|-=|\*=|\/=|%=|\^=|\|=|&=|
1709                                 =>|->|<<|>>|<|>|=|!|~|
1710                                 &&|\|\||,|\^|\+\+|--|&|\||\+|-|\*|\/|%|
1711                                 \?|:
1712                         }x;
1713                         my @elements = split(/($ops|;)/, $opline);
1714                         my $off = 0;
1715
1716                         my $blank = copy_spacing($opline);
1717
1718                         for (my $n = 0; $n < $#elements; $n += 2) {
1719                                 $off += length($elements[$n]);
1720
1721                                 # Pick up the preceeding and succeeding characters.
1722                                 my $ca = substr($opline, 0, $off);
1723                                 my $cc = '';
1724                                 if (length($opline) >= ($off + length($elements[$n + 1]))) {
1725                                         $cc = substr($opline, $off + length($elements[$n + 1]));
1726                                 }
1727                                 my $cb = "$ca$;$cc";
1728
1729                                 my $a = '';
1730                                 $a = 'V' if ($elements[$n] ne '');
1731                                 $a = 'W' if ($elements[$n] =~ /\s$/);
1732                                 $a = 'C' if ($elements[$n] =~ /$;$/);
1733                                 $a = 'B' if ($elements[$n] =~ /(\[|\()$/);
1734                                 $a = 'O' if ($elements[$n] eq '');
1735                                 $a = 'E' if ($ca =~ /^\s*$/);
1736
1737                                 my $op = $elements[$n + 1];
1738
1739                                 my $c = '';
1740                                 if (defined $elements[$n + 2]) {
1741                                         $c = 'V' if ($elements[$n + 2] ne '');
1742                                         $c = 'W' if ($elements[$n + 2] =~ /^\s/);
1743                                         $c = 'C' if ($elements[$n + 2] =~ /^$;/);
1744                                         $c = 'B' if ($elements[$n + 2] =~ /^(\)|\]|;)/);
1745                                         $c = 'O' if ($elements[$n + 2] eq '');
1746                                         $c = 'E' if ($elements[$n + 2] =~ /\s*\\$/);
1747                                 } else {
1748                                         $c = 'E';
1749                                 }
1750
1751                                 my $ctx = "${a}x${c}";
1752
1753                                 my $at = "(ctx:$ctx)";
1754
1755                                 my $ptr = substr($blank, 0, $off) . "^";
1756                                 my $hereptr = "$hereline$ptr\n";
1757
1758                                 # Pull out the value of this operator.
1759                                 my $op_type = substr($curr_values, $off + 1, 1);
1760
1761                                 # Get the full operator variant.
1762                                 my $opv = $op . substr($curr_vars, $off, 1);
1763
1764                                 # Ignore operators passed as parameters.
1765                                 if ($op_type ne 'V' &&
1766                                     $ca =~ /\s$/ && $cc =~ /^\s*,/) {
1767
1768 #                               # Ignore comments
1769 #                               } elsif ($op =~ /^$;+$/) {
1770
1771                                 # ; should have either the end of line or a space or \ after it
1772                                 } elsif ($op eq ';') {
1773                                         if ($ctx !~ /.x[WEBC]/ &&
1774                                             $cc !~ /^\\/ && $cc !~ /^;/) {
1775                                                 ERROR("space required after that '$op' $at\n" . $hereptr);
1776                                         }
1777
1778                                 # // is a comment
1779                                 } elsif ($op eq '//') {
1780
1781                                 # No spaces for:
1782                                 #   ->
1783                                 #   :   when part of a bitfield
1784                                 } elsif ($op eq '->' || $opv eq ':B') {
1785                                         if ($ctx =~ /Wx.|.xW/) {
1786                                                 ERROR("spaces prohibited around that '$op' $at\n" . $hereptr);
1787                                         }
1788
1789                                 # , must have a space on the right.
1790                                 } elsif ($op eq ',') {
1791                                         if ($ctx !~ /.x[WEC]/ && $cc !~ /^}/) {
1792                                                 ERROR("space required after that '$op' $at\n" . $hereptr);
1793                                         }
1794
1795                                 # '*' as part of a type definition -- reported already.
1796                                 } elsif ($opv eq '*_') {
1797                                         #warn "'*' is part of type\n";
1798
1799                                 # unary operators should have a space before and
1800                                 # none after.  May be left adjacent to another
1801                                 # unary operator, or a cast
1802                                 } elsif ($op eq '!' || $op eq '~' ||
1803                                          $opv eq '*U' || $opv eq '-U' ||
1804                                          $opv eq '&U' || $opv eq '&&U') {
1805                                         if ($ctx !~ /[WEBC]x./ && $ca !~ /(?:\)|!|~|\*|-|\&|\||\+\+|\-\-|\{)$/) {
1806                                                 ERROR("space required before that '$op' $at\n" . $hereptr);
1807                                         }
1808                                         if ($op eq '*' && $cc =~/\s*const\b/) {
1809                                                 # A unary '*' may be const
1810
1811                                         } elsif ($ctx =~ /.xW/) {
1812                                                 ERROR("space prohibited after that '$op' $at\n" . $hereptr);
1813                                         }
1814
1815                                 # unary ++ and unary -- are allowed no space on one side.
1816                                 } elsif ($op eq '++' or $op eq '--') {
1817                                         if ($ctx !~ /[WEOBC]x[^W]/ && $ctx !~ /[^W]x[WOBEC]/) {
1818                                                 ERROR("space required one side of that '$op' $at\n" . $hereptr);
1819                                         }
1820                                         if ($ctx =~ /Wx[BE]/ ||
1821                                             ($ctx =~ /Wx./ && $cc =~ /^;/)) {
1822                                                 ERROR("space prohibited before that '$op' $at\n" . $hereptr);
1823                                         }
1824                                         if ($ctx =~ /ExW/) {
1825                                                 ERROR("space prohibited after that '$op' $at\n" . $hereptr);
1826                                         }
1827
1828
1829                                 # << and >> may either have or not have spaces both sides
1830                                 } elsif ($op eq '<<' or $op eq '>>' or
1831                                          $op eq '&' or $op eq '^' or $op eq '|' or
1832                                          $op eq '+' or $op eq '-' or
1833                                          $op eq '*' or $op eq '/' or
1834                                          $op eq '%')
1835                                 {
1836                                         if ($ctx =~ /Wx[^WCE]|[^WCE]xW/) {
1837                                                 ERROR("need consistent spacing around '$op' $at\n" .
1838                                                         $hereptr);
1839                                         }
1840
1841                                 # A colon needs no spaces before when it is
1842                                 # terminating a case value or a label.
1843                                 } elsif ($opv eq ':C' || $opv eq ':L') {
1844                                         if ($ctx =~ /Wx./) {
1845                                                 ERROR("space prohibited before that '$op' $at\n" . $hereptr);
1846                                         }
1847
1848                                 # All the others need spaces both sides.
1849                                 } elsif ($ctx !~ /[EWC]x[CWE]/) {
1850                                         my $ok = 0;
1851
1852                                         # Ignore email addresses <foo@bar>
1853                                         if (($op eq '<' &&
1854                                              $cc =~ /^\S+\@\S+>/) ||
1855                                             ($op eq '>' &&
1856                                              $ca =~ /<\S+\@\S+$/))
1857                                         {
1858                                                 $ok = 1;
1859                                         }
1860
1861                                         # Ignore ?:
1862                                         if (($opv eq ':O' && $ca =~ /\?$/) ||
1863                                             ($op eq '?' && $cc =~ /^:/)) {
1864                                                 $ok = 1;
1865                                         }
1866
1867                                         if ($ok == 0) {
1868                                                 ERROR("spaces required around that '$op' $at\n" . $hereptr);
1869                                         }
1870                                 }
1871                                 $off += length($elements[$n + 1]);
1872                         }
1873                 }
1874
1875 # check for multiple assignments
1876                 if ($line =~ /^.\s*$Lval\s*=\s*$Lval\s*=(?!=)/) {
1877                         CHK("multiple assignments should be avoided\n" . $herecurr);
1878                 }
1879
1880 ## # check for multiple declarations, allowing for a function declaration
1881 ## # continuation.
1882 ##              if ($line =~ /^.\s*$Type\s+$Ident(?:\s*=[^,{]*)?\s*,\s*$Ident.*/ &&
1883 ##                  $line !~ /^.\s*$Type\s+$Ident(?:\s*=[^,{]*)?\s*,\s*$Type\s*$Ident.*/) {
1884 ##
1885 ##                      # Remove any bracketed sections to ensure we do not
1886 ##                      # falsly report the parameters of functions.
1887 ##                      my $ln = $line;
1888 ##                      while ($ln =~ s/\([^\(\)]*\)//g) {
1889 ##                      }
1890 ##                      if ($ln =~ /,/) {
1891 ##                              WARN("declaring multiple variables together should be avoided\n" . $herecurr);
1892 ##                      }
1893 ##              }
1894
1895 #need space before brace following if, while, etc
1896                 if (($line =~ /\(.*\){/ && $line !~ /\($Type\){/) ||
1897                     $line =~ /do{/) {
1898                         ERROR("space required before the open brace '{'\n" . $herecurr);
1899                 }
1900
1901 # closing brace should have a space following it when it has anything
1902 # on the line
1903                 if ($line =~ /}(?!(?:,|;|\)))\S/) {
1904                         ERROR("space required after that close brace '}'\n" . $herecurr);
1905                 }
1906
1907 # check spacing on square brackets
1908                 if ($line =~ /\[\s/ && $line !~ /\[\s*$/) {
1909                         ERROR("space prohibited after that open square bracket '['\n" . $herecurr);
1910                 }
1911                 if ($line =~ /\s\]/) {
1912                         ERROR("space prohibited before that close square bracket ']'\n" . $herecurr);
1913                 }
1914
1915 # check spacing on parentheses
1916                 if ($line =~ /\(\s/ && $line !~ /\(\s*(?:\\)?$/ &&
1917                     $line !~ /for\s*\(\s+;/) {
1918                         ERROR("space prohibited after that open parenthesis '('\n" . $herecurr);
1919                 }
1920                 if ($line =~ /(\s+)\)/ && $line !~ /^.\s*\)/ &&
1921                     $line !~ /for\s*\(.*;\s+\)/ &&
1922                     $line !~ /:\s+\)/) {
1923                         ERROR("space prohibited before that close parenthesis ')'\n" . $herecurr);
1924                 }
1925
1926 #goto labels aren't indented, allow a single space however
1927                 if ($line=~/^.\s+[A-Za-z\d_]+:(?![0-9]+)/ and
1928                    !($line=~/^. [A-Za-z\d_]+:/) and !($line=~/^.\s+default:/)) {
1929                         WARN("labels should not be indented\n" . $herecurr);
1930                 }
1931
1932 # Return is not a function.
1933                 if (defined($stat) && $stat =~ /^.\s*return(\s*)(\(.*);/s) {
1934                         my $spacing = $1;
1935                         my $value = $2;
1936
1937                         # Flatten any parentheses and braces
1938                         $value =~ s/\)\(/\) \(/g;
1939                         while ($value =~ s/\([^\(\)]*\)/1/) {
1940                         }
1941
1942                         if ($value =~ /^(?:$Ident|-?$Constant)$/) {
1943                                 ERROR("return is not a function, parentheses are not required\n" . $herecurr);
1944
1945                         } elsif ($spacing !~ /\s+/) {
1946                                 ERROR("space required before the open parenthesis '('\n" . $herecurr);
1947                         }
1948                 }
1949
1950 # Need a space before open parenthesis after if, while etc
1951                 if ($line=~/\b(if|while|for|switch)\(/) {
1952                         ERROR("space required before the open parenthesis '('\n" . $herecurr);
1953                 }
1954
1955 # Check for illegal assignment in if conditional -- and check for trailing
1956 # statements after the conditional.
1957                 if ($line =~ /do\s*(?!{)/) {
1958                         my ($stat_next) = ctx_statement_block($line_nr_next,
1959                                                 $remain_next, $off_next);
1960                         $stat_next =~ s/\n./\n /g;
1961                         ##print "stat<$stat> stat_next<$stat_next>\n";
1962
1963                         if ($stat_next =~ /^\s*while\b/) {
1964                                 # If the statement carries leading newlines,
1965                                 # then count those as offsets.
1966                                 my ($whitespace) =
1967                                         ($stat_next =~ /^((?:\s*\n[+-])*\s*)/s);
1968                                 my $offset =
1969                                         statement_rawlines($whitespace) - 1;
1970
1971                                 $suppress_whiletrailers{$line_nr_next +
1972                                                                 $offset} = 1;
1973                         }
1974                 }
1975                 if (!defined $suppress_whiletrailers{$linenr} &&
1976                     $line =~ /\b(?:if|while|for)\s*\(/ && $line !~ /^.\s*#/) {
1977                         my ($s, $c) = ($stat, $cond);
1978
1979                         if ($c =~ /\bif\s*\(.*[^<>!=]=[^=].*/) {
1980                                 ERROR("do not use assignment in if condition\n" . $herecurr);
1981                         }
1982
1983                         # Find out what is on the end of the line after the
1984                         # conditional.
1985                         substr($s, 0, length($c), '');
1986                         $s =~ s/\n.*//g;
1987                         $s =~ s/$;//g;  # Remove any comments
1988                         if (length($c) && $s !~ /^\s*{?\s*\\*\s*$/ &&
1989                             $c !~ /}\s*while\s*/)
1990                         {
1991                                 ERROR("trailing statements should be on next line\n" . $herecurr);
1992                         }
1993                 }
1994
1995 # Check for bitwise tests written as boolean
1996                 if ($line =~ /
1997                         (?:
1998                                 (?:\[|\(|\&\&|\|\|)
1999                                 \s*0[xX][0-9]+\s*
2000                                 (?:\&\&|\|\|)
2001                         |
2002                                 (?:\&\&|\|\|)
2003                                 \s*0[xX][0-9]+\s*
2004                                 (?:\&\&|\|\||\)|\])
2005                         )/x)
2006                 {
2007                         WARN("boolean test with hexadecimal, perhaps just 1 \& or \|?\n" . $herecurr);
2008                 }
2009
2010 # if and else should not have general statements after it
2011                 if ($line =~ /^.\s*(?:}\s*)?else\b(.*)/) {
2012                         my $s = $1;
2013                         $s =~ s/$;//g;  # Remove any comments
2014                         if ($s !~ /^\s*(?:\sif|(?:{|)\s*\\?\s*$)/) {
2015                                 ERROR("trailing statements should be on next line\n" . $herecurr);
2016                         }
2017                 }
2018 # case and default should not have general statements after them
2019                 if ($line =~ /^.\s*(?:case\s*.*|default\s*):/g &&
2020                     $line !~ /\G(?:
2021                         (?:\s*{)?(?:\s*$;*)(?:\s*\\)?\s*$|
2022                         \s*return\s+
2023                     )/xg)
2024                 {
2025                         ERROR("trailing statements should be on next line\n" . $herecurr);
2026                 }
2027
2028                 # Check for }<nl>else {, these must be at the same
2029                 # indent level to be relevant to each other.
2030                 if ($prevline=~/}\s*$/ and $line=~/^.\s*else\s*/ and
2031                                                 $previndent == $indent) {
2032                         ERROR("else should follow close brace '}'\n" . $hereprev);
2033                 }
2034
2035                 if ($prevline=~/}\s*$/ and $line=~/^.\s*while\s*/ and
2036                                                 $previndent == $indent) {
2037                         my ($s, $c) = ctx_statement_block($linenr, $realcnt, 0);
2038
2039                         # Find out what is on the end of the line after the
2040                         # conditional.
2041                         substr($s, 0, length($c), '');
2042                         $s =~ s/\n.*//g;
2043
2044                         if ($s =~ /^\s*;/) {
2045                                 ERROR("while should follow close brace '}'\n" . $hereprev);
2046                         }
2047                 }
2048
2049 #studly caps, commented out until figure out how to distinguish between use of existing and adding new
2050 #               if (($line=~/[\w_][a-z\d]+[A-Z]/) and !($line=~/print/)) {
2051 #                   print "No studly caps, use _\n";
2052 #                   print "$herecurr";
2053 #                   $clean = 0;
2054 #               }
2055
2056 #no spaces allowed after \ in define
2057                 if ($line=~/\#\s*define.*\\\s$/) {
2058                         WARN("Whitepspace after \\ makes next lines useless\n" . $herecurr);
2059                 }
2060
2061 #warn if <asm/foo.h> is #included and <linux/foo.h> is available (uses RAW line)
2062                 if ($tree && $rawline =~ m{^.\s*\#\s*include\s*\<asm\/(.*)\.h\>}) {
2063                         my $file = "$1.h";
2064                         my $checkfile = "include/linux/$file";
2065                         if (-f "$root/$checkfile" &&
2066                             $realfile ne $checkfile &&
2067                             $1 ne 'irq')
2068                         {
2069                                 if ($realfile =~ m{^arch/}) {
2070                                         CHK("Consider using #include <linux/$file> instead of <asm/$file>\n" . $herecurr);
2071                                 } else {
2072                                         WARN("Use #include <linux/$file> instead of <asm/$file>\n" . $herecurr);
2073                                 }
2074                         }
2075                 }
2076
2077 # multi-statement macros should be enclosed in a do while loop, grab the
2078 # first statement and ensure its the whole macro if its not enclosed
2079 # in a known good container
2080                 if ($realfile !~ m@/vmlinux.lds.h$@ &&
2081                     $line =~ /^.\s*\#\s*define\s*$Ident(\()?/) {
2082                         my $ln = $linenr;
2083                         my $cnt = $realcnt;
2084                         my ($off, $dstat, $dcond, $rest);
2085                         my $ctx = '';
2086
2087                         my $args = defined($1);
2088
2089                         # Find the end of the macro and limit our statement
2090                         # search to that.
2091                         while ($cnt > 0 && defined $lines[$ln - 1] &&
2092                                 $lines[$ln - 1] =~ /^(?:-|..*\\$)/)
2093                         {
2094                                 $ctx .= $rawlines[$ln - 1] . "\n";
2095                                 $cnt-- if ($lines[$ln - 1] !~ /^-/);
2096                                 $ln++;
2097                         }
2098                         $ctx .= $rawlines[$ln - 1];
2099
2100                         ($dstat, $dcond, $ln, $cnt, $off) =
2101                                 ctx_statement_block($linenr, $ln - $linenr + 1, 0);
2102                         #print "dstat<$dstat> dcond<$dcond> cnt<$cnt> off<$off>\n";
2103                         #print "LINE<$lines[$ln-1]> len<" . length($lines[$ln-1]) . "\n";
2104
2105                         # Extract the remainder of the define (if any) and
2106                         # rip off surrounding spaces, and trailing \'s.
2107                         $rest = '';
2108                         while ($off != 0 || ($cnt > 0 && $rest =~ /\\\s*$/)) {
2109                                 #print "ADDING cnt<$cnt> $off <" . substr($lines[$ln - 1], $off) . "> rest<$rest>\n";
2110                                 if ($off != 0 || $lines[$ln - 1] !~ /^-/) {
2111                                         $rest .= substr($lines[$ln - 1], $off) . "\n";
2112                                         $cnt--;
2113                                 }
2114                                 $ln++;
2115                                 $off = 0;
2116                         }
2117                         $rest =~ s/\\\n.//g;
2118                         $rest =~ s/^\s*//s;
2119                         $rest =~ s/\s*$//s;
2120
2121                         # Clean up the original statement.
2122                         if ($args) {
2123                                 substr($dstat, 0, length($dcond), '');
2124                         } else {
2125                                 $dstat =~ s/^.\s*\#\s*define\s+$Ident\s*//;
2126                         }
2127                         $dstat =~ s/$;//g;
2128                         $dstat =~ s/\\\n.//g;
2129                         $dstat =~ s/^\s*//s;
2130                         $dstat =~ s/\s*$//s;
2131
2132                         # Flatten any parentheses and braces
2133                         while ($dstat =~ s/\([^\(\)]*\)/1/) {
2134                         }
2135                         while ($dstat =~ s/\{[^\{\}]*\}/1/) {
2136                         }
2137
2138                         my $exceptions = qr{
2139                                 $Declare|
2140                                 module_param_named|
2141                                 MODULE_PARAM_DESC|
2142                                 DECLARE_PER_CPU|
2143                                 DEFINE_PER_CPU|
2144                                 __typeof__\(
2145                         }x;
2146                         #print "REST<$rest>\n";
2147                         if ($rest ne '') {
2148                                 if ($rest !~ /while\s*\(/ &&
2149                                     $dstat !~ /$exceptions/)
2150                                 {
2151                                         ERROR("Macros with multiple statements should be enclosed in a do - while loop\n" . "$here\n$ctx\n");
2152                                 }
2153
2154                         } elsif ($ctx !~ /;/) {
2155                                 if ($dstat ne '' &&
2156                                     $dstat !~ /^(?:$Ident|-?$Constant)$/ &&
2157                                     $dstat !~ /$exceptions/ &&
2158                                     $dstat !~ /^\.$Ident\s*=/ &&
2159                                     $dstat =~ /$Operators/)
2160                                 {
2161                                         ERROR("Macros with complex values should be enclosed in parenthesis\n" . "$here\n$ctx\n");
2162                                 }
2163                         }
2164                 }
2165
2166 # check for redundant bracing round if etc
2167                 if ($line =~ /(^.*)\bif\b/ && $1 !~ /else\s*$/) {
2168                         my ($level, $endln, @chunks) =
2169                                 ctx_statement_full($linenr, $realcnt, 1);
2170                         #print "chunks<$#chunks> linenr<$linenr> endln<$endln> level<$level>\n";
2171                         #print "APW: <<$chunks[1][0]>><<$chunks[1][1]>>\n";
2172                         if ($#chunks > 0 && $level == 0) {
2173                                 my $allowed = 0;
2174                                 my $seen = 0;
2175                                 my $herectx = $here . "\n";
2176                                 my $ln = $linenr - 1;
2177                                 for my $chunk (@chunks) {
2178                                         my ($cond, $block) = @{$chunk};
2179
2180                                         # If the condition carries leading newlines, then count those as offsets.
2181                                         my ($whitespace) = ($cond =~ /^((?:\s*\n[+-])*\s*)/s);
2182                                         my $offset = statement_rawlines($whitespace) - 1;
2183
2184                                         #print "COND<$cond> whitespace<$whitespace> offset<$offset>\n";
2185
2186                                         # We have looked at and allowed this specific line.
2187                                         $suppress_ifbraces{$ln + $offset} = 1;
2188
2189                                         $herectx .= "$rawlines[$ln + $offset]\n[...]\n";
2190                                         $ln += statement_rawlines($block) - 1;
2191
2192                                         substr($block, 0, length($cond), '');
2193
2194                                         $seen++ if ($block =~ /^\s*{/);
2195
2196                                         #print "cond<$cond> block<$block> allowed<$allowed>\n";
2197                                         if (statement_lines($cond) > 1) {
2198                                                 #print "APW: ALLOWED: cond<$cond>\n";
2199                                                 $allowed = 1;
2200                                         }
2201                                         if ($block =~/\b(?:if|for|while)\b/) {
2202                                                 #print "APW: ALLOWED: block<$block>\n";
2203                                                 $allowed = 1;
2204                                         }
2205                                         if (statement_block_size($block) > 1) {
2206                                                 #print "APW: ALLOWED: lines block<$block>\n";
2207                                                 $allowed = 1;
2208                                         }
2209                                 }
2210                                 if ($seen && !$allowed) {
2211                                         WARN("braces {} are not necessary for any arm of this statement\n" . $herectx);
2212                                 }
2213                         }
2214                 }
2215                 if (!defined $suppress_ifbraces{$linenr - 1} &&
2216                                         $line =~ /\b(if|while|for|else)\b/) {
2217                         my $allowed = 0;
2218
2219                         # Check the pre-context.
2220                         if (substr($line, 0, $-[0]) =~ /(\}\s*)$/) {
2221                                 #print "APW: ALLOWED: pre<$1>\n";
2222                                 $allowed = 1;
2223                         }
2224
2225                         my ($level, $endln, @chunks) =
2226                                 ctx_statement_full($linenr, $realcnt, $-[0]);
2227
2228                         # Check the condition.
2229                         my ($cond, $block) = @{$chunks[0]};
2230                         #print "CHECKING<$linenr> cond<$cond> block<$block>\n";
2231                         if (defined $cond) {
2232                                 substr($block, 0, length($cond), '');
2233                         }
2234                         if (statement_lines($cond) > 1) {
2235                                 #print "APW: ALLOWED: cond<$cond>\n";
2236                                 $allowed = 1;
2237                         }
2238                         if ($block =~/\b(?:if|for|while)\b/) {
2239                                 #print "APW: ALLOWED: block<$block>\n";
2240                                 $allowed = 1;
2241                         }
2242                         if (statement_block_size($block) > 1) {
2243                                 #print "APW: ALLOWED: lines block<$block>\n";
2244                                 $allowed = 1;
2245                         }
2246                         # Check the post-context.
2247                         if (defined $chunks[1]) {
2248                                 my ($cond, $block) = @{$chunks[1]};
2249                                 if (defined $cond) {
2250                                         substr($block, 0, length($cond), '');
2251                                 }
2252                                 if ($block =~ /^\s*\{/) {
2253                                         #print "APW: ALLOWED: chunk-1 block<$block>\n";
2254                                         $allowed = 1;
2255                                 }
2256                         }
2257                         if ($level == 0 && $block =~ /^\s*\{/ && !$allowed) {
2258                                 my $herectx = $here . "\n";;
2259                                 my $cnt = statement_rawlines($block);
2260
2261                                 for (my $n = 0; $n < $cnt; $n++) {
2262                                         $herectx .= raw_line($linenr, $n) . "\n";;
2263                                 }
2264
2265                                 WARN("braces {} are not necessary for single statement blocks\n" . $herectx);
2266                         }
2267                 }
2268
2269 # don't include deprecated include files (uses RAW line)
2270                 for my $inc (@dep_includes) {
2271                         if ($rawline =~ m@^.\s*\#\s*include\s*\<$inc>@) {
2272                                 ERROR("Don't use <$inc>: see Documentation/feature-removal-schedule.txt\n" . $herecurr);
2273                         }
2274                 }
2275
2276 # don't use deprecated functions
2277                 for my $func (@dep_functions) {
2278                         if ($line =~ /\b$func\b/) {
2279                                 ERROR("Don't use $func(): see Documentation/feature-removal-schedule.txt\n" . $herecurr);
2280                         }
2281                 }
2282
2283 # no volatiles please
2284                 my $asm_volatile = qr{\b(__asm__|asm)\s+(__volatile__|volatile)\b};
2285                 if ($line =~ /\bvolatile\b/ && $line !~ /$asm_volatile/) {
2286                         WARN("Use of volatile is usually wrong: see Documentation/volatile-considered-harmful.txt\n" . $herecurr);
2287                 }
2288
2289 # SPIN_LOCK_UNLOCKED & RW_LOCK_UNLOCKED are deprecated
2290                 if ($line =~ /\b(SPIN_LOCK_UNLOCKED|RW_LOCK_UNLOCKED)/) {
2291                         ERROR("Use of $1 is deprecated: see Documentation/spinlocks.txt\n" . $herecurr);
2292                 }
2293
2294 # warn about #if 0
2295                 if ($line =~ /^.\s*\#\s*if\s+0\b/) {
2296                         CHK("if this code is redundant consider removing it\n" .
2297                                 $herecurr);
2298                 }
2299
2300 # check for needless kfree() checks
2301                 if ($prevline =~ /\bif\s*\(([^\)]*)\)/) {
2302                         my $expr = $1;
2303                         if ($line =~ /\bkfree\(\Q$expr\E\);/) {
2304                                 WARN("kfree(NULL) is safe this check is probably not required\n" . $hereprev);
2305                         }
2306                 }
2307 # check for needless usb_free_urb() checks
2308                 if ($prevline =~ /\bif\s*\(([^\)]*)\)/) {
2309                         my $expr = $1;
2310                         if ($line =~ /\busb_free_urb\(\Q$expr\E\);/) {
2311                                 WARN("usb_free_urb(NULL) is safe this check is probably not required\n" . $hereprev);
2312                         }
2313                 }
2314
2315 # warn about #ifdefs in C files
2316 #               if ($line =~ /^.\s*\#\s*if(|n)def/ && ($realfile =~ /\.c$/)) {
2317 #                       print "#ifdef in C files should be avoided\n";
2318 #                       print "$herecurr";
2319 #                       $clean = 0;
2320 #               }
2321
2322 # warn about spacing in #ifdefs
2323                 if ($line =~ /^.\s*\#\s*(ifdef|ifndef|elif)\s\s+/) {
2324                         ERROR("exactly one space required after that #$1\n" . $herecurr);
2325                 }
2326
2327 # check for spinlock_t definitions without a comment.
2328                 if ($line =~ /^.\s*(struct\s+mutex|spinlock_t)\s+\S+;/ ||
2329                     $line =~ /^.\s*(DEFINE_MUTEX)\s*\(/) {
2330                         my $which = $1;
2331                         if (!ctx_has_comment($first_line, $linenr)) {
2332                                 CHK("$1 definition without comment\n" . $herecurr);
2333                         }
2334                 }
2335 # check for memory barriers without a comment.
2336                 if ($line =~ /\b(mb|rmb|wmb|read_barrier_depends|smp_mb|smp_rmb|smp_wmb|smp_read_barrier_depends)\(/) {
2337                         if (!ctx_has_comment($first_line, $linenr)) {
2338                                 CHK("memory barrier without comment\n" . $herecurr);
2339                         }
2340                 }
2341 # check of hardware specific defines
2342                 if ($line =~ m@^.\s*\#\s*if.*\b(__i386__|__powerpc64__|__sun__|__s390x__)\b@ && $realfile !~ m@include/asm-@) {
2343                         CHK("architecture specific defines should be avoided\n" .  $herecurr);
2344                 }
2345
2346 # check the location of the inline attribute, that it is between
2347 # storage class and type.
2348                 if ($line =~ /\b$Type\s+$Inline\b/ ||
2349                     $line =~ /\b$Inline\s+$Storage\b/) {
2350                         ERROR("inline keyword should sit between storage class and type\n" . $herecurr);
2351                 }
2352
2353 # Check for __inline__ and __inline, prefer inline
2354                 if ($line =~ /\b(__inline__|__inline)\b/) {
2355                         WARN("plain inline is preferred over $1\n" . $herecurr);
2356                 }
2357
2358 # check for new externs in .c files.
2359                 if ($realfile =~ /\.c$/ && defined $stat &&
2360                     $stat =~ /^.\s*(?:extern\s+)?$Type\s+($Ident)(\s*)\(/s)
2361                 {
2362                         my $function_name = $1;
2363                         my $paren_space = $2;
2364
2365                         my $s = $stat;
2366                         if (defined $cond) {
2367                                 substr($s, 0, length($cond), '');
2368                         }
2369                         if ($s =~ /^\s*;/ &&
2370                             $function_name ne 'uninitialized_var')
2371                         {
2372                                 WARN("externs should be avoided in .c files\n" .  $herecurr);
2373                         }
2374
2375                         if ($paren_space =~ /\n/) {
2376                                 WARN("arguments for function declarations should follow identifier\n" . $herecurr);
2377                         }
2378
2379                 } elsif ($realfile =~ /\.c$/ && defined $stat &&
2380                     $stat =~ /^.\s*extern\s+/)
2381                 {
2382                         WARN("externs should be avoided in .c files\n" .  $herecurr);
2383                 }
2384
2385 # checks for new __setup's
2386                 if ($rawline =~ /\b__setup\("([^"]*)"/) {
2387                         my $name = $1;
2388
2389                         if (!grep(/$name/, @setup_docs)) {
2390                                 CHK("__setup appears un-documented -- check Documentation/kernel-parameters.txt\n" . $herecurr);
2391                         }
2392                 }
2393
2394 # check for pointless casting of kmalloc return
2395                 if ($line =~ /\*\s*\)\s*k[czm]alloc\b/) {
2396                         WARN("unnecessary cast may hide bugs, see http://c-faq.com/malloc/mallocnocast.html\n" . $herecurr);
2397                 }
2398
2399 # check for gcc specific __FUNCTION__
2400                 if ($line =~ /__FUNCTION__/) {
2401                         WARN("__func__ should be used instead of gcc specific __FUNCTION__\n"  . $herecurr);
2402                 }
2403
2404 # check for semaphores used as mutexes
2405                 if ($line =~ /^.\s*(DECLARE_MUTEX|init_MUTEX)\s*\(/) {
2406                         WARN("mutexes are preferred for single holder semaphores\n" . $herecurr);
2407                 }
2408 # check for semaphores used as mutexes
2409                 if ($line =~ /^.\s*init_MUTEX_LOCKED\s*\(/) {
2410                         WARN("consider using a completion\n" . $herecurr);
2411                 }
2412 # recommend strict_strto* over simple_strto*
2413                 if ($line =~ /\bsimple_(strto.*?)\s*\(/) {
2414                         WARN("consider using strict_$1 in preference to simple_$1\n" . $herecurr);
2415                 }
2416 # check for __initcall(), use device_initcall() explicitly please
2417                 if ($line =~ /^.\s*__initcall\s*\(/) {
2418                         WARN("please use device_initcall() instead of __initcall()\n" . $herecurr);
2419                 }
2420
2421 # use of NR_CPUS is usually wrong
2422 # ignore definitions of NR_CPUS and usage to define arrays as likely right
2423                 if ($line =~ /\bNR_CPUS\b/ &&
2424                     $line !~ /^.\s*\s*#\s*if\b.*\bNR_CPUS\b/ &&
2425                     $line !~ /^.\s*\s*#\s*define\b.*\bNR_CPUS\b/ &&
2426                     $line !~ /^.\s*$Declare\s.*\[[^\]]*NR_CPUS[^\]]*\]/ &&
2427                     $line !~ /\[[^\]]*\.\.\.[^\]]*NR_CPUS[^\]]*\]/ &&
2428                     $line !~ /\[[^\]]*NR_CPUS[^\]]*\.\.\.[^\]]*\]/)
2429                 {
2430                         WARN("usage of NR_CPUS is often wrong - consider using cpu_possible(), num_possible_cpus(), for_each_possible_cpu(), etc\n" . $herecurr);
2431                 }
2432
2433 # check for %L{u,d,i} in strings
2434                 my $string;
2435                 while ($line =~ /(?:^|")([X\t]*)(?:"|$)/g) {
2436                         $string = substr($rawline, $-[1], $+[1] - $-[1]);
2437                         $string =~ s/%%/__/g;
2438                         if ($string =~ /(?<!%)%L[udi]/) {
2439                                 WARN("\%Ld/%Lu are not-standard C, use %lld/%llu\n" . $herecurr);
2440                                 last;
2441                         }
2442                 }
2443         }
2444
2445         # If we have no input at all, then there is nothing to report on
2446         # so just keep quiet.
2447         if ($#rawlines == -1) {
2448                 exit(0);
2449         }
2450
2451         # In mailback mode only produce a report in the negative, for
2452         # things that appear to be patches.
2453         if ($mailback && ($clean == 1 || !$is_patch)) {
2454                 exit(0);
2455         }
2456
2457         # This is not a patch, and we are are in 'no-patch' mode so
2458         # just keep quiet.
2459         if (!$chk_patch && !$is_patch) {
2460                 exit(0);
2461         }
2462
2463         if (!$is_patch) {
2464                 ERROR("Does not appear to be a unified-diff format patch\n");
2465         }
2466         if ($is_patch && $chk_signoff && $signoff == 0) {
2467                 ERROR("Missing Signed-off-by: line(s)\n");
2468         }
2469
2470         print report_dump();
2471         if ($summary && !($clean == 1 && $quiet == 1)) {
2472                 print "$filename " if ($summary_file);
2473                 print "total: $cnt_error errors, $cnt_warn warnings, " .
2474                         (($check)? "$cnt_chk checks, " : "") .
2475                         "$cnt_lines lines checked\n";
2476                 print "\n" if ($quiet == 0);
2477         }
2478
2479         if ($clean == 1 && $quiet == 0) {
2480                 print "$vname has no obvious style problems and is ready for submission.\n"
2481         }
2482         if ($clean == 0 && $quiet == 0) {
2483                 print "$vname has style problems, please review.  If any of these errors\n";
2484                 print "are false positives report them to the maintainer, see\n";
2485                 print "CHECKPATCH in MAINTAINERS.\n";
2486         }
2487
2488         return $clean;
2489 }