git.oblomov.eu Git - wine/blob - tools/widl/parser.y

   1 %{
   2 /*
   3  * IDL Compiler
   4  *
   5  * Copyright 2002 Ove Kaaven
   6  *
   7  * This library is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU Lesser General Public
   9  * License as published by the Free Software Foundation; either
  10  * version 2.1 of the License, or (at your option) any later version.
  11  *
  12  * This library is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15  * Lesser General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU Lesser General Public
  18  * License along with this library; if not, write to the Free Software
  19  * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  20  */
  21
  22 #include "config.h"
  23
  24 #include <stdio.h>
  25 #include <stdlib.h>
  26 #include <stdarg.h>
  27 #include <assert.h>
  28 #include <ctype.h>
  29 #include <string.h>
  30 #ifdef HAVE_ALLOCA_H
  31 #include <alloca.h>
  32 #endif
  33
  34 #include "windef.h"
  35
  36 #include "widl.h"
  37 #include "utils.h"
  38 #include "parser.h"
  39 #include "header.h"
  40 #include "typelib.h"
  41
  42 #if defined(YYBYACC)
  43         /* Berkeley yacc (byacc) doesn't seem to know about these */
  44         /* Some *BSD supplied versions do define these though */
  45 # ifndef YYEMPTY
  46 #  define YYEMPTY       (-1)    /* Empty lookahead value of yychar */
  47 # endif
  48 # ifndef YYLEX
  49 #  define YYLEX         yylex()
  50 # endif
  51
  52 #elif defined(YYBISON)
  53         /* Bison was used for original development */
  54         /* #define YYEMPTY -2 */
  55         /* #define YYLEX   yylex() */
  56
  57 #else
  58         /* No yacc we know yet */
  59 # if !defined(YYEMPTY) || !defined(YYLEX)
  60 #  error Yacc version/type unknown. This version needs to be verified for settings of YYEMPTY and YYLEX.
  61 # elif defined(__GNUC__)        /* gcc defines the #warning directive */
  62 #  warning Yacc version/type unknown. It defines YYEMPTY and YYLEX, but is not tested
  63   /* #else we just take a chance that it works... */
  64 # endif
  65 #endif
  66
  67 static attr_t *make_attr(enum attr_type type);
  68 static attr_t *make_attrv(enum attr_type type, unsigned long val);
  69 static attr_t *make_attrp(enum attr_type type, void *val);
  70 static expr_t *make_expr(enum expr_type type);
  71 static expr_t *make_exprl(enum expr_type type, long val);
  72 static expr_t *make_exprs(enum expr_type type, char *val);
  73 static expr_t *make_exprt(enum expr_type type, typeref_t *tref, expr_t *expr);
  74 static expr_t *make_expr1(enum expr_type type, expr_t *expr);
  75 static expr_t *make_expr2(enum expr_type type, expr_t *exp1, expr_t *exp2);
  76 static expr_t *make_expr3(enum expr_type type, expr_t *expr1, expr_t *expr2, expr_t *expr3);
  77 static type_t *make_type(unsigned char type, type_t *ref);
  78 static typeref_t *make_tref(char *name, type_t *ref);
  79 static typeref_t *uniq_tref(typeref_t *ref);
  80 static type_t *type_ref(typeref_t *ref);
  81 static void set_type(var_t *v, typeref_t *ref, expr_t *arr);
  82 static ifref_t *make_ifref(type_t *iface);
  83 static var_t *make_var(char *name);
  84 static func_t *make_func(var_t *def, var_t *args);
  85 static class_t *make_class(char *name);
  86
  87 static type_t *reg_type(type_t *type, const char *name, int t);
  88 static type_t *reg_types(type_t *type, var_t *names, int t);
  89 static type_t *find_type(const char *name, int t);
  90 static type_t *find_type2(char *name, int t);
  91 static type_t *get_type(unsigned char type, char *name, int t);
  92 static type_t *get_typev(unsigned char type, var_t *name, int t);
  93 static int get_struct_type(var_t *fields);
  94
  95 static var_t *reg_const(var_t *var);
  96 static var_t *find_const(char *name, int f);
  97
  98 #define tsENUM   1
  99 #define tsSTRUCT 2
 100 #define tsUNION  3
 101
 102 static type_t std_bool = { "boolean" };
 103 static type_t std_int = { "int" };
 104 static type_t std_int64 = { "__int64" };
 105 static type_t std_uhyper = { "MIDL_uhyper" };
 106
 107 %}
 108 %union {
 109         attr_t *attr;
 110         expr_t *expr;
 111         type_t *type;
 112         typeref_t *tref;
 113         var_t *var;
 114         func_t *func;
 115         ifref_t *ifref;
 116         class_t *clas;
 117         char *str;
 118         UUID *uuid;
 119         unsigned int num;
 120 }
 121
 122 %token <str> aIDENTIFIER
 123 %token <str> aKNOWNTYPE
 124 %token <num> aNUM aHEXNUM
 125 %token <str> aSTRING
 126 %token <uuid> aUUID
 127 %token aEOF
 128 %token SHL SHR
 129 %token tAGGREGATABLE tALLOCATE tAPPOBJECT tASYNC tASYNCUUID
 130 %token tAUTOHANDLE tBINDABLE tBOOLEAN tBROADCAST tBYTE tBYTECOUNT
 131 %token tCALLAS tCALLBACK tCASE tCDECL tCHAR tCOCLASS tCODE tCOMMSTATUS
 132 %token tCONST tCONTEXTHANDLE tCONTEXTHANDLENOSERIALIZE
 133 %token tCONTEXTHANDLESERIALIZE tCONTROL tCPPQUOTE
 134 %token tDEFAULT
 135 %token tDEFAULTCOLLELEM
 136 %token tDEFAULTVALUE
 137 %token tDEFAULTVTABLE
 138 %token tDISPLAYBIND
 139 %token tDISPINTERFACE
 140 %token tDLLNAME tDOUBLE tDUAL
 141 %token tENDPOINT
 142 %token tENTRY tENUM tERRORSTATUST
 143 %token tEXPLICITHANDLE tEXTERN
 144 %token tFLOAT
 145 %token tHANDLE
 146 %token tHANDLET
 147 %token tHELPCONTEXT tHELPFILE
 148 %token tHELPSTRING tHELPSTRINGCONTEXT tHELPSTRINGDLL
 149 %token tHIDDEN
 150 %token tHYPER tID tIDEMPOTENT
 151 %token tIIDIS
 152 %token tIMMEDIATEBIND
 153 %token tIMPLICITHANDLE
 154 %token tIMPORT tIMPORTLIB
 155 %token tIN tINLINE
 156 %token tINPUTSYNC
 157 %token tINT tINT64
 158 %token tINTERFACE
 159 %token tLCID
 160 %token tLENGTHIS tLIBRARY
 161 %token tLOCAL
 162 %token tLONG
 163 %token tMETHODS
 164 %token tMODULE
 165 %token tNONBROWSABLE
 166 %token tNONCREATABLE
 167 %token tNONEXTENSIBLE
 168 %token tOBJECT tODL tOLEAUTOMATION
 169 %token tOPTIONAL
 170 %token tOUT
 171 %token tPOINTERDEFAULT
 172 %token tPROPERTIES
 173 %token tPROPGET tPROPPUT tPROPPUTREF
 174 %token tPTR
 175 %token tPUBLIC
 176 %token tRANGE
 177 %token tREADONLY tREF
 178 %token tREQUESTEDIT
 179 %token tRESTRICTED
 180 %token tRETVAL
 181 %token tSHORT
 182 %token tSIGNED
 183 %token tSINGLE
 184 %token tSIZEIS tSIZEOF
 185 %token tSMALL
 186 %token tSOURCE
 187 %token tSTDCALL
 188 %token tSTRING tSTRUCT
 189 %token tSWITCH tSWITCHIS tSWITCHTYPE
 190 %token tTRANSMITAS
 191 %token tTYPEDEF
 192 %token tUNION
 193 %token tUNIQUE
 194 %token tUNSIGNED
 195 %token tUUID
 196 %token tV1ENUM
 197 %token tVARARG
 198 %token tVERSION
 199 %token tVOID
 200 %token tWCHAR tWIREMARSHAL
 201
 202 %type <attr> m_attributes attributes attrib_list attribute
 203 %type <expr> m_exprs /* exprs expr_list */ m_expr expr expr_list_const expr_const
 204 %type <expr> array array_list
 205 %type <type> inherit interface interfacehdr interfacedef interfacedec
 206 %type <type> dispinterface dispinterfacehdr dispinterfacedef
 207 %type <type> module modulehdr moduledef
 208 %type <type> base_type int_std
 209 %type <type> enumdef structdef typedef uniondef
 210 %type <ifref> gbl_statements coclass_ints coclass_int
 211 %type <tref> type
 212 %type <var> m_args no_args args arg
 213 %type <var> fields field s_field cases case enums enum_list enum constdef externdef
 214 %type <var> m_ident t_ident ident p_ident pident pident_list
 215 %type <var> dispint_props
 216 %type <func> funcdef int_statements
 217 %type <func> dispint_meths
 218 %type <clas> coclass coclasshdr coclassdef
 219 %type <num> pointer_type version
 220 %type <str> libraryhdr
 221
 222 %left ','
 223 %right '?' ':'
 224 %left '|'
 225 %left '&'
 226 %left '-' '+'
 227 %left '*' '/'
 228 %left SHL SHR
 229 %right '~'
 230 %right CAST
 231 %right PPTR
 232 %right NEG
 233
 234 %%
 235
 236 input:   gbl_statements                        { write_proxies($1); write_client($1); write_server($1); }
 237         ;
 238
 239 gbl_statements:                                 { $$ = NULL; }
 240         | gbl_statements interfacedec           { $$ = $1; }
 241         | gbl_statements interfacedef           { $$ = make_ifref($2); LINK($$, $1); }
 242         | gbl_statements coclass ';'    { $$ = $1; if (!parse_only && do_header) write_coclass_forward($2); }
 243         | gbl_statements coclassdef             { $$ = $1; add_coclass($2); }
 244         | gbl_statements moduledef              { $$ = $1; add_module($2); }
 245         | gbl_statements librarydef             { $$ = $1; }
 246         | gbl_statements statement              { $$ = $1; }
 247         ;
 248
 249 imp_statements:                                 {}
 250         | imp_statements interfacedec           { if (!parse_only) add_interface($2); }
 251         | imp_statements interfacedef           { if (!parse_only) add_interface($2); }
 252         | imp_statements coclass ';'    {}
 253         | imp_statements coclassdef             { if (!parse_only) add_coclass($2); }
 254         | imp_statements moduledef              { if (!parse_only) add_module($2); }
 255         | imp_statements statement              {}
 256         | imp_statements importlib              {}
 257         ;
 258
 259 int_statements:                                 { $$ = NULL; }
 260         | int_statements funcdef ';'            { $$ = $2; LINK($$, $1); }
 261         | int_statements statement              { $$ = $1; }
 262         ;
 263
 264 statement: ';'                                  {}
 265         | constdef ';'                          { if (!parse_only && do_header) { write_constdef($1); } }
 266         | cppquote                              {}
 267         | enumdef ';'                           { if (!parse_only && do_header) { write_type(header, $1, NULL, NULL); fprintf(header, ";\n\n"); } }
 268         | externdef ';'                         { if (!parse_only && do_header) { write_externdef($1); } }
 269         | import                                {}
 270         | structdef ';'                         { if (!parse_only && do_header) { write_type(header, $1, NULL, NULL); fprintf(header, ";\n\n"); } }
 271         | typedef ';'                           {}
 272         | uniondef ';'                          { if (!parse_only && do_header) { write_type(header, $1, NULL, NULL); fprintf(header, ";\n\n"); } }
 273         ;
 274
 275 cppquote: tCPPQUOTE '(' aSTRING ')'             { if (!parse_only && do_header) fprintf(header, "%s\n", $3); }
 276         ;
 277 import_start: tIMPORT aSTRING ';'               { assert(yychar == YYEMPTY);
 278                                                   if (!do_import($2)) yychar = aEOF; }
 279         ;
 280 import:   import_start imp_statements aEOF      {}
 281         ;
 282
 283 importlib: tIMPORTLIB '(' aSTRING ')'           { if(!parse_only) add_importlib($3); }
 284         ;
 285
 286 libraryhdr: tLIBRARY aIDENTIFIER                { $$ = $2; }
 287         ;
 288 library_start: attributes libraryhdr '{'        { start_typelib($2, $1);
 289                                                   if (!parse_only && do_header) write_library($2, $1); }
 290         ;
 291 librarydef: library_start imp_statements '}'    { end_typelib(); }
 292         ;
 293
 294 m_args:                                         { $$ = NULL; }
 295         | args
 296         ;
 297
 298 no_args:  tVOID                                 { $$ = NULL; }
 299         ;
 300
 301 args:     arg
 302         | args ',' arg                          { LINK($3, $1); $$ = $3; }
 303         | no_args
 304         ;
 305
 306 /* split into two rules to get bison to resolve a tVOID conflict */
 307 arg:      attributes type pident array          { $$ = $3;
 308                                                   set_type($$, $2, $4);
 309                                                   $$->attrs = $1;
 310                                                 }
 311         | type pident array                     { $$ = $2;
 312                                                   set_type($$, $1, $3);
 313                                                 }
 314         | attributes type pident '(' m_args ')' { $$ = $3;
 315                                                   $$->ptr_level--;
 316                                                   set_type($$, $2, NULL);
 317                                                   $$->attrs = $1;
 318                                                   $$->args = $5;
 319                                                 }
 320         | type pident '(' m_args ')'            { $$ = $2;
 321                                                   $$->ptr_level--;
 322                                                   set_type($$, $1, NULL);
 323                                                   $$->args = $4;
 324                                                 }
 325         ;
 326
 327 array:                                          { $$ = NULL; }
 328         | '[' array_list ']'                    { $$ = $2; }
 329         | '[' '*' ']'                           { $$ = make_expr(EXPR_VOID); }
 330         ;
 331
 332 array_list: m_expr /* size of first dimension is optional */
 333         | array_list ',' expr                   { LINK($3, $1); $$ = $3; }
 334         | array_list ']' '[' expr               { LINK($4, $1); $$ = $4; }
 335         ;
 336
 337 m_attributes:                                   { $$ = NULL; }
 338         | attributes
 339         ;
 340
 341 attributes:
 342           '[' attrib_list ']'                   { $$ = $2; }
 343         ;
 344
 345 attrib_list: attribute
 346         | attrib_list ',' attribute             { LINK($3, $1); $$ = $3; }
 347         | attrib_list ']' '[' attribute         { LINK($4, $1); $$ = $4; }
 348         ;
 349
 350 attribute:
 351           tAGGREGATABLE                         { $$ = make_attr(ATTR_AGGREGATABLE); }
 352         | tAPPOBJECT                            { $$ = make_attr(ATTR_APPOBJECT); }
 353         | tASYNC                                { $$ = make_attr(ATTR_ASYNC); }
 354         | tAUTOHANDLE                           { $$ = make_attr(ATTR_AUTO_HANDLE); }
 355         | tBINDABLE                             { $$ = make_attr(ATTR_BINDABLE); }
 356         | tCALLAS '(' ident ')'                 { $$ = make_attrp(ATTR_CALLAS, $3); }
 357         | tCASE '(' expr_list_const ')'         { $$ = make_attrp(ATTR_CASE, $3); }
 358         | tCONTEXTHANDLE                        { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); }
 359         | tCONTEXTHANDLENOSERIALIZE             { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); /* RPC_CONTEXT_HANDLE_DONT_SERIALIZE */ }
 360         | tCONTEXTHANDLESERIALIZE               { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); /* RPC_CONTEXT_HANDLE_SERIALIZE */ }
 361         | tCONTROL                              { $$ = make_attr(ATTR_CONTROL); }
 362         | tDEFAULT                              { $$ = make_attr(ATTR_DEFAULT); }
 363         | tDEFAULTCOLLELEM                      { $$ = make_attr(ATTR_DEFAULTCOLLELEM); }
 364         | tDEFAULTVALUE '(' expr_const ')'      { $$ = make_attrp(ATTR_DEFAULTVALUE_EXPR, $3); }
 365         | tDEFAULTVALUE '(' aSTRING ')'         { $$ = make_attrp(ATTR_DEFAULTVALUE_STRING, $3); }
 366         | tDEFAULTVTABLE                        { $$ = make_attr(ATTR_DEFAULTVTABLE); }
 367         | tDISPLAYBIND                          { $$ = make_attr(ATTR_DISPLAYBIND); }
 368         | tDLLNAME '(' aSTRING ')'              { $$ = make_attrp(ATTR_DLLNAME, $3); }
 369         | tDUAL                                 { $$ = make_attr(ATTR_DUAL); }
 370         | tENDPOINT '(' aSTRING ')'             { $$ = make_attrp(ATTR_ENDPOINT, $3); }
 371         | tENTRY '(' aSTRING ')'                { $$ = make_attrp(ATTR_ENTRY_STRING, $3); }
 372         | tENTRY '(' expr_const ')'             { $$ = make_attrp(ATTR_ENTRY_ORDINAL, $3); }
 373         | tEXPLICITHANDLE                       { $$ = make_attr(ATTR_EXPLICIT_HANDLE); }
 374         | tHANDLE                               { $$ = make_attr(ATTR_HANDLE); }
 375         | tHELPCONTEXT '(' expr_const ')'       { $$ = make_attrp(ATTR_HELPCONTEXT, $3); }
 376         | tHELPFILE '(' aSTRING ')'             { $$ = make_attrp(ATTR_HELPFILE, $3); }
 377         | tHELPSTRING '(' aSTRING ')'           { $$ = make_attrp(ATTR_HELPSTRING, $3); }
 378         | tHELPSTRINGCONTEXT '(' expr_const ')' { $$ = make_attrp(ATTR_HELPSTRINGCONTEXT, $3); }
 379         | tHELPSTRINGDLL '(' aSTRING ')'        { $$ = make_attrp(ATTR_HELPSTRINGDLL, $3); }
 380         | tHIDDEN                               { $$ = make_attr(ATTR_HIDDEN); }
 381         | tID '(' expr_const ')'                { $$ = make_attrp(ATTR_ID, $3); }
 382         | tIDEMPOTENT                           { $$ = make_attr(ATTR_IDEMPOTENT); }
 383         | tIIDIS '(' ident ')'                  { $$ = make_attrp(ATTR_IIDIS, $3); }
 384         | tIMMEDIATEBIND                        { $$ = make_attr(ATTR_IMMEDIATEBIND); }
 385         | tIMPLICITHANDLE '(' tHANDLET aIDENTIFIER ')'  { $$ = make_attrp(ATTR_IMPLICIT_HANDLE, $4); }
 386         | tIN                                   { $$ = make_attr(ATTR_IN); }
 387         | tINPUTSYNC                            { $$ = make_attr(ATTR_INPUTSYNC); }
 388         | tLENGTHIS '(' m_exprs ')'             { $$ = make_attrp(ATTR_LENGTHIS, $3); }
 389         | tLOCAL                                { $$ = make_attr(ATTR_LOCAL); }
 390         | tNONBROWSABLE                         { $$ = make_attr(ATTR_NONBROWSABLE); }
 391         | tNONCREATABLE                         { $$ = make_attr(ATTR_NONCREATABLE); }
 392         | tNONEXTENSIBLE                        { $$ = make_attr(ATTR_NONEXTENSIBLE); }
 393         | tOBJECT                               { $$ = make_attr(ATTR_OBJECT); }
 394         | tODL                                  { $$ = make_attr(ATTR_ODL); }
 395         | tOLEAUTOMATION                        { $$ = make_attr(ATTR_OLEAUTOMATION); }
 396         | tOPTIONAL                             { $$ = make_attr(ATTR_OPTIONAL); }
 397         | tOUT                                  { $$ = make_attr(ATTR_OUT); }
 398         | tPOINTERDEFAULT '(' pointer_type ')'  { $$ = make_attrv(ATTR_POINTERDEFAULT, $3); }
 399         | tPROPGET                              { $$ = make_attr(ATTR_PROPGET); }
 400         | tPROPPUT                              { $$ = make_attr(ATTR_PROPPUT); }
 401         | tPROPPUTREF                           { $$ = make_attr(ATTR_PROPPUTREF); }
 402         | tPUBLIC                               { $$ = make_attr(ATTR_PUBLIC); }
 403         | tRANGE '(' expr_const ',' expr_const ')' { LINK($5, $3); $$ = make_attrp(ATTR_RANGE, $5); }
 404         | tREADONLY                             { $$ = make_attr(ATTR_READONLY); }
 405         | tREQUESTEDIT                          { $$ = make_attr(ATTR_REQUESTEDIT); }
 406         | tRESTRICTED                           { $$ = make_attr(ATTR_RESTRICTED); }
 407         | tRETVAL                               { $$ = make_attr(ATTR_RETVAL); }
 408         | tSIZEIS '(' m_exprs ')'               { $$ = make_attrp(ATTR_SIZEIS, $3); }
 409         | tSOURCE                               { $$ = make_attr(ATTR_SOURCE); }
 410         | tSTRING                               { $$ = make_attr(ATTR_STRING); }
 411         | tSWITCHIS '(' expr ')'                { $$ = make_attrp(ATTR_SWITCHIS, $3); }
 412         | tSWITCHTYPE '(' type ')'              { $$ = make_attrp(ATTR_SWITCHTYPE, type_ref($3)); }
 413         | tTRANSMITAS '(' type ')'              { $$ = make_attrp(ATTR_TRANSMITAS, type_ref($3)); }
 414         | tUUID '(' aUUID ')'                   { $$ = make_attrp(ATTR_UUID, $3); }
 415         | tV1ENUM                               { $$ = make_attr(ATTR_V1ENUM); }
 416         | tVARARG                               { $$ = make_attr(ATTR_VARARG); }
 417         | tVERSION '(' version ')'              { $$ = make_attrv(ATTR_VERSION, $3); }
 418         | tWIREMARSHAL '(' type ')'             { $$ = make_attrp(ATTR_WIREMARSHAL, type_ref($3)); }
 419         | pointer_type                          { $$ = make_attrv(ATTR_POINTERTYPE, $1); }
 420         ;
 421
 422 callconv:
 423         | tSTDCALL
 424         ;
 425
 426 cases:                                          { $$ = NULL; }
 427         | cases case                            { if ($2) { LINK($2, $1); $$ = $2; }
 428                                                   else { $$ = $1; }
 429                                                 }
 430         ;
 431
 432 case:     tCASE expr ':' field                  { attr_t *a = make_attrp(ATTR_CASE, $2);
 433                                                   $$ = $4; if (!$$) $$ = make_var(NULL);
 434                                                   LINK(a, $$->attrs); $$->attrs = a;
 435                                                 }
 436         | tDEFAULT ':' field                    { attr_t *a = make_attr(ATTR_DEFAULT);
 437                                                   $$ = $3; if (!$$) $$ = make_var(NULL);
 438                                                   LINK(a, $$->attrs); $$->attrs = a;
 439                                                 }
 440         ;
 441
 442 constdef: tCONST type ident '=' expr_const      { $$ = reg_const($3);
 443                                                   set_type($$, $2, NULL);
 444                                                   $$->eval = $5;
 445                                                 }
 446         ;
 447
 448 enums:                                          { $$ = NULL; }
 449         | enum_list ','                         { $$ = $1; }
 450         | enum_list
 451         ;
 452
 453 enum_list: enum                                 { if (!$$->eval)
 454                                                     $$->eval = make_exprl(EXPR_NUM, 0 /* default for first enum entry */);
 455                                                 }
 456         | enum_list ',' enum                    { LINK($3, $1); $$ = $3;
 457                                                   if (!$$->eval)
 458                                                     $$->eval = make_exprl(EXPR_NUM, $1->eval->cval + 1);
 459                                                 }
 460         ;
 461
 462 enum:     ident '=' expr_const                  { $$ = reg_const($1);
 463                                                   $$->eval = $3;
 464                                                   $$->type = make_type(RPC_FC_LONG, &std_int);
 465                                                 }
 466         | ident                                 { $$ = reg_const($1);
 467                                                   $$->type = make_type(RPC_FC_LONG, &std_int);
 468                                                 }
 469         ;
 470
 471 enumdef: tENUM t_ident '{' enums '}'            { $$ = get_typev(RPC_FC_ENUM16, $2, tsENUM);
 472                                                   $$->fields = $4;
 473                                                   $$->defined = TRUE;
 474                                                   if(in_typelib)
 475                                                       add_enum($$);
 476                                                 }
 477         ;
 478
 479 m_exprs:  m_expr
 480         | m_exprs ',' m_expr                    { LINK($3, $1); $$ = $3; }
 481         ;
 482
 483 /*
 484 exprs:                                          { $$ = make_expr(EXPR_VOID); }
 485         | expr_list
 486         ;
 487
 488 expr_list: expr
 489         | expr_list ',' expr                    { LINK($3, $1); $$ = $3; }
 490         ;
 491 */
 492
 493 m_expr:                                         { $$ = make_expr(EXPR_VOID); }
 494         | expr
 495         ;
 496
 497 expr:     aNUM                                  { $$ = make_exprl(EXPR_NUM, $1); }
 498         | aHEXNUM                               { $$ = make_exprl(EXPR_HEXNUM, $1); }
 499         | aIDENTIFIER                           { $$ = make_exprs(EXPR_IDENTIFIER, $1); }
 500         | expr '?' expr ':' expr                { $$ = make_expr3(EXPR_COND, $1, $3, $5); }
 501         | expr '|' expr                         { $$ = make_expr2(EXPR_OR , $1, $3); }
 502         | expr '&' expr                         { $$ = make_expr2(EXPR_AND, $1, $3); }
 503         | expr '+' expr                         { $$ = make_expr2(EXPR_ADD, $1, $3); }
 504         | expr '-' expr                         { $$ = make_expr2(EXPR_SUB, $1, $3); }
 505         | expr '*' expr                         { $$ = make_expr2(EXPR_MUL, $1, $3); }
 506         | expr '/' expr                         { $$ = make_expr2(EXPR_DIV, $1, $3); }
 507         | expr SHL expr                         { $$ = make_expr2(EXPR_SHL, $1, $3); }
 508         | expr SHR expr                         { $$ = make_expr2(EXPR_SHR, $1, $3); }
 509         | '~' expr                              { $$ = make_expr1(EXPR_NOT, $2); }
 510         | '-' expr %prec NEG                    { $$ = make_expr1(EXPR_NEG, $2); }
 511         | '*' expr %prec PPTR                   { $$ = make_expr1(EXPR_PPTR, $2); }
 512         | '(' type ')' expr %prec CAST          { $$ = make_exprt(EXPR_CAST, $2, $4); }
 513         | tSIZEOF '(' type ')'                  { $$ = make_exprt(EXPR_SIZEOF, $3, NULL); }
 514         | '(' expr ')'                          { $$ = $2; }
 515         ;
 516
 517 expr_list_const: expr_const
 518         | expr_list_const ',' expr_const        { LINK($3, $1); $$ = $3; }
 519         ;
 520
 521 expr_const: expr                                { $$ = $1;
 522                                                   if (!$$->is_const)
 523                                                       yyerror("expression is not constant");
 524                                                 }
 525         ;
 526
 527 externdef: tEXTERN tCONST type ident            { $$ = $4;
 528                                                   set_type($$, $3, NULL);
 529                                                 }
 530         ;
 531
 532 fields:                                         { $$ = NULL; }
 533         | fields field                          { if ($2) { LINK($2, $1); $$ = $2; }
 534                                                   else { $$ = $1; }
 535                                                 }
 536         ;
 537
 538 field:    s_field ';'                           { $$ = $1; }
 539         | m_attributes uniondef ';'             { $$ = make_var(NULL); $$->type = $2; $$->attrs = $1; }
 540         | attributes ';'                        { $$ = make_var(NULL); $$->attrs = $1; }
 541         | ';'                                   { $$ = NULL; }
 542         ;
 543
 544 s_field:  m_attributes type pident array        { $$ = $3; set_type($$, $2, $4); $$->attrs = $1; }
 545         ;
 546
 547 funcdef:
 548           m_attributes type callconv pident
 549           '(' m_args ')'                        { set_type($4, $2, NULL);
 550                                                   $4->attrs = $1;
 551                                                   $$ = make_func($4, $6);
 552                                                   if (is_attr($4->attrs, ATTR_IN)) {
 553                                                     yyerror("inapplicable attribute [in] for function '%s'",$$->def->name);
 554                                                   }
 555                                                 }
 556         ;
 557
 558 m_ident:                                        { $$ = NULL; }
 559         | ident
 560         ;
 561
 562 t_ident:                                        { $$ = NULL; }
 563         | aIDENTIFIER                           { $$ = make_var($1); }
 564         | aKNOWNTYPE                            { $$ = make_var($1); }
 565         ;
 566
 567 ident:    aIDENTIFIER                           { $$ = make_var($1); }
 568 /* some "reserved words" used in attributes are also used as field names in some MS IDL files */
 569         | aKNOWNTYPE                            { $$ = make_var($<str>1); }
 570         | tASYNC                                { $$ = make_var($<str>1); }
 571         | tID                                   { $$ = make_var($<str>1); }
 572         | tLCID                                 { $$ = make_var($<str>1); }
 573         | tOBJECT                               { $$ = make_var($<str>1); }
 574         | tRANGE                                { $$ = make_var($<str>1); }
 575         | tRETVAL                               { $$ = make_var($<str>1); }
 576         | tUUID                                 { $$ = make_var($<str>1); }
 577         | tVERSION                              { $$ = make_var($<str>1); }
 578         ;
 579
 580 base_type: tBYTE                                { $$ = make_type(RPC_FC_BYTE, NULL); }
 581         | tWCHAR                                { $$ = make_type(RPC_FC_WCHAR, NULL); }
 582         | int_std
 583         | tSIGNED int_std                       { $$ = $2; $$->sign = 1; }
 584         | tUNSIGNED int_std                     { $$ = $2; $$->sign = -1;
 585                                                   switch ($$->type) {
 586                                                   case RPC_FC_CHAR:  break;
 587                                                   case RPC_FC_SMALL: $$->type = RPC_FC_USMALL; break;
 588                                                   case RPC_FC_SHORT: $$->type = RPC_FC_USHORT; break;
 589                                                   case RPC_FC_LONG:  $$->type = RPC_FC_ULONG;  break;
 590                                                   case RPC_FC_HYPER:
 591                                                     if (!$$->ref) { $$->ref = &std_uhyper; $$->sign = 0; }
 592                                                     break;
 593                                                   default: break;
 594                                                   }
 595                                                 }
 596         | tUNSIGNED                             { $$ = make_type(RPC_FC_ULONG, &std_int); $$->sign = -1; }
 597         | tFLOAT                                { $$ = make_type(RPC_FC_FLOAT, NULL); }
 598         | tSINGLE                               { $$ = make_type(RPC_FC_FLOAT, NULL); }
 599         | tDOUBLE                               { $$ = make_type(RPC_FC_DOUBLE, NULL); }
 600         | tBOOLEAN                              { $$ = make_type(RPC_FC_BYTE, &std_bool); /* ? */ }
 601         | tERRORSTATUST                         { $$ = make_type(RPC_FC_ERROR_STATUS_T, NULL); }
 602         | tHANDLET                              { $$ = make_type(RPC_FC_BIND_PRIMITIVE, NULL); /* ? */ }
 603         ;
 604
 605 m_int:
 606         | tINT
 607         ;
 608
 609 int_std:  tINT                                  { $$ = make_type(RPC_FC_LONG, &std_int); } /* win32 only */
 610         | tSHORT m_int                          { $$ = make_type(RPC_FC_SHORT, NULL); }
 611         | tSMALL                                { $$ = make_type(RPC_FC_SMALL, NULL); }
 612         | tLONG m_int                           { $$ = make_type(RPC_FC_LONG, NULL); }
 613         | tHYPER m_int                          { $$ = make_type(RPC_FC_HYPER, NULL); }
 614         | tINT64                                { $$ = make_type(RPC_FC_HYPER, &std_int64); }
 615         | tCHAR                                 { $$ = make_type(RPC_FC_CHAR, NULL); }
 616         ;
 617
 618 coclass:  tCOCLASS aIDENTIFIER                  { $$ = make_class($2); }
 619         | tCOCLASS aKNOWNTYPE                   { $$ = make_class($2); }
 620         ;
 621
 622 coclasshdr: attributes coclass                  { $$ = $2;
 623                                                   $$->attrs = $1;
 624                                                   if (!parse_only && do_header)
 625                                                     write_coclass($$);
 626                                                 }
 627         ;
 628
 629 coclassdef: coclasshdr '{' coclass_ints '}'     { $$ = $1;
 630                                                   $$->ifaces = $3;
 631                                                 }
 632         ;
 633
 634 coclass_ints:                                   { $$ = NULL; }
 635         | coclass_ints coclass_int              { LINK($2, $1); $$ = $2; }
 636         ;
 637
 638 coclass_int:
 639           m_attributes interfacedec             { $$ = make_ifref($2); $$->attrs = $1; }
 640         ;
 641
 642 dispinterface: tDISPINTERFACE aIDENTIFIER       { $$ = get_type(0, $2, 0); }
 643         |      tDISPINTERFACE aKNOWNTYPE        { $$ = get_type(0, $2, 0); }
 644         ;
 645
 646 dispinterfacehdr: attributes dispinterface      { attr_t *attrs;
 647                                                   $$ = $2;
 648                                                   if ($$->defined) yyerror("multiple definition error");
 649                                                   attrs = make_attr(ATTR_DISPINTERFACE);
 650                                                   LINK(attrs, $1);
 651                                                   $$->attrs = attrs;
 652                                                   $$->ref = find_type("IDispatch", 0);
 653                                                   if (!$$->ref) yyerror("IDispatch is undefined");
 654                                                   $$->defined = TRUE;
 655                                                   if (!parse_only && do_header) write_forward($$);
 656                                                 }
 657         ;
 658
 659 dispint_props: tPROPERTIES ':'                  { $$ = NULL; }
 660         | dispint_props s_field ';'             { LINK($2, $1); $$ = $2; }
 661         ;
 662
 663 dispint_meths: tMETHODS ':'                     { $$ = NULL; }
 664         | dispint_meths funcdef ';'             { LINK($2, $1); $$ = $2; }
 665         ;
 666
 667 dispinterfacedef: dispinterfacehdr '{'
 668           dispint_props
 669           dispint_meths
 670           '}'                                   { $$ = $1;
 671                                                   $$->fields = $3;
 672                                                   $$->funcs = $4;
 673                                                   if (!parse_only && do_header) write_dispinterface($$);
 674                                                 }
 675 /* FIXME: not sure how to handle this yet
 676         | dispinterfacehdr '{' interface '}'    { $$ = $1;
 677                                                   if (!parse_only && do_header) write_interface($$);
 678                                                 }
 679 */
 680         ;
 681
 682 inherit:                                        { $$ = NULL; }
 683         | ':' aKNOWNTYPE                        { $$ = find_type2($2, 0); }
 684         ;
 685
 686 interface: tINTERFACE aIDENTIFIER               { $$ = get_type(RPC_FC_IP, $2, 0); }
 687         |  tINTERFACE aKNOWNTYPE                { $$ = get_type(RPC_FC_IP, $2, 0); }
 688         ;
 689
 690 interfacehdr: attributes interface              { $$ = $2;
 691                                                   if ($$->defined) yyerror("multiple definition error");
 692                                                   $$->attrs = $1;
 693                                                   $$->defined = TRUE;
 694                                                   if (!parse_only && do_header) write_forward($$);
 695                                                 }
 696         ;
 697
 698 interfacedef: interfacehdr inherit
 699           '{' int_statements '}'                { $$ = $1;
 700                                                   $$->ref = $2;
 701                                                   $$->funcs = $4;
 702                                                   if (!parse_only && do_header) write_interface($$);
 703                                                 }
 704 /* MIDL is able to import the definition of a base class from inside the
 705  * definition of a derived class, I'll try to support it with this rule */
 706         | interfacehdr ':' aIDENTIFIER
 707           '{' import int_statements '}'         { $$ = $1;
 708                                                   $$->ref = find_type2($3, 0);
 709                                                   if (!$$->ref) yyerror("base class '%s' not found in import", $3);
 710                                                   $$->funcs = $6;
 711                                                   if (!parse_only && do_header) write_interface($$);
 712                                                 }
 713         | dispinterfacedef                      { $$ = $1; }
 714         ;
 715
 716 interfacedec:
 717           interface ';'                         { $$ = $1; if (!parse_only && do_header) write_forward($$); }
 718         | dispinterface ';'                     { $$ = $1; if (!parse_only && do_header) write_forward($$); }
 719         ;
 720
 721 module:   tMODULE aIDENTIFIER                   { $$ = make_type(0, NULL); $$->name = $2; }
 722         | tMODULE aKNOWNTYPE                    { $$ = make_type(0, NULL); $$->name = $2; }
 723         ;
 724
 725 modulehdr: attributes module                    { $$ = $2;
 726                                                   $$->attrs = $1;
 727                                                 }
 728         ;
 729
 730 moduledef: modulehdr '{' int_statements '}'     { $$ = $1;
 731                                                   $$->funcs = $3;
 732                                                   /* FIXME: if (!parse_only && do_header) write_module($$); */
 733                                                 }
 734         ;
 735
 736 p_ident:  '*' pident %prec PPTR                 { $$ = $2; $$->ptr_level++; }
 737         | tCONST p_ident                        { $$ = $2; /* FIXME */ }
 738         ;
 739
 740 pident:   ident
 741         | p_ident
 742         | '(' pident ')'                        { $$ = $2; }
 743         ;
 744
 745 pident_list:
 746           pident
 747         | pident_list ',' pident                { LINK($3, $1); $$ = $3; }
 748         ;
 749
 750 pointer_type:
 751           tREF                                  { $$ = RPC_FC_RP; }
 752         | tUNIQUE                               { $$ = RPC_FC_UP; }
 753         | tPTR                                  { $$ = RPC_FC_FP; }
 754         ;
 755
 756 structdef: tSTRUCT t_ident '{' fields '}'       { $$ = get_typev(RPC_FC_STRUCT, $2, tsSTRUCT);
 757                                                   /* overwrite RPC_FC_STRUCT with a more exact type */
 758                                                   $$->type = get_struct_type( $4 );
 759                                                   $$->fields = $4;
 760                                                   $$->defined = TRUE;
 761                                                   if(in_typelib)
 762                                                       add_struct($$);
 763                                                 }
 764         ;
 765
 766 type:     tVOID                                 { $$ = make_tref(NULL, make_type(0, NULL)); }
 767         | aKNOWNTYPE                            { $$ = make_tref($1, find_type($1, 0)); }
 768         | base_type                             { $$ = make_tref(NULL, $1); }
 769         | tCONST type                           { $$ = uniq_tref($2); $$->ref->is_const = TRUE; }
 770         | enumdef                               { $$ = make_tref(NULL, $1); }
 771         | tENUM aIDENTIFIER                     { $$ = make_tref(NULL, find_type2($2, tsENUM)); }
 772         | structdef                             { $$ = make_tref(NULL, $1); }
 773         | tSTRUCT aIDENTIFIER                   { $$ = make_tref(NULL, get_type(RPC_FC_STRUCT, $2, tsSTRUCT)); }
 774         | uniondef                              { $$ = make_tref(NULL, $1); }
 775         | tUNION aIDENTIFIER                    { $$ = make_tref(NULL, find_type2($2, tsUNION)); }
 776         ;
 777
 778 typedef: tTYPEDEF m_attributes type pident_list { typeref_t *tref = uniq_tref($3);
 779                                                   $4->tname = tref->name;
 780                                                   tref->name = NULL;
 781                                                   $$ = type_ref(tref);
 782                                                   $$->attrs = $2;
 783                                                   if (!parse_only && do_header)
 784                                                     write_typedef($$, $4);
 785                                                   if (in_typelib && $$->attrs)
 786                                                     add_typedef($$, $4);
 787                                                   reg_types($$, $4, 0);
 788                                                 }
 789         ;
 790
 791 uniondef: tUNION t_ident '{' fields '}'         { $$ = get_typev(RPC_FC_NON_ENCAPSULATED_UNION, $2, tsUNION);
 792                                                   $$->fields = $4;
 793                                                   $$->defined = TRUE;
 794                                                 }
 795         | tUNION t_ident
 796           tSWITCH '(' s_field ')'
 797           m_ident '{' cases '}'                 { var_t *u = $7;
 798                                                   $$ = get_typev(RPC_FC_ENCAPSULATED_UNION, $2, tsUNION);
 799                                                   if (!u) u = make_var("tagged_union");
 800                                                   u->type = make_type(RPC_FC_NON_ENCAPSULATED_UNION, NULL);
 801                                                   u->type->fields = $9;
 802                                                   u->type->defined = TRUE;
 803                                                   LINK(u, $5); $$->fields = u;
 804                                                   $$->defined = TRUE;
 805                                                 }
 806         ;
 807
 808 version:
 809           aNUM                                  { $$ = MAKELONG($1, 0); }
 810         | aNUM '.' aNUM                         { $$ = MAKELONG($1, $3); }
 811         ;
 812
 813 %%
 814
 815 static attr_t *make_attr(enum attr_type type)
 816 {
 817   attr_t *a = xmalloc(sizeof(attr_t));
 818   a->type = type;
 819   a->u.ival = 0;
 820   INIT_LINK(a);
 821   return a;
 822 }
 823
 824 static attr_t *make_attrv(enum attr_type type, unsigned long val)
 825 {
 826   attr_t *a = xmalloc(sizeof(attr_t));
 827   a->type = type;
 828   a->u.ival = val;
 829   INIT_LINK(a);
 830   return a;
 831 }
 832
 833 static attr_t *make_attrp(enum attr_type type, void *val)
 834 {
 835   attr_t *a = xmalloc(sizeof(attr_t));
 836   a->type = type;
 837   a->u.pval = val;
 838   INIT_LINK(a);
 839   return a;
 840 }
 841
 842 static expr_t *make_expr(enum expr_type type)
 843 {
 844   expr_t *e = xmalloc(sizeof(expr_t));
 845   e->type = type;
 846   e->ref = NULL;
 847   e->u.lval = 0;
 848   e->is_const = FALSE;
 849   INIT_LINK(e);
 850   return e;
 851 }
 852
 853 static expr_t *make_exprl(enum expr_type type, long val)
 854 {
 855   expr_t *e = xmalloc(sizeof(expr_t));
 856   e->type = type;
 857   e->ref = NULL;
 858   e->u.lval = val;
 859   e->is_const = FALSE;
 860   INIT_LINK(e);
 861   /* check for numeric constant */
 862   if (type == EXPR_NUM || type == EXPR_HEXNUM) {
 863     e->is_const = TRUE;
 864     e->cval = val;
 865   }
 866   return e;
 867 }
 868
 869 static expr_t *make_exprs(enum expr_type type, char *val)
 870 {
 871   expr_t *e;
 872   e = xmalloc(sizeof(expr_t));
 873   e->type = type;
 874   e->ref = NULL;
 875   e->u.sval = val;
 876   e->is_const = FALSE;
 877   INIT_LINK(e);
 878   /* check for predefined constants */
 879   if (type == EXPR_IDENTIFIER) {
 880     var_t *c = find_const(val, 0);
 881     if (c) {
 882       e->u.sval = c->name;
 883       free(val);
 884       e->is_const = TRUE;
 885       e->cval = c->eval->cval;
 886     }
 887   }
 888   return e;
 889 }
 890
 891 static expr_t *make_exprt(enum expr_type type, typeref_t *tref, expr_t *expr)
 892 {
 893   expr_t *e;
 894   e = xmalloc(sizeof(expr_t));
 895   e->type = type;
 896   e->ref = expr;
 897   e->u.tref = tref;
 898   e->is_const = FALSE;
 899   INIT_LINK(e);
 900   /* check for cast of constant expression */
 901   if (type == EXPR_SIZEOF) {
 902     switch (tref->ref->type) {
 903       case RPC_FC_BYTE:
 904       case RPC_FC_CHAR:
 905       case RPC_FC_SMALL:
 906       case RPC_FC_USMALL:
 907         e->is_const = TRUE;
 908         e->cval = 1;
 909         break;
 910       case RPC_FC_WCHAR:
 911       case RPC_FC_USHORT:
 912       case RPC_FC_SHORT:
 913         e->is_const = TRUE;
 914         e->cval = 2;
 915         break;
 916       case RPC_FC_LONG:
 917       case RPC_FC_ULONG:
 918       case RPC_FC_FLOAT:
 919       case RPC_FC_ERROR_STATUS_T:
 920         e->is_const = TRUE;
 921         e->cval = 4;
 922         break;
 923       case RPC_FC_HYPER:
 924       case RPC_FC_DOUBLE:
 925         e->is_const = TRUE;
 926         e->cval = 8;
 927         break;
 928     }
 929   }
 930   if (type == EXPR_CAST && expr->is_const) {
 931     e->is_const = TRUE;
 932     e->cval = expr->cval;
 933   }
 934   return e;
 935 }
 936
 937 static expr_t *make_expr1(enum expr_type type, expr_t *expr)
 938 {
 939   expr_t *e;
 940   e = xmalloc(sizeof(expr_t));
 941   e->type = type;
 942   e->ref = expr;
 943   e->u.lval = 0;
 944   e->is_const = FALSE;
 945   INIT_LINK(e);
 946   /* check for compile-time optimization */
 947   if (expr->is_const) {
 948     e->is_const = TRUE;
 949     switch (type) {
 950     case EXPR_NEG:
 951       e->cval = -expr->cval;
 952       break;
 953     case EXPR_NOT:
 954       e->cval = ~expr->cval;
 955       break;
 956     default:
 957       e->is_const = FALSE;
 958       break;
 959     }
 960   }
 961   return e;
 962 }
 963
 964 static expr_t *make_expr2(enum expr_type type, expr_t *expr1, expr_t *expr2)
 965 {
 966   expr_t *e;
 967   e = xmalloc(sizeof(expr_t));
 968   e->type = type;
 969   e->ref = expr1;
 970   e->u.ext = expr2;
 971   e->is_const = FALSE;
 972   INIT_LINK(e);
 973   /* check for compile-time optimization */
 974   if (expr1->is_const && expr2->is_const) {
 975     e->is_const = TRUE;
 976     switch (type) {
 977     case EXPR_ADD:
 978       e->cval = expr1->cval + expr2->cval;
 979       break;
 980     case EXPR_SUB:
 981       e->cval = expr1->cval - expr2->cval;
 982       break;
 983     case EXPR_MUL:
 984       e->cval = expr1->cval * expr2->cval;
 985       break;
 986     case EXPR_DIV:
 987       e->cval = expr1->cval / expr2->cval;
 988       break;
 989     case EXPR_OR:
 990       e->cval = expr1->cval | expr2->cval;
 991       break;
 992     case EXPR_AND:
 993       e->cval = expr1->cval & expr2->cval;
 994       break;
 995     case EXPR_SHL:
 996       e->cval = expr1->cval << expr2->cval;
 997       break;
 998     case EXPR_SHR:
 999       e->cval = expr1->cval >> expr2->cval;
1000       break;
1001     default:
1002       e->is_const = FALSE;
1003       break;
1004     }
1005   }
1006   return e;
1007 }
1008
1009 static expr_t *make_expr3(enum expr_type type, expr_t *expr1, expr_t *expr2, expr_t *expr3)
1010 {
1011   expr_t *e;
1012   e = xmalloc(sizeof(expr_t));
1013   e->type = type;
1014   e->ref = expr1;
1015   e->u.ext = expr2;
1016   e->ext2 = expr3;
1017   e->is_const = FALSE;
1018   INIT_LINK(e);
1019   /* check for compile-time optimization */
1020   if (expr1->is_const && expr2->is_const && expr3->is_const) {
1021     e->is_const = TRUE;
1022     switch (type) {
1023     case EXPR_COND:
1024       e->cval = expr1->cval ? expr2->cval : expr3->cval;
1025       break;
1026     default:
1027       e->is_const = FALSE;
1028       break;
1029     }
1030   }
1031   return e;
1032 }
1033
1034 static type_t *make_type(unsigned char type, type_t *ref)
1035 {
1036   type_t *t = xmalloc(sizeof(type_t));
1037   t->name = NULL;
1038   t->type = type;
1039   t->ref = ref;
1040   t->attrs = NULL;
1041   t->funcs = NULL;
1042   t->fields = NULL;
1043   t->ignore = parse_only;
1044   t->is_const = FALSE;
1045   t->sign = 0;
1046   t->defined = FALSE;
1047   t->written = FALSE;
1048   t->typelib_idx = -1;
1049   INIT_LINK(t);
1050   return t;
1051 }
1052
1053 static typeref_t *make_tref(char *name, type_t *ref)
1054 {
1055   typeref_t *t = xmalloc(sizeof(typeref_t));
1056   t->name = name;
1057   t->ref = ref;
1058   t->uniq = ref ? 0 : 1;
1059   return t;
1060 }
1061
1062 static typeref_t *uniq_tref(typeref_t *ref)
1063 {
1064   typeref_t *t = ref;
1065   type_t *tp;
1066   if (t->uniq) return t;
1067   tp = make_type(0, t->ref);
1068   tp->name = t->name;
1069   t->name = NULL;
1070   t->ref = tp;
1071   t->uniq = 1;
1072   return t;
1073 }
1074
1075 static type_t *type_ref(typeref_t *ref)
1076 {
1077   type_t *t = ref->ref;
1078   if (ref->name) free(ref->name);
1079   free(ref);
1080   return t;
1081 }
1082
1083 static void set_type(var_t *v, typeref_t *ref, expr_t *arr)
1084 {
1085   v->type = ref->ref;
1086   v->tname = ref->name;
1087   ref->name = NULL;
1088   free(ref);
1089   v->array = arr;
1090 }
1091
1092 static ifref_t *make_ifref(type_t *iface)
1093 {
1094   ifref_t *l = xmalloc(sizeof(ifref_t));
1095   l->iface = iface;
1096   l->attrs = NULL;
1097   INIT_LINK(l);
1098   return l;
1099 }
1100
1101 static var_t *make_var(char *name)
1102 {
1103   var_t *v = xmalloc(sizeof(var_t));
1104   v->name = name;
1105   v->ptr_level = 0;
1106   v->type = NULL;
1107   v->tname = NULL;
1108   v->attrs = NULL;
1109   v->array = NULL;
1110   v->eval = NULL;
1111   INIT_LINK(v);
1112   return v;
1113 }
1114
1115 static func_t *make_func(var_t *def, var_t *args)
1116 {
1117   func_t *f = xmalloc(sizeof(func_t));
1118   f->def = def;
1119   f->args = args;
1120   f->ignore = parse_only;
1121   f->idx = -1;
1122   INIT_LINK(f);
1123   return f;
1124 }
1125
1126 static class_t *make_class(char *name)
1127 {
1128   class_t *c = xmalloc(sizeof(class_t));
1129   c->name = name;
1130   c->attrs = NULL;
1131   c->ifaces = NULL;
1132   INIT_LINK(c);
1133   return c;
1134 }
1135
1136 #define HASHMAX 64
1137
1138 static int hash_ident(const char *name)
1139 {
1140   const char *p = name;
1141   int sum = 0;
1142   /* a simple sum hash is probably good enough */
1143   while (*p) {
1144     sum += *p;
1145     p++;
1146   }
1147   return sum & (HASHMAX-1);
1148 }
1149
1150 /***** type repository *****/
1151
1152 struct rtype {
1153   const char *name;
1154   type_t *type;
1155   int t;
1156   struct rtype *next;
1157 };
1158
1159 struct rtype *type_hash[HASHMAX];
1160
1161 static type_t *reg_type(type_t *type, const char *name, int t)
1162 {
1163   struct rtype *nt;
1164   int hash;
1165   if (!name) {
1166     yyerror("registering named type without name");
1167     return type;
1168   }
1169   hash = hash_ident(name);
1170   nt = xmalloc(sizeof(struct rtype));
1171   nt->name = name;
1172   nt->type = type;
1173   nt->t = t;
1174   nt->next = type_hash[hash];
1175   type_hash[hash] = nt;
1176   return type;
1177 }
1178
1179 /* determine pointer type from attrs */
1180 static unsigned char get_pointer_type( type_t *type )
1181 {
1182   int t;
1183   if (is_attr( type->attrs, ATTR_STRING ))
1184   {
1185     type_t *t = type;
1186     while( t->type == 0 && t->ref )
1187       t = t->ref;
1188     switch( t->type )
1189     {
1190     case RPC_FC_CHAR:
1191       return RPC_FC_C_CSTRING;
1192     case RPC_FC_WCHAR:
1193       return RPC_FC_C_WSTRING;
1194     }
1195   }
1196   t = get_attrv( type->attrs, ATTR_POINTERTYPE );
1197   if (t) return t;
1198   return RPC_FC_FP;
1199 }
1200
1201 static type_t *reg_types(type_t *type, var_t *names, int t)
1202 {
1203   type_t *ptr = type;
1204   int ptrc = 0;
1205
1206   while (names) {
1207     var_t *next = NEXT_LINK(names);
1208     if (names->name) {
1209       type_t *cur = ptr;
1210       int cptr = names->ptr_level;
1211       if (cptr > ptrc) {
1212         while (cptr > ptrc) {
1213           int t = get_pointer_type( cur );
1214           cur = ptr = make_type(t, cur);
1215           ptrc++;
1216         }
1217       } else {
1218         while (cptr < ptrc) {
1219           cur = cur->ref;
1220           cptr++;
1221         }
1222       }
1223       reg_type(cur, names->name, t);
1224     }
1225     free(names);
1226     names = next;
1227   }
1228   return type;
1229 }
1230
1231 static type_t *find_type(const char *name, int t)
1232 {
1233   struct rtype *cur = type_hash[hash_ident(name)];
1234   while (cur && (cur->t != t || strcmp(cur->name, name)))
1235     cur = cur->next;
1236   if (!cur) {
1237     yyerror("type '%s' not found", name);
1238     return NULL;
1239   }
1240   return cur->type;
1241 }
1242
1243 static type_t *find_type2(char *name, int t)
1244 {
1245   type_t *tp = find_type(name, t);
1246   free(name);
1247   return tp;
1248 }
1249
1250 int is_type(const char *name)
1251 {
1252   struct rtype *cur = type_hash[hash_ident(name)];
1253   while (cur && (cur->t || strcmp(cur->name, name)))
1254     cur = cur->next;
1255   if (cur) return TRUE;
1256   return FALSE;
1257 }
1258
1259 static type_t *get_type(unsigned char type, char *name, int t)
1260 {
1261   struct rtype *cur = NULL;
1262   type_t *tp;
1263   if (name) {
1264     cur = type_hash[hash_ident(name)];
1265     while (cur && (cur->t != t || strcmp(cur->name, name)))
1266       cur = cur->next;
1267   }
1268   if (cur) {
1269     free(name);
1270     return cur->type;
1271   }
1272   tp = make_type(type, NULL);
1273   tp->name = name;
1274   if (!name) return tp;
1275   return reg_type(tp, name, t);
1276 }
1277
1278 static type_t *get_typev(unsigned char type, var_t *name, int t)
1279 {
1280   char *sname = NULL;
1281   if (name) {
1282     sname = name->name;
1283     free(name);
1284   }
1285   return get_type(type, sname, t);
1286 }
1287
1288 static int get_struct_type(var_t *field)
1289 {
1290   int has_pointer = 0;
1291   int has_conformance = 0;
1292   int has_variance = 0;
1293
1294   for (; field; field = NEXT_LINK(field))
1295   {
1296     type_t *t = field->type;
1297
1298     /* get the base type */
1299     while( (t->type == 0) && t->ref )
1300       t = t->ref;
1301
1302     if (field->ptr_level > 0)
1303     {
1304         has_pointer = 1;
1305         continue;
1306     }
1307
1308     if (is_string_type(field->attrs, 0, field->array))
1309     {
1310         has_conformance = 1;
1311         has_variance = 1;
1312         continue;
1313     }
1314
1315     if (is_array_type(field->attrs, 0, field->array))
1316     {
1317         if (field->array && !field->array->is_const)
1318         {
1319             has_conformance = 1;
1320             if (PREV_LINK(field))
1321                 yyerror("field '%s' deriving from a conformant array must be the last field in the structure",
1322                         field->name);
1323         }
1324         if (is_attr(field->attrs, ATTR_LENGTHIS))
1325             has_variance = 1;
1326     }
1327
1328     switch (t->type)
1329     {
1330     /*
1331      * RPC_FC_BYTE, RPC_FC_STRUCT, etc
1332      *  Simple types don't effect the type of struct.
1333      *  A struct containing a simple struct is still a simple struct.
1334      *  So long as we can block copy the data, we return RPC_FC_STRUCT.
1335      */
1336     case 0: /* void pointer */
1337     case RPC_FC_BYTE:
1338     case RPC_FC_CHAR:
1339     case RPC_FC_SMALL:
1340     case RPC_FC_USMALL:
1341     case RPC_FC_WCHAR:
1342     case RPC_FC_SHORT:
1343     case RPC_FC_USHORT:
1344     case RPC_FC_LONG:
1345     case RPC_FC_ULONG:
1346     case RPC_FC_INT3264:
1347     case RPC_FC_UINT3264:
1348     case RPC_FC_HYPER:
1349     case RPC_FC_FLOAT:
1350     case RPC_FC_DOUBLE:
1351     case RPC_FC_STRUCT:
1352     case RPC_FC_ENUM16:
1353     case RPC_FC_ENUM32:
1354       break;
1355
1356     case RPC_FC_UP:
1357     case RPC_FC_FP:
1358       has_pointer = 1;
1359       break;
1360     case RPC_FC_CARRAY:
1361       has_conformance = 1;
1362       if (PREV_LINK(field))
1363           yyerror("field '%s' deriving from a conformant array must be the last field in the structure",
1364                   field->name);
1365       break;
1366     case RPC_FC_C_CSTRING:
1367     case RPC_FC_C_WSTRING:
1368       has_conformance = 1;
1369       has_variance = 1;
1370       break;
1371
1372     /*
1373      * Propagate member attributes
1374      *  a struct should be at least as complex as its member
1375      */
1376     case RPC_FC_CVSTRUCT:
1377       has_conformance = 1;
1378       has_variance = 1;
1379       has_pointer = 1;
1380       break;
1381
1382     case RPC_FC_CPSTRUCT:
1383       has_conformance = 1;
1384       if (PREV_LINK(field))
1385           yyerror("field '%s' deriving from a conformant array must be the last field in the structure",
1386                   field->name);
1387       has_pointer = 1;
1388       break;
1389
1390     case RPC_FC_CSTRUCT:
1391       has_conformance = 1;
1392       if (PREV_LINK(field))
1393           yyerror("field '%s' deriving from a conformant array must be the last field in the structure",
1394                   field->name);
1395       break;
1396
1397     case RPC_FC_PSTRUCT:
1398       has_pointer = 1;
1399       break;
1400
1401     default:
1402       fprintf(stderr,"Unknown struct member %s with type (0x%02x)\n",
1403               field->name, t->type);
1404       /* fallthru - treat it as complex */
1405
1406     /* as soon as we see one of these these members, it's bogus... */
1407     case RPC_FC_IP:
1408     case RPC_FC_ENCAPSULATED_UNION:
1409     case RPC_FC_NON_ENCAPSULATED_UNION:
1410     case RPC_FC_TRANSMIT_AS:
1411     case RPC_FC_REPRESENT_AS:
1412     case RPC_FC_PAD:
1413     case RPC_FC_EMBEDDED_COMPLEX:
1414     case RPC_FC_BOGUS_STRUCT:
1415       return RPC_FC_BOGUS_STRUCT;
1416     }
1417   }
1418
1419   if( has_variance )
1420     return RPC_FC_CVSTRUCT;
1421   if( has_conformance && has_pointer )
1422     return RPC_FC_CPSTRUCT;
1423   if( has_conformance )
1424     return RPC_FC_CSTRUCT;
1425   if( has_pointer )
1426     return RPC_FC_PSTRUCT;
1427   return RPC_FC_STRUCT;
1428 }
1429
1430 /***** constant repository *****/
1431
1432 struct rconst {
1433   char *name;
1434   var_t *var;
1435   struct rconst *next;
1436 };
1437
1438 struct rconst *const_hash[HASHMAX];
1439
1440 static var_t *reg_const(var_t *var)
1441 {
1442   struct rconst *nc;
1443   int hash;
1444   if (!var->name) {
1445     yyerror("registering constant without name");
1446     return var;
1447   }
1448   hash = hash_ident(var->name);
1449   nc = xmalloc(sizeof(struct rconst));
1450   nc->name = var->name;
1451   nc->var = var;
1452   nc->next = const_hash[hash];
1453   const_hash[hash] = nc;
1454   return var;
1455 }
1456
1457 static var_t *find_const(char *name, int f)
1458 {
1459   struct rconst *cur = const_hash[hash_ident(name)];
1460   while (cur && strcmp(cur->name, name))
1461     cur = cur->next;
1462   if (!cur) {
1463     if (f) yyerror("constant '%s' not found", name);
1464     return NULL;
1465   }
1466   return cur->var;
1467 }