git.oblomov.eu Git - linux-2.6/blob - arch/arm/kernel/entry-common.S

   1 /*
   2  *  linux/arch/arm/kernel/entry-common.S
   3  *
   4  *  Copyright (C) 2000 Russell King
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  */
  10 #include <linux/config.h>
  11
  12 #include <asm/unistd.h>
  13
  14 #include "entry-header.S"
  15
  16
  17         .align  5
  18 /*
  19  * This is the fast syscall return path.  We do as little as
  20  * possible here, and this includes saving r0 back into the SVC
  21  * stack.
  22  */
  23 ret_fast_syscall:
  24         disable_irq                             @ disable interrupts
  25         ldr     r1, [tsk, #TI_FLAGS]
  26         tst     r1, #_TIF_WORK_MASK
  27         bne     fast_work_pending
  28
  29         @ fast_restore_user_regs
  30         ldr     r1, [sp, #S_OFF + S_PSR]        @ get calling cpsr
  31         ldr     lr, [sp, #S_OFF + S_PC]!        @ get pc
  32         msr     spsr_cxsf, r1                   @ save in spsr_svc
  33         ldmdb   sp, {r1 - lr}^                  @ get calling r1 - lr
  34         mov     r0, r0
  35         add     sp, sp, #S_FRAME_SIZE - S_PC
  36         movs    pc, lr                          @ return & move spsr_svc into cpsr
  37
  38 /*
  39  * Ok, we need to do extra processing, enter the slow path.
  40  */
  41 fast_work_pending:
  42         str     r0, [sp, #S_R0+S_OFF]!          @ returned r0
  43 work_pending:
  44         tst     r1, #_TIF_NEED_RESCHED
  45         bne     work_resched
  46         tst     r1, #_TIF_NOTIFY_RESUME | _TIF_SIGPENDING
  47         beq     no_work_pending
  48         mov     r0, sp                          @ 'regs'
  49         mov     r2, why                         @ 'syscall'
  50         bl      do_notify_resume
  51         b       ret_slow_syscall                @ Check work again
  52
  53 work_resched:
  54         bl      schedule
  55 /*
  56  * "slow" syscall return path.  "why" tells us if this was a real syscall.
  57  */
  58 ENTRY(ret_to_user)
  59 ret_slow_syscall:
  60         disable_irq                             @ disable interrupts
  61         ldr     r1, [tsk, #TI_FLAGS]
  62         tst     r1, #_TIF_WORK_MASK
  63         bne     work_pending
  64 no_work_pending:
  65         @ slow_restore_user_regs
  66         ldr     r1, [sp, #S_PSR]                @ get calling cpsr
  67         ldr     lr, [sp, #S_PC]!                @ get pc
  68         msr     spsr_cxsf, r1                   @ save in spsr_svc
  69         ldmdb   sp, {r0 - lr}^                  @ get calling r1 - lr
  70         mov     r0, r0
  71         add     sp, sp, #S_FRAME_SIZE - S_PC
  72         movs    pc, lr                          @ return & move spsr_svc into cpsr
  73
  74 /*
  75  * This is how we return from a fork.
  76  */
  77 ENTRY(ret_from_fork)
  78         bl      schedule_tail
  79         get_thread_info tsk
  80         ldr     r1, [tsk, #TI_FLAGS]            @ check for syscall tracing
  81         mov     why, #1
  82         tst     r1, #_TIF_SYSCALL_TRACE         @ are we tracing syscalls?
  83         beq     ret_slow_syscall
  84         mov     r1, sp
  85         mov     r0, #1                          @ trace exit [IP = 1]
  86         bl      syscall_trace
  87         b       ret_slow_syscall
  88
  89
  90 #include "calls.S"
  91
  92 /*=============================================================================
  93  * SWI handler
  94  *-----------------------------------------------------------------------------
  95  */
  96
  97         /* If we're optimising for StrongARM the resulting code won't
  98            run on an ARM7 and we can save a couple of instructions.
  99                                                                 --pb */
 100 #ifdef CONFIG_CPU_ARM710
 101         .macro  arm710_bug_check, instr, temp
 102         and     \temp, \instr, #0x0f000000      @ check for SWI
 103         teq     \temp, #0x0f000000
 104         bne     .Larm700bug
 105         .endm
 106
 107 .Larm700bug:
 108         ldmia   sp, {r0 - lr}^                  @ Get calling r0 - lr
 109         mov     r0, r0
 110         add     sp, sp, #S_FRAME_SIZE
 111         subs    pc, lr, #4
 112 #else
 113         .macro  arm710_bug_check, instr, temp
 114         .endm
 115 #endif
 116
 117         .align  5
 118 ENTRY(vector_swi)
 119         sub     sp, sp, #S_FRAME_SIZE
 120         stmia   sp, {r0 - r12}                  @ Calling r0 - r12
 121         add     r8, sp, #S_PC
 122         stmdb   r8, {sp, lr}^                   @ Calling sp, lr
 123         mrs     r8, spsr                        @ called from non-FIQ mode, so ok.
 124         str     lr, [sp, #S_PC]                 @ Save calling PC
 125         str     r8, [sp, #S_PSR]                @ Save CPSR
 126         str     r0, [sp, #S_OLD_R0]             @ Save OLD_R0
 127         zero_fp
 128
 129         /*
 130          * Get the system call number.
 131          */
 132 #ifdef CONFIG_ARM_THUMB
 133         tst     r8, #PSR_T_BIT                  @ this is SPSR from save_user_regs
 134         addne   scno, r7, #__NR_SYSCALL_BASE    @ put OS number in
 135         ldreq   scno, [lr, #-4]
 136 #else
 137         ldr     scno, [lr, #-4]                 @ get SWI instruction
 138 #endif
 139         arm710_bug_check scno, ip
 140
 141 #ifdef CONFIG_ALIGNMENT_TRAP
 142         ldr     ip, __cr_alignment
 143         ldr     ip, [ip]
 144         mcr     p15, 0, ip, c1, c0              @ update control register
 145 #endif
 146         enable_irq
 147
 148         stmdb   sp!, {r4, r5}                   @ push fifth and sixth args
 149
 150         get_thread_info tsk
 151         ldr     ip, [tsk, #TI_FLAGS]            @ check for syscall tracing
 152         bic     scno, scno, #0xff000000         @ mask off SWI op-code
 153         eor     scno, scno, #__NR_SYSCALL_BASE  @ check OS number
 154         adr     tbl, sys_call_table             @ load syscall table pointer
 155         tst     ip, #_TIF_SYSCALL_TRACE         @ are we tracing syscalls?
 156         bne     __sys_trace
 157
 158         adr     lr, ret_fast_syscall            @ return address
 159         cmp     scno, #NR_syscalls              @ check upper syscall limit
 160         ldrcc   pc, [tbl, scno, lsl #2]         @ call sys_* routine
 161
 162         add     r1, sp, #S_OFF
 163 2:      mov     why, #0                         @ no longer a real syscall
 164         cmp     scno, #(__ARM_NR_BASE - __NR_SYSCALL_BASE)
 165         eor     r0, scno, #__NR_SYSCALL_BASE    @ put OS number back
 166         bcs     arm_syscall
 167         b       sys_ni_syscall                  @ not private func
 168
 169         /*
 170          * This is the really slow path.  We're going to be doing
 171          * context switches, and waiting for our parent to respond.
 172          */
 173 __sys_trace:
 174         add     r1, sp, #S_OFF
 175         mov     r0, #0                          @ trace entry [IP = 0]
 176         bl      syscall_trace
 177
 178         adr     lr, __sys_trace_return          @ return address
 179         add     r1, sp, #S_R0 + S_OFF           @ pointer to regs
 180         cmp     scno, #NR_syscalls              @ check upper syscall limit
 181         ldmccia r1, {r0 - r3}                   @ have to reload r0 - r3
 182         ldrcc   pc, [tbl, scno, lsl #2]         @ call sys_* routine
 183         b       2b
 184
 185 __sys_trace_return:
 186         str     r0, [sp, #S_R0 + S_OFF]!        @ save returned r0
 187         mov     r1, sp
 188         mov     r0, #1                          @ trace exit [IP = 1]
 189         bl      syscall_trace
 190         b       ret_slow_syscall
 191
 192         .align  5
 193 #ifdef CONFIG_ALIGNMENT_TRAP
 194         .type   __cr_alignment, #object
 195 __cr_alignment:
 196         .word   cr_alignment
 197 #endif
 198
 199         .type   sys_call_table, #object
 200 ENTRY(sys_call_table)
 201 #include "calls.S"
 202
 203 /*============================================================================
 204  * Special system call wrappers
 205  */
 206 @ r0 = syscall number
 207 @ r8 = syscall table
 208                 .type   sys_syscall, #function
 209 sys_syscall:
 210                 eor     scno, r0, #__NR_SYSCALL_BASE
 211                 cmp     scno, #__NR_syscall - __NR_SYSCALL_BASE
 212                 cmpne   scno, #NR_syscalls      @ check range
 213                 stmloia sp, {r5, r6}            @ shuffle args
 214                 movlo   r0, r1
 215                 movlo   r1, r2
 216                 movlo   r2, r3
 217                 movlo   r3, r4
 218                 ldrlo   pc, [tbl, scno, lsl #2]
 219                 b       sys_ni_syscall
 220
 221 sys_fork_wrapper:
 222                 add     r0, sp, #S_OFF
 223                 b       sys_fork
 224
 225 sys_vfork_wrapper:
 226                 add     r0, sp, #S_OFF
 227                 b       sys_vfork
 228
 229 sys_execve_wrapper:
 230                 add     r3, sp, #S_OFF
 231                 b       sys_execve
 232
 233 sys_clone_wrapper:
 234                 add     ip, sp, #S_OFF
 235                 str     ip, [sp, #4]
 236                 b       sys_clone
 237
 238 sys_sigsuspend_wrapper:
 239                 add     r3, sp, #S_OFF
 240                 b       sys_sigsuspend
 241
 242 sys_rt_sigsuspend_wrapper:
 243                 add     r2, sp, #S_OFF
 244                 b       sys_rt_sigsuspend
 245
 246 sys_sigreturn_wrapper:
 247                 add     r0, sp, #S_OFF
 248                 b       sys_sigreturn
 249
 250 sys_rt_sigreturn_wrapper:
 251                 add     r0, sp, #S_OFF
 252                 b       sys_rt_sigreturn
 253
 254 sys_sigaltstack_wrapper:
 255                 ldr     r2, [sp, #S_OFF + S_SP]
 256                 b       do_sigaltstack
 257
 258 /*
 259  * Note: off_4k (r5) is always units of 4K.  If we can't do the requested
 260  * offset, we return EINVAL.
 261  */
 262 sys_mmap2:
 263 #if PAGE_SHIFT > 12
 264                 tst     r5, #PGOFF_MASK
 265                 moveq   r5, r5, lsr #PAGE_SHIFT - 12
 266                 streq   r5, [sp, #4]
 267                 beq     do_mmap2
 268                 mov     r0, #-EINVAL
 269                 RETINSTR(mov,pc, lr)
 270 #else
 271                 str     r5, [sp, #4]
 272                 b       do_mmap2
 273 #endif