git.oblomov.eu Git - wine/blob - tools/widl/parser.y

   1 %{
   2 /*
   3  * IDL Compiler
   4  *
   5  * Copyright 2002 Ove Kaaven
   6  *
   7  * This library is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU Lesser General Public
   9  * License as published by the Free Software Foundation; either
  10  * version 2.1 of the License, or (at your option) any later version.
  11  *
  12  * This library is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15  * Lesser General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU Lesser General Public
  18  * License along with this library; if not, write to the Free Software
  19  * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  20  */
  21
  22 #include "config.h"
  23
  24 #include <stdio.h>
  25 #include <stdlib.h>
  26 #include <stdarg.h>
  27 #include <assert.h>
  28 #include <ctype.h>
  29 #include <string.h>
  30 #ifdef HAVE_ALLOCA_H
  31 #include <alloca.h>
  32 #endif
  33
  34 #include "windef.h"
  35
  36 #include "widl.h"
  37 #include "utils.h"
  38 #include "parser.h"
  39 #include "header.h"
  40 #include "typelib.h"
  41
  42 #if defined(YYBYACC)
  43         /* Berkeley yacc (byacc) doesn't seem to know about these */
  44         /* Some *BSD supplied versions do define these though */
  45 # ifndef YYEMPTY
  46 #  define YYEMPTY       (-1)    /* Empty lookahead value of yychar */
  47 # endif
  48 # ifndef YYLEX
  49 #  define YYLEX         yylex()
  50 # endif
  51
  52 #elif defined(YYBISON)
  53         /* Bison was used for original development */
  54         /* #define YYEMPTY -2 */
  55         /* #define YYLEX   yylex() */
  56
  57 #else
  58         /* No yacc we know yet */
  59 # if !defined(YYEMPTY) || !defined(YYLEX)
  60 #  error Yacc version/type unknown. This version needs to be verified for settings of YYEMPTY and YYLEX.
  61 # elif defined(__GNUC__)        /* gcc defines the #warning directive */
  62 #  warning Yacc version/type unknown. It defines YYEMPTY and YYLEX, but is not tested
  63   /* #else we just take a chance that it works... */
  64 # endif
  65 #endif
  66
  67 static attr_t *make_attr(enum attr_type type);
  68 static attr_t *make_attrv(enum attr_type type, unsigned long val);
  69 static attr_t *make_attrp(enum attr_type type, void *val);
  70 static expr_t *make_expr(enum expr_type type);
  71 static expr_t *make_exprl(enum expr_type type, long val);
  72 static expr_t *make_exprs(enum expr_type type, char *val);
  73 static expr_t *make_exprt(enum expr_type type, typeref_t *tref, expr_t *expr);
  74 static expr_t *make_expr1(enum expr_type type, expr_t *expr);
  75 static expr_t *make_expr2(enum expr_type type, expr_t *exp1, expr_t *exp2);
  76 static expr_t *make_expr3(enum expr_type type, expr_t *expr1, expr_t *expr2, expr_t *expr3);
  77 static type_t *make_type(unsigned char type, type_t *ref);
  78 static typeref_t *make_tref(char *name, type_t *ref);
  79 static typeref_t *uniq_tref(typeref_t *ref);
  80 static type_t *type_ref(typeref_t *ref);
  81 static void set_type(var_t *v, typeref_t *ref, expr_t *arr);
  82 static ifref_t *make_ifref(type_t *iface);
  83 static var_t *make_var(char *name);
  84 static func_t *make_func(var_t *def, var_t *args);
  85 static type_t *make_class(char *name);
  86 static type_t *make_safearray(void);
  87
  88 static type_t *reg_type(type_t *type, const char *name, int t);
  89 static type_t *reg_types(type_t *type, var_t *names, int t);
  90 static type_t *find_type(const char *name, int t);
  91 static type_t *find_type2(char *name, int t);
  92 static type_t *get_type(unsigned char type, char *name, int t);
  93 static type_t *get_typev(unsigned char type, var_t *name, int t);
  94 static int get_struct_type(var_t *fields);
  95
  96 static var_t *reg_const(var_t *var);
  97 static var_t *find_const(char *name, int f);
  98
  99 static void write_libid(const char *name, const attr_t *attr);
 100 static void write_clsid(type_t *cls);
 101 static void write_diid(type_t *iface);
 102 static void write_iid(type_t *iface);
 103
 104 static int compute_method_indexes(type_t *iface);
 105
 106 #define tsENUM   1
 107 #define tsSTRUCT 2
 108 #define tsUNION  3
 109
 110 static type_t std_bool = { "boolean" };
 111 static type_t std_int = { "int" };
 112 static type_t std_int64 = { "__int64" };
 113 static type_t std_uhyper = { "MIDL_uhyper" };
 114
 115 %}
 116 %union {
 117         attr_t *attr;
 118         expr_t *expr;
 119         type_t *type;
 120         typeref_t *tref;
 121         var_t *var;
 122         func_t *func;
 123         ifref_t *ifref;
 124         char *str;
 125         UUID *uuid;
 126         unsigned int num;
 127 }
 128
 129 %token <str> aIDENTIFIER
 130 %token <str> aKNOWNTYPE
 131 %token <num> aNUM aHEXNUM
 132 %token <str> aSTRING
 133 %token <uuid> aUUID
 134 %token aEOF
 135 %token SHL SHR
 136 %token tAGGREGATABLE tALLOCATE tAPPOBJECT tASYNC tASYNCUUID
 137 %token tAUTOHANDLE tBINDABLE tBOOLEAN tBROADCAST tBYTE tBYTECOUNT
 138 %token tCALLAS tCALLBACK tCASE tCDECL tCHAR tCOCLASS tCODE tCOMMSTATUS
 139 %token tCONST tCONTEXTHANDLE tCONTEXTHANDLENOSERIALIZE
 140 %token tCONTEXTHANDLESERIALIZE tCONTROL tCPPQUOTE
 141 %token tDEFAULT
 142 %token tDEFAULTCOLLELEM
 143 %token tDEFAULTVALUE
 144 %token tDEFAULTVTABLE
 145 %token tDISPLAYBIND
 146 %token tDISPINTERFACE
 147 %token tDLLNAME tDOUBLE tDUAL
 148 %token tENDPOINT
 149 %token tENTRY tENUM tERRORSTATUST
 150 %token tEXPLICITHANDLE tEXTERN
 151 %token tFALSE
 152 %token tFLOAT
 153 %token tHANDLE
 154 %token tHANDLET
 155 %token tHELPCONTEXT tHELPFILE
 156 %token tHELPSTRING tHELPSTRINGCONTEXT tHELPSTRINGDLL
 157 %token tHIDDEN
 158 %token tHYPER tID tIDEMPOTENT
 159 %token tIIDIS
 160 %token tIMMEDIATEBIND
 161 %token tIMPLICITHANDLE
 162 %token tIMPORT tIMPORTLIB
 163 %token tIN tINLINE
 164 %token tINPUTSYNC
 165 %token tINT tINT64
 166 %token tINTERFACE
 167 %token tLCID
 168 %token tLENGTHIS tLIBRARY
 169 %token tLOCAL
 170 %token tLONG
 171 %token tMETHODS
 172 %token tMODULE
 173 %token tNONBROWSABLE
 174 %token tNONCREATABLE
 175 %token tNONEXTENSIBLE
 176 %token tOBJECT tODL tOLEAUTOMATION
 177 %token tOPTIONAL
 178 %token tOUT
 179 %token tPOINTERDEFAULT
 180 %token tPROPERTIES
 181 %token tPROPGET tPROPPUT tPROPPUTREF
 182 %token tPTR
 183 %token tPUBLIC
 184 %token tRANGE
 185 %token tREADONLY tREF
 186 %token tREQUESTEDIT
 187 %token tRESTRICTED
 188 %token tRETVAL
 189 %token tSAFEARRAY
 190 %token tSHORT
 191 %token tSIGNED
 192 %token tSINGLE
 193 %token tSIZEIS tSIZEOF
 194 %token tSMALL
 195 %token tSOURCE
 196 %token tSTDCALL
 197 %token tSTRING tSTRUCT
 198 %token tSWITCH tSWITCHIS tSWITCHTYPE
 199 %token tTRANSMITAS
 200 %token tTRUE
 201 %token tTYPEDEF
 202 %token tUNION
 203 %token tUNIQUE
 204 %token tUNSIGNED
 205 %token tUUID
 206 %token tV1ENUM
 207 %token tVARARG
 208 %token tVERSION
 209 %token tVOID
 210 %token tWCHAR tWIREMARSHAL
 211
 212 %type <attr> m_attributes attributes attrib_list attribute
 213 %type <expr> m_exprs /* exprs expr_list */ m_expr expr expr_list_const expr_const
 214 %type <expr> array array_list
 215 %type <type> inherit interface interfacehdr interfacedef interfacedec
 216 %type <type> dispinterface dispinterfacehdr dispinterfacedef
 217 %type <type> module modulehdr moduledef
 218 %type <type> base_type int_std
 219 %type <type> enumdef structdef typedef uniondef
 220 %type <ifref> gbl_statements coclass_ints coclass_int
 221 %type <tref> type
 222 %type <var> m_args no_args args arg
 223 %type <var> fields field s_field cases case enums enum_list enum constdef externdef
 224 %type <var> m_ident t_ident ident p_ident pident pident_list
 225 %type <var> dispint_props
 226 %type <func> funcdef int_statements
 227 %type <func> dispint_meths
 228 %type <type> coclass coclasshdr coclassdef
 229 %type <num> pointer_type version
 230 %type <str> libraryhdr
 231
 232 %left ','
 233 %right '?' ':'
 234 %left '|'
 235 %left '&'
 236 %left '-' '+'
 237 %left '*' '/'
 238 %left SHL SHR
 239 %right '~'
 240 %right CAST
 241 %right PPTR
 242 %right NEG
 243
 244 %%
 245
 246 input:   gbl_statements                        { write_proxies($1); write_client($1); write_server($1); }
 247         ;
 248
 249 gbl_statements:                                 { $$ = NULL; }
 250         | gbl_statements interfacedec           { $$ = $1; }
 251         | gbl_statements interfacedef           { $$ = make_ifref($2); LINK($$, $1); }
 252         | gbl_statements coclass ';'            { $$ = $1;
 253                                                   reg_type($2, $2->name, 0);
 254                                                   if (!parse_only && do_header) write_coclass_forward($2);
 255                                                 }
 256         | gbl_statements coclassdef             { $$ = $1;
 257                                                   add_coclass($2);
 258                                                   reg_type($2, $2->name, 0);
 259                                                   if (!parse_only && do_header) write_coclass_forward($2);
 260                                                 }
 261         | gbl_statements moduledef              { $$ = $1; add_module($2); }
 262         | gbl_statements librarydef             { $$ = $1; }
 263         | gbl_statements statement              { $$ = $1; }
 264         ;
 265
 266 imp_statements:                                 {}
 267         | imp_statements interfacedec           { if (!parse_only) add_interface($2); }
 268         | imp_statements interfacedef           { if (!parse_only) add_interface($2); }
 269         | imp_statements coclass ';'            { reg_type($2, $2->name, 0); if (!parse_only && do_header) write_coclass_forward($2); }
 270         | imp_statements coclassdef             { if (!parse_only) add_coclass($2);
 271                                                   reg_type($2, $2->name, 0);
 272                                                   if (!parse_only && do_header) write_coclass_forward($2);
 273                                                 }
 274         | imp_statements moduledef              { if (!parse_only) add_module($2); }
 275         | imp_statements statement              {}
 276         | imp_statements importlib              {}
 277         ;
 278
 279 int_statements:                                 { $$ = NULL; }
 280         | int_statements funcdef ';'            { $$ = $2; LINK($$, $1); }
 281         | int_statements statement              { $$ = $1; }
 282         ;
 283
 284 statement: ';'                                  {}
 285         | constdef ';'                          { if (!parse_only && do_header) { write_constdef($1); } }
 286         | cppquote                              {}
 287         | enumdef ';'                           { if (!parse_only && do_header) { write_type(header, $1, NULL, NULL); fprintf(header, ";\n\n"); } }
 288         | externdef ';'                         { if (!parse_only && do_header) { write_externdef($1); } }
 289         | import                                {}
 290         | structdef ';'                         { if (!parse_only && do_header) { write_type(header, $1, NULL, NULL); fprintf(header, ";\n\n"); } }
 291         | typedef ';'                           {}
 292         | uniondef ';'                          { if (!parse_only && do_header) { write_type(header, $1, NULL, NULL); fprintf(header, ";\n\n"); } }
 293         ;
 294
 295 cppquote: tCPPQUOTE '(' aSTRING ')'             { if (!parse_only && do_header) fprintf(header, "%s\n", $3); }
 296         ;
 297 import_start: tIMPORT aSTRING ';'               { assert(yychar == YYEMPTY);
 298                                                   if (!do_import($2)) yychar = aEOF; }
 299         ;
 300 import:   import_start imp_statements aEOF      {}
 301         ;
 302
 303 importlib: tIMPORTLIB '(' aSTRING ')'           { if(!parse_only) add_importlib($3); }
 304         ;
 305
 306 libraryhdr: tLIBRARY aIDENTIFIER                { $$ = $2; }
 307         ;
 308 library_start: attributes libraryhdr '{'        { start_typelib($2, $1);
 309                                                   if (!parse_only && do_header) write_library($2, $1);
 310                                                   if (!parse_only && do_idfile) write_libid($2, $1);
 311                                                 }
 312         ;
 313 librarydef: library_start imp_statements '}'    { end_typelib(); }
 314         ;
 315
 316 m_args:                                         { $$ = NULL; }
 317         | args
 318         ;
 319
 320 no_args:  tVOID                                 { $$ = NULL; }
 321         ;
 322
 323 args:     arg
 324         | args ',' arg                          { LINK($3, $1); $$ = $3; }
 325         | no_args
 326         ;
 327
 328 /* split into two rules to get bison to resolve a tVOID conflict */
 329 arg:      attributes type pident array          { $$ = $3;
 330                                                   set_type($$, $2, $4);
 331                                                   $$->attrs = $1;
 332                                                 }
 333         | type pident array                     { $$ = $2;
 334                                                   set_type($$, $1, $3);
 335                                                 }
 336         | attributes type pident '(' m_args ')' { $$ = $3;
 337                                                   $$->ptr_level--;
 338                                                   set_type($$, $2, NULL);
 339                                                   $$->attrs = $1;
 340                                                   $$->args = $5;
 341                                                 }
 342         | type pident '(' m_args ')'            { $$ = $2;
 343                                                   $$->ptr_level--;
 344                                                   set_type($$, $1, NULL);
 345                                                   $$->args = $4;
 346                                                 }
 347         ;
 348
 349 array:                                          { $$ = NULL; }
 350         | '[' array_list ']'                    { $$ = $2; }
 351         | '[' '*' ']'                           { $$ = make_expr(EXPR_VOID); }
 352         ;
 353
 354 array_list: m_expr /* size of first dimension is optional */
 355         | array_list ',' expr                   { LINK($3, $1); $$ = $3; }
 356         | array_list ']' '[' expr               { LINK($4, $1); $$ = $4; }
 357         ;
 358
 359 m_attributes:                                   { $$ = NULL; }
 360         | attributes
 361         ;
 362
 363 attributes:
 364           '[' attrib_list ']'                   { $$ = $2;
 365                                                   if (!$$)
 366                                                     yyerror("empty attribute lists unsupported");
 367                                                 }
 368         ;
 369
 370 attrib_list: attribute
 371         | attrib_list ',' attribute             { if ($3) { LINK($3, $1); $$ = $3; }
 372                                                   else { $$ = $1; }
 373                                                 }
 374         | attrib_list ']' '[' attribute         { if ($4) { LINK($4, $1); $$ = $4; }
 375                                                   else { $$ = $1; }
 376                                                 }
 377         ;
 378
 379 attribute:                                      { $$ = NULL; }
 380         | tAGGREGATABLE                         { $$ = make_attr(ATTR_AGGREGATABLE); }
 381         | tAPPOBJECT                            { $$ = make_attr(ATTR_APPOBJECT); }
 382         | tASYNC                                { $$ = make_attr(ATTR_ASYNC); }
 383         | tAUTOHANDLE                           { $$ = make_attr(ATTR_AUTO_HANDLE); }
 384         | tBINDABLE                             { $$ = make_attr(ATTR_BINDABLE); }
 385         | tCALLAS '(' ident ')'                 { $$ = make_attrp(ATTR_CALLAS, $3); }
 386         | tCASE '(' expr_list_const ')'         { $$ = make_attrp(ATTR_CASE, $3); }
 387         | tCONTEXTHANDLE                        { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); }
 388         | tCONTEXTHANDLENOSERIALIZE             { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); /* RPC_CONTEXT_HANDLE_DONT_SERIALIZE */ }
 389         | tCONTEXTHANDLESERIALIZE               { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); /* RPC_CONTEXT_HANDLE_SERIALIZE */ }
 390         | tCONTROL                              { $$ = make_attr(ATTR_CONTROL); }
 391         | tDEFAULT                              { $$ = make_attr(ATTR_DEFAULT); }
 392         | tDEFAULTCOLLELEM                      { $$ = make_attr(ATTR_DEFAULTCOLLELEM); }
 393         | tDEFAULTVALUE '(' expr_const ')'      { $$ = make_attrp(ATTR_DEFAULTVALUE_EXPR, $3); }
 394         | tDEFAULTVALUE '(' aSTRING ')'         { $$ = make_attrp(ATTR_DEFAULTVALUE_STRING, $3); }
 395         | tDEFAULTVTABLE                        { $$ = make_attr(ATTR_DEFAULTVTABLE); }
 396         | tDISPLAYBIND                          { $$ = make_attr(ATTR_DISPLAYBIND); }
 397         | tDLLNAME '(' aSTRING ')'              { $$ = make_attrp(ATTR_DLLNAME, $3); }
 398         | tDUAL                                 { $$ = make_attr(ATTR_DUAL); }
 399         | tENDPOINT '(' aSTRING ')'             { $$ = make_attrp(ATTR_ENDPOINT, $3); }
 400         | tENTRY '(' aSTRING ')'                { $$ = make_attrp(ATTR_ENTRY_STRING, $3); }
 401         | tENTRY '(' expr_const ')'             { $$ = make_attrp(ATTR_ENTRY_ORDINAL, $3); }
 402         | tEXPLICITHANDLE                       { $$ = make_attr(ATTR_EXPLICIT_HANDLE); }
 403         | tHANDLE                               { $$ = make_attr(ATTR_HANDLE); }
 404         | tHELPCONTEXT '(' expr_const ')'       { $$ = make_attrp(ATTR_HELPCONTEXT, $3); }
 405         | tHELPFILE '(' aSTRING ')'             { $$ = make_attrp(ATTR_HELPFILE, $3); }
 406         | tHELPSTRING '(' aSTRING ')'           { $$ = make_attrp(ATTR_HELPSTRING, $3); }
 407         | tHELPSTRINGCONTEXT '(' expr_const ')' { $$ = make_attrp(ATTR_HELPSTRINGCONTEXT, $3); }
 408         | tHELPSTRINGDLL '(' aSTRING ')'        { $$ = make_attrp(ATTR_HELPSTRINGDLL, $3); }
 409         | tHIDDEN                               { $$ = make_attr(ATTR_HIDDEN); }
 410         | tID '(' expr_const ')'                { $$ = make_attrp(ATTR_ID, $3); }
 411         | tIDEMPOTENT                           { $$ = make_attr(ATTR_IDEMPOTENT); }
 412         | tIIDIS '(' ident ')'                  { $$ = make_attrp(ATTR_IIDIS, $3); }
 413         | tIMMEDIATEBIND                        { $$ = make_attr(ATTR_IMMEDIATEBIND); }
 414         | tIMPLICITHANDLE '(' tHANDLET aIDENTIFIER ')'  { $$ = make_attrp(ATTR_IMPLICIT_HANDLE, $4); }
 415         | tIN                                   { $$ = make_attr(ATTR_IN); }
 416         | tINPUTSYNC                            { $$ = make_attr(ATTR_INPUTSYNC); }
 417         | tLENGTHIS '(' m_exprs ')'             { $$ = make_attrp(ATTR_LENGTHIS, $3); }
 418         | tLOCAL                                { $$ = make_attr(ATTR_LOCAL); }
 419         | tNONBROWSABLE                         { $$ = make_attr(ATTR_NONBROWSABLE); }
 420         | tNONCREATABLE                         { $$ = make_attr(ATTR_NONCREATABLE); }
 421         | tNONEXTENSIBLE                        { $$ = make_attr(ATTR_NONEXTENSIBLE); }
 422         | tOBJECT                               { $$ = make_attr(ATTR_OBJECT); }
 423         | tODL                                  { $$ = make_attr(ATTR_ODL); }
 424         | tOLEAUTOMATION                        { $$ = make_attr(ATTR_OLEAUTOMATION); }
 425         | tOPTIONAL                             { $$ = make_attr(ATTR_OPTIONAL); }
 426         | tOUT                                  { $$ = make_attr(ATTR_OUT); }
 427         | tPOINTERDEFAULT '(' pointer_type ')'  { $$ = make_attrv(ATTR_POINTERDEFAULT, $3); }
 428         | tPROPGET                              { $$ = make_attr(ATTR_PROPGET); }
 429         | tPROPPUT                              { $$ = make_attr(ATTR_PROPPUT); }
 430         | tPROPPUTREF                           { $$ = make_attr(ATTR_PROPPUTREF); }
 431         | tPUBLIC                               { $$ = make_attr(ATTR_PUBLIC); }
 432         | tRANGE '(' expr_const ',' expr_const ')' { LINK($5, $3); $$ = make_attrp(ATTR_RANGE, $5); }
 433         | tREADONLY                             { $$ = make_attr(ATTR_READONLY); }
 434         | tREQUESTEDIT                          { $$ = make_attr(ATTR_REQUESTEDIT); }
 435         | tRESTRICTED                           { $$ = make_attr(ATTR_RESTRICTED); }
 436         | tRETVAL                               { $$ = make_attr(ATTR_RETVAL); }
 437         | tSIZEIS '(' m_exprs ')'               { $$ = make_attrp(ATTR_SIZEIS, $3); }
 438         | tSOURCE                               { $$ = make_attr(ATTR_SOURCE); }
 439         | tSTRING                               { $$ = make_attr(ATTR_STRING); }
 440         | tSWITCHIS '(' expr ')'                { $$ = make_attrp(ATTR_SWITCHIS, $3); }
 441         | tSWITCHTYPE '(' type ')'              { $$ = make_attrp(ATTR_SWITCHTYPE, type_ref($3)); }
 442         | tTRANSMITAS '(' type ')'              { $$ = make_attrp(ATTR_TRANSMITAS, type_ref($3)); }
 443         | tUUID '(' aUUID ')'                   { $$ = make_attrp(ATTR_UUID, $3); }
 444         | tV1ENUM                               { $$ = make_attr(ATTR_V1ENUM); }
 445         | tVARARG                               { $$ = make_attr(ATTR_VARARG); }
 446         | tVERSION '(' version ')'              { $$ = make_attrv(ATTR_VERSION, $3); }
 447         | tWIREMARSHAL '(' type ')'             { $$ = make_attrp(ATTR_WIREMARSHAL, type_ref($3)); }
 448         | pointer_type                          { $$ = make_attrv(ATTR_POINTERTYPE, $1); }
 449         ;
 450
 451 callconv:
 452         | tSTDCALL
 453         ;
 454
 455 cases:                                          { $$ = NULL; }
 456         | cases case                            { if ($2) { LINK($2, $1); $$ = $2; }
 457                                                   else { $$ = $1; }
 458                                                 }
 459         ;
 460
 461 case:     tCASE expr ':' field                  { attr_t *a = make_attrp(ATTR_CASE, $2);
 462                                                   $$ = $4; if (!$$) $$ = make_var(NULL);
 463                                                   LINK(a, $$->attrs); $$->attrs = a;
 464                                                 }
 465         | tDEFAULT ':' field                    { attr_t *a = make_attr(ATTR_DEFAULT);
 466                                                   $$ = $3; if (!$$) $$ = make_var(NULL);
 467                                                   LINK(a, $$->attrs); $$->attrs = a;
 468                                                 }
 469         ;
 470
 471 constdef: tCONST type ident '=' expr_const      { $$ = reg_const($3);
 472                                                   set_type($$, $2, NULL);
 473                                                   $$->eval = $5;
 474                                                 }
 475         ;
 476
 477 enums:                                          { $$ = NULL; }
 478         | enum_list ','                         { $$ = $1; }
 479         | enum_list
 480         ;
 481
 482 enum_list: enum                                 { if (!$$->eval)
 483                                                     $$->eval = make_exprl(EXPR_NUM, 0 /* default for first enum entry */);
 484                                                 }
 485         | enum_list ',' enum                    { LINK($3, $1); $$ = $3;
 486                                                   if (!$$->eval)
 487                                                     $$->eval = make_exprl(EXPR_NUM, $1->eval->cval + 1);
 488                                                 }
 489         ;
 490
 491 enum:     ident '=' expr_const                  { $$ = reg_const($1);
 492                                                   $$->eval = $3;
 493                                                   $$->type = make_type(RPC_FC_LONG, &std_int);
 494                                                 }
 495         | ident                                 { $$ = reg_const($1);
 496                                                   $$->type = make_type(RPC_FC_LONG, &std_int);
 497                                                 }
 498         ;
 499
 500 enumdef: tENUM t_ident '{' enums '}'            { $$ = get_typev(RPC_FC_ENUM16, $2, tsENUM);
 501                                                   $$->kind = TKIND_ENUM;
 502                                                   $$->fields = $4;
 503                                                   $$->defined = TRUE;
 504                                                   if(in_typelib)
 505                                                       add_enum($$);
 506                                                 }
 507         ;
 508
 509 m_exprs:  m_expr
 510         | m_exprs ',' m_expr                    { LINK($3, $1); $$ = $3; }
 511         ;
 512
 513 /*
 514 exprs:                                          { $$ = make_expr(EXPR_VOID); }
 515         | expr_list
 516         ;
 517
 518 expr_list: expr
 519         | expr_list ',' expr                    { LINK($3, $1); $$ = $3; }
 520         ;
 521 */
 522
 523 m_expr:                                         { $$ = make_expr(EXPR_VOID); }
 524         | expr
 525         ;
 526
 527 expr:     aNUM                                  { $$ = make_exprl(EXPR_NUM, $1); }
 528         | aHEXNUM                               { $$ = make_exprl(EXPR_HEXNUM, $1); }
 529         | tFALSE                                { $$ = make_exprl(EXPR_TRUEFALSE, 0); }
 530         | tTRUE                                 { $$ = make_exprl(EXPR_TRUEFALSE, 1); }
 531         | aIDENTIFIER                           { $$ = make_exprs(EXPR_IDENTIFIER, $1); }
 532         | expr '?' expr ':' expr                { $$ = make_expr3(EXPR_COND, $1, $3, $5); }
 533         | expr '|' expr                         { $$ = make_expr2(EXPR_OR , $1, $3); }
 534         | expr '&' expr                         { $$ = make_expr2(EXPR_AND, $1, $3); }
 535         | expr '+' expr                         { $$ = make_expr2(EXPR_ADD, $1, $3); }
 536         | expr '-' expr                         { $$ = make_expr2(EXPR_SUB, $1, $3); }
 537         | expr '*' expr                         { $$ = make_expr2(EXPR_MUL, $1, $3); }
 538         | expr '/' expr                         { $$ = make_expr2(EXPR_DIV, $1, $3); }
 539         | expr SHL expr                         { $$ = make_expr2(EXPR_SHL, $1, $3); }
 540         | expr SHR expr                         { $$ = make_expr2(EXPR_SHR, $1, $3); }
 541         | '~' expr                              { $$ = make_expr1(EXPR_NOT, $2); }
 542         | '-' expr %prec NEG                    { $$ = make_expr1(EXPR_NEG, $2); }
 543         | '*' expr %prec PPTR                   { $$ = make_expr1(EXPR_PPTR, $2); }
 544         | '(' type ')' expr %prec CAST          { $$ = make_exprt(EXPR_CAST, $2, $4); }
 545         | tSIZEOF '(' type ')'                  { $$ = make_exprt(EXPR_SIZEOF, $3, NULL); }
 546         | '(' expr ')'                          { $$ = $2; }
 547         ;
 548
 549 expr_list_const: expr_const
 550         | expr_list_const ',' expr_const        { LINK($3, $1); $$ = $3; }
 551         ;
 552
 553 expr_const: expr                                { $$ = $1;
 554                                                   if (!$$->is_const)
 555                                                       yyerror("expression is not constant");
 556                                                 }
 557         ;
 558
 559 externdef: tEXTERN tCONST type ident            { $$ = $4;
 560                                                   set_type($$, $3, NULL);
 561                                                 }
 562         ;
 563
 564 fields:                                         { $$ = NULL; }
 565         | fields field                          { if ($2) { LINK($2, $1); $$ = $2; }
 566                                                   else { $$ = $1; }
 567                                                 }
 568         ;
 569
 570 field:    s_field ';'                           { $$ = $1; }
 571         | m_attributes uniondef ';'             { $$ = make_var(NULL); $$->type = $2; $$->attrs = $1; }
 572         | attributes ';'                        { $$ = make_var(NULL); $$->attrs = $1; }
 573         | ';'                                   { $$ = NULL; }
 574         ;
 575
 576 s_field:  m_attributes type pident array        { $$ = $3; set_type($$, $2, $4); $$->attrs = $1; }
 577         ;
 578
 579 funcdef:
 580           m_attributes type callconv pident
 581           '(' m_args ')'                        { set_type($4, $2, NULL);
 582                                                   $4->attrs = $1;
 583                                                   $$ = make_func($4, $6);
 584                                                   if (is_attr($4->attrs, ATTR_IN)) {
 585                                                     yyerror("inapplicable attribute [in] for function '%s'",$$->def->name);
 586                                                   }
 587                                                 }
 588         ;
 589
 590 m_ident:                                        { $$ = NULL; }
 591         | ident
 592         ;
 593
 594 t_ident:                                        { $$ = NULL; }
 595         | aIDENTIFIER                           { $$ = make_var($1); }
 596         | aKNOWNTYPE                            { $$ = make_var($1); }
 597         ;
 598
 599 ident:    aIDENTIFIER                           { $$ = make_var($1); }
 600 /* some "reserved words" used in attributes are also used as field names in some MS IDL files */
 601         | aKNOWNTYPE                            { $$ = make_var($<str>1); }
 602         | tASYNC                                { $$ = make_var($<str>1); }
 603         | tID                                   { $$ = make_var($<str>1); }
 604         | tLCID                                 { $$ = make_var($<str>1); }
 605         | tOBJECT                               { $$ = make_var($<str>1); }
 606         | tRANGE                                { $$ = make_var($<str>1); }
 607         | tRETVAL                               { $$ = make_var($<str>1); }
 608         | tUUID                                 { $$ = make_var($<str>1); }
 609         | tVERSION                              { $$ = make_var($<str>1); }
 610         ;
 611
 612 base_type: tBYTE                                { $$ = make_type(RPC_FC_BYTE, NULL); }
 613         | tWCHAR                                { $$ = make_type(RPC_FC_WCHAR, NULL); }
 614         | int_std
 615         | tSIGNED int_std                       { $$ = $2; $$->sign = 1; }
 616         | tUNSIGNED int_std                     { $$ = $2; $$->sign = -1;
 617                                                   switch ($$->type) {
 618                                                   case RPC_FC_CHAR:  break;
 619                                                   case RPC_FC_SMALL: $$->type = RPC_FC_USMALL; break;
 620                                                   case RPC_FC_SHORT: $$->type = RPC_FC_USHORT; break;
 621                                                   case RPC_FC_LONG:  $$->type = RPC_FC_ULONG;  break;
 622                                                   case RPC_FC_HYPER:
 623                                                     if (!$$->ref) { $$->ref = &std_uhyper; $$->sign = 0; }
 624                                                     break;
 625                                                   default: break;
 626                                                   }
 627                                                 }
 628         | tUNSIGNED                             { $$ = make_type(RPC_FC_ULONG, &std_int); $$->sign = -1; }
 629         | tFLOAT                                { $$ = make_type(RPC_FC_FLOAT, NULL); }
 630         | tSINGLE                               { $$ = make_type(RPC_FC_FLOAT, NULL); }
 631         | tDOUBLE                               { $$ = make_type(RPC_FC_DOUBLE, NULL); }
 632         | tBOOLEAN                              { $$ = make_type(RPC_FC_BYTE, &std_bool); /* ? */ }
 633         | tERRORSTATUST                         { $$ = make_type(RPC_FC_ERROR_STATUS_T, NULL); }
 634         | tHANDLET                              { $$ = make_type(RPC_FC_BIND_PRIMITIVE, NULL); /* ? */ }
 635         ;
 636
 637 m_int:
 638         | tINT
 639         ;
 640
 641 int_std:  tINT                                  { $$ = make_type(RPC_FC_LONG, &std_int); } /* win32 only */
 642         | tSHORT m_int                          { $$ = make_type(RPC_FC_SHORT, NULL); }
 643         | tSMALL                                { $$ = make_type(RPC_FC_SMALL, NULL); }
 644         | tLONG m_int                           { $$ = make_type(RPC_FC_LONG, NULL); }
 645         | tHYPER m_int                          { $$ = make_type(RPC_FC_HYPER, NULL); }
 646         | tINT64                                { $$ = make_type(RPC_FC_HYPER, &std_int64); }
 647         | tCHAR                                 { $$ = make_type(RPC_FC_CHAR, NULL); }
 648         ;
 649
 650 coclass:  tCOCLASS aIDENTIFIER                  { $$ = make_class($2); }
 651         | tCOCLASS aKNOWNTYPE                   { $$ = find_type($2, 0);
 652                                                   if ($$->defined) yyerror("multiple definition error");
 653                                                   if ($$->kind != TKIND_COCLASS) yyerror("%s was not declared a coclass", $2);
 654                                                 }
 655         ;
 656
 657 coclasshdr: attributes coclass                  { $$ = $2;
 658                                                   $$->attrs = $1;
 659                                                   if (!parse_only && do_header)
 660                                                     write_coclass($$);
 661                                                   if (!parse_only && do_idfile)
 662                                                     write_clsid($$);
 663                                                 }
 664         ;
 665
 666 coclassdef: coclasshdr '{' coclass_ints '}'     { $$ = $1;
 667                                                   $$->ifaces = $3;
 668                                                   $$->defined = TRUE;
 669                                                 }
 670         ;
 671
 672 coclass_ints:                                   { $$ = NULL; }
 673         | coclass_ints coclass_int              { LINK($2, $1); $$ = $2; }
 674         ;
 675
 676 coclass_int:
 677           m_attributes interfacedec             { $$ = make_ifref($2); $$->attrs = $1; }
 678         ;
 679
 680 dispinterface: tDISPINTERFACE aIDENTIFIER       { $$ = get_type(0, $2, 0); $$->kind = TKIND_DISPATCH; }
 681         |      tDISPINTERFACE aKNOWNTYPE        { $$ = get_type(0, $2, 0); $$->kind = TKIND_DISPATCH; }
 682         ;
 683
 684 dispinterfacehdr: attributes dispinterface      { attr_t *attrs;
 685                                                   $$ = $2;
 686                                                   if ($$->defined) yyerror("multiple definition error");
 687                                                   attrs = make_attr(ATTR_DISPINTERFACE);
 688                                                   LINK(attrs, $1);
 689                                                   $$->attrs = attrs;
 690                                                   $$->ref = find_type("IDispatch", 0);
 691                                                   if (!$$->ref) yyerror("IDispatch is undefined");
 692                                                   $$->defined = TRUE;
 693                                                   if (!parse_only && do_header) write_forward($$);
 694                                                 }
 695         ;
 696
 697 dispint_props: tPROPERTIES ':'                  { $$ = NULL; }
 698         | dispint_props s_field ';'             { LINK($2, $1); $$ = $2; }
 699         ;
 700
 701 dispint_meths: tMETHODS ':'                     { $$ = NULL; }
 702         | dispint_meths funcdef ';'             { LINK($2, $1); $$ = $2; }
 703         ;
 704
 705 dispinterfacedef: dispinterfacehdr '{'
 706           dispint_props
 707           dispint_meths
 708           '}'                                   { $$ = $1;
 709                                                   $$->fields = $3;
 710                                                   $$->funcs = $4;
 711                                                   if (!parse_only && do_header) write_dispinterface($$);
 712                                                   if (!parse_only && do_idfile) write_diid($$);
 713                                                 }
 714 /* FIXME: not sure how to handle this yet
 715         | dispinterfacehdr '{' interface '}'    { $$ = $1;
 716                                                   compute_method_indexes($$);
 717                                                   if (!parse_only && do_header) write_interface($$);
 718                                                   if (!parse_only && do_idfile) write_iid($$);
 719                                                 }
 720 */
 721         ;
 722
 723 inherit:                                        { $$ = NULL; }
 724         | ':' aKNOWNTYPE                        { $$ = find_type2($2, 0); }
 725         ;
 726
 727 interface: tINTERFACE aIDENTIFIER               { $$ = get_type(RPC_FC_IP, $2, 0); $$->kind = TKIND_INTERFACE; }
 728         |  tINTERFACE aKNOWNTYPE                { $$ = get_type(RPC_FC_IP, $2, 0); $$->kind = TKIND_INTERFACE; }
 729         ;
 730
 731 interfacehdr: attributes interface              { $$ = $2;
 732                                                   if ($$->defined) yyerror("multiple definition error");
 733                                                   $$->attrs = $1;
 734                                                   $$->defined = TRUE;
 735                                                   if (!parse_only && do_header) write_forward($$);
 736                                                 }
 737         ;
 738
 739 interfacedef: interfacehdr inherit
 740           '{' int_statements '}'                { $$ = $1;
 741                                                   $$->ref = $2;
 742                                                   $$->funcs = $4;
 743                                                   compute_method_indexes($$);
 744                                                   if (!parse_only && do_header) write_interface($$);
 745                                                   if (!parse_only && do_idfile) write_iid($$);
 746                                                 }
 747 /* MIDL is able to import the definition of a base class from inside the
 748  * definition of a derived class, I'll try to support it with this rule */
 749         | interfacehdr ':' aIDENTIFIER
 750           '{' import int_statements '}'         { $$ = $1;
 751                                                   $$->ref = find_type2($3, 0);
 752                                                   if (!$$->ref) yyerror("base class '%s' not found in import", $3);
 753                                                   $$->funcs = $6;
 754                                                   compute_method_indexes($$);
 755                                                   if (!parse_only && do_header) write_interface($$);
 756                                                   if (!parse_only && do_idfile) write_iid($$);
 757                                                 }
 758         | dispinterfacedef                      { $$ = $1; }
 759         ;
 760
 761 interfacedec:
 762           interface ';'                         { $$ = $1; if (!parse_only && do_header) write_forward($$); }
 763         | dispinterface ';'                     { $$ = $1; if (!parse_only && do_header) write_forward($$); }
 764         ;
 765
 766 module:   tMODULE aIDENTIFIER                   { $$ = make_type(0, NULL); $$->name = $2; $$->kind = TKIND_MODULE; }
 767         | tMODULE aKNOWNTYPE                    { $$ = make_type(0, NULL); $$->name = $2; $$->kind = TKIND_MODULE; }
 768         ;
 769
 770 modulehdr: attributes module                    { $$ = $2;
 771                                                   $$->attrs = $1;
 772                                                 }
 773         ;
 774
 775 moduledef: modulehdr '{' int_statements '}'     { $$ = $1;
 776                                                   $$->funcs = $3;
 777                                                   /* FIXME: if (!parse_only && do_header) write_module($$); */
 778                                                 }
 779         ;
 780
 781 p_ident:  '*' pident %prec PPTR                 { $$ = $2; $$->ptr_level++; }
 782         | tCONST p_ident                        { $$ = $2; /* FIXME */ }
 783         ;
 784
 785 pident:   ident
 786         | p_ident
 787         | '(' pident ')'                        { $$ = $2; }
 788         ;
 789
 790 pident_list:
 791           pident
 792         | pident_list ',' pident                { LINK($3, $1); $$ = $3; }
 793         ;
 794
 795 pointer_type:
 796           tREF                                  { $$ = RPC_FC_RP; }
 797         | tUNIQUE                               { $$ = RPC_FC_UP; }
 798         | tPTR                                  { $$ = RPC_FC_FP; }
 799         ;
 800
 801 structdef: tSTRUCT t_ident '{' fields '}'       { $$ = get_typev(RPC_FC_STRUCT, $2, tsSTRUCT);
 802                                                   /* overwrite RPC_FC_STRUCT with a more exact type */
 803                                                   $$->type = get_struct_type( $4 );
 804                                                   $$->kind = TKIND_RECORD;
 805                                                   $$->fields = $4;
 806                                                   $$->defined = TRUE;
 807                                                   if(in_typelib)
 808                                                       add_struct($$);
 809                                                 }
 810         ;
 811
 812 type:     tVOID                                 { $$ = make_tref(NULL, make_type(0, NULL)); }
 813         | aKNOWNTYPE                            { $$ = make_tref($1, find_type($1, 0)); }
 814         | base_type                             { $$ = make_tref(NULL, $1); }
 815         | tCONST type                           { $$ = uniq_tref($2); $$->ref->is_const = TRUE; }
 816         | enumdef                               { $$ = make_tref(NULL, $1); }
 817         | tENUM aIDENTIFIER                     { $$ = make_tref(NULL, find_type2($2, tsENUM)); }
 818         | structdef                             { $$ = make_tref(NULL, $1); }
 819         | tSTRUCT aIDENTIFIER                   { $$ = make_tref(NULL, get_type(RPC_FC_STRUCT, $2, tsSTRUCT)); }
 820         | uniondef                              { $$ = make_tref(NULL, $1); }
 821         | tUNION aIDENTIFIER                    { $$ = make_tref(NULL, find_type2($2, tsUNION)); }
 822         | tSAFEARRAY '(' type ')'               { $$ = make_tref(NULL, make_safearray()); }
 823         ;
 824
 825 typedef: tTYPEDEF m_attributes type pident_list { typeref_t *tref = uniq_tref($3);
 826                                                   $4->tname = tref->name;
 827                                                   tref->name = NULL;
 828                                                   $$ = type_ref(tref);
 829                                                   $$->attrs = $2;
 830                                                   if (!parse_only && do_header)
 831                                                     write_typedef($$, $4);
 832                                                   if (in_typelib && $$->attrs)
 833                                                     add_typedef($$, $4);
 834                                                   reg_types($$, $4, 0);
 835                                                 }
 836         ;
 837
 838 uniondef: tUNION t_ident '{' fields '}'         { $$ = get_typev(RPC_FC_NON_ENCAPSULATED_UNION, $2, tsUNION);
 839                                                   $$->kind = TKIND_UNION;
 840                                                   $$->fields = $4;
 841                                                   $$->defined = TRUE;
 842                                                 }
 843         | tUNION t_ident
 844           tSWITCH '(' s_field ')'
 845           m_ident '{' cases '}'                 { var_t *u = $7;
 846                                                   $$ = get_typev(RPC_FC_ENCAPSULATED_UNION, $2, tsUNION);
 847                                                   $$->kind = TKIND_UNION;
 848                                                   if (!u) u = make_var("tagged_union");
 849                                                   u->type = make_type(RPC_FC_NON_ENCAPSULATED_UNION, NULL);
 850                                                   u->type->kind = TKIND_UNION;
 851                                                   u->type->fields = $9;
 852                                                   u->type->defined = TRUE;
 853                                                   LINK(u, $5); $$->fields = u;
 854                                                   $$->defined = TRUE;
 855                                                 }
 856         ;
 857
 858 version:
 859           aNUM                                  { $$ = MAKELONG($1, 0); }
 860         | aNUM '.' aNUM                         { $$ = MAKELONG($1, $3); }
 861         ;
 862
 863 %%
 864
 865 static attr_t *make_attr(enum attr_type type)
 866 {
 867   attr_t *a = xmalloc(sizeof(attr_t));
 868   a->type = type;
 869   a->u.ival = 0;
 870   INIT_LINK(a);
 871   return a;
 872 }
 873
 874 static attr_t *make_attrv(enum attr_type type, unsigned long val)
 875 {
 876   attr_t *a = xmalloc(sizeof(attr_t));
 877   a->type = type;
 878   a->u.ival = val;
 879   INIT_LINK(a);
 880   return a;
 881 }
 882
 883 static attr_t *make_attrp(enum attr_type type, void *val)
 884 {
 885   attr_t *a = xmalloc(sizeof(attr_t));
 886   a->type = type;
 887   a->u.pval = val;
 888   INIT_LINK(a);
 889   return a;
 890 }
 891
 892 static expr_t *make_expr(enum expr_type type)
 893 {
 894   expr_t *e = xmalloc(sizeof(expr_t));
 895   e->type = type;
 896   e->ref = NULL;
 897   e->u.lval = 0;
 898   e->is_const = FALSE;
 899   INIT_LINK(e);
 900   return e;
 901 }
 902
 903 static expr_t *make_exprl(enum expr_type type, long val)
 904 {
 905   expr_t *e = xmalloc(sizeof(expr_t));
 906   e->type = type;
 907   e->ref = NULL;
 908   e->u.lval = val;
 909   e->is_const = FALSE;
 910   INIT_LINK(e);
 911   /* check for numeric constant */
 912   if (type == EXPR_NUM || type == EXPR_HEXNUM || type == EXPR_TRUEFALSE) {
 913     /* make sure true/false value is valid */
 914     assert(type != EXPR_TRUEFALSE || val == 0 || val == 1);
 915     e->is_const = TRUE;
 916     e->cval = val;
 917   }
 918   return e;
 919 }
 920
 921 static expr_t *make_exprs(enum expr_type type, char *val)
 922 {
 923   expr_t *e;
 924   e = xmalloc(sizeof(expr_t));
 925   e->type = type;
 926   e->ref = NULL;
 927   e->u.sval = val;
 928   e->is_const = FALSE;
 929   INIT_LINK(e);
 930   /* check for predefined constants */
 931   if (type == EXPR_IDENTIFIER) {
 932     var_t *c = find_const(val, 0);
 933     if (c) {
 934       e->u.sval = c->name;
 935       free(val);
 936       e->is_const = TRUE;
 937       e->cval = c->eval->cval;
 938     }
 939   }
 940   return e;
 941 }
 942
 943 static expr_t *make_exprt(enum expr_type type, typeref_t *tref, expr_t *expr)
 944 {
 945   expr_t *e;
 946   e = xmalloc(sizeof(expr_t));
 947   e->type = type;
 948   e->ref = expr;
 949   e->u.tref = tref;
 950   e->is_const = FALSE;
 951   INIT_LINK(e);
 952   /* check for cast of constant expression */
 953   if (type == EXPR_SIZEOF) {
 954     switch (tref->ref->type) {
 955       case RPC_FC_BYTE:
 956       case RPC_FC_CHAR:
 957       case RPC_FC_SMALL:
 958       case RPC_FC_USMALL:
 959         e->is_const = TRUE;
 960         e->cval = 1;
 961         break;
 962       case RPC_FC_WCHAR:
 963       case RPC_FC_USHORT:
 964       case RPC_FC_SHORT:
 965         e->is_const = TRUE;
 966         e->cval = 2;
 967         break;
 968       case RPC_FC_LONG:
 969       case RPC_FC_ULONG:
 970       case RPC_FC_FLOAT:
 971       case RPC_FC_ERROR_STATUS_T:
 972         e->is_const = TRUE;
 973         e->cval = 4;
 974         break;
 975       case RPC_FC_HYPER:
 976       case RPC_FC_DOUBLE:
 977         e->is_const = TRUE;
 978         e->cval = 8;
 979         break;
 980     }
 981   }
 982   if (type == EXPR_CAST && expr->is_const) {
 983     e->is_const = TRUE;
 984     e->cval = expr->cval;
 985   }
 986   return e;
 987 }
 988
 989 static expr_t *make_expr1(enum expr_type type, expr_t *expr)
 990 {
 991   expr_t *e;
 992   e = xmalloc(sizeof(expr_t));
 993   e->type = type;
 994   e->ref = expr;
 995   e->u.lval = 0;
 996   e->is_const = FALSE;
 997   INIT_LINK(e);
 998   /* check for compile-time optimization */
 999   if (expr->is_const) {
1000     e->is_const = TRUE;
1001     switch (type) {
1002     case EXPR_NEG:
1003       e->cval = -expr->cval;
1004       break;
1005     case EXPR_NOT:
1006       e->cval = ~expr->cval;
1007       break;
1008     default:
1009       e->is_const = FALSE;
1010       break;
1011     }
1012   }
1013   return e;
1014 }
1015
1016 static expr_t *make_expr2(enum expr_type type, expr_t *expr1, expr_t *expr2)
1017 {
1018   expr_t *e;
1019   e = xmalloc(sizeof(expr_t));
1020   e->type = type;
1021   e->ref = expr1;
1022   e->u.ext = expr2;
1023   e->is_const = FALSE;
1024   INIT_LINK(e);
1025   /* check for compile-time optimization */
1026   if (expr1->is_const && expr2->is_const) {
1027     e->is_const = TRUE;
1028     switch (type) {
1029     case EXPR_ADD:
1030       e->cval = expr1->cval + expr2->cval;
1031       break;
1032     case EXPR_SUB:
1033       e->cval = expr1->cval - expr2->cval;
1034       break;
1035     case EXPR_MUL:
1036       e->cval = expr1->cval * expr2->cval;
1037       break;
1038     case EXPR_DIV:
1039       e->cval = expr1->cval / expr2->cval;
1040       break;
1041     case EXPR_OR:
1042       e->cval = expr1->cval | expr2->cval;
1043       break;
1044     case EXPR_AND:
1045       e->cval = expr1->cval & expr2->cval;
1046       break;
1047     case EXPR_SHL:
1048       e->cval = expr1->cval << expr2->cval;
1049       break;
1050     case EXPR_SHR:
1051       e->cval = expr1->cval >> expr2->cval;
1052       break;
1053     default:
1054       e->is_const = FALSE;
1055       break;
1056     }
1057   }
1058   return e;
1059 }
1060
1061 static expr_t *make_expr3(enum expr_type type, expr_t *expr1, expr_t *expr2, expr_t *expr3)
1062 {
1063   expr_t *e;
1064   e = xmalloc(sizeof(expr_t));
1065   e->type = type;
1066   e->ref = expr1;
1067   e->u.ext = expr2;
1068   e->ext2 = expr3;
1069   e->is_const = FALSE;
1070   INIT_LINK(e);
1071   /* check for compile-time optimization */
1072   if (expr1->is_const && expr2->is_const && expr3->is_const) {
1073     e->is_const = TRUE;
1074     switch (type) {
1075     case EXPR_COND:
1076       e->cval = expr1->cval ? expr2->cval : expr3->cval;
1077       break;
1078     default:
1079       e->is_const = FALSE;
1080       break;
1081     }
1082   }
1083   return e;
1084 }
1085
1086 static type_t *make_type(unsigned char type, type_t *ref)
1087 {
1088   type_t *t = xmalloc(sizeof(type_t));
1089   t->name = NULL;
1090   t->kind = TKIND_PRIMITIVE;
1091   t->type = type;
1092   t->ref = ref;
1093   t->attrs = NULL;
1094   t->funcs = NULL;
1095   t->fields = NULL;
1096   t->ifaces = NULL;
1097   t->ignore = parse_only;
1098   t->is_const = FALSE;
1099   t->sign = 0;
1100   t->defined = FALSE;
1101   t->written = FALSE;
1102   t->typelib_idx = -1;
1103   INIT_LINK(t);
1104   return t;
1105 }
1106
1107 static typeref_t *make_tref(char *name, type_t *ref)
1108 {
1109   typeref_t *t = xmalloc(sizeof(typeref_t));
1110   t->name = name;
1111   t->ref = ref;
1112   t->uniq = ref ? 0 : 1;
1113   return t;
1114 }
1115
1116 static typeref_t *uniq_tref(typeref_t *ref)
1117 {
1118   typeref_t *t = ref;
1119   type_t *tp;
1120   if (t->uniq) return t;
1121   tp = make_type(0, t->ref);
1122   tp->name = t->name;
1123   t->name = NULL;
1124   t->ref = tp;
1125   t->uniq = 1;
1126   return t;
1127 }
1128
1129 static type_t *type_ref(typeref_t *ref)
1130 {
1131   type_t *t = ref->ref;
1132   if (ref->name) free(ref->name);
1133   free(ref);
1134   return t;
1135 }
1136
1137 static void set_type(var_t *v, typeref_t *ref, expr_t *arr)
1138 {
1139   v->type = ref->ref;
1140   v->tname = ref->name;
1141   ref->name = NULL;
1142   free(ref);
1143   v->array = arr;
1144 }
1145
1146 static ifref_t *make_ifref(type_t *iface)
1147 {
1148   ifref_t *l = xmalloc(sizeof(ifref_t));
1149   l->iface = iface;
1150   l->attrs = NULL;
1151   INIT_LINK(l);
1152   return l;
1153 }
1154
1155 static var_t *make_var(char *name)
1156 {
1157   var_t *v = xmalloc(sizeof(var_t));
1158   v->name = name;
1159   v->ptr_level = 0;
1160   v->type = NULL;
1161   v->tname = NULL;
1162   v->attrs = NULL;
1163   v->array = NULL;
1164   v->eval = NULL;
1165   INIT_LINK(v);
1166   return v;
1167 }
1168
1169 static func_t *make_func(var_t *def, var_t *args)
1170 {
1171   func_t *f = xmalloc(sizeof(func_t));
1172   f->def = def;
1173   f->args = args;
1174   f->ignore = parse_only;
1175   f->idx = -1;
1176   INIT_LINK(f);
1177   return f;
1178 }
1179
1180 static type_t *make_class(char *name)
1181 {
1182   type_t *c = make_type(0, NULL);
1183   c->name = name;
1184   c->kind = TKIND_COCLASS;
1185   INIT_LINK(c);
1186   return c;
1187 }
1188
1189 static type_t *make_safearray(void)
1190 {
1191   return make_type(RPC_FC_FP, find_type("SAFEARRAY", 0));
1192 }
1193
1194 #define HASHMAX 64
1195
1196 static int hash_ident(const char *name)
1197 {
1198   const char *p = name;
1199   int sum = 0;
1200   /* a simple sum hash is probably good enough */
1201   while (*p) {
1202     sum += *p;
1203     p++;
1204   }
1205   return sum & (HASHMAX-1);
1206 }
1207
1208 /***** type repository *****/
1209
1210 struct rtype {
1211   const char *name;
1212   type_t *type;
1213   int t;
1214   struct rtype *next;
1215 };
1216
1217 struct rtype *type_hash[HASHMAX];
1218
1219 static type_t *reg_type(type_t *type, const char *name, int t)
1220 {
1221   struct rtype *nt;
1222   int hash;
1223   if (!name) {
1224     yyerror("registering named type without name");
1225     return type;
1226   }
1227   hash = hash_ident(name);
1228   nt = xmalloc(sizeof(struct rtype));
1229   nt->name = name;
1230   nt->type = type;
1231   nt->t = t;
1232   nt->next = type_hash[hash];
1233   type_hash[hash] = nt;
1234   return type;
1235 }
1236
1237 /* determine pointer type from attrs */
1238 static unsigned char get_pointer_type( type_t *type )
1239 {
1240   int t;
1241   if (is_attr( type->attrs, ATTR_STRING ))
1242   {
1243     switch( ref_type( type ) )
1244     {
1245     case RPC_FC_CHAR:
1246       return RPC_FC_C_CSTRING;
1247     case RPC_FC_WCHAR:
1248       return RPC_FC_C_WSTRING;
1249     }
1250   }
1251   t = get_attrv( type->attrs, ATTR_POINTERTYPE );
1252   if (t) return t;
1253   return RPC_FC_FP;
1254 }
1255
1256 static type_t *reg_types(type_t *type, var_t *names, int t)
1257 {
1258   type_t *ptr = type;
1259   int ptrc = 0;
1260
1261   while (names) {
1262     var_t *next = NEXT_LINK(names);
1263     if (names->name) {
1264       type_t *cur = ptr;
1265       int cptr = names->ptr_level;
1266       if (cptr > ptrc) {
1267         while (cptr > ptrc) {
1268           int t = get_pointer_type( cur );
1269           cur = ptr = make_type(t, cur);
1270           ptrc++;
1271         }
1272       } else {
1273         while (cptr < ptrc) {
1274           cur = cur->ref;
1275           cptr++;
1276         }
1277       }
1278       reg_type(cur, names->name, t);
1279     }
1280     free(names);
1281     names = next;
1282   }
1283   return type;
1284 }
1285
1286 static type_t *find_type(const char *name, int t)
1287 {
1288   struct rtype *cur = type_hash[hash_ident(name)];
1289   while (cur && (cur->t != t || strcmp(cur->name, name)))
1290     cur = cur->next;
1291   if (!cur) {
1292     yyerror("type '%s' not found", name);
1293     return NULL;
1294   }
1295   return cur->type;
1296 }
1297
1298 static type_t *find_type2(char *name, int t)
1299 {
1300   type_t *tp = find_type(name, t);
1301   free(name);
1302   return tp;
1303 }
1304
1305 int is_type(const char *name)
1306 {
1307   struct rtype *cur = type_hash[hash_ident(name)];
1308   while (cur && (cur->t || strcmp(cur->name, name)))
1309     cur = cur->next;
1310   if (cur) return TRUE;
1311   return FALSE;
1312 }
1313
1314 static type_t *get_type(unsigned char type, char *name, int t)
1315 {
1316   struct rtype *cur = NULL;
1317   type_t *tp;
1318   if (name) {
1319     cur = type_hash[hash_ident(name)];
1320     while (cur && (cur->t != t || strcmp(cur->name, name)))
1321       cur = cur->next;
1322   }
1323   if (cur) {
1324     free(name);
1325     return cur->type;
1326   }
1327   tp = make_type(type, NULL);
1328   tp->name = name;
1329   if (!name) return tp;
1330   return reg_type(tp, name, t);
1331 }
1332
1333 static type_t *get_typev(unsigned char type, var_t *name, int t)
1334 {
1335   char *sname = NULL;
1336   if (name) {
1337     sname = name->name;
1338     free(name);
1339   }
1340   return get_type(type, sname, t);
1341 }
1342
1343 static int get_struct_type(var_t *field)
1344 {
1345   int has_pointer = 0;
1346   int has_conformance = 0;
1347   int has_variance = 0;
1348
1349   for (; field; field = NEXT_LINK(field))
1350   {
1351     type_t *t = field->type;
1352
1353     /* get the base type */
1354     while( (t->type == 0) && t->ref )
1355       t = t->ref;
1356
1357     if (field->ptr_level > 0)
1358     {
1359         has_pointer = 1;
1360         continue;
1361     }
1362
1363     if (is_string_type(field->attrs, 0, field->array))
1364     {
1365         has_conformance = 1;
1366         has_variance = 1;
1367         continue;
1368     }
1369
1370     if (is_array_type(field->attrs, 0, field->array))
1371     {
1372         if (field->array && !field->array->is_const)
1373         {
1374             has_conformance = 1;
1375             if (PREV_LINK(field))
1376                 yyerror("field '%s' deriving from a conformant array must be the last field in the structure",
1377                         field->name);
1378         }
1379         if (is_attr(field->attrs, ATTR_LENGTHIS))
1380             has_variance = 1;
1381     }
1382
1383     switch (t->type)
1384     {
1385     /*
1386      * RPC_FC_BYTE, RPC_FC_STRUCT, etc
1387      *  Simple types don't effect the type of struct.
1388      *  A struct containing a simple struct is still a simple struct.
1389      *  So long as we can block copy the data, we return RPC_FC_STRUCT.
1390      */
1391     case 0: /* void pointer */
1392     case RPC_FC_BYTE:
1393     case RPC_FC_CHAR:
1394     case RPC_FC_SMALL:
1395     case RPC_FC_USMALL:
1396     case RPC_FC_WCHAR:
1397     case RPC_FC_SHORT:
1398     case RPC_FC_USHORT:
1399     case RPC_FC_LONG:
1400     case RPC_FC_ULONG:
1401     case RPC_FC_INT3264:
1402     case RPC_FC_UINT3264:
1403     case RPC_FC_HYPER:
1404     case RPC_FC_FLOAT:
1405     case RPC_FC_DOUBLE:
1406     case RPC_FC_STRUCT:
1407     case RPC_FC_ENUM16:
1408     case RPC_FC_ENUM32:
1409       break;
1410
1411     case RPC_FC_UP:
1412     case RPC_FC_FP:
1413       has_pointer = 1;
1414       break;
1415     case RPC_FC_CARRAY:
1416       has_conformance = 1;
1417       if (PREV_LINK(field))
1418           yyerror("field '%s' deriving from a conformant array must be the last field in the structure",
1419                   field->name);
1420       break;
1421     case RPC_FC_C_CSTRING:
1422     case RPC_FC_C_WSTRING:
1423       has_conformance = 1;
1424       has_variance = 1;
1425       break;
1426
1427     /*
1428      * Propagate member attributes
1429      *  a struct should be at least as complex as its member
1430      */
1431     case RPC_FC_CVSTRUCT:
1432       has_conformance = 1;
1433       has_variance = 1;
1434       has_pointer = 1;
1435       break;
1436
1437     case RPC_FC_CPSTRUCT:
1438       has_conformance = 1;
1439       if (PREV_LINK(field))
1440           yyerror("field '%s' deriving from a conformant array must be the last field in the structure",
1441                   field->name);
1442       has_pointer = 1;
1443       break;
1444
1445     case RPC_FC_CSTRUCT:
1446       has_conformance = 1;
1447       if (PREV_LINK(field))
1448           yyerror("field '%s' deriving from a conformant array must be the last field in the structure",
1449                   field->name);
1450       break;
1451
1452     case RPC_FC_PSTRUCT:
1453       has_pointer = 1;
1454       break;
1455
1456     default:
1457       fprintf(stderr,"Unknown struct member %s with type (0x%02x)\n",
1458               field->name, t->type);
1459       /* fallthru - treat it as complex */
1460
1461     /* as soon as we see one of these these members, it's bogus... */
1462     case RPC_FC_IP:
1463     case RPC_FC_ENCAPSULATED_UNION:
1464     case RPC_FC_NON_ENCAPSULATED_UNION:
1465     case RPC_FC_TRANSMIT_AS:
1466     case RPC_FC_REPRESENT_AS:
1467     case RPC_FC_PAD:
1468     case RPC_FC_EMBEDDED_COMPLEX:
1469     case RPC_FC_BOGUS_STRUCT:
1470       return RPC_FC_BOGUS_STRUCT;
1471     }
1472   }
1473
1474   if( has_variance )
1475     return RPC_FC_CVSTRUCT;
1476   if( has_conformance && has_pointer )
1477     return RPC_FC_CPSTRUCT;
1478   if( has_conformance )
1479     return RPC_FC_CSTRUCT;
1480   if( has_pointer )
1481     return RPC_FC_PSTRUCT;
1482   return RPC_FC_STRUCT;
1483 }
1484
1485 /***** constant repository *****/
1486
1487 struct rconst {
1488   char *name;
1489   var_t *var;
1490   struct rconst *next;
1491 };
1492
1493 struct rconst *const_hash[HASHMAX];
1494
1495 static var_t *reg_const(var_t *var)
1496 {
1497   struct rconst *nc;
1498   int hash;
1499   if (!var->name) {
1500     yyerror("registering constant without name");
1501     return var;
1502   }
1503   hash = hash_ident(var->name);
1504   nc = xmalloc(sizeof(struct rconst));
1505   nc->name = var->name;
1506   nc->var = var;
1507   nc->next = const_hash[hash];
1508   const_hash[hash] = nc;
1509   return var;
1510 }
1511
1512 static var_t *find_const(char *name, int f)
1513 {
1514   struct rconst *cur = const_hash[hash_ident(name)];
1515   while (cur && strcmp(cur->name, name))
1516     cur = cur->next;
1517   if (!cur) {
1518     if (f) yyerror("constant '%s' not found", name);
1519     return NULL;
1520   }
1521   return cur->var;
1522 }
1523
1524 static void write_libid(const char *name, const attr_t *attr)
1525 {
1526   const UUID *uuid = get_attrp(attr, ATTR_UUID);
1527   write_guid(idfile, "LIBID", name, uuid);
1528 }
1529
1530 static void write_clsid(type_t *cls)
1531 {
1532   const UUID *uuid = get_attrp(cls->attrs, ATTR_UUID);
1533   write_guid(idfile, "CLSID", cls->name, uuid);
1534 }
1535
1536 static void write_diid(type_t *iface)
1537 {
1538   const UUID *uuid = get_attrp(iface->attrs, ATTR_UUID);
1539   write_guid(idfile, "DIID", iface->name, uuid);
1540 }
1541
1542 static void write_iid(type_t *iface)
1543 {
1544   const UUID *uuid = get_attrp(iface->attrs, ATTR_UUID);
1545   write_guid(idfile, "IID", iface->name, uuid);
1546 }
1547
1548 static int compute_method_indexes(type_t *iface)
1549 {
1550   int idx;
1551   func_t *f = iface->funcs;
1552
1553   if (iface->ref)
1554     idx = compute_method_indexes(iface->ref);
1555   else
1556     idx = 0;
1557
1558   if (! f)
1559     return idx;
1560
1561   while (NEXT_LINK(f))
1562     f = NEXT_LINK(f);
1563
1564   for ( ; f ; f = PREV_LINK(f))
1565     if (! is_callas(f->def->attrs))
1566       f->idx = idx++;
1567
1568   return idx;
1569 }