git.oblomov.eu Git - linux-2.6/blob - arch/cris/arch-v10/kernel/entry.S

   1 /* $Id: entry.S,v 1.28 2005/06/20 05:06:30 starvik Exp $
   2  *
   3  *  linux/arch/cris/entry.S
   4  *
   5  *  Copyright (C) 2000, 2001, 2002 Axis Communications AB
   6  *
   7  *  Authors:    Bjorn Wesen (bjornw@axis.com)
   8  *
   9  *  $Log: entry.S,v $
  10  *  Revision 1.28  2005/06/20 05:06:30  starvik
  11  *  Remove unnecessary diff to kernel.org tree
  12  *
  13  *  Revision 1.27  2005/03/04 08:16:16  starvik
  14  *  Merge of Linux 2.6.11.
  15  *
  16  *  Revision 1.26  2005/01/11 13:49:47  starvik
  17  *  Added NMI handler.
  18  *
  19  *  Revision 1.25  2004/12/27 11:18:32  starvik
  20  *  Merge of Linux 2.6.10 (not functional yet).
  21  *
  22  *  Revision 1.24  2004/12/22 10:41:23  starvik
  23  *  Updates to make v10 compile with the latest SMP aware generic code (even
  24  *  though v10 will never have SMP).
  25  *
  26  *  Revision 1.23  2004/10/19 13:07:37  starvik
  27  *  Merge of Linux 2.6.9
  28  *
  29  *  Revision 1.22  2004/06/21 10:29:55  starvik
  30  *  Merge of Linux 2.6.7
  31  *
  32  *  Revision 1.21  2004/06/09 05:30:27  starvik
  33  *  Clean up multiple interrupt handling.
  34  *    Prevent interrupts from interrupting each other.
  35  *    Handle all active interrupts.
  36  *
  37  *  Revision 1.20  2004/06/08 08:55:32  starvik
  38  *  Removed unused code
  39  *
  40  *  Revision 1.19  2004/06/04 11:56:15  starvik
  41  *  Implemented page table lookup for refills in assembler for improved performance.
  42  *
  43  *  Revision 1.18  2004/05/11 12:28:25  starvik
  44  *  Merge of Linux 2.6.6
  45  *
  46  *  Revision 1.17  2003/09/11 07:29:49  starvik
  47  *  Merge of Linux 2.6.0-test5
  48  *
  49  *  Revision 1.16  2003/07/04 08:27:41  starvik
  50  *  Merge of Linux 2.5.74
  51  *
  52  *  Revision 1.15  2003/04/09 07:32:55  starvik
  53  *  resume should return task_struct, not thread_info
  54  *
  55  *  Revision 1.14  2003/04/09 05:20:44  starvik
  56  *  Merge of Linux 2.5.67
  57  *
  58  *  Revision 1.13  2002/12/11 15:42:02  starvik
  59  *  Extracted v10 (ETRAX 100LX) specific stuff from arch/cris/kernel/*.c
  60  *
  61  *  Revision 1.12  2002/12/10 09:00:10  starvik
  62  *  Merge of Linux 2.5.51
  63  *
  64  *  Revision 1.11  2002/12/05 07:53:10  starvik
  65  *  Corrected constants used with btstq
  66  *
  67  *  Revision 1.10  2002/11/27 08:45:10  starvik
  68  *  pid is in task_struct, not thread_info
  69  *
  70  *  Revision 1.9  2002/11/26 09:52:05  starvik
  71  *  Added preemptive kernel scheduling (if CONFIG_PREEMPT)
  72  *
  73  *  Revision 1.8  2002/11/20 11:56:11  starvik
  74  *  Merge of Linux 2.5.48
  75  *
  76  *  Revision 1.7  2002/11/18 13:02:42  starvik
  77  *  Added fourth parameter to do_notify_resume
  78  *  Minor cleanup
  79  *
  80  *  Revision 1.6  2002/11/11 10:37:50  starvik
  81  *  Use new asm-offset defines
  82  *  Modified for new location of current->work etc
  83  *  Removed SYMBOL_NAME from syscalls
  84  *  Added some new syscalls
  85  *
  86  *  Revision 1.5  2002/11/05 06:45:11  starvik
  87  *  Merge of Linux 2.5.45
  88  *
  89  *  Revision 1.4  2002/02/05 15:41:31  bjornw
  90  *  Rewritten to conform better to current 2.5 code (similar to arch/i386)
  91  *
  92  *  Revision 1.3  2002/01/21 15:22:20  bjornw
  93  *  NICE_DOGGY fix from 2.4 arch/cris
  94  *
  95  *  Revision 1.37  2001/12/07 17:03:55  bjornw
  96  *  Call a c-hook called watchdog_bite_hook instead of show_registers directly
  97  *
  98  *  Revision 1.36  2001/11/22 13:36:36  bjornw
  99  *  * In ret_from_intr, check regs->dccr for usermode reentrance instead of
 100  *    DCCR explicitely (because the latter might not reflect current reality)
 101  *  * In mmu_bus_fault, set $r9 _after_ calling the C-code instead of before
 102  *    since $r9 is call-clobbered and is potentially needed afterwards
 103  *
 104  *  Revision 1.35  2001/10/30 17:10:15  bjornw
 105  *  Add some syscalls
 106  *
 107  *  Revision 1.34  2001/10/01 14:45:03  bjornw
 108  *  Removed underscores and added register prefixes
 109  *
 110  *  Revision 1.33  2001/08/21 13:48:01  jonashg
 111  *  Added fix by HP to avoid oops when doing a hard_reset_now.
 112  *
 113  *  Revision 1.32  2001/08/14 04:32:02  hp
 114  *  In _resume, add comment why R9 is saved; don't sound like it's call-saved.
 115  *
 116  *  Revision 1.31  2001/07/25 16:07:42  bjornw
 117  *  softirq_active/mask -> softirq_pending only
 118  *
 119  *  Revision 1.30  2001/07/05 01:03:32  hp
 120  *  - include asm/errno.h to get ENOSYS.
 121  *  - Use ENOSYS, not local constant LENOSYS; tweak comments.
 122  *  - Explain why .include, not #include is used.
 123  *  - Make oops-register-dump if watchdog bits and it's not expected.
 124  *  - Don't jsr, use jump _hard_reset_now, and skip spurious nop.
 125  *  - Use correct section attribute for section .rodata.
 126  *  - Adjust sys_ni_syscall fill number.
 127  *
 128  *  Revision 1.29  2001/06/25 14:07:00  hp
 129  *      Fix review comment.
 130  *      * head.S: Use IO_STATE, IO_FIELD and IO_MASK constructs instead of
 131  *      magic numbers.  Add comment that -traditional must not be used.
 132  *      * entry.S (SYMBOL_NAME): Change redefinition to use ## concatenation.
 133  *      Correct and update comment.
 134  *      * Makefile (.S.o): Don't use -traditional.  Add comment why the
 135  *      toplevel rule can't be used (now that there's a reason).
 136  *
 137  *  Revision 1.28  2001/06/21 02:00:40  hp
 138  *      * entry.S: Include asm/unistd.h.
 139  *      (_sys_call_table): Use section .rodata, not .data.
 140  *      (_kernel_thread): Move from...
 141  *      * process.c: ... here.
 142  *      * entryoffsets.c (VAL): Break out from...
 143  *      (OF): Use VAL.
 144  *      (LCLONE_VM): New asmified value from CLONE_VM.
 145  *
 146  *  Revision 1.27  2001/05/29 11:25:27  markusl
 147  *  In case of "spurious_interrupt", do hard_reset instead of hanging system in a loop...
 148  *
 149  *  Revision 1.26  2001/05/15 15:46:03  bjornw
 150  *  Include config.h now that we use some CONFIG_ options
 151  *
 152  *  Revision 1.25  2001/05/15 05:38:47  hp
 153  *  Tweaked code in _ret_from_sys_call
 154  *
 155  *  Revision 1.24  2001/05/15 05:27:49  hp
 156  *  Save r9 in r1 over function call rather than on stack.
 157  *
 158  *  Revision 1.23  2001/05/15 05:10:00  hp
 159  *  Generate entry.S structure offsets from C
 160  *
 161  *  Revision 1.22  2001/04/17 13:58:39  orjanf
 162  *  * Renamed CONFIG_KGDB to CONFIG_ETRAX_KGDB.
 163  *
 164  *  Revision 1.21  2001/04/17 11:33:29  orjanf
 165  *  Updated according to review:
 166  *  * Included asm/sv_addr_ag.h to get macro for internal register.
 167  *  * Corrected comment regarding system call argument passing.
 168  *  * Removed comment about instruction being in a delay slot.
 169  *  * Added comment about SYMBOL_NAME macro.
 170  *
 171  *  Revision 1.20  2001/04/12 08:51:07  hp
 172  *  - Add entry for sys_fcntl64.  In fact copy last piece from i386 including ...
 173  *  - .rept to fill table to safe state with sys_ni_syscall.
 174  *
 175  *  Revision 1.19  2001/04/04 09:43:32  orjanf
 176  *  * Moved do_sigtrap from traps.c to entry.S.
 177  *  * LTASK_PID need not be global anymore.
 178  *
 179  *  Revision 1.18  2001/03/26 09:25:02  markusl
 180  *  Updated after review, should now handle USB interrupts correctly.
 181  *
 182  *  Revision 1.17  2001/03/21 16:12:55  bjornw
 183  *  * Always make room for the cpu status record in the frame, in order to
 184  *    use the same framelength and layout for both mmu busfaults and normal
 185  *    irqs. No need to check for the explicit CRIS_FRAME_FIXUP type anymore.
 186  *  * Fixed bug with using addq for popping the stack in the epilogue - it
 187  *    destroyed the flag register. Use instructions that don't affect the
 188  *    flag register instead.
 189  *  * Removed write to R_PORT_PA_DATA during spurious_interrupt
 190  *
 191  *  Revision 1.16  2001/03/20 19:43:02  bjornw
 192  *  * Get rid of esp0 setting
 193  *  * Give a 7th argument to a systemcall - the stackframe
 194  *
 195  *  Revision 1.15  2001/03/05 13:14:30  bjornw
 196  *  Spelling fix
 197  *
 198  *  Revision 1.14  2001/02/23 08:36:36  perf
 199  *  New ABI; syscallnr=r9, arg5=mof, arg6=srp.
 200  *  Corrected tracesys call check.
 201  *
 202  *  Revision 1.13  2001/02/15 08:40:55  perf
 203  *  H-P by way of perf;
 204  *  - (_system_call): Don't read system call function address into r1.
 205  *  - (RBFExit): There is no such thing as a null pop.  Adjust sp by addq.
 206  *  - (_system_call): Don't use r10 and don't save and restore it.
 207  *  - (THREAD_ESP0): New constant.
 208  *  - (_system_call): Inline set_esp0.
 209  *
 210  *  Revision 1.12  2001/01/31 17:56:25  orjanf
 211  *  Added definition of LTASK_PID and made it global.
 212  *
 213  *  Revision 1.11  2001/01/10 21:13:29  bjornw
 214  *  SYMBOL_NAME is defined incorrectly for the compiler options we currently use
 215  *
 216  *  Revision 1.10  2000/12/18 23:47:56  bjornw
 217  *  * Added syscall trace support (ptrace), completely untested of course
 218  *  * Removed redundant check for NULL entries in syscall_table
 219  *
 220  *  Revision 1.9  2000/11/21 16:40:51  bjornw
 221  *  * New frame type used when an SBFS frame needs to be popped without
 222  *    actually restarting the instruction
 223  *  * Enable interrupts in signal_return (they did so in x86, I hope it's a good
 224  *    idea)
 225  *
 226  *  Revision 1.8  2000/11/17 16:53:35  bjornw
 227  *  Added detection of frame-type in Rexit, so that mmu_bus_fault can
 228  *  use ret_from_intr in the return-path to check for signals (like SEGV)
 229  *  and other foul things that might have occurred during the fault.
 230  *
 231  *  Revision 1.7  2000/10/06 15:04:28  bjornw
 232  *  Include mof in register savings
 233  *
 234  *  Revision 1.6  2000/09/12 16:02:44  bjornw
 235  *  Linux-2.4.0-test7 derived updates
 236  *
 237  *  Revision 1.5  2000/08/17 15:35:15  bjornw
 238  *  2.4.0-test6 changed local_irq_count and friends API
 239  *
 240  *  Revision 1.4  2000/08/02 13:59:30  bjornw
 241  *  Removed olduname and uname from the syscall list
 242  *
 243  *  Revision 1.3  2000/07/31 13:32:58  bjornw
 244  *  * Export ret_from_intr
 245  *  * _resume updated (prev/last tjohejsan)
 246  *  * timer_interrupt obsolete
 247  *  * SIGSEGV detection in mmu_bus_fault temporarily disabled
 248  *
 249  *
 250  */
 251
 252 /*
 253  * entry.S contains the system-call and fault low-level handling routines.
 254  *
 255  * NOTE: This code handles signal-recognition, which happens every time
 256  * after a timer-interrupt and after each system call.
 257  *
 258  * Stack layout in 'ret_from_system_call':
 259  *      ptrace needs to have all regs on the stack.
 260  *      if the order here is changed, it needs to be
 261  *      updated in fork.c:copy_process, signal.c:do_signal,
 262  *      ptrace.c and ptrace.h
 263  *
 264  */
 265
 266 #include <linux/config.h>
 267 #include <linux/linkage.h>
 268 #include <linux/sys.h>
 269 #include <asm/unistd.h>
 270 #include <asm/arch/sv_addr_ag.h>
 271 #include <asm/errno.h>
 272 #include <asm/thread_info.h>
 273 #include <asm/asm-offsets.h>
 274 #include <asm/page.h>
 275 #include <asm/pgtable.h>
 276
 277         ;; functions exported from this file
 278
 279         .globl system_call
 280         .globl ret_from_intr
 281         .globl ret_from_fork
 282         .globl resume
 283         .globl multiple_interrupt
 284         .globl hwbreakpoint
 285         .globl IRQ1_interrupt
 286         .globl spurious_interrupt
 287         .globl hw_bp_trigs
 288         .globl mmu_bus_fault
 289         .globl do_sigtrap
 290         .globl gdb_handle_breakpoint
 291         .globl sys_call_table
 292
 293         ;; below are various parts of system_call which are not in the fast-path
 294
 295 #ifdef CONFIG_PREEMPT
 296         ; Check if preemptive kernel scheduling should be done
 297 _resume_kernel:
 298         di
 299         ; Load current task struct
 300         movs.w  -8192, $r0      ;  THREAD_SIZE = 8192
 301         and.d   $sp, $r0
 302         move.d  [$r0+TI_preempt_count], $r10    ;  Preemption disabled?
 303         bne     _Rexit
 304         nop
 305 _need_resched:
 306         move.d  [$r0+TI_flags], $r10
 307         btstq   TIF_NEED_RESCHED, $r10  ; Check if need_resched is set
 308         bpl     _Rexit
 309         nop
 310         ; Ok, lets's do some preemptive kernel scheduling
 311         jsr     preempt_schedule_irq
 312         ; Load new task struct
 313         movs.w  -8192, $r0      ;  THREAD_SIZE = 8192
 314         and.d   $sp, $r0
 315         ; One more time (with new task)
 316         ba      _need_resched
 317         nop
 318 #else
 319 #define _resume_kernel _Rexit
 320 #endif
 321
 322         ; Called at exit from fork. schedule_tail must be called to drop
 323         ; spinlock if CONFIG_PREEMPT
 324 ret_from_fork:
 325         jsr schedule_tail
 326         ba  ret_from_sys_call
 327         nop
 328
 329 ret_from_intr:
 330         ;; check for resched if preemptive kernel or if we're going back to user-mode
 331         ;; this test matches the user_regs(regs) macro
 332         ;; we cannot simply test $dccr, because that does not necessarily
 333         ;; reflect what mode we'll return into.
 334
 335         move.d  [$sp + PT_dccr], $r0; regs->dccr
 336         btstq   8, $r0          ; U-flag
 337         bpl     _resume_kernel
 338         ; Note that di below is in delay slot
 339
 340 _resume_userspace:
 341         di                      ; so need_resched and sigpending don't change
 342
 343         movs.w  -8192, $r0      ; THREAD_SIZE == 8192
 344         and.d   $sp, $r0
 345
 346         move.d  [$r0+TI_flags], $r10    ; current->work
 347         and.d   _TIF_WORK_MASK, $r10    ; is there any work to be done on return
 348         bne     _work_pending
 349         nop
 350         ba      _Rexit
 351         nop
 352
 353         ;; The system_call is called by a BREAK instruction, which works like
 354         ;; an interrupt call but it stores the return PC in BRP instead of IRP.
 355         ;; Since we dont really want to have two epilogues (one for system calls
 356         ;; and one for interrupts) we push the contents of BRP instead of IRP in the
 357         ;; system call prologue, to make it look like an ordinary interrupt on the
 358         ;; stackframe.
 359         ;;
 360         ;; Since we can't have system calls inside interrupts, it should not matter
 361         ;; that we don't stack IRP.
 362         ;;
 363         ;; In r9 we have the wanted syscall number. Arguments come in r10,r11,r12,r13,mof,srp
 364         ;;
 365         ;; This function looks on the _surface_ like spaghetti programming, but it's
 366         ;; really designed so that the fast-path does not force cache-loading of non-used
 367         ;; instructions. Only the non-common cases cause the outlined code to run..
 368
 369 system_call:
 370         ;; stack-frame similar to the irq heads, which is reversed in ret_from_sys_call
 371         move    $brp,[$sp=$sp-16]; instruction pointer and room for a fake SBFS frame
 372         push    $srp
 373         push    $dccr
 374         push    $mof
 375         subq    14*4, $sp               ; make room for r0-r13
 376         movem   $r13, [$sp]     ; push r0-r13
 377         push    $r10            ; push orig_r10
 378         clear.d [$sp=$sp-4]     ; frametype == 0, normal stackframe
 379
 380         movs.w  -ENOSYS, $r0
 381         move.d  $r0, [$sp+PT_r10]       ; put the default return value in r10 in the frame
 382
 383         ;; check if this process is syscall-traced
 384
 385         movs.w  -8192, $r0      ; THREAD_SIZE == 8192
 386         and.d   $sp, $r0
 387
 388         move.d  [$r0+TI_flags], $r0
 389         btstq   TIF_SYSCALL_TRACE, $r0
 390         bmi     _syscall_trace_entry
 391         nop
 392
 393 _syscall_traced:
 394
 395         ;; check for sanity in the requested syscall number
 396
 397         cmpu.w  NR_syscalls, $r9
 398         bcc     ret_from_sys_call
 399         lslq    2, $r9          ;  multiply by 4, in the delay slot
 400
 401         ;; as a bonus 7th parameter, we give the location on the stack
 402         ;; of the register structure itself. some syscalls need this.
 403
 404         push    $sp
 405
 406         ;; the parameter carrying registers r10, r11, r12 and 13 are intact.
 407         ;; the fifth and sixth parameters (if any) was in mof and srp
 408         ;; respectively, and we need to put them on the stack.
 409
 410         push    $srp
 411         push    $mof
 412
 413         jsr     [$r9+sys_call_table]    ; actually do the system call
 414         addq    3*4, $sp                ; pop the mof, srp and regs parameters
 415         move.d  $r10, [$sp+PT_r10]      ; save the return value
 416
 417         moveq   1, $r9          ; "parameter" to ret_from_sys_call to show it was a sys call
 418
 419         ;; fall through into ret_from_sys_call to return
 420
 421 ret_from_sys_call:
 422         ;; r9 is a parameter - if >=1 we came from a syscall, if 0, from an irq
 423
 424         ;; get the current task-struct pointer (see top for defs)
 425
 426         movs.w  -8192, $r0      ; THREAD_SIZE == 8192
 427         and.d   $sp, $r0
 428
 429         di                      ; make sure need_resched and sigpending don't change
 430         move.d  [$r0+TI_flags],$r1
 431         and.d   _TIF_ALLWORK_MASK, $r1
 432         bne     _syscall_exit_work
 433         nop
 434
 435 _Rexit:
 436         ;; this epilogue MUST match the prologues in multiple_interrupt, irq.h and ptregs.h
 437         pop     $r10            ; frametype
 438         bne     _RBFexit        ; was not CRIS_FRAME_NORMAL, handle otherwise
 439         addq    4, $sp          ; skip orig_r10, in delayslot
 440         movem   [$sp+], $r13    ; registers r0-r13
 441         pop     $mof            ; multiply overflow register
 442         pop     $dccr           ; condition codes
 443         pop     $srp            ; subroutine return pointer
 444         ;; now we have a 4-word SBFS frame which we do not want to restore
 445         ;; using RBF since it was not stacked with SBFS. instead we would like to
 446         ;; just get the PC value to restart it with, and skip the rest of
 447         ;; the frame.
 448         ;; Also notice that it's important to use instructions here that
 449         ;; keep the interrupts disabled (since we've already popped DCCR)
 450         move    [$sp=$sp+16], $p8; pop the SBFS frame from the sp
 451         jmpu    [$sp-16]        ; return through the irp field in the sbfs frame
 452
 453 _RBFexit:
 454         movem   [$sp+], $r13    ; registers r0-r13, in delay slot
 455         pop     $mof            ; multiply overflow register
 456         pop     $dccr           ; condition codes
 457         pop     $srp            ; subroutine return pointer
 458         rbf     [$sp+]          ; return by popping the CPU status
 459
 460         ;; We get here after doing a syscall if extra work might need to be done
 461         ;; perform syscall exit tracing if needed
 462
 463 _syscall_exit_work:
 464         ;; $r0 contains current at this point and irq's are disabled
 465
 466         move.d  [$r0+TI_flags], $r1
 467         btstq   TIF_SYSCALL_TRACE, $r1
 468         bpl     _work_pending
 469         nop
 470
 471         ei
 472
 473         move.d  $r9, $r1        ; preserve r9
 474         jsr     do_syscall_trace
 475         move.d  $r1, $r9
 476
 477         ba      _resume_userspace
 478         nop
 479
 480 _work_pending:
 481         move.d  [$r0+TI_flags], $r1
 482         btstq   TIF_NEED_RESCHED, $r1
 483         bpl     _work_notifysig ; was neither trace nor sched, must be signal/notify
 484         nop
 485
 486 _work_resched:
 487         move.d  $r9, $r1        ; preserve r9
 488         jsr     schedule
 489         move.d  $r1, $r9
 490         di
 491
 492         move.d  [$r0+TI_flags], $r1
 493         and.d   _TIF_WORK_MASK, $r1; ignore the syscall trace counter
 494         beq     _Rexit
 495         nop
 496         btstq   TIF_NEED_RESCHED, $r1
 497         bmi     _work_resched   ; current->work.need_resched
 498         nop
 499
 500 _work_notifysig:
 501         ;; deal with pending signals and notify-resume requests
 502
 503         move.d  $r9, $r10       ; do_notify_resume syscall/irq param
 504         moveq   0, $r11         ; oldset param - 0 in this case
 505         move.d  $sp, $r12       ; the regs param
 506         move.d  $r1, $r13       ; the thread_info_flags parameter
 507         jsr     do_notify_resume
 508
 509         ba _Rexit
 510         nop
 511
 512         ;; We get here as a sidetrack when we've entered a syscall with the
 513         ;; trace-bit set. We need to call do_syscall_trace and then continue
 514         ;; with the call.
 515
 516 _syscall_trace_entry:
 517         ;; PT_r10 in the frame contains -ENOSYS as required, at this point
 518
 519         jsr     do_syscall_trace
 520
 521         ;; now re-enter the syscall code to do the syscall itself
 522         ;; we need to restore $r9 here to contain the wanted syscall, and
 523         ;; the other parameter-bearing registers
 524
 525         move.d  [$sp+PT_r9], $r9
 526         move.d  [$sp+PT_orig_r10], $r10  ; PT_r10 is already filled with -ENOSYS.
 527         move.d  [$sp+PT_r11],      $r11
 528         move.d  [$sp+PT_r12],      $r12
 529         move.d  [$sp+PT_r13],      $r13
 530         move    [$sp+PT_mof],      $mof
 531         move    [$sp+PT_srp],      $srp
 532
 533         ba      _syscall_traced
 534         nop
 535
 536         ;; resume performs the actual task-switching, by switching stack pointers
 537         ;; input arguments: r10 = prev, r11 = next, r12 = thread offset in task struct
 538         ;; returns old current in r10
 539         ;;
 540         ;; TODO:  see the i386 version. The switch_to which calls resume in our version
 541         ;;        could really be an inline asm of this.
 542
 543 resume:
 544         push    $srp                     ; we keep the old/new PC on the stack
 545         add.d   $r12, $r10               ; r10 = current tasks tss
 546         move    $dccr, [$r10+THREAD_dccr]; save irq enable state
 547         di
 548
 549         move    $usp, [$r10+ THREAD_usp] ; save user-mode stackpointer
 550
 551         ;; See copy_thread for the reason why register R9 is saved.
 552         subq    10*4, $sp
 553         movem   $r9, [$sp]               ; save non-scratch registers and R9.
 554
 555         move.d  $sp, [$r10+THREAD_ksp]   ; save the kernel stack pointer for the old task
 556         move.d  $sp, $r10                ; return last running task in r10
 557         and.d   -8192, $r10              ; get thread_info from stackpointer
 558         move.d  [$r10+TI_task], $r10     ; get task
 559         add.d   $r12, $r11               ; find the new tasks tss
 560         move.d  [$r11+THREAD_ksp], $sp   ; switch into the new stackframe by restoring kernel sp
 561
 562         movem   [$sp+], $r9              ; restore non-scratch registers and R9.
 563
 564         move    [$r11+THREAD_usp], $usp ; restore user-mode stackpointer
 565
 566         move    [$r11+THREAD_dccr], $dccr ; restore irq enable status
 567         jump    [$sp+]                   ; restore PC
 568
 569         ;; This is the MMU bus fault handler.
 570         ;; It needs to stack the CPU status and overall is different
 571         ;; from the other interrupt handlers.
 572
 573 mmu_bus_fault:
 574         ;; For refills we try to do a quick page table lookup. If it is
 575         ;; a real fault we let the mm subsystem handle it.
 576
 577         ;; the first longword in the sbfs frame was the interrupted PC
 578         ;; which fits nicely with the "IRP" slot in pt_regs normally used to
 579         ;; contain the return address. used by Oops to print kernel errors.
 580         sbfs    [$sp=$sp-16]    ; push the internal CPU status
 581         push    $dccr
 582         di
 583         subq    2*4, $sp
 584         movem   $r1, [$sp]
 585         move.d  [R_MMU_CAUSE], $r1
 586         ;; ETRAX 100LX TR89 bugfix: if the second half of an unaligned
 587         ;; write causes a MMU-fault, it will not be restarted correctly.
 588         ;; This could happen if a write crosses a page-boundary and the
 589         ;; second page is not yet COW'ed or even loaded. The workaround
 590         ;; is to clear the unaligned bit in the CPU status record, so
 591         ;; that the CPU will rerun both the first and second halves of
 592         ;; the instruction. This will not have any sideeffects unless
 593         ;; the first half goes to any device or memory that can't be
 594         ;; written twice, and which is mapped through the MMU.
 595         ;;
 596         ;; We only need to do this for writes.
 597         btstq   8, $r1             ; Write access?
 598         bpl     1f
 599         nop
 600         move.d  [$sp+16], $r0      ; Clear unaligned bit in csrinstr
 601         and.d   ~(1<<5), $r0
 602         move.d  $r0, [$sp+16]
 603 1:      btstq   12, $r1            ; Refill?
 604         bpl     2f
 605         lsrq    24, $r1     ; Get PGD index (bit 24-31)
 606         move.d  [per_cpu__current_pgd], $r0 ; PGD for the current process
 607         move.d  [$r0+$r1.d], $r0   ; Get PMD
 608         beq     2f
 609         nop
 610         and.w   PAGE_MASK, $r0     ; Remove PMD flags
 611         move.d  [R_MMU_CAUSE], $r1
 612         lsrq    PAGE_SHIFT, $r1
 613         and.d   0x7ff, $r1         ; Get PTE index into PGD (bit 13-23)
 614         move.d  [$r0+$r1.d], $r1   ; Get PTE
 615         beq     2f
 616         nop
 617         ;; Store in TLB
 618         move.d  $r1, [R_TLB_LO]
 619         ;; Return
 620         movem   [$sp+], $r1
 621         pop     $dccr
 622         rbf     [$sp+]          ; return by popping the CPU status
 623
 624 2:      ; PMD or PTE missing, let the mm subsystem fix it up.
 625         movem   [$sp+], $r1
 626         pop     $dccr
 627
 628         ; Ok, not that easy, pass it on to the mm subsystem
 629         ; The MMU status record is now on the stack
 630         push    $srp            ; make a stackframe similar to pt_regs
 631         push    $dccr
 632         push    $mof
 633         di
 634         subq    14*4, $sp
 635         movem   $r13, [$sp]
 636         push    $r10            ; dummy orig_r10
 637         moveq   1, $r10
 638         push    $r10            ; frametype == 1, BUSFAULT frame type
 639
 640         move.d  $sp, $r10       ; pt_regs argument to handle_mmu_bus_fault
 641
 642         jsr     handle_mmu_bus_fault  ; in arch/cris/arch-v10/mm/fault.c
 643
 644         ;; now we need to return through the normal path, we cannot just
 645         ;; do the RBFexit since we might have killed off the running
 646         ;; process due to a SEGV, scheduled due to a page blocking or
 647         ;; whatever.
 648
 649         moveq   0, $r9          ; busfault is equivalent to an irq
 650
 651         ba      ret_from_intr
 652         nop
 653
 654         ;; special handlers for breakpoint and NMI
 655 hwbreakpoint:
 656         push    $dccr
 657         di
 658         push    $r10
 659         push    $r11
 660         move.d  [hw_bp_trig_ptr],$r10
 661         move    $brp,$r11
 662         move.d  $r11,[$r10+]
 663         move.d  $r10,[hw_bp_trig_ptr]
 664 1:      pop     $r11
 665         pop     $r10
 666         pop     $dccr
 667         retb
 668         nop
 669
 670 IRQ1_interrupt:
 671         ;; this prologue MUST match the one in irq.h and the struct in ptregs.h!!!
 672         move    $brp,[$sp=$sp-16]; instruction pointer and room for a fake SBFS frame
 673         push    $srp
 674         push    $dccr
 675         push    $mof
 676         di
 677         subq    14*4, $sp
 678         movem   $r13, [$sp]
 679         push    $r10            ; push orig_r10
 680         clear.d [$sp=$sp-4]     ; frametype == 0, normal frame
 681
 682         move.d  [R_IRQ_MASK0_RD], $r1 ; External NMI or watchdog?
 683         and.d   0x80000000, $r1
 684         beq     wdog
 685         move.d  $sp, $r10
 686         jsr     handle_nmi
 687         setf m                  ; Enable NMI again
 688         retb                    ; Return from NMI
 689         nop
 690 wdog:
 691 #if defined(CONFIG_ETRAX_WATCHDOG) && !defined(CONFIG_SVINTO_SIM)
 692 ;; Check if we're waiting for reset to happen, as signalled by
 693 ;; hard_reset_now setting cause_of_death to a magic value.  If so, just
 694 ;; get stuck until reset happens.
 695         .comm   cause_of_death, 4       ;; Don't declare this anywhere.
 696         move.d  [cause_of_death], $r10
 697         cmp.d   0xbedead, $r10
 698 _killed_by_death:
 699         beq     _killed_by_death
 700         nop
 701
 702 ;; We'll see this in ksymoops dumps.
 703 Watchdog_bite:
 704
 705 #ifdef CONFIG_ETRAX_WATCHDOG_NICE_DOGGY
 706        ;; We just restart the watchdog here to be sure we dont get
 707        ;; hit while printing the watchdogmsg below
 708        ;; This restart is compatible with the rest of the C-code, so
 709        ;; the C-code can keep restarting the watchdog after this point.
 710        ;; The non-NICE_DOGGY code below though, disables the possibility
 711        ;; to restart since it changes the watchdog key, to avoid any
 712        ;; buggy loops etc. keeping the watchdog alive after this.
 713        jsr     reset_watchdog
 714 #else
 715
 716 ;; We need to extend the 3.3ms after the NMI at watchdog bite, so we have
 717 ;; time for an oops-dump over a 115k2 serial wire.  Another 100ms should do.
 718
 719 ;; Change the watchdog key to an arbitrary 3-bit value and restart the
 720 ;; watchdog.
 721 #define WD_INIT 2
 722         moveq     IO_FIELD (R_WATCHDOG, key, WD_INIT), $r10
 723         move.d  R_WATCHDOG, $r11
 724
 725         move.d  $r10, [$r11]
 726         moveq     IO_FIELD (R_WATCHDOG, key,                            \
 727                             IO_EXTRACT (R_WATCHDOG, key,                \
 728                                         IO_MASK (R_WATCHDOG, key))      \
 729                             ^ WD_INIT)                                  \
 730                 | IO_STATE (R_WATCHDOG, enable, start), $r10
 731         move.d  $r10, [$r11]
 732
 733 #endif
 734
 735 ;; Note that we don't do "setf m" here (or after two necessary NOPs),
 736 ;; since *not* doing that saves us from re-entrancy checks.  We don't want
 737 ;; to get here again due to possible subsequent NMIs; we want the watchdog
 738 ;; to reset us.
 739
 740         move.d  _watchdogmsg,$r10
 741         jsr     printk
 742
 743         move.d  $sp, $r10
 744         jsr     watchdog_bite_hook
 745
 746 ;; This nop is here so we see the "Watchdog_bite" label in ksymoops dumps
 747 ;; rather than "spurious_interrupt".
 748         nop
 749 ;; At this point we drop down into spurious_interrupt, which will do a
 750 ;; hard reset.
 751
 752         .section .rodata,"a"
 753 _watchdogmsg:
 754         .ascii  "Oops: bitten by watchdog\n\0"
 755         .previous
 756
 757 #endif /* CONFIG_ETRAX_WATCHDOG and not CONFIG_SVINTO_SIM */
 758
 759 spurious_interrupt:
 760         di
 761         jump hard_reset_now
 762
 763         ;; this handles the case when multiple interrupts arrive at the same time
 764         ;; we jump to the first set interrupt bit in a priority fashion
 765         ;; the hardware will call the unserved interrupts after the handler finishes
 766
 767 multiple_interrupt:
 768         ;; this prologue MUST match the one in irq.h and the struct in ptregs.h!!!
 769         move    $irp,[$sp=$sp-16]; instruction pointer and room for a fake SBFS frame
 770         push    $srp
 771         push    $dccr
 772         push    $mof
 773         di
 774         subq    14*4, $sp
 775         movem   $r13, [$sp]
 776         push    $r10            ; push orig_r10
 777         clear.d [$sp=$sp-4]     ; frametype == 0, normal frame
 778
 779         moveq   2, $r2          ; first bit we care about is the timer0 irq
 780         move.d  [R_VECT_MASK_RD], $r0; read the irq bits that triggered the multiple irq
 781         move.d  $r0, [R_VECT_MASK_CLR] ; Block all active IRQs
 782 1:
 783         btst    $r2, $r0        ; check for the irq given by bit r2
 784         bpl     2f
 785         move.d  $r2, $r10       ; First argument to do_IRQ
 786         move.d  $sp, $r11       ; second argument to do_IRQ
 787         jsr     do_IRQ
 788 2:
 789         addq    1, $r2          ; next vector bit
 790         cmp.b   32, $r2
 791         bne     1b      ; process all irq's up to and including number 31
 792         moveq   0, $r9  ; make ret_from_intr realise we came from an ir
 793
 794         move.d  $r0, [R_VECT_MASK_SET] ;  Unblock all the IRQs
 795         jump    ret_from_intr
 796
 797 do_sigtrap:
 798         ;;
 799         ;; SIGTRAP the process that executed the break instruction.
 800         ;; Make a frame that Rexit in entry.S expects.
 801         ;;
 802         move    $brp, [$sp=$sp-16]      ; Push BRP while faking a cpu status record.
 803         push    $srp                    ; Push subroutine return pointer.
 804         push    $dccr                   ; Push condition codes.
 805         push    $mof                    ; Push multiply overflow reg.
 806         di                              ; Need to disable irq's at this point.
 807         subq    14*4, $sp               ; Make room for r0-r13.
 808         movem   $r13, [$sp]             ; Push the r0-r13 registers.
 809         push    $r10                    ; Push orig_r10.
 810         clear.d [$sp=$sp-4]             ; Frametype - this is a normal stackframe.
 811
 812         movs.w  -8192,$r9               ; THREAD_SIZE == 8192
 813         and.d   $sp, $r9
 814         move.d  [$r9+TI_task], $r10
 815         move.d  [$r10+TASK_pid], $r10   ; current->pid as arg1.
 816         moveq   5, $r11                 ; SIGTRAP as arg2.
 817         jsr     sys_kill
 818         jump    ret_from_intr           ; Use the return routine for interrupts.
 819
 820 gdb_handle_breakpoint:
 821         push    $dccr
 822         push    $r0
 823 #ifdef CONFIG_ETRAX_KGDB
 824         move    $dccr, $r0              ; U-flag not affected by previous insns.
 825         btstq   8, $r0                  ; Test the U-flag.
 826         bmi     _ugdb_handle_breakpoint ; Go to user mode debugging.
 827         nop                             ; Empty delay slot (cannot pop r0 here).
 828         pop     $r0                     ; Restore r0.
 829         ba      kgdb_handle_breakpoint  ; Go to kernel debugging.
 830         pop     $dccr                   ; Restore dccr in delay slot.
 831 #endif
 832
 833 _ugdb_handle_breakpoint:
 834         move    $brp, $r0               ; Use r0 temporarily for calculation.
 835         subq    2, $r0                  ; Set to address of previous instruction.
 836         move    $r0, $brp
 837         pop     $r0                     ; Restore r0.
 838         ba      do_sigtrap              ; SIGTRAP the offending process.
 839         pop     $dccr                   ; Restore dccr in delay slot.
 840
 841         .data
 842
 843 hw_bp_trigs:
 844         .space 64*4
 845 hw_bp_trig_ptr:
 846         .dword hw_bp_trigs
 847
 848         .section .rodata,"a"
 849 sys_call_table:
 850         .long sys_restart_syscall       /* 0 - old "setup()" system call, used for restarting */
 851         .long sys_exit
 852         .long sys_fork
 853         .long sys_read
 854         .long sys_write
 855         .long sys_open          /* 5 */
 856         .long sys_close
 857         .long sys_waitpid
 858         .long sys_creat
 859         .long sys_link
 860         .long sys_unlink        /* 10 */
 861         .long sys_execve
 862         .long sys_chdir
 863         .long sys_time
 864         .long sys_mknod
 865         .long sys_chmod         /* 15 */
 866         .long sys_lchown16
 867         .long sys_ni_syscall    /* old break syscall holder */
 868         .long sys_stat
 869         .long sys_lseek
 870         .long sys_getpid        /* 20 */
 871         .long sys_mount
 872         .long sys_oldumount
 873         .long sys_setuid16
 874         .long sys_getuid16
 875         .long sys_stime         /* 25 */
 876         .long sys_ptrace
 877         .long sys_alarm
 878         .long sys_fstat
 879         .long sys_pause
 880         .long sys_utime         /* 30 */
 881         .long sys_ni_syscall    /* old stty syscall holder */
 882         .long sys_ni_syscall    /* old gtty syscall holder */
 883         .long sys_access
 884         .long sys_nice
 885         .long sys_ni_syscall    /* 35  old ftime syscall holder */
 886         .long sys_sync
 887         .long sys_kill
 888         .long sys_rename
 889         .long sys_mkdir
 890         .long sys_rmdir         /* 40 */
 891         .long sys_dup
 892         .long sys_pipe
 893         .long sys_times
 894         .long sys_ni_syscall    /* old prof syscall holder */
 895         .long sys_brk           /* 45 */
 896         .long sys_setgid16
 897         .long sys_getgid16
 898         .long sys_signal
 899         .long sys_geteuid16
 900         .long sys_getegid16     /* 50 */
 901         .long sys_acct
 902         .long sys_umount        /* recycled never used phys( */
 903         .long sys_ni_syscall    /* old lock syscall holder */
 904         .long sys_ioctl
 905         .long sys_fcntl         /* 55 */
 906         .long sys_ni_syscall    /* old mpx syscall holder */
 907         .long sys_setpgid
 908         .long sys_ni_syscall    /* old ulimit syscall holder */
 909         .long sys_ni_syscall    /* old sys_olduname holder */
 910         .long sys_umask         /* 60 */
 911         .long sys_chroot
 912         .long sys_ustat
 913         .long sys_dup2
 914         .long sys_getppid
 915         .long sys_getpgrp       /* 65 */
 916         .long sys_setsid
 917         .long sys_sigaction
 918         .long sys_sgetmask
 919         .long sys_ssetmask
 920         .long sys_setreuid16    /* 70 */
 921         .long sys_setregid16
 922         .long sys_sigsuspend
 923         .long sys_sigpending
 924         .long sys_sethostname
 925         .long sys_setrlimit     /* 75 */
 926         .long sys_old_getrlimit
 927         .long sys_getrusage
 928         .long sys_gettimeofday
 929         .long sys_settimeofday
 930         .long sys_getgroups16   /* 80 */
 931         .long sys_setgroups16
 932         .long sys_select        /* was old_select in Linux/E100 */
 933         .long sys_symlink
 934         .long sys_lstat
 935         .long sys_readlink      /* 85 */
 936         .long sys_uselib
 937         .long sys_swapon
 938         .long sys_reboot
 939         .long old_readdir
 940         .long old_mmap          /* 90 */
 941         .long sys_munmap
 942         .long sys_truncate
 943         .long sys_ftruncate
 944         .long sys_fchmod
 945         .long sys_fchown16      /* 95 */
 946         .long sys_getpriority
 947         .long sys_setpriority
 948         .long sys_ni_syscall    /* old profil syscall holder */
 949         .long sys_statfs
 950         .long sys_fstatfs       /* 100 */
 951         .long sys_ni_syscall    /* sys_ioperm in i386 */
 952         .long sys_socketcall
 953         .long sys_syslog
 954         .long sys_setitimer
 955         .long sys_getitimer     /* 105 */
 956         .long sys_newstat
 957         .long sys_newlstat
 958         .long sys_newfstat
 959         .long sys_ni_syscall    /* old sys_uname holder */
 960         .long sys_ni_syscall    /* sys_iopl in i386 */
 961         .long sys_vhangup
 962         .long sys_ni_syscall    /* old "idle" system call */
 963         .long sys_ni_syscall    /* vm86old in i386 */
 964         .long sys_wait4
 965         .long sys_swapoff       /* 115 */
 966         .long sys_sysinfo
 967         .long sys_ipc
 968         .long sys_fsync
 969         .long sys_sigreturn
 970         .long sys_clone         /* 120 */
 971         .long sys_setdomainname
 972         .long sys_newuname
 973         .long sys_ni_syscall    /* sys_modify_ldt */
 974         .long sys_adjtimex
 975         .long sys_mprotect      /* 125 */
 976         .long sys_sigprocmask
 977         .long sys_ni_syscall    /* old "create_module" */
 978         .long sys_init_module
 979         .long sys_delete_module
 980         .long sys_ni_syscall    /* 130: old "get_kernel_syms" */
 981         .long sys_quotactl
 982         .long sys_getpgid
 983         .long sys_fchdir
 984         .long sys_bdflush
 985         .long sys_sysfs         /* 135 */
 986         .long sys_personality
 987         .long sys_ni_syscall    /* for afs_syscall */
 988         .long sys_setfsuid16
 989         .long sys_setfsgid16
 990         .long sys_llseek        /* 140 */
 991         .long sys_getdents
 992         .long sys_select
 993         .long sys_flock
 994         .long sys_msync
 995         .long sys_readv         /* 145 */
 996         .long sys_writev
 997         .long sys_getsid
 998         .long sys_fdatasync
 999         .long sys_sysctl
1000         .long sys_mlock         /* 150 */
1001         .long sys_munlock
1002         .long sys_mlockall
1003         .long sys_munlockall
1004         .long sys_sched_setparam
1005         .long sys_sched_getparam        /* 155 */
1006         .long sys_sched_setscheduler
1007         .long sys_sched_getscheduler
1008         .long sys_sched_yield
1009         .long sys_sched_get_priority_max
1010         .long sys_sched_get_priority_min        /* 160 */
1011         .long sys_sched_rr_get_interval
1012         .long sys_nanosleep
1013         .long sys_mremap
1014         .long sys_setresuid16
1015         .long sys_getresuid16   /* 165 */
1016         .long sys_ni_syscall    /* sys_vm86 */
1017         .long sys_ni_syscall    /* Old sys_query_module */
1018         .long sys_poll
1019         .long sys_nfsservctl
1020         .long sys_setresgid16   /* 170 */
1021         .long sys_getresgid16
1022         .long sys_prctl
1023         .long sys_rt_sigreturn
1024         .long sys_rt_sigaction
1025         .long sys_rt_sigprocmask        /* 175 */
1026         .long sys_rt_sigpending
1027         .long sys_rt_sigtimedwait
1028         .long sys_rt_sigqueueinfo
1029         .long sys_rt_sigsuspend
1030         .long sys_pread64       /* 180 */
1031         .long sys_pwrite64
1032         .long sys_chown16
1033         .long sys_getcwd
1034         .long sys_capget
1035         .long sys_capset        /* 185 */
1036         .long sys_sigaltstack
1037         .long sys_sendfile
1038         .long sys_ni_syscall    /* streams1 */
1039         .long sys_ni_syscall    /* streams2 */
1040         .long sys_vfork         /* 190 */
1041         .long sys_getrlimit
1042         .long sys_mmap2
1043         .long sys_truncate64
1044         .long sys_ftruncate64
1045         .long sys_stat64        /* 195 */
1046         .long sys_lstat64
1047         .long sys_fstat64
1048         .long sys_lchown
1049         .long sys_getuid
1050         .long sys_getgid        /* 200 */
1051         .long sys_geteuid
1052         .long sys_getegid
1053         .long sys_setreuid
1054         .long sys_setregid
1055         .long sys_getgroups     /* 205 */
1056         .long sys_setgroups
1057         .long sys_fchown
1058         .long sys_setresuid
1059         .long sys_getresuid
1060         .long sys_setresgid     /* 210 */
1061         .long sys_getresgid
1062         .long sys_chown
1063         .long sys_setuid
1064         .long sys_setgid
1065         .long sys_setfsuid      /* 215 */
1066         .long sys_setfsgid
1067         .long sys_pivot_root
1068         .long sys_mincore
1069         .long sys_madvise
1070         .long sys_getdents64    /* 220 */
1071         .long sys_fcntl64
1072         .long sys_ni_syscall    /* reserved for TUX */
1073         .long sys_ni_syscall
1074         .long sys_gettid
1075         .long sys_readahead     /* 225 */
1076         .long sys_setxattr
1077         .long sys_lsetxattr
1078         .long sys_fsetxattr
1079         .long sys_getxattr
1080         .long sys_lgetxattr     /* 230 */
1081         .long sys_fgetxattr
1082         .long sys_listxattr
1083         .long sys_llistxattr
1084         .long sys_flistxattr
1085         .long sys_removexattr   /* 235 */
1086         .long sys_lremovexattr
1087         .long sys_fremovexattr
1088         .long sys_tkill
1089         .long sys_sendfile64
1090         .long sys_futex         /* 240 */
1091         .long sys_sched_setaffinity
1092         .long sys_sched_getaffinity
1093         .long sys_ni_syscall    /* sys_set_thread_area */
1094         .long sys_ni_syscall    /* sys_get_thread_area */
1095         .long sys_io_setup      /* 245 */
1096         .long sys_io_destroy
1097         .long sys_io_getevents
1098         .long sys_io_submit
1099         .long sys_io_cancel
1100         .long sys_fadvise64     /* 250 */
1101         .long sys_ni_syscall
1102         .long sys_exit_group
1103         .long sys_lookup_dcookie
1104         .long sys_epoll_create
1105         .long sys_epoll_ctl     /* 255 */
1106         .long sys_epoll_wait
1107         .long sys_remap_file_pages
1108         .long sys_set_tid_address
1109         .long sys_timer_create
1110         .long sys_timer_settime         /* 260 */
1111         .long sys_timer_gettime
1112         .long sys_timer_getoverrun
1113         .long sys_timer_delete
1114         .long sys_clock_settime
1115         .long sys_clock_gettime         /* 265 */
1116         .long sys_clock_getres
1117         .long sys_clock_nanosleep
1118         .long sys_statfs64
1119         .long sys_fstatfs64
1120         .long sys_tgkill        /* 270 */
1121         .long sys_utimes
1122         .long sys_fadvise64_64
1123         .long sys_ni_syscall    /* sys_vserver */
1124         .long sys_ni_syscall    /* sys_mbind */
1125         .long sys_ni_syscall    /* 275 sys_get_mempolicy */
1126         .long sys_ni_syscall    /* sys_set_mempolicy */
1127         .long sys_mq_open
1128         .long sys_mq_unlink
1129         .long sys_mq_timedsend
1130         .long sys_mq_timedreceive       /* 280 */
1131         .long sys_mq_notify
1132         .long sys_mq_getsetattr
1133         .long sys_ni_syscall            /* reserved for kexec */
1134         .long sys_waitid
1135         .long sys_ni_syscall            /* 285 */ /* available */
1136         .long sys_add_key
1137         .long sys_request_key
1138         .long sys_keyctl
1139
1140         /*
1141          * NOTE!! This doesn't have to be exact - we just have
1142          * to make sure we have _enough_ of the "sys_ni_syscall"
1143          * entries. Don't panic if you notice that this hasn't
1144          * been shrunk every time we add a new system call.
1145          */
1146
1147         .rept NR_syscalls-(.-sys_call_table)/4
1148                 .long sys_ni_syscall
1149         .endr
1150