git.oblomov.eu Git - linux-2.6/blob - arch/x86/kernel/entry_64.S

   1 /*
   2  *  linux/arch/x86_64/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  *  Copyright (C) 2000, 2001, 2002  Andi Kleen SuSE Labs
   6  *  Copyright (C) 2000  Pavel Machek <pavel@suse.cz>
   7  */
   8
   9 /*
  10  * entry.S contains the system-call and fault low-level handling routines.
  11  *
  12  * NOTE: This code handles signal-recognition, which happens every time
  13  * after an interrupt and after each system call.
  14  *
  15  * Normal syscalls and interrupts don't save a full stack frame, this is
  16  * only done for syscall tracing, signals or fork/exec et.al.
  17  *
  18  * A note on terminology:
  19  * - top of stack: Architecture defined interrupt frame from SS to RIP
  20  * at the top of the kernel process stack.
  21  * - partial stack frame: partially saved registers upto R11.
  22  * - full stack frame: Like partial stack frame, but all register saved.
  23  *
  24  * Some macro usage:
  25  * - CFI macros are used to generate dwarf2 unwind information for better
  26  * backtraces. They don't change any code.
  27  * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
  28  * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
  29  * There are unfortunately lots of special cases where some registers
  30  * not touched. The macro is a big mess that should be cleaned up.
  31  * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
  32  * Gives a full stack frame.
  33  * - ENTRY/END Define functions in the symbol table.
  34  * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
  35  * frame that is otherwise undefined after a SYSCALL
  36  * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
  37  * - errorentry/paranoidentry/zeroentry - Define exception entry points.
  38  */
  39
  40 #include <linux/linkage.h>
  41 #include <asm/segment.h>
  42 #include <asm/cache.h>
  43 #include <asm/errno.h>
  44 #include <asm/dwarf2.h>
  45 #include <asm/calling.h>
  46 #include <asm/asm-offsets.h>
  47 #include <asm/msr.h>
  48 #include <asm/unistd.h>
  49 #include <asm/thread_info.h>
  50 #include <asm/hw_irq.h>
  51 #include <asm/page_types.h>
  52 #include <asm/irqflags.h>
  53 #include <asm/paravirt.h>
  54 #include <asm/ftrace.h>
  55 #include <asm/percpu.h>
  56
  57 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  58 #include <linux/elf-em.h>
  59 #define AUDIT_ARCH_X86_64       (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
  60 #define __AUDIT_ARCH_64BIT 0x80000000
  61 #define __AUDIT_ARCH_LE    0x40000000
  62
  63         .code64
  64 #ifdef CONFIG_FUNCTION_TRACER
  65 #ifdef CONFIG_DYNAMIC_FTRACE
  66 ENTRY(mcount)
  67         retq
  68 END(mcount)
  69
  70 ENTRY(ftrace_caller)
  71         cmpl $0, function_trace_stop
  72         jne  ftrace_stub
  73
  74         MCOUNT_SAVE_FRAME
  75
  76         movq 0x38(%rsp), %rdi
  77         movq 8(%rbp), %rsi
  78         subq $MCOUNT_INSN_SIZE, %rdi
  79
  80 GLOBAL(ftrace_call)
  81         call ftrace_stub
  82
  83         MCOUNT_RESTORE_FRAME
  84
  85 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
  86 GLOBAL(ftrace_graph_call)
  87         jmp ftrace_stub
  88 #endif
  89
  90 GLOBAL(ftrace_stub)
  91         retq
  92 END(ftrace_caller)
  93
  94 #else /* ! CONFIG_DYNAMIC_FTRACE */
  95 ENTRY(mcount)
  96         cmpl $0, function_trace_stop
  97         jne  ftrace_stub
  98
  99         cmpq $ftrace_stub, ftrace_trace_function
 100         jnz trace
 101
 102 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 103         cmpq $ftrace_stub, ftrace_graph_return
 104         jnz ftrace_graph_caller
 105
 106         cmpq $ftrace_graph_entry_stub, ftrace_graph_entry
 107         jnz ftrace_graph_caller
 108 #endif
 109
 110 GLOBAL(ftrace_stub)
 111         retq
 112
 113 trace:
 114         MCOUNT_SAVE_FRAME
 115
 116         movq 0x38(%rsp), %rdi
 117         movq 8(%rbp), %rsi
 118         subq $MCOUNT_INSN_SIZE, %rdi
 119
 120         call   *ftrace_trace_function
 121
 122         MCOUNT_RESTORE_FRAME
 123
 124         jmp ftrace_stub
 125 END(mcount)
 126 #endif /* CONFIG_DYNAMIC_FTRACE */
 127 #endif /* CONFIG_FUNCTION_TRACER */
 128
 129 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 130 ENTRY(ftrace_graph_caller)
 131         cmpl $0, function_trace_stop
 132         jne ftrace_stub
 133
 134         MCOUNT_SAVE_FRAME
 135
 136         leaq 8(%rbp), %rdi
 137         movq 0x38(%rsp), %rsi
 138         subq $MCOUNT_INSN_SIZE, %rsi
 139
 140         call    prepare_ftrace_return
 141
 142         MCOUNT_RESTORE_FRAME
 143
 144         retq
 145 END(ftrace_graph_caller)
 146
 147 GLOBAL(return_to_handler)
 148         subq  $80, %rsp
 149
 150         /* Save the return values */
 151         movq %rax, (%rsp)
 152         movq %rdx, 8(%rsp)
 153
 154         call ftrace_return_to_handler
 155
 156         movq %rax, 72(%rsp)
 157         movq 8(%rsp), %rdx
 158         movq (%rsp), %rax
 159         addq $72, %rsp
 160         retq
 161 #endif
 162
 163
 164 #ifndef CONFIG_PREEMPT
 165 #define retint_kernel retint_restore_args
 166 #endif
 167
 168 #ifdef CONFIG_PARAVIRT
 169 ENTRY(native_usergs_sysret64)
 170         swapgs
 171         sysretq
 172 ENDPROC(native_usergs_sysret64)
 173 #endif /* CONFIG_PARAVIRT */
 174
 175
 176 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
 177 #ifdef CONFIG_TRACE_IRQFLAGS
 178         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 179         jnc  1f
 180         TRACE_IRQS_ON
 181 1:
 182 #endif
 183 .endm
 184
 185 /*
 186  * C code is not supposed to know about undefined top of stack. Every time
 187  * a C function with an pt_regs argument is called from the SYSCALL based
 188  * fast path FIXUP_TOP_OF_STACK is needed.
 189  * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
 190  * manipulation.
 191  */
 192
 193         /* %rsp:at FRAMEEND */
 194         .macro FIXUP_TOP_OF_STACK tmp offset=0
 195         movq PER_CPU_VAR(old_rsp),\tmp
 196         movq \tmp,RSP+\offset(%rsp)
 197         movq $__USER_DS,SS+\offset(%rsp)
 198         movq $__USER_CS,CS+\offset(%rsp)
 199         movq $-1,RCX+\offset(%rsp)
 200         movq R11+\offset(%rsp),\tmp  /* get eflags */
 201         movq \tmp,EFLAGS+\offset(%rsp)
 202         .endm
 203
 204         .macro RESTORE_TOP_OF_STACK tmp offset=0
 205         movq RSP+\offset(%rsp),\tmp
 206         movq \tmp,PER_CPU_VAR(old_rsp)
 207         movq EFLAGS+\offset(%rsp),\tmp
 208         movq \tmp,R11+\offset(%rsp)
 209         .endm
 210
 211         .macro FAKE_STACK_FRAME child_rip
 212         /* push in order ss, rsp, eflags, cs, rip */
 213         xorl %eax, %eax
 214         pushq $__KERNEL_DS /* ss */
 215         CFI_ADJUST_CFA_OFFSET   8
 216         /*CFI_REL_OFFSET        ss,0*/
 217         pushq %rax /* rsp */
 218         CFI_ADJUST_CFA_OFFSET   8
 219         CFI_REL_OFFSET  rsp,0
 220         pushq $X86_EFLAGS_IF /* eflags - interrupts on */
 221         CFI_ADJUST_CFA_OFFSET   8
 222         /*CFI_REL_OFFSET        rflags,0*/
 223         pushq $__KERNEL_CS /* cs */
 224         CFI_ADJUST_CFA_OFFSET   8
 225         /*CFI_REL_OFFSET        cs,0*/
 226         pushq \child_rip /* rip */
 227         CFI_ADJUST_CFA_OFFSET   8
 228         CFI_REL_OFFSET  rip,0
 229         pushq   %rax /* orig rax */
 230         CFI_ADJUST_CFA_OFFSET   8
 231         .endm
 232
 233         .macro UNFAKE_STACK_FRAME
 234         addq $8*6, %rsp
 235         CFI_ADJUST_CFA_OFFSET   -(6*8)
 236         .endm
 237
 238 /*
 239  * initial frame state for interrupts (and exceptions without error code)
 240  */
 241         .macro EMPTY_FRAME start=1 offset=0
 242         .if \start
 243         CFI_STARTPROC simple
 244         CFI_SIGNAL_FRAME
 245         CFI_DEF_CFA rsp,8+\offset
 246         .else
 247         CFI_DEF_CFA_OFFSET 8+\offset
 248         .endif
 249         .endm
 250
 251 /*
 252  * initial frame state for interrupts (and exceptions without error code)
 253  */
 254         .macro INTR_FRAME start=1 offset=0
 255         EMPTY_FRAME \start, SS+8+\offset-RIP
 256         /*CFI_REL_OFFSET ss, SS+\offset-RIP*/
 257         CFI_REL_OFFSET rsp, RSP+\offset-RIP
 258         /*CFI_REL_OFFSET rflags, EFLAGS+\offset-RIP*/
 259         /*CFI_REL_OFFSET cs, CS+\offset-RIP*/
 260         CFI_REL_OFFSET rip, RIP+\offset-RIP
 261         .endm
 262
 263 /*
 264  * initial frame state for exceptions with error code (and interrupts
 265  * with vector already pushed)
 266  */
 267         .macro XCPT_FRAME start=1 offset=0
 268         INTR_FRAME \start, RIP+\offset-ORIG_RAX
 269         /*CFI_REL_OFFSET orig_rax, ORIG_RAX-ORIG_RAX*/
 270         .endm
 271
 272 /*
 273  * frame that enables calling into C.
 274  */
 275         .macro PARTIAL_FRAME start=1 offset=0
 276         XCPT_FRAME \start, ORIG_RAX+\offset-ARGOFFSET
 277         CFI_REL_OFFSET rdi, RDI+\offset-ARGOFFSET
 278         CFI_REL_OFFSET rsi, RSI+\offset-ARGOFFSET
 279         CFI_REL_OFFSET rdx, RDX+\offset-ARGOFFSET
 280         CFI_REL_OFFSET rcx, RCX+\offset-ARGOFFSET
 281         CFI_REL_OFFSET rax, RAX+\offset-ARGOFFSET
 282         CFI_REL_OFFSET r8, R8+\offset-ARGOFFSET
 283         CFI_REL_OFFSET r9, R9+\offset-ARGOFFSET
 284         CFI_REL_OFFSET r10, R10+\offset-ARGOFFSET
 285         CFI_REL_OFFSET r11, R11+\offset-ARGOFFSET
 286         .endm
 287
 288 /*
 289  * frame that enables passing a complete pt_regs to a C function.
 290  */
 291         .macro DEFAULT_FRAME start=1 offset=0
 292         PARTIAL_FRAME \start, R11+\offset-R15
 293         CFI_REL_OFFSET rbx, RBX+\offset
 294         CFI_REL_OFFSET rbp, RBP+\offset
 295         CFI_REL_OFFSET r12, R12+\offset
 296         CFI_REL_OFFSET r13, R13+\offset
 297         CFI_REL_OFFSET r14, R14+\offset
 298         CFI_REL_OFFSET r15, R15+\offset
 299         .endm
 300
 301 /* save partial stack frame */
 302 ENTRY(save_args)
 303         XCPT_FRAME
 304         cld
 305         movq_cfi rdi, RDI+16-ARGOFFSET
 306         movq_cfi rsi, RSI+16-ARGOFFSET
 307         movq_cfi rdx, RDX+16-ARGOFFSET
 308         movq_cfi rcx, RCX+16-ARGOFFSET
 309         movq_cfi rax, RAX+16-ARGOFFSET
 310         movq_cfi  r8,  R8+16-ARGOFFSET
 311         movq_cfi  r9,  R9+16-ARGOFFSET
 312         movq_cfi r10, R10+16-ARGOFFSET
 313         movq_cfi r11, R11+16-ARGOFFSET
 314
 315         leaq -ARGOFFSET+16(%rsp),%rdi   /* arg1 for handler */
 316         movq_cfi rbp, 8         /* push %rbp */
 317         leaq 8(%rsp), %rbp              /* mov %rsp, %ebp */
 318         testl $3, CS(%rdi)
 319         je 1f
 320         SWAPGS
 321         /*
 322          * irq_count is used to check if a CPU is already on an interrupt stack
 323          * or not. While this is essentially redundant with preempt_count it is
 324          * a little cheaper to use a separate counter in the PDA (short of
 325          * moving irq_enter into assembly, which would be too much work)
 326          */
 327 1:      incl PER_CPU_VAR(irq_count)
 328         jne 2f
 329         popq_cfi %rax                   /* move return address... */
 330         mov PER_CPU_VAR(irq_stack_ptr),%rsp
 331         EMPTY_FRAME 0
 332         pushq_cfi %rbp                  /* backlink for unwinder */
 333         pushq_cfi %rax                  /* ... to the new stack */
 334         /*
 335          * We entered an interrupt context - irqs are off:
 336          */
 337 2:      TRACE_IRQS_OFF
 338         ret
 339         CFI_ENDPROC
 340 END(save_args)
 341
 342 ENTRY(save_rest)
 343         PARTIAL_FRAME 1 REST_SKIP+8
 344         movq 5*8+16(%rsp), %r11 /* save return address */
 345         movq_cfi rbx, RBX+16
 346         movq_cfi rbp, RBP+16
 347         movq_cfi r12, R12+16
 348         movq_cfi r13, R13+16
 349         movq_cfi r14, R14+16
 350         movq_cfi r15, R15+16
 351         movq %r11, 8(%rsp)      /* return address */
 352         FIXUP_TOP_OF_STACK %r11, 16
 353         ret
 354         CFI_ENDPROC
 355 END(save_rest)
 356
 357 /* save complete stack frame */
 358         .pushsection .kprobes.text, "ax"
 359 ENTRY(save_paranoid)
 360         XCPT_FRAME 1 RDI+8
 361         cld
 362         movq_cfi rdi, RDI+8
 363         movq_cfi rsi, RSI+8
 364         movq_cfi rdx, RDX+8
 365         movq_cfi rcx, RCX+8
 366         movq_cfi rax, RAX+8
 367         movq_cfi r8, R8+8
 368         movq_cfi r9, R9+8
 369         movq_cfi r10, R10+8
 370         movq_cfi r11, R11+8
 371         movq_cfi rbx, RBX+8
 372         movq_cfi rbp, RBP+8
 373         movq_cfi r12, R12+8
 374         movq_cfi r13, R13+8
 375         movq_cfi r14, R14+8
 376         movq_cfi r15, R15+8
 377         movl $1,%ebx
 378         movl $MSR_GS_BASE,%ecx
 379         rdmsr
 380         testl %edx,%edx
 381         js 1f   /* negative -> in kernel */
 382         SWAPGS
 383         xorl %ebx,%ebx
 384 1:      ret
 385         CFI_ENDPROC
 386 END(save_paranoid)
 387         .popsection
 388
 389 /*
 390  * A newly forked process directly context switches into this address.
 391  *
 392  * rdi: prev task we switched from
 393  */
 394 ENTRY(ret_from_fork)
 395         DEFAULT_FRAME
 396
 397         LOCK ; btr $TIF_FORK,TI_flags(%r8)
 398
 399         push kernel_eflags(%rip)
 400         CFI_ADJUST_CFA_OFFSET 8
 401         popf                                    # reset kernel eflags
 402         CFI_ADJUST_CFA_OFFSET -8
 403
 404         call schedule_tail                      # rdi: 'prev' task parameter
 405
 406         GET_THREAD_INFO(%rcx)
 407
 408         RESTORE_REST
 409
 410         testl $3, CS-ARGOFFSET(%rsp)            # from kernel_thread?
 411         je   int_ret_from_sys_call
 412
 413         testl $_TIF_IA32, TI_flags(%rcx)        # 32-bit compat task needs IRET
 414         jnz  int_ret_from_sys_call
 415
 416         RESTORE_TOP_OF_STACK %rdi, -ARGOFFSET
 417         jmp ret_from_sys_call                   # go to the SYSRET fastpath
 418
 419         CFI_ENDPROC
 420 END(ret_from_fork)
 421
 422 /*
 423  * System call entry. Upto 6 arguments in registers are supported.
 424  *
 425  * SYSCALL does not save anything on the stack and does not change the
 426  * stack pointer.
 427  */
 428
 429 /*
 430  * Register setup:
 431  * rax  system call number
 432  * rdi  arg0
 433  * rcx  return address for syscall/sysret, C arg3
 434  * rsi  arg1
 435  * rdx  arg2
 436  * r10  arg3    (--> moved to rcx for C)
 437  * r8   arg4
 438  * r9   arg5
 439  * r11  eflags for syscall/sysret, temporary for C
 440  * r12-r15,rbp,rbx saved by C code, not touched.
 441  *
 442  * Interrupts are off on entry.
 443  * Only called from user space.
 444  *
 445  * XXX  if we had a free scratch register we could save the RSP into the stack frame
 446  *      and report it properly in ps. Unfortunately we haven't.
 447  *
 448  * When user can change the frames always force IRET. That is because
 449  * it deals with uncanonical addresses better. SYSRET has trouble
 450  * with them due to bugs in both AMD and Intel CPUs.
 451  */
 452
 453 ENTRY(system_call)
 454         CFI_STARTPROC   simple
 455         CFI_SIGNAL_FRAME
 456         CFI_DEF_CFA     rsp,KERNEL_STACK_OFFSET
 457         CFI_REGISTER    rip,rcx
 458         /*CFI_REGISTER  rflags,r11*/
 459         SWAPGS_UNSAFE_STACK
 460         /*
 461          * A hypervisor implementation might want to use a label
 462          * after the swapgs, so that it can do the swapgs
 463          * for the guest and jump here on syscall.
 464          */
 465 ENTRY(system_call_after_swapgs)
 466
 467         movq    %rsp,PER_CPU_VAR(old_rsp)
 468         movq    PER_CPU_VAR(kernel_stack),%rsp
 469         /*
 470          * No need to follow this irqs off/on section - it's straight
 471          * and short:
 472          */
 473         ENABLE_INTERRUPTS(CLBR_NONE)
 474         SAVE_ARGS 8,1
 475         movq  %rax,ORIG_RAX-ARGOFFSET(%rsp)
 476         movq  %rcx,RIP-ARGOFFSET(%rsp)
 477         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 478         GET_THREAD_INFO(%rcx)
 479         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%rcx)
 480         jnz tracesys
 481 system_call_fastpath:
 482         cmpq $__NR_syscall_max,%rax
 483         ja badsys
 484         movq %r10,%rcx
 485         call *sys_call_table(,%rax,8)  # XXX:    rip relative
 486         movq %rax,RAX-ARGOFFSET(%rsp)
 487 /*
 488  * Syscall return path ending with SYSRET (fast path)
 489  * Has incomplete stack frame and undefined top of stack.
 490  */
 491 ret_from_sys_call:
 492         movl $_TIF_ALLWORK_MASK,%edi
 493         /* edi: flagmask */
 494 sysret_check:
 495         LOCKDEP_SYS_EXIT
 496         GET_THREAD_INFO(%rcx)
 497         DISABLE_INTERRUPTS(CLBR_NONE)
 498         TRACE_IRQS_OFF
 499         movl TI_flags(%rcx),%edx
 500         andl %edi,%edx
 501         jnz  sysret_careful
 502         CFI_REMEMBER_STATE
 503         /*
 504          * sysretq will re-enable interrupts:
 505          */
 506         TRACE_IRQS_ON
 507         movq RIP-ARGOFFSET(%rsp),%rcx
 508         CFI_REGISTER    rip,rcx
 509         RESTORE_ARGS 0,-ARG_SKIP,1
 510         /*CFI_REGISTER  rflags,r11*/
 511         movq    PER_CPU_VAR(old_rsp), %rsp
 512         USERGS_SYSRET64
 513
 514         CFI_RESTORE_STATE
 515         /* Handle reschedules */
 516         /* edx: work, edi: workmask */
 517 sysret_careful:
 518         bt $TIF_NEED_RESCHED,%edx
 519         jnc sysret_signal
 520         TRACE_IRQS_ON
 521         ENABLE_INTERRUPTS(CLBR_NONE)
 522         pushq %rdi
 523         CFI_ADJUST_CFA_OFFSET 8
 524         call schedule
 525         popq  %rdi
 526         CFI_ADJUST_CFA_OFFSET -8
 527         jmp sysret_check
 528
 529         /* Handle a signal */
 530 sysret_signal:
 531         TRACE_IRQS_ON
 532         ENABLE_INTERRUPTS(CLBR_NONE)
 533 #ifdef CONFIG_AUDITSYSCALL
 534         bt $TIF_SYSCALL_AUDIT,%edx
 535         jc sysret_audit
 536 #endif
 537         /* edx: work flags (arg3) */
 538         leaq -ARGOFFSET(%rsp),%rdi # &pt_regs -> arg1
 539         xorl %esi,%esi # oldset -> arg2
 540         SAVE_REST
 541         FIXUP_TOP_OF_STACK %r11
 542         call do_notify_resume
 543         RESTORE_TOP_OF_STACK %r11
 544         RESTORE_REST
 545         movl $_TIF_WORK_MASK,%edi
 546         /* Use IRET because user could have changed frame. This
 547            works because ptregscall_common has called FIXUP_TOP_OF_STACK. */
 548         DISABLE_INTERRUPTS(CLBR_NONE)
 549         TRACE_IRQS_OFF
 550         jmp int_with_check
 551
 552 badsys:
 553         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 554         jmp ret_from_sys_call
 555
 556 #ifdef CONFIG_AUDITSYSCALL
 557         /*
 558          * Fast path for syscall audit without full syscall trace.
 559          * We just call audit_syscall_entry() directly, and then
 560          * jump back to the normal fast path.
 561          */
 562 auditsys:
 563         movq %r10,%r9                   /* 6th arg: 4th syscall arg */
 564         movq %rdx,%r8                   /* 5th arg: 3rd syscall arg */
 565         movq %rsi,%rcx                  /* 4th arg: 2nd syscall arg */
 566         movq %rdi,%rdx                  /* 3rd arg: 1st syscall arg */
 567         movq %rax,%rsi                  /* 2nd arg: syscall number */
 568         movl $AUDIT_ARCH_X86_64,%edi    /* 1st arg: audit arch */
 569         call audit_syscall_entry
 570         LOAD_ARGS 0             /* reload call-clobbered registers */
 571         jmp system_call_fastpath
 572
 573         /*
 574          * Return fast path for syscall audit.  Call audit_syscall_exit()
 575          * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
 576          * masked off.
 577          */
 578 sysret_audit:
 579         movq %rax,%rsi          /* second arg, syscall return value */
 580         cmpq $0,%rax            /* is it < 0? */
 581         setl %al                /* 1 if so, 0 if not */
 582         movzbl %al,%edi         /* zero-extend that into %edi */
 583         inc %edi /* first arg, 0->1(AUDITSC_SUCCESS), 1->2(AUDITSC_FAILURE) */
 584         call audit_syscall_exit
 585         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
 586         jmp sysret_check
 587 #endif  /* CONFIG_AUDITSYSCALL */
 588
 589         /* Do syscall tracing */
 590 tracesys:
 591 #ifdef CONFIG_AUDITSYSCALL
 592         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%rcx)
 593         jz auditsys
 594 #endif
 595         SAVE_REST
 596         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 597         FIXUP_TOP_OF_STACK %rdi
 598         movq %rsp,%rdi
 599         call syscall_trace_enter
 600         /*
 601          * Reload arg registers from stack in case ptrace changed them.
 602          * We don't reload %rax because syscall_trace_enter() returned
 603          * the value it wants us to use in the table lookup.
 604          */
 605         LOAD_ARGS ARGOFFSET, 1
 606         RESTORE_REST
 607         cmpq $__NR_syscall_max,%rax
 608         ja   int_ret_from_sys_call      /* RAX(%rsp) set to -ENOSYS above */
 609         movq %r10,%rcx  /* fixup for C */
 610         call *sys_call_table(,%rax,8)
 611         movq %rax,RAX-ARGOFFSET(%rsp)
 612         /* Use IRET because user could have changed frame */
 613
 614 /*
 615  * Syscall return path ending with IRET.
 616  * Has correct top of stack, but partial stack frame.
 617  */
 618 GLOBAL(int_ret_from_sys_call)
 619         DISABLE_INTERRUPTS(CLBR_NONE)
 620         TRACE_IRQS_OFF
 621         testl $3,CS-ARGOFFSET(%rsp)
 622         je retint_restore_args
 623         movl $_TIF_ALLWORK_MASK,%edi
 624         /* edi: mask to check */
 625 GLOBAL(int_with_check)
 626         LOCKDEP_SYS_EXIT_IRQ
 627         GET_THREAD_INFO(%rcx)
 628         movl TI_flags(%rcx),%edx
 629         andl %edi,%edx
 630         jnz   int_careful
 631         andl    $~TS_COMPAT,TI_status(%rcx)
 632         jmp   retint_swapgs
 633
 634         /* Either reschedule or signal or syscall exit tracking needed. */
 635         /* First do a reschedule test. */
 636         /* edx: work, edi: workmask */
 637 int_careful:
 638         bt $TIF_NEED_RESCHED,%edx
 639         jnc  int_very_careful
 640         TRACE_IRQS_ON
 641         ENABLE_INTERRUPTS(CLBR_NONE)
 642         pushq %rdi
 643         CFI_ADJUST_CFA_OFFSET 8
 644         call schedule
 645         popq %rdi
 646         CFI_ADJUST_CFA_OFFSET -8
 647         DISABLE_INTERRUPTS(CLBR_NONE)
 648         TRACE_IRQS_OFF
 649         jmp int_with_check
 650
 651         /* handle signals and tracing -- both require a full stack frame */
 652 int_very_careful:
 653         TRACE_IRQS_ON
 654         ENABLE_INTERRUPTS(CLBR_NONE)
 655         SAVE_REST
 656         /* Check for syscall exit trace */
 657         testl $_TIF_WORK_SYSCALL_EXIT,%edx
 658         jz int_signal
 659         pushq %rdi
 660         CFI_ADJUST_CFA_OFFSET 8
 661         leaq 8(%rsp),%rdi       # &ptregs -> arg1
 662         call syscall_trace_leave
 663         popq %rdi
 664         CFI_ADJUST_CFA_OFFSET -8
 665         andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
 666         jmp int_restore_rest
 667
 668 int_signal:
 669         testl $_TIF_DO_NOTIFY_MASK,%edx
 670         jz 1f
 671         movq %rsp,%rdi          # &ptregs -> arg1
 672         xorl %esi,%esi          # oldset -> arg2
 673         call do_notify_resume
 674 1:      movl $_TIF_WORK_MASK,%edi
 675 int_restore_rest:
 676         RESTORE_REST
 677         DISABLE_INTERRUPTS(CLBR_NONE)
 678         TRACE_IRQS_OFF
 679         jmp int_with_check
 680         CFI_ENDPROC
 681 END(system_call)
 682
 683 /*
 684  * Certain special system calls that need to save a complete full stack frame.
 685  */
 686         .macro PTREGSCALL label,func,arg
 687 ENTRY(\label)
 688         PARTIAL_FRAME 1 8               /* offset 8: return address */
 689         subq $REST_SKIP, %rsp
 690         CFI_ADJUST_CFA_OFFSET REST_SKIP
 691         call save_rest
 692         DEFAULT_FRAME 0 8               /* offset 8: return address */
 693         leaq 8(%rsp), \arg      /* pt_regs pointer */
 694         call \func
 695         jmp ptregscall_common
 696         CFI_ENDPROC
 697 END(\label)
 698         .endm
 699
 700         PTREGSCALL stub_clone, sys_clone, %r8
 701         PTREGSCALL stub_fork, sys_fork, %rdi
 702         PTREGSCALL stub_vfork, sys_vfork, %rdi
 703         PTREGSCALL stub_sigaltstack, sys_sigaltstack, %rdx
 704         PTREGSCALL stub_iopl, sys_iopl, %rsi
 705
 706 ENTRY(ptregscall_common)
 707         DEFAULT_FRAME 1 8       /* offset 8: return address */
 708         RESTORE_TOP_OF_STACK %r11, 8
 709         movq_cfi_restore R15+8, r15
 710         movq_cfi_restore R14+8, r14
 711         movq_cfi_restore R13+8, r13
 712         movq_cfi_restore R12+8, r12
 713         movq_cfi_restore RBP+8, rbp
 714         movq_cfi_restore RBX+8, rbx
 715         ret $REST_SKIP          /* pop extended registers */
 716         CFI_ENDPROC
 717 END(ptregscall_common)
 718
 719 ENTRY(stub_execve)
 720         CFI_STARTPROC
 721         popq %r11
 722         CFI_ADJUST_CFA_OFFSET -8
 723         CFI_REGISTER rip, r11
 724         SAVE_REST
 725         FIXUP_TOP_OF_STACK %r11
 726         movq %rsp, %rcx
 727         call sys_execve
 728         RESTORE_TOP_OF_STACK %r11
 729         movq %rax,RAX(%rsp)
 730         RESTORE_REST
 731         jmp int_ret_from_sys_call
 732         CFI_ENDPROC
 733 END(stub_execve)
 734
 735 /*
 736  * sigreturn is special because it needs to restore all registers on return.
 737  * This cannot be done with SYSRET, so use the IRET return path instead.
 738  */
 739 ENTRY(stub_rt_sigreturn)
 740         CFI_STARTPROC
 741         addq $8, %rsp
 742         CFI_ADJUST_CFA_OFFSET   -8
 743         SAVE_REST
 744         movq %rsp,%rdi
 745         FIXUP_TOP_OF_STACK %r11
 746         call sys_rt_sigreturn
 747         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 748         RESTORE_REST
 749         jmp int_ret_from_sys_call
 750         CFI_ENDPROC
 751 END(stub_rt_sigreturn)
 752
 753 /*
 754  * Build the entry stubs and pointer table with some assembler magic.
 755  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 756  * single cache line on all modern x86 implementations.
 757  */
 758         .section .init.rodata,"a"
 759 ENTRY(interrupt)
 760         .text
 761         .p2align 5
 762         .p2align CONFIG_X86_L1_CACHE_SHIFT
 763 ENTRY(irq_entries_start)
 764         INTR_FRAME
 765 vector=FIRST_EXTERNAL_VECTOR
 766 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 767         .balign 32
 768   .rept 7
 769     .if vector < NR_VECTORS
 770       .if vector <> FIRST_EXTERNAL_VECTOR
 771         CFI_ADJUST_CFA_OFFSET -8
 772       .endif
 773 1:      pushq $(~vector+0x80)   /* Note: always in signed byte range */
 774         CFI_ADJUST_CFA_OFFSET 8
 775       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 776         jmp 2f
 777       .endif
 778       .previous
 779         .quad 1b
 780       .text
 781 vector=vector+1
 782     .endif
 783   .endr
 784 2:      jmp common_interrupt
 785 .endr
 786         CFI_ENDPROC
 787 END(irq_entries_start)
 788
 789 .previous
 790 END(interrupt)
 791 .previous
 792
 793 /*
 794  * Interrupt entry/exit.
 795  *
 796  * Interrupt entry points save only callee clobbered registers in fast path.
 797  *
 798  * Entry runs with interrupts off.
 799  */
 800
 801 /* 0(%rsp): ~(interrupt number) */
 802         .macro interrupt func
 803         subq $10*8, %rsp
 804         CFI_ADJUST_CFA_OFFSET 10*8
 805         call save_args
 806         PARTIAL_FRAME 0
 807         call \func
 808         .endm
 809
 810         /*
 811          * The interrupt stubs push (~vector+0x80) onto the stack and
 812          * then jump to common_interrupt.
 813          */
 814         .p2align CONFIG_X86_L1_CACHE_SHIFT
 815 common_interrupt:
 816         XCPT_FRAME
 817         addq $-0x80,(%rsp)              /* Adjust vector to [-256,-1] range */
 818         interrupt do_IRQ
 819         /* 0(%rsp): old_rsp-ARGOFFSET */
 820 ret_from_intr:
 821         DISABLE_INTERRUPTS(CLBR_NONE)
 822         TRACE_IRQS_OFF
 823         decl PER_CPU_VAR(irq_count)
 824         leaveq
 825         CFI_DEF_CFA_REGISTER    rsp
 826         CFI_ADJUST_CFA_OFFSET   -8
 827 exit_intr:
 828         GET_THREAD_INFO(%rcx)
 829         testl $3,CS-ARGOFFSET(%rsp)
 830         je retint_kernel
 831
 832         /* Interrupt came from user space */
 833         /*
 834          * Has a correct top of stack, but a partial stack frame
 835          * %rcx: thread info. Interrupts off.
 836          */
 837 retint_with_reschedule:
 838         movl $_TIF_WORK_MASK,%edi
 839 retint_check:
 840         LOCKDEP_SYS_EXIT_IRQ
 841         movl TI_flags(%rcx),%edx
 842         andl %edi,%edx
 843         CFI_REMEMBER_STATE
 844         jnz  retint_careful
 845
 846 retint_swapgs:          /* return to user-space */
 847         /*
 848          * The iretq could re-enable interrupts:
 849          */
 850         DISABLE_INTERRUPTS(CLBR_ANY)
 851         TRACE_IRQS_IRETQ
 852         SWAPGS
 853         jmp restore_args
 854
 855 retint_restore_args:    /* return to kernel space */
 856         DISABLE_INTERRUPTS(CLBR_ANY)
 857         /*
 858          * The iretq could re-enable interrupts:
 859          */
 860         TRACE_IRQS_IRETQ
 861 restore_args:
 862         RESTORE_ARGS 0,8,0
 863
 864 irq_return:
 865         INTERRUPT_RETURN
 866
 867         .section __ex_table, "a"
 868         .quad irq_return, bad_iret
 869         .previous
 870
 871 #ifdef CONFIG_PARAVIRT
 872 ENTRY(native_iret)
 873         iretq
 874
 875         .section __ex_table,"a"
 876         .quad native_iret, bad_iret
 877         .previous
 878 #endif
 879
 880         .section .fixup,"ax"
 881 bad_iret:
 882         /*
 883          * The iret traps when the %cs or %ss being restored is bogus.
 884          * We've lost the original trap vector and error code.
 885          * #GPF is the most likely one to get for an invalid selector.
 886          * So pretend we completed the iret and took the #GPF in user mode.
 887          *
 888          * We are now running with the kernel GS after exception recovery.
 889          * But error_entry expects us to have user GS to match the user %cs,
 890          * so swap back.
 891          */
 892         pushq $0
 893
 894         SWAPGS
 895         jmp general_protection
 896
 897         .previous
 898
 899         /* edi: workmask, edx: work */
 900 retint_careful:
 901         CFI_RESTORE_STATE
 902         bt    $TIF_NEED_RESCHED,%edx
 903         jnc   retint_signal
 904         TRACE_IRQS_ON
 905         ENABLE_INTERRUPTS(CLBR_NONE)
 906         pushq %rdi
 907         CFI_ADJUST_CFA_OFFSET   8
 908         call  schedule
 909         popq %rdi
 910         CFI_ADJUST_CFA_OFFSET   -8
 911         GET_THREAD_INFO(%rcx)
 912         DISABLE_INTERRUPTS(CLBR_NONE)
 913         TRACE_IRQS_OFF
 914         jmp retint_check
 915
 916 retint_signal:
 917         testl $_TIF_DO_NOTIFY_MASK,%edx
 918         jz    retint_swapgs
 919         TRACE_IRQS_ON
 920         ENABLE_INTERRUPTS(CLBR_NONE)
 921         SAVE_REST
 922         movq $-1,ORIG_RAX(%rsp)
 923         xorl %esi,%esi          # oldset
 924         movq %rsp,%rdi          # &pt_regs
 925         call do_notify_resume
 926         RESTORE_REST
 927         DISABLE_INTERRUPTS(CLBR_NONE)
 928         TRACE_IRQS_OFF
 929         GET_THREAD_INFO(%rcx)
 930         jmp retint_with_reschedule
 931
 932 #ifdef CONFIG_PREEMPT
 933         /* Returning to kernel space. Check if we need preemption */
 934         /* rcx:  threadinfo. interrupts off. */
 935 ENTRY(retint_kernel)
 936         cmpl $0,TI_preempt_count(%rcx)
 937         jnz  retint_restore_args
 938         bt  $TIF_NEED_RESCHED,TI_flags(%rcx)
 939         jnc  retint_restore_args
 940         bt   $9,EFLAGS-ARGOFFSET(%rsp)  /* interrupts off? */
 941         jnc  retint_restore_args
 942         call preempt_schedule_irq
 943         jmp exit_intr
 944 #endif
 945
 946         CFI_ENDPROC
 947 END(common_interrupt)
 948
 949 /*
 950  * APIC interrupts.
 951  */
 952 .macro apicinterrupt num sym do_sym
 953 ENTRY(\sym)
 954         INTR_FRAME
 955         pushq $~(\num)
 956         CFI_ADJUST_CFA_OFFSET 8
 957         interrupt \do_sym
 958         jmp ret_from_intr
 959         CFI_ENDPROC
 960 END(\sym)
 961 .endm
 962
 963 #ifdef CONFIG_SMP
 964 apicinterrupt IRQ_MOVE_CLEANUP_VECTOR \
 965         irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
 966 apicinterrupt REBOOT_VECTOR \
 967         reboot_interrupt smp_reboot_interrupt
 968 #endif
 969
 970 #ifdef CONFIG_X86_UV
 971 apicinterrupt UV_BAU_MESSAGE \
 972         uv_bau_message_intr1 uv_bau_message_interrupt
 973 #endif
 974 apicinterrupt LOCAL_TIMER_VECTOR \
 975         apic_timer_interrupt smp_apic_timer_interrupt
 976 apicinterrupt GENERIC_INTERRUPT_VECTOR \
 977         generic_interrupt smp_generic_interrupt
 978
 979 #ifdef CONFIG_SMP
 980 apicinterrupt INVALIDATE_TLB_VECTOR_START+0 \
 981         invalidate_interrupt0 smp_invalidate_interrupt
 982 apicinterrupt INVALIDATE_TLB_VECTOR_START+1 \
 983         invalidate_interrupt1 smp_invalidate_interrupt
 984 apicinterrupt INVALIDATE_TLB_VECTOR_START+2 \
 985         invalidate_interrupt2 smp_invalidate_interrupt
 986 apicinterrupt INVALIDATE_TLB_VECTOR_START+3 \
 987         invalidate_interrupt3 smp_invalidate_interrupt
 988 apicinterrupt INVALIDATE_TLB_VECTOR_START+4 \
 989         invalidate_interrupt4 smp_invalidate_interrupt
 990 apicinterrupt INVALIDATE_TLB_VECTOR_START+5 \
 991         invalidate_interrupt5 smp_invalidate_interrupt
 992 apicinterrupt INVALIDATE_TLB_VECTOR_START+6 \
 993         invalidate_interrupt6 smp_invalidate_interrupt
 994 apicinterrupt INVALIDATE_TLB_VECTOR_START+7 \
 995         invalidate_interrupt7 smp_invalidate_interrupt
 996 #endif
 997
 998 apicinterrupt THRESHOLD_APIC_VECTOR \
 999         threshold_interrupt smp_threshold_interrupt
1000 apicinterrupt THERMAL_APIC_VECTOR \
1001         thermal_interrupt smp_thermal_interrupt
1002
1003 #ifdef CONFIG_X86_MCE
1004 apicinterrupt MCE_SELF_VECTOR \
1005         mce_self_interrupt smp_mce_self_interrupt
1006 #endif
1007
1008 #ifdef CONFIG_SMP
1009 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
1010         call_function_single_interrupt smp_call_function_single_interrupt
1011 apicinterrupt CALL_FUNCTION_VECTOR \
1012         call_function_interrupt smp_call_function_interrupt
1013 apicinterrupt RESCHEDULE_VECTOR \
1014         reschedule_interrupt smp_reschedule_interrupt
1015 #endif
1016
1017 apicinterrupt ERROR_APIC_VECTOR \
1018         error_interrupt smp_error_interrupt
1019 apicinterrupt SPURIOUS_APIC_VECTOR \
1020         spurious_interrupt smp_spurious_interrupt
1021
1022 #ifdef CONFIG_PERF_COUNTERS
1023 apicinterrupt LOCAL_PENDING_VECTOR \
1024         perf_pending_interrupt smp_perf_pending_interrupt
1025 #endif
1026
1027 /*
1028  * Exception entry points.
1029  */
1030 .macro zeroentry sym do_sym
1031 ENTRY(\sym)
1032         INTR_FRAME
1033         PARAVIRT_ADJUST_EXCEPTION_FRAME
1034         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1035         subq $15*8,%rsp
1036         CFI_ADJUST_CFA_OFFSET 15*8
1037         call error_entry
1038         DEFAULT_FRAME 0
1039         movq %rsp,%rdi          /* pt_regs pointer */
1040         xorl %esi,%esi          /* no error code */
1041         call \do_sym
1042         jmp error_exit          /* %ebx: no swapgs flag */
1043         CFI_ENDPROC
1044 END(\sym)
1045 .endm
1046
1047 .macro paranoidzeroentry sym do_sym
1048 ENTRY(\sym)
1049         INTR_FRAME
1050         PARAVIRT_ADJUST_EXCEPTION_FRAME
1051         pushq $-1               /* ORIG_RAX: no syscall to restart */
1052         CFI_ADJUST_CFA_OFFSET 8
1053         subq $15*8, %rsp
1054         call save_paranoid
1055         TRACE_IRQS_OFF
1056         movq %rsp,%rdi          /* pt_regs pointer */
1057         xorl %esi,%esi          /* no error code */
1058         call \do_sym
1059         jmp paranoid_exit       /* %ebx: no swapgs flag */
1060         CFI_ENDPROC
1061 END(\sym)
1062 .endm
1063
1064 .macro paranoidzeroentry_ist sym do_sym ist
1065 ENTRY(\sym)
1066         INTR_FRAME
1067         PARAVIRT_ADJUST_EXCEPTION_FRAME
1068         pushq $-1               /* ORIG_RAX: no syscall to restart */
1069         CFI_ADJUST_CFA_OFFSET 8
1070         subq $15*8, %rsp
1071         call save_paranoid
1072         TRACE_IRQS_OFF
1073         movq %rsp,%rdi          /* pt_regs pointer */
1074         xorl %esi,%esi          /* no error code */
1075         PER_CPU(init_tss, %rbp)
1076         subq $EXCEPTION_STKSZ, TSS_ist + (\ist - 1) * 8(%rbp)
1077         call \do_sym
1078         addq $EXCEPTION_STKSZ, TSS_ist + (\ist - 1) * 8(%rbp)
1079         jmp paranoid_exit       /* %ebx: no swapgs flag */
1080         CFI_ENDPROC
1081 END(\sym)
1082 .endm
1083
1084 .macro errorentry sym do_sym
1085 ENTRY(\sym)
1086         XCPT_FRAME
1087         PARAVIRT_ADJUST_EXCEPTION_FRAME
1088         subq $15*8,%rsp
1089         CFI_ADJUST_CFA_OFFSET 15*8
1090         call error_entry
1091         DEFAULT_FRAME 0
1092         movq %rsp,%rdi                  /* pt_regs pointer */
1093         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1094         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1095         call \do_sym
1096         jmp error_exit                  /* %ebx: no swapgs flag */
1097         CFI_ENDPROC
1098 END(\sym)
1099 .endm
1100
1101         /* error code is on the stack already */
1102 .macro paranoiderrorentry sym do_sym
1103 ENTRY(\sym)
1104         XCPT_FRAME
1105         PARAVIRT_ADJUST_EXCEPTION_FRAME
1106         subq $15*8,%rsp
1107         CFI_ADJUST_CFA_OFFSET 15*8
1108         call save_paranoid
1109         DEFAULT_FRAME 0
1110         TRACE_IRQS_OFF
1111         movq %rsp,%rdi                  /* pt_regs pointer */
1112         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1113         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1114         call \do_sym
1115         jmp paranoid_exit               /* %ebx: no swapgs flag */
1116         CFI_ENDPROC
1117 END(\sym)
1118 .endm
1119
1120 zeroentry divide_error do_divide_error
1121 zeroentry overflow do_overflow
1122 zeroentry bounds do_bounds
1123 zeroentry invalid_op do_invalid_op
1124 zeroentry device_not_available do_device_not_available
1125 paranoiderrorentry double_fault do_double_fault
1126 zeroentry coprocessor_segment_overrun do_coprocessor_segment_overrun
1127 errorentry invalid_TSS do_invalid_TSS
1128 errorentry segment_not_present do_segment_not_present
1129 zeroentry spurious_interrupt_bug do_spurious_interrupt_bug
1130 zeroentry coprocessor_error do_coprocessor_error
1131 errorentry alignment_check do_alignment_check
1132 zeroentry simd_coprocessor_error do_simd_coprocessor_error
1133
1134         /* Reload gs selector with exception handling */
1135         /* edi:  new selector */
1136 ENTRY(native_load_gs_index)
1137         CFI_STARTPROC
1138         pushf
1139         CFI_ADJUST_CFA_OFFSET 8
1140         DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
1141         SWAPGS
1142 gs_change:
1143         movl %edi,%gs
1144 2:      mfence          /* workaround */
1145         SWAPGS
1146         popf
1147         CFI_ADJUST_CFA_OFFSET -8
1148         ret
1149         CFI_ENDPROC
1150 END(native_load_gs_index)
1151
1152         .section __ex_table,"a"
1153         .align 8
1154         .quad gs_change,bad_gs
1155         .previous
1156         .section .fixup,"ax"
1157         /* running with kernelgs */
1158 bad_gs:
1159         SWAPGS                  /* switch back to user gs */
1160         xorl %eax,%eax
1161         movl %eax,%gs
1162         jmp  2b
1163         .previous
1164
1165 /*
1166  * Create a kernel thread.
1167  *
1168  * C extern interface:
1169  *      extern long kernel_thread(int (*fn)(void *), void * arg, unsigned long flags)
1170  *
1171  * asm input arguments:
1172  *      rdi: fn, rsi: arg, rdx: flags
1173  */
1174 ENTRY(kernel_thread)
1175         CFI_STARTPROC
1176         FAKE_STACK_FRAME $child_rip
1177         SAVE_ALL
1178
1179         # rdi: flags, rsi: usp, rdx: will be &pt_regs
1180         movq %rdx,%rdi
1181         orq  kernel_thread_flags(%rip),%rdi
1182         movq $-1, %rsi
1183         movq %rsp, %rdx
1184
1185         xorl %r8d,%r8d
1186         xorl %r9d,%r9d
1187
1188         # clone now
1189         call do_fork
1190         movq %rax,RAX(%rsp)
1191         xorl %edi,%edi
1192
1193         /*
1194          * It isn't worth to check for reschedule here,
1195          * so internally to the x86_64 port you can rely on kernel_thread()
1196          * not to reschedule the child before returning, this avoids the need
1197          * of hacks for example to fork off the per-CPU idle tasks.
1198          * [Hopefully no generic code relies on the reschedule -AK]
1199          */
1200         RESTORE_ALL
1201         UNFAKE_STACK_FRAME
1202         ret
1203         CFI_ENDPROC
1204 END(kernel_thread)
1205
1206 ENTRY(child_rip)
1207         pushq $0                # fake return address
1208         CFI_STARTPROC
1209         /*
1210          * Here we are in the child and the registers are set as they were
1211          * at kernel_thread() invocation in the parent.
1212          */
1213         movq %rdi, %rax
1214         movq %rsi, %rdi
1215         call *%rax
1216         # exit
1217         mov %eax, %edi
1218         call do_exit
1219         ud2                     # padding for call trace
1220         CFI_ENDPROC
1221 END(child_rip)
1222
1223 /*
1224  * execve(). This function needs to use IRET, not SYSRET, to set up all state properly.
1225  *
1226  * C extern interface:
1227  *       extern long execve(char *name, char **argv, char **envp)
1228  *
1229  * asm input arguments:
1230  *      rdi: name, rsi: argv, rdx: envp
1231  *
1232  * We want to fallback into:
1233  *      extern long sys_execve(char *name, char **argv,char **envp, struct pt_regs *regs)
1234  *
1235  * do_sys_execve asm fallback arguments:
1236  *      rdi: name, rsi: argv, rdx: envp, rcx: fake frame on the stack
1237  */
1238 ENTRY(kernel_execve)
1239         CFI_STARTPROC
1240         FAKE_STACK_FRAME $0
1241         SAVE_ALL
1242         movq %rsp,%rcx
1243         call sys_execve
1244         movq %rax, RAX(%rsp)
1245         RESTORE_REST
1246         testq %rax,%rax
1247         je int_ret_from_sys_call
1248         RESTORE_ARGS
1249         UNFAKE_STACK_FRAME
1250         ret
1251         CFI_ENDPROC
1252 END(kernel_execve)
1253
1254 /* Call softirq on interrupt stack. Interrupts are off. */
1255 ENTRY(call_softirq)
1256         CFI_STARTPROC
1257         push %rbp
1258         CFI_ADJUST_CFA_OFFSET   8
1259         CFI_REL_OFFSET rbp,0
1260         mov  %rsp,%rbp
1261         CFI_DEF_CFA_REGISTER rbp
1262         incl PER_CPU_VAR(irq_count)
1263         cmove PER_CPU_VAR(irq_stack_ptr),%rsp
1264         push  %rbp                      # backlink for old unwinder
1265         call __do_softirq
1266         leaveq
1267         CFI_DEF_CFA_REGISTER    rsp
1268         CFI_ADJUST_CFA_OFFSET   -8
1269         decl PER_CPU_VAR(irq_count)
1270         ret
1271         CFI_ENDPROC
1272 END(call_softirq)
1273
1274 #ifdef CONFIG_XEN
1275 zeroentry xen_hypervisor_callback xen_do_hypervisor_callback
1276
1277 /*
1278  * A note on the "critical region" in our callback handler.
1279  * We want to avoid stacking callback handlers due to events occurring
1280  * during handling of the last event. To do this, we keep events disabled
1281  * until we've done all processing. HOWEVER, we must enable events before
1282  * popping the stack frame (can't be done atomically) and so it would still
1283  * be possible to get enough handler activations to overflow the stack.
1284  * Although unlikely, bugs of that kind are hard to track down, so we'd
1285  * like to avoid the possibility.
1286  * So, on entry to the handler we detect whether we interrupted an
1287  * existing activation in its critical region -- if so, we pop the current
1288  * activation and restart the handler using the previous one.
1289  */
1290 ENTRY(xen_do_hypervisor_callback)   # do_hypervisor_callback(struct *pt_regs)
1291         CFI_STARTPROC
1292 /*
1293  * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1294  * see the correct pointer to the pt_regs
1295  */
1296         movq %rdi, %rsp            # we don't return, adjust the stack frame
1297         CFI_ENDPROC
1298         DEFAULT_FRAME
1299 11:     incl PER_CPU_VAR(irq_count)
1300         movq %rsp,%rbp
1301         CFI_DEF_CFA_REGISTER rbp
1302         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
1303         pushq %rbp                      # backlink for old unwinder
1304         call xen_evtchn_do_upcall
1305         popq %rsp
1306         CFI_DEF_CFA_REGISTER rsp
1307         decl PER_CPU_VAR(irq_count)
1308         jmp  error_exit
1309         CFI_ENDPROC
1310 END(do_hypervisor_callback)
1311
1312 /*
1313  * Hypervisor uses this for application faults while it executes.
1314  * We get here for two reasons:
1315  *  1. Fault while reloading DS, ES, FS or GS
1316  *  2. Fault while executing IRET
1317  * Category 1 we do not need to fix up as Xen has already reloaded all segment
1318  * registers that could be reloaded and zeroed the others.
1319  * Category 2 we fix up by killing the current process. We cannot use the
1320  * normal Linux return path in this case because if we use the IRET hypercall
1321  * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1322  * We distinguish between categories by comparing each saved segment register
1323  * with its current contents: any discrepancy means we in category 1.
1324  */
1325 ENTRY(xen_failsafe_callback)
1326         INTR_FRAME 1 (6*8)
1327         /*CFI_REL_OFFSET gs,GS*/
1328         /*CFI_REL_OFFSET fs,FS*/
1329         /*CFI_REL_OFFSET es,ES*/
1330         /*CFI_REL_OFFSET ds,DS*/
1331         CFI_REL_OFFSET r11,8
1332         CFI_REL_OFFSET rcx,0
1333         movw %ds,%cx
1334         cmpw %cx,0x10(%rsp)
1335         CFI_REMEMBER_STATE
1336         jne 1f
1337         movw %es,%cx
1338         cmpw %cx,0x18(%rsp)
1339         jne 1f
1340         movw %fs,%cx
1341         cmpw %cx,0x20(%rsp)
1342         jne 1f
1343         movw %gs,%cx
1344         cmpw %cx,0x28(%rsp)
1345         jne 1f
1346         /* All segments match their saved values => Category 2 (Bad IRET). */
1347         movq (%rsp),%rcx
1348         CFI_RESTORE rcx
1349         movq 8(%rsp),%r11
1350         CFI_RESTORE r11
1351         addq $0x30,%rsp
1352         CFI_ADJUST_CFA_OFFSET -0x30
1353         pushq_cfi $0    /* RIP */
1354         pushq_cfi %r11
1355         pushq_cfi %rcx
1356         jmp general_protection
1357         CFI_RESTORE_STATE
1358 1:      /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1359         movq (%rsp),%rcx
1360         CFI_RESTORE rcx
1361         movq 8(%rsp),%r11
1362         CFI_RESTORE r11
1363         addq $0x30,%rsp
1364         CFI_ADJUST_CFA_OFFSET -0x30
1365         pushq_cfi $0
1366         SAVE_ALL
1367         jmp error_exit
1368         CFI_ENDPROC
1369 END(xen_failsafe_callback)
1370
1371 #endif /* CONFIG_XEN */
1372
1373 /*
1374  * Some functions should be protected against kprobes
1375  */
1376         .pushsection .kprobes.text, "ax"
1377
1378 paranoidzeroentry_ist debug do_debug DEBUG_STACK
1379 paranoidzeroentry_ist int3 do_int3 DEBUG_STACK
1380 paranoiderrorentry stack_segment do_stack_segment
1381 #ifdef CONFIG_XEN
1382 zeroentry xen_debug do_debug
1383 zeroentry xen_int3 do_int3
1384 errorentry xen_stack_segment do_stack_segment
1385 #endif
1386 errorentry general_protection do_general_protection
1387 errorentry page_fault do_page_fault
1388 #ifdef CONFIG_X86_MCE
1389 paranoidzeroentry machine_check *machine_check_vector(%rip)
1390 #endif
1391
1392         /*
1393          * "Paranoid" exit path from exception stack.
1394          * Paranoid because this is used by NMIs and cannot take
1395          * any kernel state for granted.
1396          * We don't do kernel preemption checks here, because only
1397          * NMI should be common and it does not enable IRQs and
1398          * cannot get reschedule ticks.
1399          *
1400          * "trace" is 0 for the NMI handler only, because irq-tracing
1401          * is fundamentally NMI-unsafe. (we cannot change the soft and
1402          * hard flags at once, atomically)
1403          */
1404
1405         /* ebx: no swapgs flag */
1406 ENTRY(paranoid_exit)
1407         INTR_FRAME
1408         DISABLE_INTERRUPTS(CLBR_NONE)
1409         TRACE_IRQS_OFF
1410         testl %ebx,%ebx                         /* swapgs needed? */
1411         jnz paranoid_restore
1412         testl $3,CS(%rsp)
1413         jnz   paranoid_userspace
1414 paranoid_swapgs:
1415         TRACE_IRQS_IRETQ 0
1416         SWAPGS_UNSAFE_STACK
1417         RESTORE_ALL 8
1418         jmp irq_return
1419 paranoid_restore:
1420         TRACE_IRQS_IRETQ 0
1421         RESTORE_ALL 8
1422         jmp irq_return
1423 paranoid_userspace:
1424         GET_THREAD_INFO(%rcx)
1425         movl TI_flags(%rcx),%ebx
1426         andl $_TIF_WORK_MASK,%ebx
1427         jz paranoid_swapgs
1428         movq %rsp,%rdi                  /* &pt_regs */
1429         call sync_regs
1430         movq %rax,%rsp                  /* switch stack for scheduling */
1431         testl $_TIF_NEED_RESCHED,%ebx
1432         jnz paranoid_schedule
1433         movl %ebx,%edx                  /* arg3: thread flags */
1434         TRACE_IRQS_ON
1435         ENABLE_INTERRUPTS(CLBR_NONE)
1436         xorl %esi,%esi                  /* arg2: oldset */
1437         movq %rsp,%rdi                  /* arg1: &pt_regs */
1438         call do_notify_resume
1439         DISABLE_INTERRUPTS(CLBR_NONE)
1440         TRACE_IRQS_OFF
1441         jmp paranoid_userspace
1442 paranoid_schedule:
1443         TRACE_IRQS_ON
1444         ENABLE_INTERRUPTS(CLBR_ANY)
1445         call schedule
1446         DISABLE_INTERRUPTS(CLBR_ANY)
1447         TRACE_IRQS_OFF
1448         jmp paranoid_userspace
1449         CFI_ENDPROC
1450 END(paranoid_exit)
1451
1452 /*
1453  * Exception entry point. This expects an error code/orig_rax on the stack.
1454  * returns in "no swapgs flag" in %ebx.
1455  */
1456 ENTRY(error_entry)
1457         XCPT_FRAME
1458         CFI_ADJUST_CFA_OFFSET 15*8
1459         /* oldrax contains error code */
1460         cld
1461         movq_cfi rdi, RDI+8
1462         movq_cfi rsi, RSI+8
1463         movq_cfi rdx, RDX+8
1464         movq_cfi rcx, RCX+8
1465         movq_cfi rax, RAX+8
1466         movq_cfi  r8,  R8+8
1467         movq_cfi  r9,  R9+8
1468         movq_cfi r10, R10+8
1469         movq_cfi r11, R11+8
1470         movq_cfi rbx, RBX+8
1471         movq_cfi rbp, RBP+8
1472         movq_cfi r12, R12+8
1473         movq_cfi r13, R13+8
1474         movq_cfi r14, R14+8
1475         movq_cfi r15, R15+8
1476         xorl %ebx,%ebx
1477         testl $3,CS+8(%rsp)
1478         je error_kernelspace
1479 error_swapgs:
1480         SWAPGS
1481 error_sti:
1482         TRACE_IRQS_OFF
1483         ret
1484         CFI_ENDPROC
1485
1486 /*
1487  * There are two places in the kernel that can potentially fault with
1488  * usergs. Handle them here. The exception handlers after iret run with
1489  * kernel gs again, so don't set the user space flag. B stepping K8s
1490  * sometimes report an truncated RIP for IRET exceptions returning to
1491  * compat mode. Check for these here too.
1492  */
1493 error_kernelspace:
1494         incl %ebx
1495         leaq irq_return(%rip),%rcx
1496         cmpq %rcx,RIP+8(%rsp)
1497         je error_swapgs
1498         movl %ecx,%ecx  /* zero extend */
1499         cmpq %rcx,RIP+8(%rsp)
1500         je error_swapgs
1501         cmpq $gs_change,RIP+8(%rsp)
1502         je error_swapgs
1503         jmp error_sti
1504 END(error_entry)
1505
1506
1507 /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1508 ENTRY(error_exit)
1509         DEFAULT_FRAME
1510         movl %ebx,%eax
1511         RESTORE_REST
1512         DISABLE_INTERRUPTS(CLBR_NONE)
1513         TRACE_IRQS_OFF
1514         GET_THREAD_INFO(%rcx)
1515         testl %eax,%eax
1516         jne retint_kernel
1517         LOCKDEP_SYS_EXIT_IRQ
1518         movl TI_flags(%rcx),%edx
1519         movl $_TIF_WORK_MASK,%edi
1520         andl %edi,%edx
1521         jnz retint_careful
1522         jmp retint_swapgs
1523         CFI_ENDPROC
1524 END(error_exit)
1525
1526
1527         /* runs on exception stack */
1528 ENTRY(nmi)
1529         INTR_FRAME
1530         PARAVIRT_ADJUST_EXCEPTION_FRAME
1531         pushq_cfi $-1
1532         subq $15*8, %rsp
1533         CFI_ADJUST_CFA_OFFSET 15*8
1534         call save_paranoid
1535         DEFAULT_FRAME 0
1536         /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1537         movq %rsp,%rdi
1538         movq $-1,%rsi
1539         call do_nmi
1540 #ifdef CONFIG_TRACE_IRQFLAGS
1541         /* paranoidexit; without TRACE_IRQS_OFF */
1542         /* ebx: no swapgs flag */
1543         DISABLE_INTERRUPTS(CLBR_NONE)
1544         testl %ebx,%ebx                         /* swapgs needed? */
1545         jnz nmi_restore
1546         testl $3,CS(%rsp)
1547         jnz nmi_userspace
1548 nmi_swapgs:
1549         SWAPGS_UNSAFE_STACK
1550 nmi_restore:
1551         RESTORE_ALL 8
1552         jmp irq_return
1553 nmi_userspace:
1554         GET_THREAD_INFO(%rcx)
1555         movl TI_flags(%rcx),%ebx
1556         andl $_TIF_WORK_MASK,%ebx
1557         jz nmi_swapgs
1558         movq %rsp,%rdi                  /* &pt_regs */
1559         call sync_regs
1560         movq %rax,%rsp                  /* switch stack for scheduling */
1561         testl $_TIF_NEED_RESCHED,%ebx
1562         jnz nmi_schedule
1563         movl %ebx,%edx                  /* arg3: thread flags */
1564         ENABLE_INTERRUPTS(CLBR_NONE)
1565         xorl %esi,%esi                  /* arg2: oldset */
1566         movq %rsp,%rdi                  /* arg1: &pt_regs */
1567         call do_notify_resume
1568         DISABLE_INTERRUPTS(CLBR_NONE)
1569         jmp nmi_userspace
1570 nmi_schedule:
1571         ENABLE_INTERRUPTS(CLBR_ANY)
1572         call schedule
1573         DISABLE_INTERRUPTS(CLBR_ANY)
1574         jmp nmi_userspace
1575         CFI_ENDPROC
1576 #else
1577         jmp paranoid_exit
1578         CFI_ENDPROC
1579 #endif
1580 END(nmi)
1581
1582 ENTRY(ignore_sysret)
1583         CFI_STARTPROC
1584         mov $-ENOSYS,%eax
1585         sysret
1586         CFI_ENDPROC
1587 END(ignore_sysret)
1588
1589 /*
1590  * End of kprobes section
1591  */
1592         .popsection