git.oblomov.eu Git - nouveau/blob - configure.ac

   1 #  Copyright 2005 Adam Jackson.
   2 #
   3 #  Permission is hereby granted, free of charge, to any person obtaining a
   4 #  copy of this software and associated documentation files (the "Software"),
   5 #  to deal in the Software without restriction, including without limitation
   6 #  on the rights to use, copy, modify, merge, publish, distribute, sub
   7 #  license, and/or sell copies of the Software, and to permit persons to whom
   8 #  the Software is furnished to do so, subject to the following conditions:
   9 #
  10 #  The above copyright notice and this permission notice (including the next
  11 #  paragraph) shall be included in all copies or substantial portions of the
  12 #  Software.
  13 #
  14 #  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  15 #  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  16 #  FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
  17 #  ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
  18 #  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  19 #  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  20 #
  21 # Process this file with autoconf to produce a configure script
  22
  23 AC_PREREQ(2.57)
  24 AC_INIT([xf86-video-nouveau],
  25         0.0.10,
  26         [https://bugs.freedesktop.org/enter_bug.cgi?product=xorg],
  27         xf86-video-nouveau)
  28
  29 AC_DEFINE_UNQUOTED([NV_MAJOR_VERSION],
  30                    [$(echo $PACKAGE_VERSION | sed -e 's/^\([[0-9]]\)\.[[0-9]]\.[[0-9]]/\1/')],
  31                    [Major version])
  32 AC_DEFINE_UNQUOTED([NV_MINOR_VERSION],
  33                    [$(echo $PACKAGE_VERSION | sed -e 's/^[[0-9]]\.\([[0-9]]\)\.[[0-9]]/\1/')],
  34                    [Minor version])
  35 AC_DEFINE_UNQUOTED([NV_PATCHLEVEL],
  36                    [$(echo $PACKAGE_VERSION | sed -e 's/^[[0-9]]\.[[0-9]]\.\([[0-9]]\)/\1/')],
  37                    [Patch version])
  38 AC_DEFINE_UNQUOTED([NV_DRIVER_DATE],
  39                    [$(echo -n \";git-log |head -3|tail -1|tr -d '\n';echo -n \")],
  40                    [Driver date])
  41
  42 AC_CONFIG_SRCDIR([Makefile.am])
  43 AM_CONFIG_HEADER([config.h])
  44 AC_CONFIG_AUX_DIR(.)
  45
  46 AM_INIT_AUTOMAKE([dist-bzip2])
  47
  48 # Checks for programs.
  49 AC_DISABLE_STATIC
  50 AC_PROG_LIBTOOL
  51 AC_PROG_CC
  52
  53 AH_TOP([#include "xorg-server.h"])
  54
  55 AC_ARG_WITH(xorg-module-dir,
  56             AC_HELP_STRING([--with-xorg-module-dir=DIR],
  57                            [Default xorg module directory [[default=$libdir/xorg/modules]]]),
  58             [moduledir="$withval"],
  59             [moduledir="$libdir/xorg/modules"])
  60
  61 # Checks for extensions
  62 XORG_DRIVER_CHECK_EXT(RANDR, randrproto)
  63 XORG_DRIVER_CHECK_EXT(RENDER, renderproto)
  64 XORG_DRIVER_CHECK_EXT(XV, videoproto)
  65 XORG_DRIVER_CHECK_EXT(DPMSExtension, xextproto)
  66
  67 # Checks for pkg-config packages
  68 PKG_CHECK_MODULES(XORG, [xorg-server >= 1.3] xproto fontsproto libdrm xf86driproto $REQUIRED_MODULES)
  69 sdkdir=$(pkg-config --variable=sdkdir xorg-server)
  70
  71 # Checks for libraries.
  72 AC_CHECK_DECL(XSERVER_LIBPCIACCESS,
  73                 [XSERVER_LIBPCIACCESS=yes],[XSERVER_LIBPCIACCESS=no],
  74                 [#include "xorg/xorg-server.h"])
  75
  76 if test x$XSERVER_LIBPCIACCESS = xyes; then
  77         PKG_CHECK_MODULES([PCIACCESS], [pciaccess >= 0.10])
  78 fi
  79
  80 AM_CONDITIONAL(XSERVER_LIBPCIACCESS, test "x$XSERVER_LIBPCIACCESS" = xyes)
  81
  82 # Checks for header files.
  83 AC_HEADER_STDC
  84
  85 # Use -Wall all the time
  86 CFLAGS="$CFLAGS -Wall"
  87
  88 # Check for -minline-all-stringops availabtility
  89 OLD_CFLAGS="$CFLAGS"
  90 CFLAGS="$CFLAGS -minline-all-stringops"
  91 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ #include <stdio.h> ]], [[ ]])],
  92 [ CFLAGS="$OLD_CFLAGS -minline-all-stringops"],[CFLAGS="$OLD_CFLAGS"])
  93
  94 AC_SUBST([CFLAGS])
  95
  96 AC_SUBST([XORG_CFLAGS])
  97 AC_SUBST([moduledir])
  98
  99 DRIVER_NAME=nouveau
 100 AC_SUBST([DRIVER_NAME])
 101
 102 XORG_MANPAGE_SECTIONS
 103 XORG_RELEASE_VERSION
 104
 105 AC_OUTPUT([
 106         Makefile
 107         src/Makefile
 108         man/Makefile
 109 ])