git.oblomov.eu Git - wine/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Author: Michael Patra   <micky@marie.physik.tu-berlin.de>
   3 dnl                         <patra@itp1.physik.tu-berlin.de>
   4 AC_REVISION([configure.in 1.00])
   5 AC_INIT(controls/edit.c)
   6 AC_CONFIG_HEADER(include/config.h)
   7 AC_CONFIG_AUX_DIR(tools)
   8
   9 # We want these before the checks, so the checks can modify their values.
  10 LIBS="$LIBS -lm"
  11 test -z "$PROGEXT" && PROGEXT="" AC_SUBST(PROGEXT)
  12
  13 dnl **** Command-line arguments ****
  14
  15 dnl Default values
  16 MAIN_TARGET=emu
  17 LIB_TARGET=libwine.a
  18 ALT_LINK="-L\$(TOPOBJDIR) -lwine"
  19 TRACE_MSGS=yes  # the TRACE() macro
  20 DEBUG_MSGS=yes  # the TRACE(), WARN(), and FIXME() macros.
  21
  22 AC_ARG_ENABLE(emulator,
  23 [  --disable-emulator      build only the Wine library, not the emulator],
  24 [if test "$enableval" = "no"; then MAIN_TARGET="lib"; fi])
  25
  26 AC_ARG_ENABLE(dll,
  27 [  --enable-dll            build the Wine library as a DLL],
  28 [if test "$enableval" = "no"; then : ; else LIB_TARGET="libwine.so.1.0"; fi])
  29
  30 AC_ARG_ENABLE(lib,
  31 [  --disable-lib           build the Wine without building libwine.a],
  32 [if test "$enableval" = "no"; then ALT_LINK="\$(LIBOBJS) \$(X11OBJS)"; LIB_TARGET=""; fi])
  33
  34 dnl AC_ARG_WITH(ipc,
  35 dnl [  --enable-ipc            use inter-process communication for DDE],
  36 dnl [if test "$enableval" = "no"; then : ; else OPTIONS="-DCONFIG_IPC"; fi])
  37
  38 AC_ARG_ENABLE(debug,
  39 [  --disable-debug         compile out all debugging messages],
  40 [if test "$enableval" = "no"; then DEBUG_MSGS="no"; fi])
  41
  42 AC_ARG_ENABLE(trace,
  43 [  --disable-trace         compile out TRACE messages],
  44 [if test "$enableval" = "no"; then TRACE_MSGS="no"; fi])
  45
  46 AC_ARG_WITH(reentrant-x,
  47 [  --without-reentrant-x   compile for use with non-reentrant X libraries])
  48
  49 AC_SUBST(MAIN_TARGET)
  50 AC_SUBST(LIB_TARGET)
  51 AC_SUBST(ALT_LINK)
  52 AC_SUBST(OPTIONS)
  53
  54 if test "$DEBUG_MSGS" = "no"
  55 then
  56     AC_DEFINE(NO_DEBUG_MSGS)
  57     AC_DEFINE(NO_TRACE_MSGS)
  58 else
  59     if test "$TRACE_MSGS" = "no"
  60     then
  61         AC_DEFINE(NO_TRACE_MSGS)
  62     fi
  63 fi
  64
  65 dnl **** Check for some programs ****
  66
  67 AC_PROG_MAKE_SET
  68 AC_PROG_CC
  69 AC_PROG_CPP
  70 AC_PATH_XTRA
  71 AC_PROG_YACC
  72 AC_PROG_LEX
  73 AC_PROG_RANLIB
  74 AC_PROG_INSTALL
  75 AC_PROG_LN_S
  76 AC_CHECK_PROG(C2MAN,c2man,c2man,true)
  77
  78 dnl **** Check for some libraries ****
  79
  80 dnl Check for -li386 for NetBSD and OpenBSD
  81 AC_CHECK_LIB(i386,i386_set_ldt)
  82 dnl Check for -lossaudio for NetBSD
  83 AC_CHECK_LIB(ossaudio,_oss_ioctl)
  84 dnl Check for -lw for Solaris
  85 AC_CHECK_LIB(w,iswalnum)
  86 dnl Check for -lnsl for Solaris
  87 AC_CHECK_FUNCS(gethostbyname)
  88 if test "$ac_cv_func_gethostbyname" = "no"
  89 then
  90     AC_CHECK_LIB(nsl,gethostbyname)
  91 fi
  92 dnl Check for -lxpg4 for FreeBSD
  93 AC_CHECK_LIB(xpg4,setrunelocale)
  94 dnl Check for -ldl
  95 AC_CHECK_LIB(dl,dlopen)
  96 AC_SUBST(XLIB)
  97 if test "$have_x" = "yes"
  98 then
  99     XLIB="-lXext -lX11"
 100     ac_save_CPPFLAGS="$CPPFLAGS"
 101     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 102
 103     dnl Check for -lXpm
 104     AC_CHECK_HEADERS(X11/xpm.h)
 105     if test "$ac_cv_header_X11_xpm_h" = "yes"
 106     then
 107         AC_CHECK_LIB(Xpm,XpmCreatePixmapFromData,AC_DEFINE(HAVE_LIBXXPM) X_PRE_LIBS="$X_PRE_LIBS -lXpm",,$X_LIBS -lXext -lX11)
 108     fi
 109
 110     dnl Check for X Shm extension
 111     AC_CHECK_HEADERS(X11/Xlib.h X11/extensions/XShm.h)
 112     if test "$ac_cv_header_X11_Xlib_h" = "yes" -a "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 113     then
 114         AC_CHECK_LIB(Xext,XShmQueryExtension,AC_DEFINE(HAVE_LIBXXSHM),,$X_LIBS -lXext -lX11)
 115     fi
 116     dnl Check for XFree86 DGA extension
 117     AC_CHECK_HEADERS(X11/Xlib.h X11/extensions/xf86dga.h)
 118     if test "$ac_cv_header_X11_Xlib_h" = "yes" -a "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
 119     then
 120          AC_CHECK_LIB(Xxf86dga,XF86DGAQueryExtension,AC_DEFINE(HAVE_LIBXXF86DGA) X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga",,$X_LIBS -lXext -lX11)
 121     fi
 122
 123     dnl Check for XFree86 VMODE extension
 124     AC_CHECK_HEADERS(X11/Xlib.h X11/extensions/xf86vmode.h)
 125     if test "$ac_cv_header_X11_Xlib_h" = "yes" -a "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 126     then
 127         AC_CHECK_LIB(Xxf86vm,XF86VidModeQueryExtension,AC_DEFINE(HAVE_LIBXXF86VM) X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm",,$X_LIBS -lXext -lX11)
 128     fi
 129     dnl Check for the presence of Mesa
 130     AC_CHECK_HEADERS(GL/gl.h GL/osmesa.h)
 131     if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_osmesa_h" = "yes"
 132     then
 133         AC_CHECK_LIB(MesaGL,OSMesaCreateContext,AC_DEFINE(HAVE_LIBMESAGL) X_PRE_LIBS="$X_PRE_LIBS -lMesaGL",,$X_LIBS -lXext -lX11 -lm)
 134     fi
 135
 136     CPPFLAGS="$ac_save_CPPFLAGS"
 137 else
 138     XLIB=""
 139     X_CFLAGS=""
 140     X_LIBS=""
 141 fi
 142
 143 dnl **** Check which curses lib to use ***
 144 AC_CHECK_HEADERS(ncurses.h)
 145 if test "$ac_cv_header_ncurses_h" = "yes"
 146 then
 147     AC_CHECK_LIB(ncurses,waddch)
 148 fi
 149 if test "$ac_cv_lib_ncurses_waddch" = "yes"
 150 then
 151     AC_CHECK_LIB(ncurses,resizeterm,AC_DEFINE(HAVE_RESIZETERM))
 152     AC_CHECK_LIB(ncurses,getbkgd,AC_DEFINE(HAVE_GETBKGD))
 153 else
 154     AC_CHECK_HEADERS(curses.h)
 155     if test "$ac_cv_header_curses_h" = "yes"
 156     then
 157        AC_CHECK_LIB(curses,waddch)
 158        AC_CHECK_LIB(curses,resizeterm,AC_DEFINE(HAVE_RESIZETERM))
 159        AC_CHECK_LIB(curses,getbkgd,AC_DEFINE(HAVE_GETBKGD))
 160     fi
 161 fi
 162
 163 dnl **** Check for IPX (currently Linux only) ****
 164 AC_CACHE_CHECK("for GNU style IPX support", ac_cv_c_ipx_gnu,
 165  AC_TRY_COMPILE(
 166    [#include <sys/socket.h>
 167     #include <netipx/ipx.h>],
 168    [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 169    [AC_DEFINE(HAVE_IPX_GNU)
 170     ac_cv_c_ipx_gnu="yes"],
 171    [ac_cv_c_ipx_gnu="no"])
 172  )
 173
 174 if test "$ac_cv_c_ipx_gnu" = "no"
 175 then
 176  AC_CACHE_CHECK("for linux style IPX support", ac_cv_c_ipx_linux,
 177   AC_TRY_COMPILE(
 178     [#include <sys/socket.h>
 179      #include <asm/types.h>
 180      #include <linux/ipx.h>],
 181     [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 182     [AC_DEFINE(HAVE_IPX_LINUX)
 183      ac_cv_c_ipx_linux="yes"],
 184     [ac_cv_c_ipx_linux="no"])
 185   )
 186 fi
 187
 188 dnl **** Check for Open Sound System ****
 189 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
 190
 191 AC_CACHE_CHECK("for Open Sound System",
 192         ac_cv_c_opensoundsystem,
 193         AC_TRY_COMPILE([
 194         #if defined(HAVE_SYS_SOUNDCARD_H)
 195                 #include <sys/soundcard.h>
 196         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 197                 #include <machine/soundcard.h>
 198         #elif defined(HAVE_SOUNDCARD_H)
 199                 #include <soundcard.h>
 200         #endif
 201         ],[
 202
 203 /* check for one of the Open Sound System specific SNDCTL_ defines */
 204 #if !defined(SNDCTL_DSP_STEREO)
 205 #error No open sound system
 206 #endif
 207 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
 208
 209 if test "$ac_cv_c_opensoundsystem" = "yes"
 210 then
 211     AC_DEFINE(HAVE_OSS)
 212 fi
 213
 214 dnl **** Check for union semun ****
 215
 216 AC_CACHE_CHECK("for union semun", ac_cv_c_union_semun,
 217  AC_TRY_COMPILE([#include <sys/types.h>
 218 #include <sys/sem.h>],[union semun foo],
 219                 ac_cv_c_union_semun="yes", ac_cv_c_union_semun="no"))
 220 if test "$ac_cv_c_union_semun" = "yes"
 221 then
 222     AC_DEFINE(HAVE_UNION_SEMUN)
 223 fi
 224
 225 dnl **** If ln -s doesn't work, use cp instead ****
 226 if test "$ac_cv_prog_LN_S" = "ln -s"; then : ; else LN_S=cp ; fi
 227
 228 dnl **** Check for gcc strength-reduce bug ****
 229
 230 if test "x${GCC}" = "xyes"
 231 then
 232   CFLAGS="$CFLAGS -Wall"
 233   AC_CACHE_CHECK( "for gcc strength-reduce bug", ac_cv_c_gcc_strength_bug,
 234                   AC_TRY_RUN([
 235 int main(void) {
 236   static int Array[[3]];
 237   unsigned int B = 3;
 238   int i;
 239   for(i=0; i<B; i++) Array[[i]] = i - 3;
 240   exit( Array[[1]] != -2 );
 241 }],
 242     ac_cv_c_gcc_strength_bug="no",
 243     ac_cv_c_gcc_strength_bug="yes",
 244     ac_cv_c_gcc_strength_bug="yes") )
 245   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 246   then
 247     CFLAGS="$CFLAGS -fno-strength-reduce"
 248   fi
 249 fi
 250
 251 dnl **** Check for underscore on external symbols ****
 252
 253 AC_CACHE_CHECK("whether external symbols need an underscore prefix",
 254                ac_cv_c_extern_prefix,
 255 [saved_libs=$LIBS
 256 LIBS="conftest_asm.s $LIBS"
 257 cat > conftest_asm.s <<EOF
 258         .globl _ac_test
 259 _ac_test:
 260         .long 0
 261 EOF
 262 AC_TRY_LINK([extern int ac_test;],[if (ac_test) return 1],
 263             ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no")
 264 LIBS=$saved_libs])
 265 if test "$ac_cv_c_extern_prefix" = "yes"
 266 then
 267   AC_DEFINE(NEED_UNDERSCORE_PREFIX)
 268 fi
 269
 270 dnl **** Check for .string in assembler ****
 271
 272 AC_CACHE_CHECK("whether assembler accepts .string",
 273                ac_cv_c_asm_string,
 274 [saved_libs=$LIBS
 275 LIBS="conftest_asm.s $LIBS"
 276 cat > conftest_asm.s <<EOF
 277         .string "test"
 278 EOF
 279 AC_TRY_LINK(,,ac_cv_c_asm_string="yes",ac_cv_c_asm_string="no")
 280 LIBS=$saved_libs])
 281 if test "$ac_cv_c_asm_string" = "yes"
 282 then
 283   AC_DEFINE(HAVE_ASM_STRING)
 284 fi
 285
 286 dnl **** Check for working dll ****
 287
 288 DLLFLAGS=""
 289 LDSHARED=""
 290 if test "$LIB_TARGET" = "libwine.so.1.0"
 291 then
 292   AC_CACHE_CHECK("whether we can build a Linux dll",
 293                  ac_cv_c_dll_linux,
 294   [saved_cflags=$CFLAGS
 295   CFLAGS="$CFLAGS -fPIC -shared -Wl,-soname,conftest.so.1.0"
 296   AC_TRY_LINK(,[return 1],ac_cv_c_dll_linux="yes",ac_cv_c_dll_linux="no")
 297   CFLAGS=$saved_cflags
 298   ])
 299   if test "$ac_cv_c_dll_linux" = "yes"
 300   then
 301     DLLFLAGS="-fPIC"
 302     LDSHARED="\$(CC) -shared -Wl,-soname,libwine.so"
 303   else
 304     AC_CACHE_CHECK("whether we can build a NetBSD dll",
 305                    ac_cv_c_dll_netbsd,
 306     [saved_cflags=$CFLAGS
 307     CFLAGS="$CFLAGS -fPIC -Bshareable -Bforcearchive"
 308     AC_TRY_LINK(,[return 1],ac_cv_c_dll_netbsd="yes",ac_cv_c_dll_netbsd="no")
 309     CFLAGS=$saved_cflags
 310     ])
 311     if test "$ac_cv_c_dll_netbsd" = "yes"
 312     then
 313       DLLFLAGS="-fPIC"
 314       LDSHARED="ld -Bshareable -Bforcearchive"
 315     fi
 316   fi
 317   if test "$ac_cv_c_dll_linux" = "no" -a "$ac_cv_c_dll_netbsd" = "no"
 318   then
 319     LIB_TARGET="libwine.a"
 320   fi
 321 fi
 322 AC_SUBST(DLLFLAGS)
 323 AC_SUBST(LDSHARED)
 324
 325 dnl **** Check for reentrant libc ****
 326 dnl
 327 dnl For cross-compiling we blindly assume that libc is reentrant. This is
 328 dnl ok since non-reentrant libc is quite rare (mostly old libc5 versions).
 329
 330 AC_CACHE_CHECK("for reentrant libc", wine_cv_libc_reentrant,
 331   [AC_TRY_RUN([int myerrno = 0;
 332 char buf[256];
 333 int *__errno_location(){return &myerrno;}
 334 main(){connect(0,buf,255); exit(!myerrno);}],
 335   wine_cv_libc_reentrant=yes, wine_cv_libc_reentrant=no,
 336   wine_cv_libc_reentrant=yes ) ] )
 337 if test "$wine_cv_libc_reentrant" = "no"
 338 then
 339   AC_DEFINE(NO_REENTRANT_LIBC)
 340 fi
 341
 342 dnl **** Check for reentrant X libraries ****
 343 dnl
 344 dnl This may fail to determine whether X libraries are reentrant if
 345 dnl AC_PATH_XTRA does not set x_libraries. In this case manual configuration
 346 dnl is possible with the --without-reentrant-x option.
 347
 348 if test "$have_x" = "yes"
 349 then
 350 AC_CACHE_CHECK( "for reentrant X libraries", wine_cv_x_reentrant,
 351   [ if test "x$with_reentrant_x" = "xno"
 352     then
 353         wine_cv_x_reentrant=no
 354     else
 355         libX11_ckeck=none
 356         for dir in "$x_libraries" /usr/lib /usr/local/lib /lib; do
 357             if test -r $dir/libX11.so; then
 358                 libX11_check="-D $dir/libX11.so"
 359                 break 1
 360             fi
 361             if test -r $dir/libX11.a; then
 362                 libX11_check="$dir/libX11.a"
 363                 break 1
 364             fi
 365         done
 366         if test "$libX11_check" != "none"; then
 367             if nm $libX11_check | grep __errno_location >/dev/null 2>&1
 368             then
 369                 wine_cv_x_reentrant=yes
 370             else
 371                 wine_cv_x_reentrant=no
 372             fi
 373         else
 374             wine_cv_x_reentrant=unknown
 375         fi
 376     fi ] )
 377 else
 378     wine_cv_x_reentrant=no
 379 fi
 380 if test "$wine_cv_x_reentrant" = "no"
 381 then
 382   AC_DEFINE(NO_REENTRANT_X11)
 383 fi
 384
 385 dnl **** Check for functions and header files ****
 386
 387 AC_CHECK_FUNCS(clone getpagesize memmove sendmsg sigaltstack strerror stricmp tcgetattr timegm usleep wait4 waitpid vfscanf)
 388 AC_CHECK_HEADERS(wctype.h sys/syscall.h syscall.h sys/param.h sys/vfs.h sys/mount.h sys/statfs.h float.h linux/cdrom.h linux/ucdrom.h sys/cdio.h sys/filio.h sys/modem.h strings.h sys/strtio.h dlfcn.h unistd.h sys/sockio.h net/if.h netinet/in.h sys/file.h libio.h curses.h ncurses.h elf.h resolv.h)
 389 AC_HEADER_STAT()
 390 AC_C_CONST()
 391 AC_TYPE_SIZE_T()
 392 AC_CHECK_SIZEOF(long long,0)
 393
 394 dnl **** Check for sendmsg in -lsocket if not found above ****
 395
 396 if test $ac_cv_func_sendmsg = no; then
 397     AC_CHECK_LIB(socket,sendmsg)
 398 fi
 399
 400 dnl **** statfs checks ****
 401
 402 if test "$ac_cv_header_sys_vfs_h" = "yes"
 403 then
 404     AC_CACHE_CHECK( "whether sys/vfs.h defines statfs",
 405                     wine_cv_sys_vfs_has_statfs,
 406         AC_TRY_COMPILE([
 407         #include <sys/types.h>
 408         #ifdef HAVE_SYS_PARAM_H
 409         # include <sys/param.h>
 410         #endif
 411         #include <sys/vfs.h>
 412         ],[
 413                 struct statfs stfs;
 414
 415                 memset(&stfs,0,sizeof(stfs));
 416         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
 417         )
 418     )
 419     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
 420     then
 421       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS)
 422     fi
 423 fi
 424
 425 if test "$ac_cv_header_sys_statfs_h" = "yes"
 426 then
 427     AC_CACHE_CHECK( "whether sys/statfs.h defines statfs",
 428                     wine_cv_sys_statfs_has_statfs,
 429         AC_TRY_COMPILE([
 430         #include <sys/types.h>
 431         #ifdef HAVE_SYS_PARAM_H
 432         # include <sys/param.h>
 433         #endif
 434         #include <sys/statfs.h>
 435         ],[
 436                 struct statfs stfs;
 437         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
 438         )
 439     )
 440     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
 441     then
 442       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS)
 443     fi
 444 fi
 445
 446 if test "$ac_cv_header_sys_mount_h" = "yes"
 447 then
 448     AC_CACHE_CHECK( "whether sys/mount.h defines statfs",
 449                     wine_cv_sys_mount_has_statfs,
 450         AC_TRY_COMPILE([
 451         #include <sys/types.h>
 452         #ifdef HAVE_SYS_PARAM_H
 453         # include <sys/param.h>
 454         #endif
 455         #include <sys/mount.h>
 456         ],[
 457                 struct statfs stfs;
 458         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
 459         )
 460     )
 461     if test "$wine_cv_sys_mount_has_statfs" = "yes"
 462     then
 463       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT)
 464     fi
 465 fi
 466
 467 dnl **** FIXME: what about mixed cases, where we need two of them? ***
 468
 469 AC_CACHE_CHECK( "for statfs.f_bfree", wine_cv_statfs_bfree,
 470   [ if test "x$statfs_bfree" = "xno"
 471     then
 472         wine_cv_statfs_bfree=no
 473     else
 474         AC_TRY_COMPILE([
 475         #include <sys/types.h>
 476         #ifdef HAVE_SYS_PARAM_H
 477         # include <sys/param.h>
 478         #endif
 479         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
 480         # include <sys/mount.h>
 481         #else
 482         # ifdef STATFS_DEFINED_BY_SYS_VFS
 483         #  include <sys/vfs.h>
 484         # else
 485         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
 486         #   include <sys/statfs.h>
 487         #  endif
 488         # endif
 489         #endif
 490         ],[
 491                 struct statfs stfs;
 492
 493                 stfs.f_bfree++;
 494         ],wine_cv_statfs_bfree=yes,wine_cv_statfs_bfree=no
 495         )
 496     fi ] )
 497 if test "$wine_cv_statfs_bfree" = "yes"
 498 then
 499   AC_DEFINE(STATFS_HAS_BFREE)
 500 fi
 501
 502 AC_CACHE_CHECK( "for statfs.f_bavail", wine_cv_statfs_bavail,
 503   [ if test "x$statfs_bavail" = "xno"
 504     then
 505         wine_cv_statfs_bavail=no
 506     else
 507         AC_TRY_COMPILE([
 508         #include <sys/types.h>
 509         #ifdef HAVE_SYS_PARAM_H
 510         # include <sys/param.h>
 511         #endif
 512         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
 513         # include <sys/mount.h>
 514         #else
 515         # ifdef STATFS_DEFINED_BY_SYS_VFS
 516         #  include <sys/vfs.h>
 517         # else
 518         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
 519         #   include <sys/statfs.h>
 520         #  endif
 521         # endif
 522         #endif
 523         ],[
 524                 struct statfs stfs;
 525
 526                 stfs.f_bavail++;
 527         ],wine_cv_statfs_bavail=yes,wine_cv_statfs_bavail=no
 528         )
 529     fi ] )
 530 if test "$wine_cv_statfs_bavail" = "yes"
 531 then
 532   AC_DEFINE(STATFS_HAS_BAVAIL)
 533 fi
 534
 535 dnl *** check for working sigaltstack
 536 dnl glibc 2.0x defines it, but it always fails... so it is useless for us.
 537
 538 AC_CACHE_CHECK("for working sigaltstack",
 539         ac_cv_c_working_sigaltstack,
 540         AC_TRY_RUN([
 541         #include <stdio.h>
 542         #include <time.h> /* <sys/time.h> ? bad magic without end */
 543         #include <sys/types.h>
 544         #include <sys/signal.h>
 545         #ifdef HAVE_SYS_PARAM_H
 546         # include <sys/param.h>
 547         #endif
 548         #ifdef HAVE_SYSCALL_H
 549         # include <syscall.h>
 550         #else
 551         # ifdef HAVE_SYS_SYSCALL_H
 552         #  include <sys/syscall.h>
 553         # endif
 554         #endif
 555
 556         unsigned char *xaltstack;
 557
 558         int
 559         main(int argc,char **argv) {
 560             struct sigaltstack  ss;
 561
 562             xaltstack = malloc(16384);
 563             ss.ss_sp    = xaltstack;
 564             ss.ss_size  = 16384;
 565             ss.ss_flags = 0;
 566             if (sigaltstack(&ss, NULL) < 0) {
 567                 /* this catches the glibc case */
 568                 perror("sigaltstack");
 569                 return (1); /* aka exit(1) aka fail */
 570             }
 571             /* assume it works. */
 572             return 0; /* OK */
 573         }
 574         ],
 575         ac_cv_c_working_sigaltstack="yes",
 576         ac_cv_c_working_sigaltstack="no",
 577         ac_cv_c_working_sigaltstack="no"
 578 ))
 579
 580 if test "$ac_cv_c_working_sigaltstack" = "yes"
 581 then
 582     AC_DEFINE(HAVE_WORKING_SIGALTSTACK)
 583 fi
 584
 585
 586 dnl *** check for file descriptor passing with msg_accrights
 587
 588 AC_CACHE_CHECK("for msg_accrights in struct msghdr", ac_cv_c_msg_accrights,
 589  AC_TRY_COMPILE([#include <sys/types.h>
 590 #include <sys/socket.h>],[struct msghdr hdr; hdr.msg_accrights=0],
 591                 ac_cv_c_msg_accrights="yes", ac_cv_c_msg_accrights="no"))
 592 if test "$ac_cv_c_msg_accrights" = "yes"
 593 then
 594     AC_DEFINE(HAVE_MSGHDR_ACCRIGHTS)
 595 fi
 596
 597 dnl **** Generate output files ****
 598
 599 MAKE_RULES=Make.rules
 600 AC_SUBST_FILE(MAKE_RULES)
 601
 602 AC_OUTPUT([
 603 Make.rules
 604 Makefile
 605 console/Makefile
 606 controls/Makefile
 607 debugger/Makefile
 608 dlls/Makefile
 609 dlls/advapi32/Makefile
 610 dlls/comctl32/Makefile
 611 dlls/imagehlp/Makefile
 612 dlls/msacm/Makefile
 613 dlls/msacm32/Makefile
 614 dlls/ntdll/Makefile
 615 dlls/psapi/Makefile
 616 dlls/rasapi32/Makefile
 617 dlls/shell32/Makefile
 618 dlls/ver/Makefile
 619 dlls/version/Makefile
 620 dlls/winaspi/Makefile
 621 dlls/wnaspi32/Makefile
 622 documentation/Makefile
 623 files/Makefile
 624 graphics/Makefile
 625 graphics/metafiledrv/Makefile
 626 graphics/psdrv/Makefile
 627 graphics/ttydrv/Makefile
 628 graphics/win16drv/Makefile
 629 graphics/x11drv/Makefile
 630 if1632/Makefile
 631 include/Makefile
 632 ipc/Makefile
 633 library/Makefile
 634 libtest/Makefile
 635 loader/Makefile
 636 loader/ne/Makefile
 637 loader/dos/Makefile
 638 memory/Makefile
 639 misc/Makefile
 640 miscemu/Makefile
 641 msdos/Makefile
 642 multimedia/Makefile
 643 objects/Makefile
 644 ole/Makefile
 645 programs/Makefile
 646 programs/clock/Makefile
 647 programs/cmdlgtst/Makefile
 648 programs/control/Makefile
 649 programs/avitools/Makefile
 650 programs/notepad/Makefile
 651 programs/progman/Makefile
 652 programs/regtest/Makefile
 653 programs/view/Makefile
 654 programs/winhelp/Makefile
 655 programs/winver/Makefile
 656 rc/Makefile
 657 relay32/Makefile
 658 resources/Makefile
 659 scheduler/Makefile
 660 server/Makefile
 661 tools/Makefile
 662 tools/wrc/Makefile
 663 tsx11/Makefile
 664 win32/Makefile
 665 windows/Makefile
 666 windows/ttydrv/Makefile
 667 windows/x11drv/Makefile ])
 668
 669 if test "$have_x" = "no"
 670 then
 671   echo
 672   echo "*** Warning: X development files not found. Wine will be built without"
 673   echo "*** X support, which currently does not work, and would probably not be"
 674   echo "*** what you want anyway. You will need to install devel packages of"
 675   echo "*** Xlib/Xfree86 and Xpm at the very least."
 676 elif test "$ac_cv_lib_Xpm_XpmCreatePixmapFromData" = "no"
 677 then
 678   echo
 679   echo "*** Warning: Xpm development files not found. Wine will be built without"
 680   echo "*** Xpm support, which currently does not work. You will need to install"
 681   echo "*** devel packages of Xpm."
 682 fi
 683
 684 if test "$ac_cv_lib_ncurses_resizeterm" = "no" -a "$ac_cv_lib_ncurses_waddch" = "yes"
 685 then
 686   echo
 687   echo "*** Warning: resizeterm not found in ncurses. Wine will be built without"
 688   echo "*** terminal resize support. Consider upgrading ncurses."
 689 fi
 690
 691 if test "$wine_cv_libc_reentrant" = "no"
 692 then
 693   echo
 694   echo "*** Warning: non-reentrant libc detected. Wine will be build without"
 695   echo "*** thread support. Consider upgrading libc to a more recent"
 696   echo "*** reentrant version of libc."
 697 fi
 698
 699 echo
 700 echo "Configure finished.  Do 'make depend && make' to compile Wine."
 701 echo
 702
 703 dnl Local Variables:
 704 dnl comment-start: "dnl "
 705 dnl comment-end: ""
 706 dnl comment-start-skip: "\\bdnl\\b\\s *"
 707 dnl compile-command: "autoconf"
 708 dnl End: