git.oblomov.eu Git - linux-2.6/blob - include/asm-generic/vmlinux.lds.h

   1 #ifndef LOAD_OFFSET
   2 #define LOAD_OFFSET 0
   3 #endif
   4
   5 #ifndef VMLINUX_SYMBOL
   6 #define VMLINUX_SYMBOL(_sym_) _sym_
   7 #endif
   8
   9 /* Align . to a 8 byte boundary equals to maximum function alignment. */
  10 #define ALIGN_FUNCTION()  . = ALIGN(8)
  11
  12 #define RODATA                                                          \
  13         . = ALIGN(4096);                                                \
  14         __start_rodata = .;                                             \
  15         .rodata           : AT(ADDR(.rodata) - LOAD_OFFSET) {           \
  16                 *(.rodata) *(.rodata.*)                                 \
  17                 *(__vermagic)           /* Kernel version magic */      \
  18         }                                                               \
  19                                                                         \
  20         .rodata1          : AT(ADDR(.rodata1) - LOAD_OFFSET) {          \
  21                 *(.rodata1)                                             \
  22         }                                                               \
  23                                                                         \
  24         /* PCI quirks */                                                \
  25         .pci_fixup        : AT(ADDR(.pci_fixup) - LOAD_OFFSET) {        \
  26                 VMLINUX_SYMBOL(__start_pci_fixups_early) = .;           \
  27                 *(.pci_fixup_early)                                     \
  28                 VMLINUX_SYMBOL(__end_pci_fixups_early) = .;             \
  29                 VMLINUX_SYMBOL(__start_pci_fixups_header) = .;          \
  30                 *(.pci_fixup_header)                                    \
  31                 VMLINUX_SYMBOL(__end_pci_fixups_header) = .;            \
  32                 VMLINUX_SYMBOL(__start_pci_fixups_final) = .;           \
  33                 *(.pci_fixup_final)                                     \
  34                 VMLINUX_SYMBOL(__end_pci_fixups_final) = .;             \
  35                 VMLINUX_SYMBOL(__start_pci_fixups_enable) = .;          \
  36                 *(.pci_fixup_enable)                                    \
  37                 VMLINUX_SYMBOL(__end_pci_fixups_enable) = .;            \
  38         }                                                               \
  39                                                                         \
  40         /* RapidIO route ops */                                         \
  41         .rio_route        : AT(ADDR(.rio_route) - LOAD_OFFSET) {        \
  42                 VMLINUX_SYMBOL(__start_rio_route_ops) = .;              \
  43                 *(.rio_route_ops)                                       \
  44                 VMLINUX_SYMBOL(__end_rio_route_ops) = .;                \
  45         }                                                               \
  46                                                                         \
  47         /* Kernel symbol table: Normal symbols */                       \
  48         __ksymtab         : AT(ADDR(__ksymtab) - LOAD_OFFSET) {         \
  49                 VMLINUX_SYMBOL(__start___ksymtab) = .;                  \
  50                 *(__ksymtab)                                            \
  51                 VMLINUX_SYMBOL(__stop___ksymtab) = .;                   \
  52         }                                                               \
  53                                                                         \
  54         /* Kernel symbol table: GPL-only symbols */                     \
  55         __ksymtab_gpl     : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) {     \
  56                 VMLINUX_SYMBOL(__start___ksymtab_gpl) = .;              \
  57                 *(__ksymtab_gpl)                                        \
  58                 VMLINUX_SYMBOL(__stop___ksymtab_gpl) = .;               \
  59         }                                                               \
  60                                                                         \
  61         /* Kernel symbol table: Normal unused symbols */                \
  62         __ksymtab_unused  : AT(ADDR(__ksymtab_unused) - LOAD_OFFSET) {  \
  63                 VMLINUX_SYMBOL(__start___ksymtab_unused) = .;           \
  64                 *(__ksymtab_unused)                                     \
  65                 VMLINUX_SYMBOL(__stop___ksymtab_unused) = .;            \
  66         }                                                               \
  67                                                                         \
  68         /* Kernel symbol table: GPL-only unused symbols */              \
  69         __ksymtab_unused_gpl : AT(ADDR(__ksymtab_unused_gpl) - LOAD_OFFSET) { \
  70                 VMLINUX_SYMBOL(__start___ksymtab_unused_gpl) = .;       \
  71                 *(__ksymtab_unused_gpl)                                 \
  72                 VMLINUX_SYMBOL(__stop___ksymtab_unused_gpl) = .;        \
  73         }                                                               \
  74                                                                         \
  75         /* Kernel symbol table: GPL-future-only symbols */              \
  76         __ksymtab_gpl_future : AT(ADDR(__ksymtab_gpl_future) - LOAD_OFFSET) { \
  77                 VMLINUX_SYMBOL(__start___ksymtab_gpl_future) = .;       \
  78                 *(__ksymtab_gpl_future)                                 \
  79                 VMLINUX_SYMBOL(__stop___ksymtab_gpl_future) = .;        \
  80         }                                                               \
  81                                                                         \
  82         /* Kernel symbol table: Normal symbols */                       \
  83         __kcrctab         : AT(ADDR(__kcrctab) - LOAD_OFFSET) {         \
  84                 VMLINUX_SYMBOL(__start___kcrctab) = .;                  \
  85                 *(__kcrctab)                                            \
  86                 VMLINUX_SYMBOL(__stop___kcrctab) = .;                   \
  87         }                                                               \
  88                                                                         \
  89         /* Kernel symbol table: GPL-only symbols */                     \
  90         __kcrctab_gpl     : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) {     \
  91                 VMLINUX_SYMBOL(__start___kcrctab_gpl) = .;              \
  92                 *(__kcrctab_gpl)                                        \
  93                 VMLINUX_SYMBOL(__stop___kcrctab_gpl) = .;               \
  94         }                                                               \
  95                                                                         \
  96         /* Kernel symbol table: Normal unused symbols */                \
  97         __kcrctab_unused  : AT(ADDR(__kcrctab_unused) - LOAD_OFFSET) {  \
  98                 VMLINUX_SYMBOL(__start___kcrctab_unused) = .;           \
  99                 *(__kcrctab_unused)                                     \
 100                 VMLINUX_SYMBOL(__stop___kcrctab_unused) = .;            \
 101         }                                                               \
 102                                                                         \
 103         /* Kernel symbol table: GPL-only unused symbols */              \
 104         __kcrctab_unused_gpl : AT(ADDR(__kcrctab_unused_gpl) - LOAD_OFFSET) { \
 105                 VMLINUX_SYMBOL(__start___kcrctab_unused_gpl) = .;       \
 106                 *(__kcrctab_unused_gpl)                                 \
 107                 VMLINUX_SYMBOL(__stop___kcrctab_unused_gpl) = .;        \
 108         }                                                               \
 109                                                                         \
 110         /* Kernel symbol table: GPL-future-only symbols */              \
 111         __kcrctab_gpl_future : AT(ADDR(__kcrctab_gpl_future) - LOAD_OFFSET) { \
 112                 VMLINUX_SYMBOL(__start___kcrctab_gpl_future) = .;       \
 113                 *(__kcrctab_gpl_future)                                 \
 114                 VMLINUX_SYMBOL(__stop___kcrctab_gpl_future) = .;        \
 115         }                                                               \
 116                                                                         \
 117         /* Kernel symbol table: strings */                              \
 118         __ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) { \
 119                 *(__ksymtab_strings)                                    \
 120         }                                                               \
 121         __end_rodata = .;                                               \
 122         . = ALIGN(4096);                                                \
 123                                                                         \
 124         /* Built-in module parameters. */                               \
 125         __param : AT(ADDR(__param) - LOAD_OFFSET) {                     \
 126                 VMLINUX_SYMBOL(__start___param) = .;                    \
 127                 *(__param)                                              \
 128                 VMLINUX_SYMBOL(__stop___param) = .;                     \
 129         }
 130
 131 #define SECURITY_INIT                                                   \
 132         .security_initcall.init : AT(ADDR(.security_initcall.init) - LOAD_OFFSET) { \
 133                 VMLINUX_SYMBOL(__security_initcall_start) = .;          \
 134                 *(.security_initcall.init)                              \
 135                 VMLINUX_SYMBOL(__security_initcall_end) = .;            \
 136         }
 137
 138 /* sched.text is aling to function alignment to secure we have same
 139  * address even at second ld pass when generating System.map */
 140 #define SCHED_TEXT                                                      \
 141                 ALIGN_FUNCTION();                                       \
 142                 VMLINUX_SYMBOL(__sched_text_start) = .;                 \
 143                 *(.sched.text)                                          \
 144                 VMLINUX_SYMBOL(__sched_text_end) = .;
 145
 146 /* spinlock.text is aling to function alignment to secure we have same
 147  * address even at second ld pass when generating System.map */
 148 #define LOCK_TEXT                                                       \
 149                 ALIGN_FUNCTION();                                       \
 150                 VMLINUX_SYMBOL(__lock_text_start) = .;                  \
 151                 *(.spinlock.text)                                       \
 152                 VMLINUX_SYMBOL(__lock_text_end) = .;
 153
 154 #define KPROBES_TEXT                                                    \
 155                 ALIGN_FUNCTION();                                       \
 156                 VMLINUX_SYMBOL(__kprobes_text_start) = .;               \
 157                 *(.kprobes.text)                                        \
 158                 VMLINUX_SYMBOL(__kprobes_text_end) = .;
 159
 160                 /* DWARF debug sections.
 161                 Symbols in the DWARF debugging sections are relative to
 162                 the beginning of the section so we begin them at 0.  */
 163 #define DWARF_DEBUG                                                     \
 164                 /* DWARF 1 */                                           \
 165                 .debug          0 : { *(.debug) }                       \
 166                 .line           0 : { *(.line) }                        \
 167                 /* GNU DWARF 1 extensions */                            \
 168                 .debug_srcinfo  0 : { *(.debug_srcinfo) }               \
 169                 .debug_sfnames  0 : { *(.debug_sfnames) }               \
 170                 /* DWARF 1.1 and DWARF 2 */                             \
 171                 .debug_aranges  0 : { *(.debug_aranges) }               \
 172                 .debug_pubnames 0 : { *(.debug_pubnames) }              \
 173                 /* DWARF 2 */                                           \
 174                 .debug_info     0 : { *(.debug_info                     \
 175                                 .gnu.linkonce.wi.*) }                   \
 176                 .debug_abbrev   0 : { *(.debug_abbrev) }                \
 177                 .debug_line     0 : { *(.debug_line) }                  \
 178                 .debug_frame    0 : { *(.debug_frame) }                 \
 179                 .debug_str      0 : { *(.debug_str) }                   \
 180                 .debug_loc      0 : { *(.debug_loc) }                   \
 181                 .debug_macinfo  0 : { *(.debug_macinfo) }               \
 182                 /* SGI/MIPS DWARF 2 extensions */                       \
 183                 .debug_weaknames 0 : { *(.debug_weaknames) }            \
 184                 .debug_funcnames 0 : { *(.debug_funcnames) }            \
 185                 .debug_typenames 0 : { *(.debug_typenames) }            \
 186                 .debug_varnames  0 : { *(.debug_varnames) }             \
 187
 188                 /* Stabs debugging sections.  */
 189 #define STABS_DEBUG                                                     \
 190                 .stab 0 : { *(.stab) }                                  \
 191                 .stabstr 0 : { *(.stabstr) }                            \
 192                 .stab.excl 0 : { *(.stab.excl) }                        \
 193                 .stab.exclstr 0 : { *(.stab.exclstr) }                  \
 194                 .stab.index 0 : { *(.stab.index) }                      \
 195                 .stab.indexstr 0 : { *(.stab.indexstr) }                \
 196                 .comment 0 : { *(.comment) }