git.oblomov.eu Git - linux-2.6/blob - arch/sparc64/kernel/sys32.S

   1 /* $Id: sys32.S,v 1.12 2000/03/24 04:17:37 davem Exp $
   2  * sys32.S: I-cache tricks for 32-bit compatibility layer simple
   3  *          conversions.
   4  *
   5  * Copyright (C) 1997 David S. Miller (davem@caip.rutgers.edu)
   6  * Copyright (C) 1998 Jakub Jelinek   (jj@ultra.linux.cz)
   7  */
   8
   9 #include <linux/config.h>
  10 #include <asm/errno.h>
  11
  12 /* NOTE: call as jump breaks return stack, we have to avoid that */
  13
  14         .text
  15
  16 #define SIGN1(STUB,SYSCALL,REG1) \
  17         .align  32; \
  18         .globl  STUB; \
  19 STUB:   sethi   %hi(SYSCALL), %g1; \
  20         jmpl    %g1 + %lo(SYSCALL), %g0; \
  21         sra     REG1, 0, REG1
  22
  23 #define SIGN2(STUB,SYSCALL,REG1,REG2) \
  24         .align  32; \
  25         .globl  STUB; \
  26 STUB:   sethi   %hi(SYSCALL), %g1; \
  27         sra     REG1, 0, REG1; \
  28         jmpl    %g1 + %lo(SYSCALL), %g0; \
  29         sra     REG2, 0, REG2
  30
  31 #define SIGN3(STUB,SYSCALL,REG1,REG2,REG3) \
  32         .align  32; \
  33         .globl  STUB; \
  34 STUB:   sra     REG1, 0, REG1; \
  35         sethi   %hi(SYSCALL), %g1; \
  36         sra     REG2, 0, REG2; \
  37         jmpl    %g1 + %lo(SYSCALL), %g0; \
  38         sra     REG3, 0, REG3
  39
  40 #define SIGN4(STUB,SYSCALL,REG1,REG2,REG3,REG4) \
  41         .align  32; \
  42         .globl  STUB; \
  43 STUB:   sra     REG1, 0, REG1; \
  44         sethi   %hi(SYSCALL), %g1; \
  45         sra     REG2, 0, REG2; \
  46         sra     REG3, 0, REG3; \
  47         jmpl    %g1 + %lo(SYSCALL), %g0; \
  48         sra     REG4, 0, REG4
  49
  50 SIGN1(sys32_exit, sparc_exit, %o0)
  51 SIGN1(sys32_exit_group, sys_exit_group, %o0)
  52 SIGN1(sys32_wait4, compat_sys_wait4, %o2)
  53 SIGN1(sys32_creat, sys_creat, %o1)
  54 SIGN1(sys32_mknod, sys_mknod, %o1)
  55 SIGN1(sys32_perfctr, sys_perfctr, %o0)
  56 SIGN1(sys32_umount, sys_umount, %o1)
  57 SIGN1(sys32_signal, sys_signal, %o0)
  58 SIGN1(sys32_access, sys_access, %o1)
  59 SIGN1(sys32_msync, sys_msync, %o2)
  60 SIGN2(sys32_reboot, sys_reboot, %o0, %o1)
  61 SIGN1(sys32_setitimer, compat_sys_setitimer, %o0)
  62 SIGN1(sys32_getitimer, compat_sys_getitimer, %o0)
  63 SIGN1(sys32_sethostname, sys_sethostname, %o1)
  64 SIGN1(sys32_swapon, sys_swapon, %o1)
  65 SIGN1(sys32_sigaction, compat_sys_sigaction, %o0)
  66 SIGN1(sys32_rt_sigaction, compat_sys_rt_sigaction, %o0)
  67 SIGN1(sys32_sigprocmask, compat_sys_sigprocmask, %o0)
  68 SIGN1(sys32_rt_sigprocmask, compat_sys_rt_sigprocmask, %o0)
  69 SIGN2(sys32_rt_sigqueueinfo, compat_sys_rt_sigqueueinfo, %o0, %o1)
  70 SIGN1(sys32_getrusage, compat_sys_getrusage, %o0)
  71 SIGN1(sys32_setxattr, sys_setxattr, %o4)
  72 SIGN1(sys32_lsetxattr, sys_lsetxattr, %o4)
  73 SIGN1(sys32_fsetxattr, sys_fsetxattr, %o4)
  74 SIGN1(sys32_fgetxattr, sys_fgetxattr, %o0)
  75 SIGN1(sys32_flistxattr, sys_flistxattr, %o0)
  76 SIGN1(sys32_fremovexattr, sys_fremovexattr, %o0)
  77 SIGN2(sys32_tkill, sys_tkill, %o0, %o1)
  78 SIGN1(sys32_epoll_create, sys_epoll_create, %o0)
  79 SIGN3(sys32_epoll_ctl, sys_epoll_ctl, %o0, %o1, %o2)
  80 SIGN3(sys32_epoll_wait, sys_epoll_wait, %o0, %o2, %o3)
  81 SIGN1(sys32_readahead, compat_sys_readahead, %o0)
  82 SIGN2(sys32_fadvise64, compat_sys_fadvise64, %o0, %o4)
  83 SIGN2(sys32_fadvise64_64, compat_sys_fadvise64_64, %o0, %o5)
  84 SIGN2(sys32_bdflush, sys_bdflush, %o0, %o1)
  85 SIGN1(sys32_mlockall, sys_mlockall, %o0)
  86 SIGN1(sys32_nfsservctl, compat_sys_nfsservctl, %o0)
  87 SIGN1(sys32_clock_settime, compat_sys_clock_settime, %o1)
  88 SIGN1(sys32_clock_nanosleep, compat_sys_clock_nanosleep, %o1)
  89 SIGN1(sys32_timer_settime, compat_sys_timer_settime, %o1)
  90 SIGN1(sys32_io_submit, compat_sys_io_submit, %o1)
  91 SIGN1(sys32_mq_open, compat_sys_mq_open, %o1)
  92 SIGN1(sys32_select, compat_sys_select, %o0)
  93 SIGN1(sys32_mkdir, sys_mkdir, %o1)
  94 SIGN3(sys32_futex, compat_sys_futex, %o1, %o2, %o5)
  95 SIGN1(sys32_sysfs, compat_sys_sysfs, %o0)
  96 SIGN3(sys32_ipc, compat_sys_ipc, %o1, %o2, %o3)
  97 SIGN2(sys32_sendfile, compat_sys_sendfile, %o0, %o1)
  98 SIGN2(sys32_sendfile64, compat_sys_sendfile64, %o0, %o1)
  99 SIGN1(sys32_prctl, sys_prctl, %o0)
 100 SIGN1(sys32_sched_rr_get_interval, compat_sys_sched_rr_get_interval, %o0)
 101 SIGN2(sys32_waitpid, sys_waitpid, %o0, %o2)
 102 SIGN1(sys32_getgroups, sys_getgroups, %o0)
 103 SIGN1(sys32_getpgid, sys_getpgid, %o0)
 104 SIGN2(sys32_getpriority, sys_getpriority, %o0, %o1)
 105 SIGN1(sys32_getsid, sys_getsid, %o0)
 106 SIGN2(sys32_kill, sys_kill, %o0, %o1)
 107 SIGN1(sys32_nice, sys_nice, %o0)
 108 SIGN1(sys32_lseek, sys_lseek, %o1)
 109 SIGN2(sys32_open, sparc32_open, %o1, %o2)
 110 SIGN1(sys32_readlink, sys_readlink, %o2)
 111 SIGN1(sys32_sched_get_priority_max, sys_sched_get_priority_max, %o0)
 112 SIGN1(sys32_sched_get_priority_min, sys_sched_get_priority_min, %o0)
 113 SIGN1(sys32_sched_getparam, sys_sched_getparam, %o0)
 114 SIGN1(sys32_sched_getscheduler, sys_sched_getscheduler, %o0)
 115 SIGN1(sys32_sched_setparam, sys_sched_setparam, %o0)
 116 SIGN2(sys32_sched_setscheduler, sys_sched_setscheduler, %o0, %o1)
 117 SIGN1(sys32_getdomainname, sys_getdomainname, %o1)
 118 SIGN1(sys32_setdomainname, sys_setdomainname, %o1)
 119 SIGN1(sys32_setgroups, sys_setgroups, %o0)
 120 SIGN2(sys32_setpgid, sys_setpgid, %o0, %o1)
 121 SIGN3(sys32_setpriority, sys_setpriority, %o0, %o1, %o2)
 122 SIGN1(sys32_ssetmask, sys_ssetmask, %o0)
 123 SIGN2(sys32_syslog, sys_syslog, %o0, %o2)
 124 SIGN1(sys32_umask, sys_umask, %o0)
 125 SIGN3(sys32_tgkill, sys_tgkill, %o0, %o1, %o2)
 126 SIGN1(sys32_sendto, sys_sendto, %o0)
 127 SIGN1(sys32_recvfrom, sys_recvfrom, %o0)
 128 SIGN3(sys32_socket, sys_socket, %o0, %o1, %o2)
 129 SIGN2(sys32_connect, sys_connect, %o0, %o2)
 130 SIGN2(sys32_bind, sys_bind, %o0, %o2)
 131 SIGN2(sys32_listen, sys_listen, %o0, %o1)
 132 SIGN1(sys32_recvmsg, compat_sys_recvmsg, %o0)
 133 SIGN1(sys32_sendmsg, compat_sys_sendmsg, %o0)
 134 SIGN2(sys32_shutdown, sys_shutdown, %o0, %o1)
 135 SIGN3(sys32_socketpair, sys_socketpair, %o0, %o1, %o2)
 136 SIGN1(sys32_getpeername, sys_getpeername, %o0)
 137 SIGN1(sys32_getsockname, sys_getsockname, %o0)
 138 SIGN2(sys32_ioprio_get, sys_ioprio_get, %o0, %o1)
 139 SIGN3(sys32_ioprio_set, sys_ioprio_set, %o0, %o1, %o2)
 140
 141         .globl          sys32_mmap2
 142 sys32_mmap2:
 143         sethi           %hi(sys_mmap), %g1
 144         jmpl            %g1 + %lo(sys_mmap), %g0
 145          sllx           %o5, 12, %o5
 146
 147         .align          32
 148         .globl          sys32_socketcall
 149 sys32_socketcall:       /* %o0=call, %o1=args */
 150         cmp             %o0, 1
 151         bl,pn           %xcc, do_einval
 152          cmp            %o0, 17
 153         bg,pn           %xcc, do_einval
 154          sub            %o0, 1, %o0
 155         sllx            %o0, 5, %o0
 156         sethi           %hi(__socketcall_table_begin), %g2
 157         or              %g2, %lo(__socketcall_table_begin), %g2
 158         jmpl            %g2 + %o0, %g0
 159          nop
 160 do_einval:
 161         retl
 162          mov            -EINVAL, %o0
 163
 164         .align          32
 165 __socketcall_table_begin:
 166
 167         /* Each entry is exactly 32 bytes. */
 168 do_sys_socket: /* sys_socket(int, int, int) */
 169 1:      ldswa           [%o1 + 0x0] %asi, %o0
 170         sethi           %hi(sys_socket), %g1
 171 2:      ldswa           [%o1 + 0x8] %asi, %o2
 172         jmpl            %g1 + %lo(sys_socket), %g0
 173 3:       ldswa          [%o1 + 0x4] %asi, %o1
 174         nop
 175         nop
 176         nop
 177 do_sys_bind: /* sys_bind(int fd, struct sockaddr *, int) */
 178 4:      ldswa           [%o1 + 0x0] %asi, %o0
 179         sethi           %hi(sys_bind), %g1
 180 5:      ldswa           [%o1 + 0x8] %asi, %o2
 181         jmpl            %g1 + %lo(sys_bind), %g0
 182 6:       lduwa          [%o1 + 0x4] %asi, %o1
 183         nop
 184         nop
 185         nop
 186 do_sys_connect: /* sys_connect(int, struct sockaddr *, int) */
 187 7:      ldswa           [%o1 + 0x0] %asi, %o0
 188         sethi           %hi(sys_connect), %g1
 189 8:      ldswa           [%o1 + 0x8] %asi, %o2
 190         jmpl            %g1 + %lo(sys_connect), %g0
 191 9:       lduwa          [%o1 + 0x4] %asi, %o1
 192         nop
 193         nop
 194         nop
 195 do_sys_listen: /* sys_listen(int, int) */
 196 10:     ldswa           [%o1 + 0x0] %asi, %o0
 197         sethi           %hi(sys_listen), %g1
 198         jmpl            %g1 + %lo(sys_listen), %g0
 199 11:      ldswa          [%o1 + 0x4] %asi, %o1
 200         nop
 201         nop
 202         nop
 203         nop
 204 do_sys_accept: /* sys_accept(int, struct sockaddr *, int *) */
 205 12:     ldswa           [%o1 + 0x0] %asi, %o0
 206         sethi           %hi(sys_accept), %g1
 207 13:     lduwa           [%o1 + 0x8] %asi, %o2
 208         jmpl            %g1 + %lo(sys_accept), %g0
 209 14:      lduwa          [%o1 + 0x4] %asi, %o1
 210         nop
 211         nop
 212         nop
 213 do_sys_getsockname: /* sys_getsockname(int, struct sockaddr *, int *) */
 214 15:     ldswa           [%o1 + 0x0] %asi, %o0
 215         sethi           %hi(sys_getsockname), %g1
 216 16:     lduwa           [%o1 + 0x8] %asi, %o2
 217         jmpl            %g1 + %lo(sys_getsockname), %g0
 218 17:      lduwa          [%o1 + 0x4] %asi, %o1
 219         nop
 220         nop
 221         nop
 222 do_sys_getpeername: /* sys_getpeername(int, struct sockaddr *, int *) */
 223 18:     ldswa           [%o1 + 0x0] %asi, %o0
 224         sethi           %hi(sys_getpeername), %g1
 225 19:     lduwa           [%o1 + 0x8] %asi, %o2
 226         jmpl            %g1 + %lo(sys_getpeername), %g0
 227 20:      lduwa          [%o1 + 0x4] %asi, %o1
 228         nop
 229         nop
 230         nop
 231 do_sys_socketpair: /* sys_socketpair(int, int, int, int *) */
 232 21:     ldswa           [%o1 + 0x0] %asi, %o0
 233         sethi           %hi(sys_socketpair), %g1
 234 22:     ldswa           [%o1 + 0x8] %asi, %o2
 235 23:     lduwa           [%o1 + 0xc] %asi, %o3
 236         jmpl            %g1 + %lo(sys_socketpair), %g0
 237 24:      ldswa          [%o1 + 0x4] %asi, %o1
 238         nop
 239         nop
 240 do_sys_send: /* sys_send(int, void *, size_t, unsigned int) */
 241 25:     ldswa           [%o1 + 0x0] %asi, %o0
 242         sethi           %hi(sys_send), %g1
 243 26:     lduwa           [%o1 + 0x8] %asi, %o2
 244 27:     lduwa           [%o1 + 0xc] %asi, %o3
 245         jmpl            %g1 + %lo(sys_send), %g0
 246 28:      lduwa          [%o1 + 0x4] %asi, %o1
 247         nop
 248         nop
 249 do_sys_recv: /* sys_recv(int, void *, size_t, unsigned int) */
 250 29:     ldswa           [%o1 + 0x0] %asi, %o0
 251         sethi           %hi(sys_recv), %g1
 252 30:     lduwa           [%o1 + 0x8] %asi, %o2
 253 31:     lduwa           [%o1 + 0xc] %asi, %o3
 254         jmpl            %g1 + %lo(sys_recv), %g0
 255 32:      lduwa          [%o1 + 0x4] %asi, %o1
 256         nop
 257         nop
 258 do_sys_sendto: /* sys_sendto(int, u32, compat_size_t, unsigned int, u32, int) */
 259 33:     ldswa           [%o1 + 0x0] %asi, %o0
 260         sethi           %hi(sys_sendto), %g1
 261 34:     lduwa           [%o1 + 0x8] %asi, %o2
 262 35:     lduwa           [%o1 + 0xc] %asi, %o3
 263 36:     lduwa           [%o1 + 0x10] %asi, %o4
 264 37:     ldswa           [%o1 + 0x14] %asi, %o5
 265         jmpl            %g1 + %lo(sys_sendto), %g0
 266 38:      lduwa          [%o1 + 0x4] %asi, %o1
 267 do_sys_recvfrom: /* sys_recvfrom(int, u32, compat_size_t, unsigned int, u32, u32) */
 268 39:     ldswa           [%o1 + 0x0] %asi, %o0
 269         sethi           %hi(sys_recvfrom), %g1
 270 40:     lduwa           [%o1 + 0x8] %asi, %o2
 271 41:     lduwa           [%o1 + 0xc] %asi, %o3
 272 42:     lduwa           [%o1 + 0x10] %asi, %o4
 273 43:     lduwa           [%o1 + 0x14] %asi, %o5
 274         jmpl            %g1 + %lo(sys_recvfrom), %g0
 275 44:      lduwa          [%o1 + 0x4] %asi, %o1
 276 do_sys_shutdown: /* sys_shutdown(int, int) */
 277 45:     ldswa           [%o1 + 0x0] %asi, %o0
 278         sethi           %hi(sys_shutdown), %g1
 279         jmpl            %g1 + %lo(sys_shutdown), %g0
 280 46:      ldswa          [%o1 + 0x4] %asi, %o1
 281         nop
 282         nop
 283         nop
 284         nop
 285 do_sys_setsockopt: /* compat_sys_setsockopt(int, int, int, char *, int) */
 286 47:     ldswa           [%o1 + 0x0] %asi, %o0
 287         sethi           %hi(compat_sys_setsockopt), %g1
 288 48:     ldswa           [%o1 + 0x8] %asi, %o2
 289 49:     lduwa           [%o1 + 0xc] %asi, %o3
 290 50:     ldswa           [%o1 + 0x10] %asi, %o4
 291         jmpl            %g1 + %lo(compat_sys_setsockopt), %g0
 292 51:      ldswa          [%o1 + 0x4] %asi, %o1
 293         nop
 294 do_sys_getsockopt: /* compat_sys_getsockopt(int, int, int, u32, u32) */
 295 52:     ldswa           [%o1 + 0x0] %asi, %o0
 296         sethi           %hi(compat_sys_getsockopt), %g1
 297 53:     ldswa           [%o1 + 0x8] %asi, %o2
 298 54:     lduwa           [%o1 + 0xc] %asi, %o3
 299 55:     lduwa           [%o1 + 0x10] %asi, %o4
 300         jmpl            %g1 + %lo(compat_sys_getsockopt), %g0
 301 56:      ldswa          [%o1 + 0x4] %asi, %o1
 302         nop
 303 do_sys_sendmsg: /* compat_sys_sendmsg(int, struct compat_msghdr *, unsigned int) */
 304 57:     ldswa           [%o1 + 0x0] %asi, %o0
 305         sethi           %hi(compat_sys_sendmsg), %g1
 306 58:     lduwa           [%o1 + 0x8] %asi, %o2
 307         jmpl            %g1 + %lo(compat_sys_sendmsg), %g0
 308 59:      lduwa          [%o1 + 0x4] %asi, %o1
 309         nop
 310         nop
 311         nop
 312 do_sys_recvmsg: /* compat_sys_recvmsg(int, struct compat_msghdr *, unsigned int) */
 313 60:     ldswa           [%o1 + 0x0] %asi, %o0
 314         sethi           %hi(compat_sys_recvmsg), %g1
 315 61:     lduwa           [%o1 + 0x8] %asi, %o2
 316         jmpl            %g1 + %lo(compat_sys_recvmsg), %g0
 317 62:      lduwa          [%o1 + 0x4] %asi, %o1
 318         nop
 319         nop
 320         nop
 321
 322         .section        __ex_table
 323         .align          4
 324         .word           1b, __retl_efault, 2b, __retl_efault
 325         .word           3b, __retl_efault, 4b, __retl_efault
 326         .word           5b, __retl_efault, 6b, __retl_efault
 327         .word           7b, __retl_efault, 8b, __retl_efault
 328         .word           9b, __retl_efault, 10b, __retl_efault
 329         .word           11b, __retl_efault, 12b, __retl_efault
 330         .word           13b, __retl_efault, 14b, __retl_efault
 331         .word           15b, __retl_efault, 16b, __retl_efault
 332         .word           17b, __retl_efault, 18b, __retl_efault
 333         .word           19b, __retl_efault, 20b, __retl_efault
 334         .word           21b, __retl_efault, 22b, __retl_efault
 335         .word           23b, __retl_efault, 24b, __retl_efault
 336         .word           25b, __retl_efault, 26b, __retl_efault
 337         .word           27b, __retl_efault, 28b, __retl_efault
 338         .word           29b, __retl_efault, 30b, __retl_efault
 339         .word           31b, __retl_efault, 32b, __retl_efault
 340         .word           33b, __retl_efault, 34b, __retl_efault
 341         .word           35b, __retl_efault, 36b, __retl_efault
 342         .word           37b, __retl_efault, 38b, __retl_efault
 343         .word           39b, __retl_efault, 40b, __retl_efault
 344         .word           41b, __retl_efault, 42b, __retl_efault
 345         .word           43b, __retl_efault, 44b, __retl_efault
 346         .word           45b, __retl_efault, 46b, __retl_efault
 347         .word           47b, __retl_efault, 48b, __retl_efault
 348         .word           49b, __retl_efault, 50b, __retl_efault
 349         .word           51b, __retl_efault, 52b, __retl_efault
 350         .word           53b, __retl_efault, 54b, __retl_efault
 351         .word           55b, __retl_efault, 56b, __retl_efault
 352         .word           57b, __retl_efault, 58b, __retl_efault
 353         .word           59b, __retl_efault, 60b, __retl_efault
 354         .word           61b, __retl_efault, 62b, __retl_efault
 355         .previous