git.oblomov.eu Git - linux-2.6/blob - include/asm-generic/vmlinux.lds.h

   1 #include <linux/section-names.h>
   2
   3 #ifndef LOAD_OFFSET
   4 #define LOAD_OFFSET 0
   5 #endif
   6
   7 #ifndef VMLINUX_SYMBOL
   8 #define VMLINUX_SYMBOL(_sym_) _sym_
   9 #endif
  10
  11 /* Align . to a 8 byte boundary equals to maximum function alignment. */
  12 #define ALIGN_FUNCTION()  . = ALIGN(8)
  13
  14 /* The actual configuration determine if the init/exit sections
  15  * are handled as text/data or they can be discarded (which
  16  * often happens at runtime)
  17  */
  18 #ifdef CONFIG_HOTPLUG
  19 #define DEV_KEEP(sec)    *(.dev##sec)
  20 #define DEV_DISCARD(sec)
  21 #else
  22 #define DEV_KEEP(sec)
  23 #define DEV_DISCARD(sec) *(.dev##sec)
  24 #endif
  25
  26 #ifdef CONFIG_HOTPLUG_CPU
  27 #define CPU_KEEP(sec)    *(.cpu##sec)
  28 #define CPU_DISCARD(sec)
  29 #else
  30 #define CPU_KEEP(sec)
  31 #define CPU_DISCARD(sec) *(.cpu##sec)
  32 #endif
  33
  34 #if defined(CONFIG_MEMORY_HOTPLUG)
  35 #define MEM_KEEP(sec)    *(.mem##sec)
  36 #define MEM_DISCARD(sec)
  37 #else
  38 #define MEM_KEEP(sec)
  39 #define MEM_DISCARD(sec) *(.mem##sec)
  40 #endif
  41
  42 #ifdef CONFIG_FTRACE_MCOUNT_RECORD
  43 #define MCOUNT_REC()    VMLINUX_SYMBOL(__start_mcount_loc) = .; \
  44                         *(__mcount_loc)                         \
  45                         VMLINUX_SYMBOL(__stop_mcount_loc) = .;
  46 #else
  47 #define MCOUNT_REC()
  48 #endif
  49
  50 #ifdef CONFIG_TRACE_BRANCH_PROFILING
  51 #define LIKELY_PROFILE()        VMLINUX_SYMBOL(__start_annotated_branch_profile) = .; \
  52                                 *(_ftrace_annotated_branch)                           \
  53                                 VMLINUX_SYMBOL(__stop_annotated_branch_profile) = .;
  54 #else
  55 #define LIKELY_PROFILE()
  56 #endif
  57
  58 #ifdef CONFIG_PROFILE_ALL_BRANCHES
  59 #define BRANCH_PROFILE()        VMLINUX_SYMBOL(__start_branch_profile) = .;   \
  60                                 *(_ftrace_branch)                             \
  61                                 VMLINUX_SYMBOL(__stop_branch_profile) = .;
  62 #else
  63 #define BRANCH_PROFILE()
  64 #endif
  65
  66 #ifdef CONFIG_EVENT_TRACER
  67 #define FTRACE_EVENTS() VMLINUX_SYMBOL(__start_ftrace_events) = .;      \
  68                         *(_ftrace_events)                               \
  69                         VMLINUX_SYMBOL(__stop_ftrace_events) = .;
  70 #else
  71 #define FTRACE_EVENTS()
  72 #endif
  73
  74 #ifdef CONFIG_TRACING
  75 #define TRACE_PRINTKS() VMLINUX_SYMBOL(__start___trace_bprintk_fmt) = .;      \
  76                          *(__trace_printk_fmt) /* Trace_printk fmt' pointer */ \
  77                          VMLINUX_SYMBOL(__stop___trace_bprintk_fmt) = .;
  78 #else
  79 #define TRACE_PRINTKS()
  80 #endif
  81
  82 #ifdef CONFIG_FTRACE_SYSCALLS
  83 #define TRACE_SYSCALLS() VMLINUX_SYMBOL(__start_syscalls_metadata) = .; \
  84                          *(__syscalls_metadata)                         \
  85                          VMLINUX_SYMBOL(__stop_syscalls_metadata) = .;
  86 #else
  87 #define TRACE_SYSCALLS()
  88 #endif
  89
  90 /* .data section */
  91 #define DATA_DATA                                                       \
  92         *(.data)                                                        \
  93         *(.data.init.refok)                                             \
  94         *(.ref.data)                                                    \
  95         DEV_KEEP(init.data)                                             \
  96         DEV_KEEP(exit.data)                                             \
  97         CPU_KEEP(init.data)                                             \
  98         CPU_KEEP(exit.data)                                             \
  99         MEM_KEEP(init.data)                                             \
 100         MEM_KEEP(exit.data)                                             \
 101         . = ALIGN(8);                                                   \
 102         VMLINUX_SYMBOL(__start___markers) = .;                          \
 103         *(__markers)                                                    \
 104         VMLINUX_SYMBOL(__stop___markers) = .;                           \
 105         . = ALIGN(32);                                                  \
 106         VMLINUX_SYMBOL(__start___tracepoints) = .;                      \
 107         *(__tracepoints)                                                \
 108         VMLINUX_SYMBOL(__stop___tracepoints) = .;                       \
 109         /* implement dynamic printk debug */                            \
 110         . = ALIGN(8);                                                   \
 111         VMLINUX_SYMBOL(__start___verbose) = .;                          \
 112         *(__verbose)                                                    \
 113         VMLINUX_SYMBOL(__stop___verbose) = .;                           \
 114         LIKELY_PROFILE()                                                \
 115         BRANCH_PROFILE()                                                \
 116         TRACE_PRINTKS()                                                 \
 117         FTRACE_EVENTS()                                                 \
 118         TRACE_SYSCALLS()
 119
 120 #define RO_DATA(align)                                                  \
 121         . = ALIGN((align));                                             \
 122         .rodata           : AT(ADDR(.rodata) - LOAD_OFFSET) {           \
 123                 VMLINUX_SYMBOL(__start_rodata) = .;                     \
 124                 *(.rodata) *(.rodata.*)                                 \
 125                 *(__vermagic)           /* Kernel version magic */      \
 126                 *(__markers_strings)    /* Markers: strings */          \
 127                 *(__tracepoints_strings)/* Tracepoints: strings */      \
 128         }                                                               \
 129                                                                         \
 130         .rodata1          : AT(ADDR(.rodata1) - LOAD_OFFSET) {          \
 131                 *(.rodata1)                                             \
 132         }                                                               \
 133                                                                         \
 134         BUG_TABLE                                                       \
 135                                                                         \
 136         /* PCI quirks */                                                \
 137         .pci_fixup        : AT(ADDR(.pci_fixup) - LOAD_OFFSET) {        \
 138                 VMLINUX_SYMBOL(__start_pci_fixups_early) = .;           \
 139                 *(.pci_fixup_early)                                     \
 140                 VMLINUX_SYMBOL(__end_pci_fixups_early) = .;             \
 141                 VMLINUX_SYMBOL(__start_pci_fixups_header) = .;          \
 142                 *(.pci_fixup_header)                                    \
 143                 VMLINUX_SYMBOL(__end_pci_fixups_header) = .;            \
 144                 VMLINUX_SYMBOL(__start_pci_fixups_final) = .;           \
 145                 *(.pci_fixup_final)                                     \
 146                 VMLINUX_SYMBOL(__end_pci_fixups_final) = .;             \
 147                 VMLINUX_SYMBOL(__start_pci_fixups_enable) = .;          \
 148                 *(.pci_fixup_enable)                                    \
 149                 VMLINUX_SYMBOL(__end_pci_fixups_enable) = .;            \
 150                 VMLINUX_SYMBOL(__start_pci_fixups_resume) = .;          \
 151                 *(.pci_fixup_resume)                                    \
 152                 VMLINUX_SYMBOL(__end_pci_fixups_resume) = .;            \
 153                 VMLINUX_SYMBOL(__start_pci_fixups_resume_early) = .;    \
 154                 *(.pci_fixup_resume_early)                              \
 155                 VMLINUX_SYMBOL(__end_pci_fixups_resume_early) = .;      \
 156                 VMLINUX_SYMBOL(__start_pci_fixups_suspend) = .;         \
 157                 *(.pci_fixup_suspend)                                   \
 158                 VMLINUX_SYMBOL(__end_pci_fixups_suspend) = .;           \
 159         }                                                               \
 160                                                                         \
 161         /* Built-in firmware blobs */                                   \
 162         .builtin_fw        : AT(ADDR(.builtin_fw) - LOAD_OFFSET) {      \
 163                 VMLINUX_SYMBOL(__start_builtin_fw) = .;                 \
 164                 *(.builtin_fw)                                          \
 165                 VMLINUX_SYMBOL(__end_builtin_fw) = .;                   \
 166         }                                                               \
 167                                                                         \
 168         /* RapidIO route ops */                                         \
 169         .rio_route        : AT(ADDR(.rio_route) - LOAD_OFFSET) {        \
 170                 VMLINUX_SYMBOL(__start_rio_route_ops) = .;              \
 171                 *(.rio_route_ops)                                       \
 172                 VMLINUX_SYMBOL(__end_rio_route_ops) = .;                \
 173         }                                                               \
 174                                                                         \
 175         TRACEDATA                                                       \
 176                                                                         \
 177         /* Kernel symbol table: Normal symbols */                       \
 178         __ksymtab         : AT(ADDR(__ksymtab) - LOAD_OFFSET) {         \
 179                 VMLINUX_SYMBOL(__start___ksymtab) = .;                  \
 180                 *(__ksymtab)                                            \
 181                 VMLINUX_SYMBOL(__stop___ksymtab) = .;                   \
 182         }                                                               \
 183                                                                         \
 184         /* Kernel symbol table: GPL-only symbols */                     \
 185         __ksymtab_gpl     : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) {     \
 186                 VMLINUX_SYMBOL(__start___ksymtab_gpl) = .;              \
 187                 *(__ksymtab_gpl)                                        \
 188                 VMLINUX_SYMBOL(__stop___ksymtab_gpl) = .;               \
 189         }                                                               \
 190                                                                         \
 191         /* Kernel symbol table: Normal unused symbols */                \
 192         __ksymtab_unused  : AT(ADDR(__ksymtab_unused) - LOAD_OFFSET) {  \
 193                 VMLINUX_SYMBOL(__start___ksymtab_unused) = .;           \
 194                 *(__ksymtab_unused)                                     \
 195                 VMLINUX_SYMBOL(__stop___ksymtab_unused) = .;            \
 196         }                                                               \
 197                                                                         \
 198         /* Kernel symbol table: GPL-only unused symbols */              \
 199         __ksymtab_unused_gpl : AT(ADDR(__ksymtab_unused_gpl) - LOAD_OFFSET) { \
 200                 VMLINUX_SYMBOL(__start___ksymtab_unused_gpl) = .;       \
 201                 *(__ksymtab_unused_gpl)                                 \
 202                 VMLINUX_SYMBOL(__stop___ksymtab_unused_gpl) = .;        \
 203         }                                                               \
 204                                                                         \
 205         /* Kernel symbol table: GPL-future-only symbols */              \
 206         __ksymtab_gpl_future : AT(ADDR(__ksymtab_gpl_future) - LOAD_OFFSET) { \
 207                 VMLINUX_SYMBOL(__start___ksymtab_gpl_future) = .;       \
 208                 *(__ksymtab_gpl_future)                                 \
 209                 VMLINUX_SYMBOL(__stop___ksymtab_gpl_future) = .;        \
 210         }                                                               \
 211                                                                         \
 212         /* Kernel symbol table: Normal symbols */                       \
 213         __kcrctab         : AT(ADDR(__kcrctab) - LOAD_OFFSET) {         \
 214                 VMLINUX_SYMBOL(__start___kcrctab) = .;                  \
 215                 *(__kcrctab)                                            \
 216                 VMLINUX_SYMBOL(__stop___kcrctab) = .;                   \
 217         }                                                               \
 218                                                                         \
 219         /* Kernel symbol table: GPL-only symbols */                     \
 220         __kcrctab_gpl     : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) {     \
 221                 VMLINUX_SYMBOL(__start___kcrctab_gpl) = .;              \
 222                 *(__kcrctab_gpl)                                        \
 223                 VMLINUX_SYMBOL(__stop___kcrctab_gpl) = .;               \
 224         }                                                               \
 225                                                                         \
 226         /* Kernel symbol table: Normal unused symbols */                \
 227         __kcrctab_unused  : AT(ADDR(__kcrctab_unused) - LOAD_OFFSET) {  \
 228                 VMLINUX_SYMBOL(__start___kcrctab_unused) = .;           \
 229                 *(__kcrctab_unused)                                     \
 230                 VMLINUX_SYMBOL(__stop___kcrctab_unused) = .;            \
 231         }                                                               \
 232                                                                         \
 233         /* Kernel symbol table: GPL-only unused symbols */              \
 234         __kcrctab_unused_gpl : AT(ADDR(__kcrctab_unused_gpl) - LOAD_OFFSET) { \
 235                 VMLINUX_SYMBOL(__start___kcrctab_unused_gpl) = .;       \
 236                 *(__kcrctab_unused_gpl)                                 \
 237                 VMLINUX_SYMBOL(__stop___kcrctab_unused_gpl) = .;        \
 238         }                                                               \
 239                                                                         \
 240         /* Kernel symbol table: GPL-future-only symbols */              \
 241         __kcrctab_gpl_future : AT(ADDR(__kcrctab_gpl_future) - LOAD_OFFSET) { \
 242                 VMLINUX_SYMBOL(__start___kcrctab_gpl_future) = .;       \
 243                 *(__kcrctab_gpl_future)                                 \
 244                 VMLINUX_SYMBOL(__stop___kcrctab_gpl_future) = .;        \
 245         }                                                               \
 246                                                                         \
 247         /* Kernel symbol table: strings */                              \
 248         __ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) { \
 249                 *(__ksymtab_strings)                                    \
 250         }                                                               \
 251                                                                         \
 252         /* __*init sections */                                          \
 253         __init_rodata : AT(ADDR(__init_rodata) - LOAD_OFFSET) {         \
 254                 *(.ref.rodata)                                          \
 255                 MCOUNT_REC()                                            \
 256                 DEV_KEEP(init.rodata)                                   \
 257                 DEV_KEEP(exit.rodata)                                   \
 258                 CPU_KEEP(init.rodata)                                   \
 259                 CPU_KEEP(exit.rodata)                                   \
 260                 MEM_KEEP(init.rodata)                                   \
 261                 MEM_KEEP(exit.rodata)                                   \
 262         }                                                               \
 263                                                                         \
 264         /* Built-in module parameters. */                               \
 265         __param : AT(ADDR(__param) - LOAD_OFFSET) {                     \
 266                 VMLINUX_SYMBOL(__start___param) = .;                    \
 267                 *(__param)                                              \
 268                 VMLINUX_SYMBOL(__stop___param) = .;                     \
 269                 . = ALIGN((align));                                     \
 270                 VMLINUX_SYMBOL(__end_rodata) = .;                       \
 271         }                                                               \
 272         . = ALIGN((align));
 273
 274 /* RODATA provided for backward compatibility.
 275  * All archs are supposed to use RO_DATA() */
 276 #define RODATA RO_DATA(4096)
 277
 278 #define SECURITY_INIT                                                   \
 279         .security_initcall.init : AT(ADDR(.security_initcall.init) - LOAD_OFFSET) { \
 280                 VMLINUX_SYMBOL(__security_initcall_start) = .;          \
 281                 *(.security_initcall.init)                              \
 282                 VMLINUX_SYMBOL(__security_initcall_end) = .;            \
 283         }
 284
 285 /* .text section. Map to function alignment to avoid address changes
 286  * during second ld run in second ld pass when generating System.map */
 287 #define TEXT_TEXT                                                       \
 288                 ALIGN_FUNCTION();                                       \
 289                 *(.text.hot)                                            \
 290                 *(.text)                                                \
 291                 *(.ref.text)                                            \
 292                 *(.text.init.refok)                                     \
 293                 *(.exit.text.refok)                                     \
 294         DEV_KEEP(init.text)                                             \
 295         DEV_KEEP(exit.text)                                             \
 296         CPU_KEEP(init.text)                                             \
 297         CPU_KEEP(exit.text)                                             \
 298         MEM_KEEP(init.text)                                             \
 299         MEM_KEEP(exit.text)                                             \
 300                 *(.text.unlikely)
 301
 302
 303 /* sched.text is aling to function alignment to secure we have same
 304  * address even at second ld pass when generating System.map */
 305 #define SCHED_TEXT                                                      \
 306                 ALIGN_FUNCTION();                                       \
 307                 VMLINUX_SYMBOL(__sched_text_start) = .;                 \
 308                 *(.sched.text)                                          \
 309                 VMLINUX_SYMBOL(__sched_text_end) = .;
 310
 311 /* spinlock.text is aling to function alignment to secure we have same
 312  * address even at second ld pass when generating System.map */
 313 #define LOCK_TEXT                                                       \
 314                 ALIGN_FUNCTION();                                       \
 315                 VMLINUX_SYMBOL(__lock_text_start) = .;                  \
 316                 *(.spinlock.text)                                       \
 317                 VMLINUX_SYMBOL(__lock_text_end) = .;
 318
 319 #define KPROBES_TEXT                                                    \
 320                 ALIGN_FUNCTION();                                       \
 321                 VMLINUX_SYMBOL(__kprobes_text_start) = .;               \
 322                 *(.kprobes.text)                                        \
 323                 VMLINUX_SYMBOL(__kprobes_text_end) = .;
 324
 325 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 326 #define IRQENTRY_TEXT                                                   \
 327                 ALIGN_FUNCTION();                                       \
 328                 VMLINUX_SYMBOL(__irqentry_text_start) = .;              \
 329                 *(.irqentry.text)                                       \
 330                 VMLINUX_SYMBOL(__irqentry_text_end) = .;
 331 #else
 332 #define IRQENTRY_TEXT
 333 #endif
 334
 335 /* Section used for early init (in .S files) */
 336 #define HEAD_TEXT  *(HEAD_TEXT_SECTION)
 337
 338 /* init and exit section handling */
 339 #define INIT_DATA                                                       \
 340         *(.init.data)                                                   \
 341         DEV_DISCARD(init.data)                                          \
 342         DEV_DISCARD(init.rodata)                                        \
 343         CPU_DISCARD(init.data)                                          \
 344         CPU_DISCARD(init.rodata)                                        \
 345         MEM_DISCARD(init.data)                                          \
 346         MEM_DISCARD(init.rodata)
 347
 348 #define INIT_TEXT                                                       \
 349         *(.init.text)                                                   \
 350         DEV_DISCARD(init.text)                                          \
 351         CPU_DISCARD(init.text)                                          \
 352         MEM_DISCARD(init.text)
 353
 354 #define EXIT_DATA                                                       \
 355         *(.exit.data)                                                   \
 356         DEV_DISCARD(exit.data)                                          \
 357         DEV_DISCARD(exit.rodata)                                        \
 358         CPU_DISCARD(exit.data)                                          \
 359         CPU_DISCARD(exit.rodata)                                        \
 360         MEM_DISCARD(exit.data)                                          \
 361         MEM_DISCARD(exit.rodata)
 362
 363 #define EXIT_TEXT                                                       \
 364         *(.exit.text)                                                   \
 365         DEV_DISCARD(exit.text)                                          \
 366         CPU_DISCARD(exit.text)                                          \
 367         MEM_DISCARD(exit.text)
 368
 369                 /* DWARF debug sections.
 370                 Symbols in the DWARF debugging sections are relative to
 371                 the beginning of the section so we begin them at 0.  */
 372 #define DWARF_DEBUG                                                     \
 373                 /* DWARF 1 */                                           \
 374                 .debug          0 : { *(.debug) }                       \
 375                 .line           0 : { *(.line) }                        \
 376                 /* GNU DWARF 1 extensions */                            \
 377                 .debug_srcinfo  0 : { *(.debug_srcinfo) }               \
 378                 .debug_sfnames  0 : { *(.debug_sfnames) }               \
 379                 /* DWARF 1.1 and DWARF 2 */                             \
 380                 .debug_aranges  0 : { *(.debug_aranges) }               \
 381                 .debug_pubnames 0 : { *(.debug_pubnames) }              \
 382                 /* DWARF 2 */                                           \
 383                 .debug_info     0 : { *(.debug_info                     \
 384                                 .gnu.linkonce.wi.*) }                   \
 385                 .debug_abbrev   0 : { *(.debug_abbrev) }                \
 386                 .debug_line     0 : { *(.debug_line) }                  \
 387                 .debug_frame    0 : { *(.debug_frame) }                 \
 388                 .debug_str      0 : { *(.debug_str) }                   \
 389                 .debug_loc      0 : { *(.debug_loc) }                   \
 390                 .debug_macinfo  0 : { *(.debug_macinfo) }               \
 391                 /* SGI/MIPS DWARF 2 extensions */                       \
 392                 .debug_weaknames 0 : { *(.debug_weaknames) }            \
 393                 .debug_funcnames 0 : { *(.debug_funcnames) }            \
 394                 .debug_typenames 0 : { *(.debug_typenames) }            \
 395                 .debug_varnames  0 : { *(.debug_varnames) }             \
 396
 397                 /* Stabs debugging sections.  */
 398 #define STABS_DEBUG                                                     \
 399                 .stab 0 : { *(.stab) }                                  \
 400                 .stabstr 0 : { *(.stabstr) }                            \
 401                 .stab.excl 0 : { *(.stab.excl) }                        \
 402                 .stab.exclstr 0 : { *(.stab.exclstr) }                  \
 403                 .stab.index 0 : { *(.stab.index) }                      \
 404                 .stab.indexstr 0 : { *(.stab.indexstr) }                \
 405                 .comment 0 : { *(.comment) }
 406
 407 #ifdef CONFIG_GENERIC_BUG
 408 #define BUG_TABLE                                                       \
 409         . = ALIGN(8);                                                   \
 410         __bug_table : AT(ADDR(__bug_table) - LOAD_OFFSET) {             \
 411                 VMLINUX_SYMBOL(__start___bug_table) = .;                \
 412                 *(__bug_table)                                          \
 413                 VMLINUX_SYMBOL(__stop___bug_table) = .;                 \
 414         }
 415 #else
 416 #define BUG_TABLE
 417 #endif
 418
 419 #ifdef CONFIG_PM_TRACE
 420 #define TRACEDATA                                                       \
 421         . = ALIGN(4);                                                   \
 422         .tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) {               \
 423                 VMLINUX_SYMBOL(__tracedata_start) = .;                  \
 424                 *(.tracedata)                                           \
 425                 VMLINUX_SYMBOL(__tracedata_end) = .;                    \
 426         }
 427 #else
 428 #define TRACEDATA
 429 #endif
 430
 431 #define NOTES                                                           \
 432         .notes : AT(ADDR(.notes) - LOAD_OFFSET) {                       \
 433                 VMLINUX_SYMBOL(__start_notes) = .;                      \
 434                 *(.note.*)                                              \
 435                 VMLINUX_SYMBOL(__stop_notes) = .;                       \
 436         }
 437
 438 #define INITCALLS                                                       \
 439         *(.initcallearly.init)                                          \
 440         VMLINUX_SYMBOL(__early_initcall_end) = .;                       \
 441         *(.initcall0.init)                                              \
 442         *(.initcall0s.init)                                             \
 443         *(.initcall1.init)                                              \
 444         *(.initcall1s.init)                                             \
 445         *(.initcall2.init)                                              \
 446         *(.initcall2s.init)                                             \
 447         *(.initcall3.init)                                              \
 448         *(.initcall3s.init)                                             \
 449         *(.initcall4.init)                                              \
 450         *(.initcall4s.init)                                             \
 451         *(.initcall5.init)                                              \
 452         *(.initcall5s.init)                                             \
 453         *(.initcallrootfs.init)                                         \
 454         *(.initcall6.init)                                              \
 455         *(.initcall6s.init)                                             \
 456         *(.initcall7.init)                                              \
 457         *(.initcall7s.init)
 458
 459 /**
 460  * PERCPU_VADDR - define output section for percpu area
 461  * @vaddr: explicit base address (optional)
 462  * @phdr: destination PHDR (optional)
 463  *
 464  * Macro which expands to output section for percpu area.  If @vaddr
 465  * is not blank, it specifies explicit base address and all percpu
 466  * symbols will be offset from the given address.  If blank, @vaddr
 467  * always equals @laddr + LOAD_OFFSET.
 468  *
 469  * @phdr defines the output PHDR to use if not blank.  Be warned that
 470  * output PHDR is sticky.  If @phdr is specified, the next output
 471  * section in the linker script will go there too.  @phdr should have
 472  * a leading colon.
 473  *
 474  * Note that this macros defines __per_cpu_load as an absolute symbol.
 475  * If there is no need to put the percpu section at a predetermined
 476  * address, use PERCPU().
 477  */
 478 #define PERCPU_VADDR(vaddr, phdr)                                       \
 479         VMLINUX_SYMBOL(__per_cpu_load) = .;                             \
 480         .data.percpu vaddr : AT(VMLINUX_SYMBOL(__per_cpu_load)          \
 481                                 - LOAD_OFFSET) {                        \
 482                 VMLINUX_SYMBOL(__per_cpu_start) = .;                    \
 483                 *(.data.percpu.first)                                   \
 484                 *(.data.percpu.page_aligned)                            \
 485                 *(.data.percpu)                                         \
 486                 *(.data.percpu.shared_aligned)                          \
 487                 VMLINUX_SYMBOL(__per_cpu_end) = .;                      \
 488         } phdr                                                          \
 489         . = VMLINUX_SYMBOL(__per_cpu_load) + SIZEOF(.data.percpu);
 490
 491 /**
 492  * PERCPU - define output section for percpu area, simple version
 493  * @align: required alignment
 494  *
 495  * Align to @align and outputs output section for percpu area.  This
 496  * macro doesn't maniuplate @vaddr or @phdr and __per_cpu_load and
 497  * __per_cpu_start will be identical.
 498  *
 499  * This macro is equivalent to ALIGN(align); PERCPU_VADDR( , ) except
 500  * that __per_cpu_load is defined as a relative symbol against
 501  * .data.percpu which is required for relocatable x86_32
 502  * configuration.
 503  */
 504 #define PERCPU(align)                                                   \
 505         . = ALIGN(align);                                               \
 506         .data.percpu    : AT(ADDR(.data.percpu) - LOAD_OFFSET) {        \
 507                 VMLINUX_SYMBOL(__per_cpu_load) = .;                     \
 508                 VMLINUX_SYMBOL(__per_cpu_start) = .;                    \
 509                 *(.data.percpu.first)                                   \
 510                 *(.data.percpu.page_aligned)                            \
 511                 *(.data.percpu)                                         \
 512                 *(.data.percpu.shared_aligned)                          \
 513                 VMLINUX_SYMBOL(__per_cpu_end) = .;                      \
 514         }