git.oblomov.eu Git - linux-2.6/blob - arch/arm/kernel/vmlinux.lds.S

   1 /* ld script to make ARM Linux kernel
   2  * taken from the i386 version by Russell King
   3  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   4  */
   5
   6 #include <asm-generic/vmlinux.lds.h>
   7 #include <asm/thread_info.h>
   8 #include <asm/memory.h>
   9
  10 OUTPUT_ARCH(arm)
  11 ENTRY(stext)
  12
  13 #ifndef __ARMEB__
  14 jiffies = jiffies_64;
  15 #else
  16 jiffies = jiffies_64 + 4;
  17 #endif
  18
  19 SECTIONS
  20 {
  21 #ifdef CONFIG_XIP_KERNEL
  22         . = XIP_VIRT_ADDR(CONFIG_XIP_PHYS_ADDR);
  23 #else
  24         . = PAGE_OFFSET + TEXT_OFFSET;
  25 #endif
  26         .init : {                       /* Init code and data           */
  27                 _stext = .;
  28                         _sinittext = .;
  29                         *(.init.text)
  30                         _einittext = .;
  31                 __proc_info_begin = .;
  32                         *(.proc.info.init)
  33                 __proc_info_end = .;
  34                 __arch_info_begin = .;
  35                         *(.arch.info.init)
  36                 __arch_info_end = .;
  37                 __tagtable_begin = .;
  38                         *(.taglist.init)
  39                 __tagtable_end = .;
  40                 . = ALIGN(16);
  41                 __setup_start = .;
  42                         *(.init.setup)
  43                 __setup_end = .;
  44                 __early_begin = .;
  45                         *(.early_param.init)
  46                 __early_end = .;
  47                 __initcall_start = .;
  48                         INITCALLS
  49                 __initcall_end = .;
  50                 __con_initcall_start = .;
  51                         *(.con_initcall.init)
  52                 __con_initcall_end = .;
  53                 __security_initcall_start = .;
  54                         *(.security_initcall.init)
  55                 __security_initcall_end = .;
  56 #ifdef CONFIG_BLK_DEV_INITRD
  57                 . = ALIGN(32);
  58                 __initramfs_start = .;
  59                         usr/built-in.o(.init.ramfs)
  60                 __initramfs_end = .;
  61 #endif
  62                 . = ALIGN(4096);
  63                 __per_cpu_start = .;
  64                         *(.data.percpu)
  65                 __per_cpu_end = .;
  66 #ifndef CONFIG_XIP_KERNEL
  67                 __init_begin = _stext;
  68                 *(.init.data)
  69                 . = ALIGN(4096);
  70                 __init_end = .;
  71 #endif
  72         }
  73
  74         /DISCARD/ : {                   /* Exit code and data           */
  75                 *(.exit.text)
  76                 *(.exit.data)
  77                 *(.exitcall.exit)
  78 #ifndef CONFIG_MMU
  79                 *(.fixup)
  80                 *(__ex_table)
  81 #endif
  82         }
  83
  84         .text : {                       /* Real text segment            */
  85                 _text = .;              /* Text and read-only data      */
  86                         *(.text)
  87                         SCHED_TEXT
  88                         LOCK_TEXT
  89 #ifdef CONFIG_MMU
  90                         *(.fixup)
  91 #endif
  92                         *(.gnu.warning)
  93                         *(.rodata)
  94                         *(.rodata.*)
  95                         *(.glue_7)
  96                         *(.glue_7t)
  97                 *(.got)                 /* Global offset table          */
  98         }
  99
 100         RODATA
 101
 102         _etext = .;                     /* End of text and rodata section */
 103
 104 #ifdef CONFIG_XIP_KERNEL
 105         __data_loc = ALIGN(4);          /* location in binary */
 106         . = PAGE_OFFSET + TEXT_OFFSET;
 107 #else
 108         . = ALIGN(THREAD_SIZE);
 109         __data_loc = .;
 110 #endif
 111
 112         .data : AT(__data_loc) {
 113                 __data_start = .;       /* address in memory */
 114
 115                 /*
 116                  * first, the init task union, aligned
 117                  * to an 8192 byte boundary.
 118                  */
 119                 *(.init.task)
 120
 121 #ifdef CONFIG_XIP_KERNEL
 122                 . = ALIGN(4096);
 123                 __init_begin = .;
 124                 *(.init.data)
 125                 . = ALIGN(4096);
 126                 __init_end = .;
 127 #endif
 128
 129                 . = ALIGN(4096);
 130                 __nosave_begin = .;
 131                 *(.data.nosave)
 132                 . = ALIGN(4096);
 133                 __nosave_end = .;
 134
 135                 /*
 136                  * then the cacheline aligned data
 137                  */
 138                 . = ALIGN(32);
 139                 *(.data.cacheline_aligned)
 140
 141                 /*
 142                  * The exception fixup table (might need resorting at runtime)
 143                  */
 144                 . = ALIGN(32);
 145                 __start___ex_table = .;
 146 #ifdef CONFIG_MMU
 147                 *(__ex_table)
 148 #endif
 149                 __stop___ex_table = .;
 150
 151                 /*
 152                  * and the usual data section
 153                  */
 154                 *(.data)
 155                 CONSTRUCTORS
 156
 157                 _edata = .;
 158         }
 159         _edata_loc = __data_loc + SIZEOF(.data);
 160
 161         .bss : {
 162                 __bss_start = .;        /* BSS                          */
 163                 *(.bss)
 164                 *(COMMON)
 165                 _end = .;
 166         }
 167                                         /* Stabs debugging sections.    */
 168         .stab 0 : { *(.stab) }
 169         .stabstr 0 : { *(.stabstr) }
 170         .stab.excl 0 : { *(.stab.excl) }
 171         .stab.exclstr 0 : { *(.stab.exclstr) }
 172         .stab.index 0 : { *(.stab.index) }
 173         .stab.indexstr 0 : { *(.stab.indexstr) }
 174         .comment 0 : { *(.comment) }
 175 }
 176
 177 /*
 178  * These must never be empty
 179  * If you have to comment these two assert statements out, your
 180  * binutils is too old (for other reasons as well)
 181  */
 182 ASSERT((__proc_info_end - __proc_info_begin), "missing CPU support")
 183 ASSERT((__arch_info_end - __arch_info_begin), "no machine record defined")