git.oblomov.eu Git - linux-2.6/blob - arch/arm/boot/compressed/vmlinux.lds.in

   1 /*
   2  *  linux/arch/arm/boot/compressed/vmlinux.lds.in
   3  *
   4  *  Copyright (C) 2000 Russell King
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  */
  10 OUTPUT_ARCH(arm)
  11 ENTRY(_start)
  12 SECTIONS
  13 {
  14   /DISCARD/ : {
  15     *(.ARM.exidx*)
  16     *(.ARM.extab*)
  17   }
  18
  19   . = TEXT_START;
  20   _text = .;
  21
  22   .text : {
  23     _start = .;
  24     *(.start)
  25     *(.text)
  26     *(.text.*)
  27     *(.fixup)
  28     *(.gnu.warning)
  29     *(.rodata)
  30     *(.rodata.*)
  31     *(.glue_7)
  32     *(.glue_7t)
  33     *(.piggydata)
  34     . = ALIGN(4);
  35   }
  36
  37   _etext = .;
  38
  39   _got_start = .;
  40   .got                  : { *(.got) }
  41   _got_end = .;
  42   .got.plt              : { *(.got.plt) }
  43   .data                 : { *(.data) }
  44   _edata = .;
  45
  46   . = BSS_START;
  47   __bss_start = .;
  48   .bss                  : { *(.bss) }
  49   _end = .;
  50
  51   .stack (NOLOAD)       : { *(.stack) }
  52
  53   .stab 0               : { *(.stab) }
  54   .stabstr 0            : { *(.stabstr) }
  55   .stab.excl 0          : { *(.stab.excl) }
  56   .stab.exclstr 0       : { *(.stab.exclstr) }
  57   .stab.index 0         : { *(.stab.index) }
  58   .stab.indexstr 0      : { *(.stab.indexstr) }
  59   .comment 0            : { *(.comment) }
  60 }
  61