git.oblomov.eu Git - linux-2.6/blob - arch/x86/kernel/vmlinux_64.lds.S

   1 /* ld script to make x86-64 Linux kernel
   2  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>;
   3  */
   4
   5 #define LOAD_OFFSET __START_KERNEL_map
   6
   7 #include <asm-generic/vmlinux.lds.h>
   8 #include <asm/page.h>
   9
  10 #undef i386     /* in case the preprocessor is a 32bit one */
  11
  12 OUTPUT_FORMAT("elf64-x86-64", "elf64-x86-64", "elf64-x86-64")
  13 OUTPUT_ARCH(i386:x86-64)
  14 ENTRY(phys_startup_64)
  15 jiffies_64 = jiffies;
  16 _proxy_pda = 1;
  17 PHDRS {
  18         text PT_LOAD FLAGS(5);  /* R_E */
  19         data PT_LOAD FLAGS(7);  /* RWE */
  20         user PT_LOAD FLAGS(7);  /* RWE */
  21         data.init PT_LOAD FLAGS(7);     /* RWE */
  22         note PT_NOTE FLAGS(0);  /* ___ */
  23 }
  24 SECTIONS
  25 {
  26   . = __START_KERNEL;
  27   phys_startup_64 = startup_64 - LOAD_OFFSET;
  28   _text = .;                    /* Text and read-only data */
  29   .text :  AT(ADDR(.text) - LOAD_OFFSET) {
  30         /* First the code that has to be first for bootstrapping */
  31         *(.text.head)
  32         _stext = .;
  33         /* Then the rest */
  34         TEXT_TEXT
  35         SCHED_TEXT
  36         LOCK_TEXT
  37         KPROBES_TEXT
  38         IRQENTRY_TEXT
  39         *(.fixup)
  40         *(.gnu.warning)
  41         _etext = .;             /* End of text section */
  42   } :text = 0x9090
  43
  44   NOTES :text :note
  45
  46   . = ALIGN(16);                /* Exception table */
  47   __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) {
  48         __start___ex_table = .;
  49          *(__ex_table)
  50         __stop___ex_table = .;
  51   } :text = 0x9090
  52
  53   RODATA
  54
  55   . = ALIGN(PAGE_SIZE);         /* Align data segment to page size boundary */
  56                                 /* Data */
  57   .data : AT(ADDR(.data) - LOAD_OFFSET) {
  58         DATA_DATA
  59         CONSTRUCTORS
  60         } :data
  61
  62   _edata = .;                   /* End of data section */
  63
  64   . = ALIGN(PAGE_SIZE);
  65   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
  66   .data.cacheline_aligned : AT(ADDR(.data.cacheline_aligned) - LOAD_OFFSET) {
  67         *(.data.cacheline_aligned)
  68   }
  69   . = ALIGN(CONFIG_X86_INTERNODE_CACHE_BYTES);
  70   .data.read_mostly : AT(ADDR(.data.read_mostly) - LOAD_OFFSET) {
  71         *(.data.read_mostly)
  72   }
  73
  74 #define VSYSCALL_ADDR (-10*1024*1024)
  75 #define VSYSCALL_PHYS_ADDR ((LOADADDR(.data.read_mostly) + SIZEOF(.data.read_mostly) + 4095) & ~(4095))
  76 #define VSYSCALL_VIRT_ADDR ((ADDR(.data.read_mostly) + SIZEOF(.data.read_mostly) + 4095) & ~(4095))
  77
  78 #define VLOAD_OFFSET (VSYSCALL_ADDR - VSYSCALL_PHYS_ADDR)
  79 #define VLOAD(x) (ADDR(x) - VLOAD_OFFSET)
  80
  81 #define VVIRT_OFFSET (VSYSCALL_ADDR - VSYSCALL_VIRT_ADDR)
  82 #define VVIRT(x) (ADDR(x) - VVIRT_OFFSET)
  83
  84   . = VSYSCALL_ADDR;
  85   .vsyscall_0 :  AT(VSYSCALL_PHYS_ADDR) { *(.vsyscall_0) } :user
  86   __vsyscall_0 = VSYSCALL_VIRT_ADDR;
  87
  88   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
  89   .vsyscall_fn : AT(VLOAD(.vsyscall_fn)) { *(.vsyscall_fn) }
  90   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
  91   .vsyscall_gtod_data : AT(VLOAD(.vsyscall_gtod_data))
  92                 { *(.vsyscall_gtod_data) }
  93   vsyscall_gtod_data = VVIRT(.vsyscall_gtod_data);
  94   .vsyscall_clock : AT(VLOAD(.vsyscall_clock))
  95                 { *(.vsyscall_clock) }
  96   vsyscall_clock = VVIRT(.vsyscall_clock);
  97
  98
  99   .vsyscall_1 ADDR(.vsyscall_0) + 1024: AT(VLOAD(.vsyscall_1))
 100                 { *(.vsyscall_1) }
 101   .vsyscall_2 ADDR(.vsyscall_0) + 2048: AT(VLOAD(.vsyscall_2))
 102                 { *(.vsyscall_2) }
 103
 104   .vgetcpu_mode : AT(VLOAD(.vgetcpu_mode)) { *(.vgetcpu_mode) }
 105   vgetcpu_mode = VVIRT(.vgetcpu_mode);
 106
 107   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
 108   .jiffies : AT(VLOAD(.jiffies)) { *(.jiffies) }
 109   jiffies = VVIRT(.jiffies);
 110
 111   .vsyscall_3 ADDR(.vsyscall_0) + 3072: AT(VLOAD(.vsyscall_3))
 112                 { *(.vsyscall_3) }
 113
 114   . = VSYSCALL_VIRT_ADDR + PAGE_SIZE;
 115
 116 #undef VSYSCALL_ADDR
 117 #undef VSYSCALL_PHYS_ADDR
 118 #undef VSYSCALL_VIRT_ADDR
 119 #undef VLOAD_OFFSET
 120 #undef VLOAD
 121 #undef VVIRT_OFFSET
 122 #undef VVIRT
 123
 124   . = ALIGN(THREAD_SIZE);       /* init_task */
 125   .data.init_task : AT(ADDR(.data.init_task) - LOAD_OFFSET) {
 126         *(.data.init_task)
 127   }:data.init
 128
 129   . = ALIGN(PAGE_SIZE);
 130   .data.page_aligned : AT(ADDR(.data.page_aligned) - LOAD_OFFSET) {
 131         *(.data.page_aligned)
 132   }
 133
 134   /* might get freed after init */
 135   . = ALIGN(PAGE_SIZE);
 136   __smp_alt_begin = .;
 137   __smp_locks = .;
 138   .smp_locks : AT(ADDR(.smp_locks) - LOAD_OFFSET) {
 139         *(.smp_locks)
 140   }
 141   __smp_locks_end = .;
 142   . = ALIGN(PAGE_SIZE);
 143   __smp_alt_end = .;
 144
 145   . = ALIGN(PAGE_SIZE);         /* Init code and data */
 146   __init_begin = .;
 147   .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {
 148         _sinittext = .;
 149         INIT_TEXT
 150         _einittext = .;
 151   }
 152   .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) {
 153         __initdata_begin = .;
 154         INIT_DATA
 155         __initdata_end = .;
 156    }
 157
 158   . = ALIGN(16);
 159   __setup_start = .;
 160   .init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) { *(.init.setup) }
 161   __setup_end = .;
 162   __initcall_start = .;
 163   .initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET) {
 164         INITCALLS
 165   }
 166   __initcall_end = .;
 167   __con_initcall_start = .;
 168   .con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) {
 169         *(.con_initcall.init)
 170   }
 171   __con_initcall_end = .;
 172   __x86_cpu_dev_start = .;
 173   .x86_cpu_dev.init : AT(ADDR(.x86_cpu_dev.init) - LOAD_OFFSET) {
 174         *(.x86_cpu_dev.init)
 175   }
 176   __x86_cpu_dev_end = .;
 177   SECURITY_INIT
 178
 179   . = ALIGN(8);
 180   .parainstructions : AT(ADDR(.parainstructions) - LOAD_OFFSET) {
 181   __parainstructions = .;
 182        *(.parainstructions)
 183   __parainstructions_end = .;
 184   }
 185
 186   . = ALIGN(8);
 187   __alt_instructions = .;
 188   .altinstructions : AT(ADDR(.altinstructions) - LOAD_OFFSET) {
 189         *(.altinstructions)
 190   }
 191   __alt_instructions_end = .;
 192   .altinstr_replacement : AT(ADDR(.altinstr_replacement) - LOAD_OFFSET) {
 193         *(.altinstr_replacement)
 194   }
 195   /* .exit.text is discard at runtime, not link time, to deal with references
 196      from .altinstructions and .eh_frame */
 197   .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) {
 198         EXIT_TEXT
 199   }
 200   .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) {
 201         EXIT_DATA
 202   }
 203
 204 #ifdef CONFIG_BLK_DEV_INITRD
 205   . = ALIGN(PAGE_SIZE);
 206   __initramfs_start = .;
 207   .init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET) { *(.init.ramfs) }
 208   __initramfs_end = .;
 209 #endif
 210
 211   PERCPU(PAGE_SIZE)
 212
 213   . = ALIGN(PAGE_SIZE);
 214   __init_end = .;
 215
 216   . = ALIGN(PAGE_SIZE);
 217   __nosave_begin = .;
 218   .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) { *(.data.nosave) }
 219   . = ALIGN(PAGE_SIZE);
 220   __nosave_end = .;
 221
 222   __bss_start = .;              /* BSS */
 223   .bss : AT(ADDR(.bss) - LOAD_OFFSET) {
 224         *(.bss.page_aligned)
 225         *(.bss)
 226         }
 227   __bss_stop = .;
 228
 229   _end = . ;
 230
 231   /* Sections to be discarded */
 232   /DISCARD/ : {
 233         *(.exitcall.exit)
 234         *(.eh_frame)
 235         }
 236
 237   STABS_DEBUG
 238
 239   DWARF_DEBUG
 240 }
 241
 242 /*
 243  * Build-time check on the image size:
 244  */
 245 ASSERT((_end - _text <= KERNEL_IMAGE_SIZE),
 246         "kernel image bigger than KERNEL_IMAGE_SIZE")