git.oblomov.eu Git - linux-2.6/blob - arch/um/kernel/uml.lds.S

   1 #include <asm-generic/vmlinux.lds.h>
   2
   3 OUTPUT_FORMAT(ELF_FORMAT)
   4 OUTPUT_ARCH(ELF_ARCH)
   5 ENTRY(_start)
   6 jiffies = jiffies_64;
   7
   8 SECTIONS
   9 {
  10   /* This must contain the right address - not quite the default ELF one.*/
  11   PROVIDE (__executable_start = START);
  12   /* Static binaries stick stuff here, like the sigreturn trampoline,
  13    * invisibly to objdump.  So, just make __binary_start equal to the very
  14    * beginning of the executable, and if there are unmapped pages after this,
  15    * they are forever unusable.
  16    */
  17   __binary_start = START;
  18
  19   . = START + SIZEOF_HEADERS;
  20
  21 #ifdef MODE_TT
  22   .remap_data : { UNMAP_PATH (.data .bss) }
  23   .remap : { UNMAP_PATH (.text) }
  24
  25   . = ALIGN(4096);              /* Init code and data */
  26 #endif
  27
  28   _text = .;
  29   _stext = .;
  30   __init_begin = .;
  31   .init.text : {
  32         _sinittext = .;
  33         *(.init.text)
  34         _einittext = .;
  35   }
  36   . = ALIGN(4096);
  37
  38   .text      :
  39   {
  40     TEXT_TEXT
  41     SCHED_TEXT
  42     LOCK_TEXT
  43     *(.fixup)
  44     /* .gnu.warning sections are handled specially by elf32.em.  */
  45     *(.gnu.warning)
  46     *(.gnu.linkonce.t*)
  47
  48     . = ALIGN(4096);
  49     __syscall_stub_start = .;
  50     *(.__syscall_stub*)
  51     __syscall_stub_end = .;
  52     . = ALIGN(4096);
  53   }
  54
  55   #include "asm/common.lds.S"
  56
  57   init.data : { *(init.data) }
  58   .data    :
  59   {
  60     . = ALIGN(KERNEL_STACK_SIZE);               /* init_task */
  61     *(.data.init_task)
  62     . = ALIGN(KERNEL_STACK_SIZE);
  63     *(.data.init_irqstack)
  64     DATA_DATA
  65     *(.gnu.linkonce.d*)
  66     CONSTRUCTORS
  67   }
  68   .data1   : { *(.data1) }
  69   .ctors         :
  70   {
  71     *(.ctors)
  72   }
  73   .dtors         :
  74   {
  75     *(.dtors)
  76   }
  77
  78   .got           : { *(.got.plt) *(.got) }
  79   .dynamic       : { *(.dynamic) }
  80   .tdata          : { *(.tdata .tdata.* .gnu.linkonce.td.*) }
  81   .tbss           : { *(.tbss .tbss.* .gnu.linkonce.tb.*) *(.tcommon) }
  82   /* We want the small data sections together, so single-instruction offsets
  83      can access them all, and initialized data all before uninitialized, so
  84      we can shorten the on-disk segment size.  */
  85   .sdata     : { *(.sdata) }
  86   _edata  =  .;
  87   PROVIDE (edata = .);
  88   . = ALIGN(0x1000);
  89   .sbss      :
  90   {
  91    __bss_start = .;
  92    PROVIDE(_bss_start = .);
  93    *(.sbss)
  94    *(.scommon)
  95   }
  96   .bss       :
  97   {
  98    *(.dynbss)
  99    *(.bss)
 100    *(COMMON)
 101   }
 102   _end = .;
 103   PROVIDE (end = .);
 104
 105   STABS_DEBUG
 106
 107   DWARF_DEBUG
 108 }