git.oblomov.eu Git - linux-2.6/blob - arch/sh/kernel/vmlinux.lds.S

   1 /* $Id: vmlinux.lds.S,v 1.8 2003/05/16 17:18:14 lethal Exp $
   2  * ld script to make SuperH Linux kernel
   3  * Written by Niibe Yutaka
   4  */
   5 #include <asm/thread_info.h>
   6 #include <asm/cache.h>
   7 #include <asm-generic/vmlinux.lds.h>
   8
   9 #ifdef CONFIG_CPU_LITTLE_ENDIAN
  10 OUTPUT_FORMAT("elf32-sh-linux", "elf32-sh-linux", "elf32-sh-linux")
  11 #else
  12 OUTPUT_FORMAT("elf32-shbig-linux", "elf32-shbig-linux", "elf32-shbig-linux")
  13 #endif
  14 OUTPUT_ARCH(sh)
  15 ENTRY(_start)
  16 SECTIONS
  17 {
  18   . = CONFIG_PAGE_OFFSET + CONFIG_MEMORY_START + CONFIG_ZERO_PAGE_OFFSET;
  19   _text = .;                    /* Text and read-only data */
  20   text = .;                     /* Text and read-only data */
  21   .empty_zero_page : {
  22         *(.empty_zero_page)
  23         } = 0
  24   .text : {
  25         TEXT_TEXT
  26         SCHED_TEXT
  27         LOCK_TEXT
  28         *(.fixup)
  29         *(.gnu.warning)
  30         } = 0x0009
  31
  32   . = ALIGN(16);                /* Exception table */
  33   __start___ex_table = .;
  34   __ex_table : { *(__ex_table) }
  35   __stop___ex_table = .;
  36
  37   _etext = .;                   /* End of text section */
  38
  39   RODATA
  40
  41   BUG_TABLE
  42
  43   .data : {                     /* Data */
  44         DATA_DATA
  45
  46          /* Align the initial ramdisk image (INITRD) on page boundaries. */
  47          . = ALIGN(PAGE_SIZE);
  48          __rd_start = .;
  49          *(.initrd)
  50          . = ALIGN(PAGE_SIZE);
  51          __rd_end = .;
  52
  53         CONSTRUCTORS
  54         }
  55
  56   . = ALIGN(PAGE_SIZE);
  57   .data.page_aligned : { *(.data.page_aligned) }
  58   __nosave_begin = .;
  59   .data_nosave : { *(.data.nosave) }
  60   . = ALIGN(PAGE_SIZE);
  61   __nosave_end = .;
  62
  63   PERCPU(PAGE_SIZE)
  64   .data.cacheline_aligned : { *(.data.cacheline_aligned) }
  65
  66   _edata = .;                   /* End of data section */
  67
  68   . = ALIGN(THREAD_SIZE);               /* init_task */
  69   .data.init_task : { *(.data.init_task) }
  70
  71   . = ALIGN(PAGE_SIZE);         /* Init code and data */
  72   __init_begin = .;
  73   _sinittext = .;
  74   .init.text : { *(.init.text) }
  75   _einittext = .;
  76   .init.data : { *(.init.data) }
  77   . = ALIGN(16);
  78   __setup_start = .;
  79   .init.setup : { *(.init.setup) }
  80   __setup_end = .;
  81   __initcall_start = .;
  82   .initcall.init : {
  83         INITCALLS
  84   }
  85   __initcall_end = .;
  86   __con_initcall_start = .;
  87   .con_initcall.init : { *(.con_initcall.init) }
  88   __con_initcall_end = .;
  89   SECURITY_INIT
  90
  91 #ifdef CONFIG_BLK_DEV_INITRD
  92   __initramfs_start = .;
  93   .init.ramfs : { *(.init.ramfs) }
  94   __initramfs_end = .;
  95 #endif
  96
  97  . = ALIGN(4);
  98   __machvec_start = .;
  99   .machvec.init : { *(.machvec.init) }
 100   __machvec_end = .;
 101
 102   . = ALIGN(PAGE_SIZE);
 103   .bss : {
 104         __init_end = .;
 105         __bss_start = .;                /* BSS */
 106         *(.bss.page_aligned)
 107         *(.bss)
 108         . = ALIGN(4);
 109         _end = . ;
 110   }
 111
 112   /* When something in the kernel is NOT compiled as a module, the
 113    * module cleanup code and data are put into these segments.  Both
 114    * can then be thrown away, as cleanup code is never called unless
 115    * it's a module.
 116    */
 117   /DISCARD/ : {
 118         *(.exitcall.exit)
 119         }
 120
 121   STABS_DEBUG
 122
 123   DWARF_DEBUG
 124 }