git.oblomov.eu Git - linux-2.6/blob - arch/ppc/kernel/head_8xx.S

   1 /*
   2  *  PowerPC version
   3  *    Copyright (C) 1995-1996 Gary Thomas (gdt@linuxppc.org)
   4  *  Rewritten by Cort Dougan (cort@cs.nmt.edu) for PReP
   5  *    Copyright (C) 1996 Cort Dougan <cort@cs.nmt.edu>
   6  *  Low-level exception handlers and MMU support
   7  *  rewritten by Paul Mackerras.
   8  *    Copyright (C) 1996 Paul Mackerras.
   9  *  MPC8xx modifications by Dan Malek
  10  *    Copyright (C) 1997 Dan Malek (dmalek@jlc.net).
  11  *
  12  *  This file contains low-level support and setup for PowerPC 8xx
  13  *  embedded processors, including trap and interrupt dispatch.
  14  *
  15  *  This program is free software; you can redistribute it and/or
  16  *  modify it under the terms of the GNU General Public License
  17  *  as published by the Free Software Foundation; either version
  18  *  2 of the License, or (at your option) any later version.
  19  *
  20  */
  21
  22 #include <asm/processor.h>
  23 #include <asm/page.h>
  24 #include <asm/mmu.h>
  25 #include <asm/cache.h>
  26 #include <asm/pgtable.h>
  27 #include <asm/cputable.h>
  28 #include <asm/thread_info.h>
  29 #include <asm/ppc_asm.h>
  30 #include <asm/asm-offsets.h>
  31
  32 /* Macro to make the code more readable. */
  33 #ifdef CONFIG_8xx_CPU6
  34 #define DO_8xx_CPU6(val, reg)   \
  35         li      reg, val;       \
  36         stw     reg, 12(r0);    \
  37         lwz     reg, 12(r0);
  38 #else
  39 #define DO_8xx_CPU6(val, reg)
  40 #endif
  41         .text
  42         .globl  _stext
  43 _stext:
  44         .text
  45         .globl  _start
  46 _start:
  47
  48 /* MPC8xx
  49  * This port was done on an MBX board with an 860.  Right now I only
  50  * support an ELF compressed (zImage) boot from EPPC-Bug because the
  51  * code there loads up some registers before calling us:
  52  *   r3: ptr to board info data
  53  *   r4: initrd_start or if no initrd then 0
  54  *   r5: initrd_end - unused if r4 is 0
  55  *   r6: Start of command line string
  56  *   r7: End of command line string
  57  *
  58  * I decided to use conditional compilation instead of checking PVR and
  59  * adding more processor specific branches around code I don't need.
  60  * Since this is an embedded processor, I also appreciate any memory
  61  * savings I can get.
  62  *
  63  * The MPC8xx does not have any BATs, but it supports large page sizes.
  64  * We first initialize the MMU to support 8M byte pages, then load one
  65  * entry into each of the instruction and data TLBs to map the first
  66  * 8M 1:1.  I also mapped an additional I/O space 1:1 so we can get to
  67  * the "internal" processor registers before MMU_init is called.
  68  *
  69  * The TLB code currently contains a major hack.  Since I use the condition
  70  * code register, I have to save and restore it.  I am out of registers, so
  71  * I just store it in memory location 0 (the TLB handlers are not reentrant).
  72  * To avoid making any decisions, I need to use the "segment" valid bit
  73  * in the first level table, but that would require many changes to the
  74  * Linux page directory/table functions that I don't want to do right now.
  75  *
  76  * I used to use SPRG2 for a temporary register in the TLB handler, but it
  77  * has since been put to other uses.  I now use a hack to save a register
  78  * and the CCR at memory location 0.....Someday I'll fix this.....
  79  *      -- Dan
  80  */
  81         .globl  __start
  82 __start:
  83         mr      r31,r3                  /* save parameters */
  84         mr      r30,r4
  85         mr      r29,r5
  86         mr      r28,r6
  87         mr      r27,r7
  88
  89         /* We have to turn on the MMU right away so we get cache modes
  90          * set correctly.
  91          */
  92         bl      initial_mmu
  93
  94 /* We now have the lower 8 Meg mapped into TLB entries, and the caches
  95  * ready to work.
  96  */
  97
  98 turn_on_mmu:
  99         mfmsr   r0
 100         ori     r0,r0,MSR_DR|MSR_IR
 101         mtspr   SPRN_SRR1,r0
 102         lis     r0,start_here@h
 103         ori     r0,r0,start_here@l
 104         mtspr   SPRN_SRR0,r0
 105         SYNC
 106         rfi                             /* enables MMU */
 107
 108 /*
 109  * Exception entry code.  This code runs with address translation
 110  * turned off, i.e. using physical addresses.
 111  * We assume sprg3 has the physical address of the current
 112  * task's thread_struct.
 113  */
 114 #define EXCEPTION_PROLOG        \
 115         mtspr   SPRN_SPRG0,r10; \
 116         mtspr   SPRN_SPRG1,r11; \
 117         mfcr    r10;            \
 118         EXCEPTION_PROLOG_1;     \
 119         EXCEPTION_PROLOG_2
 120
 121 #define EXCEPTION_PROLOG_1      \
 122         mfspr   r11,SPRN_SRR1;          /* check whether user or kernel */ \
 123         andi.   r11,r11,MSR_PR; \
 124         tophys(r11,r1);                 /* use tophys(r1) if kernel */ \
 125         beq     1f;             \
 126         mfspr   r11,SPRN_SPRG3; \
 127         lwz     r11,THREAD_INFO-THREAD(r11);    \
 128         addi    r11,r11,THREAD_SIZE;    \
 129         tophys(r11,r11);        \
 130 1:      subi    r11,r11,INT_FRAME_SIZE  /* alloc exc. frame */
 131
 132
 133 #define EXCEPTION_PROLOG_2      \
 134         CLR_TOP32(r11);         \
 135         stw     r10,_CCR(r11);          /* save registers */ \
 136         stw     r12,GPR12(r11); \
 137         stw     r9,GPR9(r11);   \
 138         mfspr   r10,SPRN_SPRG0; \
 139         stw     r10,GPR10(r11); \
 140         mfspr   r12,SPRN_SPRG1; \
 141         stw     r12,GPR11(r11); \
 142         mflr    r10;            \
 143         stw     r10,_LINK(r11); \
 144         mfspr   r12,SPRN_SRR0;  \
 145         mfspr   r9,SPRN_SRR1;   \
 146         stw     r1,GPR1(r11);   \
 147         stw     r1,0(r11);      \
 148         tovirt(r1,r11);                 /* set new kernel sp */ \
 149         li      r10,MSR_KERNEL & ~(MSR_IR|MSR_DR); /* can take exceptions */ \
 150         MTMSRD(r10);                    /* (except for mach check in rtas) */ \
 151         stw     r0,GPR0(r11);   \
 152         SAVE_4GPRS(3, r11);     \
 153         SAVE_2GPRS(7, r11)
 154
 155 /*
 156  * Note: code which follows this uses cr0.eq (set if from kernel),
 157  * r11, r12 (SRR0), and r9 (SRR1).
 158  *
 159  * Note2: once we have set r1 we are in a position to take exceptions
 160  * again, and we could thus set MSR:RI at that point.
 161  */
 162
 163 /*
 164  * Exception vectors.
 165  */
 166 #define EXCEPTION(n, label, hdlr, xfer)         \
 167         . = n;                                  \
 168 label:                                          \
 169         EXCEPTION_PROLOG;                       \
 170         addi    r3,r1,STACK_FRAME_OVERHEAD;     \
 171         xfer(n, hdlr)
 172
 173 #define EXC_XFER_TEMPLATE(n, hdlr, trap, copyee, tfer, ret)     \
 174         li      r10,trap;                                       \
 175         stw     r10,TRAP(r11);                                  \
 176         li      r10,MSR_KERNEL;                                 \
 177         copyee(r10, r9);                                        \
 178         bl      tfer;                                           \
 179 i##n:                                                           \
 180         .long   hdlr;                                           \
 181         .long   ret
 182
 183 #define COPY_EE(d, s)           rlwimi d,s,0,16,16
 184 #define NOCOPY(d, s)
 185
 186 #define EXC_XFER_STD(n, hdlr)           \
 187         EXC_XFER_TEMPLATE(n, hdlr, n, NOCOPY, transfer_to_handler_full, \
 188                           ret_from_except_full)
 189
 190 #define EXC_XFER_LITE(n, hdlr)          \
 191         EXC_XFER_TEMPLATE(n, hdlr, n+1, NOCOPY, transfer_to_handler, \
 192                           ret_from_except)
 193
 194 #define EXC_XFER_EE(n, hdlr)            \
 195         EXC_XFER_TEMPLATE(n, hdlr, n, COPY_EE, transfer_to_handler_full, \
 196                           ret_from_except_full)
 197
 198 #define EXC_XFER_EE_LITE(n, hdlr)       \
 199         EXC_XFER_TEMPLATE(n, hdlr, n+1, COPY_EE, transfer_to_handler, \
 200                           ret_from_except)
 201
 202 /* System reset */
 203         EXCEPTION(0x100, Reset, unknown_exception, EXC_XFER_STD)
 204
 205 /* Machine check */
 206         . = 0x200
 207 MachineCheck:
 208         EXCEPTION_PROLOG
 209         mfspr r4,SPRN_DAR
 210         stw r4,_DAR(r11)
 211         mfspr r5,SPRN_DSISR
 212         stw r5,_DSISR(r11)
 213         addi r3,r1,STACK_FRAME_OVERHEAD
 214         EXC_XFER_STD(0x200, machine_check_exception)
 215
 216 /* Data access exception.
 217  * This is "never generated" by the MPC8xx.  We jump to it for other
 218  * translation errors.
 219  */
 220         . = 0x300
 221 DataAccess:
 222         EXCEPTION_PROLOG
 223         mfspr   r10,SPRN_DSISR
 224         stw     r10,_DSISR(r11)
 225         mr      r5,r10
 226         mfspr   r4,SPRN_DAR
 227         EXC_XFER_EE_LITE(0x300, handle_page_fault)
 228
 229 /* Instruction access exception.
 230  * This is "never generated" by the MPC8xx.  We jump to it for other
 231  * translation errors.
 232  */
 233         . = 0x400
 234 InstructionAccess:
 235         EXCEPTION_PROLOG
 236         mr      r4,r12
 237         mr      r5,r9
 238         EXC_XFER_EE_LITE(0x400, handle_page_fault)
 239
 240 /* External interrupt */
 241         EXCEPTION(0x500, HardwareInterrupt, do_IRQ, EXC_XFER_LITE)
 242
 243 /* Alignment exception */
 244         . = 0x600
 245 Alignment:
 246         EXCEPTION_PROLOG
 247         mfspr   r4,SPRN_DAR
 248         stw     r4,_DAR(r11)
 249         mfspr   r5,SPRN_DSISR
 250         stw     r5,_DSISR(r11)
 251         addi    r3,r1,STACK_FRAME_OVERHEAD
 252         EXC_XFER_EE(0x600, alignment_exception)
 253
 254 /* Program check exception */
 255         EXCEPTION(0x700, ProgramCheck, program_check_exception, EXC_XFER_STD)
 256
 257 /* No FPU on MPC8xx.  This exception is not supposed to happen.
 258 */
 259         EXCEPTION(0x800, FPUnavailable, unknown_exception, EXC_XFER_STD)
 260
 261 /* Decrementer */
 262         EXCEPTION(0x900, Decrementer, timer_interrupt, EXC_XFER_LITE)
 263
 264         EXCEPTION(0xa00, Trap_0a, unknown_exception, EXC_XFER_EE)
 265         EXCEPTION(0xb00, Trap_0b, unknown_exception, EXC_XFER_EE)
 266
 267 /* System call */
 268         . = 0xc00
 269 SystemCall:
 270         EXCEPTION_PROLOG
 271         EXC_XFER_EE_LITE(0xc00, DoSyscall)
 272
 273 /* Single step - not used on 601 */
 274         EXCEPTION(0xd00, SingleStep, single_step_exception, EXC_XFER_STD)
 275         EXCEPTION(0xe00, Trap_0e, unknown_exception, EXC_XFER_EE)
 276         EXCEPTION(0xf00, Trap_0f, unknown_exception, EXC_XFER_EE)
 277
 278 /* On the MPC8xx, this is a software emulation interrupt.  It occurs
 279  * for all unimplemented and illegal instructions.
 280  */
 281         EXCEPTION(0x1000, SoftEmu, SoftwareEmulation, EXC_XFER_STD)
 282
 283         . = 0x1100
 284 /*
 285  * For the MPC8xx, this is a software tablewalk to load the instruction
 286  * TLB.  It is modelled after the example in the Motorola manual.  The task
 287  * switch loads the M_TWB register with the pointer to the first level table.
 288  * If we discover there is no second level table (value is zero) or if there
 289  * is an invalid pte, we load that into the TLB, which causes another fault
 290  * into the TLB Error interrupt where we can handle such problems.
 291  * We have to use the MD_xxx registers for the tablewalk because the
 292  * equivalent MI_xxx registers only perform the attribute functions.
 293  */
 294 InstructionTLBMiss:
 295 #ifdef CONFIG_8xx_CPU6
 296         stw     r3, 8(r0)
 297 #endif
 298         DO_8xx_CPU6(0x3f80, r3)
 299         mtspr   SPRN_M_TW, r10  /* Save a couple of working registers */
 300         mfcr    r10
 301         stw     r10, 0(r0)
 302         stw     r11, 4(r0)
 303         mfspr   r10, SPRN_SRR0  /* Get effective address of fault */
 304         DO_8xx_CPU6(0x3780, r3)
 305         mtspr   SPRN_MD_EPN, r10        /* Have to use MD_EPN for walk, MI_EPN can't */
 306         mfspr   r10, SPRN_M_TWB /* Get level 1 table entry address */
 307
 308         /* If we are faulting a kernel address, we have to use the
 309          * kernel page tables.
 310          */
 311         andi.   r11, r10, 0x0800        /* Address >= 0x80000000 */
 312         beq     3f
 313         lis     r11, swapper_pg_dir@h
 314         ori     r11, r11, swapper_pg_dir@l
 315         rlwimi  r10, r11, 0, 2, 19
 316 3:
 317         lwz     r11, 0(r10)     /* Get the level 1 entry */
 318         rlwinm. r10, r11,0,0,19 /* Extract page descriptor page address */
 319         beq     2f              /* If zero, don't try to find a pte */
 320
 321         /* We have a pte table, so load the MI_TWC with the attributes
 322          * for this "segment."
 323          */
 324         ori     r11,r11,1               /* Set valid bit */
 325         DO_8xx_CPU6(0x2b80, r3)
 326         mtspr   SPRN_MI_TWC, r11        /* Set segment attributes */
 327         DO_8xx_CPU6(0x3b80, r3)
 328         mtspr   SPRN_MD_TWC, r11        /* Load pte table base address */
 329         mfspr   r11, SPRN_MD_TWC        /* ....and get the pte address */
 330         lwz     r10, 0(r11)     /* Get the pte */
 331
 332         ori     r10, r10, _PAGE_ACCESSED
 333         stw     r10, 0(r11)
 334
 335         /* The Linux PTE won't go exactly into the MMU TLB.
 336          * Software indicator bits 21, 22 and 28 must be clear.
 337          * Software indicator bits 24, 25, 26, and 27 must be
 338          * set.  All other Linux PTE bits control the behavior
 339          * of the MMU.
 340          */
 341 2:      li      r11, 0x00f0
 342         rlwimi  r10, r11, 0, 24, 28     /* Set 24-27, clear 28 */
 343         DO_8xx_CPU6(0x2d80, r3)
 344         mtspr   SPRN_MI_RPN, r10        /* Update TLB entry */
 345
 346         mfspr   r10, SPRN_M_TW  /* Restore registers */
 347         lwz     r11, 0(r0)
 348         mtcr    r11
 349         lwz     r11, 4(r0)
 350 #ifdef CONFIG_8xx_CPU6
 351         lwz     r3, 8(r0)
 352 #endif
 353         rfi
 354
 355         . = 0x1200
 356 DataStoreTLBMiss:
 357         stw     r3, 8(r0)
 358         DO_8xx_CPU6(0x3f80, r3)
 359         mtspr   SPRN_M_TW, r10  /* Save a couple of working registers */
 360         mfcr    r10
 361         stw     r10, 0(r0)
 362         stw     r11, 4(r0)
 363         mfspr   r10, SPRN_M_TWB /* Get level 1 table entry address */
 364
 365         /* If we are faulting a kernel address, we have to use the
 366          * kernel page tables.
 367          */
 368         andi.   r11, r10, 0x0800
 369         beq     3f
 370         lis     r11, swapper_pg_dir@h
 371         ori     r11, r11, swapper_pg_dir@l
 372         rlwimi  r10, r11, 0, 2, 19
 373         stw     r12, 16(r0)
 374         b LoadLargeDTLB
 375 3:
 376         lwz     r11, 0(r10)     /* Get the level 1 entry */
 377         rlwinm. r10, r11,0,0,19 /* Extract page descriptor page address */
 378         beq     2f              /* If zero, don't try to find a pte */
 379
 380         /* We have a pte table, so load fetch the pte from the table.
 381          */
 382         ori     r11, r11, 1     /* Set valid bit in physical L2 page */
 383         DO_8xx_CPU6(0x3b80, r3)
 384         mtspr   SPRN_MD_TWC, r11        /* Load pte table base address */
 385         mfspr   r10, SPRN_MD_TWC        /* ....and get the pte address */
 386         lwz     r10, 0(r10)     /* Get the pte */
 387
 388         /* Insert the Guarded flag into the TWC from the Linux PTE.
 389          * It is bit 27 of both the Linux PTE and the TWC (at least
 390          * I got that right :-).  It will be better when we can put
 391          * this into the Linux pgd/pmd and load it in the operation
 392          * above.
 393          */
 394         rlwimi  r11, r10, 0, 27, 27
 395         DO_8xx_CPU6(0x3b80, r3)
 396         mtspr   SPRN_MD_TWC, r11
 397
 398         mfspr   r11, SPRN_MD_TWC        /* get the pte address again */
 399         ori     r10, r10, _PAGE_ACCESSED
 400         stw     r10, 0(r11)
 401
 402         /* The Linux PTE won't go exactly into the MMU TLB.
 403          * Software indicator bits 21, 22 and 28 must be clear.
 404          * Software indicator bits 24, 25, 26, and 27 must be
 405          * set.  All other Linux PTE bits control the behavior
 406          * of the MMU.
 407          */
 408 2:      li      r11, 0x00f0
 409         rlwimi  r10, r11, 0, 24, 28     /* Set 24-27, clear 28 */
 410         DO_8xx_CPU6(0x3d80, r3)
 411         mtspr   SPRN_MD_RPN, r10        /* Update TLB entry */
 412
 413         mfspr   r10, SPRN_M_TW  /* Restore registers */
 414         lwz     r11, 0(r0)
 415         mtcr    r11
 416         lwz     r11, 4(r0)
 417         lwz     r3, 8(r0)
 418         rfi
 419
 420 /* This is an instruction TLB error on the MPC8xx.  This could be due
 421  * to many reasons, such as executing guarded memory or illegal instruction
 422  * addresses.  There is nothing to do but handle a big time error fault.
 423  */
 424         . = 0x1300
 425 InstructionTLBError:
 426         b       InstructionAccess
 427
 428 LoadLargeDTLB:
 429         li      r12, 0
 430         lwz     r11, 0(r10)     /* Get the level 1 entry */
 431         rlwinm. r10, r11,0,0,19 /* Extract page descriptor page address */
 432         beq     3f              /* If zero, don't try to find a pte */
 433
 434         /* We have a pte table, so load fetch the pte from the table.
 435          */
 436         ori     r11, r11, 1     /* Set valid bit in physical L2 page */
 437         DO_8xx_CPU6(0x3b80, r3)
 438         mtspr   SPRN_MD_TWC, r11        /* Load pte table base address */
 439         mfspr   r10, SPRN_MD_TWC        /* ....and get the pte address */
 440         lwz     r10, 0(r10)     /* Get the pte */
 441
 442         /* Insert the Guarded flag into the TWC from the Linux PTE.
 443          * It is bit 27 of both the Linux PTE and the TWC (at least
 444          * I got that right :-).  It will be better when we can put
 445          * this into the Linux pgd/pmd and load it in the operation
 446          * above.
 447          */
 448         rlwimi  r11, r10, 0, 27, 27
 449
 450         rlwimi  r12, r10, 0, 0, 9       /* extract phys. addr */
 451         mfspr   r3, SPRN_MD_EPN
 452         rlwinm  r3, r3, 0, 0, 9         /* extract virtual address */
 453         tophys(r3, r3)
 454         cmpw    r3, r12                 /* only use 8M page if it is a direct
 455                                            kernel mapping */
 456         bne     1f
 457         ori     r11, r11, MD_PS8MEG
 458         li      r12, 1
 459         b       2f
 460 1:
 461         li      r12, 0          /* can't use 8MB TLB, so zero r12. */
 462 2:
 463         DO_8xx_CPU6(0x3b80, r3)
 464         mtspr   SPRN_MD_TWC, r11
 465
 466         /* The Linux PTE won't go exactly into the MMU TLB.
 467          * Software indicator bits 21, 22 and 28 must be clear.
 468          * Software indicator bits 24, 25, 26, and 27 must be
 469          * set.  All other Linux PTE bits control the behavior
 470          * of the MMU.
 471          */
 472 3:      li      r11, 0x00f0
 473         rlwimi  r10, r11, 0, 24, 28     /* Set 24-27, clear 28 */
 474         cmpwi   r12, 1
 475         bne 4f
 476         ori     r10, r10, 0x8
 477
 478         mfspr   r12, SPRN_MD_EPN
 479         lis     r3, 0xff80              /* 10-19 must be clear for 8MB TLB */
 480         ori     r3, r3, 0x0fff
 481         and     r12, r3, r12
 482         DO_8xx_CPU6(0x3780, r3)
 483         mtspr   SPRN_MD_EPN, r12
 484
 485         lis     r3, 0xff80              /* 10-19 must be clear for 8MB TLB */
 486         ori     r3, r3, 0x0fff
 487         and     r10, r3, r10
 488 4:
 489         DO_8xx_CPU6(0x3d80, r3)
 490         mtspr   SPRN_MD_RPN, r10        /* Update TLB entry */
 491
 492         mfspr   r10, SPRN_M_TW  /* Restore registers */
 493         lwz     r11, 0(r0)
 494         mtcr    r11
 495         lwz     r11, 4(r0)
 496
 497         lwz     r12, 16(r0)
 498         lwz     r3, 8(r0)
 499         rfi
 500
 501 /* This is the data TLB error on the MPC8xx.  This could be due to
 502  * many reasons, including a dirty update to a pte.  We can catch that
 503  * one here, but anything else is an error.  First, we track down the
 504  * Linux pte.  If it is valid, write access is allowed, but the
 505  * page dirty bit is not set, we will set it and reload the TLB.  For
 506  * any other case, we bail out to a higher level function that can
 507  * handle it.
 508  */
 509         . = 0x1400
 510 DataTLBError:
 511 #ifdef CONFIG_8xx_CPU6
 512         stw     r3, 8(r0)
 513 #endif
 514         DO_8xx_CPU6(0x3f80, r3)
 515         mtspr   SPRN_M_TW, r10  /* Save a couple of working registers */
 516         mfcr    r10
 517         stw     r10, 0(r0)
 518         stw     r11, 4(r0)
 519
 520         /* First, make sure this was a store operation.
 521         */
 522         mfspr   r10, SPRN_DSISR
 523         andis.  r11, r10, 0x0200        /* If set, indicates store op */
 524         beq     2f
 525
 526         /* The EA of a data TLB miss is automatically stored in the MD_EPN
 527          * register.  The EA of a data TLB error is automatically stored in
 528          * the DAR, but not the MD_EPN register.  We must copy the 20 most
 529          * significant bits of the EA from the DAR to MD_EPN before we
 530          * start walking the page tables.  We also need to copy the CASID
 531          * value from the M_CASID register.
 532          * Addendum:  The EA of a data TLB error is _supposed_ to be stored
 533          * in DAR, but it seems that this doesn't happen in some cases, such
 534          * as when the error is due to a dcbi instruction to a page with a
 535          * TLB that doesn't have the changed bit set.  In such cases, there
 536          * does not appear to be any way  to recover the EA of the error
 537          * since it is neither in DAR nor MD_EPN.  As a workaround, the
 538          * _PAGE_HWWRITE bit is set for all kernel data pages when the PTEs
 539          * are initialized in mapin_ram().  This will avoid the problem,
 540          * assuming we only use the dcbi instruction on kernel addresses.
 541          */
 542         mfspr   r10, SPRN_DAR
 543         rlwinm  r11, r10, 0, 0, 19
 544         ori     r11, r11, MD_EVALID
 545         mfspr   r10, SPRN_M_CASID
 546         rlwimi  r11, r10, 0, 28, 31
 547         DO_8xx_CPU6(0x3780, r3)
 548         mtspr   SPRN_MD_EPN, r11
 549
 550         mfspr   r10, SPRN_M_TWB /* Get level 1 table entry address */
 551
 552         /* If we are faulting a kernel address, we have to use the
 553          * kernel page tables.
 554          */
 555         andi.   r11, r10, 0x0800
 556         beq     3f
 557         lis     r11, swapper_pg_dir@h
 558         ori     r11, r11, swapper_pg_dir@l
 559         rlwimi  r10, r11, 0, 2, 19
 560 3:
 561         lwz     r11, 0(r10)     /* Get the level 1 entry */
 562         rlwinm. r10, r11,0,0,19 /* Extract page descriptor page address */
 563         beq     2f              /* If zero, bail */
 564
 565         /* We have a pte table, so fetch the pte from the table.
 566          */
 567         ori     r11, r11, 1             /* Set valid bit in physical L2 page */
 568         DO_8xx_CPU6(0x3b80, r3)
 569         mtspr   SPRN_MD_TWC, r11                /* Load pte table base address */
 570         mfspr   r11, SPRN_MD_TWC                /* ....and get the pte address */
 571         lwz     r10, 0(r11)             /* Get the pte */
 572
 573         andi.   r11, r10, _PAGE_RW      /* Is it writeable? */
 574         beq     2f                      /* Bail out if not */
 575
 576         /* Update 'changed', among others.
 577         */
 578         ori     r10, r10, _PAGE_DIRTY|_PAGE_ACCESSED|_PAGE_HWWRITE
 579         mfspr   r11, SPRN_MD_TWC                /* Get pte address again */
 580         stw     r10, 0(r11)             /* and update pte in table */
 581
 582         /* The Linux PTE won't go exactly into the MMU TLB.
 583          * Software indicator bits 21, 22 and 28 must be clear.
 584          * Software indicator bits 24, 25, 26, and 27 must be
 585          * set.  All other Linux PTE bits control the behavior
 586          * of the MMU.
 587          */
 588         li      r11, 0x00f0
 589         rlwimi  r10, r11, 0, 24, 28     /* Set 24-27, clear 28 */
 590         DO_8xx_CPU6(0x3d80, r3)
 591         mtspr   SPRN_MD_RPN, r10        /* Update TLB entry */
 592
 593         mfspr   r10, SPRN_M_TW  /* Restore registers */
 594         lwz     r11, 0(r0)
 595         mtcr    r11
 596         lwz     r11, 4(r0)
 597 #ifdef CONFIG_8xx_CPU6
 598         lwz     r3, 8(r0)
 599 #endif
 600         rfi
 601 2:
 602         mfspr   r10, SPRN_M_TW  /* Restore registers */
 603         lwz     r11, 0(r0)
 604         mtcr    r11
 605         lwz     r11, 4(r0)
 606 #ifdef CONFIG_8xx_CPU6
 607         lwz     r3, 8(r0)
 608 #endif
 609         b       DataAccess
 610
 611         EXCEPTION(0x1500, Trap_15, unknown_exception, EXC_XFER_EE)
 612         EXCEPTION(0x1600, Trap_16, unknown_exception, EXC_XFER_EE)
 613         EXCEPTION(0x1700, Trap_17, unknown_exception, EXC_XFER_EE)
 614         EXCEPTION(0x1800, Trap_18, unknown_exception, EXC_XFER_EE)
 615         EXCEPTION(0x1900, Trap_19, unknown_exception, EXC_XFER_EE)
 616         EXCEPTION(0x1a00, Trap_1a, unknown_exception, EXC_XFER_EE)
 617         EXCEPTION(0x1b00, Trap_1b, unknown_exception, EXC_XFER_EE)
 618
 619 /* On the MPC8xx, these next four traps are used for development
 620  * support of breakpoints and such.  Someday I will get around to
 621  * using them.
 622  */
 623         EXCEPTION(0x1c00, Trap_1c, unknown_exception, EXC_XFER_EE)
 624         EXCEPTION(0x1d00, Trap_1d, unknown_exception, EXC_XFER_EE)
 625         EXCEPTION(0x1e00, Trap_1e, unknown_exception, EXC_XFER_EE)
 626         EXCEPTION(0x1f00, Trap_1f, unknown_exception, EXC_XFER_EE)
 627
 628         . = 0x2000
 629
 630         .globl  giveup_fpu
 631 giveup_fpu:
 632         blr
 633
 634 /*
 635  * This is where the main kernel code starts.
 636  */
 637 start_here:
 638         /* ptr to current */
 639         lis     r2,init_task@h
 640         ori     r2,r2,init_task@l
 641
 642         /* ptr to phys current thread */
 643         tophys(r4,r2)
 644         addi    r4,r4,THREAD    /* init task's THREAD */
 645         mtspr   SPRN_SPRG3,r4
 646         li      r3,0
 647         mtspr   SPRN_SPRG2,r3   /* 0 => r1 has kernel sp */
 648
 649         /* stack */
 650         lis     r1,init_thread_union@ha
 651         addi    r1,r1,init_thread_union@l
 652         li      r0,0
 653         stwu    r0,THREAD_SIZE-STACK_FRAME_OVERHEAD(r1)
 654
 655         bl      early_init      /* We have to do this with MMU on */
 656
 657 /*
 658  * Decide what sort of machine this is and initialize the MMU.
 659  */
 660         mr      r3,r31
 661         mr      r4,r30
 662         mr      r5,r29
 663         mr      r6,r28
 664         mr      r7,r27
 665         bl      machine_init
 666         bl      MMU_init
 667
 668 /*
 669  * Go back to running unmapped so we can load up new values
 670  * and change to using our exception vectors.
 671  * On the 8xx, all we have to do is invalidate the TLB to clear
 672  * the old 8M byte TLB mappings and load the page table base register.
 673  */
 674         /* The right way to do this would be to track it down through
 675          * init's THREAD like the context switch code does, but this is
 676          * easier......until someone changes init's static structures.
 677          */
 678         lis     r6, swapper_pg_dir@h
 679         ori     r6, r6, swapper_pg_dir@l
 680         tophys(r6,r6)
 681 #ifdef CONFIG_8xx_CPU6
 682         lis     r4, cpu6_errata_word@h
 683         ori     r4, r4, cpu6_errata_word@l
 684         li      r3, 0x3980
 685         stw     r3, 12(r4)
 686         lwz     r3, 12(r4)
 687 #endif
 688         mtspr   SPRN_M_TWB, r6
 689         lis     r4,2f@h
 690         ori     r4,r4,2f@l
 691         tophys(r4,r4)
 692         li      r3,MSR_KERNEL & ~(MSR_IR|MSR_DR)
 693         mtspr   SPRN_SRR0,r4
 694         mtspr   SPRN_SRR1,r3
 695         rfi
 696 /* Load up the kernel context */
 697 2:
 698         SYNC                    /* Force all PTE updates to finish */
 699         tlbia                   /* Clear all TLB entries */
 700         sync                    /* wait for tlbia/tlbie to finish */
 701         TLBSYNC                 /* ... on all CPUs */
 702
 703         /* set up the PTE pointers for the Abatron bdiGDB.
 704         */
 705         tovirt(r6,r6)
 706         lis     r5, abatron_pteptrs@h
 707         ori     r5, r5, abatron_pteptrs@l
 708         stw     r5, 0xf0(r0)    /* Must match your Abatron config file */
 709         tophys(r5,r5)
 710         stw     r6, 0(r5)
 711
 712 /* Now turn on the MMU for real! */
 713         li      r4,MSR_KERNEL
 714         lis     r3,start_kernel@h
 715         ori     r3,r3,start_kernel@l
 716         mtspr   SPRN_SRR0,r3
 717         mtspr   SPRN_SRR1,r4
 718         rfi                     /* enable MMU and jump to start_kernel */
 719
 720 /* Set up the initial MMU state so we can do the first level of
 721  * kernel initialization.  This maps the first 8 MBytes of memory 1:1
 722  * virtual to physical.  Also, set the cache mode since that is defined
 723  * by TLB entries and perform any additional mapping (like of the IMMR).
 724  * If configured to pin some TLBs, we pin the first 8 Mbytes of kernel,
 725  * 24 Mbytes of data, and the 8M IMMR space.  Anything not covered by
 726  * these mappings is mapped by page tables.
 727  */
 728 initial_mmu:
 729         tlbia                   /* Invalidate all TLB entries */
 730 #ifdef CONFIG_PIN_TLB
 731         lis     r8, MI_RSV4I@h
 732         ori     r8, r8, 0x1c00
 733 #else
 734         li      r8, 0
 735 #endif
 736         mtspr   SPRN_MI_CTR, r8 /* Set instruction MMU control */
 737
 738 #ifdef CONFIG_PIN_TLB
 739         lis     r10, (MD_RSV4I | MD_RESETVAL)@h
 740         ori     r10, r10, 0x1c00
 741         mr      r8, r10
 742 #else
 743         lis     r10, MD_RESETVAL@h
 744 #endif
 745 #ifndef CONFIG_8xx_COPYBACK
 746         oris    r10, r10, MD_WTDEF@h
 747 #endif
 748         mtspr   SPRN_MD_CTR, r10        /* Set data TLB control */
 749
 750         /* Now map the lower 8 Meg into the TLBs.  For this quick hack,
 751          * we can load the instruction and data TLB registers with the
 752          * same values.
 753          */
 754         lis     r8, KERNELBASE@h        /* Create vaddr for TLB */
 755         ori     r8, r8, MI_EVALID       /* Mark it valid */
 756         mtspr   SPRN_MI_EPN, r8
 757         mtspr   SPRN_MD_EPN, r8
 758         li      r8, MI_PS8MEG           /* Set 8M byte page */
 759         ori     r8, r8, MI_SVALID       /* Make it valid */
 760         mtspr   SPRN_MI_TWC, r8
 761         mtspr   SPRN_MD_TWC, r8
 762         li      r8, MI_BOOTINIT         /* Create RPN for address 0 */
 763         mtspr   SPRN_MI_RPN, r8         /* Store TLB entry */
 764         mtspr   SPRN_MD_RPN, r8
 765         lis     r8, MI_Kp@h             /* Set the protection mode */
 766         mtspr   SPRN_MI_AP, r8
 767         mtspr   SPRN_MD_AP, r8
 768
 769         /* Map another 8 MByte at the IMMR to get the processor
 770          * internal registers (among other things).
 771          */
 772 #ifdef CONFIG_PIN_TLB
 773         addi    r10, r10, 0x0100
 774         mtspr   SPRN_MD_CTR, r10
 775 #endif
 776         mfspr   r9, 638                 /* Get current IMMR */
 777         andis.  r9, r9, 0xff80          /* Get 8Mbyte boundary */
 778
 779         mr      r8, r9                  /* Create vaddr for TLB */
 780         ori     r8, r8, MD_EVALID       /* Mark it valid */
 781         mtspr   SPRN_MD_EPN, r8
 782         li      r8, MD_PS8MEG           /* Set 8M byte page */
 783         ori     r8, r8, MD_SVALID       /* Make it valid */
 784         mtspr   SPRN_MD_TWC, r8
 785         mr      r8, r9                  /* Create paddr for TLB */
 786         ori     r8, r8, MI_BOOTINIT|0x2 /* Inhibit cache -- Cort */
 787         mtspr   SPRN_MD_RPN, r8
 788
 789 #ifdef CONFIG_PIN_TLB
 790         /* Map two more 8M kernel data pages.
 791         */
 792         addi    r10, r10, 0x0100
 793         mtspr   SPRN_MD_CTR, r10
 794
 795         lis     r8, KERNELBASE@h        /* Create vaddr for TLB */
 796         addis   r8, r8, 0x0080          /* Add 8M */
 797         ori     r8, r8, MI_EVALID       /* Mark it valid */
 798         mtspr   SPRN_MD_EPN, r8
 799         li      r9, MI_PS8MEG           /* Set 8M byte page */
 800         ori     r9, r9, MI_SVALID       /* Make it valid */
 801         mtspr   SPRN_MD_TWC, r9
 802         li      r11, MI_BOOTINIT        /* Create RPN for address 0 */
 803         addis   r11, r11, 0x0080        /* Add 8M */
 804         mtspr   SPRN_MD_RPN, r11
 805
 806         addi    r10, r10, 0x0100
 807         mtspr   SPRN_MD_CTR, r10
 808
 809         addis   r8, r8, 0x0080          /* Add 8M */
 810         mtspr   SPRN_MD_EPN, r8
 811         mtspr   SPRN_MD_TWC, r9
 812         addis   r11, r11, 0x0080        /* Add 8M */
 813         mtspr   SPRN_MD_RPN, r11
 814 #endif
 815
 816         /* Since the cache is enabled according to the information we
 817          * just loaded into the TLB, invalidate and enable the caches here.
 818          * We should probably check/set other modes....later.
 819          */
 820         lis     r8, IDC_INVALL@h
 821         mtspr   SPRN_IC_CST, r8
 822         mtspr   SPRN_DC_CST, r8
 823         lis     r8, IDC_ENABLE@h
 824         mtspr   SPRN_IC_CST, r8
 825 #ifdef CONFIG_8xx_COPYBACK
 826         mtspr   SPRN_DC_CST, r8
 827 #else
 828         /* For a debug option, I left this here to easily enable
 829          * the write through cache mode
 830          */
 831         lis     r8, DC_SFWT@h
 832         mtspr   SPRN_DC_CST, r8
 833         lis     r8, IDC_ENABLE@h
 834         mtspr   SPRN_DC_CST, r8
 835 #endif
 836         blr
 837
 838
 839 /*
 840  * Set up to use a given MMU context.
 841  * r3 is context number, r4 is PGD pointer.
 842  *
 843  * We place the physical address of the new task page directory loaded
 844  * into the MMU base register, and set the ASID compare register with
 845  * the new "context."
 846  */
 847 _GLOBAL(set_context)
 848
 849 #ifdef CONFIG_BDI_SWITCH
 850         /* Context switch the PTE pointer for the Abatron BDI2000.
 851          * The PGDIR is passed as second argument.
 852          */
 853         lis     r5, KERNELBASE@h
 854         lwz     r5, 0xf0(r5)
 855         stw     r4, 0x4(r5)
 856 #endif
 857
 858 #ifdef CONFIG_8xx_CPU6
 859         lis     r6, cpu6_errata_word@h
 860         ori     r6, r6, cpu6_errata_word@l
 861         tophys  (r4, r4)
 862         li      r7, 0x3980
 863         stw     r7, 12(r6)
 864         lwz     r7, 12(r6)
 865         mtspr   SPRN_M_TWB, r4               /* Update MMU base address */
 866         li      r7, 0x3380
 867         stw     r7, 12(r6)
 868         lwz     r7, 12(r6)
 869         mtspr   SPRN_M_CASID, r3             /* Update context */
 870 #else
 871         mtspr   SPRN_M_CASID,r3         /* Update context */
 872         tophys  (r4, r4)
 873         mtspr   SPRN_M_TWB, r4          /* and pgd */
 874 #endif
 875         SYNC
 876         blr
 877
 878 #ifdef CONFIG_8xx_CPU6
 879 /* It's here because it is unique to the 8xx.
 880  * It is important we get called with interrupts disabled.  I used to
 881  * do that, but it appears that all code that calls this already had
 882  * interrupt disabled.
 883  */
 884         .globl  set_dec_cpu6
 885 set_dec_cpu6:
 886         lis     r7, cpu6_errata_word@h
 887         ori     r7, r7, cpu6_errata_word@l
 888         li      r4, 0x2c00
 889         stw     r4, 8(r7)
 890         lwz     r4, 8(r7)
 891         mtspr   22, r3          /* Update Decrementer */
 892         SYNC
 893         blr
 894 #endif
 895
 896 /*
 897  * We put a few things here that have to be page-aligned.
 898  * This stuff goes at the beginning of the data segment,
 899  * which is page-aligned.
 900  */
 901         .data
 902         .globl  sdata
 903 sdata:
 904         .globl  empty_zero_page
 905 empty_zero_page:
 906         .space  4096
 907
 908         .globl  swapper_pg_dir
 909 swapper_pg_dir:
 910         .space  4096
 911
 912 /*
 913  * This space gets a copy of optional info passed to us by the bootstrap
 914  * Used to pass parameters into the kernel like root=/dev/sda1, etc.
 915  */
 916         .globl  cmd_line
 917 cmd_line:
 918         .space  512
 919
 920 /* Room for two PTE table poiners, usually the kernel and current user
 921  * pointer to their respective root page table (pgdir).
 922  */
 923 abatron_pteptrs:
 924         .space  8
 925
 926 #ifdef CONFIG_8xx_CPU6
 927         .globl  cpu6_errata_word
 928 cpu6_errata_word:
 929         .space  16
 930 #endif
 931