git.oblomov.eu Git - linux-2.6/blob - arch/s390/kernel/vdso64/clock_gettime.S

   1 /*
   2  * Userland implementation of clock_gettime() for 64 bits processes in a
   3  * s390 kernel for use in the vDSO
   4  *
   5  *  Copyright IBM Corp. 2008
   6  *  Author(s): Martin Schwidefsky (schwidefsky@de.ibm.com)
   7  *
   8  * This program is free software; you can redistribute it and/or modify
   9  * it under the terms of the GNU General Public License (version 2 only)
  10  * as published by the Free Software Foundation.
  11  */
  12 #include <asm/vdso.h>
  13 #include <asm/asm-offsets.h>
  14 #include <asm/unistd.h>
  15
  16         .text
  17         .align 4
  18         .globl __kernel_clock_gettime
  19         .type  __kernel_clock_gettime,@function
  20 __kernel_clock_gettime:
  21         .cfi_startproc
  22         larl    %r5,_vdso_data
  23         cghi    %r2,CLOCK_REALTIME
  24         je      4f
  25         cghi    %r2,CLOCK_MONOTONIC
  26         jne     9f
  27
  28         /* CLOCK_MONOTONIC */
  29         ltgr    %r3,%r3
  30         jz      3f                              /* tp == NULL */
  31 0:      lg      %r4,__VDSO_UPD_COUNT(%r5)       /* load update counter */
  32         tmll    %r4,0x0001                      /* pending update ? loop */
  33         jnz     0b
  34         stck    48(%r15)                        /* Store TOD clock */
  35         lg      %r1,48(%r15)
  36         sg      %r1,__VDSO_XTIME_STAMP(%r5)     /* TOD - cycle_last */
  37         mghi    %r1,1000
  38         srlg    %r1,%r1,12                      /* cyc2ns(clock,cycle_delta) */
  39         alg     %r1,__VDSO_XTIME_NSEC(%r5)      /*  + xtime */
  40         lg      %r0,__VDSO_XTIME_SEC(%r5)
  41         alg     %r1,__VDSO_WTOM_NSEC(%r5)       /*  + wall_to_monotonic */
  42         alg     %r0,__VDSO_WTOM_SEC(%r5)
  43         clg     %r4,__VDSO_UPD_COUNT(%r5)       /* check update counter */
  44         jne     0b
  45         larl    %r5,10f
  46 1:      clg     %r1,0(%r5)
  47         jl      2f
  48         slg     %r1,0(%r5)
  49         aghi    %r0,1
  50         j       1b
  51 2:      stg     %r0,0(%r3)                      /* store tp->tv_sec */
  52         stg     %r1,8(%r3)                      /* store tp->tv_nsec */
  53 3:      lghi    %r2,0
  54         br      %r14
  55
  56         /* CLOCK_REALTIME */
  57 4:      ltr     %r3,%r3                         /* tp == NULL */
  58         jz      8f
  59 5:      lg      %r4,__VDSO_UPD_COUNT(%r5)       /* load update counter */
  60         tmll    %r4,0x0001                      /* pending update ? loop */
  61         jnz     5b
  62         stck    48(%r15)                        /* Store TOD clock */
  63         lg      %r1,48(%r15)
  64         sg      %r1,__VDSO_XTIME_STAMP(%r5)     /* TOD - cycle_last */
  65         mghi    %r1,1000
  66         srlg    %r1,%r1,12                      /* cyc2ns(clock,cycle_delta) */
  67         alg     %r1,__VDSO_XTIME_NSEC(%r5)      /*  + xtime */
  68         lg      %r0,__VDSO_XTIME_SEC(%r5)
  69         clg     %r4,__VDSO_UPD_COUNT(%r5)       /* check update counter */
  70         jne     5b
  71         larl    %r5,10f
  72 6:      clg     %r1,0(%r5)
  73         jl      7f
  74         slg     %r1,0(%r5)
  75         aghi    %r0,1
  76         j       6b
  77 7:      stg     %r0,0(%r3)                      /* store tp->tv_sec */
  78         stg     %r1,8(%r3)                      /* store tp->tv_nsec */
  79 8:      lghi    %r2,0
  80         br      %r14
  81
  82         /* Fallback to system call */
  83 9:      lghi    %r1,__NR_clock_gettime
  84         svc     0
  85         br      %r14
  86
  87 10:     .quad   1000000000
  88         .cfi_endproc
  89         .size   __kernel_clock_gettime,.-__kernel_clock_gettime