git.oblomov.eu Git - linux-2.6/blob - arch/arm/lib/backtrace.S

   1 /*
   2  *  linux/arch/arm/lib/backtrace.S
   3  *
   4  *  Copyright (C) 1995, 1996 Russell King
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  *
  10  * 27/03/03 Ian Molton Clean up CONFIG_CPU
  11  *
  12  */
  13 #include <linux/linkage.h>
  14 #include <asm/assembler.h>
  15                 .text
  16
  17 @ fp is 0 or stack frame
  18
  19 #define frame   r4
  20 #define sv_fp   r5
  21 #define sv_pc   r6
  22 #define mask    r7
  23 #define offset  r8
  24
  25 ENTRY(__backtrace)
  26                 mov     r1, #0x10
  27                 mov     r0, fp
  28
  29 ENTRY(c_backtrace)
  30
  31 #if !defined(CONFIG_FRAME_POINTER) || !defined(CONFIG_PRINTK)
  32                 mov     pc, lr
  33 ENDPROC(__backtrace)
  34 ENDPROC(c_backtrace)
  35 #else
  36                 stmfd   sp!, {r4 - r8, lr}      @ Save an extra register so we have a location...
  37                 movs    frame, r0               @ if frame pointer is zero
  38                 beq     no_frame                @ we have no stack frames
  39
  40                 tst     r1, #0x10               @ 26 or 32-bit mode?
  41                 moveq   mask, #0xfc000003       @ mask for 26-bit
  42                 movne   mask, #0                @ mask for 32-bit
  43
  44 1:              stmfd   sp!, {pc}               @ calculate offset of PC stored
  45                 ldr     r0, [sp], #4            @ by stmfd for this CPU
  46                 adr     r1, 1b
  47                 sub     offset, r0, r1
  48
  49 /*
  50  * Stack frame layout:
  51  *             optionally saved caller registers (r4 - r10)
  52  *             saved fp
  53  *             saved sp
  54  *             saved lr
  55  *    frame => saved pc
  56  *             optionally saved arguments (r0 - r3)
  57  * saved sp => <next word>
  58  *
  59  * Functions start with the following code sequence:
  60  *                  mov   ip, sp
  61  *                  stmfd sp!, {r0 - r3} (optional)
  62  * corrected pc =>  stmfd sp!, {..., fp, ip, lr, pc}
  63  */
  64 for_each_frame: tst     frame, mask             @ Check for address exceptions
  65                 bne     no_frame
  66
  67 1001:           ldr     sv_pc, [frame, #0]      @ get saved pc
  68 1002:           ldr     sv_fp, [frame, #-12]    @ get saved fp
  69
  70                 sub     sv_pc, sv_pc, offset    @ Correct PC for prefetching
  71                 bic     sv_pc, sv_pc, mask      @ mask PC/LR for the mode
  72
  73 1003:           ldr     r2, [sv_pc, #-4]        @ if stmfd sp!, {args} exists,
  74                 ldr     r3, .Ldsi+4             @ adjust saved 'pc' back one
  75                 teq     r3, r2, lsr #10         @ instruction
  76                 subne   r0, sv_pc, #4           @ allow for mov
  77                 subeq   r0, sv_pc, #8           @ allow for mov + stmia
  78
  79                 ldr     r1, [frame, #-4]        @ get saved lr
  80                 mov     r2, frame
  81                 bic     r1, r1, mask            @ mask PC/LR for the mode
  82                 bl      dump_backtrace_entry
  83
  84                 ldr     r1, [sv_pc, #-4]        @ if stmfd sp!, {args} exists,
  85                 ldr     r3, .Ldsi+4
  86                 teq     r3, r1, lsr #10
  87                 ldreq   r0, [frame, #-8]        @ get sp
  88                 subeq   r0, r0, #4              @ point at the last arg
  89                 bleq    .Ldumpstm               @ dump saved registers
  90
  91 1004:           ldr     r1, [sv_pc, #0]         @ if stmfd sp!, {..., fp, ip, lr, pc}
  92                 ldr     r3, .Ldsi               @ instruction exists,
  93                 teq     r3, r1, lsr #10
  94                 subeq   r0, frame, #16
  95                 bleq    .Ldumpstm               @ dump saved registers
  96
  97                 teq     sv_fp, #0               @ zero saved fp means
  98                 beq     no_frame                @ no further frames
  99
 100                 cmp     sv_fp, frame            @ next frame must be
 101                 mov     frame, sv_fp            @ above the current frame
 102                 bhi     for_each_frame
 103
 104 1006:           adr     r0, .Lbad
 105                 mov     r1, frame
 106                 bl      printk
 107 no_frame:       ldmfd   sp!, {r4 - r8, pc}
 108 ENDPROC(__backtrace)
 109 ENDPROC(c_backtrace)
 110
 111                 .section __ex_table,"a"
 112                 .align  3
 113                 .long   1001b, 1006b
 114                 .long   1002b, 1006b
 115                 .long   1003b, 1006b
 116                 .long   1004b, 1006b
 117                 .previous
 118
 119 #define instr r4
 120 #define reg   r5
 121 #define stack r6
 122
 123 .Ldumpstm:      stmfd   sp!, {instr, reg, stack, r7, lr}
 124                 mov     stack, r0
 125                 mov     instr, r1
 126                 mov     reg, #10
 127                 mov     r7, #0
 128 1:              mov     r3, #1
 129                 tst     instr, r3, lsl reg
 130                 beq     2f
 131                 add     r7, r7, #1
 132                 teq     r7, #6
 133                 moveq   r7, #1
 134                 moveq   r1, #'\n'
 135                 movne   r1, #' '
 136                 ldr     r3, [stack], #-4
 137                 mov     r2, reg
 138                 adr     r0, .Lfp
 139                 bl      printk
 140 2:              subs    reg, reg, #1
 141                 bpl     1b
 142                 teq     r7, #0
 143                 adrne   r0, .Lcr
 144                 blne    printk
 145                 ldmfd   sp!, {instr, reg, stack, r7, pc}
 146
 147 .Lfp:           .asciz  "%cr%d:%08x"
 148 .Lcr:           .asciz  "\n"
 149 .Lbad:          .asciz  "Backtrace aborted due to bad frame pointer <%p>\n"
 150                 .align
 151 .Ldsi:          .word   0xe92dd800 >> 10        @ stmfd sp!, {... fp, ip, lr, pc}
 152                 .word   0xe92d0000 >> 10        @ stmfd sp!, {}
 153
 154 #endif