git.oblomov.eu Git - linux-2.6/blob - arch/powerpc/kernel/vdso32/vdso32.lds.S

   1 /*
   2  * This is the infamous ld script for the 32 bits vdso
   3  * library
   4  */
   5 #include <asm/vdso.h>
   6
   7 OUTPUT_FORMAT("elf32-powerpc", "elf32-powerpc", "elf32-powerpc")
   8 OUTPUT_ARCH(powerpc:common)
   9 ENTRY(_start)
  10
  11 SECTIONS
  12 {
  13         . = VDSO32_LBASE + SIZEOF_HEADERS;
  14
  15         .hash           : { *(.hash) }                  :text
  16         .gnu.hash       : { *(.gnu.hash) }
  17         .dynsym         : { *(.dynsym) }
  18         .dynstr         : { *(.dynstr) }
  19         .gnu.version    : { *(.gnu.version) }
  20         .gnu.version_d  : { *(.gnu.version_d) }
  21         .gnu.version_r  : { *(.gnu.version_r) }
  22
  23         .note           : { *(.note.*) }                :text   :note
  24
  25         . = ALIGN(16);
  26         .text           : {
  27                 *(.text .stub .text.* .gnu.linkonce.t.* __ftr_alt_*)
  28         }
  29         PROVIDE(__etext = .);
  30         PROVIDE(_etext = .);
  31         PROVIDE(etext = .);
  32
  33         . = ALIGN(8);
  34         __ftr_fixup     : { *(__ftr_fixup) }
  35
  36         . = ALIGN(8);
  37         __lwsync_fixup  : { *(__lwsync_fixup) }
  38
  39 #ifdef CONFIG_PPC64
  40         . = ALIGN(8);
  41         __fw_ftr_fixup  : { *(__fw_ftr_fixup) }
  42 #endif
  43
  44         /*
  45          * Other stuff is appended to the text segment:
  46          */
  47         .rodata         : { *(.rodata .rodata.* .gnu.linkonce.r.*) }
  48         .rodata1        : { *(.rodata1) }
  49
  50         .eh_frame_hdr   : { *(.eh_frame_hdr) }          :text   :eh_frame_hdr
  51         .eh_frame       : { KEEP (*(.eh_frame)) }       :text
  52         .gcc_except_table : { *(.gcc_except_table) }
  53         .fixup          : { *(.fixup) }
  54
  55         .dynamic        : { *(.dynamic) }               :text   :dynamic
  56         .got            : { *(.got) }
  57         .plt            : { *(.plt) }
  58
  59         _end = .;
  60         __end = .;
  61         PROVIDE(end = .);
  62
  63         /*
  64          * Stabs debugging sections are here too.
  65          */
  66         .stab 0 : { *(.stab) }
  67         .stabstr 0 : { *(.stabstr) }
  68         .stab.excl 0 : { *(.stab.excl) }
  69         .stab.exclstr 0 : { *(.stab.exclstr) }
  70         .stab.index 0 : { *(.stab.index) }
  71         .stab.indexstr 0 : { *(.stab.indexstr) }
  72         .comment       0 : { *(.comment) }
  73
  74         /*
  75          * DWARF debug sections.
  76          * Symbols in the DWARF debugging sections are relative to the beginning
  77          * of the section so we begin them at 0.
  78          */
  79         /* DWARF 1 */
  80         .debug          0 : { *(.debug) }
  81         .line           0 : { *(.line) }
  82         /* GNU DWARF 1 extensions */
  83         .debug_srcinfo  0 : { *(.debug_srcinfo) }
  84         .debug_sfnames  0 : { *(.debug_sfnames) }
  85         /* DWARF 1.1 and DWARF 2 */
  86         .debug_aranges  0 : { *(.debug_aranges) }
  87         .debug_pubnames 0 : { *(.debug_pubnames) }
  88         /* DWARF 2 */
  89         .debug_info     0 : { *(.debug_info .gnu.linkonce.wi.*) }
  90         .debug_abbrev   0 : { *(.debug_abbrev) }
  91         .debug_line     0 : { *(.debug_line) }
  92         .debug_frame    0 : { *(.debug_frame) }
  93         .debug_str      0 : { *(.debug_str) }
  94         .debug_loc      0 : { *(.debug_loc) }
  95         .debug_macinfo  0 : { *(.debug_macinfo) }
  96         /* SGI/MIPS DWARF 2 extensions */
  97         .debug_weaknames 0 : { *(.debug_weaknames) }
  98         .debug_funcnames 0 : { *(.debug_funcnames) }
  99         .debug_typenames 0 : { *(.debug_typenames) }
 100         .debug_varnames  0 : { *(.debug_varnames) }
 101
 102         /DISCARD/       : {
 103                 *(.note.GNU-stack)
 104                 *(.data .data.* .gnu.linkonce.d.* .sdata*)
 105                 *(.bss .sbss .dynbss .dynsbss)
 106         }
 107 }
 108
 109 /*
 110  * Very old versions of ld do not recognize this name token; use the constant.
 111  */
 112 #define PT_GNU_EH_FRAME 0x6474e550
 113
 114 /*
 115  * We must supply the ELF program headers explicitly to get just one
 116  * PT_LOAD segment, and set the flags explicitly to make segments read-only.
 117  */
 118 PHDRS
 119 {
 120         text            PT_LOAD FILEHDR PHDRS FLAGS(5); /* PF_R|PF_X */
 121         dynamic         PT_DYNAMIC FLAGS(4);            /* PF_R */
 122         note            PT_NOTE FLAGS(4);               /* PF_R */
 123         eh_frame_hdr    PT_GNU_EH_FRAME;
 124 }
 125
 126 /*
 127  * This controls what symbols we export from the DSO.
 128  */
 129 VERSION
 130 {
 131         VDSO_VERSION_STRING {
 132         global:
 133                 /*
 134                  * Has to be there for the kernel to find
 135                  */
 136                 __kernel_datapage_offset;
 137
 138                 __kernel_get_syscall_map;
 139                 __kernel_gettimeofday;
 140                 __kernel_clock_gettime;
 141                 __kernel_clock_getres;
 142                 __kernel_get_tbfreq;
 143                 __kernel_sync_dicache;
 144                 __kernel_sync_dicache_p5;
 145                 __kernel_sigtramp32;
 146                 __kernel_sigtramp_rt32;
 147
 148         local: *;
 149         };
 150 }