git.oblomov.eu Git - linux-2.6/blob - arch/x86/boot/compressed/head_32.S

   1 /*
   2  *  linux/boot/head.S
   3  *
   4  *  Copyright (C) 1991, 1992, 1993  Linus Torvalds
   5  */
   6
   7 /*
   8  *  head.S contains the 32-bit startup code.
   9  *
  10  * NOTE!!! Startup happens at absolute address 0x00001000, which is also where
  11  * the page directory will exist. The startup code will be overwritten by
  12  * the page directory. [According to comments etc elsewhere on a compressed
  13  * kernel it will end up at 0x1000 + 1Mb I hope so as I assume this. - AC]
  14  *
  15  * Page 0 is deliberately kept safe, since System Management Mode code in
  16  * laptops may need to access the BIOS data stored there.  This is also
  17  * useful for future device drivers that either access the BIOS via VM86
  18  * mode.
  19  */
  20
  21 /*
  22  * High loaded stuff by Hans Lermen & Werner Almesberger, Feb. 1996
  23  */
  24 .text
  25
  26 #include <linux/linkage.h>
  27 #include <asm/segment.h>
  28 #include <asm/page.h>
  29 #include <asm/boot.h>
  30 #include <asm/asm-offsets.h>
  31
  32 .section ".text.head","ax",@progbits
  33         .globl startup_32
  34
  35 startup_32:
  36         /* check to see if KEEP_SEGMENTS flag is meaningful */
  37         cmpw $0x207, BP_version(%esi)
  38         jb 1f
  39
  40         /* test KEEP_SEGMENTS flag to see if the bootloader is asking
  41          * us to not reload segments */
  42         testb $(1<<6), BP_loadflags(%esi)
  43         jnz 2f
  44
  45 1:      cli
  46         movl $(__BOOT_DS),%eax
  47         movl %eax,%ds
  48         movl %eax,%es
  49         movl %eax,%fs
  50         movl %eax,%gs
  51         movl %eax,%ss
  52
  53 2:      cld
  54
  55 /* Calculate the delta between where we were compiled to run
  56  * at and where we were actually loaded at.  This can only be done
  57  * with a short local call on x86.  Nothing  else will tell us what
  58  * address we are running at.  The reserved chunk of the real-mode
  59  * data at 0x1e4 (defined as a scratch field) are used as the stack
  60  * for this calculation. Only 4 bytes are needed.
  61  */
  62         leal (0x1e4+4)(%esi), %esp
  63         call 1f
  64 1:      popl %ebp
  65         subl $1b, %ebp
  66
  67 /* %ebp contains the address we are loaded at by the boot loader and %ebx
  68  * contains the address where we should move the kernel image temporarily
  69  * for safe in-place decompression.
  70  */
  71
  72 #ifdef CONFIG_RELOCATABLE
  73         movl    %ebp, %ebx
  74         addl    $(CONFIG_PHYSICAL_ALIGN - 1), %ebx
  75         andl    $(~(CONFIG_PHYSICAL_ALIGN - 1)), %ebx
  76 #else
  77         movl $LOAD_PHYSICAL_ADDR, %ebx
  78 #endif
  79
  80         /* Replace the compressed data size with the uncompressed size */
  81         subl input_len(%ebp), %ebx
  82         movl output_len(%ebp), %eax
  83         addl %eax, %ebx
  84         /* Add 8 bytes for every 32K input block */
  85         shrl $12, %eax
  86         addl %eax, %ebx
  87         /* Add 32K + 18 bytes of extra slack */
  88         addl $(32768 + 18), %ebx
  89         /* Align on a 4K boundary */
  90         addl $4095, %ebx
  91         andl $~4095, %ebx
  92
  93 /* Copy the compressed kernel to the end of our buffer
  94  * where decompression in place becomes safe.
  95  */
  96         pushl %esi
  97         leal _end(%ebp), %esi
  98         leal _end(%ebx), %edi
  99         movl $(_end - startup_32), %ecx
 100         std
 101         rep
 102         movsb
 103         cld
 104         popl %esi
 105
 106 /* Compute the kernel start address.
 107  */
 108 #ifdef CONFIG_RELOCATABLE
 109         addl    $(CONFIG_PHYSICAL_ALIGN - 1), %ebp
 110         andl    $(~(CONFIG_PHYSICAL_ALIGN - 1)), %ebp
 111 #else
 112         movl    $LOAD_PHYSICAL_ADDR, %ebp
 113 #endif
 114
 115 /*
 116  * Jump to the relocated address.
 117  */
 118         leal relocated(%ebx), %eax
 119         jmp *%eax
 120 .section ".text"
 121 relocated:
 122
 123 /*
 124  * Clear BSS
 125  */
 126         xorl %eax,%eax
 127         leal _edata(%ebx),%edi
 128         leal _end(%ebx), %ecx
 129         subl %edi,%ecx
 130         cld
 131         rep
 132         stosb
 133
 134 /*
 135  * Setup the stack for the decompressor
 136  */
 137         leal stack_end(%ebx), %esp
 138
 139 /*
 140  * Do the decompression, and jump to the new kernel..
 141  */
 142         movl output_len(%ebx), %eax
 143         pushl %eax
 144         pushl %ebp      # output address
 145         movl input_len(%ebx), %eax
 146         pushl %eax      # input_len
 147         leal input_data(%ebx), %eax
 148         pushl %eax      # input_data
 149         leal _end(%ebx), %eax
 150         pushl %eax      # end of the image as third argument
 151         pushl %esi      # real mode pointer as second arg
 152         call decompress_kernel
 153         addl $20, %esp
 154         popl %ecx
 155
 156 #if CONFIG_RELOCATABLE
 157 /* Find the address of the relocations.
 158  */
 159         movl %ebp, %edi
 160         addl %ecx, %edi
 161
 162 /* Calculate the delta between where vmlinux was compiled to run
 163  * and where it was actually loaded.
 164  */
 165         movl %ebp, %ebx
 166         subl $LOAD_PHYSICAL_ADDR, %ebx
 167         jz   2f         /* Nothing to be done if loaded at compiled addr. */
 168 /*
 169  * Process relocations.
 170  */
 171
 172 1:      subl $4, %edi
 173         movl 0(%edi), %ecx
 174         testl %ecx, %ecx
 175         jz 2f
 176         addl %ebx, -__PAGE_OFFSET(%ebx, %ecx)
 177         jmp 1b
 178 2:
 179 #endif
 180
 181 /*
 182  * Jump to the decompressed kernel.
 183  */
 184         xorl %ebx,%ebx
 185         jmp *%ebp
 186
 187 .bss
 188 .balign 4
 189 stack:
 190         .fill 4096, 1, 0
 191 stack_end: