git.oblomov.eu Git - linux-2.6/blob - arch/arm/kernel/head-nommu.S

   1 /*
   2  *  linux/arch/arm/kernel/head-nommu.S
   3  *
   4  *  Copyright (C) 1994-2002 Russell King
   5  *  Copyright (C) 2003-2006 Hyok S. Choi
   6  *
   7  * This program is free software; you can redistribute it and/or modify
   8  * it under the terms of the GNU General Public License version 2 as
   9  * published by the Free Software Foundation.
  10  *
  11  *  Common kernel startup code (non-paged MM)
  12  *
  13  */
  14 #include <linux/linkage.h>
  15 #include <linux/init.h>
  16
  17 #include <asm/assembler.h>
  18 #include <asm/ptrace.h>
  19 #include <asm/asm-offsets.h>
  20 #include <asm/thread_info.h>
  21 #include <asm/system.h>
  22
  23 /*
  24  * Kernel startup entry point.
  25  * ---------------------------
  26  *
  27  * This is normally called from the decompressor code.  The requirements
  28  * are: MMU = off, D-cache = off, I-cache = dont care, r0 = 0,
  29  * r1 = machine nr.
  30  *
  31  * See linux/arch/arm/tools/mach-types for the complete list of machine
  32  * numbers for r1.
  33  *
  34  */
  35         .section ".text.head", "ax"
  36 ENTRY(stext)
  37         msr     cpsr_c, #PSR_F_BIT | PSR_I_BIT | SVC_MODE @ ensure svc mode
  38                                                 @ and irqs disabled
  39 #ifndef CONFIG_CPU_CP15
  40         ldr     r9, =CONFIG_PROCESSOR_ID
  41 #else
  42         mrc     p15, 0, r9, c0, c0              @ get processor id
  43 #endif
  44         bl      __lookup_processor_type         @ r5=procinfo r9=cpuid
  45         movs    r10, r5                         @ invalid processor (r5=0)?
  46         beq     __error_p                               @ yes, error 'p'
  47         bl      __lookup_machine_type           @ r5=machinfo
  48         movs    r8, r5                          @ invalid machine (r5=0)?
  49         beq     __error_a                       @ yes, error 'a'
  50
  51         ldr     r13, __switch_data              @ address to jump to after
  52                                                 @ the initialization is done
  53         adr     lr, __after_proc_init           @ return (PIC) address
  54         add     pc, r10, #PROCINFO_INITFUNC
  55 ENDPROC(stext)
  56
  57 /*
  58  * Set the Control Register and Read the process ID.
  59  */
  60 __after_proc_init:
  61 #ifdef CONFIG_CPU_CP15
  62         mrc     p15, 0, r0, c1, c0, 0           @ read control reg
  63 #ifdef CONFIG_ALIGNMENT_TRAP
  64         orr     r0, r0, #CR_A
  65 #else
  66         bic     r0, r0, #CR_A
  67 #endif
  68 #ifdef CONFIG_CPU_DCACHE_DISABLE
  69         bic     r0, r0, #CR_C
  70 #endif
  71 #ifdef CONFIG_CPU_BPREDICT_DISABLE
  72         bic     r0, r0, #CR_Z
  73 #endif
  74 #ifdef CONFIG_CPU_ICACHE_DISABLE
  75         bic     r0, r0, #CR_I
  76 #endif
  77 #ifdef CONFIG_CPU_HIGH_VECTOR
  78         orr     r0, r0, #CR_V
  79 #else
  80         bic     r0, r0, #CR_V
  81 #endif
  82         mcr     p15, 0, r0, c1, c0, 0           @ write control reg
  83 #endif /* CONFIG_CPU_CP15 */
  84
  85         mov     pc, r13                         @ clear the BSS and jump
  86                                                 @ to start_kernel
  87 ENDPROC(__after_proc_init)
  88         .ltorg
  89
  90 #include "head-common.S"