git.oblomov.eu Git - linux-2.6/blob - arch/arm/boot/compressed/vmlinux.lds.in

   1 /*
   2  *  linux/arch/arm/boot/compressed/vmlinux.lds.in
   3  *
   4  *  Copyright (C) 2000 Russell King
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  */
  10 OUTPUT_ARCH(arm)
  11 ENTRY(_start)
  12 SECTIONS
  13 {
  14   . = TEXT_START;
  15   _text = .;
  16
  17   .text : {
  18     _start = .;
  19     *(.start)
  20     *(.text)
  21     *(.text.*)
  22     *(.fixup)
  23     *(.gnu.warning)
  24     *(.rodata)
  25     *(.rodata.*)
  26     *(.glue_7)
  27     *(.glue_7t)
  28     *(.piggydata)
  29     . = ALIGN(4);
  30   }
  31
  32   _etext = .;
  33
  34   _got_start = .;
  35   .got                  : { *(.got) }
  36   _got_end = .;
  37   .got.plt              : { *(.got.plt) }
  38   .data                 : { *(.data) }
  39   _edata = .;
  40
  41   . = BSS_START;
  42   __bss_start = .;
  43   .bss                  : { *(.bss) }
  44   _end = .;
  45
  46   .stack (NOLOAD)       : { *(.stack) }
  47
  48   .stab 0               : { *(.stab) }
  49   .stabstr 0            : { *(.stabstr) }
  50   .stab.excl 0          : { *(.stab.excl) }
  51   .stab.exclstr 0       : { *(.stab.exclstr) }
  52   .stab.index 0         : { *(.stab.index) }
  53   .stab.indexstr 0      : { *(.stab.indexstr) }
  54   .comment 0            : { *(.comment) }
  55 }
  56