git.oblomov.eu Git - linux-2.6/blob - arch/alpha/lib/ev67-strcat.S

   1 /*
   2  * arch/alpha/lib/ev67-strcat.S
   3  * 21264 version contributed by Rick Gorton <rick.gorton@alpha-processor.com>
   4  *
   5  * Append a null-terminated string from SRC to DST.
   6  *
   7  * Much of the information about 21264 scheduling/coding comes from:
   8  *      Compiler Writer's Guide for the Alpha 21264
   9  *      abbreviated as 'CWG' in other comments here
  10  *      ftp.digital.com/pub/Digital/info/semiconductor/literature/dsc-library.html
  11  * Scheduling notation:
  12  *      E       - either cluster
  13  *      U       - upper subcluster; U0 - subcluster U0; U1 - subcluster U1
  14  *      L       - lower subcluster; L0 - subcluster L0; L1 - subcluster L1
  15  * Try not to change the actual algorithm if possible for consistency.
  16  * Commentary: It seems bogus to walk the input string twice - once
  17  * to determine the length, and then again while doing the copy.
  18  * A significant (future) enhancement would be to only read the input
  19  * string once.
  20  */
  21
  22
  23         .text
  24
  25         .align 4
  26         .globl strcat
  27         .ent strcat
  28 strcat:
  29         .frame $30, 0, $26
  30         .prologue 0
  31
  32         mov     $16, $0         # E : set up return value
  33         /* Find the end of the string.  */
  34         ldq_u   $1, 0($16)      # L : load first quadword (a0 may be misaligned)
  35         lda     $2, -1          # E :
  36         insqh   $2, $16, $2     # U :
  37
  38         andnot  $16, 7, $16     # E :
  39         or      $2, $1, $1      # E :
  40         cmpbge  $31, $1, $2     # E : bits set iff byte == 0
  41         bne     $2, $found      # U :
  42
  43 $loop:  ldq     $1, 8($16)      # L :
  44         addq    $16, 8, $16     # E :
  45         cmpbge  $31, $1, $2     # E :
  46         beq     $2, $loop       # U :
  47
  48 $found: cttz    $2, $3          # U0 :
  49         addq    $16, $3, $16    # E :
  50         /* Now do the append.  */
  51         mov     $26, $23        # E :
  52         br      __stxcpy        # L0 :
  53
  54         .end strcat