git.oblomov.eu Git - wine/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 AC_PREREQ(2.53b)
   8 AC_INIT([Wine],WINE_VERSION,[wine-devel@winehq.org])
   9 AC_CONFIG_SRCDIR(server/atom.c)
  10 AC_CONFIG_HEADERS(include/config.h)
  11 AC_CONFIG_AUX_DIR(tools)
  12
  13 dnl **** Command-line arguments ****
  14
  15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
  16 AC_ARG_ENABLE(win64, AC_HELP_STRING([--enable-win64], [build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
  17
  18 AC_ARG_WITH(opengl,    AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
  19 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
  20
  21 AC_CANONICAL_HOST
  22 case $host in
  23   x86_64*linux*)
  24     if test "x$enable_win64" != "xyes"
  25     then
  26       test -n "$CC" || CC="gcc -m32"
  27       test -n "$LD" || LD="ld -m elf_i386"
  28       test -n "$AS" || AS="as --32"
  29       host_cpu="i386"
  30     fi
  31     ;;
  32 esac
  33
  34 dnl enable_win16 defaults to yes on x86, to no on other CPUs
  35 case $host_cpu in
  36   *i[[3456789]]86*)
  37     if test "x$enable_win16" != "xno"
  38     then
  39       enable_win16="yes"
  40     fi
  41     ;;
  42 esac
  43
  44 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
  45 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
  46 if test "x$enable_win16" != "xyes"
  47 then
  48   WIN16_FILES=""
  49   WIN16_INSTALL=""
  50 fi
  51
  52 dnl check for out of tree build with unclean source tree
  53 case "$srcdir" in
  54  .) ;;
  55  *) if test -f "$srcdir/Makefile" -o -f "$srcdir/include/config.h"; then
  56       AC_MSG_ERROR([you are building out of the source tree, but the source tree contains object files.
  57 You need to run 'make distclean' in the source tree first.])
  58     fi ;;
  59 esac
  60
  61 dnl **** Check for some programs ****
  62
  63 AC_PROG_MAKE_SET
  64 AC_PROG_CC
  65 AC_PROG_CXX
  66 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
  67 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
  68
  69 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
  70   [if test -z "$with_wine_tools"; then
  71      if test "$cross_compiling" = "yes"; then
  72        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
  73      else
  74        wine_cv_toolsdir="\$(TOPOBJDIR)"
  75      fi
  76    elif test -d "$with_wine_tools/tools/winebuild"; then
  77      case $with_wine_tools in
  78        /*) wine_cv_toolsdir="$with_wine_tools" ;;
  79        *)  wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
  80      esac
  81    else
  82      AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
  83    fi])
  84 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
  85
  86 AC_PATH_XTRA
  87
  88 dnl Check for flex
  89 AC_CHECK_PROGS(FLEX,flex,none)
  90 if test "$FLEX" = "none"
  91 then
  92   AC_MSG_ERROR([no suitable flex found. Please install the 'flex' package.])
  93 fi
  94
  95 dnl Check for bison
  96 AC_CHECK_PROGS(BISON,bison,none)
  97 if test "$BISON" = "none"
  98 then
  99   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
 100 fi
 101
 102 AC_CHECK_TOOLS(AS,[gas as],as)
 103 AC_CHECK_TOOL(LD,ld,ld)
 104 AC_CHECK_TOOL(AR,ar,ar)
 105 AC_PROG_RANLIB
 106 AC_CHECK_TOOL(STRIP,strip,strip)
 107 AC_CHECK_TOOL(WINDRES,windres,false)
 108 AC_PROG_LN_S
 109 WINE_PROG_LN
 110 AC_PROG_EGREP
 111 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
 112 AC_PROG_INSTALL
 113 dnl Prepend src dir to install path dir if it's a relative path
 114 case "$INSTALL" in
 115   [[\\/$]]* | ?:[[\\/]]* ) ;;
 116   *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
 117 esac
 118
 119 dnl Check for lint
 120 AC_CHECK_PROGS(LINT, lclint lint)
 121 if test "$LINT" = "lint"
 122 then
 123   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 124   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 125 fi
 126 AC_SUBST(LINT)
 127 AC_SUBST(LINTFLAGS)
 128
 129 dnl Check for various programs
 130 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
 131 AC_CHECK_PROGS(PKG_CONFIG, pkg-config, false)
 132
 133 case $host_cpu in
 134   *i[[3456789]]86*)
 135     AC_PATH_PROG(PRELINK, prelink, false, [/sbin /usr/sbin $PATH])
 136     ;;
 137 esac
 138
 139 dnl **** Check for some libraries ****
 140
 141 dnl Check for -li386 for NetBSD and OpenBSD
 142 AC_CHECK_LIB(i386,i386_set_ldt)
 143 dnl Check for -lossaudio for NetBSD
 144 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 145 dnl Check for -lxpg4 for FreeBSD
 146 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
 147 dnl Check for -lpthread
 148 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
 149
 150 AC_SUBST(XLIB,"")
 151 AC_SUBST(XFILES,"")
 152 AC_SUBST(OPENGLFILES,"")
 153 AC_SUBST(GLU32FILES,"")
 154 AC_SUBST(OPENGL_LIBS,"")
 155 AC_SUBST(QUARTZFILES,"")
 156
 157 dnl **** Check for header files ****
 158
 159 AC_CHECK_HEADERS(\
 160         AudioUnit/AudioUnit.h \
 161         Carbon/Carbon.h \
 162         CoreAudio/CoreAudio.h \
 163         DiskArbitration/DiskArbitration.h \
 164         IOKit/IOKitLib.h \
 165         alsa/asoundlib.h \
 166         arpa/inet.h \
 167         arpa/nameser.h \
 168         asm/types.h \
 169         capi20.h \
 170         cups/cups.h \
 171         curses.h \
 172         direct.h \
 173         dlfcn.h \
 174         elf.h \
 175         float.h \
 176         fontconfig/fontconfig.h \
 177         getopt.h \
 178         ieeefp.h \
 179         io.h \
 180         jack/jack.h \
 181         jpeglib.h \
 182         lber.h \
 183         lcms.h \
 184         lcms/lcms.h \
 185         ldap.h \
 186         libaudioio.h \
 187         link.h \
 188         linux/cdrom.h \
 189         linux/compiler.h \
 190         linux/hdreg.h \
 191         linux/input.h \
 192         linux/ioctl.h \
 193         linux/joystick.h \
 194         linux/major.h \
 195         linux/param.h \
 196         linux/serial.h \
 197         linux/ucdrom.h \
 198         mach/mach.h \
 199         mach/machine.h \
 200         machine/cpu.h \
 201         machine/limits.h \
 202         machine/soundcard.h \
 203         mntent.h \
 204         ncurses.h \
 205         netdb.h \
 206         netinet/in.h \
 207         netinet/in_systm.h \
 208         netinet/tcp.h \
 209         netinet/tcp_fsm.h \
 210         openssl/err.h \
 211         openssl/ssl.h \
 212         poll.h \
 213         process.h \
 214         pthread.h \
 215         pwd.h \
 216         regex.h \
 217         sched.h \
 218         scsi/scsi.h \
 219         scsi/scsi_ioctl.h \
 220         scsi/sg.h \
 221         soundcard.h \
 222         stdint.h \
 223         strings.h \
 224         sys/asoundlib.h \
 225         sys/cdio.h \
 226         sys/elf32.h \
 227         sys/epoll.h \
 228         sys/errno.h \
 229         sys/event.h \
 230         sys/exec_elf.h \
 231         sys/filio.h \
 232         sys/ioctl.h \
 233         sys/ipc.h \
 234         sys/limits.h \
 235         sys/link.h \
 236         sys/lwp.h \
 237         sys/mman.h \
 238         sys/modem.h \
 239         sys/msg.h \
 240         sys/mtio.h \
 241         sys/param.h \
 242         sys/poll.h \
 243         sys/prctl.h \
 244         sys/ptrace.h \
 245         sys/reg.h \
 246         sys/resource.h \
 247         sys/scsiio.h \
 248         sys/shm.h \
 249         sys/signal.h \
 250         sys/socket.h \
 251         sys/sockio.h \
 252         sys/soundcard.h \
 253         sys/statvfs.h \
 254         sys/strtio.h \
 255         sys/syscall.h \
 256         sys/sysctl.h \
 257         sys/time.h \
 258         sys/times.h \
 259         sys/uio.h \
 260         sys/un.h \
 261         sys/vm86.h \
 262         sys/wait.h \
 263         syscall.h \
 264         termios.h \
 265         unicode/ubidi.h \
 266         unistd.h \
 267         utime.h \
 268         valgrind/memcheck.h
 269 )
 270 AC_HEADER_STAT()
 271
 272 dnl **** Checks for headers that depend on other ones ****
 273
 274 AC_CHECK_HEADERS([sys/mount.h sys/statfs.h sys/user.h sys/vfs.h],,,
 275     [#include <sys/types.h>
 276      #if HAVE_SYS_PARAM_H
 277      # include <sys/param.h>
 278      #endif])
 279
 280 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h netipx/ipx.h],,,
 281     [#include <sys/types.h>
 282      #if HAVE_SYS_SOCKET_H
 283      # include <sys/socket.h>
 284      #endif])
 285
 286 AC_CHECK_HEADERS([linux/ipx.h],,,
 287     [#include <sys/types.h>
 288      #ifdef HAVE_ASM_TYPES_H
 289      # include <asm/types.h>
 290      #endif
 291      #if HAVE_SYS_SOCKET_H
 292      # include <sys/socket.h>
 293      #endif])
 294
 295 AC_CHECK_HEADERS([resolv.h],,,
 296     [#include <sys/types.h>
 297      #if HAVE_SYS_SOCKET_H
 298      # include <sys/socket.h>
 299      #endif
 300      #if HAVE_NETINET_IN_H
 301      # include <netinet/in.h>
 302      #endif
 303      #if HAVE_ARPA_NAMESER_H
 304      # include <arpa/nameser.h>
 305      #endif])
 306
 307 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
 308
 309 AC_CHECK_HEADERS([pthread_np.h],,,
 310 [#ifdef HAVE_PTHREAD_H
 311 #include <pthread.h>
 312 #endif])
 313
 314 AC_CHECK_HEADERS([linux/videodev.h],,,
 315 [#ifdef HAVE_SYS_TIME_H
 316 #include <sys/time.h>
 317 #endif
 318 #include <sys/types.h>
 319 #ifdef HAVE_ASM_TYPES_H
 320 #include <asm/types.h>
 321 #endif])
 322
 323 dnl Check for broken kernel header that doesn't define __user
 324 AC_CHECK_HEADERS([linux/capi.h],,,[#define __user])
 325
 326 dnl **** Check for X11 ****
 327
 328 if test "$have_x" = "yes"
 329 then
 330     XLIB="-lXext -lX11"
 331     ac_save_CPPFLAGS="$CPPFLAGS"
 332     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 333
 334     dnl *** All of the following tests require X11/Xlib.h
 335     AC_CHECK_HEADERS([X11/Xlib.h \
 336                       X11/XKBlib.h \
 337                       X11/Xutil.h \
 338                       X11/extensions/shape.h \
 339                       X11/extensions/XInput.h \
 340                       X11/extensions/XShm.h \
 341                       X11/extensions/Xinerama.h \
 342                       X11/extensions/Xrandr.h \
 343                       X11/extensions/Xrender.h \
 344                       X11/extensions/xf86vmode.h],,,
 345 [#ifdef HAVE_X11_XLIB_H
 346 # include <X11/Xlib.h>
 347 #endif
 348 #ifdef HAVE_X11_XUTIL_H
 349 # include <X11/Xutil.h>
 350 #endif])
 351
 352         dnl *** Check for X keyboard extension
 353         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 354         then
 355               AC_CHECK_LIB(X11, XkbQueryExtension,
 356               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 357               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 358         fi
 359
 360         dnl *** Check for X Shm extension
 361         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 362         then
 363               AC_CHECK_LIB(Xext, XShmQueryExtension,
 364               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 365               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 366         fi
 367
 368         dnl *** Check for X shape extension
 369         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 370         then
 371               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 372               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 373               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 374         fi
 375
 376         dnl *** Check for XFree86 VMODE extension
 377         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 378         then
 379                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 380                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 381                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 382                   ],,
 383                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 384         fi
 385
 386         dnl *** Check for X RandR extension
 387         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
 388         then
 389                 AC_TRY_COMPILE([#include <X11/Xlib.h>
 390 #include <X11/extensions/Xrandr.h>],[static typeof(XRRSetScreenConfigAndRate) * func;],
 391                   [AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])])
 392         fi
 393
 394         dnl *** Check for Transform functions in Xrender
 395         if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes"
 396         then
 397               AC_CHECK_LIB(Xrender, XRenderSetPictureTransform,
 398                 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
 399                  [Define if Xrender has the XRenderSetPictureTransform function])],,
 400                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 401         fi
 402
 403         dnl *** Check for Xinerama extension
 404         if test "$ac_cv_header_X11_extensions_Xinerama_h" = "yes"
 405         then
 406                 AC_TRY_COMPILE([#include <X11/Xlib.h>
 407 #include <X11/extensions/Xinerama.h>],[static typeof(XineramaQueryScreens) * func;],
 408                   [AC_DEFINE(HAVE_LIBXINERAMA, 1, [Define if you have the Xinerama library])])
 409         fi
 410
 411     dnl *** End of X11/Xlib.h check
 412
 413     dnl Check for the presence of OpenGL
 414     if test "x$with_opengl" != "xno"
 415     then
 416         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h GL/glu.h,,,
 417 [#ifdef HAVE_GL_GLX_H
 418 # include <GL/glx.h>
 419 #endif])
 420         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 421         then
 422             dnl Check for some problems due to old Mesa versions
 423             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_header_version_OK,
 424               AC_TRY_COMPILE(
 425                 [#include <GL/gl.h>],
 426                 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 427                 [wine_cv_opengl_header_version_OK="yes"],
 428                 [wine_cv_opengl_header_version_OK="no"]
 429               )
 430             )
 431
 432             if test "$wine_cv_opengl_header_version_OK" = "yes"
 433             then
 434                 dnl Check for the presence of the library
 435                 AC_CHECK_LIB(GL,glXCreateContext,
 436                              [OPENGL_LIBS="-lGL"
 437                              OPENGLFILES='$(OPENGLFILES)'
 438                              AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])]
 439                              ,,
 440                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 441
 442                 dnl Check for GLU32 library.
 443                 AC_CHECK_LIB(GLU,gluLookAt,
 444                              [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
 445                              GLU32FILES='$(GLU32FILES)']
 446                              ,,
 447                              $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
 448                 )
 449              fi
 450          else
 451              wine_cv_opengl_headers_found="no"
 452          fi
 453     fi
 454     dnl **** Check for NAS ****
 455     AC_SUBST(NASLIBS,"")
 456     AC_CHECK_HEADERS(audio/audiolib.h,
 457          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
 458           AC_CHECK_LIB(audio,AuCreateFlow,
 459                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
 460                         NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
 461                        [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 462
 463     CPPFLAGS="$ac_save_CPPFLAGS"
 464     XFILES='$(XFILES)'
 465 else
 466     XLIB=""
 467     X_CFLAGS=""
 468     X_LIBS=""
 469 fi
 470
 471 dnl **** Check for libxml2 ****
 472
 473 AC_SUBST(XML2LIBS,"")
 474 AC_SUBST(XML2INCL,"")
 475 AC_SUBST(XSLTLIBS,"")
 476 AC_SUBST(XSLTINCL,"")
 477 if test "$PKG_CONFIG" != "false"
 478 then
 479     ac_save_CPPFLAGS="$CPPFLAGS"
 480     ac_xml_libs="`$PKG_CONFIG --libs libxml-2.0 2>/dev/null`"
 481     ac_xml_cflags="`$PKG_CONFIG --cflags libxml-2.0 2>/dev/null`"
 482     CPPFLAGS="$CPPFLAGS $ac_xml_cflags"
 483     AC_CHECK_HEADERS(libxml/parser.h,
 484         [AC_CHECK_LIB(xml2, xmlParseMemory,
 485             [AC_DEFINE(HAVE_LIBXML2, 1, [Define if you have the libxml2 library])
 486              XML2LIBS="$ac_xml_libs"
 487              XML2INCL="$ac_xml_cflags"],,$ac_xml_libs)
 488          AC_CHECK_LIB(xml2, xmlReadMemory,
 489             [AC_DEFINE(HAVE_XMLREADMEMORY,1,[Define if libxml2 has the xmlReadMemory function])],,$ac_xml_libs)
 490          AC_CHECK_LIB(xml2, xmlNewDocPI,
 491             [AC_DEFINE(HAVE_XMLNEWDOCPI,1,[Define if libxml2 has the xmlNewDocPI function])],,$ac_xml_libs)
 492         ])
 493     CPPFLAGS="$ac_save_CPPFLAGS"
 494     ac_xslt_libs="`$PKG_CONFIG --libs libxslt 2>/dev/null`"
 495     ac_xslt_cflags="`$PKG_CONFIG --cflags libxslt 2>/dev/null`"
 496     CPPFLAGS="$CPPFLAGS $ac_xslt_cflags"
 497     AC_CHECK_HEADERS([libxslt/pattern.h libxslt/transform.h],
 498         [AC_CHECK_LIB(xslt, xsltCompilePattern,
 499             [AC_DEFINE(HAVE_LIBXSLT, 1, [Define if you have the libxslt library])
 500              XSLTLIBS="$ac_xslt_libs"
 501              XSLTINCL="$ac_xslt_cflags"],,$ac_xslt_libs)
 502         ],,
 503 [#ifdef HAVE_LIBXSLT_PATTERN_H
 504 # include <libxslt/pattern.h>
 505 #endif])
 506     CPPFLAGS="$ac_save_CPPFLAGS"
 507 fi
 508
 509 dnl **** Check for libhal ****
 510 AC_SUBST(HALINCL,"")
 511 if test "$PKG_CONFIG" != "false"
 512 then
 513     ac_save_CPPFLAGS="$CPPFLAGS"
 514     ac_hal_libs="`$PKG_CONFIG --libs hal 2>/dev/null`"
 515     ac_hal_cflags="`$PKG_CONFIG --cflags hal 2>/dev/null`"
 516     CPPFLAGS="$CPPFLAGS $ac_hal_cflags"
 517     AC_CHECK_HEADERS([dbus/dbus.h hal/libhal.h])
 518     if test "$ac_cv_header_dbus_dbus_h" = "yes" -a "$ac_cv_header_hal_libhal_h" = "yes"
 519     then
 520         AC_CHECK_LIB(hal, libhal_ctx_new,
 521           [AC_CHECK_LIB(dbus-1, dbus_connection_close,
 522             [AC_DEFINE(HAVE_LIBHAL, 1, [Define if you have the hal library])
 523              HALINCL="$ac_hal_cflags"],,$ac_hal_libs)])
 524     fi
 525     CPPFLAGS="$ac_save_CPPFLAGS"
 526 fi
 527
 528 dnl **** Check which curses lib to use ***
 529 CURSESLIBS=""
 530 if test "$ac_cv_header_ncurses_h" = "yes"
 531 then
 532     AC_CHECK_LIB(ncurses,waddch,[CURSESLIBS="-lncurses"])
 533 elif test "$ac_cv_header_curses_h" = "yes"
 534 then
 535     AC_CHECK_LIB(curses,waddch,[CURSESLIBS="-lcurses"])
 536 fi
 537 ac_save_LIBS="$LIBS"
 538 LIBS="$LIBS $CURSESLIBS"
 539 AC_CHECK_FUNCS(mousemask)
 540 LIBS="$ac_save_LIBS"
 541
 542 dnl **** Check for SANE ****
 543 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
 544 AC_SUBST(SANEINCL,"")
 545 if test "$sane_devel" != "no"
 546 then
 547     SANEINCL="`$sane_devel --cflags`"
 548     ac_save_CPPFLAGS="$CPPFLAGS"
 549     CPPFLAGS="$CPPFLAGS $SANEINCL"
 550     AC_CHECK_HEADER(sane/sane.h,
 551                     [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
 552                     [SANEINCL=""])
 553     CPPFLAGS="$ac_save_CPPFLAGS"
 554 fi
 555
 556 dnl **** Check for libgphoto2 ****
 557 AC_CHECK_PROG(gphoto2_devel,gphoto2-config,gphoto2-config,no)
 558 AC_CHECK_PROG(gphoto2port_devel,gphoto2-port-config,gphoto2-port-config,no)
 559 AC_SUBST(GPHOTO2LIBS,"")
 560 AC_SUBST(GPHOTO2INCL,"")
 561 if test "$gphoto2_devel" != "no" -a "$gphoto2port_devel" != "no"
 562 then
 563     GPHOTO2INCL="`$gphoto2_devel --cflags` `$gphoto2port_devel --cflags`"
 564     GPHOTO2LIBS=""
 565     for i in `$gphoto2_devel --libs` `$gphoto2port_devel --libs`
 566     do
 567       case "$i" in
 568         -L/usr/lib|-L/usr/lib64) ;;
 569         -L*|-l*) GPHOTO2LIBS="$GPHOTO2LIBS $i";;
 570       esac
 571     done
 572     ac_save_CPPFLAGS="$CPPFLAGS"
 573     ac_save_LIBS="$LIBS"
 574     CPPFLAGS="$CPPFLAGS $GPHOTO2INCL"
 575     LIBS="$LIBS $GPHOTO2LIBS"
 576     AC_CHECK_HEADER(gphoto2-camera.h,
 577                     [AC_CHECK_LIB(gphoto2,gp_camera_new,
 578                                   [AC_DEFINE(HAVE_GPHOTO2, 1, [Define if we have libgphoto2 development environment])],
 579                                   [GPHOTO2LIBS=""
 580                                   GPHOTO2INCL=""])],
 581                     [GPHOTO2LIBS=""
 582                     GPHOTO2INCL=""])
 583     LIBS="$ac_save_LIBS"
 584     CPPFLAGS="$ac_save_CPPFLAGS"
 585 fi
 586
 587 dnl **** Check for the ICU library ****
 588 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
 589 then
 590     saved_libs="$LIBS"
 591     for i in ${ICU_LIB_DIR-/usr/lib}/libsicu ${ICU_LIB_DIR-/usr/lib}/libicu
 592     do
 593         TEST_ICUUC_LIB="${ICUUC_LIB-${i}uc.a}"
 594         TEST_ICUDATA_LIB="${ICUDATA_LIB-${i}data.a}"
 595         AC_MSG_CHECKING(whether can link with ICU libraries $TEST_ICUUC_LIB and $TEST_ICUDATA_LIB)
 596         LIBS="$saved_libs $TEST_ICUUC_LIB $TEST_ICUDATA_LIB -lstdc++ -lgcc_s"
 597         AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
 598                     [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
 599                      AC_SUBST(ICULIBS,"$TEST_ICUUC_LIB $TEST_ICUDATA_LIB -lstdc++ -lgcc_s")
 600                      AC_MSG_RESULT(yes)],
 601                     [AC_MSG_RESULT(no)])
 602     done
 603     LIBS="$saved_libs"
 604 fi
 605
 606 dnl **** Check for resolver library ***
 607 AC_SUBST(RESOLVLIBS,"")
 608 if test "$ac_cv_header_resolv_h" = "yes"
 609 then
 610     AC_CHECK_LIB(resolv, res_query,
 611         [AC_DEFINE(HAVE_RESOLV, 1, [Define if you have the resolver library and header])
 612          RESOLVLIBS="-lresolv"])
 613 fi
 614
 615 dnl **** Check for LittleCMS ***
 616 AC_SUBST(LCMSLIBS,"")
 617 if test "$ac_cv_header_lcms_h" = "yes" -o "$ac_cv_header_lcms_lcms_h" = "yes"
 618 then
 619     AC_CHECK_LIB(lcms, cmsOpenProfileFromFile,
 620         [AC_DEFINE(HAVE_LCMS, 1, [Define if you have the LittleCMS development environment])
 621          LCMSLIBS="-llcms"])
 622 fi
 623
 624 dnl **** Check for OpenLDAP ***
 625 AC_SUBST(LDAPLIBS,"")
 626 if test "$ac_cv_header_ldap_h" = "yes" -a "$ac_cv_header_lber_h" = "yes"
 627 then
 628     AC_CHECK_LIB(ldap_r, ldap_initialize,
 629         [AC_CHECK_LIB(lber, ber_init,
 630             [AC_DEFINE(HAVE_LDAP, 1, [Define if you have the OpenLDAP development environment])
 631              LDAPLIBS="-lldap_r -llber"],,
 632              [$LIBPTHREAD])],,
 633              [$LIBPTHREAD])
 634     WINE_CHECK_LIB_FUNCS(\
 635         ldap_count_references \
 636         ldap_first_reference \
 637         ldap_next_reference \
 638         ldap_parse_reference,
 639         [$LDAPLIBS $LIBPTHREAD])
 640 fi
 641
 642 dnl **** Check for FreeType 2 ****
 643 AC_SUBST(FREETYPELIBS,"")
 644 AC_SUBST(FREETYPEINCL,"")
 645 AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
 646 if test "$ft_devel" = "no"
 647 then
 648     AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
 649     if test "$ft_devel2" = "freetype2-config"
 650     then
 651         ft_devel=$ft_devel2
 652     fi
 653 fi
 654
 655 if test "$ft_devel" = "no"
 656 then
 657     wine_cv_msg_freetype=yes
 658 else
 659     FREETYPELIBS=`$ft_devel --libs`
 660     FREETYPEINCL=`$ft_devel --cflags`
 661     AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$FREETYPELIBS)
 662     if test "$ft_lib" = "no"
 663     then
 664         wine_cv_msg_freetype=yes
 665         FREETYPELIBS=""
 666         FREETYPEINCL=""
 667     else
 668         ac_save_CPPFLAGS="$CPPFLAGS"
 669         CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
 670         AC_CHECK_HEADERS(ft2build.h \
 671                          freetype/freetype.h \
 672                          freetype/ftglyph.h \
 673                          freetype/tttables.h \
 674                          freetype/ftnames.h \
 675                          freetype/ftsnames.h \
 676                          freetype/ttnameid.h \
 677                          freetype/ftoutln.h \
 678                          freetype/ftwinfnt.h \
 679                          freetype/ftmodapi.h \
 680                          freetype/internal/sfnt.h,,,
 681                          [#if HAVE_FT2BUILD_H
 682                           #include <ft2build.h>
 683                           #endif])
 684         AC_TRY_CPP([#include <ft2build.h>
 685                     #include <freetype/fttrigon.h>],
 686                     [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
 687           [Define if you have the <freetype/fttrigon.h> header file.])
 688                     wine_cv_fttrigon=yes],
 689                     wine_cv_fttrigon=no)
 690         AC_CHECK_TYPES(FT_TrueTypeEngineType,,,[#include <freetype/ftmodapi.h>])
 691         ac_save_CFLAGS="$CFLAGS"
 692         CFLAGS="$CFLAGS $FREETYPELIBS"
 693         AC_CHECK_FUNCS(FT_Load_Sfnt_Table)
 694         CFLAGS="$ac_save_CFLAGS"
 695         CPPFLAGS="$ac_save_CPPFLAGS"
 696         dnl Check that we have at least freetype/freetype.h
 697         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
 698         then
 699             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
 700             wine_cv_msg_freetype=no
 701         else
 702             FREETYPELIBS=""
 703             FREETYPEINCL=""
 704             wine_cv_msg_freetype=yes
 705         fi
 706     fi
 707 fi
 708
 709 dnl Only build the fonts dir if we have both freetype and fontforge
 710 if test "$FONTFORGE" != "false" -a -n "$FREETYPELIBS"
 711 then
 712   AC_SUBST(FONTSSUBDIRS,"fonts")
 713 fi
 714
 715 dnl **** Check for parport (currently Linux only) ****
 716 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
 717  AC_TRY_COMPILE(
 718    [#include <linux/ppdev.h>],
 719    [ioctl (1,PPCLAIM,0)],
 720    [ac_cv_c_ppdev="yes"],
 721    [ac_cv_c_ppdev="no"])
 722  )
 723 if test "$ac_cv_c_ppdev" = "yes"
 724 then
 725     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
 726 fi
 727
 728 dnl **** Check for va_copy ****
 729 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
 730  AC_TRY_LINK(
 731    [#include <stdarg.h>],
 732    [va_list ap1, ap2;
 733     va_copy(ap1,ap2);
 734    ],
 735    [ac_cv_c_va_copy="yes"],
 736    [ac_cv_c_va_copy="no"])
 737  )
 738 if test "$ac_cv_c_va_copy" = "yes"
 739 then
 740     AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
 741 fi
 742 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
 743  AC_TRY_LINK(
 744    [#include <stdarg.h>],
 745    [va_list ap1, ap2;
 746     __va_copy(ap1,ap2);
 747    ],
 748    [ac_cv_c___va_copy="yes"],
 749    [ac_cv_c___va_copy="no"])
 750  )
 751 if test "$ac_cv_c___va_copy" = "yes"
 752 then
 753     AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
 754 fi
 755
 756 dnl **** Check for sigsetjmp ****
 757 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
 758  AC_TRY_LINK(
 759    [#include <setjmp.h>],
 760    [sigjmp_buf buf;
 761     sigsetjmp( buf, 1 );
 762     siglongjmp( buf, 1 );],
 763    [ac_cv_c_sigsetjmp="yes"],
 764    [ac_cv_c_sigsetjmp="no"])
 765  )
 766 if test "$ac_cv_c_sigsetjmp" = "yes"
 767 then
 768     AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
 769 fi
 770
 771 dnl **** Check for pthread_rwlock_t ****
 772 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
 773 #include <pthread.h>])
 774
 775 dnl **** Check for pthread functions ****
 776 WINE_CHECK_LIB_FUNCS(\
 777         pthread_attr_get_np \
 778         pthread_getattr_np \
 779         pthread_get_stackaddr_np \
 780         pthread_get_stacksize_np,
 781         [$LIBPTHREAD])
 782
 783 dnl **** Check for aRts Sound Server ****
 784 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
 785 if test x$ARTSCCONFIG != x -a x$ARTSCCONFIG != x'"$ARTSCCONFIG"';
 786 then
 787     ARTSC_CFLAGS=""
 788     for i in `$ARTSCCONFIG --cflags`
 789     do
 790       case "$i" in
 791         -I*) ARTSC_CFLAGS="$ARTSC_CFLAGS $i";;
 792       esac
 793     done
 794     ARTSC_LIBS=""
 795     for i in `$ARTSCCONFIG --libs`
 796     do
 797       case "$i" in
 798         -L/usr/lib|-L/usr/lib64) ;;
 799         -L*|-l*) ARTSC_LIBS="$ARTSC_LIBS $i";;
 800       esac
 801     done
 802     save_CFLAGS="$CFLAGS"
 803     CFLAGS="$CFLAGS $ARTSC_CFLAGS"
 804     AC_CHECK_LIB(artsc,arts_init,
 805         [AC_TRY_COMPILE([#include <artsc.h>],[arts_stream_t stream;],
 806             [AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
 807             AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
 808             AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])])],,
 809             $ARTSC_LIBS)
 810     CFLAGS="$save_CFLAGS"
 811 fi
 812
 813 dnl **** Check for EsounD ****
 814 AC_PATH_PROG(ESDCONFIG, esd-config)
 815 if test x$ESDCONFIG != x -a x$ESDCONFIG != x'"$ESDCONFIG"';
 816 then
 817     ESD_CFLAGS=""
 818     for i in `$ESDCONFIG --cflags`
 819     do
 820       case "$i" in
 821         -I*) ESD_CFLAGS="$ESD_CFLAGS $i";;
 822       esac
 823     done
 824     ESD_LIBS=`$ESDCONFIG --libs`
 825     save_CFLAGS="$CFLAGS"
 826     CFLAGS="$CFLAGS $ESD_CFLAGS"
 827     AC_CHECK_LIB(esd,esd_open_sound,
 828         [AC_SUBST(ESDLIBS, $ESD_LIBS)
 829          AC_SUBST(ESDINCL, $ESD_CFLAGS)
 830          AC_DEFINE(HAVE_ESD, 1, [Define if you have EsounD sound server])])
 831     CFLAGS="$save_CFLAGS"
 832 fi
 833
 834 dnl **** Check for ALSA 1.x ****
 835 AC_SUBST(ALSALIBS,"")
 836 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
 837 then
 838     AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
 839         [AC_TRY_COMPILE([#ifdef HAVE_ALSA_ASOUNDLIB_H
 840 #include <alsa/asoundlib.h>
 841 #elif defined(HAVE_SYS_ASOUNDLIB_H)
 842 #include <sys/asoundlib.h>
 843 #endif],
 844                         [int ret = snd_pcm_hw_params_get_access(NULL, NULL)],
 845                         [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
 846                          ALSALIBS="-lasound"])])
 847 fi
 848
 849 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
 850
 851 AC_SUBST(AUDIOIOLIBS,"")
 852 if test "$ac_cv_header_libaudioio_h" = "yes"
 853 then
 854     AC_CHECK_LIB(audioio,AudioIOGetVersion,
 855                   [AUDIOIOLIBS="-laudioio"
 856                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])
 857 fi
 858
 859 dnl **** Check for capi4linux ****
 860
 861 if test "$ac_cv_header_capi20_h" = "yes" -a "$ac_cv_header_linux_capi_h" = "yes"
 862 then
 863     AC_CHECK_LIB(capi20,capi20_register,[AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])])
 864 fi
 865
 866 dnl **** Check for gcc specific options ****
 867
 868 AC_SUBST(EXTRACFLAGS,"")
 869 if test "x${GCC}" = "xyes"
 870 then
 871   EXTRACFLAGS="-Wall -pipe"
 872
 873   dnl Check for strength-reduce bug
 874   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
 875                   AC_TRY_RUN([
 876 int     L[[4]] = {0,1,2,3};
 877 int main(void) {
 878   static int Array[[3]];
 879   unsigned int B = 3;
 880   int i;
 881   for(i=0; i<B; i++) Array[[i]] = i - 3;
 882   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
 883   L[[i]] = 4;
 884
 885   exit( Array[[1]] != -2 || L[[2]] != 3);
 886 }],
 887     ac_cv_c_gcc_strength_bug="no",
 888     ac_cv_c_gcc_strength_bug="yes",
 889     ac_cv_c_gcc_strength_bug="yes") )
 890   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 891   then
 892     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
 893   fi
 894
 895   dnl Check for some compiler flags
 896
 897   WINE_TRY_CFLAGS([-fshort-wchar],
 898                   [AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar",
 899                              [Specifies the compiler flag that forces a short wchar_t])])
 900   WINE_TRY_CFLAGS([-fno-strict-aliasing])
 901   WINE_TRY_CFLAGS([-Wdeclaration-after-statement])
 902   WINE_TRY_CFLAGS([-Wwrite-strings])
 903
 904   dnl Check for noisy string.h
 905   saved_CFLAGS="$CFLAGS"
 906   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
 907   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
 908       AC_TRY_COMPILE([#include <string.h>],[],
 909                      [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
 910   CFLAGS="$saved_CFLAGS"
 911   if test "$ac_cv_c_string_h_warnings" = "no"
 912   then
 913     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
 914   fi
 915
 916   AC_SUBST(BUILTINFLAG,"")
 917   saved_CFLAGS="$CFLAGS"
 918   CFLAGS="$CFLAGS -Werror"
 919   AC_CACHE_CHECK([for builtin wchar inlines], ac_cv_c_builtin_wchar_ctype,
 920       AC_TRY_COMPILE([],
 921                      [int iswlower(unsigned short);],
 922                      [ac_cv_c_builtin_wchar_ctype=no],[ac_cv_c_builtin_wchar_ctype=yes]))
 923   CFLAGS="$saved_CFLAGS"
 924   if test "$ac_cv_c_builtin_wchar_ctype" = "yes"
 925   then
 926     BUILTINFLAG="-fno-builtin"
 927   fi
 928 fi
 929
 930 dnl **** Check how to define a function in assembly code ****
 931
 932 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
 933   WINE_TRY_ASM_LINK(
 934       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
 935       ac_cv_asm_func_def=".def",
 936     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
 937       ac_cv_asm_func_def=".type @function",
 938     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
 939       ac_cv_asm_func_def=".type 2",
 940       ac_cv_asm_func_def="unknown")])]))
 941
 942 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
 943 case "$ac_cv_asm_func_def" in
 944   ".def")
 945      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
 946   ".type @function")
 947      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
 948   ".type 2")
 949      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
 950   *)
 951      AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
 952 esac
 953
 954 dnl **** Check for underscore on external symbols ****
 955
 956 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
 957     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
 958                       [extern int ac_test;],
 959                       [if (ac_test) return 1],
 960                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
 961
 962 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
 963 if test "$ac_cv_c_extern_prefix" = "yes"
 964 then
 965   AC_DEFINE([__ASM_NAME(name)], ["_" name])
 966 else
 967   AC_DEFINE([__ASM_NAME(name)], [name])
 968 fi
 969
 970 dnl **** Check for working dll ****
 971
 972 AC_SUBST(DLLEXT,"")
 973 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 974 AC_SUBST(LDSHARED,"")
 975 AC_SUBST(LDDLLFLAGS,"")
 976 AC_SUBST(LIBEXT,"so")
 977 AC_SUBST(IMPLIBEXT,"def")
 978 AC_SUBST(LIBWINE_LDFLAGS,"")
 979
 980 case $host_os in
 981   cygwin*|mingw32*)
 982     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 983     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 984     AC_CHECK_TOOL(MINGWAR,ar,false)
 985     if test "$DLLWRAP" = "false"; then
 986       LIBEXT="a"
 987     else
 988       dnl FIXME - check whether dllwrap works correctly...
 989       LIBEXT="dll"
 990     fi
 991     IMPLIBEXT="a"
 992     dnl We can't build 16-bit NE dlls
 993     WIN16_FILES=""
 994     WIN16_INSTALL=""
 995     ;;
 996   darwin*|macosx*)
 997     DLLEXT=".so"
 998     LIBEXT="dylib"
 999     DLLFLAGS="$DLLFLAGS -fPIC"
1000     LDDLLFLAGS="-bundle -multiply_defined suppress"
1001     LIBWINE_LDFLAGS="-multiply_defined suppress"
1002     LDSHARED="\$(CC) -dynamiclib -install_name @executable_path/\`\$(RELPATH) \$(bindir) \$(libdir)\`/\$(DYNAME)"
1003     STRIP="$STRIP -u -r"
1004     dnl declare needed frameworks
1005     AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
1006     AC_SUBST(IOKITLIB,"-framework IOKit -framework CoreFoundation")
1007     AC_SUBST(LDEXECFLAGS,["-image_base 0x7bf00000 -Wl,-segaddr,WINE_DOS,0x00000000,-segaddr,WINE_SHARED_HEAP,0x7f000000"])
1008     if test "$ac_cv_header_DiskArbitration_DiskArbitration_h" = "yes"
1009     then
1010         dnl DiskArbitration API is not public on Darwin < 8.0, use it only if header found
1011         AC_SUBST(DISKARBITRATIONLIB,"-framework DiskArbitration -framework CoreFoundation")
1012     fi
1013     if test "$ac_cv_header_CoreAudio_CoreAudio_h" = "yes" -a "$ac_cv_header_AudioUnit_AudioUnit_h" = "yes"
1014     then
1015         dnl CoreServices needed by AudioUnit
1016         AC_SUBST(COREAUDIO,"-framework CoreAudio -framework AudioUnit -framework CoreServices")
1017     fi
1018     case $host_cpu in
1019       *powerpc*)
1020         LDDLLFLAGS="$LDDLLFLAGS -read_only_relocs warning"  dnl FIXME
1021         ;;
1022     esac
1023     dnl Enable quartz driver on Mac OS X
1024     if test "$ac_cv_header_Carbon_Carbon_h" = "yes"
1025     then
1026         AC_SUBST(CARBONLIB,"-framework Carbon")
1027         QUARTZFILES='$(QUARTZFILES)'
1028     fi
1029     ;;
1030   *)
1031     DLLFLAGS="$DLLFLAGS -fPIC"
1032     DLLEXT=".so"
1033     AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
1034         [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-Bsymbolic],
1035                               ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
1036     if test "$ac_cv_c_dll_gnuelf" = "yes"
1037     then
1038       LDSHARED="\$(CC) -shared"
1039       LDDLLFLAGS="-shared -Wl,-Bsymbolic"
1040       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,confest.so.1],
1041                       [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"],
1042                       [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-h,confest.so.1],
1043                                        [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-h,%)"])])
1044
1045       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs], [LDDLLFLAGS="$LDDLLFLAGS,-z,defs"])
1046
1047       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
1048                       [LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"])
1049
1050       echo '{ global: *; };' >conftest.map
1051       WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
1052                       [LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"])
1053       rm -f conftest.map
1054
1055       WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
1056                       [AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])])
1057
1058       WINE_TRY_CFLAGS([-fPIC -Wl,--rpath,\$ORIGIN/../lib],
1059                       [LIBWINE_LDFLAGS="-Wl,--rpath,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"])
1060
1061       case $host_cpu in
1062         *i[[3456789]]86* | x86_64)
1063           WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
1064                           [LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400"])
1065           ;;
1066       esac
1067
1068     else
1069       AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
1070           [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
1071                                 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
1072       if test "$ac_cv_c_dll_unixware" = "yes"
1073       then
1074         LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
1075         LDDLLFLAGS="-Wl,-G,-B,symbolic"
1076
1077       else
1078         AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
1079           [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
1080         if test "$ac_cv_c_dll_hpux" = "yes"
1081         then
1082           LIBEXT="sl"
1083           DLLEXT=".sl"
1084           LDDLLFLAGS="-shared -fPIC"
1085           LDSHARED="\$(CC) -shared"
1086         fi
1087       fi
1088     fi
1089
1090     dnl Check for cross compiler to build test programs
1091     AC_SUBST(CROSSTEST,"")
1092     if test "$cross_compiling" = "no"
1093     then
1094       WINE_CHECK_MINGW_PROG(CROSSCC,gcc,false)
1095       WINE_CHECK_MINGW_PROG(DLLTOOL,dlltool,false)
1096       WINE_CHECK_MINGW_PROG(CROSSWINDRES,windres,false)
1097       WINE_CHECK_MINGW_PROG(MINGWAR,ar,false)
1098       if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
1099     fi
1100     ;;
1101 esac
1102
1103 if test "$LIBEXT" = "a"; then
1104   AC_MSG_ERROR(
1105 [could not find a way to build shared libraries.
1106 It is currently not possible to build Wine without shared library
1107 (.so) support to allow transparent switch between .so and .dll files.
1108 If you are using Linux, you will need a newer binutils.]
1109 )
1110 fi
1111
1112 case $build_os in
1113   cygwin*|mingw32*)
1114     AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/wine:\$\$PATH\"") ;;
1115   darwin*|macosx*)
1116     AC_SUBST(LDPATH,"DYLD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$DYLD_LIBRARY_PATH\"") ;;
1117   *)
1118     AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\"") ;;
1119 esac
1120
1121 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1122 case $host_os in
1123   mingw32*)
1124     AC_SUBST(CRTLIBS,"-lmsvcrt")
1125     AC_SUBST(SOCKETLIBS,"-lws2_32")
1126     ;;
1127 esac
1128
1129 AC_SUBST(MAIN_BINARY,"wine-pthread")  dnl Default value
1130 case $host_cpu in
1131   *i[[3456789]]86*)
1132     case $host_os in
1133       linux* | k*bsd*-gnu)
1134         AC_SUBST(MAIN_BINARY,"wine-glibc")
1135         AC_SUBST(EXTRA_BINARIES,"wine-kthread wine-pthread wine-preloader") ;;
1136     esac
1137     ;;
1138 esac
1139
1140 dnl **** Get the soname for libraries that we load dynamically ****
1141
1142 if test "$LIBEXT" = "so" -o "$LIBEXT" = "dylib"
1143 then
1144   WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
1145   WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1146   WINE_GET_SONAME(Xi,XOpenDevice,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1147   WINE_GET_SONAME(Xinerama,XineramaQueryScreens,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1148   WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1149   WINE_GET_SONAME(Xrandr,XRRQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1150   WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
1151   WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
1152   WINE_GET_SONAME(hal,libhal_ctx_new)
1153   WINE_GET_SONAME(txc_dxtn,fetch_2d_texel_rgba_dxt1)
1154   WINE_GET_SONAME(cups,cupsGetDefault)
1155   WINE_GET_SONAME(jack,jack_client_new)
1156   WINE_GET_SONAME(fontconfig,FcInit)
1157   WINE_GET_SONAME(ssl,SSL_library_init)
1158   WINE_GET_SONAME(crypto,BIO_new_socket)
1159   WINE_GET_SONAME(ncurses,waddch)
1160   WINE_GET_SONAME(curses,waddch)
1161   WINE_GET_SONAME(jpeg,jpeg_start_decompress)
1162   WINE_GET_SONAME(capi20,capi20_isinstalled)
1163   WINE_GET_SONAME(sane,sane_init)
1164 fi
1165
1166
1167 dnl **** Check for functions ****
1168
1169 AC_CHECK_FUNCS(\
1170         _pclose \
1171         _popen \
1172         _snprintf \
1173         _spawnvp \
1174         _stricmp \
1175         _strnicmp \
1176         _vsnprintf \
1177         asctime_r \
1178         chsize \
1179         clone \
1180         connect \
1181         dlopen \
1182         epoll_create \
1183         ffs \
1184         finite \
1185         fork \
1186         fpclass \
1187         fstatfs \
1188         fstatvfs \
1189         ftruncate \
1190         futimes \
1191         futimesat \
1192         getaddrinfo \
1193         getdirentries \
1194         gethostbyname \
1195         getnameinfo \
1196         getnetbyname \
1197         getopt_long \
1198         getpagesize \
1199         getprotobyname \
1200         getprotobynumber \
1201         getpwuid \
1202         getservbyport \
1203         gettid \
1204         gettimeofday \
1205         getuid \
1206         inet_aton \
1207         inet_network \
1208         kqueue \
1209         lstat \
1210         memmove \
1211         mmap \
1212         pclose \
1213         poll \
1214         popen \
1215         prctl \
1216         pread \
1217         pwrite \
1218         readlink \
1219         rfork \
1220         sched_yield \
1221         select \
1222         sendmsg \
1223         setrlimit \
1224         settimeofday \
1225         sigaltstack \
1226         sigprocmask \
1227         snprintf \
1228         spawnvp \
1229         statfs \
1230         statvfs \
1231         strcasecmp \
1232         strerror \
1233         strncasecmp \
1234         strtold \
1235         tcgetattr \
1236         timegm \
1237         usleep \
1238         vsnprintf \
1239         wait4 \
1240         waitpid \
1241 )
1242
1243 dnl Check for -ldl
1244 if test "$ac_cv_func_dlopen" = no
1245 then
1246     AC_CHECK_LIB(dl,dlopen,[AC_DEFINE(HAVE_DLOPEN,1) AC_SUBST(LIBDL,"-ldl")])
1247 fi
1248 WINE_CHECK_LIB_FUNCS(dladdr,[$LIBDL])
1249
1250 dnl Check for -lpoll for Mac OS X/Darwin
1251 if test "$ac_cv_func_poll" = no
1252 then
1253     AC_CHECK_LIB(poll,poll,[AC_DEFINE(HAVE_POLL,1) AC_SUBST(LIBPOLL,"-lpoll")])
1254 fi
1255
1256 dnl Check for -lnsl for Solaris
1257 if test "$ac_cv_func_gethostbyname" = no
1258 then
1259     AC_CHECK_LIB(nsl,gethostbyname)
1260 fi
1261
1262 dnl Check for -lsocket for Solaris
1263 if test "$ac_cv_func_connect" = no
1264 then
1265     AC_CHECK_LIB(socket,connect)
1266 fi
1267
1268 dnl Check for -lresolv for Solaris
1269 if test "$ac_cv_func_inet_aton" = no
1270 then
1271     AC_CHECK_LIB(resolv,inet_aton)
1272 fi
1273
1274 dnl **** Check for types ****
1275
1276 AC_C_CONST
1277 AC_C_INLINE
1278 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1279 AC_CHECK_TYPES([sigset_t],,,[#include <signal.h>])
1280 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
1281
1282 AC_CHECK_MEMBERS([struct ff_effect.direction],,,
1283 [#ifdef HAVE_LINUX_INPUT_H
1284 #include <linux/input.h>
1285 #endif])
1286
1287 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
1288                AC_TRY_LINK([#include <signal.h>],[sigset_t set; sigaddset(&set,SIGTERM);],
1289                            wine_cv_have_sigaddset=yes,wine_cv_have_sigaddset=no))
1290 if test "$wine_cv_have_sigaddset" = "yes"
1291 then
1292   AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
1293 fi
1294
1295
1296 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1297         wine_cv_linux_gethostbyname_r_6,
1298         AC_TRY_LINK([
1299 #include <netdb.h>
1300         ], [
1301     char *name=NULL;
1302     struct hostent he;
1303     struct hostent *result;
1304     char *buf=NULL;
1305     int bufsize=0;
1306     int res,errnr;
1307     char *addr=NULL;
1308     int addrlen=0;
1309     int addrtype=0;
1310     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1311     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1312     ],
1313         wine_cv_linux_gethostbyname_r_6=yes,
1314         wine_cv_linux_gethostbyname_r_6=no
1315         )
1316    )
1317    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1318    then
1319       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1320                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1321    fi
1322
1323 if test "$ac_cv_header_linux_joystick_h" = "yes"
1324 then
1325    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1326         wine_cv_linux_joystick_22_api,
1327         AC_TRY_COMPILE([
1328         #include <sys/ioctl.h>
1329         #include <linux/joystick.h>
1330
1331         struct js_event blub;
1332         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1333         #error "no 2.2 header"
1334         #endif
1335         ],/*empty*/,
1336         wine_cv_linux_joystick_22_api=yes,
1337         wine_cv_linux_joystick_22_api=no,
1338         wine_cv_linux_joystick_22_api=no
1339         )
1340    )
1341    if test "$wine_cv_linux_joystick_22_api" = "yes"
1342    then
1343       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1344                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1345    fi
1346 fi
1347
1348 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1349
1350 dnl Check for statfs members
1351 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1352 [#include <sys/types.h>
1353 #ifdef HAVE_SYS_PARAM_H
1354 # include <sys/param.h>
1355 #endif
1356 #ifdef HAVE_SYS_MOUNT_H
1357 # include <sys/mount.h>
1358 #endif
1359 #ifdef HAVE_SYS_VFS_H
1360 # include <sys/vfs.h>
1361 #endif
1362 #ifdef HAVE_SYS_STATFS_H
1363 # include <sys/statfs.h>
1364 #endif])
1365
1366 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1367 [#ifdef HAVE_SYS_STATVFS_H
1368 #include <sys/statvfs.h>
1369 #endif])
1370
1371 dnl Check for socket structure members
1372 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1373 [#include <sys/types.h>
1374 #ifdef HAVE_SYS_SOCKET_H
1375 # include <sys/socket.h>
1376 #endif
1377 #ifdef HAVE_SYS_UN_H
1378 # include <sys/un.h>
1379 #endif])
1380
1381 dnl Check for scsireq_t and sg_io_hdr_t members
1382 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
1383 [#include <sys/types.h>
1384 #ifdef HAVE_SCSI_SG_H
1385 #include <scsi/sg.h>
1386 #endif])
1387
1388 dnl Check for siginfo_t members
1389 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1390
1391 dnl Check for struct mtget members
1392 AC_CHECK_MEMBERS([struct mtget.mt_blksiz, struct mtget.mt_gstat, struct mtget.mt_blkno],,,
1393 [#include <sys/types.h>
1394 #ifdef HAVE_SYS_MTIO_H
1395 #include <sys/mtio.h>
1396 #endif])
1397
1398 dnl Check for struct option
1399 AC_CHECK_MEMBERS([struct option.name],,,
1400 [#ifdef HAVE_GETOPT_H
1401 #include <getopt.h>
1402 #endif])
1403
1404 dnl Check for stat.st_blocks
1405 AC_CHECK_MEMBERS([struct stat.st_blocks])
1406
1407 dnl Check for sin6_scope_id
1408 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_scope_id],,,
1409 [#ifdef HAVE_SYS_TYPES_H
1410 #include <sys/types.h>
1411 #endif
1412 #ifdef HAVE_NETINET_IN_H
1413 #include <netinet/in.h>
1414 #endif])
1415
1416 dnl Check for ns_msg ptr member
1417 AC_CHECK_MEMBERS([ns_msg._msg_ptr],,,
1418 [#ifdef HAVE_SYS_TYPES_H
1419 #include <sys/types.h>
1420 #endif
1421 #ifdef HAVE_NETINET_IN_H
1422 # include <netinet/in.h>
1423 #endif
1424 #ifdef HAVE_ARPA_NAMESER_H
1425 # include <arpa/nameser.h>
1426 #endif])
1427
1428 dnl Check for the external timezone variables timezone and daylight
1429 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
1430                AC_TRY_LINK([#include <time.h>],[timezone = 1],
1431                            ac_cv_have_timezone="yes", ac_cv_have_timezone="no"))
1432 if test "$ac_cv_have_timezone" = "yes"
1433 then
1434     AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
1435 fi
1436 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
1437                AC_TRY_LINK([#include <time.h>],[daylight = 1],
1438                            ac_cv_have_daylight="yes", ac_cv_have_daylight="no"))
1439 if test "$ac_cv_have_daylight" = "yes"
1440 then
1441     AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
1442 fi
1443
1444 dnl *** check for the need to define platform-specific symbols
1445
1446 case $host_cpu in
1447   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1448   *x86_64*)         WINE_CHECK_DEFINE([__x86_64__]) ;;
1449   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
1450   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
1451   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
1452 esac
1453
1454 case $host_vendor in
1455   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1456 esac
1457
1458 dnl **** Generate output files ****
1459
1460 dnl autoconf versions before 2.59d need backslashes to escape newlines in subst variables
1461 AC_SUBST(DEPENDENCIES,m4_if(m4_version_compare(m4_defn([m4_PACKAGE_VERSION]), [2.59d]), -1,
1462 ["### Dependencies:\\
1463 \\
1464 .INIT: Makefile\\
1465 .BEGIN: Makefile\\
1466 Makefile: dummy\\
1467         -\$(MAKEDEP) -C\$(SRCDIR) -S\$(TOPSRCDIR) -T\$(TOPOBJDIR) \$(EXTRAINCL) \$(DEPEND_SRCS)\\
1468 \\
1469 \$(OBJS): \$(IDL_GEN_HEADERS)\\
1470 \$(IDL_GEN_C_SRCS:.c=.o): \$(IDL_GEN_C_SRCS)\\
1471 \$(LEX_SRCS:.l=.yy.o): \$(LEX_SRCS:.l=.yy.c)\\
1472 \$(BISON_SRCS:.y=.tab.o): \$(BISON_SRCS:.y=.tab.c)"],
1473 ["### Dependencies:
1474
1475 .INIT: Makefile
1476 .BEGIN: Makefile
1477 Makefile: dummy
1478         -\$(MAKEDEP) -C\$(SRCDIR) -S\$(TOPSRCDIR) -T\$(TOPOBJDIR) \$(EXTRAINCL) \$(DEPEND_SRCS)
1479
1480 \$(OBJS): \$(IDL_GEN_HEADERS)
1481 \$(IDL_GEN_C_SRCS:.c=.o): \$(IDL_GEN_C_SRCS)
1482 \$(LEX_SRCS:.l=.yy.o): \$(LEX_SRCS:.l=.yy.c)
1483 \$(BISON_SRCS:.y=.tab.o): \$(BISON_SRCS:.y=.tab.c)"]))
1484
1485 AH_TOP([#define __WINE_CONFIG_H])
1486
1487 AC_CONFIG_COMMANDS([include/stamp-h], [echo timestamp > include/stamp-h])
1488
1489 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/enhmfdrv)
1490 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/mfdrv)
1491 WINE_CONFIG_EXTRA_DIR(dlls/kernel32/nls)
1492 WINE_CONFIG_EXTRA_DIR(dlls/user32/resources)
1493 WINE_CONFIG_EXTRA_DIR(dlls/wineps.drv/data)
1494 WINE_CONFIG_EXTRA_DIR(include/wine)
1495
1496 MAKE_RULES=Make.rules
1497 AC_SUBST_FILE(MAKE_RULES)
1498
1499 MAKE_DLL_RULES=dlls/Makedll.rules
1500 AC_SUBST_FILE(MAKE_DLL_RULES)
1501
1502 MAKE_IMPLIB_RULES=dlls/Makeimplib.rules
1503 AC_SUBST_FILE(MAKE_IMPLIB_RULES)
1504
1505 MAKE_TEST_RULES=dlls/Maketest.rules
1506 AC_SUBST_FILE(MAKE_TEST_RULES)
1507
1508 MAKE_PROG_RULES=programs/Makeprog.rules
1509 AC_SUBST_FILE(MAKE_PROG_RULES)
1510
1511 AC_CONFIG_FILES([Make.rules])
1512 AC_CONFIG_FILES([dlls/Makedll.rules])
1513 AC_CONFIG_FILES([dlls/Makeimplib.rules])
1514 AC_CONFIG_FILES([dlls/Maketest.rules])
1515 AC_CONFIG_FILES([programs/Makeprog.rules])
1516 AC_CONFIG_FILES([Makefile])
1517 AC_CONFIG_FILES([dlls/Makefile])
1518 AC_CONFIG_FILES([dlls/activeds/Makefile])
1519 AC_CONFIG_FILES([dlls/advapi32/Makefile])
1520 AC_CONFIG_FILES([dlls/advapi32/tests/Makefile])
1521 AC_CONFIG_FILES([dlls/advpack/Makefile])
1522 AC_CONFIG_FILES([dlls/advpack/tests/Makefile])
1523 AC_CONFIG_FILES([dlls/amstream/Makefile])
1524 AC_CONFIG_FILES([dlls/atl/Makefile])
1525 AC_CONFIG_FILES([dlls/avicap32/Makefile])
1526 AC_CONFIG_FILES([dlls/avifil32/Makefile])
1527 AC_CONFIG_FILES([dlls/browseui/Makefile])
1528 AC_CONFIG_FILES([dlls/browseui/tests/Makefile])
1529 AC_CONFIG_FILES([dlls/cabinet/Makefile])
1530 AC_CONFIG_FILES([dlls/cabinet/tests/Makefile])
1531 AC_CONFIG_FILES([dlls/capi2032/Makefile])
1532 AC_CONFIG_FILES([dlls/cards/Makefile])
1533 AC_CONFIG_FILES([dlls/cfgmgr32/Makefile])
1534 AC_CONFIG_FILES([dlls/clusapi/Makefile])
1535 AC_CONFIG_FILES([dlls/comcat/Makefile])
1536 AC_CONFIG_FILES([dlls/comcat/tests/Makefile])
1537 AC_CONFIG_FILES([dlls/comctl32/Makefile])
1538 AC_CONFIG_FILES([dlls/comctl32/tests/Makefile])
1539 AC_CONFIG_FILES([dlls/comdlg32/Makefile])
1540 AC_CONFIG_FILES([dlls/comdlg32/tests/Makefile])
1541 AC_CONFIG_FILES([dlls/compstui/Makefile])
1542 AC_CONFIG_FILES([dlls/credui/Makefile])
1543 AC_CONFIG_FILES([dlls/crtdll/Makefile])
1544 AC_CONFIG_FILES([dlls/crypt32/Makefile])
1545 AC_CONFIG_FILES([dlls/crypt32/tests/Makefile])
1546 AC_CONFIG_FILES([dlls/cryptdll/Makefile])
1547 AC_CONFIG_FILES([dlls/cryptnet/Makefile])
1548 AC_CONFIG_FILES([dlls/ctl3d32/Makefile])
1549 AC_CONFIG_FILES([dlls/d3d8/Makefile])
1550 AC_CONFIG_FILES([dlls/d3d8/tests/Makefile])
1551 AC_CONFIG_FILES([dlls/d3d9/Makefile])
1552 AC_CONFIG_FILES([dlls/d3d9/tests/Makefile])
1553 AC_CONFIG_FILES([dlls/d3dim/Makefile])
1554 AC_CONFIG_FILES([dlls/d3drm/Makefile])
1555 AC_CONFIG_FILES([dlls/d3dx8/Makefile])
1556 AC_CONFIG_FILES([dlls/d3dxof/Makefile])
1557 AC_CONFIG_FILES([dlls/dbghelp/Makefile])
1558 AC_CONFIG_FILES([dlls/dciman32/Makefile])
1559 AC_CONFIG_FILES([dlls/ddraw/Makefile])
1560 AC_CONFIG_FILES([dlls/ddraw/tests/Makefile])
1561 AC_CONFIG_FILES([dlls/ddrawex/Makefile])
1562 AC_CONFIG_FILES([dlls/devenum/Makefile])
1563 AC_CONFIG_FILES([dlls/dinput/Makefile])
1564 AC_CONFIG_FILES([dlls/dinput/tests/Makefile])
1565 AC_CONFIG_FILES([dlls/dinput8/Makefile])
1566 AC_CONFIG_FILES([dlls/dmband/Makefile])
1567 AC_CONFIG_FILES([dlls/dmcompos/Makefile])
1568 AC_CONFIG_FILES([dlls/dmime/Makefile])
1569 AC_CONFIG_FILES([dlls/dmloader/Makefile])
1570 AC_CONFIG_FILES([dlls/dmscript/Makefile])
1571 AC_CONFIG_FILES([dlls/dmstyle/Makefile])
1572 AC_CONFIG_FILES([dlls/dmsynth/Makefile])
1573 AC_CONFIG_FILES([dlls/dmusic/Makefile])
1574 AC_CONFIG_FILES([dlls/dmusic32/Makefile])
1575 AC_CONFIG_FILES([dlls/dnsapi/Makefile])
1576 AC_CONFIG_FILES([dlls/dnsapi/tests/Makefile])
1577 AC_CONFIG_FILES([dlls/dplay/Makefile])
1578 AC_CONFIG_FILES([dlls/dplayx/Makefile])
1579 AC_CONFIG_FILES([dlls/dplayx/tests/Makefile])
1580 AC_CONFIG_FILES([dlls/dpnaddr/Makefile])
1581 AC_CONFIG_FILES([dlls/dpnet/Makefile])
1582 AC_CONFIG_FILES([dlls/dpnhpast/Makefile])
1583 AC_CONFIG_FILES([dlls/dsound/Makefile])
1584 AC_CONFIG_FILES([dlls/dsound/tests/Makefile])
1585 AC_CONFIG_FILES([dlls/dswave/Makefile])
1586 AC_CONFIG_FILES([dlls/dxdiagn/Makefile])
1587 AC_CONFIG_FILES([dlls/dxerr8/Makefile])
1588 AC_CONFIG_FILES([dlls/dxerr9/Makefile])
1589 AC_CONFIG_FILES([dlls/dxguid/Makefile])
1590 AC_CONFIG_FILES([dlls/gdi32/Makefile])
1591 AC_CONFIG_FILES([dlls/gdi32/tests/Makefile])
1592 AC_CONFIG_FILES([dlls/glu32/Makefile])
1593 AC_CONFIG_FILES([dlls/gphoto2.ds/Makefile])
1594 AC_CONFIG_FILES([dlls/hhctrl.ocx/Makefile])
1595 AC_CONFIG_FILES([dlls/hid/Makefile])
1596 AC_CONFIG_FILES([dlls/hlink/Makefile])
1597 AC_CONFIG_FILES([dlls/hlink/tests/Makefile])
1598 AC_CONFIG_FILES([dlls/iccvid/Makefile])
1599 AC_CONFIG_FILES([dlls/icmp/Makefile])
1600 AC_CONFIG_FILES([dlls/ifsmgr.vxd/Makefile])
1601 AC_CONFIG_FILES([dlls/imaadp32.acm/Makefile])
1602 AC_CONFIG_FILES([dlls/imagehlp/Makefile])
1603 AC_CONFIG_FILES([dlls/imm32/Makefile])
1604 AC_CONFIG_FILES([dlls/infosoft/Makefile])
1605 AC_CONFIG_FILES([dlls/infosoft/tests/Makefile])
1606 AC_CONFIG_FILES([dlls/inseng/Makefile])
1607 AC_CONFIG_FILES([dlls/iphlpapi/Makefile])
1608 AC_CONFIG_FILES([dlls/iphlpapi/tests/Makefile])
1609 AC_CONFIG_FILES([dlls/itss/Makefile])
1610 AC_CONFIG_FILES([dlls/itss/tests/Makefile])
1611 AC_CONFIG_FILES([dlls/kernel32/Makefile])
1612 AC_CONFIG_FILES([dlls/kernel32/tests/Makefile])
1613 AC_CONFIG_FILES([dlls/localspl/Makefile])
1614 AC_CONFIG_FILES([dlls/localspl/tests/Makefile])
1615 AC_CONFIG_FILES([dlls/lz32/Makefile])
1616 AC_CONFIG_FILES([dlls/lz32/tests/Makefile])
1617 AC_CONFIG_FILES([dlls/mapi32/Makefile])
1618 AC_CONFIG_FILES([dlls/mapi32/tests/Makefile])
1619 AC_CONFIG_FILES([dlls/mciavi32/Makefile])
1620 AC_CONFIG_FILES([dlls/mcicda/Makefile])
1621 AC_CONFIG_FILES([dlls/mciseq/Makefile])
1622 AC_CONFIG_FILES([dlls/mciwave/Makefile])
1623 AC_CONFIG_FILES([dlls/midimap/Makefile])
1624 AC_CONFIG_FILES([dlls/mlang/Makefile])
1625 AC_CONFIG_FILES([dlls/mlang/tests/Makefile])
1626 AC_CONFIG_FILES([dlls/mmdevldr.vxd/Makefile])
1627 AC_CONFIG_FILES([dlls/monodebg.vxd/Makefile])
1628 AC_CONFIG_FILES([dlls/mpr/Makefile])
1629 AC_CONFIG_FILES([dlls/mprapi/Makefile])
1630 AC_CONFIG_FILES([dlls/msacm32.drv/Makefile])
1631 AC_CONFIG_FILES([dlls/msacm32/Makefile])
1632 AC_CONFIG_FILES([dlls/msacm32/tests/Makefile])
1633 AC_CONFIG_FILES([dlls/msadp32.acm/Makefile])
1634 AC_CONFIG_FILES([dlls/mscms/Makefile])
1635 AC_CONFIG_FILES([dlls/mscms/tests/Makefile])
1636 AC_CONFIG_FILES([dlls/mscoree/Makefile])
1637 AC_CONFIG_FILES([dlls/msdmo/Makefile])
1638 AC_CONFIG_FILES([dlls/msftedit/Makefile])
1639 AC_CONFIG_FILES([dlls/msg711.acm/Makefile])
1640 AC_CONFIG_FILES([dlls/mshtml/Makefile])
1641 AC_CONFIG_FILES([dlls/mshtml/tests/Makefile])
1642 AC_CONFIG_FILES([dlls/msi/Makefile])
1643 AC_CONFIG_FILES([dlls/msi/tests/Makefile])
1644 AC_CONFIG_FILES([dlls/msimg32/Makefile])
1645 AC_CONFIG_FILES([dlls/msisys.ocx/Makefile])
1646 AC_CONFIG_FILES([dlls/msnet32/Makefile])
1647 AC_CONFIG_FILES([dlls/msrle32/Makefile])
1648 AC_CONFIG_FILES([dlls/msvcrt/Makefile])
1649 AC_CONFIG_FILES([dlls/msvcrt/tests/Makefile])
1650 AC_CONFIG_FILES([dlls/msvcrt20/Makefile])
1651 AC_CONFIG_FILES([dlls/msvcrt40/Makefile])
1652 AC_CONFIG_FILES([dlls/msvcrtd/Makefile])
1653 AC_CONFIG_FILES([dlls/msvcrtd/tests/Makefile])
1654 AC_CONFIG_FILES([dlls/msvfw32/Makefile])
1655 AC_CONFIG_FILES([dlls/msvidc32/Makefile])
1656 AC_CONFIG_FILES([dlls/mswsock/Makefile])
1657 AC_CONFIG_FILES([dlls/msxml3/Makefile])
1658 AC_CONFIG_FILES([dlls/msxml3/tests/Makefile])
1659 AC_CONFIG_FILES([dlls/nddeapi/Makefile])
1660 AC_CONFIG_FILES([dlls/netapi32/Makefile])
1661 AC_CONFIG_FILES([dlls/netapi32/tests/Makefile])
1662 AC_CONFIG_FILES([dlls/newdev/Makefile])
1663 AC_CONFIG_FILES([dlls/ntdll/Makefile])
1664 AC_CONFIG_FILES([dlls/ntdll/tests/Makefile])
1665 AC_CONFIG_FILES([dlls/ntdsapi/Makefile])
1666 AC_CONFIG_FILES([dlls/objsel/Makefile])
1667 AC_CONFIG_FILES([dlls/odbc32/Makefile])
1668 AC_CONFIG_FILES([dlls/odbccp32/Makefile])
1669 AC_CONFIG_FILES([dlls/odbccp32/tests/Makefile])
1670 AC_CONFIG_FILES([dlls/ole32/Makefile])
1671 AC_CONFIG_FILES([dlls/ole32/tests/Makefile])
1672 AC_CONFIG_FILES([dlls/oleacc/Makefile])
1673 AC_CONFIG_FILES([dlls/oleaut32/Makefile])
1674 AC_CONFIG_FILES([dlls/oleaut32/tests/Makefile])
1675 AC_CONFIG_FILES([dlls/olecli32/Makefile])
1676 AC_CONFIG_FILES([dlls/oledlg/Makefile])
1677 AC_CONFIG_FILES([dlls/olepro32/Makefile])
1678 AC_CONFIG_FILES([dlls/olesvr32/Makefile])
1679 AC_CONFIG_FILES([dlls/opengl32/Makefile])
1680 AC_CONFIG_FILES([dlls/powrprof/Makefile])
1681 AC_CONFIG_FILES([dlls/psapi/Makefile])
1682 AC_CONFIG_FILES([dlls/psapi/tests/Makefile])
1683 AC_CONFIG_FILES([dlls/pstorec/Makefile])
1684 AC_CONFIG_FILES([dlls/qcap/Makefile])
1685 AC_CONFIG_FILES([dlls/quartz/Makefile])
1686 AC_CONFIG_FILES([dlls/quartz/tests/Makefile])
1687 AC_CONFIG_FILES([dlls/query/Makefile])
1688 AC_CONFIG_FILES([dlls/rasapi32/Makefile])
1689 AC_CONFIG_FILES([dlls/resutils/Makefile])
1690 AC_CONFIG_FILES([dlls/riched20/Makefile])
1691 AC_CONFIG_FILES([dlls/riched20/tests/Makefile])
1692 AC_CONFIG_FILES([dlls/riched32/Makefile])
1693 AC_CONFIG_FILES([dlls/rpcrt4/Makefile])
1694 AC_CONFIG_FILES([dlls/rpcrt4/tests/Makefile])
1695 AC_CONFIG_FILES([dlls/rsabase/Makefile])
1696 AC_CONFIG_FILES([dlls/rsabase/tests/Makefile])
1697 AC_CONFIG_FILES([dlls/rsaenh/Makefile])
1698 AC_CONFIG_FILES([dlls/rsaenh/tests/Makefile])
1699 AC_CONFIG_FILES([dlls/sane.ds/Makefile])
1700 AC_CONFIG_FILES([dlls/schannel/Makefile])
1701 AC_CONFIG_FILES([dlls/secur32/Makefile])
1702 AC_CONFIG_FILES([dlls/secur32/tests/Makefile])
1703 AC_CONFIG_FILES([dlls/security/Makefile])
1704 AC_CONFIG_FILES([dlls/sensapi/Makefile])
1705 AC_CONFIG_FILES([dlls/serialui/Makefile])
1706 AC_CONFIG_FILES([dlls/serialui/tests/Makefile])
1707 AC_CONFIG_FILES([dlls/setupapi/Makefile])
1708 AC_CONFIG_FILES([dlls/setupapi/tests/Makefile])
1709 AC_CONFIG_FILES([dlls/sfc/Makefile])
1710 AC_CONFIG_FILES([dlls/sfc_os/Makefile])
1711 AC_CONFIG_FILES([dlls/shdoclc/Makefile])
1712 AC_CONFIG_FILES([dlls/shdocvw/Makefile])
1713 AC_CONFIG_FILES([dlls/shdocvw/tests/Makefile])
1714 AC_CONFIG_FILES([dlls/shell32/Makefile])
1715 AC_CONFIG_FILES([dlls/shell32/tests/Makefile])
1716 AC_CONFIG_FILES([dlls/shfolder/Makefile])
1717 AC_CONFIG_FILES([dlls/shlwapi/Makefile])
1718 AC_CONFIG_FILES([dlls/shlwapi/tests/Makefile])
1719 AC_CONFIG_FILES([dlls/snmpapi/Makefile])
1720 AC_CONFIG_FILES([dlls/snmpapi/tests/Makefile])
1721 AC_CONFIG_FILES([dlls/spoolss/Makefile])
1722 AC_CONFIG_FILES([dlls/stdole2.tlb/Makefile])
1723 AC_CONFIG_FILES([dlls/stdole32.tlb/Makefile])
1724 AC_CONFIG_FILES([dlls/sti/Makefile])
1725 AC_CONFIG_FILES([dlls/strmiids/Makefile])
1726 AC_CONFIG_FILES([dlls/svrapi/Makefile])
1727 AC_CONFIG_FILES([dlls/tapi32/Makefile])
1728 AC_CONFIG_FILES([dlls/twain_32/Makefile])
1729 AC_CONFIG_FILES([dlls/unicows/Makefile])
1730 AC_CONFIG_FILES([dlls/url/Makefile])
1731 AC_CONFIG_FILES([dlls/urlmon/Makefile])
1732 AC_CONFIG_FILES([dlls/urlmon/tests/Makefile])
1733 AC_CONFIG_FILES([dlls/user32/Makefile])
1734 AC_CONFIG_FILES([dlls/user32/tests/Makefile])
1735 AC_CONFIG_FILES([dlls/userenv/Makefile])
1736 AC_CONFIG_FILES([dlls/usp10/Makefile])
1737 AC_CONFIG_FILES([dlls/usp10/tests/Makefile])
1738 AC_CONFIG_FILES([dlls/uuid/Makefile])
1739 AC_CONFIG_FILES([dlls/uxtheme/Makefile])
1740 AC_CONFIG_FILES([dlls/uxtheme/tests/Makefile])
1741 AC_CONFIG_FILES([dlls/vdhcp.vxd/Makefile])
1742 AC_CONFIG_FILES([dlls/vdmdbg/Makefile])
1743 AC_CONFIG_FILES([dlls/version/Makefile])
1744 AC_CONFIG_FILES([dlls/version/tests/Makefile])
1745 AC_CONFIG_FILES([dlls/vmm.vxd/Makefile])
1746 AC_CONFIG_FILES([dlls/vnbt.vxd/Makefile])
1747 AC_CONFIG_FILES([dlls/vnetbios.vxd/Makefile])
1748 AC_CONFIG_FILES([dlls/vtdapi.vxd/Makefile])
1749 AC_CONFIG_FILES([dlls/vwin32.vxd/Makefile])
1750 AC_CONFIG_FILES([dlls/w32skrnl/Makefile])
1751 AC_CONFIG_FILES([dlls/winealsa.drv/Makefile])
1752 AC_CONFIG_FILES([dlls/winearts.drv/Makefile])
1753 AC_CONFIG_FILES([dlls/wineaudioio.drv/Makefile])
1754 AC_CONFIG_FILES([dlls/winecoreaudio.drv/Makefile])
1755 AC_CONFIG_FILES([dlls/winecrt0/Makefile])
1756 AC_CONFIG_FILES([dlls/wined3d/Makefile])
1757 AC_CONFIG_FILES([dlls/winedos/Makefile])
1758 AC_CONFIG_FILES([dlls/wineesd.drv/Makefile])
1759 AC_CONFIG_FILES([dlls/winejack.drv/Makefile])
1760 AC_CONFIG_FILES([dlls/winejoystick.drv/Makefile])
1761 AC_CONFIG_FILES([dlls/winemp3.acm/Makefile])
1762 AC_CONFIG_FILES([dlls/winenas.drv/Makefile])
1763 AC_CONFIG_FILES([dlls/wineoss.drv/Makefile])
1764 AC_CONFIG_FILES([dlls/wineps.drv/Makefile])
1765 AC_CONFIG_FILES([dlls/winequartz.drv/Makefile])
1766 AC_CONFIG_FILES([dlls/winex11.drv/Makefile])
1767 AC_CONFIG_FILES([dlls/wing32/Makefile])
1768 AC_CONFIG_FILES([dlls/wininet/Makefile])
1769 AC_CONFIG_FILES([dlls/wininet/tests/Makefile])
1770 AC_CONFIG_FILES([dlls/winmm/Makefile])
1771 AC_CONFIG_FILES([dlls/winmm/tests/Makefile])
1772 AC_CONFIG_FILES([dlls/winnls32/Makefile])
1773 AC_CONFIG_FILES([dlls/winspool.drv/Makefile])
1774 AC_CONFIG_FILES([dlls/winspool.drv/tests/Makefile])
1775 AC_CONFIG_FILES([dlls/wintab32/Makefile])
1776 AC_CONFIG_FILES([dlls/wintrust/Makefile])
1777 AC_CONFIG_FILES([dlls/wintrust/tests/Makefile])
1778 AC_CONFIG_FILES([dlls/wldap32/Makefile])
1779 AC_CONFIG_FILES([dlls/wnaspi32/Makefile])
1780 AC_CONFIG_FILES([dlls/wow32/Makefile])
1781 AC_CONFIG_FILES([dlls/ws2_32/Makefile])
1782 AC_CONFIG_FILES([dlls/ws2_32/tests/Makefile])
1783 AC_CONFIG_FILES([dlls/wsock32/Makefile])
1784 AC_CONFIG_FILES([dlls/wtsapi32/Makefile])
1785 AC_CONFIG_FILES([documentation/Makefile])
1786 AC_CONFIG_FILES([fonts/Makefile])
1787 AC_CONFIG_FILES([include/Makefile])
1788 AC_CONFIG_FILES([libs/Makefile])
1789 AC_CONFIG_FILES([libs/port/Makefile])
1790 AC_CONFIG_FILES([libs/wine/Makefile])
1791 AC_CONFIG_FILES([libs/wpp/Makefile])
1792 AC_CONFIG_FILES([loader/Makefile])
1793 AC_CONFIG_FILES([programs/Makefile])
1794 AC_CONFIG_FILES([programs/clock/Makefile])
1795 AC_CONFIG_FILES([programs/cmd/Makefile])
1796 AC_CONFIG_FILES([programs/cmdlgtst/Makefile])
1797 AC_CONFIG_FILES([programs/control/Makefile])
1798 AC_CONFIG_FILES([programs/eject/Makefile])
1799 AC_CONFIG_FILES([programs/expand/Makefile])
1800 AC_CONFIG_FILES([programs/explorer/Makefile])
1801 AC_CONFIG_FILES([programs/hh/Makefile])
1802 AC_CONFIG_FILES([programs/icinfo/Makefile])
1803 AC_CONFIG_FILES([programs/iexplore/Makefile])
1804 AC_CONFIG_FILES([programs/msiexec/Makefile])
1805 AC_CONFIG_FILES([programs/notepad/Makefile])
1806 AC_CONFIG_FILES([programs/oleview/Makefile])
1807 AC_CONFIG_FILES([programs/progman/Makefile])
1808 AC_CONFIG_FILES([programs/regedit/Makefile])
1809 AC_CONFIG_FILES([programs/regsvr32/Makefile])
1810 AC_CONFIG_FILES([programs/rpcss/Makefile])
1811 AC_CONFIG_FILES([programs/rundll32/Makefile])
1812 AC_CONFIG_FILES([programs/start/Makefile])
1813 AC_CONFIG_FILES([programs/taskmgr/Makefile])
1814 AC_CONFIG_FILES([programs/uninstaller/Makefile])
1815 AC_CONFIG_FILES([programs/view/Makefile])
1816 AC_CONFIG_FILES([programs/wineboot/Makefile])
1817 AC_CONFIG_FILES([programs/winebrowser/Makefile])
1818 AC_CONFIG_FILES([programs/winecfg/Makefile])
1819 AC_CONFIG_FILES([programs/wineconsole/Makefile])
1820 AC_CONFIG_FILES([programs/winedbg/Makefile])
1821 AC_CONFIG_FILES([programs/winefile/Makefile])
1822 AC_CONFIG_FILES([programs/winemenubuilder/Makefile])
1823 AC_CONFIG_FILES([programs/winemine/Makefile])
1824 AC_CONFIG_FILES([programs/winepath/Makefile])
1825 AC_CONFIG_FILES([programs/winetest/Makefile])
1826 AC_CONFIG_FILES([programs/winevdm/Makefile])
1827 AC_CONFIG_FILES([programs/winhelp/Makefile])
1828 AC_CONFIG_FILES([programs/winver/Makefile])
1829 AC_CONFIG_FILES([programs/wordpad/Makefile])
1830 AC_CONFIG_FILES([programs/xcopy/Makefile])
1831 AC_CONFIG_FILES([server/Makefile])
1832 AC_CONFIG_FILES([tools/Makefile])
1833 AC_CONFIG_FILES([tools/widl/Makefile])
1834 AC_CONFIG_FILES([tools/winebuild/Makefile])
1835 AC_CONFIG_FILES([tools/winedump/Makefile])
1836 AC_CONFIG_FILES([tools/winegcc/Makefile])
1837 AC_CONFIG_FILES([tools/wmc/Makefile])
1838 AC_CONFIG_FILES([tools/wrc/Makefile])
1839
1840 AC_OUTPUT
1841
1842 dnl **** Display messages about additional packages ***
1843
1844 if test "$no_create" = "yes"
1845 then
1846   exit 0
1847 fi
1848
1849 if test "$verbose" = "yes"
1850 then
1851   dnl **** libcapi20-dev devel package ***
1852   if test "$ac_cv_header_capi20_h" != "yes" -o "$ac_cv_header_linux_capi_h" != "yes"
1853   then
1854     echo >&2
1855     AC_MSG_NOTICE([libcapi20 development files not found.])
1856     AC_MSG_NOTICE([Wine will be built without ISDN support. (capi2032.dll)])
1857   fi
1858
1859   dnl **** libcupsys-dev devel package ***
1860   if test "$ac_cv_header_cups_cups_h" != "yes"
1861   then
1862     echo >&2
1863     AC_MSG_NOTICE([libcups development files not found.])
1864     AC_MSG_NOTICE([Wine will be built without CUPS support.])
1865   fi
1866
1867   dnl **** libcurses devel package: see libncurses ***
1868   dnl **** libdbus-1 devel package ***
1869   dnl **** libdbus-1-dev is required for libhal-dev ***
1870
1871   dnl **** libgphoto2 devel package ***
1872   if test "$ac_cv_header_gphoto2_camera_h" != "yes"
1873   then
1874     echo >&2
1875     AC_MSG_NOTICE([libgphoto2 development files not found.])
1876     if test "$ac_cv_header_sane_sane_h" = "yes"
1877     then
1878       AC_MSG_NOTICE([Wine will be built with limited Digital Camera support. (twain_32.dll)])
1879     else
1880       AC_MSG_NOTICE([Wine will be built without Digital Camera support. (gphoto2.ds/twain_32.dll)])
1881     fi
1882   fi
1883
1884   dnl **** libhal devel package ***
1885   dnl **** libhal-dev depends on libdbus-1-dev ***
1886   if test "$ac_cv_header_hal_libhal_h" != "yes"
1887   then
1888     echo >&2
1889     AC_MSG_NOTICE([libhal development files not found.])
1890     AC_MSG_NOTICE([Wine will be built without dynamic device support. (explorer.exe)])
1891   fi
1892
1893   dnl **** libicu devel package ****
1894   if test "$ac_cv_header_unicode_ubidi_h" != "yes"
1895   then
1896     echo >&2
1897     AC_MSG_NOTICE([libicu development files not found.])
1898     AC_MSG_NOTICE([Wine will be built without bidi (Right to Left) support. (gdi32.dll)])
1899   fi
1900
1901   dnl **** liblcms devel package ****
1902   if test "$ac_cv_header_lcms_h" != "yes" -a "$ac_cv_header_lcms_lcms_h" != "yes"
1903   then
1904     echo >&2
1905     AC_MSG_NOTICE([liblcms development files not found.])
1906     AC_MSG_NOTICE([Wine will be built without Color Management support. (mscms.dll)])
1907   fi
1908
1909   dnl **** libldap devel package ****
1910   if test "$ac_cv_header_ldap_h" != "yes" -o "$ac_cv_header_lber_h" != "yes"
1911   then
1912     echo >&2
1913     AC_MSG_NOTICE([libldap (OpenLDAP) development files not found.])
1914     AC_MSG_NOTICE([Wine will be built without LDAP support. (wldap32.dll)])
1915   fi
1916
1917   dnl **** libncurses / libcurses devel package ***
1918   if test "x$with_curses" != "xno" -a "$ac_cv_header_ncurses_h" != "yes" -a "$ac_cv_header_curses_h" != "yes"
1919   then
1920     echo >&2
1921     AC_MSG_NOTICE([lib(n)curses development files not found.])
1922     AC_MSG_NOTICE([Wine will be built without (n)curses support. (wineconsole.exe)])
1923   fi
1924
1925   dnl **** libsane devel package ***
1926   if test "$ac_cv_header_sane_sane_h" != "yes"
1927   then
1928     echo >&2
1929     AC_MSG_NOTICE([libsane development files not found.])
1930     AC_MSG_NOTICE([Wine will be built without Scanner support. (sane.ds/twain_32.dll)])
1931   fi
1932
1933   dnl **** libX11-dev includes Xlib.h and Xutil.h and depends on ***
1934   dnl **** x11proto-input-dev (extensions/XInput.h) and x11proto-kb-dev (XKBlib.h) ***
1935   if test "$have_x" = "yes"
1936   then
1937     dnl **** libX11 - extension: Xext ***
1938     if test "$ac_cv_header_X11_extensions_shape_h" != "yes" -o "$ac_cv_header_X11_extensions_XShm_h" != "yes"
1939     then
1940       echo >&2
1941       AC_MSG_NOTICE([libxext development files not found.])
1942       AC_MSG_NOTICE([Wine will be built without Shm / Shape support. (winex11.drv)])
1943     fi
1944
1945     dnl **** libX11 - extension: Xrandr ***
1946     if test "$ac_cv_header_X11_extensions_Xrandr_h" != "yes"
1947     then
1948       echo >&2
1949       AC_MSG_NOTICE([libXrandr development files not found.])
1950       AC_MSG_NOTICE([Wine will be built without Xrandr support. (winex11.drv)])
1951     fi
1952
1953     dnl **** libX11 - extension: Xrender ***
1954     if test "$ac_cv_header_X11_extensions_Xrender_h" != "yes"
1955     then
1956       echo >&2
1957       AC_MSG_NOTICE([libXrender development files not found.])
1958       AC_MSG_NOTICE([Wine will be built without Xrender support. (winex11.drv)])
1959     fi
1960
1961     dnl **** libX11 - extension: Xxf86vm ***
1962     if test "$ac_cv_header_X11_extensions_xf86vmode_h" != "yes"
1963     then
1964       echo >&2
1965       AC_MSG_NOTICE([libXxf86vm development files not found.])
1966       AC_MSG_NOTICE([Wine will be built without XFree86-VidMode support. (winex11.drv)])
1967     fi
1968   fi
1969
1970   dnl **** libxml2 devel package ***
1971   if test "$ac_cv_header_libxml_parser_h" != "yes"
1972   then
1973     echo >&2
1974     AC_MSG_NOTICE([libxml2 development files not found.])
1975     AC_MSG_NOTICE([Wine will be built without XML support. (msxml.dll)])
1976   fi
1977
1978   dnl **** libxslt devel package ***
1979   if test "$ac_cv_header_libxslt_pattern_h" != "yes" -o "$ac_cv_header_libxslt_transform_h" != "yes"
1980   then
1981     echo >&2
1982     AC_MSG_NOTICE([libxslt development files not found.])
1983     AC_MSG_NOTICE([Wine will be built without xslt support. (msxml.dll)])
1984   fi
1985 fi
1986
1987
1988 dnl **** Display warnings about important packages ***
1989 if test "$have_x" = "no"
1990 then
1991   echo >&2
1992   AC_MSG_WARN([X development files not found. Wine will be built without])
1993   AC_MSG_WARN([X support, which currently does not work, and probably])
1994   AC_MSG_WARN([isn't what you want anyway. You will need to install devel])
1995   AC_MSG_WARN([ packages of Xlib/Xfree86 at the very least.])
1996 fi
1997
1998 if test -z "$OPENGLFILES"
1999 then
2000   echo >&2
2001   AC_MSG_WARN([Wine will be build without OpenGL or Direct3D support])
2002   AC_MSG_WARN([because something is wrong with the OpenGL setup:])
2003   if test "$wine_cv_opengl_headers_found" = "no"
2004   then
2005     AC_MSG_WARN([No OpenGL development headers were found])
2006   fi
2007   if test "$wine_cv_opengl_header_version_OK" = "no"
2008   then
2009     AC_MSG_WARN([Old Mesa headers detected. Consider upgrading your Mesa libraries (http://www.mesa3d.org/).])
2010   elif test "$ac_cv_lib_GL_glXCreateContext" = "no"
2011   then
2012      if test -f /usr/X11R6/lib/libGL.a
2013      then
2014         AC_MSG_WARN([/usr/X11R6/lib/libGL.a is present on your system.
2015 This probably prevents linking to OpenGL. Try deleting the file and restarting configure.])
2016      else
2017         AC_MSG_WARN([No OpenGL library found on this system.])
2018      fi
2019   fi
2020 fi
2021
2022 if test "$wine_cv_msg_freetype" = "yes"
2023 then
2024   echo >&2
2025   AC_MSG_WARN([Your system appears to have the FreeType 2 runtime libraries])
2026   AC_MSG_WARN([installed, but 'freetype-config' is not in your PATH. Install])
2027   AC_MSG_WARN([the freetype-devel package (or its equivalent on your distribution)])
2028   AC_MSG_WARN([to enable Wine to use TrueType fonts.])
2029 fi
2030
2031 if test -z "$FONTSSUBDIRS"
2032 then
2033   echo >&2
2034   if test "$FONTFORGE" = "false"
2035   then
2036     AC_MSG_WARN([FontForge is missing.])
2037   else
2038     AC_MSG_WARN([FreeType is missing.])
2039   fi
2040   AC_MSG_WARN([Fonts will not be built. Dialog text may be invisible or unaligned.])
2041 fi
2042
2043 if test -z "$ALSALIBS" -a \
2044         -z "$ARTSC_LIBS" -a \
2045         -z "$AUDIOIOLIBS" -a \
2046         -z "$NASLIBS" -a \
2047         -z "$ESD_LIBS" -a \
2048         -z "$ac_cv_lib_soname_jack" -a \
2049         "$ac_cv_header_sys_soundcard_h" != "yes" -a \
2050         "$ac_cv_header_machine_soundcard_h" != "yes" -a \
2051         "$ac_cv_header_soundcard_h" != "yes"
2052 then
2053   echo >&2
2054   AC_MSG_WARN([No sound system was found. Windows applications will be silent.])
2055   AC_MSG_WARN([The currently supported sound systems are:])
2056   AC_MSG_WARN([ALSA, ARTS, EsounD, AudioIO, Jack, NAS and OSS])
2057 fi
2058
2059 echo
2060 echo "Configure finished.  Do '${ac_make} depend && ${ac_make}' to compile Wine."
2061 echo
2062
2063 dnl Local Variables:
2064 dnl comment-start: "dnl "
2065 dnl comment-end: ""
2066 dnl comment-start-skip: "\\bdnl\\b\\s *"
2067 dnl compile-command: "autoconf && autoheader"
2068 dnl End: