git.oblomov.eu Git - linux-2.6/blob - arch/x86_64/kernel/suspend_asm.S

   1 /* Copyright 2004,2005 Pavel Machek <pavel@suse.cz>, Andi Kleen <ak@suse.de>, Rafael J. Wysocki <rjw@sisk.pl>
   2  *
   3  * Distribute under GPLv2.
   4  *
   5  * swsusp_arch_resume may not use any stack, nor any variable that is
   6  * not "NoSave" during copying pages:
   7  *
   8  * Its rewriting one kernel image with another. What is stack in "old"
   9  * image could very well be data page in "new" image, and overwriting
  10  * your own stack under you is bad idea.
  11  */
  12
  13         .text
  14 #include <linux/linkage.h>
  15 #include <asm/segment.h>
  16 #include <asm/page.h>
  17 #include <asm/asm-offsets.h>
  18
  19 ENTRY(swsusp_arch_suspend)
  20
  21         movq %rsp, saved_context_esp(%rip)
  22         movq %rax, saved_context_eax(%rip)
  23         movq %rbx, saved_context_ebx(%rip)
  24         movq %rcx, saved_context_ecx(%rip)
  25         movq %rdx, saved_context_edx(%rip)
  26         movq %rbp, saved_context_ebp(%rip)
  27         movq %rsi, saved_context_esi(%rip)
  28         movq %rdi, saved_context_edi(%rip)
  29         movq %r8,  saved_context_r08(%rip)
  30         movq %r9,  saved_context_r09(%rip)
  31         movq %r10, saved_context_r10(%rip)
  32         movq %r11, saved_context_r11(%rip)
  33         movq %r12, saved_context_r12(%rip)
  34         movq %r13, saved_context_r13(%rip)
  35         movq %r14, saved_context_r14(%rip)
  36         movq %r15, saved_context_r15(%rip)
  37         pushfq ; popq saved_context_eflags(%rip)
  38
  39         call swsusp_save
  40         ret
  41
  42 ENTRY(restore_image)
  43         /* switch to temporary page tables */
  44         movq    $__PAGE_OFFSET, %rdx
  45         movq    temp_level4_pgt(%rip), %rax
  46         subq    %rdx, %rax
  47         movq    %rax, %cr3
  48         /* Flush TLB */
  49         movq    mmu_cr4_features(%rip), %rax
  50         movq    %rax, %rdx
  51         andq    $~(1<<7), %rdx  # PGE
  52         movq    %rdx, %cr4;  # turn off PGE
  53         movq    %cr3, %rcx;  # flush TLB
  54         movq    %rcx, %cr3;
  55         movq    %rax, %cr4;  # turn PGE back on
  56
  57         movq    pagedir_nosave(%rip), %rdx
  58 loop:
  59         testq   %rdx, %rdx
  60         jz      done
  61
  62         /* get addresses from the pbe and copy the page */
  63         movq    pbe_address(%rdx), %rsi
  64         movq    pbe_orig_address(%rdx), %rdi
  65         movq    $512, %rcx
  66         rep
  67         movsq
  68
  69         /* progress to the next pbe */
  70         movq    pbe_next(%rdx), %rdx
  71         jmp     loop
  72 done:
  73         /* go back to the original page tables */
  74         leaq    init_level4_pgt(%rip), %rax
  75         subq    $__START_KERNEL_map, %rax
  76         movq    %rax, %cr3
  77         /* Flush TLB, including "global" things (vmalloc) */
  78         movq    mmu_cr4_features(%rip), %rax
  79         movq    %rax, %rdx
  80         andq    $~(1<<7), %rdx;  # PGE
  81         movq    %rdx, %cr4;  # turn off PGE
  82         movq    %cr3, %rcx;  # flush TLB
  83         movq    %rcx, %cr3
  84         movq    %rax, %cr4;  # turn PGE back on
  85
  86         movl    $24, %eax
  87         movl    %eax, %ds
  88
  89         movq saved_context_esp(%rip), %rsp
  90         movq saved_context_ebp(%rip), %rbp
  91         /* Don't restore %rax, it must be 0 anyway */
  92         movq saved_context_ebx(%rip), %rbx
  93         movq saved_context_ecx(%rip), %rcx
  94         movq saved_context_edx(%rip), %rdx
  95         movq saved_context_esi(%rip), %rsi
  96         movq saved_context_edi(%rip), %rdi
  97         movq saved_context_r08(%rip), %r8
  98         movq saved_context_r09(%rip), %r9
  99         movq saved_context_r10(%rip), %r10
 100         movq saved_context_r11(%rip), %r11
 101         movq saved_context_r12(%rip), %r12
 102         movq saved_context_r13(%rip), %r13
 103         movq saved_context_r14(%rip), %r14
 104         movq saved_context_r15(%rip), %r15
 105         pushq saved_context_eflags(%rip) ; popfq
 106
 107         xorq    %rax, %rax
 108
 109         ret