git.oblomov.eu Git - linux-2.6/blob - arch/m32r/kernel/vmlinux.lds.S

   1 /* ld script to make M32R Linux kernel
   2  */
   3
   4 #include <asm-generic/vmlinux.lds.h>
   5 #include <asm/addrspace.h>
   6 #include <asm/page.h>
   7
   8 OUTPUT_ARCH(m32r)
   9 ENTRY(startup_32)
  10 #if defined(__LITTLE_ENDIAN__)
  11        jiffies = jiffies_64;
  12 #else
  13        jiffies = jiffies_64 + 4;
  14 #endif
  15 SECTIONS
  16 {
  17   . = CONFIG_MEMORY_START + __PAGE_OFFSET;
  18   eit_vector = .;
  19
  20   . = . + 0x1000;
  21   .empty_zero_page : { *(.empty_zero_page) } = 0
  22
  23   /* read-only */
  24   _text = .;                    /* Text and read-only data */
  25   .boot : { *(.boot) } = 0
  26   .text : {
  27         *(.text)
  28         SCHED_TEXT
  29         LOCK_TEXT
  30         *(.fixup)
  31         *(.gnu.warning)
  32         } = 0x9090
  33 #ifdef CONFIG_SMP
  34   . = ALIGN(65536);
  35   .eit_vector4 : { *(.eit_vector4) }
  36 #endif
  37   _etext = .;                   /* End of text section */
  38
  39   . = ALIGN(16);                /* Exception table */
  40   __start___ex_table = .;
  41   __ex_table : { *(__ex_table) }
  42   __stop___ex_table = .;
  43
  44   RODATA
  45
  46   /* writeable */
  47   .data : {                     /* Data */
  48         *(.spu)
  49         *(.spi)
  50         *(.data)
  51         CONSTRUCTORS
  52         }
  53
  54   . = ALIGN(4096);
  55   __nosave_begin = .;
  56   .data_nosave : { *(.data.nosave) }
  57   . = ALIGN(4096);
  58   __nosave_end = .;
  59
  60   . = ALIGN(4096);
  61   .data.page_aligned : { *(.data.idt) }
  62
  63   . = ALIGN(32);
  64   .data.cacheline_aligned : { *(.data.cacheline_aligned) }
  65
  66   _edata = .;                   /* End of data section */
  67
  68   . = ALIGN(8192);              /* init_task */
  69   .data.init_task : { *(.data.init_task) }
  70
  71   /* will be freed after init */
  72   . = ALIGN(4096);              /* Init code and data */
  73   __init_begin = .;
  74   .init.text : {
  75         _sinittext = .;
  76         *(.init.text)
  77         _einittext = .;
  78   }
  79   .init.data : { *(.init.data) }
  80   . = ALIGN(16);
  81   __setup_start = .;
  82   .init.setup : { *(.init.setup) }
  83   __setup_end = .;
  84   __initcall_start = .;
  85   .initcall.init : {
  86         INITCALLS
  87   }
  88   __initcall_end = .;
  89   __con_initcall_start = .;
  90   .con_initcall.init : { *(.con_initcall.init) }
  91   __con_initcall_end = .;
  92   SECURITY_INIT
  93   . = ALIGN(4);
  94   __alt_instructions = .;
  95   .altinstructions : { *(.altinstructions) }
  96   __alt_instructions_end = .;
  97   .altinstr_replacement : { *(.altinstr_replacement) }
  98   /* .exit.text is discard at runtime, not link time, to deal with references
  99      from .altinstructions and .eh_frame */
 100   .exit.text : { *(.exit.text) }
 101   .exit.data : { *(.exit.data) }
 102   . = ALIGN(4096);
 103   __initramfs_start = .;
 104   .init.ramfs : { *(.init.ramfs) }
 105   __initramfs_end = .;
 106   . = ALIGN(32);
 107   __per_cpu_start = .;
 108   .data.percpu  : { *(.data.percpu) }
 109   __per_cpu_end = .;
 110   . = ALIGN(4096);
 111   __init_end = .;
 112   /* freed after init ends here */
 113
 114   __bss_start = .;              /* BSS */
 115   .bss : { *(.bss) }
 116   . = ALIGN(4);
 117   __bss_stop = .;
 118
 119   _end = . ;
 120
 121   /* Sections to be discarded */
 122   /DISCARD/ : {
 123         *(.exit.text)
 124         *(.exit.data)
 125         *(.exitcall.exit)
 126         }
 127
 128   /* Stabs debugging sections.  */
 129   .stab 0 : { *(.stab) }
 130   .stabstr 0 : { *(.stabstr) }
 131   .stab.excl 0 : { *(.stab.excl) }
 132   .stab.exclstr 0 : { *(.stab.exclstr) }
 133   .stab.index 0 : { *(.stab.index) }
 134   .stab.indexstr 0 : { *(.stab.indexstr) }
 135   .comment 0 : { *(.comment) }
 136 }