git.oblomov.eu Git - linux-2.6/blob - arch/i386/boot/setup.S

   1 /*
   2  *      setup.S         Copyright (C) 1991, 1992 Linus Torvalds
   3  *
   4  * setup.s is responsible for getting the system data from the BIOS,
   5  * and putting them into the appropriate places in system memory.
   6  * both setup.s and system has been loaded by the bootblock.
   7  *
   8  * This code asks the bios for memory/disk/other parameters, and
   9  * puts them in a "safe" place: 0x90000-0x901FF, ie where the
  10  * boot-block used to be. It is then up to the protected mode
  11  * system to read them from there before the area is overwritten
  12  * for buffer-blocks.
  13  *
  14  * Move PS/2 aux init code to psaux.c
  15  * (troyer@saifr00.cfsat.Honeywell.COM) 03Oct92
  16  *
  17  * some changes and additional features by Christoph Niemann,
  18  * March 1993/June 1994 (Christoph.Niemann@linux.org)
  19  *
  20  * add APM BIOS checking by Stephen Rothwell, May 1994
  21  * (sfr@canb.auug.org.au)
  22  *
  23  * High load stuff, initrd support and position independency
  24  * by Hans Lermen & Werner Almesberger, February 1996
  25  * <lermen@elserv.ffm.fgan.de>, <almesber@lrc.epfl.ch>
  26  *
  27  * Video handling moved to video.S by Martin Mares, March 1996
  28  * <mj@k332.feld.cvut.cz>
  29  *
  30  * Extended memory detection scheme retwiddled by orc@pell.chi.il.us (david
  31  * parsons) to avoid loadlin confusion, July 1997
  32  *
  33  * Transcribed from Intel (as86) -> AT&T (gas) by Chris Noe, May 1999.
  34  * <stiker@northlink.com>
  35  *
  36  * Fix to work around buggy BIOSes which don't use carry bit correctly
  37  * and/or report extended memory in CX/DX for e801h memory size detection
  38  * call.  As a result the kernel got wrong figures.  The int15/e801h docs
  39  * from Ralf Brown interrupt list seem to indicate AX/BX should be used
  40  * anyway.  So to avoid breaking many machines (presumably there was a reason
  41  * to orginally use CX/DX instead of AX/BX), we do a kludge to see
  42  * if CX/DX have been changed in the e801 call and if so use AX/BX .
  43  * Michael Miller, April 2001 <michaelm@mjmm.org>
  44  *
  45  * New A20 code ported from SYSLINUX by H. Peter Anvin. AMD Elan bugfixes
  46  * by Robert Schwebel, December 2001 <robert@schwebel.de>
  47  */
  48
  49 #include <asm/segment.h>
  50 #include <linux/utsrelease.h>
  51 #include <linux/compile.h>
  52 #include <asm/boot.h>
  53 #include <asm/e820.h>
  54 #include <asm/page.h>
  55 #include <asm/setup.h>
  56
  57 /* Signature words to ensure LILO loaded us right */
  58 #define SIG1    0xAA55
  59 #define SIG2    0x5A5A
  60
  61 INITSEG  = DEF_INITSEG          # 0x9000, we move boot here, out of the way
  62 SYSSEG   = DEF_SYSSEG           # 0x1000, system loaded at 0x10000 (65536).
  63 SETUPSEG = DEF_SETUPSEG         # 0x9020, this is the current segment
  64                                 # ... and the former contents of CS
  65
  66 DELTA_INITSEG = SETUPSEG - INITSEG      # 0x0020
  67
  68 .code16
  69 .globl begtext, begdata, begbss, endtext, enddata, endbss
  70
  71 .text
  72 begtext:
  73 .data
  74 begdata:
  75 .bss
  76 begbss:
  77 .text
  78
  79 start:
  80         jmp     trampoline
  81
  82 # This is the setup header, and it must start at %cs:2 (old 0x9020:2)
  83
  84                 .ascii  "HdrS"          # header signature
  85                 .word   0x0206          # header version number (>= 0x0105)
  86                                         # or else old loadlin-1.5 will fail)
  87 realmode_swtch: .word   0, 0            # default_switch, SETUPSEG
  88 start_sys_seg:  .word   SYSSEG
  89                 .word   kernel_version  # pointing to kernel version string
  90                                         # above section of header is compatible
  91                                         # with loadlin-1.5 (header v1.5). Don't
  92                                         # change it.
  93
  94 type_of_loader: .byte   0               # = 0, old one (LILO, Loadlin,
  95                                         #      Bootlin, SYSLX, bootsect...)
  96                                         # See Documentation/i386/boot.txt for
  97                                         # assigned ids
  98
  99 # flags, unused bits must be zero (RFU) bit within loadflags
 100 loadflags:
 101 LOADED_HIGH     = 1                     # If set, the kernel is loaded high
 102 CAN_USE_HEAP    = 0x80                  # If set, the loader also has set
 103                                         # heap_end_ptr to tell how much
 104                                         # space behind setup.S can be used for
 105                                         # heap purposes.
 106                                         # Only the loader knows what is free
 107 #ifndef __BIG_KERNEL__
 108                 .byte   0
 109 #else
 110                 .byte   LOADED_HIGH
 111 #endif
 112
 113 setup_move_size: .word  0x8000          # size to move, when setup is not
 114                                         # loaded at 0x90000. We will move setup
 115                                         # to 0x90000 then just before jumping
 116                                         # into the kernel. However, only the
 117                                         # loader knows how much data behind
 118                                         # us also needs to be loaded.
 119
 120 code32_start:                           # here loaders can put a different
 121                                         # start address for 32-bit code.
 122 #ifndef __BIG_KERNEL__
 123                 .long   0x1000          #   0x1000 = default for zImage
 124 #else
 125                 .long   0x100000        # 0x100000 = default for big kernel
 126 #endif
 127
 128 ramdisk_image:  .long   0               # address of loaded ramdisk image
 129                                         # Here the loader puts the 32-bit
 130                                         # address where it loaded the image.
 131                                         # This only will be read by the kernel.
 132
 133 ramdisk_size:   .long   0               # its size in bytes
 134
 135 bootsect_kludge:
 136                 .long   0               # obsolete
 137
 138 heap_end_ptr:   .word   modelist+1024   # (Header version 0x0201 or later)
 139                                         # space from here (exclusive) down to
 140                                         # end of setup code can be used by setup
 141                                         # for local heap purposes.
 142
 143 pad1:           .word   0
 144 cmd_line_ptr:   .long 0                 # (Header version 0x0202 or later)
 145                                         # If nonzero, a 32-bit pointer
 146                                         # to the kernel command line.
 147                                         # The command line should be
 148                                         # located between the start of
 149                                         # setup and the end of low
 150                                         # memory (0xa0000), or it may
 151                                         # get overwritten before it
 152                                         # gets read.  If this field is
 153                                         # used, there is no longer
 154                                         # anything magical about the
 155                                         # 0x90000 segment; the setup
 156                                         # can be located anywhere in
 157                                         # low memory 0x10000 or higher.
 158
 159 ramdisk_max:    .long (-__PAGE_OFFSET-(512 << 20)-1) & 0x7fffffff
 160                                         # (Header version 0x0203 or later)
 161                                         # The highest safe address for
 162                                         # the contents of an initrd
 163
 164 kernel_alignment:  .long CONFIG_PHYSICAL_ALIGN  #physical addr alignment
 165                                                 #required for protected mode
 166                                                 #kernel
 167 #ifdef CONFIG_RELOCATABLE
 168 relocatable_kernel:    .byte 1
 169 #else
 170 relocatable_kernel:    .byte 0
 171 #endif
 172 pad2:                   .byte 0
 173 pad3:                   .word 0
 174
 175 cmdline_size:   .long   COMMAND_LINE_SIZE-1     #length of the command line,
 176                                                 #added with boot protocol
 177                                                 #version 2.06
 178
 179 trampoline:     call    start_of_setup
 180                 .align 16
 181                                         # The offset at this point is 0x240
 182                 .space  (0xeff-0x240+1) # E820 & EDD space (ending at 0xeff)
 183 # End of setup header #####################################################
 184
 185 start_of_setup:
 186 # Bootlin depends on this being done early
 187         movw    $0x01500, %ax
 188         movb    $0x81, %dl
 189         int     $0x13
 190
 191 #ifdef SAFE_RESET_DISK_CONTROLLER
 192 # Reset the disk controller.
 193         movw    $0x0000, %ax
 194         movb    $0x80, %dl
 195         int     $0x13
 196 #endif
 197
 198 # Set %ds = %cs, we know that SETUPSEG = %cs at this point
 199         movw    %cs, %ax                # aka SETUPSEG
 200         movw    %ax, %ds
 201 # Check signature at end of setup
 202         cmpw    $SIG1, setup_sig1
 203         jne     bad_sig
 204
 205         cmpw    $SIG2, setup_sig2
 206         jne     bad_sig
 207
 208         jmp     good_sig1
 209
 210 # Routine to print asciiz string at ds:si
 211 prtstr:
 212         lodsb
 213         andb    %al, %al
 214         jz      fin
 215
 216         call    prtchr
 217         jmp     prtstr
 218
 219 fin:    ret
 220
 221 # Space printing
 222 prtsp2: call    prtspc          # Print double space
 223 prtspc: movb    $0x20, %al      # Print single space (note: fall-thru)
 224
 225 # Part of above routine, this one just prints ascii al
 226 prtchr: pushw   %ax
 227         pushw   %cx
 228         movw    $7,%bx
 229         movw    $0x01, %cx
 230         movb    $0x0e, %ah
 231         int     $0x10
 232         popw    %cx
 233         popw    %ax
 234         ret
 235
 236 beep:   movb    $0x07, %al
 237         jmp     prtchr
 238
 239 no_sig_mess: .string    "No setup signature found ..."
 240
 241 good_sig1:
 242         jmp     good_sig
 243
 244 # We now have to find the rest of the setup code/data
 245 bad_sig:
 246         movw    %cs, %ax                        # SETUPSEG
 247         subw    $DELTA_INITSEG, %ax             # INITSEG
 248         movw    %ax, %ds
 249         xorb    %bh, %bh
 250         movb    (497), %bl                      # get setup sect from bootsect
 251         subw    $4, %bx                         # LILO loads 4 sectors of setup
 252         shlw    $8, %bx                         # convert to words (1sect=2^8 words)
 253         movw    %bx, %cx
 254         shrw    $3, %bx                         # convert to segment
 255         addw    $SYSSEG, %bx
 256         movw    %bx, %cs:start_sys_seg
 257 # Move rest of setup code/data to here
 258         movw    $2048, %di                      # four sectors loaded by LILO
 259         subw    %si, %si
 260         pushw   %cs
 261         popw    %es
 262         movw    $SYSSEG, %ax
 263         movw    %ax, %ds
 264         rep
 265         movsw
 266         movw    %cs, %ax                        # aka SETUPSEG
 267         movw    %ax, %ds
 268         cmpw    $SIG1, setup_sig1
 269         jne     no_sig
 270
 271         cmpw    $SIG2, setup_sig2
 272         jne     no_sig
 273
 274         jmp     good_sig
 275
 276 no_sig:
 277         lea     no_sig_mess, %si
 278         call    prtstr
 279
 280 no_sig_loop:
 281         hlt
 282         jmp     no_sig_loop
 283
 284 good_sig:
 285         movw    %cs, %ax                        # aka SETUPSEG
 286         subw    $DELTA_INITSEG, %ax             # aka INITSEG
 287         movw    %ax, %ds
 288 # Check if an old loader tries to load a big-kernel
 289         testb   $LOADED_HIGH, %cs:loadflags     # Do we have a big kernel?
 290         jz      loader_ok                       # No, no danger for old loaders.
 291
 292         cmpb    $0, %cs:type_of_loader          # Do we have a loader that
 293                                                 # can deal with us?
 294         jnz     loader_ok                       # Yes, continue.
 295
 296         pushw   %cs                             # No, we have an old loader,
 297         popw    %ds                             # die.
 298         lea     loader_panic_mess, %si
 299         call    prtstr
 300
 301         jmp     no_sig_loop
 302
 303 loader_panic_mess: .string "Wrong loader, giving up..."
 304
 305 # check minimum cpuid
 306 # we do this here because it is the last place we can actually
 307 # show a user visible error message. Later the video modus
 308 # might be already messed up.
 309 loader_ok:
 310         call verify_cpu
 311         testl  %eax,%eax
 312         jz      cpu_ok
 313         lea     cpu_panic_mess,%si
 314         call    prtstr
 315 1:      jmp     1b
 316
 317 cpu_panic_mess:
 318         .asciz  "PANIC: CPU too old for this kernel."
 319
 320 #include "../kernel/verify_cpu.S"
 321
 322 cpu_ok:
 323 # Get memory size (extended mem, kB)
 324
 325         xorl    %eax, %eax
 326         movl    %eax, (0x1e0)
 327 #ifndef STANDARD_MEMORY_BIOS_CALL
 328         movb    %al, (E820NR)
 329 # Try three different memory detection schemes.  First, try
 330 # e820h, which lets us assemble a memory map, then try e801h,
 331 # which returns a 32-bit memory size, and finally 88h, which
 332 # returns 0-64m
 333
 334 # method E820H:
 335 # the memory map from hell.  e820h returns memory classified into
 336 # a whole bunch of different types, and allows memory holes and
 337 # everything.  We scan through this memory map and build a list
 338 # of the first 32 memory areas, which we return at [E820MAP].
 339 # This is documented at http://www.acpi.info/, in the ACPI 2.0 specification.
 340
 341 #define SMAP  0x534d4150
 342
 343 meme820:
 344         xorl    %ebx, %ebx                      # continuation counter
 345         movw    $E820MAP, %di                   # point into the whitelist
 346                                                 # so we can have the bios
 347                                                 # directly write into it.
 348
 349 jmpe820:
 350         movl    $0x0000e820, %eax               # e820, upper word zeroed
 351         movl    $SMAP, %edx                     # ascii 'SMAP'
 352         movl    $20, %ecx                       # size of the e820rec
 353         pushw   %ds                             # data record.
 354         popw    %es
 355         int     $0x15                           # make the call
 356         jc      bail820                         # fall to e801 if it fails
 357
 358         cmpl    $SMAP, %eax                     # check the return is `SMAP'
 359         jne     bail820                         # fall to e801 if it fails
 360
 361 #       cmpl    $1, 16(%di)                     # is this usable memory?
 362 #       jne     again820
 363
 364         # If this is usable memory, we save it by simply advancing %di by
 365         # sizeof(e820rec).
 366         #
 367 good820:
 368         movb    (E820NR), %al                   # up to 128 entries
 369         cmpb    $E820MAX, %al
 370         jae     bail820
 371
 372         incb    (E820NR)
 373         movw    %di, %ax
 374         addw    $20, %ax
 375         movw    %ax, %di
 376 again820:
 377         cmpl    $0, %ebx                        # check to see if
 378         jne     jmpe820                         # %ebx is set to EOF
 379 bail820:
 380
 381
 382 # method E801H:
 383 # memory size is in 1k chunksizes, to avoid confusing loadlin.
 384 # we store the 0xe801 memory size in a completely different place,
 385 # because it will most likely be longer than 16 bits.
 386 # (use 1e0 because that's what Larry Augustine uses in his
 387 # alternative new memory detection scheme, and it's sensible
 388 # to write everything into the same place.)
 389
 390 meme801:
 391         stc                                     # fix to work around buggy
 392         xorw    %cx,%cx                         # BIOSes which don't clear/set
 393         xorw    %dx,%dx                         # carry on pass/error of
 394                                                 # e801h memory size call
 395                                                 # or merely pass cx,dx though
 396                                                 # without changing them.
 397         movw    $0xe801, %ax
 398         int     $0x15
 399         jc      mem88
 400
 401         cmpw    $0x0, %cx                       # Kludge to handle BIOSes
 402         jne     e801usecxdx                     # which report their extended
 403         cmpw    $0x0, %dx                       # memory in AX/BX rather than
 404         jne     e801usecxdx                     # CX/DX.  The spec I have read
 405         movw    %ax, %cx                        # seems to indicate AX/BX
 406         movw    %bx, %dx                        # are more reasonable anyway...
 407
 408 e801usecxdx:
 409         andl    $0xffff, %edx                   # clear sign extend
 410         shll    $6, %edx                        # and go from 64k to 1k chunks
 411         movl    %edx, (0x1e0)                   # store extended memory size
 412         andl    $0xffff, %ecx                   # clear sign extend
 413         addl    %ecx, (0x1e0)                   # and add lower memory into
 414                                                 # total size.
 415
 416 # Ye Olde Traditional Methode.  Returns the memory size (up to 16mb or
 417 # 64mb, depending on the bios) in ax.
 418 mem88:
 419
 420 #endif
 421         movb    $0x88, %ah
 422         int     $0x15
 423         movw    %ax, (2)
 424
 425 # Set the keyboard repeat rate to the max
 426         movw    $0x0305, %ax
 427         xorw    %bx, %bx
 428         int     $0x16
 429
 430 # Check for video adapter and its parameters and allow the
 431 # user to browse video modes.
 432         call    video                           # NOTE: we need %ds pointing
 433                                                 # to bootsector
 434
 435 # Get hd0 data...
 436         xorw    %ax, %ax
 437         movw    %ax, %ds
 438         ldsw    (4 * 0x41), %si
 439         movw    %cs, %ax                        # aka SETUPSEG
 440         subw    $DELTA_INITSEG, %ax             # aka INITSEG
 441         pushw   %ax
 442         movw    %ax, %es
 443         movw    $0x0080, %di
 444         movw    $0x10, %cx
 445         pushw   %cx
 446         cld
 447         rep
 448         movsb
 449 # Get hd1 data...
 450         xorw    %ax, %ax
 451         movw    %ax, %ds
 452         ldsw    (4 * 0x46), %si
 453         popw    %cx
 454         popw    %es
 455         movw    $0x0090, %di
 456         rep
 457         movsb
 458 # Check that there IS a hd1 :-)
 459         movw    $0x01500, %ax
 460         movb    $0x81, %dl
 461         int     $0x13
 462         jc      no_disk1
 463
 464         cmpb    $3, %ah
 465         je      is_disk1
 466
 467 no_disk1:
 468         movw    %cs, %ax                        # aka SETUPSEG
 469         subw    $DELTA_INITSEG, %ax             # aka INITSEG
 470         movw    %ax, %es
 471         movw    $0x0090, %di
 472         movw    $0x10, %cx
 473         xorw    %ax, %ax
 474         cld
 475         rep
 476         stosb
 477 is_disk1:
 478 # check for Micro Channel (MCA) bus
 479         movw    %cs, %ax                        # aka SETUPSEG
 480         subw    $DELTA_INITSEG, %ax             # aka INITSEG
 481         movw    %ax, %ds
 482         xorw    %ax, %ax
 483         movw    %ax, (0xa0)                     # set table length to 0
 484         movb    $0xc0, %ah
 485         stc
 486         int     $0x15                           # moves feature table to es:bx
 487         jc      no_mca
 488
 489         pushw   %ds
 490         movw    %es, %ax
 491         movw    %ax, %ds
 492         movw    %cs, %ax                        # aka SETUPSEG
 493         subw    $DELTA_INITSEG, %ax             # aka INITSEG
 494         movw    %ax, %es
 495         movw    %bx, %si
 496         movw    $0xa0, %di
 497         movw    (%si), %cx
 498         addw    $2, %cx                         # table length is a short
 499         cmpw    $0x10, %cx
 500         jc      sysdesc_ok
 501
 502         movw    $0x10, %cx                      # we keep only first 16 bytes
 503 sysdesc_ok:
 504         rep
 505         movsb
 506         popw    %ds
 507 no_mca:
 508 #ifdef CONFIG_X86_VOYAGER
 509         movb    $0xff, 0x40     # flag on config found
 510         movb    $0xc0, %al
 511         mov     $0xff, %ah
 512         int     $0x15           # put voyager config info at es:di
 513         jc      no_voyager
 514         movw    $0x40, %si      # place voyager info in apm table
 515         cld
 516         movw    $7, %cx
 517 voyager_rep:
 518         movb    %es:(%di), %al
 519         movb    %al,(%si)
 520         incw    %di
 521         incw    %si
 522         decw    %cx
 523         jnz     voyager_rep
 524 no_voyager:
 525 #endif
 526 # Check for PS/2 pointing device
 527         movw    %cs, %ax                        # aka SETUPSEG
 528         subw    $DELTA_INITSEG, %ax             # aka INITSEG
 529         movw    %ax, %ds
 530         movb    $0, (0x1ff)                     # default is no pointing device
 531         int     $0x11                           # int 0x11: equipment list
 532         testb   $0x04, %al                      # check if mouse installed
 533         jz      no_psmouse
 534
 535         movb    $0xAA, (0x1ff)                  # device present
 536 no_psmouse:
 537
 538 #if defined(CONFIG_X86_SPEEDSTEP_SMI) || defined(CONFIG_X86_SPEEDSTEP_SMI_MODULE)
 539         movl    $0x0000E980, %eax               # IST Support
 540         movl    $0x47534943, %edx               # Request value
 541         int     $0x15
 542
 543         movl    %eax, (96)
 544         movl    %ebx, (100)
 545         movl    %ecx, (104)
 546         movl    %edx, (108)
 547 #endif
 548
 549 #if defined(CONFIG_APM) || defined(CONFIG_APM_MODULE)
 550 # Then check for an APM BIOS...
 551                                                 # %ds points to the bootsector
 552         movw    $0, 0x40                        # version = 0 means no APM BIOS
 553         movw    $0x05300, %ax                   # APM BIOS installation check
 554         xorw    %bx, %bx
 555         int     $0x15
 556         jc      done_apm_bios                   # Nope, no APM BIOS
 557
 558         cmpw    $0x0504d, %bx                   # Check for "PM" signature
 559         jne     done_apm_bios                   # No signature, no APM BIOS
 560
 561         andw    $0x02, %cx                      # Is 32 bit supported?
 562         je      done_apm_bios                   # No 32-bit, no (good) APM BIOS
 563
 564         movw    $0x05304, %ax                   # Disconnect first just in case
 565         xorw    %bx, %bx
 566         int     $0x15                           # ignore return code
 567         movw    $0x05303, %ax                   # 32 bit connect
 568         xorl    %ebx, %ebx
 569         xorw    %cx, %cx                        # paranoia :-)
 570         xorw    %dx, %dx                        #   ...
 571         xorl    %esi, %esi                      #   ...
 572         xorw    %di, %di                        #   ...
 573         int     $0x15
 574         jc      no_32_apm_bios                  # Ack, error.
 575
 576         movw    %ax,  (66)                      # BIOS code segment
 577         movl    %ebx, (68)                      # BIOS entry point offset
 578         movw    %cx,  (72)                      # BIOS 16 bit code segment
 579         movw    %dx,  (74)                      # BIOS data segment
 580         movl    %esi, (78)                      # BIOS code segment lengths
 581         movw    %di,  (82)                      # BIOS data segment length
 582 # Redo the installation check as the 32 bit connect
 583 # modifies the flags returned on some BIOSs
 584         movw    $0x05300, %ax                   # APM BIOS installation check
 585         xorw    %bx, %bx
 586         xorw    %cx, %cx                        # paranoia
 587         int     $0x15
 588         jc      apm_disconnect                  # error -> shouldn't happen
 589
 590         cmpw    $0x0504d, %bx                   # check for "PM" signature
 591         jne     apm_disconnect                  # no sig -> shouldn't happen
 592
 593         movw    %ax, (64)                       # record the APM BIOS version
 594         movw    %cx, (76)                       # and flags
 595         jmp     done_apm_bios
 596
 597 apm_disconnect:                                 # Tidy up
 598         movw    $0x05304, %ax                   # Disconnect
 599         xorw    %bx, %bx
 600         int     $0x15                           # ignore return code
 601
 602         jmp     done_apm_bios
 603
 604 no_32_apm_bios:
 605         andw    $0xfffd, (76)                   # remove 32 bit support bit
 606 done_apm_bios:
 607 #endif
 608
 609 #include "edd.S"
 610
 611 # Now we want to move to protected mode ...
 612         cmpw    $0, %cs:realmode_swtch
 613         jz      rmodeswtch_normal
 614
 615         lcall   *%cs:realmode_swtch
 616
 617         jmp     rmodeswtch_end
 618
 619 rmodeswtch_normal:
 620         pushw   %cs
 621         call    default_switch
 622
 623 rmodeswtch_end:
 624 # Now we move the system to its rightful place ... but we check if we have a
 625 # big-kernel. In that case we *must* not move it ...
 626         testb   $LOADED_HIGH, %cs:loadflags
 627         jz      do_move0                        # .. then we have a normal low
 628                                                 # loaded zImage
 629                                                 # .. or else we have a high
 630                                                 # loaded bzImage
 631         jmp     end_move                        # ... and we skip moving
 632
 633 do_move0:
 634         movw    $0x100, %ax                     # start of destination segment
 635         movw    %cs, %bp                        # aka SETUPSEG
 636         subw    $DELTA_INITSEG, %bp             # aka INITSEG
 637         movw    %cs:start_sys_seg, %bx          # start of source segment
 638         cld
 639 do_move:
 640         movw    %ax, %es                        # destination segment
 641         incb    %ah                             # instead of add ax,#0x100
 642         movw    %bx, %ds                        # source segment
 643         addw    $0x100, %bx
 644         subw    %di, %di
 645         subw    %si, %si
 646         movw    $0x800, %cx
 647         rep
 648         movsw
 649         cmpw    %bp, %bx                        # assume start_sys_seg > 0x200,
 650                                                 # so we will perhaps read one
 651                                                 # page more than needed, but
 652                                                 # never overwrite INITSEG
 653                                                 # because destination is a
 654                                                 # minimum one page below source
 655         jb      do_move
 656
 657 end_move:
 658 # then we load the segment descriptors
 659         movw    %cs, %ax                        # aka SETUPSEG
 660         movw    %ax, %ds
 661
 662 # Check whether we need to be downward compatible with version <=201
 663         cmpl    $0, cmd_line_ptr
 664         jne     end_move_self           # loader uses version >=202 features
 665         cmpb    $0x20, type_of_loader
 666         je      end_move_self           # bootsect loader, we know of it
 667
 668 # Boot loader doesnt support boot protocol version 2.02.
 669 # If we have our code not at 0x90000, we need to move it there now.
 670 # We also then need to move the params behind it (commandline)
 671 # Because we would overwrite the code on the current IP, we move
 672 # it in two steps, jumping high after the first one.
 673         movw    %cs, %ax
 674         cmpw    $SETUPSEG, %ax
 675         je      end_move_self
 676
 677         cli                                     # make sure we really have
 678                                                 # interrupts disabled !
 679                                                 # because after this the stack
 680                                                 # should not be used
 681         subw    $DELTA_INITSEG, %ax             # aka INITSEG
 682         movw    %ss, %dx
 683         cmpw    %ax, %dx
 684         jb      move_self_1
 685
 686         addw    $INITSEG, %dx
 687         subw    %ax, %dx                        # this will go into %ss after
 688                                                 # the move
 689 move_self_1:
 690         movw    %ax, %ds
 691         movw    $INITSEG, %ax                   # real INITSEG
 692         movw    %ax, %es
 693         movw    %cs:setup_move_size, %cx
 694         std                                     # we have to move up, so we use
 695                                                 # direction down because the
 696                                                 # areas may overlap
 697         movw    %cx, %di
 698         decw    %di
 699         movw    %di, %si
 700         subw    $move_self_here+0x200, %cx
 701         rep
 702         movsb
 703         ljmp    $SETUPSEG, $move_self_here
 704
 705 move_self_here:
 706         movw    $move_self_here+0x200, %cx
 707         rep
 708         movsb
 709         movw    $SETUPSEG, %ax
 710         movw    %ax, %ds
 711         movw    %dx, %ss
 712 end_move_self:                                  # now we are at the right place
 713
 714 #
 715 # Enable A20.  This is at the very best an annoying procedure.
 716 # A20 code ported from SYSLINUX 1.52-1.63 by H. Peter Anvin.
 717 # AMD Elan bug fix by Robert Schwebel.
 718 #
 719
 720 #if defined(CONFIG_X86_ELAN)
 721         movb $0x02, %al                 # alternate A20 gate
 722         outb %al, $0x92                 # this works on SC410/SC520
 723 a20_elan_wait:
 724         call a20_test
 725         jz a20_elan_wait
 726         jmp a20_done
 727 #endif
 728
 729
 730 A20_TEST_LOOPS          =  32           # Iterations per wait
 731 A20_ENABLE_LOOPS        = 255           # Total loops to try
 732
 733
 734 #ifndef CONFIG_X86_VOYAGER
 735 a20_try_loop:
 736
 737         # First, see if we are on a system with no A20 gate.
 738 a20_none:
 739         call    a20_test
 740         jnz     a20_done
 741
 742         # Next, try the BIOS (INT 0x15, AX=0x2401)
 743 a20_bios:
 744         movw    $0x2401, %ax
 745         pushfl                                  # Be paranoid about flags
 746         int     $0x15
 747         popfl
 748
 749         call    a20_test
 750         jnz     a20_done
 751
 752         # Try enabling A20 through the keyboard controller
 753 #endif /* CONFIG_X86_VOYAGER */
 754 a20_kbc:
 755         call    empty_8042
 756
 757 #ifndef CONFIG_X86_VOYAGER
 758         call    a20_test                        # Just in case the BIOS worked
 759         jnz     a20_done                        # but had a delayed reaction.
 760 #endif
 761
 762         movb    $0xD1, %al                      # command write
 763         outb    %al, $0x64
 764         call    empty_8042
 765
 766         movb    $0xDF, %al                      # A20 on
 767         outb    %al, $0x60
 768         call    empty_8042
 769
 770 #ifndef CONFIG_X86_VOYAGER
 771         # Wait until a20 really *is* enabled; it can take a fair amount of
 772         # time on certain systems; Toshiba Tecras are known to have this
 773         # problem.
 774 a20_kbc_wait:
 775         xorw    %cx, %cx
 776 a20_kbc_wait_loop:
 777         call    a20_test
 778         jnz     a20_done
 779         loop    a20_kbc_wait_loop
 780
 781         # Final attempt: use "configuration port A"
 782 a20_fast:
 783         inb     $0x92, %al                      # Configuration Port A
 784         orb     $0x02, %al                      # "fast A20" version
 785         andb    $0xFE, %al                      # don't accidentally reset
 786         outb    %al, $0x92
 787
 788         # Wait for configuration port A to take effect
 789 a20_fast_wait:
 790         xorw    %cx, %cx
 791 a20_fast_wait_loop:
 792         call    a20_test
 793         jnz     a20_done
 794         loop    a20_fast_wait_loop
 795
 796         # A20 is still not responding.  Try frobbing it again.
 797         #
 798         decb    (a20_tries)
 799         jnz     a20_try_loop
 800
 801         movw    $a20_err_msg, %si
 802         call    prtstr
 803
 804 a20_die:
 805         hlt
 806         jmp     a20_die
 807
 808 a20_tries:
 809         .byte   A20_ENABLE_LOOPS
 810
 811 a20_err_msg:
 812         .ascii  "linux: fatal error: A20 gate not responding!"
 813         .byte   13, 10, 0
 814
 815         # If we get here, all is good
 816 a20_done:
 817
 818 #endif /* CONFIG_X86_VOYAGER */
 819 # set up gdt and idt and 32bit start address
 820         lidt    idt_48                          # load idt with 0,0
 821         xorl    %eax, %eax                      # Compute gdt_base
 822         movw    %ds, %ax                        # (Convert %ds:gdt to a linear ptr)
 823         shll    $4, %eax
 824         addl    %eax, code32
 825         addl    $gdt, %eax
 826         movl    %eax, (gdt_48+2)
 827         lgdt    gdt_48                          # load gdt with whatever is
 828                                                 # appropriate
 829
 830 # make sure any possible coprocessor is properly reset..
 831         xorw    %ax, %ax
 832         outb    %al, $0xf0
 833         call    delay
 834
 835         outb    %al, $0xf1
 836         call    delay
 837
 838 # well, that went ok, I hope. Now we mask all interrupts - the rest
 839 # is done in init_IRQ().
 840         movb    $0xFF, %al                      # mask all interrupts for now
 841         outb    %al, $0xA1
 842         call    delay
 843
 844         movb    $0xFB, %al                      # mask all irq's but irq2 which
 845         outb    %al, $0x21                      # is cascaded
 846
 847 # Well, that certainly wasn't fun :-(. Hopefully it works, and we don't
 848 # need no steenking BIOS anyway (except for the initial loading :-).
 849 # The BIOS-routine wants lots of unnecessary data, and it's less
 850 # "interesting" anyway. This is how REAL programmers do it.
 851 #
 852 # Well, now's the time to actually move into protected mode. To make
 853 # things as simple as possible, we do no register set-up or anything,
 854 # we let the gnu-compiled 32-bit programs do that. We just jump to
 855 # absolute address 0x1000 (or the loader supplied one),
 856 # in 32-bit protected mode.
 857 #
 858 # Note that the short jump isn't strictly needed, although there are
 859 # reasons why it might be a good idea. It won't hurt in any case.
 860         movw    $1, %ax                         # protected mode (PE) bit
 861         lmsw    %ax                             # This is it!
 862         jmp     flush_instr
 863
 864 flush_instr:
 865         xorw    %bx, %bx                        # Flag to indicate a boot
 866         xorl    %esi, %esi                      # Pointer to real-mode code
 867         movw    %cs, %si
 868         subw    $DELTA_INITSEG, %si
 869         shll    $4, %esi                        # Convert to 32-bit pointer
 870
 871 # jump to startup_32 in arch/i386/boot/compressed/head.S
 872 #
 873 # NOTE: For high loaded big kernels we need a
 874 #       jmpi    0x100000,__BOOT_CS
 875 #
 876 #       but we yet haven't reloaded the CS register, so the default size
 877 #       of the target offset still is 16 bit.
 878 #       However, using an operand prefix (0x66), the CPU will properly
 879 #       take our 48 bit far pointer. (INTeL 80386 Programmer's Reference
 880 #       Manual, Mixing 16-bit and 32-bit code, page 16-6)
 881
 882         .byte 0x66, 0xea                        # prefix + jmpi-opcode
 883 code32: .long   startup_32                      # will be set to %cs+startup_32
 884         .word   __BOOT_CS
 885 .code32
 886 startup_32:
 887         movl $(__BOOT_DS), %eax
 888         movl %eax, %ds
 889         movl %eax, %es
 890         movl %eax, %fs
 891         movl %eax, %gs
 892         movl %eax, %ss
 893
 894         xorl %eax, %eax
 895 1:      incl %eax                               # check that A20 really IS enabled
 896         movl %eax, 0x00000000                   # loop forever if it isn't
 897         cmpl %eax, 0x00100000
 898         je 1b
 899
 900         # Jump to the 32bit entry point
 901         jmpl *(code32_start - start + (DELTA_INITSEG << 4))(%esi)
 902 .code16
 903
 904 # Here's a bunch of information about your current kernel..
 905 kernel_version: .ascii  UTS_RELEASE
 906                 .ascii  " ("
 907                 .ascii  LINUX_COMPILE_BY
 908                 .ascii  "@"
 909                 .ascii  LINUX_COMPILE_HOST
 910                 .ascii  ") "
 911                 .ascii  UTS_VERSION
 912                 .byte   0
 913
 914 # This is the default real mode switch routine.
 915 # to be called just before protected mode transition
 916 default_switch:
 917         cli                                     # no interrupts allowed !
 918         movb    $0x80, %al                      # disable NMI for bootup
 919                                                 # sequence
 920         outb    %al, $0x70
 921         lret
 922
 923
 924 #ifndef CONFIG_X86_VOYAGER
 925 # This routine tests whether or not A20 is enabled.  If so, it
 926 # exits with zf = 0.
 927 #
 928 # The memory address used, 0x200, is the int $0x80 vector, which
 929 # should be safe.
 930
 931 A20_TEST_ADDR = 4*0x80
 932
 933 a20_test:
 934         pushw   %cx
 935         pushw   %ax
 936         xorw    %cx, %cx
 937         movw    %cx, %fs                        # Low memory
 938         decw    %cx
 939         movw    %cx, %gs                        # High memory area
 940         movw    $A20_TEST_LOOPS, %cx
 941         movw    %fs:(A20_TEST_ADDR), %ax
 942         pushw   %ax
 943 a20_test_wait:
 944         incw    %ax
 945         movw    %ax, %fs:(A20_TEST_ADDR)
 946         call    delay                           # Serialize and make delay constant
 947         cmpw    %gs:(A20_TEST_ADDR+0x10), %ax
 948         loope   a20_test_wait
 949
 950         popw    %fs:(A20_TEST_ADDR)
 951         popw    %ax
 952         popw    %cx
 953         ret
 954
 955 #endif /* CONFIG_X86_VOYAGER */
 956
 957 # This routine checks that the keyboard command queue is empty
 958 # (after emptying the output buffers)
 959 #
 960 # Some machines have delusions that the keyboard buffer is always full
 961 # with no keyboard attached...
 962 #
 963 # If there is no keyboard controller, we will usually get 0xff
 964 # to all the reads.  With each IO taking a microsecond and
 965 # a timeout of 100,000 iterations, this can take about half a
 966 # second ("delay" == outb to port 0x80). That should be ok,
 967 # and should also be plenty of time for a real keyboard controller
 968 # to empty.
 969 #
 970
 971 empty_8042:
 972         pushl   %ecx
 973         movl    $100000, %ecx
 974
 975 empty_8042_loop:
 976         decl    %ecx
 977         jz      empty_8042_end_loop
 978
 979         call    delay
 980
 981         inb     $0x64, %al                      # 8042 status port
 982         testb   $1, %al                         # output buffer?
 983         jz      no_output
 984
 985         call    delay
 986         inb     $0x60, %al                      # read it
 987         jmp     empty_8042_loop
 988
 989 no_output:
 990         testb   $2, %al                         # is input buffer full?
 991         jnz     empty_8042_loop                 # yes - loop
 992 empty_8042_end_loop:
 993         popl    %ecx
 994         ret
 995
 996 # Read the cmos clock. Return the seconds in al
 997 gettime:
 998         pushw   %cx
 999         movb    $0x02, %ah
1000         int     $0x1a
1001         movb    %dh, %al                        # %dh contains the seconds
1002         andb    $0x0f, %al
1003         movb    %dh, %ah
1004         movb    $0x04, %cl
1005         shrb    %cl, %ah
1006         aad
1007         popw    %cx
1008         ret
1009
1010 # Delay is needed after doing I/O
1011 delay:
1012         outb    %al,$0x80
1013         ret
1014
1015 # Descriptor tables
1016 #
1017 # NOTE: The intel manual says gdt should be sixteen bytes aligned for
1018 # efficiency reasons.  However, there are machines which are known not
1019 # to boot with misaligned GDTs, so alter this at your peril!  If you alter
1020 # GDT_ENTRY_BOOT_CS (in asm/segment.h) remember to leave at least two
1021 # empty GDT entries (one for NULL and one reserved).
1022 #
1023 # NOTE: On some CPUs, the GDT must be 8 byte aligned.  This is
1024 # true for the Voyager Quad CPU card which will not boot without
1025 # This directive.  16 byte aligment is recommended by intel.
1026 #
1027         .align 16
1028 gdt:
1029         .fill GDT_ENTRY_BOOT_CS,8,0
1030
1031         .word   0xFFFF                          # 4Gb - (0x100000*0x1000 = 4Gb)
1032         .word   0                               # base address = 0
1033         .word   0x9A00                          # code read/exec
1034         .word   0x00CF                          # granularity = 4096, 386
1035                                                 #  (+5th nibble of limit)
1036
1037         .word   0xFFFF                          # 4Gb - (0x100000*0x1000 = 4Gb)
1038         .word   0                               # base address = 0
1039         .word   0x9200                          # data read/write
1040         .word   0x00CF                          # granularity = 4096, 386
1041                                                 #  (+5th nibble of limit)
1042 gdt_end:
1043         .align  4
1044
1045         .word   0                               # alignment byte
1046 idt_48:
1047         .word   0                               # idt limit = 0
1048         .word   0, 0                            # idt base = 0L
1049
1050         .word   0                               # alignment byte
1051 gdt_48:
1052         .word   gdt_end - gdt - 1               # gdt limit
1053         .word   0, 0                            # gdt base (filled in later)
1054
1055 # Include video setup & detection code
1056
1057 #include "video.S"
1058
1059 # Setup signature -- must be last
1060 setup_sig1:     .word   SIG1
1061 setup_sig2:     .word   SIG2
1062
1063 # After this point, there is some free space which is used by the video mode
1064 # handling code to store the temporary mode table (not used by the kernel).
1065
1066 modelist:
1067
1068 .text
1069 endtext:
1070 .data
1071 enddata:
1072 .bss
1073 endbss: