git.oblomov.eu Git - linux-2.6/blob - arch/x86_64/kernel/vmlinux.lds.S

   1 /* ld script to make x86-64 Linux kernel
   2  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>;
   3  */
   4
   5 #define LOAD_OFFSET __START_KERNEL_map
   6
   7 #include <asm-generic/vmlinux.lds.h>
   8 #include <asm/page.h>
   9
  10 #undef i386     /* in case the preprocessor is a 32bit one */
  11
  12 OUTPUT_FORMAT("elf64-x86-64", "elf64-x86-64", "elf64-x86-64")
  13 OUTPUT_ARCH(i386:x86-64)
  14 ENTRY(phys_startup_64)
  15 jiffies_64 = jiffies;
  16 _proxy_pda = 1;
  17 PHDRS {
  18         text PT_LOAD FLAGS(5);  /* R_E */
  19         data PT_LOAD FLAGS(7);  /* RWE */
  20         user PT_LOAD FLAGS(7);  /* RWE */
  21         data.init PT_LOAD FLAGS(7);     /* RWE */
  22         note PT_NOTE FLAGS(4);  /* R__ */
  23 }
  24 SECTIONS
  25 {
  26   . = __START_KERNEL;
  27   phys_startup_64 = startup_64 - LOAD_OFFSET;
  28   _text = .;                    /* Text and read-only data */
  29   .text :  AT(ADDR(.text) - LOAD_OFFSET) {
  30         /* First the code that has to be first for bootstrapping */
  31         *(.bootstrap.text)
  32         _stext = .;
  33         /* Then all the functions that are "hot" in profiles, to group them
  34            onto the same hugetlb entry */
  35         #include "functionlist"
  36         /* Then the rest */
  37         *(.text)
  38         SCHED_TEXT
  39         LOCK_TEXT
  40         KPROBES_TEXT
  41         *(.fixup)
  42         *(.gnu.warning)
  43         } :text = 0x9090
  44                                 /* out-of-line lock text */
  45   .text.lock : AT(ADDR(.text.lock) - LOAD_OFFSET) { *(.text.lock) }
  46
  47   _etext = .;                   /* End of text section */
  48
  49   . = ALIGN(16);                /* Exception table */
  50   __start___ex_table = .;
  51   __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { *(__ex_table) }
  52   __stop___ex_table = .;
  53
  54   BUG_TABLE
  55
  56   RODATA
  57
  58   . = ALIGN(PAGE_SIZE);        /* Align data segment to page size boundary */
  59                                 /* Data */
  60   .data : AT(ADDR(.data) - LOAD_OFFSET) {
  61         *(.data)
  62         CONSTRUCTORS
  63         } :data
  64
  65   _edata = .;                   /* End of data section */
  66
  67   . = ALIGN(PAGE_SIZE);
  68   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
  69   .data.cacheline_aligned : AT(ADDR(.data.cacheline_aligned) - LOAD_OFFSET) {
  70         *(.data.cacheline_aligned)
  71   }
  72   . = ALIGN(CONFIG_X86_INTERNODE_CACHE_BYTES);
  73   .data.read_mostly : AT(ADDR(.data.read_mostly) - LOAD_OFFSET) {
  74         *(.data.read_mostly)
  75   }
  76
  77 #define VSYSCALL_ADDR (-10*1024*1024)
  78 #define VSYSCALL_PHYS_ADDR ((LOADADDR(.data.read_mostly) + SIZEOF(.data.read_mostly) + 4095) & ~(4095))
  79 #define VSYSCALL_VIRT_ADDR ((ADDR(.data.read_mostly) + SIZEOF(.data.read_mostly) + 4095) & ~(4095))
  80
  81 #define VLOAD_OFFSET (VSYSCALL_ADDR - VSYSCALL_PHYS_ADDR)
  82 #define VLOAD(x) (ADDR(x) - VLOAD_OFFSET)
  83
  84 #define VVIRT_OFFSET (VSYSCALL_ADDR - VSYSCALL_VIRT_ADDR)
  85 #define VVIRT(x) (ADDR(x) - VVIRT_OFFSET)
  86
  87   . = VSYSCALL_ADDR;
  88   .vsyscall_0 :  AT(VSYSCALL_PHYS_ADDR) { *(.vsyscall_0) } :user
  89   __vsyscall_0 = VSYSCALL_VIRT_ADDR;
  90
  91   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
  92   .vsyscall_fn : AT(VLOAD(.vsyscall_fn)) { *(.vsyscall_fn) }
  93   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
  94   .vsyscall_gtod_data : AT(VLOAD(.vsyscall_gtod_data))
  95                 { *(.vsyscall_gtod_data) }
  96   vsyscall_gtod_data = VVIRT(.vsyscall_gtod_data);
  97
  98   .vgetcpu_mode : AT(VLOAD(.vgetcpu_mode)) { *(.vgetcpu_mode) }
  99   vgetcpu_mode = VVIRT(.vgetcpu_mode);
 100
 101   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
 102   .jiffies : AT(VLOAD(.jiffies)) { *(.jiffies) }
 103   jiffies = VVIRT(.jiffies);
 104
 105   .vsyscall_1 ADDR(.vsyscall_0) + 1024: AT(VLOAD(.vsyscall_1))
 106                 { *(.vsyscall_1) }
 107   .vsyscall_2 ADDR(.vsyscall_0) + 2048: AT(VLOAD(.vsyscall_2))
 108                 { *(.vsyscall_2) }
 109   .vsyscall_3 ADDR(.vsyscall_0) + 3072: AT(VLOAD(.vsyscall_3))
 110                 { *(.vsyscall_3) }
 111
 112   . = VSYSCALL_VIRT_ADDR + 4096;
 113
 114 #undef VSYSCALL_ADDR
 115 #undef VSYSCALL_PHYS_ADDR
 116 #undef VSYSCALL_VIRT_ADDR
 117 #undef VLOAD_OFFSET
 118 #undef VLOAD
 119 #undef VVIRT_OFFSET
 120 #undef VVIRT
 121
 122   . = ALIGN(8192);              /* init_task */
 123   .data.init_task : AT(ADDR(.data.init_task) - LOAD_OFFSET) {
 124         *(.data.init_task)
 125   }:data.init
 126
 127   . = ALIGN(4096);
 128   .data.page_aligned : AT(ADDR(.data.page_aligned) - LOAD_OFFSET) {
 129         *(.data.page_aligned)
 130   }
 131
 132   /* might get freed after init */
 133   . = ALIGN(4096);
 134   __smp_alt_begin = .;
 135   __smp_alt_instructions = .;
 136   .smp_altinstructions : AT(ADDR(.smp_altinstructions) - LOAD_OFFSET) {
 137         *(.smp_altinstructions)
 138   }
 139   __smp_alt_instructions_end = .;
 140   . = ALIGN(8);
 141   __smp_locks = .;
 142   .smp_locks : AT(ADDR(.smp_locks) - LOAD_OFFSET) {
 143         *(.smp_locks)
 144   }
 145   __smp_locks_end = .;
 146   .smp_altinstr_replacement : AT(ADDR(.smp_altinstr_replacement) - LOAD_OFFSET) {
 147         *(.smp_altinstr_replacement)
 148   }
 149   . = ALIGN(4096);
 150   __smp_alt_end = .;
 151
 152   . = ALIGN(4096);              /* Init code and data */
 153   __init_begin = .;
 154   .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {
 155         _sinittext = .;
 156         *(.init.text)
 157         _einittext = .;
 158   }
 159   __initdata_begin = .;
 160   .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { *(.init.data) }
 161   __initdata_end = .;
 162   . = ALIGN(16);
 163   __setup_start = .;
 164   .init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) { *(.init.setup) }
 165   __setup_end = .;
 166   __initcall_start = .;
 167   .initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET) {
 168         INITCALLS
 169   }
 170   __initcall_end = .;
 171   __con_initcall_start = .;
 172   .con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) {
 173         *(.con_initcall.init)
 174   }
 175   __con_initcall_end = .;
 176   SECURITY_INIT
 177   . = ALIGN(8);
 178   __alt_instructions = .;
 179   .altinstructions : AT(ADDR(.altinstructions) - LOAD_OFFSET) {
 180         *(.altinstructions)
 181   }
 182   __alt_instructions_end = .;
 183   .altinstr_replacement : AT(ADDR(.altinstr_replacement) - LOAD_OFFSET) {
 184         *(.altinstr_replacement)
 185   }
 186   /* .exit.text is discard at runtime, not link time, to deal with references
 187      from .altinstructions and .eh_frame */
 188   .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) { *(.exit.text) }
 189   .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) { *(.exit.data) }
 190
 191 #ifdef CONFIG_BLK_DEV_INITRD
 192   . = ALIGN(4096);
 193   __initramfs_start = .;
 194   .init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET) { *(.init.ramfs) }
 195   __initramfs_end = .;
 196 #endif
 197
 198   . = ALIGN(4096);
 199   __per_cpu_start = .;
 200   .data.percpu  : AT(ADDR(.data.percpu) - LOAD_OFFSET) { *(.data.percpu) }
 201   __per_cpu_end = .;
 202   . = ALIGN(4096);
 203   __init_end = .;
 204
 205   . = ALIGN(4096);
 206   __nosave_begin = .;
 207   .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) { *(.data.nosave) }
 208   . = ALIGN(4096);
 209   __nosave_end = .;
 210
 211   __bss_start = .;              /* BSS */
 212   .bss : AT(ADDR(.bss) - LOAD_OFFSET) {
 213         *(.bss.page_aligned)
 214         *(.bss)
 215         }
 216   __bss_stop = .;
 217
 218   _end = . ;
 219
 220   /* Sections to be discarded */
 221   /DISCARD/ : {
 222         *(.exitcall.exit)
 223         *(.eh_frame)
 224         }
 225
 226   STABS_DEBUG
 227
 228   DWARF_DEBUG
 229 }