git.oblomov.eu Git - mplib/blob - src/texk/kpathsea/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl Kpathsea package version:
   4 dnl   Starting development:
   5 dnl     kpse_devel_version = dev;
   6 dnl   Making releases:
   7 dnl     kpse_micro_version += 1;
   8 dnl     kpse_devel_version = ;
   9 dnl
  10 dnl Kpathsea shared library version:
  11 dnl   Only bug fixes:
  12 dnl     kpse_lib_micro += 1;
  13 dnl   Adding new interfaces (backwards compatible)
  14 dnl     kpse_lib_minor += 1;
  15 dnl     kpse_lib_micro = 0;
  16 dnl   Modifying or revoking interfaces (not backwards compatible)
  17 dnl     kpse_lib_major += 1;
  18 dnl     kpse_lib_minor = 0;
  19 dnl     kpse_lib_micro = 0;
  20 dnl
  21 m4_define([kpse_major_version], [3])[]dnl
  22 m4_define([kpse_minor_version], [5])[]dnl
  23 m4_define([kpse_micro_version], [7])[]dnl
  24 m4_define([kpse_devel_version], [])[]dnl
  25 m4_define([kpse_version], [kpse_major_version.kpse_minor_version.kpse_micro_version[]kpse_devel_version])[]dnl
  26
  27 m4_define([kpse_lib_major], [4])[]dnl
  28 m4_define([kpse_lib_minor], [1])[]dnl
  29 m4_define([kpse_lib_micro], [0])[]dnl
  30 m4_define([kpse_lt_version],[m4_eval(kpse_lib_major + kpse_lib_minor):kpse_lib_micro:kpse_lib_minor])[]dnl
  31
  32 AC_INIT([kpathsea], [kpse_version], [tex-k@mail.tug.org])
  33 AC_CONFIG_SRCDIR([pathsearch.c])
  34
  35 AC_SUBST([KPSEVERSION], [kpse_version])
  36 AC_DEFINE([KPSEVERSION], ["kpathsea version kpse_version"])
  37 AC_SUBST([KPSE_LT_VERS], [kpse_lt_version])
  38
  39 dnl Write output here, instead of putting a zillion -D's on the command line.
  40 AC_CONFIG_HEADERS([c-auto.h:c-auto.in],
  41  [sed 's/^#define PACKAGE_/#define KPSE_PACKAGE_/' c-auto.h >c-auto.tmp && mv -f c-auto.tmp c-auto.h
  42   date >stamp-auto])
  43
  44 sinclude(common.ac)
  45
  46 AH_TOP([/* c-auto.h: defines for kpathsea, as determined by configure.
  47
  48    Copyright 1994-97, 2008 Karl Berry.
  49    Copyright 1997-99, 2002, 2005 Olaf Weber.
  50
  51    This library is free software; you can redistribute it and/or
  52    modify it under the terms of the GNU Lesser General Public
  53    License as published by the Free Software Foundation; either
  54    version 2.1 of the License, or (at your option) any later version.
  55
  56    This library is distributed in the hope that it will be useful,
  57    but WITHOUT ANY WARRANTY; without even the implied warranty of
  58    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  59    Lesser General Public License for more details.
  60
  61    You should have received a copy of the GNU Lesser General Public License
  62    along with this library; if not, see <http://www.gnu.org/licenses/>.  */
  63
  64 /* Guard against double inclusion. */
  65 #ifndef KPATHSEA_C_AUTO_H
  66 #define KPATHSEA_C_AUTO_H
  67
  68 /* kpathsea: the version string. */
  69 #define KPSEVERSION "REPLACE-WITH-KPSEVERSION"])
  70 AH_BOTTOM([#endif /* !KPATHSEA_C_AUTO_H */])
  71
  72 KPSE_CONFIG_FILES([Makefile])
  73 AC_OUTPUT