git.oblomov.eu Git - wine/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 AC_PREREQ(2.53)
   8 AC_INIT([Wine],WINE_VERSION,[wine-devel@winehq.org])
   9 AC_CONFIG_SRCDIR(server/atom.c)
  10 AC_CONFIG_HEADERS(include/config.h)
  11 AC_CONFIG_AUX_DIR(tools)
  12
  13 dnl **** Command-line arguments ****
  14
  15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
  16 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
  17 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
  18 AC_ARG_ENABLE(win64, AC_HELP_STRING([--enable-win64], [build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
  19
  20 AC_ARG_WITH(opengl,    AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
  21 AC_ARG_WITH(curses,    AC_HELP_STRING([--without-curses],[do not use curses]))
  22 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
  23
  24 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
  25 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
  26 if test "x$enable_win16" = "xno"
  27 then
  28   WIN16_FILES=""
  29   WIN16_INSTALL=""
  30 fi
  31 if test "x$enable_debug" = "xno"
  32 then
  33     AC_DEFINE(NO_DEBUG_MSGS,1,[Define to disable all debug messages.])
  34 fi
  35 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
  36 then
  37     AC_DEFINE(NO_TRACE_MSGS,1,[Define to disable trace messages.])
  38 fi
  39
  40 dnl **** Check for some programs ****
  41
  42 AC_CANONICAL_HOST
  43 case $host in
  44   x86_64*linux*)
  45     if test "x$enable_win64" != "xyes"
  46     then
  47       test -n "$CC" || CC="gcc -m32"
  48       test -n "$LD" || LD="ld -m elf_i386"
  49       test -n "$AS" || AS="as --32"
  50     fi
  51     ;;
  52 esac
  53
  54 AC_PROG_MAKE_SET
  55 AC_PROG_CC
  56 AC_PROG_CXX
  57 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
  58 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
  59
  60 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
  61   [if test -z "$with_wine_tools"; then
  62      if test "$cross_compiling" = "yes"; then
  63        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
  64      else
  65        wine_cv_toolsdir="\$(TOPOBJDIR)"
  66      fi
  67    elif test -d "$with_wine_tools/tools/winebuild"; then
  68      case $with_wine_tools in
  69        /*) wine_cv_toolsdir="$with_wine_tools" ;;
  70        *)  wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
  71      esac
  72    else
  73      AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
  74    fi])
  75 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
  76
  77 AC_PATH_XTRA
  78 AC_PROG_LEX
  79
  80 dnl **** Just additional warning checks, since AC_PROG just sets 'lex' even
  81 dnl **** without one present.
  82 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
  83 if test "$XLEX" = "none"
  84 then
  85   AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
  86 fi
  87
  88 dnl Check for bison
  89 AC_CHECK_PROGS(BISON,bison,none)
  90 if test "$BISON" = "none"
  91 then
  92   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
  93 fi
  94
  95 AC_CHECK_TOOLS(AS,[gas as],as)
  96 AC_CHECK_TOOL(LD,ld,ld)
  97 AC_CHECK_TOOL(AR,ar,ar)
  98 AC_PROG_RANLIB
  99 AC_CHECK_TOOL(STRIP,strip,strip)
 100 AC_CHECK_TOOL(WINDRES,windres,false)
 101 AC_PROG_LN_S
 102 WINE_PROG_LN
 103 AC_PROG_EGREP
 104 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
 105 AC_PROG_INSTALL
 106 dnl Prepend src dir to install path dir if it's a relative path
 107 case "$INSTALL" in
 108   [[\\/$]]* | ?:[[\\/]]* ) ;;
 109   *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
 110 esac
 111
 112 dnl Check for lint
 113 AC_CHECK_PROGS(LINT, lclint lint)
 114 if test "$LINT" = "lint"
 115 then
 116   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 117   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 118 fi
 119 AC_SUBST(LINT)
 120 AC_SUBST(LINTFLAGS)
 121
 122 dnl Check for various programs
 123 AC_CHECK_PROGS(DB2HTML, docbook2html db2html, false)
 124 AC_CHECK_PROGS(DB2PDF, docbook2pdf db2pdf, false)
 125 AC_CHECK_PROGS(DB2PS, docbook2ps db2ps, false)
 126 AC_CHECK_PROGS(DB2TXT, docbook2txt db2txt, false)
 127 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
 128
 129 dnl **** Check for some libraries ****
 130
 131 dnl Check for -li386 for NetBSD and OpenBSD
 132 AC_CHECK_LIB(i386,i386_set_ldt)
 133 dnl Check for -lossaudio for NetBSD
 134 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 135 dnl Check for -lw for Solaris
 136 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
 137 dnl Check for -lnsl for Solaris
 138 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
 139 dnl Check for -lsocket for Solaris
 140 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
 141 dnl Check for -lresolv for Solaris
 142 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
 143 dnl Check for -lxpg4 for FreeBSD
 144 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
 145 dnl Check for -lpoll for Mac OS X/Darwin
 146 AC_CHECK_LIB(poll,poll)
 147 dnl Check for -lresolv for Mac OS X/Darwin
 148 AC_CHECK_LIB(resolv,res_9_init)
 149 dnl Check for -lpthread
 150 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
 151
 152 AC_SUBST(XLIB)
 153 AC_SUBST(XFILES)
 154 XFILES=""
 155 AC_SUBST(OPENGLFILES)
 156 OPENGLFILES=""
 157 AC_SUBST(GLU32FILES)
 158 GLU32FILES=""
 159 AC_SUBST(OPENGL_LIBS)
 160 OPENGL_LIBS=""
 161 if test "$have_x" = "yes"
 162 then
 163     XLIB="-lXext -lX11"
 164     ac_save_CPPFLAGS="$CPPFLAGS"
 165     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 166
 167     dnl *** All of the following tests require X11/Xlib.h
 168     AC_CHECK_HEADERS(X11/Xlib.h,
 169       [
 170         AC_CHECK_HEADERS([X11/XKBlib.h \
 171                           X11/Xutil.h \
 172                           X11/extensions/shape.h \
 173                           X11/extensions/XInput.h \
 174                           X11/extensions/XShm.h \
 175                           X11/extensions/Xrandr.h \
 176                           X11/extensions/Xrender.h \
 177                           X11/extensions/Xvlib.h \
 178                           X11/extensions/xf86dga.h \
 179                           X11/extensions/xf86vmode.h],,,
 180                          [#include <X11/Xlib.h>
 181                           #ifdef HAVE_X11_XUTIL_H
 182                           # include <X11/Xutil.h>
 183                           #endif])
 184
 185         dnl *** Check for X keyboard extension
 186         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 187         then
 188               AC_CHECK_LIB(X11, XkbQueryExtension,
 189               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 190               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 191         fi
 192
 193         dnl *** Check for X Shm extension
 194         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 195         then
 196               AC_CHECK_LIB(Xext, XShmQueryExtension,
 197               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 198               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 199         fi
 200
 201         dnl *** Check for X shape extension
 202         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 203         then
 204               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 205               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 206               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 207         fi
 208
 209         dnl *** Check for XFree86 DGA / DGA 2.0 extension
 210         if test "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
 211         then
 212               AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
 213                 [ dnl *** If found...
 214                   AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
 215                             [Define if you have the Xxf86dga library version 2])
 216                   X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 217                ],
 218                 [ dnl *** If not found, look for XF86DGAQueryExtension()
 219                   dnl *** instead (DGA 2.0 not found)...
 220                   AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
 221                     [ AC_DEFINE(HAVE_LIBXXF86DGA, 1,
 222                                 [Define if you have the Xxf86dga library version 1])
 223                       X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 224                     ],,
 225                     $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 226                   )
 227                 ],
 228                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 229         fi
 230
 231         dnl *** Check for XFree86 VMODE extension
 232         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 233         then
 234                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 235                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 236                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 237                   ],,
 238                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 239         fi
 240
 241         dnl *** Check for X RandR extension
 242         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
 243         then
 244                 AC_TRY_COMPILE([#include <X11/Xlib.h>
 245 #include <X11/extensions/Xrandr.h>],[static typeof(XRRSetScreenConfigAndRate) * func;],
 246                   [AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])])
 247         fi
 248
 249         dnl *** Check for XVideo extension supporting XvImages
 250         if test "$ac_cv_header_X11_extensions_Xvlib_h" = "yes"
 251         then
 252                 AC_CHECK_LIB(Xv, XvShmCreateImage,
 253                   [ AC_DEFINE(HAVE_XVIDEO, 1, [Define if the X libraries support XVideo])
 254                      X_PRE_LIBS="$X_PRE_LIBS -lXv"
 255                   ],,
 256                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 257         fi
 258       ]
 259     ) dnl *** End of X11/Xlib.h check
 260
 261     dnl Check for the presence of OpenGL
 262     if test "x$with_opengl" != "xno"
 263     then
 264         if test -f /usr/X11R6/lib/libGL.a -a ! -f /usr/X11R6/lib/libGL.so
 265         then
 266             AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
 267 This prevents linking to OpenGL. Delete the file and restart configure.])
 268         fi
 269
 270         AC_CHECK_HEADERS(GL/gl.h GL/glx.h)
 271         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 272         then
 273             AC_CHECK_HEADERS(GL/glext.h,,,[#include <GL/glx.h>])
 274             dnl Check for some problems due to old Mesa versions
 275             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
 276               AC_TRY_COMPILE(
 277                 [#include <GL/gl.h>],
 278                 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 279                 [wine_cv_opengl_version_OK="yes"],
 280                 [wine_cv_opengl_version_OK="no"]
 281               )
 282             )
 283
 284             if test "$wine_cv_opengl_version_OK" = "yes"
 285             then
 286                 dnl Check for the presence of the library
 287                 AC_CHECK_LIB(GL,glXCreateContext,
 288                              OPENGL_LIBS="-lGL"
 289                              ,,
 290                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 291
 292                 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
 293                 then
 294                         OPENGLFILES='$(OPENGLFILES)'
 295                         AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
 296
 297                         AC_CHECK_LIB(GL,glXGetProcAddressARB,
 298                                      AC_DEFINE(HAVE_GLX_GETPROCADDRESS, 1,
 299                                                [Define if the OpenGL library supports the glXGetProcAddressARB call]),,
 300                                      $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 301
 302                         if test "$ac_cv_lib_GL_glXGetProcAddressARB" = "yes"
 303                         then
 304                                AC_CACHE_CHECK([for OpenGL extension functions prototypes], wine_cv_extension_prototypes,
 305                                   [AC_TRY_COMPILE([#include <GL/gl.h>
 306                                                   #ifdef HAVE_GL_GLEXT_H
 307                                                   # include <GL/glext.h>
 308                                                   #endif
 309                                                   ],
 310                                                  [PFNGLCOLORTABLEEXTPROC test_proc;],
 311                                                  [wine_cv_extension_prototypes="yes"],
 312                                                  [wine_cv_extension_prototypes="no"]
 313                                   )]
 314                                 )
 315                                 if test "$wine_cv_extension_prototypes" = "yes"
 316                                 then
 317                                     AC_DEFINE(HAVE_GLEXT_PROTOTYPES, 1,
 318                                               [Define if the OpenGL headers define extension typedefs])
 319                                 fi
 320                         fi
 321
 322                 fi
 323                 dnl Check for GLU32 library.
 324                 AC_CHECK_LIB(GLU,gluLookAt,
 325                              [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
 326                              GLU32FILES='$(GLU32FILES)']
 327                              ,,
 328                              $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
 329                 )
 330              fi
 331
 332              dnl Check for glut32 library.
 333              AC_CHECK_LIB(glut,glutMainLoop,
 334                        [AC_SUBST(GLUT_LIBS,"-lglut -lXmu -lXi")
 335                         AC_SUBST(GLUT32FILES,'$(GLUT32FILES)')],,
 336                         $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXmu -lXi -lX11 $X_EXTRA_LIBS)
 337          fi
 338     fi
 339
 340     dnl **** Check for NAS ****
 341     AC_SUBST(NASLIBS,"")
 342     AC_CHECK_HEADERS(audio/audiolib.h,
 343          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
 344           AC_CHECK_LIB(audio,AuCreateFlow,
 345                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
 346                         NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
 347                        [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 348
 349     CPPFLAGS="$ac_save_CPPFLAGS"
 350     XFILES='$(XFILES)'
 351 else
 352     XLIB=""
 353     X_CFLAGS=""
 354     X_LIBS=""
 355 fi
 356
 357 dnl **** Check which curses lib to use ***
 358 CURSESLIBS=""
 359 if test "x$with_curses" != "xno"
 360 then
 361     AC_CHECK_HEADERS(ncurses.h,
 362         [AC_CHECK_LIB(ncurses,waddch,
 363             [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
 364              CURSESLIBS="-lncurses"],
 365              [AC_CHECK_HEADERS(curses.h,
 366                  [AC_CHECK_LIB(curses,waddch,
 367                      [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
 368                       CURSESLIBS="-lcurses"])])])])
 369     saved_libs="$LIBS"
 370     LIBS="$CURSESLIBS $LIBS"
 371     AC_CHECK_FUNCS(getbkgd resizeterm)
 372     LIBS="$saved_libs"
 373 fi
 374 AC_SUBST(CURSESLIBS)
 375
 376 dnl **** Check for SANE ****
 377 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
 378 if test "$sane_devel" = "no"
 379 then
 380     SANELIBS=""
 381     SANEINCL=""
 382 else
 383     SANELIBS="`$sane_devel --libs`"
 384     SANEINCL="`$sane_devel --cflags`"
 385     ac_save_CPPFLAGS="$CPPFLAGS"
 386     ac_save_LIBS="$LIBS"
 387     CPPFLAGS="$CPPFLAGS $SANEINCL"
 388     LIBS="$LIBS $SANELIBS"
 389     AC_CHECK_HEADER(sane/sane.h,
 390                     [AC_CHECK_LIB(sane,sane_open,
 391                                   [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
 392                                   [SANELIBS=""
 393                                   SANEINCL=""])],
 394                     [SANELIBS=""
 395                     SANEINCL=""])
 396     LIBS="$ac_save_LIBS"
 397     CPPFLAGS="$ac_save_CPPFLAGS"
 398 fi
 399 AC_SUBST(SANELIBS)
 400 AC_SUBST(SANEINCL)
 401
 402 dnl **** Check for the ICU library ****
 403 AC_CHECK_HEADERS(unicode/ubidi.h)
 404 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
 405 then
 406     saved_libs="$LIBS"
 407     ICU_LIB_DIR="${ICU_LIB_DIR-/usr/lib}"
 408     ICUUC_LIB="${ICUUC_LIB-$ICU_LIB_DIR/libsicuuc.a}"
 409     ICUDATA_LIB="${ICUDATA_LIB-$ICU_LIB_DIR/libsicudata.a}"
 410     AC_MSG_CHECKING(whether can link with ICU libraries $ICUUC_LIB and $ICUDATA_LIB)
 411     LIBS="$LIBS $ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s"
 412     AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
 413                 [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
 414                  AC_SUBST(ICULIBS,"$ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s")
 415                  AC_MSG_RESULT(yes)],
 416                 [AC_MSG_RESULT(no)])
 417     LIBS="$saved_libs"
 418 fi
 419
 420 dnl **** Check for FreeType 2 ****
 421 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
 422 if test "$ft_lib" = "no"
 423 then
 424     FREETYPELIBS=""
 425     FREETYPEINCL=""
 426     wine_cv_msg_freetype=no
 427 else
 428     AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
 429     if test "$ft_devel" = "no"
 430     then
 431         AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
 432         if test "$ft_devel2" = "freetype2-config"
 433         then
 434                 ft_devel=$ft_devel2
 435         fi
 436     fi
 437     if test "$ft_devel" = "no"
 438     then
 439         FREETYPELIBS=""
 440         FREETYPEINCL=""
 441         wine_cv_msg_freetype=yes
 442     else
 443         FREETYPELIBS=`$ft_devel --libs`
 444         FREETYPEINCL=`$ft_devel --cflags`
 445         ac_save_CPPFLAGS="$CPPFLAGS"
 446         CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
 447         AC_CHECK_HEADERS(ft2build.h \
 448                          freetype/freetype.h \
 449                          freetype/ftglyph.h \
 450                          freetype/tttables.h \
 451                          freetype/ftnames.h \
 452                          freetype/ftsnames.h \
 453                          freetype/ttnameid.h \
 454                          freetype/ftoutln.h \
 455                          freetype/ftwinfnt.h \
 456                          freetype/internal/sfnt.h,,,
 457                          [#if HAVE_FT2BUILD_H
 458                           #include <ft2build.h>
 459                           #endif])
 460         AC_TRY_CPP([#include <ft2build.h>
 461                     #include <freetype/fttrigon.h>],
 462                     [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
 463           [Define if you have the <freetype/fttrigon.h> header file.])
 464                     wine_cv_fttrigon=yes],
 465                     wine_cv_fttrigon=no)
 466         CPPFLAGS="$ac_save_CPPFLAGS"
 467         dnl Check that we have at least freetype/freetype.h
 468         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
 469         then
 470             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
 471             wine_cv_msg_freetype=no
 472         else
 473             FREETYPELIBS=""
 474             FREETYPEINCL=""
 475             wine_cv_msg_freetype=yes
 476         fi
 477     fi
 478 fi
 479 AC_SUBST(FREETYPELIBS)
 480 AC_SUBST(FREETYPEINCL)
 481
 482 dnl Only build the fonts dir if we have both freetype and fontforge
 483 if test "$FONTFORGE" != "false" -a -n "$FREETYPELIBS"
 484 then
 485   AC_SUBST(FONTSSUBDIRS,"fonts")
 486 fi
 487
 488 dnl **** Check for parport (currently Linux only) ****
 489 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
 490  AC_TRY_COMPILE(
 491    [#include <linux/ppdev.h>],
 492    [ioctl (1,PPCLAIM,0)],
 493    [ac_cv_c_ppdev="yes"],
 494    [ac_cv_c_ppdev="no"])
 495  )
 496 if test "$ac_cv_c_ppdev" = "yes"
 497 then
 498     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
 499 fi
 500
 501 dnl **** Check for va_copy ****
 502 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
 503  AC_TRY_LINK(
 504    [#include <stdarg.h>],
 505    [va_list ap1, ap2;
 506     va_copy(ap1,ap2);
 507    ],
 508    [ac_cv_c_va_copy="yes"],
 509    [ac_cv_c_va_copy="no"])
 510  )
 511 if test "$ac_cv_c_va_copy" = "yes"
 512 then
 513     AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
 514 fi
 515 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
 516  AC_TRY_LINK(
 517    [#include <stdarg.h>],
 518    [va_list ap1, ap2;
 519     __va_copy(ap1,ap2);
 520    ],
 521    [ac_cv_c___va_copy="yes"],
 522    [ac_cv_c___va_copy="no"])
 523  )
 524 if test "$ac_cv_c___va_copy" = "yes"
 525 then
 526     AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
 527 fi
 528
 529 dnl **** Check for sigsetjmp ****
 530 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
 531  AC_TRY_LINK(
 532    [#include <setjmp.h>],
 533    [sigjmp_buf buf;
 534     sigsetjmp( buf, 1 );
 535     siglongjmp( buf, 1 );],
 536    [ac_cv_c_sigsetjmp="yes"],
 537    [ac_cv_c_sigsetjmp="no"])
 538  )
 539 if test "$ac_cv_c_sigsetjmp" = "yes"
 540 then
 541     AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
 542 fi
 543
 544 dnl **** Check for pthread_rwlock_t ****
 545 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
 546 #include <pthread.h>])
 547
 548 dnl **** Check for pthread functions ****
 549 ac_save_LIBS="$LIBS"
 550 LIBS="$LIBS $LIBPTHREAD"
 551 AC_CHECK_FUNCS(\
 552         pthread_getattr_np \
 553         pthread_get_stackaddr_np \
 554         pthread_get_stacksize_np \
 555 )
 556 LIBS="$ac_save_LIBS"
 557
 558 dnl **** Check for Open Sound System ****
 559 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
 560
 561 AC_CACHE_CHECK([for Open Sound System],
 562         ac_cv_c_opensoundsystem,
 563         AC_TRY_COMPILE([
 564         #if defined(HAVE_SYS_SOUNDCARD_H)
 565                 #include <sys/soundcard.h>
 566         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 567                 #include <machine/soundcard.h>
 568         #elif defined(HAVE_SOUNDCARD_H)
 569                 #include <soundcard.h>
 570         #endif
 571         ],[
 572
 573 /* check for one of the Open Sound System specific SNDCTL_ defines */
 574 #if !defined(SNDCTL_DSP_STEREO)
 575 #error No open sound system
 576 #endif
 577 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
 578
 579 if test "$ac_cv_c_opensoundsystem" = "yes"
 580 then
 581     AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
 582 fi
 583
 584 AC_CACHE_CHECK([for Open Sound System/MIDI interface],
 585         ac_cv_c_opensoundsystem_midi,
 586         AC_TRY_COMPILE([
 587         #if defined(HAVE_SYS_SOUNDCARD_H)
 588                 #include <sys/soundcard.h>
 589         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 590                 #include <machine/soundcard.h>
 591         #elif defined(HAVE_SOUNDCARD_H)
 592                 #include <soundcard.h>
 593         #endif
 594         ],[
 595
 596 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
 597 #if !defined(SNDCTL_SEQ_SYNC)
 598 #error No open sound system MIDI interface
 599 #endif
 600 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
 601
 602 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
 603 then
 604     AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
 605 fi
 606
 607 dnl **** Check for aRts Sound Server ****
 608 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
 609 if test x$ARTSCCONFIG != x -a x$ARTSCCONFIG != x'"$ARTSCCONFIG"';
 610 then
 611     ARTSC_CFLAGS=""
 612     for i in `$ARTSCCONFIG --cflags`
 613     do
 614       case "$i" in
 615         -I*) ARTSC_CFLAGS="$ARTSC_CFLAGS $i";;
 616       esac
 617     done
 618     ARTSC_LIBS=`$ARTSCCONFIG --libs`
 619     save_CFLAGS="$CFLAGS"
 620     CFLAGS="$CFLAGS $ARTSC_CFLAGS"
 621     AC_TRY_COMPILE([#include <artsc.h>],[arts_stream_t stream;],
 622         [AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
 623          AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
 624          AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])])
 625     CFLAGS="$save_CFLAGS"
 626 fi
 627
 628 dnl **** Check for ALSA ****
 629 AC_SUBST(ALSALIBS,"")
 630 AC_CHECK_HEADERS(alsa/asoundlib.h sys/asoundlib.h, break)
 631 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
 632 then
 633     AC_CHECK_LIB(asound,snd_pcm_open,
 634         AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA including devel headers])
 635         ALSALIBS="-lasound")
 636 fi
 637
 638 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
 639
 640 AC_SUBST(AUDIOIOLIBS,"")
 641 AC_CHECK_HEADERS(libaudioio.h,
 642     [AC_CHECK_LIB(audioio,AudioIOGetVersion,
 643                   [AUDIOIOLIBS="-laudioio"
 644                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])])
 645
 646 dnl **** Check for capi4linux ****
 647
 648 AC_CHECK_HEADERS(capi20.h,[
 649         AC_CHECK_HEADERS(linux/capi.h,[
 650                 AC_CHECK_LIB(capi20,capi20_register,[
 651                         AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])
 652                         AC_SUBST(CAPI4LINUXLIBS,"-lcapi20")
 653                 ])
 654         ])
 655 ])
 656
 657 dnl **** Check for broken glibc mmap64 ****
 658
 659 AC_CACHE_CHECK( [whether mmap64 works defined as mmap], ac_cv_mmap64_works,
 660         AC_TRY_RUN([
 661                 #define _FILE_OFFSET_BITS 64
 662                 #include <stdio.h>
 663                 #include <unistd.h>
 664                 #include <fcntl.h>
 665                 #include <sys/mman.h>
 666                 #include <errno.h>
 667
 668                 int main(int argc,char **argv) {
 669                         int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
 670                         if (fd == -1) exit(1);
 671
 672                         unlink("conftest.map");
 673
 674                         write(fd,"test",4);
 675
 676                         if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
 677                             (errno == EINVAL)
 678                         ) {
 679                                 exit(1);
 680                         }
 681                         close(fd);
 682                         fprintf(stderr,"success!\n");
 683                         exit(0);
 684                 }
 685
 686         ],
 687     ac_cv_mmap64_works="yes",
 688     ac_cv_mmap64_works="no",
 689     ac_cv_mmap64_works="no") )
 690
 691 if test "$ac_cv_mmap64_works" = "yes"
 692 then
 693     AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
 694 fi
 695
 696 dnl **** Check for gcc specific options ****
 697
 698 AC_SUBST(EXTRACFLAGS,"")
 699 if test "x${GCC}" = "xyes"
 700 then
 701   EXTRACFLAGS="-Wall -pipe"
 702
 703   dnl Check for strength-reduce bug
 704   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
 705                   AC_TRY_RUN([
 706 int     L[[4]] = {0,1,2,3};
 707 int main(void) {
 708   static int Array[[3]];
 709   unsigned int B = 3;
 710   int i;
 711   for(i=0; i<B; i++) Array[[i]] = i - 3;
 712   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
 713   L[[i]] = 4;
 714
 715   exit( Array[[1]] != -2 || L[[2]] != 3);
 716 }],
 717     ac_cv_c_gcc_strength_bug="no",
 718     ac_cv_c_gcc_strength_bug="yes",
 719     ac_cv_c_gcc_strength_bug="yes") )
 720   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 721   then
 722     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
 723   fi
 724
 725   dnl Check for -fshort-wchar
 726   AC_CACHE_CHECK([for gcc -fshort-wchar support], ac_cv_c_gcc_fshort_wchar,
 727       [WINE_TRY_CFLAGS([-fshort-wchar],
 728                       ac_cv_c_gcc_fshort_wchar="yes",ac_cv_c_gcc_fshort_wchar="no")])
 729   if test "$ac_cv_c_gcc_fshort_wchar" = "yes"
 730   then
 731       AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar", [Specifies the compiler flag that forces a short wchar_t])
 732   fi
 733
 734   dnl Check for -mpreferred-stack-boundary
 735   AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support], ac_cv_c_gcc_stack_boundary,
 736       [WINE_TRY_CFLAGS([-mpreferred-stack-boundary=2],
 737                       ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")])
 738   if test "$ac_cv_c_gcc_stack_boundary" = "yes"
 739   then
 740     EXTRACFLAGS="$EXTRACFLAGS -mpreferred-stack-boundary=2"
 741   fi
 742
 743   dnl Check for -fno-strict-aliasing
 744   AC_CACHE_CHECK([for gcc -fno-strict-aliasing support], ac_cv_c_gcc_no_strict_aliasing,
 745       [WINE_TRY_CFLAGS([-fno-strict-aliasing],
 746                       ac_cv_c_gcc_no_strict_aliasing="yes",ac_cv_c_gcc_no_strict_aliasing="no")])
 747   if test "$ac_cv_c_gcc_no_strict_aliasing" = "yes"
 748   then
 749     EXTRACFLAGS="$EXTRACFLAGS -fno-strict-aliasing"
 750   fi
 751
 752   dnl Check for -gstabs+ option
 753   AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
 754       [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
 755   if test "$ac_cv_c_gcc_gstabs" = "yes"
 756   then
 757     EXTRACFLAGS="$EXTRACFLAGS -gstabs+"
 758   fi
 759
 760   dnl Check for noisy string.h
 761   saved_CFLAGS="$CFLAGS"
 762   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
 763   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
 764       AC_TRY_COMPILE([#include <string.h>],[],
 765                      [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
 766   CFLAGS="$saved_CFLAGS"
 767   if test "$ac_cv_c_string_h_warnings" = "no"
 768   then
 769     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
 770   fi
 771 fi
 772
 773 dnl **** Check how to define a function in assembly code ****
 774
 775 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
 776   WINE_TRY_ASM_LINK(
 777       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
 778       ac_cv_asm_func_def=".def",
 779     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
 780       ac_cv_asm_func_def=".type @function",
 781     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
 782       ac_cv_asm_func_def=".type 2",
 783       ac_cv_asm_func_def="unknown")])]))
 784
 785 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
 786 case "$ac_cv_asm_func_def" in
 787   ".def")
 788      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
 789   ".type @function")
 790      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
 791   ".type 2")
 792      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
 793   *)
 794      AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
 795 esac
 796
 797 dnl **** Check for underscore on external symbols ****
 798
 799 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
 800     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
 801                       [extern int ac_test;],
 802                       [if (ac_test) return 1],
 803                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
 804
 805 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
 806 if test "$ac_cv_c_extern_prefix" = "yes"
 807 then
 808   AC_DEFINE([__ASM_NAME(name)], ["_" name])
 809 else
 810   AC_DEFINE([__ASM_NAME(name)], [name])
 811 fi
 812
 813 dnl **** Check how to do strings in assembler ****
 814
 815 AC_CACHE_CHECK([for assembler keyword for ASCII strings], ac_cv_c_asm_string,
 816     WINE_TRY_ASM_LINK([".data\\n\\t.string \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".string",
 817       WINE_TRY_ASM_LINK([".data\\n\\t.asciz \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".asciz",
 818         WINE_TRY_ASM_LINK([".data\\n\\t.ascii \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".ascii",
 819           AC_MSG_ERROR([could not discover how to produce C strings with assembler.])))))
 820
 821 AC_DEFINE_UNQUOTED(__ASM_STRING, ["$ac_cv_c_asm_string"],
 822                    [Define to the assembler keyword used to specify an ASCII string])
 823
 824 dnl **** Check for .short in assembler ****
 825
 826 AC_CACHE_CHECK([for assembler keyword for word values], ac_cv_c_asm_short,
 827     WINE_TRY_ASM_LINK([".data\\n\\t.short 1\\n\\t.text"],,,ac_cv_c_asm_short=".short",
 828       WINE_TRY_ASM_LINK([".data\\n\\t.half 1\\n\\t.text"],,,ac_cv_c_asm_short=".half",
 829         AC_MSG_ERROR([could not discover how to specify word values with assembler.]))))
 830
 831 AC_DEFINE_UNQUOTED(__ASM_SHORT, ["$ac_cv_c_asm_short"],
 832                    [Define to the assembler keyword used to specify a word value])
 833
 834 dnl **** Check for .size in assembler ****
 835
 836 AC_CACHE_CHECK([for .size in assembler], ac_cv_c_asm_size,
 837     WINE_TRY_ASM_LINK([".globl _ac_test\n.size _ac_test, . - _ac_test"],,,
 838                       ac_cv_c_asm_size="yes",ac_cv_c_asm_size="no"))
 839
 840 if test "$ac_cv_c_asm_size" = "yes"
 841 then
 842   AC_DEFINE(HAVE_ASM_DOT_SIZE, 1, [Define if the assembler keyword .size is accepted])
 843 fi
 844
 845 dnl **** Check for working dll ****
 846
 847 AC_SUBST(DLLEXT,"")
 848 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 849 AC_SUBST(DLLIBS,"")
 850 AC_SUBST(LDSHARED,"")
 851 AC_SUBST(LDDLLFLAGS,"")
 852 AC_SUBST(LIBEXT,"so")
 853 AC_SUBST(IMPLIBEXT,"def")
 854
 855 case $host_os in
 856   cygwin*|mingw32*)
 857     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 858     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 859     if test "$DLLWRAP" = "false"; then
 860       LIBEXT="a"
 861     else
 862       dnl FIXME - check whether dllwrap works correctly...
 863       LIBEXT="dll"
 864     fi
 865     IMPLIBEXT="a"
 866     dnl We can't build 16-bit NE dlls
 867     WIN16_FILES=""
 868     WIN16_INSTALL=""
 869     ;;
 870   *)
 871     AC_CHECK_HEADERS(dlfcn.h,
 872         [AC_CHECK_FUNCS(dlopen,,
 873             [AC_CHECK_LIB(dl,dlopen,
 874                          [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
 875                           DLLIBS="-ldl"],
 876                          [LIBEXT="a"])])],
 877         [LIBEXT="a"])
 878
 879     if test "$LIBEXT" = "so"
 880     then
 881       DLLFLAGS="$DLLFLAGS -fPIC"
 882       DLLEXT=".so"
 883       AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
 884           [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
 885                                 ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
 886       if test "$ac_cv_c_dll_gnuelf" = "yes"
 887       then
 888         LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
 889         LDDLLFLAGS="-shared -Wl,-Bsymbolic"
 890         AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
 891           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
 892                            ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
 893         if test "$ac_cv_c_dll_zdefs" = "yes"
 894         then
 895           LDDLLFLAGS="$LDDLLFLAGS,-z,defs"
 896         fi
 897
 898         AC_CACHE_CHECK([whether the linker accepts -init and -fini], ac_cv_c_dll_init_fini,
 899           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
 900                            ac_cv_c_dll_init_fini="yes",ac_cv_c_dll_init_fini="no")])
 901         if test "$ac_cv_c_dll_init_fini" = "yes"
 902         then
 903           LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"
 904         fi
 905
 906         AC_CACHE_CHECK([whether the linker accepts version scripts], ac_cv_c_ld_version_scripts,
 907           [echo '{ global: *; };' >conftest.map
 908            WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
 909                            ac_cv_c_ld_version_scripts="yes",ac_cv_c_ld_version_scripts="no")
 910            rm -f conftest.map])
 911         if test "$ac_cv_c_ld_version_scripts" = "yes"
 912         then
 913           LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"
 914         fi
 915
 916         AC_CACHE_CHECK([whether the linker accepts --export-dynamic], ac_cv_c_export_dynamic,
 917           [WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
 918                            ac_cv_c_export_dynamic="yes",ac_cv_c_export_dynamic="no")])
 919         if test "$ac_cv_c_export_dynamic" = "yes"
 920         then
 921           AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])
 922         fi
 923
 924         case $host_cpu in
 925           *i[[3456789]]86*)
 926             AC_CACHE_CHECK([whether we can relocate the executable to 0x77f00000], ac_cv_ld_reloc_exec,
 927               [WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x77f00400],
 928                                ac_cv_ld_reloc_exec="yes", ac_cv_ld_reloc_exec="no")])
 929             if test "$ac_cv_ld_reloc_exec" = "yes"
 930             then
 931               LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x77f00400"
 932             fi
 933             ;;
 934         esac
 935
 936       else
 937         AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
 938             [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
 939                                   ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
 940         if test "$ac_cv_c_dll_unixware" = "yes"
 941         then
 942           LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
 943           LDDLLFLAGS="-Wl,-G,-B,symbolic"
 944
 945         else
 946           AC_CACHE_CHECK(whether we can build a Mach-O (Mac OS X/Darwin) dll, ac_cv_c_dll_macho,
 947             [WINE_TRY_SHLIB_FLAGS([-bundle], ac_cv_c_dll_macho="yes", ac_cv_c_dll_macho="no")])
 948           if test "$ac_cv_c_dll_macho" = "yes"
 949           then
 950             LIBEXT="dylib"
 951             LDDLLFLAGS="-bundle -flat_namespace -undefined suppress"
 952             LDSHARED="\$(CC) -dynamiclib"
 953             CFLAGS="$CFLAGS -ffixed-r13 -no-cpp-precomp"
 954             STRIP="$STRIP -u -r"
 955             dnl Relocate wine executable
 956             AC_SUBST(LDEXECFLAGS,"-seg1addr 0x120000")
 957             dnl Relocate libwine.dyld too
 958             AC_SUBST(LDLIBWINEFLAGS,"-seg1addr 0x140000")
 959             dnl declare needed frameworks
 960             AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
 961             AC_SUBST(IOKITLIB,"-framework IOKit")
 962             dnl using IOKit imply we use CoreFoundation too
 963             IOKITLIB = "$IOKITLIB $COREFOUNDATIONLIB"
 964           else
 965             AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
 966               [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
 967             if test "$ac_cv_c_dll_hpux" = "yes"
 968             then
 969               LIBEXT="sl"
 970               LDDLLFLAGS="-shared"
 971               LDSHARED="\$(CC) -shared"
 972             fi
 973           fi
 974         fi
 975       fi
 976     fi
 977
 978     dnl Check for cross compiler to build test programs
 979     AC_SUBST(CROSSTEST,"")
 980     if test "$cross_compiling" = "no"
 981     then
 982       AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32msvc-gcc i386-mingw32-gcc mingw-gcc,false)
 983       AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32msvc-dlltool i386-mingw32-dlltool mingw-dlltool,false)
 984       AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32msvc-windres i386-mingw32-windres mingw-windres,false)
 985       if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
 986     fi
 987     ;;
 988 esac
 989
 990 if test "$LIBEXT" = "a"; then
 991   AC_MSG_ERROR(
 992 [could not find a way to build shared libraries.
 993 It is currently not possible to build Wine without shared library
 994 (.so) support to allow transparent switch between .so and .dll files.
 995 If you are using Linux, you will need a newer binutils.]
 996 )
 997 fi
 998
 999 case $build_os in
1000   cygwin*|mingw32*)
1001     AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$PATH\"") ;;
1002   darwin*|macosx*)
1003     AC_SUBST(LDPATH,"DYLD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$DYLD_LIBRARY_PATH\"") ;;
1004   *)
1005     AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$LD_LIBRARY_PATH\"") ;;
1006 esac
1007
1008 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1009 case $host_os in
1010   mingw32*)
1011     AC_SUBST(CRTLIBS,"-lmsvcrt")
1012     AC_SUBST(SOCKETLIBS,"-lws2_32")
1013     ;;
1014 esac
1015
1016 case $host_os in
1017   linux*)
1018     AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread wine-preloader")
1019     AC_SUBST(MAIN_BINARY,"wine-glibc")
1020     ;;
1021   darwin*)
1022     AC_SUBST(WINE_BINARIES,"wine-pthread")
1023     AC_SUBST(MAIN_BINARY,"wine-pthread")
1024     ;;
1025   *)
1026     AC_SUBST(WINE_BINARIES,"wine-kthread")
1027     AC_SUBST(MAIN_BINARY,"wine-kthread")
1028     ;;
1029 esac
1030
1031 dnl **** Get the soname for libraries that we load dynamically ****
1032
1033 if test "$LIBEXT" = "so" -o "$LIBEXT" = "dylib"
1034 then
1035   WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
1036   WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1037   WINE_GET_SONAME(Xi,XOpenDevice,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1038   WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1039   WINE_GET_SONAME(Xrandr,XRRQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1040   WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
1041   WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
1042   WINE_GET_SONAME(txc_dxtn,fetch_2d_texel_rgba_dxt1)
1043   WINE_GET_SONAME(cups,cupsGetDefault)
1044   WINE_GET_SONAME(jack,jack_client_new)
1045   WINE_GET_SONAME(fontconfig,FcInit)
1046   WINE_GET_SONAME(ssl,SSL_library_init)
1047   WINE_GET_SONAME(crypto,BIO_new_socket)
1048   WINE_GET_SONAME(ncurses,waddch)
1049   WINE_GET_SONAME(curses,waddch)
1050   WINE_GET_SONAME(jpeg,jpeg_start_decompress)
1051   WINE_GET_SONAME(ungif,DGifOpen)
1052   WINE_GET_SONAME(gif,DGifOpen)
1053   WINE_GET_SONAME(lcms,cmsOpenProfileFromFile)
1054 fi
1055
1056
1057 dnl **** Check for functions ****
1058
1059 AC_FUNC_ALLOCA()
1060 AC_CHECK_FUNCS(\
1061         _lwp_create \
1062         _lwp_self \
1063         _pclose \
1064         _popen \
1065         _snprintf \
1066         _spawnvp \
1067         _stricmp \
1068         _strnicmp \
1069         _vsnprintf \
1070         chsize \
1071         clone \
1072         epoll_create \
1073         finite \
1074         fpclass \
1075         fstatfs \
1076         fstatvfs \
1077         ftruncate \
1078         ftruncate64 \
1079         futimes \
1080         getnetbyaddr \
1081         getnetbyname \
1082         getopt_long \
1083         getpagesize \
1084         getprotobyname \
1085         getprotobynumber \
1086         getpwuid \
1087         getservbyport \
1088         gettid \
1089         gettimeofday \
1090         getuid \
1091         inet_network \
1092         lseek64 \
1093         lstat \
1094         memmove \
1095         mmap \
1096         pclose \
1097         popen \
1098         pread \
1099         pwrite \
1100         readlink \
1101         rfork \
1102         sched_yield \
1103         select \
1104         sendmsg \
1105         settimeofday \
1106         sigaltstack \
1107         snprintf \
1108         spawnvp \
1109         statfs \
1110         statvfs \
1111         strcasecmp \
1112         strerror \
1113         strncasecmp \
1114         tcgetattr \
1115         timegm \
1116         usleep \
1117         vfscanf \
1118         vsnprintf \
1119         wait4 \
1120         waitpid \
1121 )
1122
1123 dnl **** Check for header files ****
1124
1125 AC_CHECK_HEADERS(\
1126         arpa/inet.h \
1127         arpa/nameser.h \
1128         cups/cups.h \
1129         direct.h \
1130         elf.h \
1131         float.h \
1132         fontconfig/fontconfig.h \
1133         getopt.h \
1134         gif_lib.h \
1135         ieeefp.h \
1136         io.h \
1137         jack/jack.h \
1138         jpeglib.h \
1139         lcms.h \
1140         libio.h \
1141         libutil.h \
1142         link.h \
1143         linux/cdrom.h \
1144         linux/compiler.h \
1145         linux/hdreg.h \
1146         linux/input.h \
1147         linux/ioctl.h \
1148         linux/joystick.h \
1149         linux/major.h \
1150         linux/param.h \
1151         linux/serial.h \
1152         linux/ucdrom.h \
1153         machine/cpu.h \
1154         mntent.h \
1155         netdb.h \
1156         netinet/in.h \
1157         netinet/in_systm.h \
1158         netinet/tcp.h \
1159         netinet/tcp_fsm.h \
1160         openssl/ssl.h \
1161         process.h \
1162         pthread.h \
1163         pty.h \
1164         pwd.h \
1165         regex.h \
1166         sched.h \
1167         scsi/sg.h \
1168         scsi/scsi.h \
1169         scsi/scsi_ioctl.h \
1170         socket.h \
1171         stdint.h \
1172         strings.h \
1173         sys/cdio.h \
1174         sys/elf32.h \
1175         sys/errno.h \
1176         sys/epoll.h \
1177         sys/exec_elf.h \
1178         sys/file.h \
1179         sys/filio.h \
1180         sys/inttypes.h \
1181         sys/ioctl.h \
1182         sys/ipc.h \
1183         sys/link.h \
1184         sys/lwp.h \
1185         sys/mman.h \
1186         sys/modem.h \
1187         sys/msg.h \
1188         sys/param.h \
1189         sys/poll.h \
1190         sys/ptrace.h \
1191         sys/reg.h \
1192         sys/scsiio.h \
1193         sys/shm.h \
1194         sys/signal.h \
1195         sys/socket.h \
1196         sys/sockio.h \
1197         sys/statfs.h \
1198         sys/statvfs.h \
1199         sys/strtio.h \
1200         sys/syscall.h \
1201         sys/sysctl.h \
1202         sys/time.h \
1203         sys/times.h \
1204         sys/uio.h \
1205         sys/un.h \
1206         sys/v86.h \
1207         sys/v86intr.h \
1208         sys/vfs.h \
1209         sys/vm86.h \
1210         sys/wait.h \
1211         syscall.h \
1212         termios.h \
1213         unistd.h \
1214         utime.h \
1215         valgrind/memcheck.h
1216 )
1217 AC_HEADER_STAT()
1218
1219 dnl **** Checks for headers that depend on other ones ****
1220
1221 AC_CHECK_HEADERS(sys/mount.h sys/user.h,,,
1222     [#include <sys/types.h>
1223      #if HAVE_SYS_PARAM_H
1224      # include <sys/param.h>
1225      #endif])
1226
1227 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h],,,
1228     [#include <sys/types.h>
1229      #if HAVE_SYS_SOCKET_H
1230      # include <sys/socket.h>
1231      #endif])
1232
1233 AC_CHECK_HEADERS([resolv.h],,,
1234     [#include <sys/types.h>
1235      #if HAVE_SYS_SOCKET_H
1236      # include <sys/socket.h>
1237      #endif
1238      #if HAVE_NETINET_IN_H
1239      # include <netinet/in.h>
1240      #endif
1241      #if HAVE_ARPA_NAMESER_H
1242      # include <arpa/nameser.h>
1243      #endif])
1244
1245 AC_CHECK_HEADERS(netinet/ip.h,,,
1246     [#include <sys/types.h>
1247      #if HAVE_SYS_SOCKET_H
1248      # include <sys/socket.h>
1249      #endif
1250      #if HAVE_NETINET_IN_SYSTM_H
1251      # include <netinet/in_systm.h>
1252      #endif])
1253
1254 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
1255
1256 dnl **** Check for IPX headers (currently Linux only) ****
1257
1258 AC_CACHE_CHECK([for GNU style IPX support], ac_cv_c_ipx_gnu,
1259  AC_TRY_COMPILE(
1260    [#include <sys/types.h>
1261     #ifdef HAVE_SYS_SOCKET_H
1262     # include <sys/socket.h>
1263     #endif
1264     #include <netipx/ipx.h>],
1265    [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1266    [ac_cv_c_ipx_gnu="yes"],
1267    [ac_cv_c_ipx_gnu="no"])
1268  )
1269 if test "$ac_cv_c_ipx_gnu" = "yes"
1270 then
1271     AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
1272 fi
1273
1274 if test "$ac_cv_c_ipx_gnu" = "no"
1275 then
1276  AC_CACHE_CHECK([for linux style IPX support], ac_cv_c_ipx_linux,
1277   AC_TRY_COMPILE(
1278     [#include <sys/types.h>
1279      #ifdef HAVE_SYS_SOCKET_H
1280      # include <sys/socket.h>
1281      #endif
1282      #include <asm/types.h>
1283      #include <linux/ipx.h>],
1284     [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1285     [ac_cv_c_ipx_linux="yes"],
1286     [ac_cv_c_ipx_linux="no"])
1287   )
1288   if test "$ac_cv_c_ipx_linux" = "yes"
1289   then
1290       AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
1291   fi
1292 fi
1293
1294 dnl **** Check for types ****
1295
1296 AC_C_CONST
1297 AC_C_INLINE
1298 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1299
1300 AC_CACHE_CHECK([whether linux/input.h is for real],
1301         wine_cv_linux_input_h,
1302         AC_TRY_COMPILE([
1303             #include <linux/input.h>
1304         ] , [
1305             int foo = EVIOCGBIT(EV_ABS,42);
1306             int bar = BTN_PINKIE;
1307             int fortytwo = 42;
1308         ],
1309         wine_cv_linux_input_h=yes,
1310         wine_cv_linux_input_h=no,
1311         no
1312         )
1313     )
1314     if test "$wine_cv_linux_input_h" = "yes"
1315     then
1316         AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
1317                   [Define if we have linux/input.h AND it contains the INPUT event API])
1318     fi
1319
1320
1321 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1322         wine_cv_linux_gethostbyname_r_6,
1323         AC_TRY_LINK([
1324 #include <netdb.h>
1325         ], [
1326     char *name=NULL;
1327     struct hostent he;
1328     struct hostent *result;
1329     char *buf=NULL;
1330     int bufsize=0;
1331     int res,errnr;
1332     char *addr=NULL;
1333     int addrlen=0;
1334     int addrtype=0;
1335     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1336     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1337     ],
1338         wine_cv_linux_gethostbyname_r_6=yes,
1339         wine_cv_linux_gethostbyname_r_6=no
1340         )
1341    )
1342    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1343    then
1344       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1345                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1346    fi
1347
1348 if test "$ac_cv_header_linux_joystick_h" = "yes"
1349 then
1350    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1351         wine_cv_linux_joystick_22_api,
1352         AC_TRY_COMPILE([
1353         #include <sys/ioctl.h>
1354         #include <linux/joystick.h>
1355
1356         struct js_event blub;
1357         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1358         #error "no 2.2 header"
1359         #endif
1360         ],/*empty*/,
1361         wine_cv_linux_joystick_22_api=yes,
1362         wine_cv_linux_joystick_22_api=no,
1363         wine_cv_linux_joystick_22_api=no
1364         )
1365    )
1366    if test "$wine_cv_linux_joystick_22_api" = "yes"
1367    then
1368       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1369                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1370    fi
1371 fi
1372
1373 dnl **** statfs checks ****
1374
1375 if test "$ac_cv_header_sys_vfs_h" = "yes"
1376 then
1377     AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
1378                     wine_cv_sys_vfs_has_statfs,
1379         AC_TRY_COMPILE([
1380         #include <sys/types.h>
1381         #ifdef HAVE_SYS_PARAM_H
1382         # include <sys/param.h>
1383         #endif
1384         #include <sys/vfs.h>
1385         ],[
1386                 struct statfs stfs;
1387
1388                 memset(&stfs,0,sizeof(stfs));
1389         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1390         )
1391     )
1392     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1393     then
1394       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1395                 [Define if the struct statfs is defined by <sys/vfs.h>])
1396     fi
1397 fi
1398
1399 if test "$ac_cv_header_sys_statfs_h" = "yes"
1400 then
1401     AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1402                     wine_cv_sys_statfs_has_statfs,
1403         AC_TRY_COMPILE([
1404         #include <sys/types.h>
1405         #ifdef HAVE_SYS_PARAM_H
1406         # include <sys/param.h>
1407         #endif
1408         #include <sys/statfs.h>
1409         ],[
1410                 struct statfs stfs;
1411         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1412         )
1413     )
1414     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1415     then
1416       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1417                 [Define if the struct statfs is defined by <sys/statfs.h>])
1418     fi
1419 fi
1420
1421 if test "$ac_cv_header_sys_mount_h" = "yes"
1422 then
1423     AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1424                     wine_cv_sys_mount_has_statfs,
1425         AC_TRY_COMPILE([
1426         #include <sys/types.h>
1427         #ifdef HAVE_SYS_PARAM_H
1428         # include <sys/param.h>
1429         #endif
1430         #include <sys/mount.h>
1431         ],[
1432                 struct statfs stfs;
1433         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1434         )
1435     )
1436     if test "$wine_cv_sys_mount_has_statfs" = "yes"
1437     then
1438       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1439                 [Define if the struct statfs is defined by <sys/mount.h>])
1440     fi
1441 fi
1442
1443 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1444
1445 dnl Check for statfs members
1446 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1447 [#include <sys/types.h>
1448 #ifdef HAVE_SYS_PARAM_H
1449 # include <sys/param.h>
1450 #endif
1451 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1452 # include <sys/mount.h>
1453 #else
1454 # ifdef STATFS_DEFINED_BY_SYS_VFS
1455 #  include <sys/vfs.h>
1456 # else
1457 #  ifdef STATFS_DEFINED_BY_SYS_STATFS
1458 #   include <sys/statfs.h>
1459 #  endif
1460 # endif
1461 #endif])
1462
1463 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1464 [#ifdef HAVE_SYS_STATVFS_H
1465 #include <sys/statvfs.h>
1466 #endif])
1467
1468 dnl Check for socket structure members
1469 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1470 [#include <sys/types.h>
1471 #ifdef HAVE_SYS_SOCKET_H
1472 # include <sys/socket.h>
1473 #endif
1474 #ifdef HAVE_SYS_UN_H
1475 # include <sys/un.h>
1476 #endif])
1477
1478 dnl Check for siginfo_t members
1479 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1480
1481 dnl Check for struct option
1482 AC_CHECK_MEMBERS([struct option.name],,,
1483 [#ifdef HAVE_GETOPT_H
1484 #include <getopt.h>
1485 #endif])
1486
1487 dnl Check for stat.st_blocks
1488 AC_CHECK_MEMBERS([struct stat.st_blocks])
1489
1490 dnl *** check for the need to define platform-specific symbols
1491
1492 case $host_cpu in
1493   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1494   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
1495   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
1496   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
1497 esac
1498
1499 case $host_vendor in
1500   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1501 esac
1502
1503 dnl **** Generate output files ****
1504
1505 AH_TOP([#define __WINE_CONFIG_H])
1506
1507 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/d3ddevice)
1508 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dclipper)
1509 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/ddraw)
1510 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/direct3d)
1511 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dpalette)
1512 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dsurface)
1513 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1514 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1515 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1516 WINE_CONFIG_EXTRA_DIR(dlls/user/dde)
1517 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1518 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1519 WINE_CONFIG_EXTRA_DIR(include/wine)
1520 WINE_CONFIG_EXTRA_DIR(misc)
1521 WINE_CONFIG_EXTRA_DIR(programs/regedit/tests)
1522 WINE_CONFIG_EXTRA_DIR(windows)
1523
1524 MAKE_RULES=Make.rules
1525 AC_SUBST_FILE(MAKE_RULES)
1526
1527 MAKE_DLL_RULES=dlls/Makedll.rules
1528 AC_SUBST_FILE(MAKE_DLL_RULES)
1529
1530 MAKE_TEST_RULES=dlls/Maketest.rules
1531 AC_SUBST_FILE(MAKE_TEST_RULES)
1532
1533 MAKE_LIB_RULES=libs/Makelib.rules
1534 AC_SUBST_FILE(MAKE_LIB_RULES)
1535
1536 MAKE_PROG_RULES=programs/Makeprog.rules
1537 AC_SUBST_FILE(MAKE_PROG_RULES)
1538
1539 AC_CONFIG_FILES([
1540 Make.rules
1541 dlls/Makedll.rules
1542 dlls/Maketest.rules
1543 libs/Makelib.rules
1544 programs/Makeprog.rules
1545 Makefile
1546 dlls/Makefile
1547 dlls/advapi32/Makefile
1548 dlls/advapi32/tests/Makefile
1549 dlls/advpack/Makefile
1550 dlls/amstream/Makefile
1551 dlls/atl/Makefile
1552 dlls/avicap32/Makefile
1553 dlls/avifil32/Makefile
1554 dlls/cabinet/Makefile
1555 dlls/capi2032/Makefile
1556 dlls/cards/Makefile
1557 dlls/cfgmgr32/Makefile
1558 dlls/comcat/Makefile
1559 dlls/comctl32/Makefile
1560 dlls/comctl32/tests/Makefile
1561 dlls/commdlg/Makefile
1562 dlls/crtdll/Makefile
1563 dlls/crypt32/Makefile
1564 dlls/ctl3d/Makefile
1565 dlls/d3d8/Makefile
1566 dlls/d3d9/Makefile
1567 dlls/d3dim/Makefile
1568 dlls/d3drm/Makefile
1569 dlls/d3dx8/Makefile
1570 dlls/d3dxof/Makefile
1571 dlls/dbghelp/Makefile
1572 dlls/dciman32/Makefile
1573 dlls/ddraw/Makefile
1574 dlls/ddraw/tests/Makefile
1575 dlls/devenum/Makefile
1576 dlls/dinput/Makefile
1577 dlls/dinput8/Makefile
1578 dlls/dmband/Makefile
1579 dlls/dmcompos/Makefile
1580 dlls/dmime/Makefile
1581 dlls/dmloader/Makefile
1582 dlls/dmscript/Makefile
1583 dlls/dmstyle/Makefile
1584 dlls/dmsynth/Makefile
1585 dlls/dmusic/Makefile
1586 dlls/dmusic32/Makefile
1587 dlls/dplay/Makefile
1588 dlls/dplayx/Makefile
1589 dlls/dpnet/Makefile
1590 dlls/dpnhpast/Makefile
1591 dlls/dsound/Makefile
1592 dlls/dsound/tests/Makefile
1593 dlls/dswave/Makefile
1594 dlls/dxdiagn/Makefile
1595 dlls/dxerr8/Makefile
1596 dlls/dxerr9/Makefile
1597 dlls/dxguid/Makefile
1598 dlls/gdi/Makefile
1599 dlls/gdi/tests/Makefile
1600 dlls/glu32/Makefile
1601 dlls/glut32/Makefile
1602 dlls/hhctrl.ocx/Makefile
1603 dlls/iccvid/Makefile
1604 dlls/icmp/Makefile
1605 dlls/ifsmgr.vxd/Makefile
1606 dlls/imagehlp/Makefile
1607 dlls/imm32/Makefile
1608 dlls/iphlpapi/Makefile
1609 dlls/iphlpapi/tests/Makefile
1610 dlls/itss/Makefile
1611 dlls/kernel/Makefile
1612 dlls/kernel/tests/Makefile
1613 dlls/lzexpand/Makefile
1614 dlls/mapi32/Makefile
1615 dlls/mapi32/tests/Makefile
1616 dlls/mlang/Makefile
1617 dlls/mlang/tests/Makefile
1618 dlls/mmdevldr.vxd/Makefile
1619 dlls/monodebg.vxd/Makefile
1620 dlls/mpr/Makefile
1621 dlls/msacm/Makefile
1622 dlls/msacm/imaadp32/Makefile
1623 dlls/msacm/msadp32/Makefile
1624 dlls/msacm/msg711/Makefile
1625 dlls/msacm/winemp3/Makefile
1626 dlls/msacm/tests/Makefile
1627 dlls/mscms/Makefile
1628 dlls/mscms/tests/Makefile
1629 dlls/msdmo/Makefile
1630 dlls/mshtml/Makefile
1631 dlls/msi/Makefile
1632 dlls/msimg32/Makefile
1633 dlls/msisys/Makefile
1634 dlls/msnet32/Makefile
1635 dlls/msrle32/Makefile
1636 dlls/msvcrt/Makefile
1637 dlls/msvcrt/tests/Makefile
1638 dlls/msvcrt20/Makefile
1639 dlls/msvcrt40/Makefile
1640 dlls/msvcrtd/Makefile
1641 dlls/msvcrtd/tests/Makefile
1642 dlls/msvidc32/Makefile
1643 dlls/msvideo/Makefile
1644 dlls/mswsock/Makefile
1645 dlls/netapi32/Makefile
1646 dlls/netapi32/tests/Makefile
1647 dlls/newdev/Makefile
1648 dlls/ntdll/Makefile
1649 dlls/ntdll/tests/Makefile
1650 dlls/odbc32/Makefile
1651 dlls/ole32/Makefile
1652 dlls/ole32/tests/Makefile
1653 dlls/oleacc/Makefile
1654 dlls/oleaut32/Makefile
1655 dlls/oleaut32/tests/Makefile
1656 dlls/olecli/Makefile
1657 dlls/oledlg/Makefile
1658 dlls/olepro32/Makefile
1659 dlls/olesvr/Makefile
1660 dlls/opengl32/Makefile
1661 dlls/psapi/Makefile
1662 dlls/psapi/tests/Makefile
1663 dlls/qcap/Makefile
1664 dlls/quartz/Makefile
1665 dlls/quartz/tests/Makefile
1666 dlls/rasapi32/Makefile
1667 dlls/richedit/Makefile
1668 dlls/rpcrt4/Makefile
1669 dlls/rpcrt4/tests/Makefile
1670 dlls/rsabase/Makefile
1671 dlls/rsabase/tests/Makefile
1672 dlls/secur32/Makefile
1673 dlls/serialui/Makefile
1674 dlls/setupapi/Makefile
1675 dlls/shdocvw/Makefile
1676 dlls/shell32/Makefile
1677 dlls/shell32/tests/Makefile
1678 dlls/shfolder/Makefile
1679 dlls/shlwapi/Makefile
1680 dlls/shlwapi/tests/Makefile
1681 dlls/snmpapi/Makefile
1682 dlls/sti/Makefile
1683 dlls/strmiids/Makefile
1684 dlls/tapi32/Makefile
1685 dlls/ttydrv/Makefile
1686 dlls/twain/Makefile
1687 dlls/unicows/Makefile
1688 dlls/url/Makefile
1689 dlls/urlmon/Makefile
1690 dlls/urlmon/tests/Makefile
1691 dlls/user/Makefile
1692 dlls/user/tests/Makefile
1693 dlls/uuid/Makefile
1694 dlls/uxtheme/Makefile
1695 dlls/vdhcp.vxd/Makefile
1696 dlls/vdmdbg/Makefile
1697 dlls/version/Makefile
1698 dlls/version/tests/Makefile
1699 dlls/vmm.vxd/Makefile
1700 dlls/vnbt.vxd/Makefile
1701 dlls/vnetbios.vxd/Makefile
1702 dlls/vtdapi.vxd/Makefile
1703 dlls/vwin32.vxd/Makefile
1704 dlls/win32s/Makefile
1705 dlls/winaspi/Makefile
1706 dlls/wined3d/Makefile
1707 dlls/winedos/Makefile
1708 dlls/wineps/Makefile
1709 dlls/wininet/Makefile
1710 dlls/wininet/tests/Makefile
1711 dlls/winmm/Makefile
1712 dlls/winmm/joystick/Makefile
1713 dlls/winmm/mcianim/Makefile
1714 dlls/winmm/mciavi/Makefile
1715 dlls/winmm/mcicda/Makefile
1716 dlls/winmm/mciseq/Makefile
1717 dlls/winmm/mciwave/Makefile
1718 dlls/winmm/midimap/Makefile
1719 dlls/winmm/tests/Makefile
1720 dlls/winmm/wavemap/Makefile
1721 dlls/winmm/winealsa/Makefile
1722 dlls/winmm/winearts/Makefile
1723 dlls/winmm/wineaudioio/Makefile
1724 dlls/winmm/winejack/Makefile
1725 dlls/winmm/winenas/Makefile
1726 dlls/winmm/wineoss/Makefile
1727 dlls/winnls/Makefile
1728 dlls/winsock/Makefile
1729 dlls/winsock/tests/Makefile
1730 dlls/winspool/Makefile
1731 dlls/winspool/tests/Makefile
1732 dlls/wintab32/Makefile
1733 dlls/wintrust/Makefile
1734 dlls/wow32/Makefile
1735 dlls/wsock32/Makefile
1736 dlls/x11drv/Makefile
1737 documentation/Makefile
1738 fonts/Makefile
1739 include/Makefile
1740 libs/Makefile
1741 libs/port/Makefile
1742 libs/unicode/Makefile
1743 libs/wine/Makefile
1744 libs/wpp/Makefile
1745 loader/Makefile
1746 programs/Makefile
1747 programs/avitools/Makefile
1748 programs/clock/Makefile
1749 programs/cmdlgtst/Makefile
1750 programs/control/Makefile
1751 programs/expand/Makefile
1752 programs/msiexec/Makefile
1753 programs/notepad/Makefile
1754 programs/progman/Makefile
1755 programs/regedit/Makefile
1756 programs/regsvr32/Makefile
1757 programs/rpcss/Makefile
1758 programs/rundll32/Makefile
1759 programs/start/Makefile
1760 programs/taskmgr/Makefile
1761 programs/uninstaller/Makefile
1762 programs/view/Makefile
1763 programs/wcmd/Makefile
1764 programs/wineboot/Makefile
1765 programs/winebrowser/Makefile
1766 programs/winecfg/Makefile
1767 programs/wineconsole/Makefile
1768 programs/winedbg/Makefile
1769 programs/winefile/Makefile
1770 programs/winemenubuilder/Makefile
1771 programs/winemine/Makefile
1772 programs/winepath/Makefile
1773 programs/winetest/Makefile
1774 programs/winevdm/Makefile
1775 programs/winhelp/Makefile
1776 programs/winver/Makefile
1777 server/Makefile
1778 tools/Makefile
1779 tools/widl/Makefile
1780 tools/winapi/Makefile
1781 tools/winebuild/Makefile
1782 tools/winedump/Makefile
1783 tools/winegcc/Makefile
1784 tools/wmc/Makefile
1785 tools/wrc/Makefile])
1786
1787 AC_OUTPUT
1788
1789 if test "$have_x" = "no"
1790 then
1791   echo
1792   echo "*** Warning: X development files not found. Wine will be built without"
1793   echo "*** X support, which currently does not work, and would probably not be"
1794   echo "*** what you want anyway. You will need to install devel packages of"
1795   echo "*** Xlib/Xfree86 at the very least."
1796 fi
1797
1798 if test "$wine_cv_opengl_version_OK" = "no"
1799 then
1800   echo
1801   echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1802   echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1803 fi
1804
1805 if test "$wine_cv_msg_freetype" = "yes"
1806 then
1807   echo
1808   echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1809   echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1810   echo "*** freetype-devel package (or its equivalent on your distribution) to"
1811   echo "*** enable Wine to use TrueType fonts."
1812 fi
1813
1814 echo
1815 echo "Configure finished.  Do '${ac_make} depend && ${ac_make}' to compile Wine."
1816 echo
1817
1818 dnl Local Variables:
1819 dnl comment-start: "dnl "
1820 dnl comment-end: ""
1821 dnl comment-start-skip: "\\bdnl\\b\\s *"
1822 dnl compile-command: "autoconf"
1823 dnl End: