git.oblomov.eu Git - linux-2.6/blob - arch/x86_64/kernel/vmlinux.lds.S

   1 /* ld script to make x86-64 Linux kernel
   2  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>;
   3  */
   4
   5 #define LOAD_OFFSET __START_KERNEL_map
   6
   7 #include <asm-generic/vmlinux.lds.h>
   8 #include <asm/page.h>
   9 #include <linux/config.h>
  10
  11 #undef i386     /* in case the preprocessor is a 32bit one */
  12
  13 OUTPUT_FORMAT("elf64-x86-64", "elf64-x86-64", "elf64-x86-64")
  14 OUTPUT_ARCH(i386:x86-64)
  15 ENTRY(phys_startup_64)
  16 jiffies_64 = jiffies;
  17 SECTIONS
  18 {
  19   . = __START_KERNEL;
  20   phys_startup_64 = startup_64 - LOAD_OFFSET;
  21   _text = .;                    /* Text and read-only data */
  22   .text :  AT(ADDR(.text) - LOAD_OFFSET) {
  23         *(.bootstrap.text)
  24         *(.text)
  25         SCHED_TEXT
  26         LOCK_TEXT
  27         KPROBES_TEXT
  28         *(.fixup)
  29         *(.gnu.warning)
  30         } = 0x9090
  31                                 /* out-of-line lock text */
  32   .text.lock : AT(ADDR(.text.lock) - LOAD_OFFSET) { *(.text.lock) }
  33
  34   _etext = .;                   /* End of text section */
  35
  36   . = ALIGN(16);                /* Exception table */
  37   __start___ex_table = .;
  38   __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { *(__ex_table) }
  39   __stop___ex_table = .;
  40
  41   RODATA
  42
  43                                 /* Data */
  44   .data : AT(ADDR(.data) - LOAD_OFFSET) {
  45         *(.data)
  46         CONSTRUCTORS
  47         }
  48
  49   _edata = .;                   /* End of data section */
  50
  51   __bss_start = .;              /* BSS */
  52   .bss : AT(ADDR(.bss) - LOAD_OFFSET) {
  53         *(.bss.page_aligned)
  54         *(.bss)
  55         }
  56   __bss_stop = .;
  57
  58   . = ALIGN(PAGE_SIZE);
  59   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
  60   .data.cacheline_aligned : AT(ADDR(.data.cacheline_aligned) - LOAD_OFFSET) {
  61         *(.data.cacheline_aligned)
  62   }
  63   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
  64   .data.read_mostly : AT(ADDR(.data.read_mostly) - LOAD_OFFSET) {
  65         *(.data.read_mostly)
  66   }
  67
  68 #define VSYSCALL_ADDR (-10*1024*1024)
  69 #define VSYSCALL_PHYS_ADDR ((LOADADDR(.data.read_mostly) + SIZEOF(.data.read_mostly) + 4095) & ~(4095))
  70 #define VSYSCALL_VIRT_ADDR ((ADDR(.data.read_mostly) + SIZEOF(.data.read_mostly) + 4095) & ~(4095))
  71
  72 #define VLOAD_OFFSET (VSYSCALL_ADDR - VSYSCALL_PHYS_ADDR)
  73 #define VLOAD(x) (ADDR(x) - VLOAD_OFFSET)
  74
  75 #define VVIRT_OFFSET (VSYSCALL_ADDR - VSYSCALL_VIRT_ADDR)
  76 #define VVIRT(x) (ADDR(x) - VVIRT_OFFSET)
  77
  78   . = VSYSCALL_ADDR;
  79   .vsyscall_0 :  AT(VSYSCALL_PHYS_ADDR) { *(.vsyscall_0) }
  80   __vsyscall_0 = VSYSCALL_VIRT_ADDR;
  81
  82   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
  83   .xtime_lock : AT(VLOAD(.xtime_lock)) { *(.xtime_lock) }
  84   xtime_lock = VVIRT(.xtime_lock);
  85
  86   .vxtime : AT(VLOAD(.vxtime)) { *(.vxtime) }
  87   vxtime = VVIRT(.vxtime);
  88
  89   .wall_jiffies : AT(VLOAD(.wall_jiffies)) { *(.wall_jiffies) }
  90   wall_jiffies = VVIRT(.wall_jiffies);
  91
  92   .sys_tz : AT(VLOAD(.sys_tz)) { *(.sys_tz) }
  93   sys_tz = VVIRT(.sys_tz);
  94
  95   .sysctl_vsyscall : AT(VLOAD(.sysctl_vsyscall)) { *(.sysctl_vsyscall) }
  96   sysctl_vsyscall = VVIRT(.sysctl_vsyscall);
  97
  98   .xtime : AT(VLOAD(.xtime)) { *(.xtime) }
  99   xtime = VVIRT(.xtime);
 100
 101   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
 102   .jiffies : AT(VLOAD(.jiffies)) { *(.jiffies) }
 103   jiffies = VVIRT(.jiffies);
 104
 105   .vsyscall_1 ADDR(.vsyscall_0) + 1024: AT(VLOAD(.vsyscall_1)) { *(.vsyscall_1) }
 106   .vsyscall_2 ADDR(.vsyscall_0) + 2048: AT(VLOAD(.vsyscall_2)) { *(.vsyscall_2) }
 107   .vsyscall_3 ADDR(.vsyscall_0) + 3072: AT(VLOAD(.vsyscall_3)) { *(.vsyscall_3) }
 108
 109   . = VSYSCALL_VIRT_ADDR + 4096;
 110
 111 #undef VSYSCALL_ADDR
 112 #undef VSYSCALL_PHYS_ADDR
 113 #undef VSYSCALL_VIRT_ADDR
 114 #undef VLOAD_OFFSET
 115 #undef VLOAD
 116 #undef VVIRT_OFFSET
 117 #undef VVIRT
 118
 119   . = ALIGN(8192);              /* init_task */
 120   .data.init_task : AT(ADDR(.data.init_task) - LOAD_OFFSET) {
 121         *(.data.init_task)
 122   }
 123
 124   . = ALIGN(4096);
 125   .data.page_aligned : AT(ADDR(.data.page_aligned) - LOAD_OFFSET) {
 126         *(.data.page_aligned)
 127   }
 128
 129   . = ALIGN(4096);              /* Init code and data */
 130   __init_begin = .;
 131   .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {
 132         _sinittext = .;
 133         *(.init.text)
 134         _einittext = .;
 135   }
 136   __initdata_begin = .;
 137   .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { *(.init.data) }
 138   __initdata_end = .;
 139   . = ALIGN(16);
 140   __setup_start = .;
 141   .init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) { *(.init.setup) }
 142   __setup_end = .;
 143   __initcall_start = .;
 144   .initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET) {
 145         *(.initcall1.init)
 146         *(.initcall2.init)
 147         *(.initcall3.init)
 148         *(.initcall4.init)
 149         *(.initcall5.init)
 150         *(.initcall6.init)
 151         *(.initcall7.init)
 152   }
 153   __initcall_end = .;
 154   __con_initcall_start = .;
 155   .con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) {
 156         *(.con_initcall.init)
 157   }
 158   __con_initcall_end = .;
 159   SECURITY_INIT
 160   . = ALIGN(8);
 161   __alt_instructions = .;
 162   .altinstructions : AT(ADDR(.altinstructions) - LOAD_OFFSET) {
 163         *(.altinstructions)
 164   }
 165   __alt_instructions_end = .;
 166   .altinstr_replacement : AT(ADDR(.altinstr_replacement) - LOAD_OFFSET) {
 167         *(.altinstr_replacement)
 168   }
 169   /* .exit.text is discard at runtime, not link time, to deal with references
 170      from .altinstructions and .eh_frame */
 171   .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) { *(.exit.text) }
 172   .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) { *(.exit.data) }
 173   . = ALIGN(4096);
 174   __initramfs_start = .;
 175   .init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET) { *(.init.ramfs) }
 176   __initramfs_end = .;
 177   /* temporary here to work around NR_CPUS. If you see this comment in 2.6.17+
 178    complain */
 179   . = ALIGN(4096);
 180   __init_end = .;
 181   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
 182   __per_cpu_start = .;
 183   .data.percpu  : AT(ADDR(.data.percpu) - LOAD_OFFSET) { *(.data.percpu) }
 184   __per_cpu_end = .;
 185
 186   . = ALIGN(4096);
 187   __nosave_begin = .;
 188   .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) { *(.data.nosave) }
 189   . = ALIGN(4096);
 190   __nosave_end = .;
 191
 192   _end = . ;
 193
 194   /* Sections to be discarded */
 195   /DISCARD/ : {
 196         *(.exitcall.exit)
 197 #ifndef CONFIG_UNWIND_INFO
 198         *(.eh_frame)
 199 #endif
 200         }
 201
 202   STABS_DEBUG
 203
 204   DWARF_DEBUG
 205 }