git.oblomov.eu Git - wine/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 AC_PREREQ(2.53b)
   8 AC_INIT([Wine],WINE_VERSION,[wine-devel@winehq.org])
   9 AC_CONFIG_SRCDIR(server/atom.c)
  10 AC_CONFIG_HEADERS(include/config.h)
  11 AC_CONFIG_AUX_DIR(tools)
  12
  13 dnl **** Command-line arguments ****
  14
  15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
  16 AC_ARG_ENABLE(win64, AC_HELP_STRING([--enable-win64], [build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
  17
  18 AC_ARG_WITH(opengl,    AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
  19 AC_ARG_WITH(curses,    AC_HELP_STRING([--without-curses],[do not use curses]))
  20 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
  21
  22 AC_CANONICAL_HOST
  23 case $host in
  24   x86_64*linux*)
  25     if test "x$enable_win64" != "xyes"
  26     then
  27       test -n "$CC" || CC="gcc -m32"
  28       test -n "$LD" || LD="ld -m elf_i386"
  29       test -n "$AS" || AS="as --32"
  30       host_cpu="i386"
  31     fi
  32     ;;
  33 esac
  34
  35 dnl enable_win16 defaults to yes on x86, to no on other CPUs
  36 case $host_cpu in
  37   *i[[3456789]]86*)
  38     if test "x$enable_win16" != "xno"
  39     then
  40       enable_win16="yes"
  41     fi
  42     ;;
  43 esac
  44
  45 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
  46 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
  47 if test "x$enable_win16" != "xyes"
  48 then
  49   WIN16_FILES=""
  50   WIN16_INSTALL=""
  51 fi
  52
  53 dnl **** Check for some programs ****
  54
  55 AC_PROG_MAKE_SET
  56 AC_PROG_CC
  57 AC_PROG_CXX
  58 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
  59 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
  60
  61 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
  62   [if test -z "$with_wine_tools"; then
  63      if test "$cross_compiling" = "yes"; then
  64        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
  65      else
  66        wine_cv_toolsdir="\$(TOPOBJDIR)"
  67      fi
  68    elif test -d "$with_wine_tools/tools/winebuild"; then
  69      case $with_wine_tools in
  70        /*) wine_cv_toolsdir="$with_wine_tools" ;;
  71        *)  wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
  72      esac
  73    else
  74      AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
  75    fi])
  76 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
  77
  78 AC_PATH_XTRA
  79 AC_PROG_LEX
  80
  81 dnl **** Just additional warning checks, since AC_PROG just sets 'lex' even
  82 dnl **** without one present.
  83 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
  84 if test "$XLEX" = "none"
  85 then
  86   AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
  87 fi
  88
  89 dnl Check for bison
  90 AC_CHECK_PROGS(BISON,bison,none)
  91 if test "$BISON" = "none"
  92 then
  93   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
  94 fi
  95
  96 AC_CHECK_TOOLS(AS,[gas as],as)
  97 AC_CHECK_TOOL(LD,ld,ld)
  98 AC_CHECK_TOOL(AR,ar,ar)
  99 AC_PROG_RANLIB
 100 AC_CHECK_TOOL(STRIP,strip,strip)
 101 AC_CHECK_TOOL(WINDRES,windres,false)
 102 AC_PROG_LN_S
 103 WINE_PROG_LN
 104 AC_PROG_EGREP
 105 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
 106 AC_PROG_INSTALL
 107 dnl Prepend src dir to install path dir if it's a relative path
 108 case "$INSTALL" in
 109   [[\\/$]]* | ?:[[\\/]]* ) ;;
 110   *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
 111 esac
 112
 113 dnl Check for lint
 114 AC_CHECK_PROGS(LINT, lclint lint)
 115 if test "$LINT" = "lint"
 116 then
 117   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 118   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 119 fi
 120 AC_SUBST(LINT)
 121 AC_SUBST(LINTFLAGS)
 122
 123 dnl Check for various programs
 124 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
 125 AC_CHECK_PROGS(PKG_CONFIG, pkg-config, false)
 126
 127 case $host_cpu in
 128   *i[[3456789]]86*)
 129     AC_CHECK_PROGS(PRELINK, prelink, false, [/sbin /usr/sbin $PATH])
 130     ;;
 131 esac
 132
 133 dnl **** Check for some libraries ****
 134
 135 dnl Check for -li386 for NetBSD and OpenBSD
 136 AC_CHECK_LIB(i386,i386_set_ldt)
 137 dnl Check for -lossaudio for NetBSD
 138 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 139 dnl Check for -lnsl for Solaris
 140 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
 141 dnl Check for -lsocket for Solaris
 142 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
 143 dnl Check for -lresolv for Solaris
 144 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
 145 dnl Check for -lxpg4 for FreeBSD
 146 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
 147 dnl Check for -lpoll for Mac OS X/Darwin
 148 AC_CHECK_LIB(poll,poll)
 149 dnl Check for -lresolv for Mac OS X/Darwin
 150 AC_CHECK_LIB(resolv,res_9_init)
 151 dnl Check for -lpthread
 152 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
 153
 154 AC_SUBST(XLIB,"")
 155 AC_SUBST(XFILES,"")
 156 AC_SUBST(OPENGLFILES,"")
 157 AC_SUBST(GLU32FILES,"")
 158 AC_SUBST(OPENGL_LIBS,"")
 159
 160 dnl **** Check for header files ****
 161
 162 AC_CHECK_HEADERS(\
 163         AudioUnit/AudioUnit.h \
 164         CoreAudio/CoreAudio.h \
 165         IOKit/IOKitLib.h \
 166         alsa/asoundlib.h \
 167         arpa/inet.h \
 168         arpa/nameser.h \
 169         asm/types.h \
 170         capi20.h \
 171         cups/cups.h \
 172         curses.h \
 173         direct.h \
 174         dlfcn.h \
 175         elf.h \
 176         float.h \
 177         fontconfig/fontconfig.h \
 178         getopt.h \
 179         gif_lib.h \
 180         ieeefp.h \
 181         io.h \
 182         jack/jack.h \
 183         jpeglib.h \
 184         lber.h \
 185         lcms.h \
 186         lcms/lcms.h \
 187         ldap.h \
 188         libaudioio.h \
 189         link.h \
 190         linux/cdrom.h \
 191         linux/compiler.h \
 192         linux/hdreg.h \
 193         linux/input.h \
 194         linux/ioctl.h \
 195         linux/joystick.h \
 196         linux/major.h \
 197         linux/param.h \
 198         linux/serial.h \
 199         linux/ucdrom.h \
 200         mach/machine.h \
 201         machine/cpu.h \
 202         machine/limits.h \
 203         machine/soundcard.h \
 204         mntent.h \
 205         ncurses.h \
 206         netdb.h \
 207         netinet/in.h \
 208         netinet/in_systm.h \
 209         netinet/tcp.h \
 210         netinet/tcp_fsm.h \
 211         openssl/err.h \
 212         openssl/ssl.h \
 213         poll.h \
 214         process.h \
 215         pthread.h \
 216         pwd.h \
 217         regex.h \
 218         sched.h \
 219         scsi/scsi.h \
 220         scsi/scsi_ioctl.h \
 221         scsi/sg.h \
 222         soundcard.h \
 223         stdint.h \
 224         strings.h \
 225         sys/asoundlib.h \
 226         sys/cdio.h \
 227         sys/elf32.h \
 228         sys/epoll.h \
 229         sys/errno.h \
 230         sys/exec_elf.h \
 231         sys/filio.h \
 232         sys/ioctl.h \
 233         sys/ipc.h \
 234         sys/limits.h \
 235         sys/link.h \
 236         sys/lwp.h \
 237         sys/mman.h \
 238         sys/modem.h \
 239         sys/msg.h \
 240         sys/mtio.h \
 241         sys/param.h \
 242         sys/poll.h \
 243         sys/prctl.h \
 244         sys/ptrace.h \
 245         sys/reg.h \
 246         sys/resource.h \
 247         sys/scsiio.h \
 248         sys/shm.h \
 249         sys/signal.h \
 250         sys/socket.h \
 251         sys/sockio.h \
 252         sys/soundcard.h \
 253         sys/statvfs.h \
 254         sys/strtio.h \
 255         sys/syscall.h \
 256         sys/sysctl.h \
 257         sys/time.h \
 258         sys/times.h \
 259         sys/uio.h \
 260         sys/un.h \
 261         sys/vm86.h \
 262         sys/wait.h \
 263         syscall.h \
 264         termios.h \
 265         unicode/ubidi.h \
 266         unistd.h \
 267         utime.h \
 268         valgrind/memcheck.h
 269 )
 270 AC_HEADER_STAT()
 271
 272 dnl **** Checks for headers that depend on other ones ****
 273
 274 AC_CHECK_HEADERS([sys/mount.h sys/statfs.h sys/user.h sys/vfs.h],,,
 275     [#include <sys/types.h>
 276      #if HAVE_SYS_PARAM_H
 277      # include <sys/param.h>
 278      #endif])
 279
 280 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h netipx/ipx.h],,,
 281     [#include <sys/types.h>
 282      #if HAVE_SYS_SOCKET_H
 283      # include <sys/socket.h>
 284      #endif])
 285
 286 AC_CHECK_HEADERS([resolv.h],,,
 287     [#include <sys/types.h>
 288      #if HAVE_SYS_SOCKET_H
 289      # include <sys/socket.h>
 290      #endif
 291      #if HAVE_NETINET_IN_H
 292      # include <netinet/in.h>
 293      #endif
 294      #if HAVE_ARPA_NAMESER_H
 295      # include <arpa/nameser.h>
 296      #endif])
 297
 298 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
 299
 300 AC_CHECK_HEADERS([linux/ipx.h linux/videodev.h],,,
 301 [#ifdef HAVE_SYS_TIME_H
 302 #include <sys/time.h>
 303 #endif
 304 #include <sys/types.h>
 305 #ifdef HAVE_ASM_TYPES_H
 306 #include <asm/types.h>
 307 #endif])
 308
 309 dnl Check for broken kernel header that doesn't define __user
 310 AC_CHECK_HEADERS([linux/capi.h],,,[#define __user])
 311
 312 dnl **** Check for X11 ****
 313
 314 if test "$have_x" = "yes"
 315 then
 316     XLIB="-lXext -lX11"
 317     ac_save_CPPFLAGS="$CPPFLAGS"
 318     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 319
 320     dnl *** All of the following tests require X11/Xlib.h
 321     AC_CHECK_HEADERS([X11/Xlib.h \
 322                       X11/XKBlib.h \
 323                       X11/Xutil.h \
 324                       X11/extensions/shape.h \
 325                       X11/extensions/XInput.h \
 326                       X11/extensions/XShm.h \
 327                       X11/extensions/Xrandr.h \
 328                       X11/extensions/Xrender.h \
 329                       X11/extensions/xf86dga.h \
 330                       X11/extensions/xf86vmode.h],,,
 331 [#ifdef HAVE_X11_XLIB_H
 332 # include <X11/Xlib.h>
 333 #endif
 334 #ifdef HAVE_X11_XUTIL_H
 335 # include <X11/Xutil.h>
 336 #endif])
 337
 338         dnl *** Check for X keyboard extension
 339         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 340         then
 341               AC_CHECK_LIB(X11, XkbQueryExtension,
 342               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 343               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 344         fi
 345
 346         dnl *** Check for X Shm extension
 347         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 348         then
 349               AC_CHECK_LIB(Xext, XShmQueryExtension,
 350               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 351               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 352         fi
 353
 354         dnl *** Check for X shape extension
 355         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 356         then
 357               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 358               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 359               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 360         fi
 361
 362         dnl *** Check for XFree86 DGA / DGA 2.0 extension
 363         if test "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
 364         then
 365               AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
 366                 [ AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
 367                             [Define if you have the Xxf86dga library version 2])
 368                   X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 369                 ],,
 370                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 371         fi
 372
 373         dnl *** Check for XFree86 VMODE extension
 374         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 375         then
 376                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 377                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 378                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 379                   ],,
 380                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 381         fi
 382
 383         dnl *** Check for X RandR extension
 384         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
 385         then
 386                 AC_TRY_COMPILE([#include <X11/Xlib.h>
 387 #include <X11/extensions/Xrandr.h>],[static typeof(XRRSetScreenConfigAndRate) * func;],
 388                   [AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])])
 389         fi
 390
 391         dnl *** Check for Transform functions in Xrender
 392         if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes"
 393         then
 394               AC_CHECK_LIB(Xrender, XRenderSetPictureTransform,
 395                 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
 396                  [Define if Xrender has the XRenderSetPictureTransform function])],,
 397                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 398         fi
 399     dnl *** End of X11/Xlib.h check
 400
 401     dnl Check for the presence of OpenGL
 402     if test "x$with_opengl" != "xno"
 403     then
 404         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h GL/glu.h,,,
 405 [#ifdef HAVE_GL_GLX_H
 406 # include <GL/glx.h>
 407 #endif])
 408         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 409         then
 410             dnl Check for some problems due to old Mesa versions
 411             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
 412               AC_TRY_COMPILE(
 413                 [#include <GL/gl.h>],
 414                 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 415                 [wine_cv_opengl_version_OK="yes"],
 416                 [wine_cv_opengl_version_OK="no"]
 417               )
 418             )
 419
 420             if test "$wine_cv_opengl_version_OK" = "yes"
 421             then
 422                 dnl Check for the presence of the library
 423                 AC_CHECK_LIB(GL,glXCreateContext,
 424                              OPENGL_LIBS="-lGL"
 425                              ,,
 426                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 427
 428                 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
 429                 then
 430                         OPENGLFILES='$(OPENGLFILES)'
 431                         AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
 432                 else
 433                     if test -f /usr/X11R6/lib/libGL.a
 434                     then
 435                        AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
 436 This prevents linking to OpenGL. Delete the file and restart configure.])
 437                     fi
 438                 fi
 439
 440                 dnl Check for GLU32 library.
 441                 AC_CHECK_LIB(GLU,gluLookAt,
 442                              [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
 443                              GLU32FILES='$(GLU32FILES)']
 444                              ,,
 445                              $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
 446                 )
 447              fi
 448
 449              dnl Check for glut32 library.
 450              AC_CHECK_LIB(glut,glutMainLoop,
 451                        [AC_SUBST(GLUT_LIBS,"-lglut -lXmu -lXi")
 452                         AC_SUBST(GLUT32FILES,'$(GLUT32FILES)')],,
 453                         $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXmu -lXi -lX11 $X_EXTRA_LIBS)
 454          fi
 455     fi
 456
 457     dnl **** Check for NAS ****
 458     AC_SUBST(NASLIBS,"")
 459     AC_CHECK_HEADERS(audio/audiolib.h,
 460          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
 461           AC_CHECK_LIB(audio,AuCreateFlow,
 462                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
 463                         NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
 464                        [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 465
 466     CPPFLAGS="$ac_save_CPPFLAGS"
 467     XFILES='$(XFILES)'
 468 else
 469     XLIB=""
 470     X_CFLAGS=""
 471     X_LIBS=""
 472 fi
 473
 474 dnl **** Check for libxml2 ****
 475
 476 AC_SUBST(XML2LIBS,"")
 477 AC_SUBST(XML2INCL,"")
 478 AC_SUBST(XSLTLIBS,"")
 479 AC_SUBST(XSLTINCL,"")
 480 if test "$PKG_CONFIG" != "false"
 481 then
 482     ac_save_CPPFLAGS="$CPPFLAGS"
 483     ac_xml_libs="`$PKG_CONFIG --libs libxml-2.0`"
 484     ac_xml_cflags="`$PKG_CONFIG --cflags libxml-2.0`"
 485     CPPFLAGS="$CPPFLAGS $ac_xml_cflags"
 486     AC_CHECK_HEADERS(libxml/parser.h,
 487         [AC_CHECK_LIB(xml2, xmlParseMemory,
 488             [AC_DEFINE(HAVE_LIBXML2, 1, [Define if you have the libxml2 library])
 489              XML2LIBS="$ac_xml_libs"
 490              XML2INCL="$ac_xml_cflags"],,$ac_xml_libs)
 491          AC_CHECK_LIB(xml2, xmlReadMemory,
 492             [AC_DEFINE(HAVE_XMLREADMEMORY,1,[Define if libxml2 has the xmlReadMemory function])],,$ac_xml_libs)
 493         ])
 494     CPPFLAGS="$ac_save_CPPFLAGS"
 495     ac_xslt_libs="`$PKG_CONFIG --libs libxslt`"
 496     ac_xslt_cflags="`$PKG_CONFIG --cflags libxslt`"
 497     CPPFLAGS="$CPPFLAGS $ac_xslt_cflags"
 498     AC_CHECK_HEADERS([libxslt/pattern.h libxslt/transform.h],
 499         [AC_CHECK_LIB(xslt, xsltCompilePattern,
 500             [AC_DEFINE(HAVE_LIBXSLT, 1, [Define if you have the libxslt library])
 501              XSLTLIBS="$ac_xslt_libs"
 502              XSLTINCL="$ac_xslt_cflags"],,$ac_xslt_libs)
 503         ],,
 504 [#ifdef HAVE_LIBXSLT_PATTERN_H
 505 # include <libxslt/pattern.h>
 506 #endif])
 507     CPPFLAGS="$ac_save_CPPFLAGS"
 508 fi
 509
 510 dnl **** Check for libhal ****
 511 AC_SUBST(HALINCL,"")
 512 if test "$PKG_CONFIG" != "false"
 513 then
 514     ac_save_CPPFLAGS="$CPPFLAGS"
 515     ac_hal_libs="`$PKG_CONFIG --libs hal`"
 516     ac_hal_cflags="`$PKG_CONFIG --cflags hal`"
 517     CPPFLAGS="$CPPFLAGS $ac_hal_cflags"
 518     AC_CHECK_HEADERS([dbus/dbus.h hal/libhal.h])
 519     if test "$ac_cv_header_dbus_dbus_h" = "yes" -a "$ac_cv_header_hal_libhal_h" = "yes"
 520     then
 521         AC_CHECK_LIB(hal, libhal_ctx_new,
 522           [AC_CHECK_LIB(dbus-1, dbus_connection_close,
 523             [AC_DEFINE(HAVE_LIBHAL, 1, [Define if you have the hal library])
 524              HALINCL="$ac_hal_cflags"],,$ac_hal_libs)])
 525     fi
 526     CPPFLAGS="$ac_save_CPPFLAGS"
 527 fi
 528
 529 dnl **** Check which curses lib to use ***
 530 CURSESLIBS=""
 531 if test "x$with_curses" != "xno"
 532 then
 533     if test "$ac_cv_header_ncurses_h" = "yes"
 534     then
 535         AC_CHECK_LIB(ncurses,waddch,
 536             [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
 537              CURSESLIBS="-lncurses"])
 538     elif test "$ac_cv_header_curses_h" = "yes"
 539     then
 540         AC_CHECK_LIB(curses,waddch,
 541             [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
 542              CURSESLIBS="-lcurses"])
 543     fi
 544 fi
 545 AC_SUBST(CURSESLIBS)
 546
 547 dnl **** Check for SANE ****
 548 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
 549 AC_SUBST(SANELIBS,"")
 550 AC_SUBST(SANEINCL,"")
 551 if test "$sane_devel" != "no"
 552 then
 553     SANELIBS="`$sane_devel --libs`"
 554     SANEINCL="`$sane_devel --cflags`"
 555     ac_save_CPPFLAGS="$CPPFLAGS"
 556     ac_save_LIBS="$LIBS"
 557     CPPFLAGS="$CPPFLAGS $SANEINCL"
 558     LIBS="$LIBS $SANELIBS"
 559     AC_CHECK_HEADER(sane/sane.h,
 560                     [AC_CHECK_LIB(sane,sane_open,
 561                                   [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
 562                                   [SANELIBS=""
 563                                   SANEINCL=""])],
 564                     [SANELIBS=""
 565                     SANEINCL=""])
 566     LIBS="$ac_save_LIBS"
 567     CPPFLAGS="$ac_save_CPPFLAGS"
 568 fi
 569
 570 dnl **** Check for libgphoto2 ****
 571 AC_CHECK_PROG(gphoto2_devel,gphoto2-config,gphoto2-config,no)
 572 AC_CHECK_PROG(gphoto2port_devel,gphoto2-port-config,gphoto2-port-config,no)
 573 AC_SUBST(GPHOTO2LIBS,"")
 574 AC_SUBST(GPHOTO2INCL,"")
 575 if test "$gphoto2_devel" != "no" -a "$gphoto2port_devel" != "no"
 576 then
 577     GPHOTO2INCL="`$gphoto2_devel --cflags` `$gphoto2port_devel --cflags`"
 578     GPHOTO2LIBS=""
 579     for i in `$gphoto2_devel --libs` `$gphoto2port_devel --libs`
 580     do
 581       case "$i" in
 582         -L/usr/lib|-L/usr/lib64) ;;
 583         -L*|-l*) GPHOTO2LIBS="$GPHOTO2LIBS $i";;
 584       esac
 585     done
 586     ac_save_CPPFLAGS="$CPPFLAGS"
 587     ac_save_LIBS="$LIBS"
 588     CPPFLAGS="$CPPFLAGS $GPHOTO2INCL"
 589     LIBS="$LIBS $GPHOTO2LIBS"
 590     AC_CHECK_HEADER(gphoto2-camera.h,
 591                     [AC_CHECK_LIB(gphoto2,gp_camera_new,
 592                                   [AC_DEFINE(HAVE_GPHOTO2, 1, [Define if we have libgphoto2 development environment])],
 593                                   [GPHOTO2LIBS=""
 594                                   GPHOTO2INCL=""])],
 595                     [GPHOTO2LIBS=""
 596                     GPHOTO2INCL=""])
 597     LIBS="$ac_save_LIBS"
 598     CPPFLAGS="$ac_save_CPPFLAGS"
 599 fi
 600
 601 dnl **** Check for the ICU library ****
 602 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
 603 then
 604     saved_libs="$LIBS"
 605     ICU_LIB_DIR="${ICU_LIB_DIR-/usr/lib}"
 606     ICUUC_LIB="${ICUUC_LIB-$ICU_LIB_DIR/libsicuuc.a}"
 607     ICUDATA_LIB="${ICUDATA_LIB-$ICU_LIB_DIR/libsicudata.a}"
 608     AC_MSG_CHECKING(whether can link with ICU libraries $ICUUC_LIB and $ICUDATA_LIB)
 609     LIBS="$LIBS $ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s"
 610     AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
 611                 [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
 612                  AC_SUBST(ICULIBS,"$ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s")
 613                  AC_MSG_RESULT(yes)],
 614                 [AC_MSG_RESULT(no)])
 615     LIBS="$saved_libs"
 616 fi
 617
 618 dnl **** Check for resolver library ***
 619 AC_SUBST(RESOLVLIBS,"")
 620 if test "$ac_cv_header_resolv_h" = "yes"
 621 then
 622     AC_CHECK_LIB(resolv, res_query,
 623         [AC_DEFINE(HAVE_RESOLV, 1, [Define if you have the resolver library and header])
 624          RESOLVLIBS="-lresolv"])
 625 fi
 626
 627 dnl **** Check for LittleCMS ***
 628 AC_SUBST(LCMSLIBS,"")
 629 if test "$ac_cv_header_lcms_h" = "yes" -o "$ac_cv_header_lcms_lcms_h" = "yes"
 630 then
 631     AC_CHECK_LIB(lcms, cmsOpenProfileFromFile,
 632         [AC_DEFINE(HAVE_LCMS, 1, [Define if you have the LittleCMS development environment])
 633          LCMSLIBS="-llcms"])
 634 fi
 635
 636 dnl **** Check for OpenLDAP ***
 637 AC_SUBST(LDAPLIBS,"")
 638 if test "$ac_cv_header_ldap_h" = "yes" -a "$ac_cv_header_lber_h" = "yes"
 639 then
 640     AC_CHECK_LIB(ldap_r, ldap_initialize,
 641         [AC_CHECK_LIB(lber, ber_init,
 642             [AC_DEFINE(HAVE_LDAP, 1, [Define if you have the OpenLDAP development environment])
 643              LDAPLIBS="-lldap_r -llber"],,
 644              [$LIBPTHREAD])],,
 645              [$LIBPTHREAD])
 646     WINE_CHECK_LIB_FUNCS(\
 647         ldap_count_references \
 648         ldap_first_reference \
 649         ldap_next_reference \
 650         ldap_parse_reference,
 651         [$LDAPLIBS $LIBPTHREAD])
 652 fi
 653
 654 dnl **** Check for FreeType 2 ****
 655 AC_SUBST(FREETYPELIBS,"")
 656 AC_SUBST(FREETYPEINCL,"")
 657 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
 658 if test "$ft_lib" = "no"
 659 then
 660     wine_cv_msg_freetype=no
 661 else
 662     AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
 663     if test "$ft_devel" = "no"
 664     then
 665         AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
 666         if test "$ft_devel2" = "freetype2-config"
 667         then
 668                 ft_devel=$ft_devel2
 669         fi
 670     fi
 671     if test "$ft_devel" = "no"
 672     then
 673         wine_cv_msg_freetype=yes
 674     else
 675         FREETYPELIBS=`$ft_devel --libs`
 676         FREETYPEINCL=`$ft_devel --cflags`
 677         ac_save_CPPFLAGS="$CPPFLAGS"
 678         CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
 679         AC_CHECK_HEADERS(ft2build.h \
 680                          freetype/freetype.h \
 681                          freetype/ftglyph.h \
 682                          freetype/tttables.h \
 683                          freetype/ftnames.h \
 684                          freetype/ftsnames.h \
 685                          freetype/ttnameid.h \
 686                          freetype/ftoutln.h \
 687                          freetype/ftwinfnt.h \
 688                          freetype/ftmodapi.h \
 689                          freetype/internal/sfnt.h,,,
 690                          [#if HAVE_FT2BUILD_H
 691                           #include <ft2build.h>
 692                           #endif])
 693         AC_TRY_CPP([#include <ft2build.h>
 694                     #include <freetype/fttrigon.h>],
 695                     [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
 696           [Define if you have the <freetype/fttrigon.h> header file.])
 697                     wine_cv_fttrigon=yes],
 698                     wine_cv_fttrigon=no)
 699         AC_CHECK_TYPES(FT_TrueTypeEngineType,,,[#include <freetype/ftmodapi.h>])
 700         ac_save_CFLAGS="$CFLAGS"
 701         CFLAGS="$CFLAGS $FREETYPELIBS"
 702         AC_CHECK_FUNCS(FT_Load_Sfnt_Table)
 703         CFLAGS="$ac_save_CFLAGS"
 704         CPPFLAGS="$ac_save_CPPFLAGS"
 705         dnl Check that we have at least freetype/freetype.h
 706         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
 707         then
 708             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
 709             wine_cv_msg_freetype=no
 710         else
 711             FREETYPELIBS=""
 712             FREETYPEINCL=""
 713             wine_cv_msg_freetype=yes
 714         fi
 715     fi
 716 fi
 717
 718 dnl Only build the fonts dir if we have both freetype and fontforge
 719 if test "$FONTFORGE" != "false" -a -n "$FREETYPELIBS"
 720 then
 721   AC_SUBST(FONTSSUBDIRS,"fonts")
 722   wine_cv_msg_fonts=no
 723 else
 724   wine_cv_msg_fonts=yes
 725 fi
 726
 727 dnl **** Check for parport (currently Linux only) ****
 728 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
 729  AC_TRY_COMPILE(
 730    [#include <linux/ppdev.h>],
 731    [ioctl (1,PPCLAIM,0)],
 732    [ac_cv_c_ppdev="yes"],
 733    [ac_cv_c_ppdev="no"])
 734  )
 735 if test "$ac_cv_c_ppdev" = "yes"
 736 then
 737     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
 738 fi
 739
 740 dnl **** Check for va_copy ****
 741 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
 742  AC_TRY_LINK(
 743    [#include <stdarg.h>],
 744    [va_list ap1, ap2;
 745     va_copy(ap1,ap2);
 746    ],
 747    [ac_cv_c_va_copy="yes"],
 748    [ac_cv_c_va_copy="no"])
 749  )
 750 if test "$ac_cv_c_va_copy" = "yes"
 751 then
 752     AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
 753 fi
 754 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
 755  AC_TRY_LINK(
 756    [#include <stdarg.h>],
 757    [va_list ap1, ap2;
 758     __va_copy(ap1,ap2);
 759    ],
 760    [ac_cv_c___va_copy="yes"],
 761    [ac_cv_c___va_copy="no"])
 762  )
 763 if test "$ac_cv_c___va_copy" = "yes"
 764 then
 765     AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
 766 fi
 767
 768 dnl **** Check for sigsetjmp ****
 769 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
 770  AC_TRY_LINK(
 771    [#include <setjmp.h>],
 772    [sigjmp_buf buf;
 773     sigsetjmp( buf, 1 );
 774     siglongjmp( buf, 1 );],
 775    [ac_cv_c_sigsetjmp="yes"],
 776    [ac_cv_c_sigsetjmp="no"])
 777  )
 778 if test "$ac_cv_c_sigsetjmp" = "yes"
 779 then
 780     AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
 781 fi
 782
 783 dnl **** Check for pthread_rwlock_t ****
 784 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
 785 #include <pthread.h>])
 786
 787 dnl **** Check for pthread functions ****
 788 WINE_CHECK_LIB_FUNCS(\
 789         pthread_getattr_np \
 790         pthread_get_stackaddr_np \
 791         pthread_get_stacksize_np,
 792         [$LIBPTHREAD])
 793
 794 dnl **** Check for aRts Sound Server ****
 795 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
 796 if test x$ARTSCCONFIG != x -a x$ARTSCCONFIG != x'"$ARTSCCONFIG"';
 797 then
 798     ARTSC_CFLAGS=""
 799     for i in `$ARTSCCONFIG --cflags`
 800     do
 801       case "$i" in
 802         -I*) ARTSC_CFLAGS="$ARTSC_CFLAGS $i";;
 803       esac
 804     done
 805     ARTSC_LIBS=""
 806     for i in `$ARTSCCONFIG --libs`
 807     do
 808       case "$i" in
 809         -L/usr/lib|-L/usr/lib64) ;;
 810         -L*|-l*) ARTSC_LIBS="$ARTSC_LIBS $i";;
 811       esac
 812     done
 813     save_CFLAGS="$CFLAGS"
 814     CFLAGS="$CFLAGS $ARTSC_CFLAGS"
 815     AC_CHECK_LIB(artsc,arts_init,
 816         [AC_TRY_COMPILE([#include <artsc.h>],[arts_stream_t stream;],
 817             [AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
 818             AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
 819             AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])])],,
 820             $ARTSC_LIBS)
 821     CFLAGS="$save_CFLAGS"
 822 fi
 823
 824 dnl **** Check for EsounD ****
 825 AC_PATH_PROG(ESDCONFIG, esd-config)
 826 if test x$ESDCONFIG != x -a x$ESDCONFIG != x'"$ESDCONFIG"';
 827 then
 828     ESD_CFLAGS=""
 829     for i in `$ESDCONFIG --cflags`
 830     do
 831       case "$i" in
 832         -I*) ESD_CFLAGS="$ESD_CFLAGS $i";;
 833       esac
 834     done
 835     ESD_LIBS=`$ESDCONFIG --libs`
 836     save_CFLAGS="$CFLAGS"
 837     CFLAGS="$CFLAGS $ESD_CFLAGS"
 838     AC_CHECK_LIB(esd,esd_open_sound,
 839         [AC_SUBST(ESDLIBS, $ESD_LIBS)
 840          AC_SUBST(ESDINCL, $ESD_CFLAGS)
 841          AC_DEFINE(HAVE_ESD, 1, [Define if you have EsounD sound server])])
 842     CFLAGS="$save_CFLAGS"
 843 fi
 844
 845 dnl **** Check for ALSA 1.x ****
 846 AC_SUBST(ALSALIBS,"")
 847 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
 848 then
 849     AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
 850         [AC_TRY_COMPILE([#ifdef HAVE_ALSA_ASOUNDLIB_H
 851 #include <alsa/asoundlib.h>
 852 #elif defined(HAVE_SYS_ASOUNDLIB_H)
 853 #include <sys/asoundlib.h>
 854 #endif],
 855                         [int ret = snd_pcm_hw_params_get_access(NULL, NULL)],
 856                         [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
 857                          ALSALIBS="-lasound"])])
 858 fi
 859
 860 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
 861
 862 AC_SUBST(AUDIOIOLIBS,"")
 863 if test "$ac_cv_header_libaudioio_h" = "yes"
 864 then
 865     AC_CHECK_LIB(audioio,AudioIOGetVersion,
 866                   [AUDIOIOLIBS="-laudioio"
 867                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])
 868 fi
 869
 870 dnl **** Check for capi4linux ****
 871
 872 if test "$ac_cv_header_capi20_h" = "yes" -a "$ac_cv_header_linux_capi_h" = "yes"
 873 then
 874     AC_CHECK_LIB(capi20,capi20_register,[AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])])
 875 fi
 876
 877 dnl **** Check for gcc specific options ****
 878
 879 AC_SUBST(EXTRACFLAGS,"")
 880 if test "x${GCC}" = "xyes"
 881 then
 882   EXTRACFLAGS="-Wall -pipe"
 883
 884   dnl Check for strength-reduce bug
 885   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
 886                   AC_TRY_RUN([
 887 int     L[[4]] = {0,1,2,3};
 888 int main(void) {
 889   static int Array[[3]];
 890   unsigned int B = 3;
 891   int i;
 892   for(i=0; i<B; i++) Array[[i]] = i - 3;
 893   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
 894   L[[i]] = 4;
 895
 896   exit( Array[[1]] != -2 || L[[2]] != 3);
 897 }],
 898     ac_cv_c_gcc_strength_bug="no",
 899     ac_cv_c_gcc_strength_bug="yes",
 900     ac_cv_c_gcc_strength_bug="yes") )
 901   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 902   then
 903     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
 904   fi
 905
 906   dnl Check for -fshort-wchar
 907   AC_CACHE_CHECK([for gcc -fshort-wchar support], ac_cv_c_gcc_fshort_wchar,
 908       [WINE_TRY_CFLAGS([-fshort-wchar],
 909                       ac_cv_c_gcc_fshort_wchar="yes",ac_cv_c_gcc_fshort_wchar="no")])
 910   if test "$ac_cv_c_gcc_fshort_wchar" = "yes"
 911   then
 912       AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar", [Specifies the compiler flag that forces a short wchar_t])
 913   fi
 914
 915   dnl Check for -fno-strict-aliasing
 916   AC_CACHE_CHECK([for gcc -fno-strict-aliasing support], ac_cv_c_gcc_no_strict_aliasing,
 917       [WINE_TRY_CFLAGS([-fno-strict-aliasing],
 918                       ac_cv_c_gcc_no_strict_aliasing="yes",ac_cv_c_gcc_no_strict_aliasing="no")])
 919   if test "$ac_cv_c_gcc_no_strict_aliasing" = "yes"
 920   then
 921     EXTRACFLAGS="$EXTRACFLAGS -fno-strict-aliasing"
 922   fi
 923
 924   dnl Check for -gstabs+ option
 925   AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
 926       [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
 927   if test "$ac_cv_c_gcc_gstabs" = "yes"
 928   then
 929     EXTRACFLAGS="$EXTRACFLAGS -gstabs+"
 930   fi
 931
 932   dnl Check for -Wdeclaration-after-statement option
 933   AC_CACHE_CHECK([for gcc -Wdeclaration-after-statement support], ac_cv_c_gcc_decl_after_statement,
 934       [WINE_TRY_CFLAGS([-Wdeclaration-after-statement],ac_cv_c_gcc_decl_after_statement="yes", ac_cv_c_gcc_decl_after_statement="no")])
 935   if test "$ac_cv_c_gcc_decl_after_statement" = "yes"
 936   then
 937     EXTRACFLAGS="$EXTRACFLAGS -Wdeclaration-after-statement"
 938   fi
 939
 940   dnl Check for noisy string.h
 941   saved_CFLAGS="$CFLAGS"
 942   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
 943   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
 944       AC_TRY_COMPILE([#include <string.h>],[],
 945                      [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
 946   CFLAGS="$saved_CFLAGS"
 947   if test "$ac_cv_c_string_h_warnings" = "no"
 948   then
 949     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
 950   fi
 951
 952   AC_SUBST(BUILTINFLAG,"")
 953   saved_CFLAGS="$CFLAGS"
 954   CFLAGS="$CFLAGS -Werror"
 955   AC_CACHE_CHECK([for builtin wchar inlines], ac_cv_c_builtin_wchar_ctype,
 956       AC_TRY_COMPILE([],
 957                      [int iswlower(unsigned short);],
 958                      [ac_cv_c_builtin_wchar_ctype=no],[ac_cv_c_builtin_wchar_ctype=yes]))
 959   CFLAGS="$saved_CFLAGS"
 960   if test "$ac_cv_c_builtin_wchar_ctype" = "yes"
 961   then
 962     BUILTINFLAG=""
 963     for builtin in \
 964       iswalnum iswalpha iswcntrl iswdigit iswgraph iswlower \
 965       iswprint iswpunct iswspace iswupper iswxdigit towlower towupper
 966     do
 967       BUILTINFLAG="$BUILTINFLAG -fno-builtin-$builtin"
 968     done
 969   fi
 970 fi
 971
 972 dnl **** Check how to define a function in assembly code ****
 973
 974 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
 975   WINE_TRY_ASM_LINK(
 976       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
 977       ac_cv_asm_func_def=".def",
 978     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
 979       ac_cv_asm_func_def=".type @function",
 980     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
 981       ac_cv_asm_func_def=".type 2",
 982       ac_cv_asm_func_def="unknown")])]))
 983
 984 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
 985 case "$ac_cv_asm_func_def" in
 986   ".def")
 987      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
 988   ".type @function")
 989      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
 990   ".type 2")
 991      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
 992   *)
 993      AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
 994 esac
 995
 996 dnl **** Check for underscore on external symbols ****
 997
 998 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
 999     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
1000                       [extern int ac_test;],
1001                       [if (ac_test) return 1],
1002                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
1003
1004 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
1005 if test "$ac_cv_c_extern_prefix" = "yes"
1006 then
1007   AC_DEFINE([__ASM_NAME(name)], ["_" name])
1008 else
1009   AC_DEFINE([__ASM_NAME(name)], [name])
1010 fi
1011
1012 dnl **** Check for working dll ****
1013
1014 AC_SUBST(DLLEXT,"")
1015 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
1016 AC_SUBST(DLLIBS,"")
1017 AC_SUBST(LDSHARED,"")
1018 AC_SUBST(LDDLLFLAGS,"")
1019 AC_SUBST(LIBEXT,"so")
1020 AC_SUBST(IMPLIBEXT,"def")
1021
1022 case $host_os in
1023   cygwin*|mingw32*)
1024     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
1025     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
1026     if test "$DLLWRAP" = "false"; then
1027       LIBEXT="a"
1028     else
1029       dnl FIXME - check whether dllwrap works correctly...
1030       LIBEXT="dll"
1031     fi
1032     IMPLIBEXT="a"
1033     dnl We can't build 16-bit NE dlls
1034     WIN16_FILES=""
1035     WIN16_INSTALL=""
1036     ;;
1037   *)
1038     if test "$ac_cv_header_dlfcn_h" = "yes"
1039     then
1040         AC_CHECK_FUNCS(dlopen,,
1041             [AC_CHECK_LIB(dl,dlopen,
1042                          [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
1043                           DLLIBS="-ldl"],
1044                          [LIBEXT="a"])])
1045         WINE_CHECK_LIB_FUNCS(dladdr,[$DLLIBS])
1046     else
1047         LIBEXT="a"
1048     fi
1049
1050     if test "$LIBEXT" = "so"
1051     then
1052       DLLFLAGS="$DLLFLAGS -fPIC"
1053       DLLEXT=".so"
1054       AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
1055           [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
1056                                 ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
1057       if test "$ac_cv_c_dll_gnuelf" = "yes"
1058       then
1059         LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
1060         LDDLLFLAGS="-shared -Wl,-Bsymbolic"
1061         AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
1062           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
1063                            ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
1064         if test "$ac_cv_c_dll_zdefs" = "yes"
1065         then
1066           LDDLLFLAGS="$LDDLLFLAGS,-z,defs"
1067         fi
1068
1069         AC_CACHE_CHECK([whether the linker accepts -init and -fini], ac_cv_c_dll_init_fini,
1070           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
1071                            ac_cv_c_dll_init_fini="yes",ac_cv_c_dll_init_fini="no")])
1072         if test "$ac_cv_c_dll_init_fini" = "yes"
1073         then
1074           LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"
1075         fi
1076
1077         AC_CACHE_CHECK([whether the linker accepts version scripts], ac_cv_c_ld_version_scripts,
1078           [echo '{ global: *; };' >conftest.map
1079            WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
1080                            ac_cv_c_ld_version_scripts="yes",ac_cv_c_ld_version_scripts="no")
1081            rm -f conftest.map])
1082         if test "$ac_cv_c_ld_version_scripts" = "yes"
1083         then
1084           LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"
1085         fi
1086
1087         AC_CACHE_CHECK([whether the linker accepts --export-dynamic], ac_cv_c_export_dynamic,
1088           [WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
1089                            ac_cv_c_export_dynamic="yes",ac_cv_c_export_dynamic="no")])
1090         if test "$ac_cv_c_export_dynamic" = "yes"
1091         then
1092           AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])
1093         fi
1094
1095         AC_CACHE_CHECK([whether the linker accepts --rpath], ac_cv_ld_rpath,
1096           [WINE_TRY_CFLAGS([-fPIC -Wl,--rpath,\$ORIGIN/../lib],
1097                            ac_cv_ld_rpath="yes",ac_cv_ld_rpath="no")])
1098         if test "$ac_cv_ld_rpath" = "yes"
1099         then
1100           AC_SUBST(LDEXERPATH,["-Wl,--rpath,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"])
1101           AC_SUBST(LDDLLRPATH,["-Wl,--rpath,\\\$\$ORIGIN/\`\$(RELPATH) \$(dlldir) \$(libdir)\`"])
1102         fi
1103
1104         case $host_cpu in
1105           *i[[3456789]]86*)
1106             AC_CACHE_CHECK([whether we can relocate the executable to 0x7bf00000], ac_cv_ld_reloc_exec,
1107               [WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
1108                                ac_cv_ld_reloc_exec="yes", ac_cv_ld_reloc_exec="no")])
1109             if test "$ac_cv_ld_reloc_exec" = "yes"
1110             then
1111               LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400"
1112             fi
1113             ;;
1114         esac
1115
1116       else
1117         AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
1118             [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
1119                                   ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
1120         if test "$ac_cv_c_dll_unixware" = "yes"
1121         then
1122           LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
1123           LDDLLFLAGS="-Wl,-G,-B,symbolic"
1124
1125         else
1126           AC_CACHE_CHECK(whether we can build a Mach-O (Mac OS X/Darwin) dll, ac_cv_c_dll_macho,
1127             [WINE_TRY_SHLIB_FLAGS([-bundle], ac_cv_c_dll_macho="yes", ac_cv_c_dll_macho="no")])
1128           if test "$ac_cv_c_dll_macho" = "yes"
1129           then
1130             LIBEXT="dylib"
1131             LDDLLFLAGS="-bundle"
1132             LDSHARED="\$(CC) -dynamiclib -install_name @executable_path/\`\$(RELPATH) \$(bindir) \$(libdir)\`/\$(DYNAME) \$(SOVERSION:%=-compatibility_version %)"
1133             STRIP="$STRIP -u -r"
1134             dnl declare needed frameworks
1135             AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
1136             AC_SUBST(IOKITLIB,"-framework IOKit -framework CoreFoundation")
1137             AC_SUBST(LDEXECFLAGS,["-image_base 0x7bf00000 -Wl,-segaddr,WINE_DOS,0x00000000,-segaddr,WINE_SHARED_HEAP,0x7ffe0000"])
1138             if test "$ac_cv_header_CoreAudio_CoreAudio_h" = "yes" -a "$ac_cv_header_AudioUnit_AudioUnit_h" = "yes"
1139             then
1140                 dnl CoreServices needed by AudioUnit
1141                 AC_SUBST(COREAUDIO,"-framework CoreAudio -framework AudioUnit -framework CoreServices")
1142             fi
1143             case $host_cpu in
1144               *powerpc*)
1145                 CFLAGS="$CFLAGS -ffixed-r13"
1146                 LDDLLFLAGS="$LDDLLFLAGS -read_only_relocs warning"
1147                 ;;
1148             esac
1149
1150           else
1151             AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
1152               [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
1153             if test "$ac_cv_c_dll_hpux" = "yes"
1154             then
1155               LIBEXT="sl"
1156               DLLEXT=".sl"
1157               LDDLLFLAGS="-shared -fPIC"
1158               LDSHARED="\$(CC) -shared"
1159             fi
1160           fi
1161         fi
1162       fi
1163     fi
1164
1165     dnl Check for cross compiler to build test programs
1166     AC_SUBST(CROSSTEST,"")
1167     if test "$cross_compiling" = "no"
1168     then
1169       AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32msvc-gcc i386-mingw32-gcc mingw-gcc,false)
1170       AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32msvc-dlltool i386-mingw32-dlltool mingw-dlltool,false)
1171       AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32msvc-windres i386-mingw32-windres mingw-windres,false)
1172       if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
1173     fi
1174     ;;
1175 esac
1176
1177 if test "$LIBEXT" = "a"; then
1178   AC_MSG_ERROR(
1179 [could not find a way to build shared libraries.
1180 It is currently not possible to build Wine without shared library
1181 (.so) support to allow transparent switch between .so and .dll files.
1182 If you are using Linux, you will need a newer binutils.]
1183 )
1184 fi
1185
1186 case $build_os in
1187   cygwin*|mingw32*)
1188     AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$PATH\"") ;;
1189   darwin*|macosx*)
1190     AC_SUBST(LDPATH,"DYLD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$DYLD_LIBRARY_PATH\"") ;;
1191   *)
1192     AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$LD_LIBRARY_PATH\"") ;;
1193 esac
1194
1195 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1196 case $host_os in
1197   mingw32*)
1198     AC_SUBST(CRTLIBS,"-lmsvcrt")
1199     AC_SUBST(SOCKETLIBS,"-lws2_32")
1200     ;;
1201 esac
1202
1203 case $host_cpu in
1204   *i[[3456789]]86*)
1205     case $host_os in
1206       linux* | k*bsd*-gnu)
1207         AC_SUBST(MAIN_BINARY,"wine-glibc")
1208         AC_SUBST(EXTRA_BINARIES,"wine-kthread wine-pthread wine-preloader") ;;
1209       darwin*|freebsd*)
1210         AC_SUBST(MAIN_BINARY,"wine-pthread") ;;
1211       *)
1212         AC_SUBST(MAIN_BINARY,"wine-kthread") ;;
1213     esac
1214     ;;
1215   *) AC_SUBST(MAIN_BINARY,"wine-pthread") ;;
1216 esac
1217
1218 dnl **** Get the soname for libraries that we load dynamically ****
1219
1220 if test "$LIBEXT" = "so" -o "$LIBEXT" = "dylib"
1221 then
1222   WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
1223   WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1224   WINE_GET_SONAME(Xi,XOpenDevice,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1225   WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1226   WINE_GET_SONAME(Xrandr,XRRQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1227   WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
1228   WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
1229   WINE_GET_SONAME(dbus-1,dbus_error_init)
1230   WINE_GET_SONAME(hal,libhal_ctx_new)
1231   WINE_GET_SONAME(txc_dxtn,fetch_2d_texel_rgba_dxt1)
1232   WINE_GET_SONAME(cups,cupsGetDefault)
1233   WINE_GET_SONAME(jack,jack_client_new)
1234   WINE_GET_SONAME(fontconfig,FcInit)
1235   WINE_GET_SONAME(ssl,SSL_library_init)
1236   WINE_GET_SONAME(crypto,BIO_new_socket)
1237   WINE_GET_SONAME(ncurses,waddch)
1238   WINE_GET_SONAME(curses,waddch)
1239   WINE_GET_SONAME(jpeg,jpeg_start_decompress)
1240   WINE_GET_SONAME(ungif,DGifOpen)
1241   WINE_GET_SONAME(gif,DGifOpen)
1242   WINE_GET_SONAME(capi20,capi20_isinstalled)
1243 fi
1244
1245
1246 dnl **** Check for functions ****
1247
1248 AC_CHECK_FUNCS(\
1249         _lwp_create \
1250         _lwp_self \
1251         _pclose \
1252         _popen \
1253         _snprintf \
1254         _spawnvp \
1255         _stricmp \
1256         _strnicmp \
1257         _vsnprintf \
1258         asctime_r \
1259         chsize \
1260         clone \
1261         epoll_create \
1262         ffs \
1263         finite \
1264         fork \
1265         fpclass \
1266         fstatfs \
1267         fstatvfs \
1268         ftruncate \
1269         futimes \
1270         futimesat \
1271         getaddrinfo \
1272         getnameinfo \
1273         getnetbyname \
1274         getopt_long \
1275         getpagesize \
1276         getprotobyname \
1277         getprotobynumber \
1278         getpwuid \
1279         getservbyport \
1280         gettid \
1281         gettimeofday \
1282         getuid \
1283         inet_network \
1284         lstat \
1285         memmove \
1286         mmap \
1287         pclose \
1288         popen \
1289         prctl \
1290         pread \
1291         pwrite \
1292         readlink \
1293         rfork \
1294         sched_yield \
1295         select \
1296         sendmsg \
1297         settimeofday \
1298         sigaltstack \
1299         sigprocmask \
1300         snprintf \
1301         spawnvp \
1302         statfs \
1303         statvfs \
1304         strcasecmp \
1305         strerror \
1306         strncasecmp \
1307         tcgetattr \
1308         timegm \
1309         usleep \
1310         vsnprintf \
1311         wait4 \
1312         waitpid \
1313 )
1314
1315
1316 dnl **** Check for types ****
1317
1318 AC_C_CONST
1319 AC_C_INLINE
1320 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1321 AC_CHECK_TYPES([sigset_t],,,[#include <signal.h>])
1322 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
1323
1324 AC_CHECK_MEMBERS([struct ff_effect.direction],,,
1325 [#ifdef HAVE_LINUX_INPUT_H
1326 #include <linux/input.h>
1327 #endif])
1328
1329 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
1330                AC_TRY_LINK([#include <signal.h>],[sigset_t set; sigaddset(&set,SIGTERM);],
1331                            wine_cv_have_sigaddset=yes,wine_cv_have_sigaddset=no))
1332 if test "$wine_cv_have_sigaddset" = "yes"
1333 then
1334   AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
1335 fi
1336
1337
1338 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1339         wine_cv_linux_gethostbyname_r_6,
1340         AC_TRY_LINK([
1341 #include <netdb.h>
1342         ], [
1343     char *name=NULL;
1344     struct hostent he;
1345     struct hostent *result;
1346     char *buf=NULL;
1347     int bufsize=0;
1348     int res,errnr;
1349     char *addr=NULL;
1350     int addrlen=0;
1351     int addrtype=0;
1352     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1353     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1354     ],
1355         wine_cv_linux_gethostbyname_r_6=yes,
1356         wine_cv_linux_gethostbyname_r_6=no
1357         )
1358    )
1359    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1360    then
1361       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1362                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1363    fi
1364
1365 if test "$ac_cv_header_linux_joystick_h" = "yes"
1366 then
1367    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1368         wine_cv_linux_joystick_22_api,
1369         AC_TRY_COMPILE([
1370         #include <sys/ioctl.h>
1371         #include <linux/joystick.h>
1372
1373         struct js_event blub;
1374         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1375         #error "no 2.2 header"
1376         #endif
1377         ],/*empty*/,
1378         wine_cv_linux_joystick_22_api=yes,
1379         wine_cv_linux_joystick_22_api=no,
1380         wine_cv_linux_joystick_22_api=no
1381         )
1382    )
1383    if test "$wine_cv_linux_joystick_22_api" = "yes"
1384    then
1385       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1386                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1387    fi
1388 fi
1389
1390 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1391
1392 dnl Check for statfs members
1393 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1394 [#include <sys/types.h>
1395 #ifdef HAVE_SYS_PARAM_H
1396 # include <sys/param.h>
1397 #endif
1398 #ifdef HAVE_SYS_MOUNT_H
1399 # include <sys/mount.h>
1400 #endif
1401 #ifdef HAVE_SYS_VFS_H
1402 # include <sys/vfs.h>
1403 #endif
1404 #ifdef HAVE_SYS_STATFS_H
1405 # include <sys/statfs.h>
1406 #endif])
1407
1408 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1409 [#ifdef HAVE_SYS_STATVFS_H
1410 #include <sys/statvfs.h>
1411 #endif])
1412
1413 dnl Check for socket structure members
1414 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1415 [#include <sys/types.h>
1416 #ifdef HAVE_SYS_SOCKET_H
1417 # include <sys/socket.h>
1418 #endif
1419 #ifdef HAVE_SYS_UN_H
1420 # include <sys/un.h>
1421 #endif])
1422
1423 dnl Check for scsireq_t and sg_io_hdr_t members
1424 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
1425 [#include <sys/types.h>
1426 #ifdef HAVE_SCSI_SG_H
1427 #include <scsi/sg.h>
1428 #endif])
1429
1430 dnl Check for siginfo_t members
1431 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1432
1433 dnl Check for struct mtget members
1434 AC_CHECK_MEMBERS([struct mtget.mt_blksiz, struct mtget.mt_gstat, struct mtget.mt_blkno],,,
1435 [#include <sys/types.h>
1436 #ifdef HAVE_SYS_MTIO_H
1437 #include <sys/mtio.h>
1438 #endif])
1439
1440 dnl Check for struct option
1441 AC_CHECK_MEMBERS([struct option.name],,,
1442 [#ifdef HAVE_GETOPT_H
1443 #include <getopt.h>
1444 #endif])
1445
1446 dnl Check for stat.st_blocks
1447 AC_CHECK_MEMBERS([struct stat.st_blocks])
1448
1449 dnl Check for sin6_scope_id
1450 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_scope_id],,,
1451 [#ifdef HAVE_SYS_TYPES_H
1452 #include <sys/types.h>
1453 #endif
1454 #ifdef HAVE_NETINET_IN_H
1455 #include <netinet/in.h>
1456 #endif])
1457
1458 dnl Check for the external timezone variables timezone and daylight
1459 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
1460                AC_TRY_LINK([#include <time.h>],[timezone;],
1461                            ac_cv_have_timezone="yes", ac_cv_have_timezone="no"))
1462 if test "$ac_cv_have_timezone" = "yes"
1463 then
1464     AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
1465 fi
1466 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
1467                AC_TRY_LINK([#include <time.h>],[daylight;],
1468                            ac_cv_have_daylight="yes", ac_cv_have_daylight="no"))
1469 if test "$ac_cv_have_daylight" = "yes"
1470 then
1471     AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
1472 fi
1473
1474 dnl *** check for the need to define platform-specific symbols
1475
1476 case $host_cpu in
1477   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1478   *x86_64*)         WINE_CHECK_DEFINE([__x86_64__]) ;;
1479   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
1480   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
1481   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
1482 esac
1483
1484 case $host_vendor in
1485   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1486 esac
1487
1488 dnl **** Generate output files ****
1489
1490 AH_TOP([#define __WINE_CONFIG_H])
1491
1492 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1493 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1494 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1495 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1496 WINE_CONFIG_EXTRA_DIR(dlls/wineps.drv/data)
1497 WINE_CONFIG_EXTRA_DIR(include/wine)
1498
1499 MAKE_RULES=Make.rules
1500 AC_SUBST_FILE(MAKE_RULES)
1501
1502 MAKE_DLL_RULES=dlls/Makedll.rules
1503 AC_SUBST_FILE(MAKE_DLL_RULES)
1504
1505 MAKE_IMPLIB_RULES=dlls/Makeimplib.rules
1506 AC_SUBST_FILE(MAKE_IMPLIB_RULES)
1507
1508 MAKE_TEST_RULES=dlls/Maketest.rules
1509 AC_SUBST_FILE(MAKE_TEST_RULES)
1510
1511 MAKE_LIB_RULES=libs/Makelib.rules
1512 AC_SUBST_FILE(MAKE_LIB_RULES)
1513
1514 MAKE_PROG_RULES=programs/Makeprog.rules
1515 AC_SUBST_FILE(MAKE_PROG_RULES)
1516
1517 AC_CONFIG_FILES([
1518 Make.rules
1519 dlls/Makedll.rules
1520 dlls/Makeimplib.rules
1521 dlls/Maketest.rules
1522 libs/Makelib.rules
1523 programs/Makeprog.rules
1524 Makefile
1525 dlls/Makefile
1526 dlls/activeds/Makefile
1527 dlls/advapi32/Makefile
1528 dlls/advapi32/tests/Makefile
1529 dlls/advpack/Makefile
1530 dlls/advpack/tests/Makefile
1531 dlls/amstream/Makefile
1532 dlls/atl/Makefile
1533 dlls/avicap32/Makefile
1534 dlls/avifil32/Makefile
1535 dlls/cabinet/Makefile
1536 dlls/cabinet/tests/Makefile
1537 dlls/capi2032/Makefile
1538 dlls/cards/Makefile
1539 dlls/cfgmgr32/Makefile
1540 dlls/comcat/Makefile
1541 dlls/comctl32/Makefile
1542 dlls/comctl32/tests/Makefile
1543 dlls/comdlg32/Makefile
1544 dlls/crtdll/Makefile
1545 dlls/crypt32/Makefile
1546 dlls/crypt32/tests/Makefile
1547 dlls/cryptdll/Makefile
1548 dlls/ctl3d32/Makefile
1549 dlls/d3d8/Makefile
1550 dlls/d3d8/tests/Makefile
1551 dlls/d3d9/Makefile
1552 dlls/d3d9/tests/Makefile
1553 dlls/d3dim/Makefile
1554 dlls/d3drm/Makefile
1555 dlls/d3dx8/Makefile
1556 dlls/d3dxof/Makefile
1557 dlls/dbghelp/Makefile
1558 dlls/dciman32/Makefile
1559 dlls/ddraw/Makefile
1560 dlls/ddraw/tests/Makefile
1561 dlls/devenum/Makefile
1562 dlls/dinput/Makefile
1563 dlls/dinput/tests/Makefile
1564 dlls/dinput8/Makefile
1565 dlls/dmband/Makefile
1566 dlls/dmcompos/Makefile
1567 dlls/dmime/Makefile
1568 dlls/dmloader/Makefile
1569 dlls/dmscript/Makefile
1570 dlls/dmstyle/Makefile
1571 dlls/dmsynth/Makefile
1572 dlls/dmusic/Makefile
1573 dlls/dmusic32/Makefile
1574 dlls/dnsapi/Makefile
1575 dlls/dnsapi/tests/Makefile
1576 dlls/dplay/Makefile
1577 dlls/dplayx/Makefile
1578 dlls/dpnet/Makefile
1579 dlls/dpnhpast/Makefile
1580 dlls/dsound/Makefile
1581 dlls/dsound/tests/Makefile
1582 dlls/dswave/Makefile
1583 dlls/dxdiagn/Makefile
1584 dlls/dxerr8/Makefile
1585 dlls/dxerr9/Makefile
1586 dlls/dxguid/Makefile
1587 dlls/gdi/Makefile
1588 dlls/gdi/tests/Makefile
1589 dlls/glu32/Makefile
1590 dlls/glut32/Makefile
1591 dlls/gphoto2.ds/Makefile
1592 dlls/hhctrl.ocx/Makefile
1593 dlls/iccvid/Makefile
1594 dlls/icmp/Makefile
1595 dlls/ifsmgr.vxd/Makefile
1596 dlls/imaadp32.acm/Makefile
1597 dlls/imagehlp/Makefile
1598 dlls/imm32/Makefile
1599 dlls/iphlpapi/Makefile
1600 dlls/iphlpapi/tests/Makefile
1601 dlls/itss/Makefile
1602 dlls/kernel/Makefile
1603 dlls/kernel/tests/Makefile
1604 dlls/lz32/Makefile
1605 dlls/lz32/tests/Makefile
1606 dlls/mapi32/Makefile
1607 dlls/mapi32/tests/Makefile
1608 dlls/mciavi32/Makefile
1609 dlls/mcicda/Makefile
1610 dlls/mciseq/Makefile
1611 dlls/mciwave/Makefile
1612 dlls/midimap/Makefile
1613 dlls/mlang/Makefile
1614 dlls/mlang/tests/Makefile
1615 dlls/mmdevldr.vxd/Makefile
1616 dlls/monodebg.vxd/Makefile
1617 dlls/mpr/Makefile
1618 dlls/mprapi/Makefile
1619 dlls/msacm32.drv/Makefile
1620 dlls/msacm32/Makefile
1621 dlls/msacm32/tests/Makefile
1622 dlls/msadp32.acm/Makefile
1623 dlls/mscms/Makefile
1624 dlls/mscms/tests/Makefile
1625 dlls/msdmo/Makefile
1626 dlls/msftedit/Makefile
1627 dlls/msg711.acm/Makefile
1628 dlls/mshtml/Makefile
1629 dlls/mshtml/tests/Makefile
1630 dlls/msi/Makefile
1631 dlls/msi/tests/Makefile
1632 dlls/msimg32/Makefile
1633 dlls/msisys.ocx/Makefile
1634 dlls/msnet32/Makefile
1635 dlls/msrle32/Makefile
1636 dlls/msvcrt/Makefile
1637 dlls/msvcrt/tests/Makefile
1638 dlls/msvcrt20/Makefile
1639 dlls/msvcrt40/Makefile
1640 dlls/msvcrtd/Makefile
1641 dlls/msvcrtd/tests/Makefile
1642 dlls/msvfw32/Makefile
1643 dlls/msvidc32/Makefile
1644 dlls/mswsock/Makefile
1645 dlls/msxml3/Makefile
1646 dlls/msxml3/tests/Makefile
1647 dlls/netapi32/Makefile
1648 dlls/netapi32/tests/Makefile
1649 dlls/newdev/Makefile
1650 dlls/ntdll/Makefile
1651 dlls/ntdll/tests/Makefile
1652 dlls/ntdsapi/Makefile
1653 dlls/objsel/Makefile
1654 dlls/odbc32/Makefile
1655 dlls/odbccp32/Makefile
1656 dlls/ole32/Makefile
1657 dlls/ole32/tests/Makefile
1658 dlls/oleacc/Makefile
1659 dlls/oleaut32/Makefile
1660 dlls/oleaut32/tests/Makefile
1661 dlls/olecli32/Makefile
1662 dlls/oledlg/Makefile
1663 dlls/olepro32/Makefile
1664 dlls/olesvr32/Makefile
1665 dlls/opengl32/Makefile
1666 dlls/powrprof/Makefile
1667 dlls/psapi/Makefile
1668 dlls/psapi/tests/Makefile
1669 dlls/qcap/Makefile
1670 dlls/quartz/Makefile
1671 dlls/quartz/tests/Makefile
1672 dlls/rasapi32/Makefile
1673 dlls/riched20/Makefile
1674 dlls/riched20/tests/Makefile
1675 dlls/riched32/Makefile
1676 dlls/rpcrt4/Makefile
1677 dlls/rpcrt4/tests/Makefile
1678 dlls/rsabase/Makefile
1679 dlls/rsabase/tests/Makefile
1680 dlls/rsaenh/Makefile
1681 dlls/rsaenh/tests/Makefile
1682 dlls/sane.ds/Makefile
1683 dlls/secur32/Makefile
1684 dlls/secur32/tests/Makefile
1685 dlls/security/Makefile
1686 dlls/sensapi/Makefile
1687 dlls/serialui/Makefile
1688 dlls/setupapi/Makefile
1689 dlls/setupapi/tests/Makefile
1690 dlls/sfc/Makefile
1691 dlls/shdocvw/Makefile
1692 dlls/shdocvw/tests/Makefile
1693 dlls/shell32/Makefile
1694 dlls/shell32/tests/Makefile
1695 dlls/shfolder/Makefile
1696 dlls/shlwapi/Makefile
1697 dlls/shlwapi/tests/Makefile
1698 dlls/snmpapi/Makefile
1699 dlls/spoolss/Makefile
1700 dlls/stdole2.tlb/Makefile
1701 dlls/stdole32.tlb/Makefile
1702 dlls/sti/Makefile
1703 dlls/strmiids/Makefile
1704 dlls/tapi32/Makefile
1705 dlls/twain_32/Makefile
1706 dlls/unicows/Makefile
1707 dlls/url/Makefile
1708 dlls/urlmon/Makefile
1709 dlls/urlmon/tests/Makefile
1710 dlls/user/Makefile
1711 dlls/user/tests/Makefile
1712 dlls/usp10/Makefile
1713 dlls/usp10/tests/Makefile
1714 dlls/uuid/Makefile
1715 dlls/uxtheme/Makefile
1716 dlls/vdhcp.vxd/Makefile
1717 dlls/vdmdbg/Makefile
1718 dlls/version/Makefile
1719 dlls/version/tests/Makefile
1720 dlls/vmm.vxd/Makefile
1721 dlls/vnbt.vxd/Makefile
1722 dlls/vnetbios.vxd/Makefile
1723 dlls/vtdapi.vxd/Makefile
1724 dlls/vwin32.vxd/Makefile
1725 dlls/w32skrnl/Makefile
1726 dlls/winecrt0/Makefile
1727 dlls/wined3d/Makefile
1728 dlls/winedos/Makefile
1729 dlls/winemp3.acm/Makefile
1730 dlls/wineps.drv/Makefile
1731 dlls/wininet/Makefile
1732 dlls/wininet/tests/Makefile
1733 dlls/winmm/Makefile
1734 dlls/winmm/joystick/Makefile
1735 dlls/winmm/tests/Makefile
1736 dlls/winmm/winealsa/Makefile
1737 dlls/winmm/winearts/Makefile
1738 dlls/winmm/wineaudioio/Makefile
1739 dlls/winmm/winecoreaudio/Makefile
1740 dlls/winmm/wineesd/Makefile
1741 dlls/winmm/winejack/Makefile
1742 dlls/winmm/winenas/Makefile
1743 dlls/winmm/wineoss/Makefile
1744 dlls/winnls32/Makefile
1745 dlls/winspool.drv/Makefile
1746 dlls/winspool.drv/tests/Makefile
1747 dlls/wintab32/Makefile
1748 dlls/wintrust/Makefile
1749 dlls/wldap32/Makefile
1750 dlls/wnaspi32/Makefile
1751 dlls/wow32/Makefile
1752 dlls/ws2_32/Makefile
1753 dlls/ws2_32/tests/Makefile
1754 dlls/wsock32/Makefile
1755 dlls/wtsapi32/Makefile
1756 dlls/x11drv/Makefile
1757 documentation/Makefile
1758 fonts/Makefile
1759 include/Makefile
1760 libs/Makefile
1761 libs/port/Makefile
1762 libs/unicode/Makefile
1763 libs/wine/Makefile
1764 libs/wpp/Makefile
1765 loader/Makefile
1766 programs/Makefile
1767 programs/clock/Makefile
1768 programs/cmdlgtst/Makefile
1769 programs/control/Makefile
1770 programs/eject/Makefile
1771 programs/expand/Makefile
1772 programs/explorer/Makefile
1773 programs/hh/Makefile
1774 programs/icinfo/Makefile
1775 programs/iexplore/Makefile
1776 programs/msiexec/Makefile
1777 programs/notepad/Makefile
1778 programs/progman/Makefile
1779 programs/regedit/Makefile
1780 programs/regsvr32/Makefile
1781 programs/rpcss/Makefile
1782 programs/rundll32/Makefile
1783 programs/start/Makefile
1784 programs/taskmgr/Makefile
1785 programs/uninstaller/Makefile
1786 programs/view/Makefile
1787 programs/wcmd/Makefile
1788 programs/wineboot/Makefile
1789 programs/winebrowser/Makefile
1790 programs/winecfg/Makefile
1791 programs/wineconsole/Makefile
1792 programs/winedbg/Makefile
1793 programs/winefile/Makefile
1794 programs/winemenubuilder/Makefile
1795 programs/winemine/Makefile
1796 programs/winepath/Makefile
1797 programs/winetest/Makefile
1798 programs/winevdm/Makefile
1799 programs/winhelp/Makefile
1800 programs/winver/Makefile
1801 programs/wordpad/Makefile
1802 server/Makefile
1803 tools/Makefile
1804 tools/widl/Makefile
1805 tools/winapi/Makefile
1806 tools/winebuild/Makefile
1807 tools/winedump/Makefile
1808 tools/winegcc/Makefile
1809 tools/wmc/Makefile
1810 tools/wrc/Makefile])
1811
1812 AC_OUTPUT
1813
1814 exitcode=0
1815 if test "$have_x" = "no"
1816 then
1817   echo
1818   echo "*** Warning: X development files not found. Wine will be built without"
1819   echo "*** X support, which currently does not work, and would probably not be"
1820   echo "*** what you want anyway. You will need to install devel packages of"
1821   echo "*** Xlib/Xfree86 at the very least."
1822   exitcode=1
1823 fi
1824
1825 if test "$wine_cv_opengl_version_OK" = "no"
1826 then
1827   echo
1828   echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1829   echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1830   exitcode=1
1831 fi
1832
1833 if test "$wine_cv_msg_freetype" = "yes"
1834 then
1835   echo
1836   echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1837   echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1838   echo "*** freetype-devel package (or its equivalent on your distribution) to"
1839   echo "*** enable Wine to use TrueType fonts."
1840   exitcode=1
1841 fi
1842
1843 if test "$wine_cv_msg_fonts" = "yes"
1844 then
1845   echo
1846   echo "*** Warning: FreeType or FontForge is missing."
1847   echo "*** Fonts will not be built. Dialog text may be invisible or unaligned."
1848   exitcode=1
1849 fi
1850
1851 if test -z "$ALSALIBS" -a \
1852         -z "$ARTSC_LIBS" -a \
1853         -z "$AUDIOIOLIBS" -a \
1854         -z "$NASLIBS" -a \
1855         -z "$ESD_LIBS" -a \
1856         -z "$ac_cv_lib_soname_jack" -a \
1857         "$ac_cv_header_sys_soundcard_h" != "yes" -a \
1858         "$ac_cv_header_machine_soundcard_h" != "yes" -a \
1859         "$ac_cv_header_soundcard_h" != "yes"
1860 then
1861   echo "*** No sound system was found. Windows applications will be silent."
1862   echo "*** The currently supported sound systems are:"
1863   echo "*** ALSA, ARTS, EsounD, AudioIO, Jack, NAS and OSS"
1864   exitcode=1
1865 fi
1866
1867 echo
1868 echo "Configure finished.  Do '${ac_make} depend && ${ac_make}' to compile Wine."
1869 echo
1870
1871 exit $exitcode
1872
1873 dnl Local Variables:
1874 dnl comment-start: "dnl "
1875 dnl comment-end: ""
1876 dnl comment-start-skip: "\\bdnl\\b\\s *"
1877 dnl compile-command: "autoconf && autoheader"
1878 dnl End: