git.oblomov.eu Git - wine/blob - tools/widl/parser.y

   1 %{
   2 /*
   3  * IDL Compiler
   4  *
   5  * Copyright 2002 Ove Kaaven
   6  *
   7  * This library is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU Lesser General Public
   9  * License as published by the Free Software Foundation; either
  10  * version 2.1 of the License, or (at your option) any later version.
  11  *
  12  * This library is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15  * Lesser General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU Lesser General Public
  18  * License along with this library; if not, write to the Free Software
  19  * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  20  */
  21
  22 #include "config.h"
  23
  24 #include <stdio.h>
  25 #include <stdlib.h>
  26 #include <stdarg.h>
  27 #include <assert.h>
  28 #include <ctype.h>
  29 #include <string.h>
  30 #ifdef HAVE_ALLOCA_H
  31 #include <alloca.h>
  32 #endif
  33
  34 #include "widl.h"
  35 #include "utils.h"
  36 #include "parser.h"
  37 #include "header.h"
  38 #include "typelib.h"
  39 #include "typegen.h"
  40
  41 #if defined(YYBYACC)
  42         /* Berkeley yacc (byacc) doesn't seem to know about these */
  43         /* Some *BSD supplied versions do define these though */
  44 # ifndef YYEMPTY
  45 #  define YYEMPTY       (-1)    /* Empty lookahead value of yychar */
  46 # endif
  47 # ifndef YYLEX
  48 #  define YYLEX         yylex()
  49 # endif
  50
  51 #elif defined(YYBISON)
  52         /* Bison was used for original development */
  53         /* #define YYEMPTY -2 */
  54         /* #define YYLEX   yylex() */
  55
  56 #else
  57         /* No yacc we know yet */
  58 # if !defined(YYEMPTY) || !defined(YYLEX)
  59 #  error Yacc version/type unknown. This version needs to be verified for settings of YYEMPTY and YYLEX.
  60 # elif defined(__GNUC__)        /* gcc defines the #warning directive */
  61 #  warning Yacc version/type unknown. It defines YYEMPTY and YYLEX, but is not tested
  62   /* #else we just take a chance that it works... */
  63 # endif
  64 #endif
  65
  66 unsigned char pointer_default = RPC_FC_UP;
  67
  68 typedef struct list typelist_t;
  69 struct typenode {
  70   type_t *type;
  71   struct list entry;
  72 };
  73
  74 typelist_t incomplete_types = LIST_INIT(incomplete_types);
  75
  76 static void add_incomplete(type_t *t);
  77 static void fix_incomplete(void);
  78
  79 static str_list_t *append_str(str_list_t *list, char *str);
  80 static attr_list_t *append_attr(attr_list_t *list, attr_t *attr);
  81 static attr_t *make_attr(enum attr_type type);
  82 static attr_t *make_attrv(enum attr_type type, unsigned long val);
  83 static attr_t *make_attrp(enum attr_type type, void *val);
  84 static expr_t *make_expr(enum expr_type type);
  85 static expr_t *make_exprl(enum expr_type type, long val);
  86 static expr_t *make_exprd(enum expr_type type, double val);
  87 static expr_t *make_exprs(enum expr_type type, char *val);
  88 static expr_t *make_exprt(enum expr_type type, type_t *tref, expr_t *expr);
  89 static expr_t *make_expr1(enum expr_type type, expr_t *expr);
  90 static expr_t *make_expr2(enum expr_type type, expr_t *exp1, expr_t *exp2);
  91 static expr_t *make_expr3(enum expr_type type, expr_t *expr1, expr_t *expr2, expr_t *expr3);
  92 static type_t *make_type(unsigned char type, type_t *ref);
  93 static expr_list_t *append_expr(expr_list_t *list, expr_t *expr);
  94 static array_dims_t *append_array(array_dims_t *list, expr_t *expr);
  95 static void set_type(var_t *v, type_t *type, int ptr_level, array_dims_t *arr, int top);
  96 static ifref_list_t *append_ifref(ifref_list_t *list, ifref_t *iface);
  97 static ifref_t *make_ifref(type_t *iface);
  98 static var_list_t *append_var(var_list_t *list, var_t *var);
  99 static var_t *make_var(char *name);
 100 static pident_list_t *append_pident(pident_list_t *list, pident_t *p);
 101 static pident_t *make_pident(var_t *var);
 102 static func_list_t *append_func(func_list_t *list, func_t *func);
 103 static func_t *make_func(var_t *def, var_list_t *args);
 104 static type_t *make_class(char *name);
 105 static type_t *make_safearray(type_t *type);
 106 static type_t *make_builtin(char *name);
 107 static type_t *make_int(int sign);
 108
 109 static type_t *reg_type(type_t *type, const char *name, int t);
 110 static type_t *reg_typedefs(type_t *type, var_list_t *names, attr_list_t *attrs);
 111 static type_t *find_type(const char *name, int t);
 112 static type_t *find_type2(char *name, int t);
 113 static type_t *get_type(unsigned char type, char *name, int t);
 114 static type_t *get_typev(unsigned char type, var_t *name, int t);
 115 static int get_struct_type(var_list_t *fields);
 116
 117 static var_t *reg_const(var_t *var);
 118 static var_t *find_const(char *name, int f);
 119
 120 static void write_libid(const char *name, const attr_list_t *attr);
 121 static void write_clsid(type_t *cls);
 122 static void write_diid(type_t *iface);
 123 static void write_iid(type_t *iface);
 124
 125 static int compute_method_indexes(type_t *iface);
 126 static char *gen_name(void);
 127 static void process_typedefs(var_list_t *names);
 128 static void check_arg(var_t *arg);
 129 static void check_all_user_types(ifref_list_t *ifaces);
 130
 131 #define tsENUM   1
 132 #define tsSTRUCT 2
 133 #define tsUNION  3
 134
 135 %}
 136 %union {
 137         attr_t *attr;
 138         attr_list_t *attr_list;
 139         str_list_t *str_list;
 140         expr_t *expr;
 141         expr_list_t *expr_list;
 142         array_dims_t *array_dims;
 143         type_t *type;
 144         var_t *var;
 145         var_list_t *var_list;
 146         pident_t *pident;
 147         pident_list_t *pident_list;
 148         func_t *func;
 149         func_list_t *func_list;
 150         ifref_t *ifref;
 151         ifref_list_t *ifref_list;
 152         char *str;
 153         UUID *uuid;
 154         unsigned int num;
 155         double dbl;
 156         interface_info_t ifinfo;
 157 }
 158
 159 %token <str> aIDENTIFIER
 160 %token <str> aKNOWNTYPE
 161 %token <num> aNUM aHEXNUM
 162 %token <dbl> aDOUBLE
 163 %token <str> aSTRING
 164 %token <uuid> aUUID
 165 %token aEOF
 166 %token SHL SHR
 167 %token tAGGREGATABLE tALLOCATE tAPPOBJECT tASYNC tASYNCUUID
 168 %token tAUTOHANDLE tBINDABLE tBOOLEAN tBROADCAST tBYTE tBYTECOUNT
 169 %token tCALLAS tCALLBACK tCASE tCDECL tCHAR tCOCLASS tCODE tCOMMSTATUS
 170 %token tCONST tCONTEXTHANDLE tCONTEXTHANDLENOSERIALIZE
 171 %token tCONTEXTHANDLESERIALIZE tCONTROL tCPPQUOTE
 172 %token tDEFAULT
 173 %token tDEFAULTCOLLELEM
 174 %token tDEFAULTVALUE
 175 %token tDEFAULTVTABLE
 176 %token tDISPLAYBIND
 177 %token tDISPINTERFACE
 178 %token tDLLNAME tDOUBLE tDUAL
 179 %token tENDPOINT
 180 %token tENTRY tENUM tERRORSTATUST
 181 %token tEXPLICITHANDLE tEXTERN
 182 %token tFALSE
 183 %token tFLOAT
 184 %token tHANDLE
 185 %token tHANDLET
 186 %token tHELPCONTEXT tHELPFILE
 187 %token tHELPSTRING tHELPSTRINGCONTEXT tHELPSTRINGDLL
 188 %token tHIDDEN
 189 %token tHYPER tID tIDEMPOTENT
 190 %token tIIDIS
 191 %token tIMMEDIATEBIND
 192 %token tIMPLICITHANDLE
 193 %token tIMPORT tIMPORTLIB
 194 %token tIN tINLINE
 195 %token tINPUTSYNC
 196 %token tINT tINT64
 197 %token tINTERFACE
 198 %token tLCID
 199 %token tLENGTHIS tLIBRARY
 200 %token tLOCAL
 201 %token tLONG
 202 %token tMETHODS
 203 %token tMODULE
 204 %token tNONBROWSABLE
 205 %token tNONCREATABLE
 206 %token tNONEXTENSIBLE
 207 %token tOBJECT tODL tOLEAUTOMATION
 208 %token tOPTIONAL
 209 %token tOUT
 210 %token tPOINTERDEFAULT
 211 %token tPROPERTIES
 212 %token tPROPGET tPROPPUT tPROPPUTREF
 213 %token tPTR
 214 %token tPUBLIC
 215 %token tRANGE
 216 %token tREADONLY tREF
 217 %token tREQUESTEDIT
 218 %token tRESTRICTED
 219 %token tRETVAL
 220 %token tSAFEARRAY
 221 %token tSHORT
 222 %token tSIGNED
 223 %token tSINGLE
 224 %token tSIZEIS tSIZEOF
 225 %token tSMALL
 226 %token tSOURCE
 227 %token tSTDCALL
 228 %token tSTRICTCONTEXTHANDLE
 229 %token tSTRING tSTRUCT
 230 %token tSWITCH tSWITCHIS tSWITCHTYPE
 231 %token tTRANSMITAS
 232 %token tTRUE
 233 %token tTYPEDEF
 234 %token tUNION
 235 %token tUNIQUE
 236 %token tUNSIGNED
 237 %token tUUID
 238 %token tV1ENUM
 239 %token tVARARG
 240 %token tVERSION
 241 %token tVOID
 242 %token tWCHAR tWIREMARSHAL
 243
 244 %type <attr> attribute
 245 %type <attr_list> m_attributes attributes attrib_list
 246 %type <str_list> str_list
 247 %type <expr> m_expr expr expr_const
 248 %type <expr_list> m_exprs /* exprs expr_list */ expr_list_const
 249 %type <array_dims> array array_list
 250 %type <ifinfo> interfacehdr
 251 %type <type> inherit interface interfacedef interfacedec
 252 %type <type> dispinterface dispinterfacehdr dispinterfacedef
 253 %type <type> module modulehdr moduledef
 254 %type <type> base_type int_std
 255 %type <type> enumdef structdef uniondef
 256 %type <type> type
 257 %type <ifref> coclass_int
 258 %type <ifref_list> gbl_statements coclass_ints
 259 %type <var> arg field s_field case enum constdef externdef
 260 %type <var_list> m_args no_args args fields cases enums enum_list dispint_props
 261 %type <var> m_ident t_ident ident
 262 %type <pident> p_ident pident
 263 %type <pident_list> pident_list
 264 %type <func> funcdef
 265 %type <func_list> int_statements dispint_meths
 266 %type <type> coclass coclasshdr coclassdef
 267 %type <num> pointer_type version
 268 %type <str> libraryhdr
 269 %type <uuid> uuid_string
 270
 271 %left ','
 272 %right '?' ':'
 273 %left '|'
 274 %left '&'
 275 %left '-' '+'
 276 %left '*' '/'
 277 %left SHL SHR
 278 %right '~'
 279 %right CAST
 280 %right PPTR
 281 %right NEG
 282 %right ADDRESSOF
 283
 284 %%
 285
 286 input:   gbl_statements                         { fix_incomplete();
 287                                                   check_all_user_types($1);
 288                                                   write_proxies($1);
 289                                                   write_client($1);
 290                                                   write_server($1);
 291                                                   write_dlldata($1);
 292                                                 }
 293         ;
 294
 295 gbl_statements:                                 { $$ = NULL; }
 296         | gbl_statements interfacedec           { $$ = $1; }
 297         | gbl_statements interfacedef           { $$ = append_ifref( $1, make_ifref($2) ); }
 298         | gbl_statements coclass ';'            { $$ = $1;
 299                                                   reg_type($2, $2->name, 0);
 300                                                   if (!parse_only && do_header) write_coclass_forward($2);
 301                                                 }
 302         | gbl_statements coclassdef             { $$ = $1;
 303                                                   add_typelib_entry($2);
 304                                                   reg_type($2, $2->name, 0);
 305                                                   if (!parse_only && do_header) write_coclass_forward($2);
 306                                                 }
 307         | gbl_statements moduledef              { $$ = $1; add_typelib_entry($2); }
 308         | gbl_statements librarydef             { $$ = $1; }
 309         | gbl_statements statement              { $$ = $1; }
 310         ;
 311
 312 imp_statements:                                 {}
 313         | imp_statements interfacedec           { if (!parse_only) add_typelib_entry($2); }
 314         | imp_statements interfacedef           { if (!parse_only) add_typelib_entry($2); }
 315         | imp_statements coclass ';'            { reg_type($2, $2->name, 0); if (!parse_only && do_header) write_coclass_forward($2); }
 316         | imp_statements coclassdef             { if (!parse_only) add_typelib_entry($2);
 317                                                   reg_type($2, $2->name, 0);
 318                                                   if (!parse_only && do_header) write_coclass_forward($2);
 319                                                 }
 320         | imp_statements moduledef              { if (!parse_only) add_typelib_entry($2); }
 321         | imp_statements statement              {}
 322         | imp_statements importlib              {}
 323         ;
 324
 325 int_statements:                                 { $$ = NULL; }
 326         | int_statements funcdef ';'            { $$ = append_func( $1, $2 ); }
 327         | int_statements statement              { $$ = $1; }
 328         ;
 329
 330 statement: ';'                                  {}
 331         | constdef ';'                          { if (!parse_only && do_header) { write_constdef($1); } }
 332         | cppquote                              {}
 333         | enumdef ';'                           { if (!parse_only && do_header) {
 334                                                     write_type_def_or_decl(header, $1, FALSE, NULL);
 335                                                     fprintf(header, ";\n\n");
 336                                                   }
 337                                                 }
 338         | externdef ';'                         { if (!parse_only && do_header) { write_externdef($1); } }
 339         | import                                {}
 340         | structdef ';'                         { if (!parse_only && do_header) {
 341                                                     write_type_def_or_decl(header, $1, FALSE, NULL);
 342                                                     fprintf(header, ";\n\n");
 343                                                   }
 344                                                 }
 345         | typedef ';'                           {}
 346         | uniondef ';'                          { if (!parse_only && do_header) {
 347                                                     write_type_def_or_decl(header, $1, FALSE, NULL);
 348                                                     fprintf(header, ";\n\n");
 349                                                   }
 350                                                 }
 351         ;
 352
 353 cppquote: tCPPQUOTE '(' aSTRING ')'             { if (!parse_only && do_header) fprintf(header, "%s\n", $3); }
 354         ;
 355 import_start: tIMPORT aSTRING ';'               { assert(yychar == YYEMPTY);
 356                                                   if (!do_import($2)) yychar = aEOF; }
 357         ;
 358 import:   import_start imp_statements aEOF      {}
 359         ;
 360
 361 importlib: tIMPORTLIB '(' aSTRING ')'           { if(!parse_only) add_importlib($3); }
 362         ;
 363
 364 libraryhdr: tLIBRARY aIDENTIFIER                { $$ = $2; }
 365         ;
 366 library_start: attributes libraryhdr '{'        { start_typelib($2, $1);
 367                                                   if (!parse_only && do_header) write_library($2, $1);
 368                                                   if (!parse_only && do_idfile) write_libid($2, $1);
 369                                                 }
 370         ;
 371 librarydef: library_start imp_statements '}'    { end_typelib(); }
 372         ;
 373
 374 m_args:                                         { $$ = NULL; }
 375         | args
 376         ;
 377
 378 no_args:  tVOID                                 { $$ = NULL; }
 379         ;
 380
 381 args:     arg                                   { check_arg($1); $$ = append_var( NULL, $1 ); }
 382         | args ',' arg                          { check_arg($3); $$ = append_var( $1, $3); }
 383         | no_args
 384         ;
 385
 386 /* split into two rules to get bison to resolve a tVOID conflict */
 387 arg:      attributes type pident array          { $$ = $3->var;
 388                                                   $$->attrs = $1;
 389                                                   set_type($$, $2, $3->ptr_level, $4, TRUE);
 390                                                   free($3);
 391                                                 }
 392         | type pident array                     { $$ = $2->var;
 393                                                   set_type($$, $1, $2->ptr_level, $3, TRUE);
 394                                                   free($2);
 395                                                 }
 396         | attributes type pident '(' m_args ')' { $$ = $3->var;
 397                                                   $$->attrs = $1;
 398                                                   set_type($$, $2, $3->ptr_level - 1, NULL, TRUE);
 399                                                   free($3);
 400                                                   $$->args = $5;
 401                                                 }
 402         | type pident '(' m_args ')'            { $$ = $2->var;
 403                                                   set_type($$, $1, $2->ptr_level - 1, NULL, TRUE);
 404                                                   free($2);
 405                                                   $$->args = $4;
 406                                                 }
 407         ;
 408
 409 array:                                          { $$ = NULL; }
 410         | '[' array_list ']'                    { $$ = $2; }
 411         | '[' '*' ']'                           { $$ = append_array( NULL, make_expr(EXPR_VOID) ); }
 412         ;
 413
 414 array_list: m_expr /* size of first dimension is optional */ { $$ = append_array( NULL, $1 ); }
 415         | array_list ',' expr                   { $$ = append_array( $1, $3 ); }
 416         | array_list ']' '[' expr               { $$ = append_array( $1, $4 ); }
 417         ;
 418
 419 m_attributes:                                   { $$ = NULL; }
 420         | attributes
 421         ;
 422
 423 attributes:
 424           '[' attrib_list ']'                   { $$ = $2;
 425                                                   if (!$$)
 426                                                     error_loc("empty attribute lists unsupported\n");
 427                                                 }
 428         ;
 429
 430 attrib_list: attribute                          { $$ = append_attr( NULL, $1 ); }
 431         | attrib_list ',' attribute             { $$ = append_attr( $1, $3 ); }
 432         | attrib_list ']' '[' attribute         { $$ = append_attr( $1, $4 ); }
 433         ;
 434
 435 str_list: aSTRING                               { $$ = append_str( NULL, $1 ); }
 436         | str_list ',' aSTRING                  { $$ = append_str( $1, $3 ); }
 437         ;
 438
 439 attribute:                                      { $$ = NULL; }
 440         | tAGGREGATABLE                         { $$ = make_attr(ATTR_AGGREGATABLE); }
 441         | tAPPOBJECT                            { $$ = make_attr(ATTR_APPOBJECT); }
 442         | tASYNC                                { $$ = make_attr(ATTR_ASYNC); }
 443         | tAUTOHANDLE                           { $$ = make_attr(ATTR_AUTO_HANDLE); }
 444         | tBINDABLE                             { $$ = make_attr(ATTR_BINDABLE); }
 445         | tCALLAS '(' ident ')'                 { $$ = make_attrp(ATTR_CALLAS, $3); }
 446         | tCASE '(' expr_list_const ')'         { $$ = make_attrp(ATTR_CASE, $3); }
 447         | tCONTEXTHANDLE                        { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); }
 448         | tCONTEXTHANDLENOSERIALIZE             { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); /* RPC_CONTEXT_HANDLE_DONT_SERIALIZE */ }
 449         | tCONTEXTHANDLESERIALIZE               { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); /* RPC_CONTEXT_HANDLE_SERIALIZE */ }
 450         | tCONTROL                              { $$ = make_attr(ATTR_CONTROL); }
 451         | tDEFAULT                              { $$ = make_attr(ATTR_DEFAULT); }
 452         | tDEFAULTCOLLELEM                      { $$ = make_attr(ATTR_DEFAULTCOLLELEM); }
 453         | tDEFAULTVALUE '(' expr_const ')'      { $$ = make_attrp(ATTR_DEFAULTVALUE_EXPR, $3); }
 454         | tDEFAULTVALUE '(' aSTRING ')'         { $$ = make_attrp(ATTR_DEFAULTVALUE_STRING, $3); }
 455         | tDEFAULTVTABLE                        { $$ = make_attr(ATTR_DEFAULTVTABLE); }
 456         | tDISPLAYBIND                          { $$ = make_attr(ATTR_DISPLAYBIND); }
 457         | tDLLNAME '(' aSTRING ')'              { $$ = make_attrp(ATTR_DLLNAME, $3); }
 458         | tDUAL                                 { $$ = make_attr(ATTR_DUAL); }
 459         | tENDPOINT '(' str_list ')'            { $$ = make_attrp(ATTR_ENDPOINT, $3); }
 460         | tENTRY '(' aSTRING ')'                { $$ = make_attrp(ATTR_ENTRY_STRING, $3); }
 461         | tENTRY '(' expr_const ')'             { $$ = make_attrp(ATTR_ENTRY_ORDINAL, $3); }
 462         | tEXPLICITHANDLE                       { $$ = make_attr(ATTR_EXPLICIT_HANDLE); }
 463         | tHANDLE                               { $$ = make_attr(ATTR_HANDLE); }
 464         | tHELPCONTEXT '(' expr_const ')'       { $$ = make_attrp(ATTR_HELPCONTEXT, $3); }
 465         | tHELPFILE '(' aSTRING ')'             { $$ = make_attrp(ATTR_HELPFILE, $3); }
 466         | tHELPSTRING '(' aSTRING ')'           { $$ = make_attrp(ATTR_HELPSTRING, $3); }
 467         | tHELPSTRINGCONTEXT '(' expr_const ')' { $$ = make_attrp(ATTR_HELPSTRINGCONTEXT, $3); }
 468         | tHELPSTRINGDLL '(' aSTRING ')'        { $$ = make_attrp(ATTR_HELPSTRINGDLL, $3); }
 469         | tHIDDEN                               { $$ = make_attr(ATTR_HIDDEN); }
 470         | tID '(' expr_const ')'                { $$ = make_attrp(ATTR_ID, $3); }
 471         | tIDEMPOTENT                           { $$ = make_attr(ATTR_IDEMPOTENT); }
 472         | tIIDIS '(' expr ')'                   { $$ = make_attrp(ATTR_IIDIS, $3); }
 473         | tIMMEDIATEBIND                        { $$ = make_attr(ATTR_IMMEDIATEBIND); }
 474         | tIMPLICITHANDLE '(' tHANDLET aIDENTIFIER ')'  { $$ = make_attrp(ATTR_IMPLICIT_HANDLE, $4); }
 475         | tIN                                   { $$ = make_attr(ATTR_IN); }
 476         | tINPUTSYNC                            { $$ = make_attr(ATTR_INPUTSYNC); }
 477         | tLENGTHIS '(' m_exprs ')'             { $$ = make_attrp(ATTR_LENGTHIS, $3); }
 478         | tLOCAL                                { $$ = make_attr(ATTR_LOCAL); }
 479         | tNONBROWSABLE                         { $$ = make_attr(ATTR_NONBROWSABLE); }
 480         | tNONCREATABLE                         { $$ = make_attr(ATTR_NONCREATABLE); }
 481         | tNONEXTENSIBLE                        { $$ = make_attr(ATTR_NONEXTENSIBLE); }
 482         | tOBJECT                               { $$ = make_attr(ATTR_OBJECT); }
 483         | tODL                                  { $$ = make_attr(ATTR_ODL); }
 484         | tOLEAUTOMATION                        { $$ = make_attr(ATTR_OLEAUTOMATION); }
 485         | tOPTIONAL                             { $$ = make_attr(ATTR_OPTIONAL); }
 486         | tOUT                                  { $$ = make_attr(ATTR_OUT); }
 487         | tPOINTERDEFAULT '(' pointer_type ')'  { $$ = make_attrv(ATTR_POINTERDEFAULT, $3); }
 488         | tPROPGET                              { $$ = make_attr(ATTR_PROPGET); }
 489         | tPROPPUT                              { $$ = make_attr(ATTR_PROPPUT); }
 490         | tPROPPUTREF                           { $$ = make_attr(ATTR_PROPPUTREF); }
 491         | tPUBLIC                               { $$ = make_attr(ATTR_PUBLIC); }
 492         | tRANGE '(' expr_const ',' expr_const ')' { expr_list_t *list = append_expr( NULL, $3 );
 493                                                      list = append_expr( list, $5 );
 494                                                      $$ = make_attrp(ATTR_RANGE, list); }
 495         | tREADONLY                             { $$ = make_attr(ATTR_READONLY); }
 496         | tREQUESTEDIT                          { $$ = make_attr(ATTR_REQUESTEDIT); }
 497         | tRESTRICTED                           { $$ = make_attr(ATTR_RESTRICTED); }
 498         | tRETVAL                               { $$ = make_attr(ATTR_RETVAL); }
 499         | tSIZEIS '(' m_exprs ')'               { $$ = make_attrp(ATTR_SIZEIS, $3); }
 500         | tSOURCE                               { $$ = make_attr(ATTR_SOURCE); }
 501         | tSTRICTCONTEXTHANDLE                  { $$ = make_attr(ATTR_STRICTCONTEXTHANDLE); }
 502         | tSTRING                               { $$ = make_attr(ATTR_STRING); }
 503         | tSWITCHIS '(' expr ')'                { $$ = make_attrp(ATTR_SWITCHIS, $3); }
 504         | tSWITCHTYPE '(' type ')'              { $$ = make_attrp(ATTR_SWITCHTYPE, $3); }
 505         | tTRANSMITAS '(' type ')'              { $$ = make_attrp(ATTR_TRANSMITAS, $3); }
 506         | tUUID '(' uuid_string ')'             { $$ = make_attrp(ATTR_UUID, $3); }
 507         | tV1ENUM                               { $$ = make_attr(ATTR_V1ENUM); }
 508         | tVARARG                               { $$ = make_attr(ATTR_VARARG); }
 509         | tVERSION '(' version ')'              { $$ = make_attrv(ATTR_VERSION, $3); }
 510         | tWIREMARSHAL '(' type ')'             { $$ = make_attrp(ATTR_WIREMARSHAL, $3); }
 511         | pointer_type                          { $$ = make_attrv(ATTR_POINTERTYPE, $1); }
 512         ;
 513
 514 uuid_string:
 515           aUUID
 516         | aSTRING                               { if (!is_valid_uuid($1))
 517                                                     error_loc("invalid UUID: %s\n", $1);
 518                                                   $$ = parse_uuid($1); }
 519         ;
 520
 521 callconv:
 522         | tSTDCALL
 523         ;
 524
 525 cases:                                          { $$ = NULL; }
 526         | cases case                            { $$ = append_var( $1, $2 ); }
 527         ;
 528
 529 case:     tCASE expr ':' field                  { attr_t *a = make_attrp(ATTR_CASE, append_expr( NULL, $2 ));
 530                                                   $$ = $4; if (!$$) $$ = make_var(NULL);
 531                                                   $$->attrs = append_attr( $$->attrs, a );
 532                                                 }
 533         | tDEFAULT ':' field                    { attr_t *a = make_attr(ATTR_DEFAULT);
 534                                                   $$ = $3; if (!$$) $$ = make_var(NULL);
 535                                                   $$->attrs = append_attr( $$->attrs, a );
 536                                                 }
 537         ;
 538
 539 constdef: tCONST type ident '=' expr_const      { $$ = reg_const($3);
 540                                                   set_type($$, $2, 0, NULL, FALSE);
 541                                                   $$->eval = $5;
 542                                                 }
 543         ;
 544
 545 enums:                                          { $$ = NULL; }
 546         | enum_list ','                         { $$ = $1; }
 547         | enum_list
 548         ;
 549
 550 enum_list: enum                                 { if (!$1->eval)
 551                                                     $1->eval = make_exprl(EXPR_NUM, 0 /* default for first enum entry */);
 552                                                   $$ = append_var( NULL, $1 );
 553                                                 }
 554         | enum_list ',' enum                    { if (!$3->eval)
 555                                                   {
 556                                                     var_t *last = LIST_ENTRY( list_tail($$), var_t, entry );
 557                                                     $3->eval = make_exprl(EXPR_NUM, last->eval->cval + 1);
 558                                                   }
 559                                                   $$ = append_var( $1, $3 );
 560                                                 }
 561         ;
 562
 563 enum:     ident '=' expr_const                  { $$ = reg_const($1);
 564                                                   $$->eval = $3;
 565                                                   $$->type = make_int(0);
 566                                                 }
 567         | ident                                 { $$ = reg_const($1);
 568                                                   $$->type = make_int(0);
 569                                                 }
 570         ;
 571
 572 enumdef: tENUM t_ident '{' enums '}'            { $$ = get_typev(RPC_FC_ENUM16, $2, tsENUM);
 573                                                   $$->kind = TKIND_ENUM;
 574                                                   $$->fields = $4;
 575                                                   $$->defined = TRUE;
 576                                                   if(in_typelib)
 577                                                       add_typelib_entry($$);
 578                                                 }
 579         ;
 580
 581 m_exprs:  m_expr                                { $$ = append_expr( NULL, $1 ); }
 582         | m_exprs ',' m_expr                    { $$ = append_expr( $1, $3 ); }
 583         ;
 584
 585 /*
 586 exprs:                                          { $$ = make_expr(EXPR_VOID); }
 587         | expr_list
 588         ;
 589
 590 expr_list: expr
 591         | expr_list ',' expr                    { LINK($3, $1); $$ = $3; }
 592         ;
 593 */
 594
 595 m_expr:                                         { $$ = make_expr(EXPR_VOID); }
 596         | expr
 597         ;
 598
 599 expr:     aNUM                                  { $$ = make_exprl(EXPR_NUM, $1); }
 600         | aHEXNUM                               { $$ = make_exprl(EXPR_HEXNUM, $1); }
 601         | aDOUBLE                               { $$ = make_exprd(EXPR_DOUBLE, $1); }
 602         | tFALSE                                { $$ = make_exprl(EXPR_TRUEFALSE, 0); }
 603         | tTRUE                                 { $$ = make_exprl(EXPR_TRUEFALSE, 1); }
 604         | aIDENTIFIER                           { $$ = make_exprs(EXPR_IDENTIFIER, $1); }
 605         | expr '?' expr ':' expr                { $$ = make_expr3(EXPR_COND, $1, $3, $5); }
 606         | expr '|' expr                         { $$ = make_expr2(EXPR_OR , $1, $3); }
 607         | expr '&' expr                         { $$ = make_expr2(EXPR_AND, $1, $3); }
 608         | expr '+' expr                         { $$ = make_expr2(EXPR_ADD, $1, $3); }
 609         | expr '-' expr                         { $$ = make_expr2(EXPR_SUB, $1, $3); }
 610         | expr '*' expr                         { $$ = make_expr2(EXPR_MUL, $1, $3); }
 611         | expr '/' expr                         { $$ = make_expr2(EXPR_DIV, $1, $3); }
 612         | expr SHL expr                         { $$ = make_expr2(EXPR_SHL, $1, $3); }
 613         | expr SHR expr                         { $$ = make_expr2(EXPR_SHR, $1, $3); }
 614         | '~' expr                              { $$ = make_expr1(EXPR_NOT, $2); }
 615         | '-' expr %prec NEG                    { $$ = make_expr1(EXPR_NEG, $2); }
 616         | '&' expr %prec ADDRESSOF      { $$ = make_expr1(EXPR_ADDRESSOF, $2); }
 617         | '*' expr %prec PPTR                   { $$ = make_expr1(EXPR_PPTR, $2); }
 618         | '(' type ')' expr %prec CAST          { $$ = make_exprt(EXPR_CAST, $2, $4); }
 619         | tSIZEOF '(' type ')'                  { $$ = make_exprt(EXPR_SIZEOF, $3, NULL); }
 620         | '(' expr ')'                          { $$ = $2; }
 621         ;
 622
 623 expr_list_const: expr_const                     { $$ = append_expr( NULL, $1 ); }
 624         | expr_list_const ',' expr_const        { $$ = append_expr( $1, $3 ); }
 625         ;
 626
 627 expr_const: expr                                { $$ = $1;
 628                                                   if (!$$->is_const)
 629                                                       error_loc("expression is not constant\n");
 630                                                 }
 631         ;
 632
 633 externdef: tEXTERN tCONST type ident            { $$ = $4;
 634                                                   set_type($$, $3, 0, NULL, FALSE);
 635                                                 }
 636         ;
 637
 638 fields:                                         { $$ = NULL; }
 639         | fields field                          { $$ = append_var( $1, $2 ); }
 640         ;
 641
 642 field:    s_field ';'                           { $$ = $1; }
 643         | m_attributes uniondef ';'             { $$ = make_var(NULL); $$->type = $2; $$->attrs = $1; }
 644         | attributes ';'                        { $$ = make_var(NULL); $$->attrs = $1; }
 645         | ';'                                   { $$ = NULL; }
 646         ;
 647
 648 s_field:  m_attributes type pident array        { $$ = $3->var;
 649                                                   $$->attrs = $1;
 650                                                   set_type($$, $2, $3->ptr_level, $4, FALSE);
 651                                                   free($3);
 652                                                 }
 653         ;
 654
 655 funcdef:
 656           m_attributes type callconv pident
 657           '(' m_args ')'                        { var_t *v = $4->var;
 658                                                   v->attrs = $1;
 659                                                   set_type(v, $2, $4->ptr_level, NULL, FALSE);
 660                                                   free($4);
 661                                                   $$ = make_func(v, $6);
 662                                                   if (is_attr(v->attrs, ATTR_IN)) {
 663                                                     error_loc("inapplicable attribute [in] for function '%s'\n",$$->def->name);
 664                                                   }
 665                                                 }
 666         ;
 667
 668 m_ident:                                        { $$ = NULL; }
 669         | ident
 670         ;
 671
 672 t_ident:                                        { $$ = NULL; }
 673         | aIDENTIFIER                           { $$ = make_var($1); }
 674         | aKNOWNTYPE                            { $$ = make_var($1); }
 675         ;
 676
 677 ident:    aIDENTIFIER                           { $$ = make_var($1); }
 678 /* some "reserved words" used in attributes are also used as field names in some MS IDL files */
 679         | aKNOWNTYPE                            { $$ = make_var($<str>1); }
 680         ;
 681
 682 base_type: tBYTE                                { $$ = make_builtin($<str>1); }
 683         | tWCHAR                                { $$ = make_builtin($<str>1); }
 684         | int_std
 685         | tSIGNED int_std                       { $$ = $2; $$->sign = 1; }
 686         | tUNSIGNED int_std                     { $$ = $2; $$->sign = -1;
 687                                                   switch ($$->type) {
 688                                                   case RPC_FC_CHAR:  break;
 689                                                   case RPC_FC_SMALL: $$->type = RPC_FC_USMALL; break;
 690                                                   case RPC_FC_SHORT: $$->type = RPC_FC_USHORT; break;
 691                                                   case RPC_FC_LONG:  $$->type = RPC_FC_ULONG;  break;
 692                                                   case RPC_FC_HYPER:
 693                                                     if ($$->name[0] == 'h') /* hyper, as opposed to __int64 */
 694                                                     {
 695                                                       $$ = alias($$, "MIDL_uhyper");
 696                                                       $$->sign = 0;
 697                                                     }
 698                                                     break;
 699                                                   default: break;
 700                                                   }
 701                                                 }
 702         | tUNSIGNED                             { $$ = make_int(-1); }
 703         | tFLOAT                                { $$ = make_builtin($<str>1); }
 704         | tSINGLE                               { $$ = duptype(find_type("float", 0), 1); }
 705         | tDOUBLE                               { $$ = make_builtin($<str>1); }
 706         | tBOOLEAN                              { $$ = make_builtin($<str>1); }
 707         | tERRORSTATUST                         { $$ = make_builtin($<str>1); }
 708         | tHANDLET                              { $$ = make_builtin($<str>1); }
 709         ;
 710
 711 m_int:
 712         | tINT
 713         ;
 714
 715 int_std:  tINT                                  { $$ = make_builtin($<str>1); }
 716         | tSHORT m_int                          { $$ = make_builtin($<str>1); }
 717         | tSMALL                                { $$ = make_builtin($<str>1); }
 718         | tLONG m_int                           { $$ = make_builtin($<str>1); }
 719         | tHYPER m_int                          { $$ = make_builtin($<str>1); }
 720         | tINT64                                { $$ = make_builtin($<str>1); }
 721         | tCHAR                                 { $$ = make_builtin($<str>1); }
 722         ;
 723
 724 coclass:  tCOCLASS aIDENTIFIER                  { $$ = make_class($2); }
 725         | tCOCLASS aKNOWNTYPE                   { $$ = find_type($2, 0);
 726                                                   if ($$->defined) error_loc("multiple definition error\n");
 727                                                   if ($$->kind != TKIND_COCLASS) error_loc("%s was not declared a coclass\n", $2);
 728                                                 }
 729         ;
 730
 731 coclasshdr: attributes coclass                  { $$ = $2;
 732                                                   $$->attrs = $1;
 733                                                   if (!parse_only && do_header)
 734                                                     write_coclass($$);
 735                                                   if (!parse_only && do_idfile)
 736                                                     write_clsid($$);
 737                                                 }
 738         ;
 739
 740 coclassdef: coclasshdr '{' coclass_ints '}'     { $$ = $1;
 741                                                   $$->ifaces = $3;
 742                                                   $$->defined = TRUE;
 743                                                 }
 744         ;
 745
 746 coclass_ints:                                   { $$ = NULL; }
 747         | coclass_ints coclass_int              { $$ = append_ifref( $1, $2 ); }
 748         ;
 749
 750 coclass_int:
 751           m_attributes interfacedec             { $$ = make_ifref($2); $$->attrs = $1; }
 752         ;
 753
 754 dispinterface: tDISPINTERFACE aIDENTIFIER       { $$ = get_type(0, $2, 0); $$->kind = TKIND_DISPATCH; }
 755         |      tDISPINTERFACE aKNOWNTYPE        { $$ = get_type(0, $2, 0); $$->kind = TKIND_DISPATCH; }
 756         ;
 757
 758 dispinterfacehdr: attributes dispinterface      { attr_t *attrs;
 759                                                   $$ = $2;
 760                                                   if ($$->defined) error_loc("multiple definition error\n");
 761                                                   attrs = make_attr(ATTR_DISPINTERFACE);
 762                                                   $$->attrs = append_attr( $1, attrs );
 763                                                   $$->ref = find_type("IDispatch", 0);
 764                                                   if (!$$->ref) error_loc("IDispatch is undefined\n");
 765                                                   $$->defined = TRUE;
 766                                                   if (!parse_only && do_header) write_forward($$);
 767                                                 }
 768         ;
 769
 770 dispint_props: tPROPERTIES ':'                  { $$ = NULL; }
 771         | dispint_props s_field ';'             { $$ = append_var( $1, $2 ); }
 772         ;
 773
 774 dispint_meths: tMETHODS ':'                     { $$ = NULL; }
 775         | dispint_meths funcdef ';'             { $$ = append_func( $1, $2 ); }
 776         ;
 777
 778 dispinterfacedef: dispinterfacehdr '{'
 779           dispint_props
 780           dispint_meths
 781           '}'                                   { $$ = $1;
 782                                                   $$->fields = $3;
 783                                                   $$->funcs = $4;
 784                                                   if (!parse_only && do_header) write_dispinterface($$);
 785                                                   if (!parse_only && do_idfile) write_diid($$);
 786                                                 }
 787         | dispinterfacehdr
 788          '{' interface ';' '}'                  { $$ = $1;
 789                                                   $$->fields = $3->fields;
 790                                                   $$->funcs = $3->funcs;
 791                                                   if (!parse_only && do_header) write_dispinterface($$);
 792                                                   if (!parse_only && do_idfile) write_diid($$);
 793                                                 }
 794         ;
 795
 796 inherit:                                        { $$ = NULL; }
 797         | ':' aKNOWNTYPE                        { $$ = find_type2($2, 0); }
 798         ;
 799
 800 interface: tINTERFACE aIDENTIFIER               { $$ = get_type(RPC_FC_IP, $2, 0); $$->kind = TKIND_INTERFACE; }
 801         |  tINTERFACE aKNOWNTYPE                { $$ = get_type(RPC_FC_IP, $2, 0); $$->kind = TKIND_INTERFACE; }
 802         ;
 803
 804 interfacehdr: attributes interface              { $$.interface = $2;
 805                                                   $$.old_pointer_default = pointer_default;
 806                                                   if (is_attr($1, ATTR_POINTERDEFAULT))
 807                                                     pointer_default = get_attrv($1, ATTR_POINTERDEFAULT);
 808                                                   if ($2->defined) error_loc("multiple definition error\n");
 809                                                   $2->attrs = $1;
 810                                                   $2->defined = TRUE;
 811                                                   if (!parse_only && do_header) write_forward($2);
 812                                                 }
 813         ;
 814
 815 interfacedef: interfacehdr inherit
 816           '{' int_statements '}'                { $$ = $1.interface;
 817                                                   $$->ref = $2;
 818                                                   $$->funcs = $4;
 819                                                   compute_method_indexes($$);
 820                                                   if (!parse_only && do_header) write_interface($$);
 821                                                   if (!parse_only && local_stubs) write_locals(local_stubs, $$, TRUE);
 822                                                   if (!parse_only && do_idfile) write_iid($$);
 823                                                   pointer_default = $1.old_pointer_default;
 824                                                 }
 825 /* MIDL is able to import the definition of a base class from inside the
 826  * definition of a derived class, I'll try to support it with this rule */
 827         | interfacehdr ':' aIDENTIFIER
 828           '{' import int_statements '}'         { $$ = $1.interface;
 829                                                   $$->ref = find_type2($3, 0);
 830                                                   if (!$$->ref) error_loc("base class '%s' not found in import\n", $3);
 831                                                   $$->funcs = $6;
 832                                                   compute_method_indexes($$);
 833                                                   if (!parse_only && do_header) write_interface($$);
 834                                                   if (!parse_only && local_stubs) write_locals(local_stubs, $$, TRUE);
 835                                                   if (!parse_only && do_idfile) write_iid($$);
 836                                                   pointer_default = $1.old_pointer_default;
 837                                                 }
 838         | dispinterfacedef                      { $$ = $1; }
 839         ;
 840
 841 interfacedec:
 842           interface ';'                         { $$ = $1; if (!parse_only && do_header) write_forward($$); }
 843         | dispinterface ';'                     { $$ = $1; if (!parse_only && do_header) write_forward($$); }
 844         ;
 845
 846 module:   tMODULE aIDENTIFIER                   { $$ = make_type(0, NULL); $$->name = $2; $$->kind = TKIND_MODULE; }
 847         | tMODULE aKNOWNTYPE                    { $$ = make_type(0, NULL); $$->name = $2; $$->kind = TKIND_MODULE; }
 848         ;
 849
 850 modulehdr: attributes module                    { $$ = $2;
 851                                                   $$->attrs = $1;
 852                                                 }
 853         ;
 854
 855 moduledef: modulehdr '{' int_statements '}'     { $$ = $1;
 856                                                   $$->funcs = $3;
 857                                                   /* FIXME: if (!parse_only && do_header) write_module($$); */
 858                                                 }
 859         ;
 860
 861 p_ident:  '*' pident %prec PPTR                 { $$ = $2; $$->ptr_level++; }
 862         | tCONST p_ident                        { $$ = $2; /* FIXME */ }
 863         ;
 864
 865 pident:   ident                                 { $$ = make_pident($1); }
 866         | p_ident
 867         | '(' pident ')'                        { $$ = $2; }
 868         ;
 869
 870 pident_list:
 871         pident                                  { $$ = append_pident( NULL, $1 ); }
 872         | pident_list ',' pident                { $$ = append_pident( $1, $3 ); }
 873         ;
 874
 875 pointer_type:
 876           tREF                                  { $$ = RPC_FC_RP; }
 877         | tUNIQUE                               { $$ = RPC_FC_UP; }
 878         | tPTR                                  { $$ = RPC_FC_FP; }
 879         ;
 880
 881 structdef: tSTRUCT t_ident '{' fields '}'       { $$ = get_typev(RPC_FC_STRUCT, $2, tsSTRUCT);
 882                                                   /* overwrite RPC_FC_STRUCT with a more exact type */
 883                                                   $$->type = get_struct_type( $4 );
 884                                                   $$->kind = TKIND_RECORD;
 885                                                   $$->fields = $4;
 886                                                   $$->defined = TRUE;
 887                                                   if(in_typelib)
 888                                                       add_typelib_entry($$);
 889                                                 }
 890         ;
 891
 892 type:     tVOID                                 { $$ = duptype(find_type("void", 0), 1); }
 893         | aKNOWNTYPE                            { $$ = find_type($1, 0); }
 894         | base_type                             { $$ = $1; }
 895         | tCONST type                           { $$ = duptype($2, 1); $$->is_const = TRUE; }
 896         | enumdef                               { $$ = $1; }
 897         | tENUM aIDENTIFIER                     { $$ = find_type2($2, tsENUM); }
 898         | structdef                             { $$ = $1; }
 899         | tSTRUCT aIDENTIFIER                   { $$ = get_type(RPC_FC_STRUCT, $2, tsSTRUCT); }
 900         | uniondef                              { $$ = $1; }
 901         | tUNION aIDENTIFIER                    { $$ = find_type2($2, tsUNION); }
 902         | tSAFEARRAY '(' type ')'               { $$ = make_safearray($3); }
 903         ;
 904
 905 typedef: tTYPEDEF m_attributes type pident_list { reg_typedefs($3, $4, $2);
 906                                                   process_typedefs($4);
 907                                                 }
 908         ;
 909
 910 uniondef: tUNION t_ident '{' fields '}'         { $$ = get_typev(RPC_FC_NON_ENCAPSULATED_UNION, $2, tsUNION);
 911                                                   $$->kind = TKIND_UNION;
 912                                                   $$->fields = $4;
 913                                                   $$->defined = TRUE;
 914                                                 }
 915         | tUNION t_ident
 916           tSWITCH '(' s_field ')'
 917           m_ident '{' cases '}'                 { var_t *u = $7;
 918                                                   $$ = get_typev(RPC_FC_ENCAPSULATED_UNION, $2, tsUNION);
 919                                                   $$->kind = TKIND_UNION;
 920                                                   if (!u) u = make_var( xstrdup("tagged_union") );
 921                                                   u->type = make_type(RPC_FC_NON_ENCAPSULATED_UNION, NULL);
 922                                                   u->type->kind = TKIND_UNION;
 923                                                   u->type->fields = $9;
 924                                                   u->type->defined = TRUE;
 925                                                   $$->fields = append_var( $$->fields, $5 );
 926                                                   $$->fields = append_var( $$->fields, u );
 927                                                   $$->defined = TRUE;
 928                                                 }
 929         ;
 930
 931 version:
 932           aNUM                                  { $$ = MAKEVERSION($1, 0); }
 933         | aNUM '.' aNUM                         { $$ = MAKEVERSION($1, $3); }
 934         ;
 935
 936 %%
 937
 938 static void decl_builtin(const char *name, unsigned char type)
 939 {
 940   type_t *t = make_type(type, NULL);
 941   t->name = xstrdup(name);
 942   reg_type(t, name, 0);
 943 }
 944
 945 static type_t *make_builtin(char *name)
 946 {
 947   /* NAME is strdup'd in the lexer */
 948   type_t *t = duptype(find_type(name, 0), 0);
 949   t->name = name;
 950   return t;
 951 }
 952
 953 static type_t *make_int(int sign)
 954 {
 955   type_t *t = duptype(find_type("int", 0), 1);
 956
 957   t->sign = sign;
 958   if (sign < 0)
 959     t->type = t->type == RPC_FC_LONG ? RPC_FC_ULONG : RPC_FC_USHORT;
 960
 961   return t;
 962 }
 963
 964 void init_types(void)
 965 {
 966   decl_builtin("void", 0);
 967   decl_builtin("byte", RPC_FC_BYTE);
 968   decl_builtin("wchar_t", RPC_FC_WCHAR);
 969   decl_builtin("int", RPC_FC_LONG);     /* win32 */
 970   decl_builtin("short", RPC_FC_SHORT);
 971   decl_builtin("small", RPC_FC_SMALL);
 972   decl_builtin("long", RPC_FC_LONG);
 973   decl_builtin("hyper", RPC_FC_HYPER);
 974   decl_builtin("__int64", RPC_FC_HYPER);
 975   decl_builtin("char", RPC_FC_CHAR);
 976   decl_builtin("float", RPC_FC_FLOAT);
 977   decl_builtin("double", RPC_FC_DOUBLE);
 978   decl_builtin("boolean", RPC_FC_BYTE);
 979   decl_builtin("error_status_t", RPC_FC_ERROR_STATUS_T);
 980   decl_builtin("handle_t", RPC_FC_BIND_PRIMITIVE);
 981 }
 982
 983 static str_list_t *append_str(str_list_t *list, char *str)
 984 {
 985     struct str_list_entry_t *entry;
 986
 987     if (!str) return list;
 988     if (!list)
 989     {
 990         list = xmalloc( sizeof(*list) );
 991         list_init( list );
 992     }
 993     entry = xmalloc( sizeof(*entry) );
 994     entry->str = str;
 995     list_add_tail( list, &entry->entry );
 996     return list;
 997 }
 998
 999 static attr_list_t *append_attr(attr_list_t *list, attr_t *attr)
1000 {
1001     if (!attr) return list;
1002     if (!list)
1003     {
1004         list = xmalloc( sizeof(*list) );
1005         list_init( list );
1006     }
1007     list_add_tail( list, &attr->entry );
1008     return list;
1009 }
1010
1011 static attr_t *make_attr(enum attr_type type)
1012 {
1013   attr_t *a = xmalloc(sizeof(attr_t));
1014   a->type = type;
1015   a->u.ival = 0;
1016   return a;
1017 }
1018
1019 static attr_t *make_attrv(enum attr_type type, unsigned long val)
1020 {
1021   attr_t *a = xmalloc(sizeof(attr_t));
1022   a->type = type;
1023   a->u.ival = val;
1024   return a;
1025 }
1026
1027 static attr_t *make_attrp(enum attr_type type, void *val)
1028 {
1029   attr_t *a = xmalloc(sizeof(attr_t));
1030   a->type = type;
1031   a->u.pval = val;
1032   return a;
1033 }
1034
1035 static expr_t *make_expr(enum expr_type type)
1036 {
1037   expr_t *e = xmalloc(sizeof(expr_t));
1038   e->type = type;
1039   e->ref = NULL;
1040   e->u.lval = 0;
1041   e->is_const = FALSE;
1042   e->cval = 0;
1043   return e;
1044 }
1045
1046 static expr_t *make_exprl(enum expr_type type, long val)
1047 {
1048   expr_t *e = xmalloc(sizeof(expr_t));
1049   e->type = type;
1050   e->ref = NULL;
1051   e->u.lval = val;
1052   e->is_const = FALSE;
1053   /* check for numeric constant */
1054   if (type == EXPR_NUM || type == EXPR_HEXNUM || type == EXPR_TRUEFALSE) {
1055     /* make sure true/false value is valid */
1056     assert(type != EXPR_TRUEFALSE || val == 0 || val == 1);
1057     e->is_const = TRUE;
1058     e->cval = val;
1059   }
1060   return e;
1061 }
1062
1063 static expr_t *make_exprd(enum expr_type type, double val)
1064 {
1065   expr_t *e = xmalloc(sizeof(expr_t));
1066   e->type = type;
1067   e->ref = NULL;
1068   e->u.dval = val;
1069   e->is_const = TRUE;
1070   e->cval = val;
1071   return e;
1072 }
1073
1074 static expr_t *make_exprs(enum expr_type type, char *val)
1075 {
1076   expr_t *e;
1077   e = xmalloc(sizeof(expr_t));
1078   e->type = type;
1079   e->ref = NULL;
1080   e->u.sval = val;
1081   e->is_const = FALSE;
1082   /* check for predefined constants */
1083   if (type == EXPR_IDENTIFIER) {
1084     var_t *c = find_const(val, 0);
1085     if (c) {
1086       e->u.sval = c->name;
1087       free(val);
1088       e->is_const = TRUE;
1089       e->cval = c->eval->cval;
1090     }
1091   }
1092   return e;
1093 }
1094
1095 static expr_t *make_exprt(enum expr_type type, type_t *tref, expr_t *expr)
1096 {
1097   expr_t *e;
1098   e = xmalloc(sizeof(expr_t));
1099   e->type = type;
1100   e->ref = expr;
1101   e->u.tref = tref;
1102   e->is_const = FALSE;
1103   /* check for cast of constant expression */
1104   if (type == EXPR_SIZEOF) {
1105     switch (tref->type) {
1106       case RPC_FC_BYTE:
1107       case RPC_FC_CHAR:
1108       case RPC_FC_SMALL:
1109       case RPC_FC_USMALL:
1110         e->is_const = TRUE;
1111         e->cval = 1;
1112         break;
1113       case RPC_FC_WCHAR:
1114       case RPC_FC_USHORT:
1115       case RPC_FC_SHORT:
1116         e->is_const = TRUE;
1117         e->cval = 2;
1118         break;
1119       case RPC_FC_LONG:
1120       case RPC_FC_ULONG:
1121       case RPC_FC_FLOAT:
1122       case RPC_FC_ERROR_STATUS_T:
1123         e->is_const = TRUE;
1124         e->cval = 4;
1125         break;
1126       case RPC_FC_HYPER:
1127       case RPC_FC_DOUBLE:
1128         e->is_const = TRUE;
1129         e->cval = 8;
1130         break;
1131     }
1132   }
1133   if (type == EXPR_CAST && expr->is_const) {
1134     e->is_const = TRUE;
1135     e->cval = expr->cval;
1136   }
1137   return e;
1138 }
1139
1140 static expr_t *make_expr1(enum expr_type type, expr_t *expr)
1141 {
1142   expr_t *e;
1143   if (type == EXPR_ADDRESSOF && expr->type != EXPR_IDENTIFIER)
1144     error("address-of operator applied to invalid expression\n");
1145   e = xmalloc(sizeof(expr_t));
1146   e->type = type;
1147   e->ref = expr;
1148   e->u.lval = 0;
1149   e->is_const = FALSE;
1150   /* check for compile-time optimization */
1151   if (expr->is_const) {
1152     e->is_const = TRUE;
1153     switch (type) {
1154     case EXPR_NEG:
1155       e->cval = -expr->cval;
1156       break;
1157     case EXPR_NOT:
1158       e->cval = ~expr->cval;
1159       break;
1160     default:
1161       e->is_const = FALSE;
1162       break;
1163     }
1164   }
1165   return e;
1166 }
1167
1168 static expr_t *make_expr2(enum expr_type type, expr_t *expr1, expr_t *expr2)
1169 {
1170   expr_t *e;
1171   e = xmalloc(sizeof(expr_t));
1172   e->type = type;
1173   e->ref = expr1;
1174   e->u.ext = expr2;
1175   e->is_const = FALSE;
1176   /* check for compile-time optimization */
1177   if (expr1->is_const && expr2->is_const) {
1178     e->is_const = TRUE;
1179     switch (type) {
1180     case EXPR_ADD:
1181       e->cval = expr1->cval + expr2->cval;
1182       break;
1183     case EXPR_SUB:
1184       e->cval = expr1->cval - expr2->cval;
1185       break;
1186     case EXPR_MUL:
1187       e->cval = expr1->cval * expr2->cval;
1188       break;
1189     case EXPR_DIV:
1190       e->cval = expr1->cval / expr2->cval;
1191       break;
1192     case EXPR_OR:
1193       e->cval = expr1->cval | expr2->cval;
1194       break;
1195     case EXPR_AND:
1196       e->cval = expr1->cval & expr2->cval;
1197       break;
1198     case EXPR_SHL:
1199       e->cval = expr1->cval << expr2->cval;
1200       break;
1201     case EXPR_SHR:
1202       e->cval = expr1->cval >> expr2->cval;
1203       break;
1204     default:
1205       e->is_const = FALSE;
1206       break;
1207     }
1208   }
1209   return e;
1210 }
1211
1212 static expr_t *make_expr3(enum expr_type type, expr_t *expr1, expr_t *expr2, expr_t *expr3)
1213 {
1214   expr_t *e;
1215   e = xmalloc(sizeof(expr_t));
1216   e->type = type;
1217   e->ref = expr1;
1218   e->u.ext = expr2;
1219   e->ext2 = expr3;
1220   e->is_const = FALSE;
1221   /* check for compile-time optimization */
1222   if (expr1->is_const && expr2->is_const && expr3->is_const) {
1223     e->is_const = TRUE;
1224     switch (type) {
1225     case EXPR_COND:
1226       e->cval = expr1->cval ? expr2->cval : expr3->cval;
1227       break;
1228     default:
1229       e->is_const = FALSE;
1230       break;
1231     }
1232   }
1233   return e;
1234 }
1235
1236 static expr_list_t *append_expr(expr_list_t *list, expr_t *expr)
1237 {
1238     if (!expr) return list;
1239     if (!list)
1240     {
1241         list = xmalloc( sizeof(*list) );
1242         list_init( list );
1243     }
1244     list_add_tail( list, &expr->entry );
1245     return list;
1246 }
1247
1248 static array_dims_t *append_array(array_dims_t *list, expr_t *expr)
1249 {
1250     if (!expr) return list;
1251     if (!list)
1252     {
1253         list = xmalloc( sizeof(*list) );
1254         list_init( list );
1255     }
1256     list_add_tail( list, &expr->entry );
1257     return list;
1258 }
1259
1260 static struct list type_pool = LIST_INIT(type_pool);
1261 typedef struct
1262 {
1263   type_t data;
1264   struct list link;
1265 } type_pool_node_t;
1266
1267 type_t *alloc_type(void)
1268 {
1269   type_pool_node_t *node = xmalloc(sizeof *node);
1270   list_add_tail(&type_pool, &node->link);
1271   return &node->data;
1272 }
1273
1274 void set_all_tfswrite(int val)
1275 {
1276   type_pool_node_t *node;
1277   LIST_FOR_EACH_ENTRY(node, &type_pool, type_pool_node_t, link)
1278     node->data.tfswrite = val;
1279 }
1280
1281 static type_t *make_type(unsigned char type, type_t *ref)
1282 {
1283   type_t *t = alloc_type();
1284   t->name = NULL;
1285   t->kind = TKIND_PRIMITIVE;
1286   t->type = type;
1287   t->ref = ref;
1288   t->attrs = NULL;
1289   t->orig = NULL;
1290   t->funcs = NULL;
1291   t->fields = NULL;
1292   t->ifaces = NULL;
1293   t->dim = 0;
1294   t->size_is = NULL;
1295   t->length_is = NULL;
1296   t->typestring_offset = 0;
1297   t->ptrdesc = 0;
1298   t->declarray = FALSE;
1299   t->ignore = (parse_only != 0);
1300   t->is_const = FALSE;
1301   t->sign = 0;
1302   t->defined = FALSE;
1303   t->written = FALSE;
1304   t->user_types_registered = FALSE;
1305   t->tfswrite = FALSE;
1306   t->typelib_idx = -1;
1307   return t;
1308 }
1309
1310 static void set_type(var_t *v, type_t *type, int ptr_level, array_dims_t *arr,
1311                      int top)
1312 {
1313   expr_list_t *sizes = get_attrp(v->attrs, ATTR_SIZEIS);
1314   expr_list_t *lengs = get_attrp(v->attrs, ATTR_LENGTHIS);
1315   int ptr_attr = get_attrv(v->attrs, ATTR_POINTERTYPE);
1316   int ptr_type = ptr_attr;
1317   int sizeless, has_varconf;
1318   expr_t *dim;
1319   type_t *atype, **ptype;
1320
1321   v->type = type;
1322
1323   if (!ptr_type && top)
1324     ptr_type = RPC_FC_RP;
1325
1326   for ( ; 0 < ptr_level; --ptr_level)
1327   {
1328     v->type = make_type(pointer_default, v->type);
1329     if (ptr_level == 1 && ptr_type && !arr)
1330     {
1331       v->type->type = ptr_type;
1332       ptr_type = 0;
1333     }
1334   }
1335
1336   if (ptr_type && !arr)
1337   {
1338     if (is_ptr(v->type))
1339     {
1340       if (v->type->type != ptr_type)
1341       {
1342         v->type = duptype(v->type, 1);
1343         v->type->type = ptr_type;
1344       }
1345     }
1346     else if (!arr && ptr_attr)
1347       error("%s: pointer attribute applied to non-pointer type\n", v->name);
1348   }
1349
1350   sizeless = FALSE;
1351   if (arr) LIST_FOR_EACH_ENTRY_REV(dim, arr, expr_t, entry)
1352   {
1353     if (sizeless)
1354       error("%s: only the first array dimension can be unspecified\n", v->name);
1355
1356     if (dim->is_const)
1357     {
1358       unsigned int align = 0;
1359       size_t size = type_memsize(v->type, &align);
1360
1361       if (dim->cval <= 0)
1362         error("%s: array dimension must be positive\n", v->name);
1363
1364       if (0xffffffffuL / size < (unsigned long) dim->cval)
1365         error("%s: total array size is too large\n", v->name);
1366       else if (0xffffuL < size * dim->cval)
1367         v->type = make_type(RPC_FC_LGFARRAY, v->type);
1368       else
1369         v->type = make_type(RPC_FC_SMFARRAY, v->type);
1370     }
1371     else
1372     {
1373       sizeless = TRUE;
1374       v->type = make_type(RPC_FC_CARRAY, v->type);
1375     }
1376
1377     v->type->declarray = TRUE;
1378     v->type->dim = dim->cval;
1379   }
1380
1381   ptype = &v->type;
1382   has_varconf = FALSE;
1383   if (sizes) LIST_FOR_EACH_ENTRY(dim, sizes, expr_t, entry)
1384   {
1385     if (dim->type != EXPR_VOID)
1386     {
1387       has_varconf = TRUE;
1388       atype = *ptype = duptype(*ptype, 0);
1389
1390       if (atype->type == RPC_FC_SMFARRAY || atype->type == RPC_FC_LGFARRAY)
1391         error("%s: cannot specify size_is for a fixed sized array\n", v->name);
1392
1393       if (atype->type != RPC_FC_CARRAY && !is_ptr(atype))
1394         error("%s: size_is attribute applied to illegal type\n", v->name);
1395
1396       atype->type = RPC_FC_CARRAY;
1397       atype->size_is = dim;
1398     }
1399
1400     ptype = &(*ptype)->ref;
1401     if (*ptype == NULL)
1402       error("%s: too many expressions in size_is attribute\n", v->name);
1403   }
1404
1405   ptype = &v->type;
1406   if (lengs) LIST_FOR_EACH_ENTRY(dim, lengs, expr_t, entry)
1407   {
1408     if (dim->type != EXPR_VOID)
1409     {
1410       has_varconf = TRUE;
1411       atype = *ptype = duptype(*ptype, 0);
1412
1413       if (atype->type == RPC_FC_SMFARRAY)
1414         atype->type = RPC_FC_SMVARRAY;
1415       else if (atype->type == RPC_FC_LGFARRAY)
1416         atype->type = RPC_FC_LGVARRAY;
1417       else if (atype->type == RPC_FC_CARRAY)
1418         atype->type = RPC_FC_CVARRAY;
1419       else
1420         error("%s: length_is attribute applied to illegal type\n", v->name);
1421
1422       atype->length_is = dim;
1423     }
1424
1425     ptype = &(*ptype)->ref;
1426     if (*ptype == NULL)
1427       error("%s: too many expressions in length_is attribute\n", v->name);
1428   }
1429
1430   if (has_varconf && !last_array(v->type))
1431   {
1432     ptype = &v->type;
1433     for (ptype = &v->type; is_array(*ptype); ptype = &(*ptype)->ref)
1434     {
1435       *ptype = duptype(*ptype, 0);
1436       (*ptype)->type = RPC_FC_BOGUS_ARRAY;
1437     }
1438   }
1439
1440   if (is_array(v->type))
1441   {
1442     const type_t *rt = v->type->ref;
1443     if (is_user_type(rt))
1444       v->type->type = RPC_FC_BOGUS_ARRAY;
1445     else
1446       switch (rt->type)
1447         {
1448         case RPC_FC_BOGUS_STRUCT:
1449         case RPC_FC_NON_ENCAPSULATED_UNION:
1450         case RPC_FC_ENCAPSULATED_UNION:
1451         case RPC_FC_ENUM16:
1452           v->type->type = RPC_FC_BOGUS_ARRAY;
1453           break;
1454           /* FC_RP should be above, but widl overuses these, and will break things.  */
1455         case RPC_FC_UP:
1456         case RPC_FC_RP:
1457           if (rt->ref->type == RPC_FC_IP)
1458             v->type->type = RPC_FC_BOGUS_ARRAY;
1459           break;
1460         }
1461   }
1462 }
1463
1464 static ifref_list_t *append_ifref(ifref_list_t *list, ifref_t *iface)
1465 {
1466     if (!iface) return list;
1467     if (!list)
1468     {
1469         list = xmalloc( sizeof(*list) );
1470         list_init( list );
1471     }
1472     list_add_tail( list, &iface->entry );
1473     return list;
1474 }
1475
1476 static ifref_t *make_ifref(type_t *iface)
1477 {
1478   ifref_t *l = xmalloc(sizeof(ifref_t));
1479   l->iface = iface;
1480   l->attrs = NULL;
1481   return l;
1482 }
1483
1484 static var_list_t *append_var(var_list_t *list, var_t *var)
1485 {
1486     if (!var) return list;
1487     if (!list)
1488     {
1489         list = xmalloc( sizeof(*list) );
1490         list_init( list );
1491     }
1492     list_add_tail( list, &var->entry );
1493     return list;
1494 }
1495
1496 static var_t *make_var(char *name)
1497 {
1498   var_t *v = xmalloc(sizeof(var_t));
1499   v->name = name;
1500   v->type = NULL;
1501   v->args = NULL;
1502   v->attrs = NULL;
1503   v->eval = NULL;
1504   return v;
1505 }
1506
1507 static pident_list_t *append_pident(pident_list_t *list, pident_t *p)
1508 {
1509   if (!p) return list;
1510   if (!list) {
1511     list = xmalloc(sizeof(*list));
1512     list_init(list);
1513   }
1514   list_add_tail(list, &p->entry);
1515   return list;
1516 }
1517
1518 static pident_t *make_pident(var_t *var)
1519 {
1520   pident_t *p = xmalloc(sizeof(*p));
1521   p->var = var;
1522   p->ptr_level = 0;
1523   return p;
1524 }
1525
1526 static func_list_t *append_func(func_list_t *list, func_t *func)
1527 {
1528     if (!func) return list;
1529     if (!list)
1530     {
1531         list = xmalloc( sizeof(*list) );
1532         list_init( list );
1533     }
1534     list_add_tail( list, &func->entry );
1535     return list;
1536 }
1537
1538 static func_t *make_func(var_t *def, var_list_t *args)
1539 {
1540   func_t *f = xmalloc(sizeof(func_t));
1541   f->def = def;
1542   f->args = args;
1543   f->ignore = parse_only;
1544   f->idx = -1;
1545   return f;
1546 }
1547
1548 static type_t *make_class(char *name)
1549 {
1550   type_t *c = make_type(0, NULL);
1551   c->name = name;
1552   c->kind = TKIND_COCLASS;
1553   return c;
1554 }
1555
1556 static type_t *make_safearray(type_t *type)
1557 {
1558   type_t *sa = duptype(find_type("SAFEARRAY", 0), 1);
1559   sa->ref = type;
1560   return make_type(pointer_default, sa);
1561 }
1562
1563 #define HASHMAX 64
1564
1565 static int hash_ident(const char *name)
1566 {
1567   const char *p = name;
1568   int sum = 0;
1569   /* a simple sum hash is probably good enough */
1570   while (*p) {
1571     sum += *p;
1572     p++;
1573   }
1574   return sum & (HASHMAX-1);
1575 }
1576
1577 /***** type repository *****/
1578
1579 struct rtype {
1580   const char *name;
1581   type_t *type;
1582   int t;
1583   struct rtype *next;
1584 };
1585
1586 struct rtype *type_hash[HASHMAX];
1587
1588 static type_t *reg_type(type_t *type, const char *name, int t)
1589 {
1590   struct rtype *nt;
1591   int hash;
1592   if (!name) {
1593     error_loc("registering named type without name\n");
1594     return type;
1595   }
1596   hash = hash_ident(name);
1597   nt = xmalloc(sizeof(struct rtype));
1598   nt->name = name;
1599   nt->type = type;
1600   nt->t = t;
1601   nt->next = type_hash[hash];
1602   type_hash[hash] = nt;
1603   return type;
1604 }
1605
1606 static int is_incomplete(const type_t *t)
1607 {
1608   return !t->defined && (is_struct(t->type) || is_union(t->type));
1609 }
1610
1611 static void add_incomplete(type_t *t)
1612 {
1613   struct typenode *tn = xmalloc(sizeof *tn);
1614   tn->type = t;
1615   list_add_tail(&incomplete_types, &tn->entry);
1616 }
1617
1618 static void fix_type(type_t *t)
1619 {
1620   if (t->kind == TKIND_ALIAS && is_incomplete(t)) {
1621     type_t *ot = t->orig;
1622     fix_type(ot);
1623     t->fields = ot->fields;
1624     t->defined = ot->defined;
1625   }
1626 }
1627
1628 static void fix_incomplete(void)
1629 {
1630   struct typenode *tn, *next;
1631
1632   LIST_FOR_EACH_ENTRY_SAFE(tn, next, &incomplete_types, struct typenode, entry) {
1633     fix_type(tn->type);
1634     free(tn);
1635   }
1636 }
1637
1638 static type_t *reg_typedefs(type_t *type, pident_list_t *pidents, attr_list_t *attrs)
1639 {
1640   type_t *ptr = type;
1641   const pident_t *pident;
1642   int ptrc = 0;
1643   int is_str = is_attr(attrs, ATTR_STRING);
1644   unsigned char ptr_type = get_attrv(attrs, ATTR_POINTERTYPE);
1645
1646   if (is_str)
1647   {
1648     type_t *t = type;
1649     unsigned char c;
1650
1651     while (is_ptr(t))
1652       t = t->ref;
1653
1654     c = t->type;
1655     if (c != RPC_FC_CHAR && c != RPC_FC_BYTE && c != RPC_FC_WCHAR)
1656     {
1657       pident = LIST_ENTRY( list_head( pidents ), const pident_t, entry );
1658       error_loc("'%s': [string] attribute is only valid on 'char', 'byte', or 'wchar_t' pointers and arrays\n",
1659               pident->var->name);
1660     }
1661   }
1662
1663   /* We must generate names for tagless enum, struct or union.
1664      Typedef-ing a tagless enum, struct or union means we want the typedef
1665      to be included in a library whether it has other attributes or not,
1666      hence the public attribute.  */
1667   if ((type->kind == TKIND_ENUM || type->kind == TKIND_RECORD
1668        || type->kind == TKIND_UNION) && ! type->name && ! parse_only)
1669   {
1670     if (! is_attr(attrs, ATTR_PUBLIC))
1671       attrs = append_attr( attrs, make_attr(ATTR_PUBLIC) );
1672     type->name = gen_name();
1673   }
1674
1675   LIST_FOR_EACH_ENTRY( pident, pidents, const pident_t, entry )
1676   {
1677     var_t *name = pident->var;
1678
1679     if (name->name) {
1680       type_t *cur = ptr;
1681       int cptr = pident->ptr_level;
1682       if (cptr > ptrc) {
1683         while (cptr > ptrc) {
1684           cur = ptr = make_type(pointer_default, cur);
1685           ptrc++;
1686         }
1687       } else {
1688         while (cptr < ptrc) {
1689           cur = cur->ref;
1690           cptr++;
1691         }
1692       }
1693       cur = alias(cur, name->name);
1694       cur->attrs = attrs;
1695       if (ptr_type)
1696       {
1697         if (is_ptr(cur))
1698           cur->type = ptr_type;
1699         else
1700           error_loc("'%s': pointer attribute applied to non-pointer type\n",
1701                   cur->name);
1702       }
1703       else if (is_str && ! is_ptr(cur))
1704         error_loc("'%s': [string] attribute applied to non-pointer type\n",
1705                 cur->name);
1706
1707       if (is_incomplete(cur))
1708         add_incomplete(cur);
1709       reg_type(cur, cur->name, 0);
1710     }
1711   }
1712   return type;
1713 }
1714
1715 static type_t *find_type(const char *name, int t)
1716 {
1717   struct rtype *cur = type_hash[hash_ident(name)];
1718   while (cur && (cur->t != t || strcmp(cur->name, name)))
1719     cur = cur->next;
1720   if (!cur) {
1721     error_loc("type '%s' not found\n", name);
1722     return NULL;
1723   }
1724   return cur->type;
1725 }
1726
1727 static type_t *find_type2(char *name, int t)
1728 {
1729   type_t *tp = find_type(name, t);
1730   free(name);
1731   return tp;
1732 }
1733
1734 int is_type(const char *name)
1735 {
1736   struct rtype *cur = type_hash[hash_ident(name)];
1737   while (cur && (cur->t || strcmp(cur->name, name)))
1738     cur = cur->next;
1739   if (cur) return TRUE;
1740   return FALSE;
1741 }
1742
1743 static type_t *get_type(unsigned char type, char *name, int t)
1744 {
1745   struct rtype *cur = NULL;
1746   type_t *tp;
1747   if (name) {
1748     cur = type_hash[hash_ident(name)];
1749     while (cur && (cur->t != t || strcmp(cur->name, name)))
1750       cur = cur->next;
1751   }
1752   if (cur) {
1753     free(name);
1754     return cur->type;
1755   }
1756   tp = make_type(type, NULL);
1757   tp->name = name;
1758   if (!name) return tp;
1759   return reg_type(tp, name, t);
1760 }
1761
1762 static type_t *get_typev(unsigned char type, var_t *name, int t)
1763 {
1764   char *sname = NULL;
1765   if (name) {
1766     sname = name->name;
1767     free(name);
1768   }
1769   return get_type(type, sname, t);
1770 }
1771
1772 static int get_struct_type(var_list_t *fields)
1773 {
1774   int has_pointer = 0;
1775   int has_conformance = 0;
1776   int has_variance = 0;
1777   var_t *field;
1778
1779   if (get_padding(fields))
1780     return RPC_FC_BOGUS_STRUCT;
1781
1782   if (fields) LIST_FOR_EACH_ENTRY( field, fields, var_t, entry )
1783   {
1784     type_t *t = field->type;
1785
1786     if (is_user_type(t))
1787       return RPC_FC_BOGUS_STRUCT;
1788
1789     if (is_ptr(t))
1790     {
1791         do
1792             t = t->ref;
1793         while (is_ptr(t));
1794
1795         switch (t->type)
1796         {
1797         case RPC_FC_IP:
1798         case RPC_FC_ENCAPSULATED_UNION:
1799         case RPC_FC_NON_ENCAPSULATED_UNION:
1800         case RPC_FC_BOGUS_STRUCT:
1801             return RPC_FC_BOGUS_STRUCT;
1802         }
1803
1804         has_pointer = 1;
1805         continue;
1806     }
1807
1808     if (field->type->declarray)
1809     {
1810         if (is_string_type(field->attrs, field->type))
1811         {
1812             if (is_conformant_array(field->type))
1813                 has_conformance = 1;
1814             has_variance = 1;
1815             continue;
1816         }
1817
1818         if (is_array(field->type->ref))
1819             return RPC_FC_BOGUS_STRUCT;
1820
1821         if (is_conformant_array(field->type))
1822         {
1823             has_conformance = 1;
1824             if (field->type->declarray && list_next(fields, &field->entry))
1825                 error_loc("field '%s' deriving from a conformant array must be the last field in the structure\n",
1826                         field->name);
1827         }
1828         if (field->type->length_is)
1829             has_variance = 1;
1830
1831         t = field->type->ref;
1832     }
1833
1834     switch (t->type)
1835     {
1836     /*
1837      * RPC_FC_BYTE, RPC_FC_STRUCT, etc
1838      *  Simple types don't effect the type of struct.
1839      *  A struct containing a simple struct is still a simple struct.
1840      *  So long as we can block copy the data, we return RPC_FC_STRUCT.
1841      */
1842     case 0: /* void pointer */
1843     case RPC_FC_BYTE:
1844     case RPC_FC_CHAR:
1845     case RPC_FC_SMALL:
1846     case RPC_FC_USMALL:
1847     case RPC_FC_WCHAR:
1848     case RPC_FC_SHORT:
1849     case RPC_FC_USHORT:
1850     case RPC_FC_LONG:
1851     case RPC_FC_ULONG:
1852     case RPC_FC_INT3264:
1853     case RPC_FC_UINT3264:
1854     case RPC_FC_HYPER:
1855     case RPC_FC_FLOAT:
1856     case RPC_FC_DOUBLE:
1857     case RPC_FC_STRUCT:
1858     case RPC_FC_ENUM16:
1859     case RPC_FC_ENUM32:
1860       break;
1861
1862     case RPC_FC_RP:
1863     case RPC_FC_UP:
1864     case RPC_FC_FP:
1865     case RPC_FC_OP:
1866     case RPC_FC_CARRAY:
1867     case RPC_FC_CVARRAY:
1868     case RPC_FC_BOGUS_ARRAY:
1869       has_pointer = 1;
1870       break;
1871
1872     /*
1873      * Propagate member attributes
1874      *  a struct should be at least as complex as its member
1875      */
1876     case RPC_FC_CVSTRUCT:
1877       has_conformance = 1;
1878       has_variance = 1;
1879       has_pointer = 1;
1880       break;
1881
1882     case RPC_FC_CPSTRUCT:
1883       has_conformance = 1;
1884       if (list_next( fields, &field->entry ))
1885           error_loc("field '%s' deriving from a conformant array must be the last field in the structure\n",
1886                   field->name);
1887       has_pointer = 1;
1888       break;
1889
1890     case RPC_FC_CSTRUCT:
1891       has_conformance = 1;
1892       if (list_next( fields, &field->entry ))
1893           error_loc("field '%s' deriving from a conformant array must be the last field in the structure\n",
1894                   field->name);
1895       break;
1896
1897     case RPC_FC_PSTRUCT:
1898       has_pointer = 1;
1899       break;
1900
1901     default:
1902       error_loc("Unknown struct member %s with type (0x%02x)\n", field->name, t->type);
1903       /* fallthru - treat it as complex */
1904
1905     /* as soon as we see one of these these members, it's bogus... */
1906     case RPC_FC_ENCAPSULATED_UNION:
1907     case RPC_FC_NON_ENCAPSULATED_UNION:
1908     case RPC_FC_BOGUS_STRUCT:
1909       return RPC_FC_BOGUS_STRUCT;
1910     }
1911   }
1912
1913   if( has_variance )
1914   {
1915     if ( has_conformance )
1916       return RPC_FC_CVSTRUCT;
1917     else
1918       return RPC_FC_BOGUS_STRUCT;
1919   }
1920   if( has_conformance && has_pointer )
1921     return RPC_FC_CPSTRUCT;
1922   if( has_conformance )
1923     return RPC_FC_CSTRUCT;
1924   if( has_pointer )
1925     return RPC_FC_PSTRUCT;
1926   return RPC_FC_STRUCT;
1927 }
1928
1929 /***** constant repository *****/
1930
1931 struct rconst {
1932   char *name;
1933   var_t *var;
1934   struct rconst *next;
1935 };
1936
1937 struct rconst *const_hash[HASHMAX];
1938
1939 static var_t *reg_const(var_t *var)
1940 {
1941   struct rconst *nc;
1942   int hash;
1943   if (!var->name) {
1944     error_loc("registering constant without name\n");
1945     return var;
1946   }
1947   hash = hash_ident(var->name);
1948   nc = xmalloc(sizeof(struct rconst));
1949   nc->name = var->name;
1950   nc->var = var;
1951   nc->next = const_hash[hash];
1952   const_hash[hash] = nc;
1953   return var;
1954 }
1955
1956 static var_t *find_const(char *name, int f)
1957 {
1958   struct rconst *cur = const_hash[hash_ident(name)];
1959   while (cur && strcmp(cur->name, name))
1960     cur = cur->next;
1961   if (!cur) {
1962     if (f) error_loc("constant '%s' not found\n", name);
1963     return NULL;
1964   }
1965   return cur->var;
1966 }
1967
1968 static void write_libid(const char *name, const attr_list_t *attr)
1969 {
1970   const UUID *uuid = get_attrp(attr, ATTR_UUID);
1971   write_guid(idfile, "LIBID", name, uuid);
1972 }
1973
1974 static void write_clsid(type_t *cls)
1975 {
1976   const UUID *uuid = get_attrp(cls->attrs, ATTR_UUID);
1977   write_guid(idfile, "CLSID", cls->name, uuid);
1978 }
1979
1980 static void write_diid(type_t *iface)
1981 {
1982   const UUID *uuid = get_attrp(iface->attrs, ATTR_UUID);
1983   write_guid(idfile, "DIID", iface->name, uuid);
1984 }
1985
1986 static void write_iid(type_t *iface)
1987 {
1988   const UUID *uuid = get_attrp(iface->attrs, ATTR_UUID);
1989   write_guid(idfile, "IID", iface->name, uuid);
1990 }
1991
1992 static int compute_method_indexes(type_t *iface)
1993 {
1994   int idx;
1995   func_t *f;
1996
1997   if (iface->ref)
1998     idx = compute_method_indexes(iface->ref);
1999   else
2000     idx = 0;
2001
2002   if (!iface->funcs)
2003     return idx;
2004
2005   LIST_FOR_EACH_ENTRY( f, iface->funcs, func_t, entry )
2006     if (! is_callas(f->def->attrs))
2007       f->idx = idx++;
2008
2009   return idx;
2010 }
2011
2012 static char *gen_name(void)
2013 {
2014   static const char format[] = "__WIDL_%s_generated_name_%08lX";
2015   static unsigned long n = 0;
2016   static const char *file_id;
2017   static size_t size;
2018   char *name;
2019
2020   if (! file_id)
2021   {
2022     char *dst = dup_basename(input_name, ".idl");
2023     file_id = dst;
2024
2025     for (; *dst; ++dst)
2026       if (! isalnum((unsigned char) *dst))
2027         *dst = '_';
2028
2029     size = sizeof format - 7 + strlen(file_id) + 8;
2030   }
2031
2032   name = xmalloc(size);
2033   sprintf(name, format, file_id, n++);
2034   return name;
2035 }
2036
2037 static void process_typedefs(pident_list_t *pidents)
2038 {
2039   pident_t *pident, *next;
2040
2041   if (!pidents) return;
2042   LIST_FOR_EACH_ENTRY_SAFE( pident, next, pidents, pident_t, entry )
2043   {
2044     var_t *var = pident->var;
2045     type_t *type = find_type(var->name, 0);
2046
2047     if (! parse_only && do_header)
2048       write_typedef(type);
2049     if (in_typelib && type->attrs)
2050       add_typelib_entry(type);
2051
2052     free(pident);
2053     free(var);
2054   }
2055 }
2056
2057 static void check_arg(var_t *arg)
2058 {
2059   type_t *t = arg->type;
2060
2061   if (t->type == 0 && ! is_var_ptr(arg))
2062     error_loc("argument '%s' has void type\n", arg->name);
2063 }
2064
2065 static void check_all_user_types(ifref_list_t *ifrefs)
2066 {
2067   const ifref_t *ifref;
2068   const func_t *f;
2069
2070   if (ifrefs) LIST_FOR_EACH_ENTRY(ifref, ifrefs, const ifref_t, entry)
2071   {
2072     const func_list_t *fs = ifref->iface->funcs;
2073     if (fs) LIST_FOR_EACH_ENTRY(f, fs, const func_t, entry)
2074       check_for_user_types_and_context_handles(f->args);
2075   }
2076 }
2077
2078 int is_valid_uuid(const char *s)
2079 {
2080   int i;
2081
2082   for (i = 0; i < 36; ++i)
2083     if (i == 8 || i == 13 || i == 18 || i == 23)
2084     {
2085       if (s[i] != '-')
2086         return FALSE;
2087     }
2088     else
2089       if (!isxdigit(s[i]))
2090         return FALSE;
2091
2092   return s[i] == '\0';
2093 }