git.oblomov.eu Git - wine/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 AC_PREREQ(2.53)
   8 AC_INIT([Wine],WINE_VERSION,[wine-devel@winehq.org])
   9 AC_CONFIG_SRCDIR(server/atom.c)
  10 AC_CONFIG_HEADERS(include/config.h)
  11 AC_CONFIG_AUX_DIR(tools)
  12
  13 dnl **** Command-line arguments ****
  14
  15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
  16 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
  17 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
  18 AC_ARG_ENABLE(win64, AC_HELP_STRING([--enable-win64], [build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
  19
  20 AC_ARG_WITH(opengl,    AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
  21 AC_ARG_WITH(curses,    AC_HELP_STRING([--without-curses],[do not use curses]))
  22 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
  23
  24 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
  25 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
  26 if test "x$enable_win16" = "xno"
  27 then
  28   WIN16_FILES=""
  29   WIN16_INSTALL=""
  30 fi
  31
  32 AC_SUBST(DLLDEFS,"")
  33 if test "x$enable_debug" = "xno"
  34 then
  35   DLLDEFS="$DLLDEFS -DWINE_NO_DEBUG_MSGS"
  36 fi
  37 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
  38 then
  39   DLLDEFS="$DLLDEFS -DWINE_NO_TRACE_MSGS"
  40 fi
  41
  42 dnl **** Check for some programs ****
  43
  44 AC_CANONICAL_HOST
  45 case $host in
  46   x86_64*linux*)
  47     if test "x$enable_win64" != "xyes"
  48     then
  49       test -n "$CC" || CC="gcc -m32"
  50       test -n "$LD" || LD="ld -m elf_i386"
  51       test -n "$AS" || AS="as --32"
  52       host_cpu="i386"
  53     fi
  54     ;;
  55 esac
  56
  57 AC_PROG_MAKE_SET
  58 AC_PROG_CC
  59 AC_PROG_CXX
  60 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
  61 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
  62
  63 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
  64   [if test -z "$with_wine_tools"; then
  65      if test "$cross_compiling" = "yes"; then
  66        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
  67      else
  68        wine_cv_toolsdir="\$(TOPOBJDIR)"
  69      fi
  70    elif test -d "$with_wine_tools/tools/winebuild"; then
  71      case $with_wine_tools in
  72        /*) wine_cv_toolsdir="$with_wine_tools" ;;
  73        *)  wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
  74      esac
  75    else
  76      AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
  77    fi])
  78 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
  79
  80 AC_PATH_XTRA
  81 AC_PROG_LEX
  82
  83 dnl **** Just additional warning checks, since AC_PROG just sets 'lex' even
  84 dnl **** without one present.
  85 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
  86 if test "$XLEX" = "none"
  87 then
  88   AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
  89 fi
  90
  91 dnl Check for bison
  92 AC_CHECK_PROGS(BISON,bison,none)
  93 if test "$BISON" = "none"
  94 then
  95   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
  96 fi
  97
  98 AC_CHECK_TOOLS(AS,[gas as],as)
  99 AC_CHECK_TOOL(LD,ld,ld)
 100 AC_CHECK_TOOL(AR,ar,ar)
 101 AC_PROG_RANLIB
 102 AC_CHECK_TOOL(STRIP,strip,strip)
 103 AC_CHECK_TOOL(WINDRES,windres,false)
 104 AC_PROG_LN_S
 105 WINE_PROG_LN
 106 AC_PROG_EGREP
 107 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
 108 AC_PROG_INSTALL
 109 dnl Prepend src dir to install path dir if it's a relative path
 110 case "$INSTALL" in
 111   [[\\/$]]* | ?:[[\\/]]* ) ;;
 112   *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
 113 esac
 114
 115 dnl Check for lint
 116 AC_CHECK_PROGS(LINT, lclint lint)
 117 if test "$LINT" = "lint"
 118 then
 119   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 120   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 121 fi
 122 AC_SUBST(LINT)
 123 AC_SUBST(LINTFLAGS)
 124
 125 dnl Check for various programs
 126 AC_CHECK_PROGS(DB2HTML, docbook2html db2html, false)
 127 AC_CHECK_PROGS(DB2PDF, docbook2pdf db2pdf, false)
 128 AC_CHECK_PROGS(DB2PS, docbook2ps db2ps, false)
 129 AC_CHECK_PROGS(DB2TXT, docbook2txt db2txt, false)
 130 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
 131
 132 dnl **** Check for some libraries ****
 133
 134 dnl Check for -li386 for NetBSD and OpenBSD
 135 AC_CHECK_LIB(i386,i386_set_ldt)
 136 dnl Check for -lossaudio for NetBSD
 137 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 138 dnl Check for -lw for Solaris
 139 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
 140 dnl Check for -lnsl for Solaris
 141 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
 142 dnl Check for -lsocket for Solaris
 143 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
 144 dnl Check for -lresolv for Solaris
 145 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
 146 dnl Check for -lxpg4 for FreeBSD
 147 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
 148 dnl Check for -lpoll for Mac OS X/Darwin
 149 AC_CHECK_LIB(poll,poll)
 150 dnl Check for -lresolv for Mac OS X/Darwin
 151 AC_CHECK_LIB(resolv,res_9_init)
 152 dnl Check for -lpthread
 153 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
 154
 155 AC_SUBST(XLIB)
 156 AC_SUBST(XFILES)
 157 XFILES=""
 158 AC_SUBST(OPENGLFILES)
 159 OPENGLFILES=""
 160 AC_SUBST(GLU32FILES)
 161 GLU32FILES=""
 162 AC_SUBST(OPENGL_LIBS)
 163 OPENGL_LIBS=""
 164
 165 dnl **** Check for header files ****
 166
 167 AC_CHECK_HEADERS(\
 168         arpa/inet.h \
 169         arpa/nameser.h \
 170         cups/cups.h \
 171         direct.h \
 172         elf.h \
 173         float.h \
 174         fontconfig/fontconfig.h \
 175         getopt.h \
 176         gif_lib.h \
 177         ieeefp.h \
 178         io.h \
 179         jack/jack.h \
 180         jpeglib.h \
 181         lcms/lcms.h \
 182         lcms.h \
 183         link.h \
 184         linux/cdrom.h \
 185         linux/compiler.h \
 186         linux/hdreg.h \
 187         linux/input.h \
 188         linux/ioctl.h \
 189         linux/joystick.h \
 190         linux/major.h \
 191         linux/param.h \
 192         linux/serial.h \
 193         linux/ucdrom.h \
 194         machine/cpu.h \
 195         mntent.h \
 196         netdb.h \
 197         netinet/in.h \
 198         netinet/in_systm.h \
 199         netinet/tcp.h \
 200         netinet/tcp_fsm.h \
 201         openssl/ssl.h \
 202         poll.h \
 203         process.h \
 204         pthread.h \
 205         pwd.h \
 206         regex.h \
 207         sched.h \
 208         scsi/sg.h \
 209         scsi/scsi.h \
 210         scsi/scsi_ioctl.h \
 211         stdint.h \
 212         strings.h \
 213         sys/cdio.h \
 214         sys/elf32.h \
 215         sys/errno.h \
 216         sys/epoll.h \
 217         sys/exec_elf.h \
 218         sys/filio.h \
 219         sys/ioctl.h \
 220         sys/ipc.h \
 221         sys/link.h \
 222         sys/lwp.h \
 223         sys/mman.h \
 224         sys/modem.h \
 225         sys/msg.h \
 226         sys/param.h \
 227         sys/poll.h \
 228         sys/ptrace.h \
 229         sys/reg.h \
 230         sys/scsiio.h \
 231         sys/shm.h \
 232         sys/signal.h \
 233         sys/socket.h \
 234         sys/sockio.h \
 235         sys/statfs.h \
 236         sys/statvfs.h \
 237         sys/strtio.h \
 238         sys/syscall.h \
 239         sys/sysctl.h \
 240         sys/time.h \
 241         sys/times.h \
 242         sys/uio.h \
 243         sys/un.h \
 244         sys/vfs.h \
 245         sys/vm86.h \
 246         sys/wait.h \
 247         syscall.h \
 248         termios.h \
 249         unistd.h \
 250         utime.h \
 251         valgrind/memcheck.h
 252 )
 253 AC_HEADER_STAT()
 254
 255 dnl **** Check for X11 ****
 256
 257 if test "$have_x" = "yes"
 258 then
 259     XLIB="-lXext -lX11"
 260     ac_save_CPPFLAGS="$CPPFLAGS"
 261     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 262
 263     dnl *** All of the following tests require X11/Xlib.h
 264     AC_CHECK_HEADERS(X11/Xlib.h,
 265       [
 266         AC_CHECK_HEADERS([X11/XKBlib.h \
 267                           X11/Xutil.h \
 268                           X11/extensions/shape.h \
 269                           X11/extensions/XInput.h \
 270                           X11/extensions/XShm.h \
 271                           X11/extensions/Xrandr.h \
 272                           X11/extensions/Xrender.h \
 273                           X11/extensions/xf86dga.h \
 274                           X11/extensions/xf86vmode.h],,,
 275                          [#include <X11/Xlib.h>
 276                           #ifdef HAVE_X11_XUTIL_H
 277                           # include <X11/Xutil.h>
 278                           #endif])
 279
 280         dnl *** Check for X keyboard extension
 281         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 282         then
 283               AC_CHECK_LIB(X11, XkbQueryExtension,
 284               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 285               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 286         fi
 287
 288         dnl *** Check for X Shm extension
 289         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 290         then
 291               AC_CHECK_LIB(Xext, XShmQueryExtension,
 292               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 293               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 294         fi
 295
 296         dnl *** Check for X shape extension
 297         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 298         then
 299               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 300               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 301               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 302         fi
 303
 304         dnl *** Check for XFree86 DGA / DGA 2.0 extension
 305         if test "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
 306         then
 307               AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
 308                 [ AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
 309                             [Define if you have the Xxf86dga library version 2])
 310                   X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 311                 ],,
 312                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 313         fi
 314
 315         dnl *** Check for XFree86 VMODE extension
 316         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 317         then
 318                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 319                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 320                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 321                   ],,
 322                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 323         fi
 324
 325         dnl *** Check for X RandR extension
 326         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
 327         then
 328                 AC_TRY_COMPILE([#include <X11/Xlib.h>
 329 #include <X11/extensions/Xrandr.h>],[static typeof(XRRSetScreenConfigAndRate) * func;],
 330                   [AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])])
 331         fi
 332
 333         dnl *** Check for Transform functions in Xrender
 334         if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes"
 335         then
 336               AC_CHECK_LIB(Xrender, XRenderSetPictureTransform,
 337                 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
 338                  [Define if Xrender has the XRenderSetPictureTransform function])],,
 339                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 340         fi
 341       ]
 342     ) dnl *** End of X11/Xlib.h check
 343
 344     dnl Check for the presence of OpenGL
 345     if test "x$with_opengl" != "xno"
 346     then
 347         if test -f /usr/X11R6/lib/libGL.a -a ! -f /usr/X11R6/lib/libGL.so
 348         then
 349             AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
 350 This prevents linking to OpenGL. Delete the file and restart configure.])
 351         fi
 352
 353         AC_CHECK_HEADERS(GL/gl.h GL/glx.h)
 354         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 355         then
 356             AC_CHECK_HEADERS(GL/glext.h,,,[#include <GL/glx.h>])
 357             dnl Check for some problems due to old Mesa versions
 358             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
 359               AC_TRY_COMPILE(
 360                 [#include <GL/gl.h>],
 361                 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 362                 [wine_cv_opengl_version_OK="yes"],
 363                 [wine_cv_opengl_version_OK="no"]
 364               )
 365             )
 366
 367             if test "$wine_cv_opengl_version_OK" = "yes"
 368             then
 369                 dnl Check for the presence of the library
 370                 AC_CHECK_LIB(GL,glXCreateContext,
 371                              OPENGL_LIBS="-lGL"
 372                              ,,
 373                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 374
 375                 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
 376                 then
 377                         OPENGLFILES='$(OPENGLFILES)'
 378                         AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
 379                 fi
 380                 dnl Check for GLU32 library.
 381                 AC_CHECK_LIB(GLU,gluLookAt,
 382                              [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
 383                              GLU32FILES='$(GLU32FILES)']
 384                              ,,
 385                              $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
 386                 )
 387              fi
 388
 389              dnl Check for glut32 library.
 390              AC_CHECK_LIB(glut,glutMainLoop,
 391                        [AC_SUBST(GLUT_LIBS,"-lglut -lXmu -lXi")
 392                         AC_SUBST(GLUT32FILES,'$(GLUT32FILES)')],,
 393                         $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXmu -lXi -lX11 $X_EXTRA_LIBS)
 394          fi
 395     fi
 396
 397     dnl **** Check for NAS ****
 398     AC_SUBST(NASLIBS,"")
 399     AC_CHECK_HEADERS(audio/audiolib.h,
 400          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
 401           AC_CHECK_LIB(audio,AuCreateFlow,
 402                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
 403                         NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
 404                        [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 405
 406     CPPFLAGS="$ac_save_CPPFLAGS"
 407     XFILES='$(XFILES)'
 408 else
 409     XLIB=""
 410     X_CFLAGS=""
 411     X_LIBS=""
 412 fi
 413
 414 dnl **** Check which curses lib to use ***
 415 CURSESLIBS=""
 416 if test "x$with_curses" != "xno"
 417 then
 418     AC_CHECK_HEADERS(ncurses.h,
 419         [AC_CHECK_LIB(ncurses,waddch,
 420             [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
 421              CURSESLIBS="-lncurses"],
 422              [AC_CHECK_HEADERS(curses.h,
 423                  [AC_CHECK_LIB(curses,waddch,
 424                      [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
 425                       CURSESLIBS="-lcurses"])])])])
 426 fi
 427 AC_SUBST(CURSESLIBS)
 428
 429 dnl **** Check for SANE ****
 430 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
 431 if test "$sane_devel" = "no"
 432 then
 433     SANELIBS=""
 434     SANEINCL=""
 435 else
 436     SANELIBS="`$sane_devel --libs`"
 437     SANEINCL="`$sane_devel --cflags`"
 438     ac_save_CPPFLAGS="$CPPFLAGS"
 439     ac_save_LIBS="$LIBS"
 440     CPPFLAGS="$CPPFLAGS $SANEINCL"
 441     LIBS="$LIBS $SANELIBS"
 442     AC_CHECK_HEADER(sane/sane.h,
 443                     [AC_CHECK_LIB(sane,sane_open,
 444                                   [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
 445                                   [SANELIBS=""
 446                                   SANEINCL=""])],
 447                     [SANELIBS=""
 448                     SANEINCL=""])
 449     LIBS="$ac_save_LIBS"
 450     CPPFLAGS="$ac_save_CPPFLAGS"
 451 fi
 452 AC_SUBST(SANELIBS)
 453 AC_SUBST(SANEINCL)
 454
 455 dnl **** Check for the ICU library ****
 456 AC_CHECK_HEADERS(unicode/ubidi.h)
 457 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
 458 then
 459     saved_libs="$LIBS"
 460     ICU_LIB_DIR="${ICU_LIB_DIR-/usr/lib}"
 461     ICUUC_LIB="${ICUUC_LIB-$ICU_LIB_DIR/libsicuuc.a}"
 462     ICUDATA_LIB="${ICUDATA_LIB-$ICU_LIB_DIR/libsicudata.a}"
 463     AC_MSG_CHECKING(whether can link with ICU libraries $ICUUC_LIB and $ICUDATA_LIB)
 464     LIBS="$LIBS $ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s"
 465     AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
 466                 [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
 467                  AC_SUBST(ICULIBS,"$ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s")
 468                  AC_MSG_RESULT(yes)],
 469                 [AC_MSG_RESULT(no)])
 470     LIBS="$saved_libs"
 471 fi
 472
 473 dnl **** Check for FreeType 2 ****
 474 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
 475 if test "$ft_lib" = "no"
 476 then
 477     FREETYPELIBS=""
 478     FREETYPEINCL=""
 479     wine_cv_msg_freetype=no
 480 else
 481     AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
 482     if test "$ft_devel" = "no"
 483     then
 484         AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
 485         if test "$ft_devel2" = "freetype2-config"
 486         then
 487                 ft_devel=$ft_devel2
 488         fi
 489     fi
 490     if test "$ft_devel" = "no"
 491     then
 492         FREETYPELIBS=""
 493         FREETYPEINCL=""
 494         wine_cv_msg_freetype=yes
 495     else
 496         FREETYPELIBS=`$ft_devel --libs`
 497         FREETYPEINCL=`$ft_devel --cflags`
 498         ac_save_CPPFLAGS="$CPPFLAGS"
 499         CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
 500         AC_CHECK_HEADERS(ft2build.h \
 501                          freetype/freetype.h \
 502                          freetype/ftglyph.h \
 503                          freetype/tttables.h \
 504                          freetype/ftnames.h \
 505                          freetype/ftsnames.h \
 506                          freetype/ttnameid.h \
 507                          freetype/ftoutln.h \
 508                          freetype/ftwinfnt.h \
 509                          freetype/internal/sfnt.h,,,
 510                          [#if HAVE_FT2BUILD_H
 511                           #include <ft2build.h>
 512                           #endif])
 513         AC_TRY_CPP([#include <ft2build.h>
 514                     #include <freetype/fttrigon.h>],
 515                     [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
 516           [Define if you have the <freetype/fttrigon.h> header file.])
 517                     wine_cv_fttrigon=yes],
 518                     wine_cv_fttrigon=no)
 519         CPPFLAGS="$ac_save_CPPFLAGS"
 520         dnl Check that we have at least freetype/freetype.h
 521         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
 522         then
 523             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
 524             wine_cv_msg_freetype=no
 525         else
 526             FREETYPELIBS=""
 527             FREETYPEINCL=""
 528             wine_cv_msg_freetype=yes
 529         fi
 530     fi
 531 fi
 532 AC_SUBST(FREETYPELIBS)
 533 AC_SUBST(FREETYPEINCL)
 534
 535 dnl Only build the fonts dir if we have both freetype and fontforge
 536 if test "$FONTFORGE" != "false" -a -n "$FREETYPELIBS"
 537 then
 538   AC_SUBST(FONTSSUBDIRS,"fonts")
 539 fi
 540
 541 dnl **** Check for parport (currently Linux only) ****
 542 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
 543  AC_TRY_COMPILE(
 544    [#include <linux/ppdev.h>],
 545    [ioctl (1,PPCLAIM,0)],
 546    [ac_cv_c_ppdev="yes"],
 547    [ac_cv_c_ppdev="no"])
 548  )
 549 if test "$ac_cv_c_ppdev" = "yes"
 550 then
 551     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
 552 fi
 553
 554 dnl **** Check for va_copy ****
 555 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
 556  AC_TRY_LINK(
 557    [#include <stdarg.h>],
 558    [va_list ap1, ap2;
 559     va_copy(ap1,ap2);
 560    ],
 561    [ac_cv_c_va_copy="yes"],
 562    [ac_cv_c_va_copy="no"])
 563  )
 564 if test "$ac_cv_c_va_copy" = "yes"
 565 then
 566     AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
 567 fi
 568 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
 569  AC_TRY_LINK(
 570    [#include <stdarg.h>],
 571    [va_list ap1, ap2;
 572     __va_copy(ap1,ap2);
 573    ],
 574    [ac_cv_c___va_copy="yes"],
 575    [ac_cv_c___va_copy="no"])
 576  )
 577 if test "$ac_cv_c___va_copy" = "yes"
 578 then
 579     AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
 580 fi
 581
 582 dnl **** Check for sigsetjmp ****
 583 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
 584  AC_TRY_LINK(
 585    [#include <setjmp.h>],
 586    [sigjmp_buf buf;
 587     sigsetjmp( buf, 1 );
 588     siglongjmp( buf, 1 );],
 589    [ac_cv_c_sigsetjmp="yes"],
 590    [ac_cv_c_sigsetjmp="no"])
 591  )
 592 if test "$ac_cv_c_sigsetjmp" = "yes"
 593 then
 594     AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
 595 fi
 596
 597 dnl **** Check for pthread_rwlock_t ****
 598 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
 599 #include <pthread.h>])
 600
 601 dnl **** Check for pthread functions ****
 602 ac_save_LIBS="$LIBS"
 603 LIBS="$LIBS $LIBPTHREAD"
 604 AC_CHECK_FUNCS(\
 605         pthread_getattr_np \
 606         pthread_get_stackaddr_np \
 607         pthread_get_stacksize_np \
 608 )
 609 LIBS="$ac_save_LIBS"
 610
 611 dnl **** Check for Open Sound System ****
 612 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
 613
 614 AC_CACHE_CHECK([for Open Sound System],
 615         ac_cv_c_opensoundsystem,
 616         AC_TRY_COMPILE([
 617         #if defined(HAVE_SYS_SOUNDCARD_H)
 618                 #include <sys/soundcard.h>
 619         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 620                 #include <machine/soundcard.h>
 621         #elif defined(HAVE_SOUNDCARD_H)
 622                 #include <soundcard.h>
 623         #endif
 624         ],[
 625
 626 /* check for one of the Open Sound System specific SNDCTL_ defines */
 627 #if !defined(SNDCTL_DSP_STEREO)
 628 #error No open sound system
 629 #endif
 630 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
 631
 632 if test "$ac_cv_c_opensoundsystem" = "yes"
 633 then
 634     AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
 635 fi
 636
 637 AC_CACHE_CHECK([for Open Sound System/MIDI interface],
 638         ac_cv_c_opensoundsystem_midi,
 639         AC_TRY_COMPILE([
 640         #if defined(HAVE_SYS_SOUNDCARD_H)
 641                 #include <sys/soundcard.h>
 642         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 643                 #include <machine/soundcard.h>
 644         #elif defined(HAVE_SOUNDCARD_H)
 645                 #include <soundcard.h>
 646         #endif
 647         ],[
 648
 649 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
 650 #if !defined(SNDCTL_SEQ_SYNC)
 651 #error No open sound system MIDI interface
 652 #endif
 653 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
 654
 655 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
 656 then
 657     AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
 658 fi
 659
 660 dnl **** Check for aRts Sound Server ****
 661 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
 662 if test x$ARTSCCONFIG != x -a x$ARTSCCONFIG != x'"$ARTSCCONFIG"';
 663 then
 664     ARTSC_CFLAGS=""
 665     for i in `$ARTSCCONFIG --cflags`
 666     do
 667       case "$i" in
 668         -I*) ARTSC_CFLAGS="$ARTSC_CFLAGS $i";;
 669       esac
 670     done
 671     ARTSC_LIBS=`$ARTSCCONFIG --libs`
 672     save_CFLAGS="$CFLAGS"
 673     CFLAGS="$CFLAGS $ARTSC_CFLAGS"
 674     AC_TRY_COMPILE([#include <artsc.h>],[arts_stream_t stream;],
 675         [AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
 676          AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
 677          AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])])
 678     CFLAGS="$save_CFLAGS"
 679 fi
 680
 681 dnl **** Check for ALSA 1.x ****
 682 AC_SUBST(ALSALIBS,"")
 683 AC_CHECK_HEADERS(alsa/asoundlib.h sys/asoundlib.h, break)
 684 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
 685 then
 686     AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
 687         [AC_TRY_COMPILE([#ifdef HAVE_ALSA_ASOUNDLIB_H
 688 #include <alsa/asoundlib.h>
 689 #elif defined(HAVE_SYS_ASOUNDLIB_H)
 690 #include <sys/asoundlib.h>
 691 #endif],
 692                         [int ret = snd_pcm_hw_params_get_access(NULL, NULL)],
 693                         [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
 694                          ALSALIBS="-lasound"])])
 695 fi
 696
 697 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
 698
 699 AC_SUBST(AUDIOIOLIBS,"")
 700 AC_CHECK_HEADERS(libaudioio.h,
 701     [AC_CHECK_LIB(audioio,AudioIOGetVersion,
 702                   [AUDIOIOLIBS="-laudioio"
 703                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])])
 704
 705 dnl **** Check for capi4linux ****
 706
 707 AC_CHECK_HEADERS(capi20.h,[
 708         AC_CHECK_HEADERS(linux/capi.h,[
 709                 AC_CHECK_LIB(capi20,capi20_register,[
 710                         AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])
 711                 ])
 712         ])
 713 ])
 714
 715 dnl **** Check for broken glibc mmap64 ****
 716
 717 AC_CACHE_CHECK( [whether mmap64 works defined as mmap], ac_cv_mmap64_works,
 718         AC_TRY_RUN([
 719                 #define _FILE_OFFSET_BITS 64
 720                 #include <stdio.h>
 721                 #include <unistd.h>
 722                 #include <fcntl.h>
 723                 #include <sys/mman.h>
 724                 #include <errno.h>
 725
 726                 int main(int argc,char **argv) {
 727                         int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
 728                         if (fd == -1) exit(1);
 729
 730                         unlink("conftest.map");
 731
 732                         write(fd,"test",4);
 733
 734                         if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
 735                             (errno == EINVAL)
 736                         ) {
 737                                 exit(1);
 738                         }
 739                         close(fd);
 740                         fprintf(stderr,"success!\n");
 741                         exit(0);
 742                 }
 743
 744         ],
 745     ac_cv_mmap64_works="yes",
 746     ac_cv_mmap64_works="no",
 747     ac_cv_mmap64_works="no") )
 748
 749 if test "$ac_cv_mmap64_works" = "yes"
 750 then
 751     AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
 752 fi
 753
 754 dnl **** Check for gcc specific options ****
 755
 756 AC_SUBST(EXTRACFLAGS,"")
 757 if test "x${GCC}" = "xyes"
 758 then
 759   EXTRACFLAGS="-Wall -pipe"
 760
 761   dnl Check for strength-reduce bug
 762   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
 763                   AC_TRY_RUN([
 764 int     L[[4]] = {0,1,2,3};
 765 int main(void) {
 766   static int Array[[3]];
 767   unsigned int B = 3;
 768   int i;
 769   for(i=0; i<B; i++) Array[[i]] = i - 3;
 770   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
 771   L[[i]] = 4;
 772
 773   exit( Array[[1]] != -2 || L[[2]] != 3);
 774 }],
 775     ac_cv_c_gcc_strength_bug="no",
 776     ac_cv_c_gcc_strength_bug="yes",
 777     ac_cv_c_gcc_strength_bug="yes") )
 778   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 779   then
 780     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
 781   fi
 782
 783   dnl Check for -fshort-wchar
 784   AC_CACHE_CHECK([for gcc -fshort-wchar support], ac_cv_c_gcc_fshort_wchar,
 785       [WINE_TRY_CFLAGS([-fshort-wchar],
 786                       ac_cv_c_gcc_fshort_wchar="yes",ac_cv_c_gcc_fshort_wchar="no")])
 787   if test "$ac_cv_c_gcc_fshort_wchar" = "yes"
 788   then
 789       AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar", [Specifies the compiler flag that forces a short wchar_t])
 790   fi
 791
 792   dnl Check for -mpreferred-stack-boundary
 793   AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support], ac_cv_c_gcc_stack_boundary,
 794       [WINE_TRY_CFLAGS([-mpreferred-stack-boundary=2],
 795                       ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")])
 796   if test "$ac_cv_c_gcc_stack_boundary" = "yes"
 797   then
 798     EXTRACFLAGS="$EXTRACFLAGS -mpreferred-stack-boundary=2"
 799   fi
 800
 801   dnl Check for -fno-strict-aliasing
 802   AC_CACHE_CHECK([for gcc -fno-strict-aliasing support], ac_cv_c_gcc_no_strict_aliasing,
 803       [WINE_TRY_CFLAGS([-fno-strict-aliasing],
 804                       ac_cv_c_gcc_no_strict_aliasing="yes",ac_cv_c_gcc_no_strict_aliasing="no")])
 805   if test "$ac_cv_c_gcc_no_strict_aliasing" = "yes"
 806   then
 807     EXTRACFLAGS="$EXTRACFLAGS -fno-strict-aliasing"
 808   fi
 809
 810   dnl Check for -gstabs+ option
 811   AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
 812       [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
 813   if test "$ac_cv_c_gcc_gstabs" = "yes"
 814   then
 815     EXTRACFLAGS="$EXTRACFLAGS -gstabs+"
 816   fi
 817
 818   dnl Check for noisy string.h
 819   saved_CFLAGS="$CFLAGS"
 820   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
 821   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
 822       AC_TRY_COMPILE([#include <string.h>],[],
 823                      [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
 824   CFLAGS="$saved_CFLAGS"
 825   if test "$ac_cv_c_string_h_warnings" = "no"
 826   then
 827     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
 828   fi
 829 fi
 830
 831 dnl **** Check how to define a function in assembly code ****
 832
 833 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
 834   WINE_TRY_ASM_LINK(
 835       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
 836       ac_cv_asm_func_def=".def",
 837     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
 838       ac_cv_asm_func_def=".type @function",
 839     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
 840       ac_cv_asm_func_def=".type 2",
 841       ac_cv_asm_func_def="unknown")])]))
 842
 843 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
 844 case "$ac_cv_asm_func_def" in
 845   ".def")
 846      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
 847   ".type @function")
 848      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
 849   ".type 2")
 850      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
 851   *)
 852      AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
 853 esac
 854
 855 dnl **** Check for underscore on external symbols ****
 856
 857 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
 858     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
 859                       [extern int ac_test;],
 860                       [if (ac_test) return 1],
 861                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
 862
 863 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
 864 if test "$ac_cv_c_extern_prefix" = "yes"
 865 then
 866   AC_DEFINE([__ASM_NAME(name)], ["_" name])
 867 else
 868   AC_DEFINE([__ASM_NAME(name)], [name])
 869 fi
 870
 871 dnl **** Check how to do strings in assembler ****
 872
 873 AC_CACHE_CHECK([for assembler keyword for ASCII strings], ac_cv_c_asm_string,
 874     WINE_TRY_ASM_LINK([".data\\n\\t.string \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".string",
 875       WINE_TRY_ASM_LINK([".data\\n\\t.asciz \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".asciz",
 876         WINE_TRY_ASM_LINK([".data\\n\\t.ascii \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".ascii",
 877           AC_MSG_ERROR([could not discover how to produce C strings with assembler.])))))
 878
 879 AC_DEFINE_UNQUOTED(__ASM_STRING, ["$ac_cv_c_asm_string"],
 880                    [Define to the assembler keyword used to specify an ASCII string])
 881
 882 dnl **** Check for .short in assembler ****
 883
 884 AC_CACHE_CHECK([for assembler keyword for word values], ac_cv_c_asm_short,
 885     WINE_TRY_ASM_LINK([".data\\n\\t.short 1\\n\\t.text"],,,ac_cv_c_asm_short=".short",
 886       WINE_TRY_ASM_LINK([".data\\n\\t.half 1\\n\\t.text"],,,ac_cv_c_asm_short=".half",
 887         AC_MSG_ERROR([could not discover how to specify word values with assembler.]))))
 888
 889 AC_DEFINE_UNQUOTED(__ASM_SHORT, ["$ac_cv_c_asm_short"],
 890                    [Define to the assembler keyword used to specify a word value])
 891
 892 dnl **** Check for .size in assembler ****
 893
 894 AC_CACHE_CHECK([for .size in assembler], ac_cv_c_asm_size,
 895     WINE_TRY_ASM_LINK([".globl _ac_test\n.size _ac_test, . - _ac_test"],,,
 896                       ac_cv_c_asm_size="yes",ac_cv_c_asm_size="no"))
 897
 898 if test "$ac_cv_c_asm_size" = "yes"
 899 then
 900   AC_DEFINE(HAVE_ASM_DOT_SIZE, 1, [Define if the assembler keyword .size is accepted])
 901 fi
 902
 903 dnl **** Check for working dll ****
 904
 905 AC_SUBST(DLLEXT,"")
 906 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 907 AC_SUBST(DLLIBS,"")
 908 AC_SUBST(LDSHARED,"")
 909 AC_SUBST(LDDLLFLAGS,"")
 910 AC_SUBST(LIBEXT,"so")
 911 AC_SUBST(IMPLIBEXT,"def")
 912
 913 case $host_os in
 914   cygwin*|mingw32*)
 915     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 916     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 917     if test "$DLLWRAP" = "false"; then
 918       LIBEXT="a"
 919     else
 920       dnl FIXME - check whether dllwrap works correctly...
 921       LIBEXT="dll"
 922     fi
 923     IMPLIBEXT="a"
 924     dnl We can't build 16-bit NE dlls
 925     WIN16_FILES=""
 926     WIN16_INSTALL=""
 927     ;;
 928   *)
 929     AC_CHECK_HEADERS(dlfcn.h,
 930         [AC_CHECK_FUNCS(dlopen,,
 931             [AC_CHECK_LIB(dl,dlopen,
 932                          [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
 933                           DLLIBS="-ldl"],
 934                          [LIBEXT="a"])])],
 935         [LIBEXT="a"])
 936
 937     if test "$LIBEXT" = "so"
 938     then
 939       DLLFLAGS="$DLLFLAGS -fPIC"
 940       DLLEXT=".so"
 941       AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
 942           [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
 943                                 ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
 944       if test "$ac_cv_c_dll_gnuelf" = "yes"
 945       then
 946         LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
 947         LDDLLFLAGS="-shared -Wl,-Bsymbolic"
 948         AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
 949           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
 950                            ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
 951         if test "$ac_cv_c_dll_zdefs" = "yes"
 952         then
 953           LDDLLFLAGS="$LDDLLFLAGS,-z,defs"
 954         fi
 955
 956         AC_CACHE_CHECK([whether the linker accepts -init and -fini], ac_cv_c_dll_init_fini,
 957           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
 958                            ac_cv_c_dll_init_fini="yes",ac_cv_c_dll_init_fini="no")])
 959         if test "$ac_cv_c_dll_init_fini" = "yes"
 960         then
 961           LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"
 962         fi
 963
 964         AC_CACHE_CHECK([whether the linker accepts version scripts], ac_cv_c_ld_version_scripts,
 965           [echo '{ global: *; };' >conftest.map
 966            WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
 967                            ac_cv_c_ld_version_scripts="yes",ac_cv_c_ld_version_scripts="no")
 968            rm -f conftest.map])
 969         if test "$ac_cv_c_ld_version_scripts" = "yes"
 970         then
 971           LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"
 972         fi
 973
 974         AC_CACHE_CHECK([whether the linker accepts --export-dynamic], ac_cv_c_export_dynamic,
 975           [WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
 976                            ac_cv_c_export_dynamic="yes",ac_cv_c_export_dynamic="no")])
 977         if test "$ac_cv_c_export_dynamic" = "yes"
 978         then
 979           AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])
 980         fi
 981
 982         case $host_cpu in
 983           *i[[3456789]]86*)
 984             AC_CACHE_CHECK([whether we can relocate the executable to 0x77f00000], ac_cv_ld_reloc_exec,
 985               [WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x77f00400],
 986                                ac_cv_ld_reloc_exec="yes", ac_cv_ld_reloc_exec="no")])
 987             if test "$ac_cv_ld_reloc_exec" = "yes"
 988             then
 989               LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x77f00400"
 990             fi
 991             ;;
 992         esac
 993
 994       else
 995         AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
 996             [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
 997                                   ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
 998         if test "$ac_cv_c_dll_unixware" = "yes"
 999         then
1000           LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
1001           LDDLLFLAGS="-Wl,-G,-B,symbolic"
1002
1003         else
1004           AC_CACHE_CHECK(whether we can build a Mach-O (Mac OS X/Darwin) dll, ac_cv_c_dll_macho,
1005             [WINE_TRY_SHLIB_FLAGS([-bundle], ac_cv_c_dll_macho="yes", ac_cv_c_dll_macho="no")])
1006           if test "$ac_cv_c_dll_macho" = "yes"
1007           then
1008             LIBEXT="dylib"
1009             LDDLLFLAGS="-bundle -flat_namespace -undefined suppress -read_only_relocs warning"
1010             LDSHARED="\$(CC) -dynamiclib"
1011             CFLAGS="$CFLAGS -ffixed-r13 -no-cpp-precomp"
1012             STRIP="$STRIP -u -r"
1013             dnl Relocate wine executable
1014             AC_SUBST(LDEXECFLAGS,"-seg1addr 0x120000")
1015             dnl Relocate libwine.dyld too
1016             AC_SUBST(LDLIBWINEFLAGS,"-seg1addr 0x140000")
1017             dnl declare needed frameworks
1018             AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
1019             AC_SUBST(IOKITLIB,"-framework IOKit")
1020             dnl using IOKit imply we use CoreFoundation too
1021             IOKITLIB="$IOKITLIB $COREFOUNDATIONLIB"
1022           else
1023             AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
1024               [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
1025             if test "$ac_cv_c_dll_hpux" = "yes"
1026             then
1027               LIBEXT="sl"
1028               DLLEXT=".sl"
1029               LDDLLFLAGS="-shared -fPIC"
1030               LDSHARED="\$(CC) -shared"
1031             fi
1032           fi
1033         fi
1034       fi
1035     fi
1036
1037     dnl Check for cross compiler to build test programs
1038     AC_SUBST(CROSSTEST,"")
1039     if test "$cross_compiling" = "no"
1040     then
1041       AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32msvc-gcc i386-mingw32-gcc mingw-gcc,false)
1042       AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32msvc-dlltool i386-mingw32-dlltool mingw-dlltool,false)
1043       AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32msvc-windres i386-mingw32-windres mingw-windres,false)
1044       if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
1045     fi
1046     ;;
1047 esac
1048
1049 if test "$LIBEXT" = "a"; then
1050   AC_MSG_ERROR(
1051 [could not find a way to build shared libraries.
1052 It is currently not possible to build Wine without shared library
1053 (.so) support to allow transparent switch between .so and .dll files.
1054 If you are using Linux, you will need a newer binutils.]
1055 )
1056 fi
1057
1058 case $build_os in
1059   cygwin*|mingw32*)
1060     AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$PATH\"") ;;
1061   darwin*|macosx*)
1062     AC_SUBST(LDPATH,"DYLD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$DYLD_LIBRARY_PATH\"") ;;
1063   *)
1064     AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$LD_LIBRARY_PATH\"") ;;
1065 esac
1066
1067 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1068 case $host_os in
1069   mingw32*)
1070     AC_SUBST(CRTLIBS,"-lmsvcrt")
1071     AC_SUBST(SOCKETLIBS,"-lws2_32")
1072     ;;
1073 esac
1074
1075 case $host_os in
1076   linux*)
1077     case $host_cpu in
1078       *i[[3456789]]86*) AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread wine-preloader") ;;
1079       *) AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread") ;;
1080     esac
1081     AC_SUBST(MAIN_BINARY,"wine-glibc")
1082     ;;
1083   darwin*)
1084     AC_SUBST(WINE_BINARIES,"wine-pthread")
1085     AC_SUBST(MAIN_BINARY,"wine-pthread")
1086     ;;
1087   *)
1088     AC_SUBST(WINE_BINARIES,"wine-kthread")
1089     AC_SUBST(MAIN_BINARY,"wine-kthread")
1090     ;;
1091 esac
1092
1093 dnl **** Get the soname for libraries that we load dynamically ****
1094
1095 if test "$LIBEXT" = "so" -o "$LIBEXT" = "dylib"
1096 then
1097   WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
1098   WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1099   WINE_GET_SONAME(Xi,XOpenDevice,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1100   WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1101   WINE_GET_SONAME(Xrandr,XRRQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1102   WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
1103   WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
1104   WINE_GET_SONAME(txc_dxtn,fetch_2d_texel_rgba_dxt1)
1105   WINE_GET_SONAME(cups,cupsGetDefault)
1106   WINE_GET_SONAME(jack,jack_client_new)
1107   WINE_GET_SONAME(fontconfig,FcInit)
1108   WINE_GET_SONAME(ssl,SSL_library_init)
1109   WINE_GET_SONAME(crypto,BIO_new_socket)
1110   WINE_GET_SONAME(ncurses,waddch)
1111   WINE_GET_SONAME(curses,waddch)
1112   WINE_GET_SONAME(jpeg,jpeg_start_decompress)
1113   WINE_GET_SONAME(ungif,DGifOpen)
1114   WINE_GET_SONAME(gif,DGifOpen)
1115   WINE_GET_SONAME(lcms,cmsOpenProfileFromFile)
1116   WINE_GET_SONAME(capi20,capi20_isinstalled)
1117 fi
1118
1119
1120 dnl **** Check for functions ****
1121
1122 AC_FUNC_ALLOCA()
1123 AC_CHECK_FUNCS(\
1124         _lwp_create \
1125         _lwp_self \
1126         _pclose \
1127         _popen \
1128         _snprintf \
1129         _spawnvp \
1130         _stricmp \
1131         _strnicmp \
1132         _vsnprintf \
1133         chsize \
1134         clone \
1135         epoll_create \
1136         ffs \
1137         finite \
1138         fork \
1139         fpclass \
1140         fstatfs \
1141         fstatvfs \
1142         ftruncate \
1143         futimes \
1144         getnetbyname \
1145         getopt_long \
1146         getpagesize \
1147         getprotobyname \
1148         getprotobynumber \
1149         getpwuid \
1150         getservbyport \
1151         gettid \
1152         gettimeofday \
1153         getuid \
1154         inet_network \
1155         lstat \
1156         memmove \
1157         mmap \
1158         pclose \
1159         popen \
1160         pread \
1161         pwrite \
1162         readlink \
1163         rfork \
1164         sched_yield \
1165         select \
1166         sendmsg \
1167         settimeofday \
1168         sigaltstack \
1169         sigprocmask \
1170         snprintf \
1171         spawnvp \
1172         statfs \
1173         statvfs \
1174         strcasecmp \
1175         strerror \
1176         strncasecmp \
1177         tcgetattr \
1178         timegm \
1179         usleep \
1180         vsnprintf \
1181         wait4 \
1182         waitpid \
1183 )
1184
1185 dnl **** Checks for headers that depend on other ones ****
1186
1187 AC_CHECK_HEADERS(sys/mount.h sys/user.h,,,
1188     [#include <sys/types.h>
1189      #if HAVE_SYS_PARAM_H
1190      # include <sys/param.h>
1191      #endif])
1192
1193 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h],,,
1194     [#include <sys/types.h>
1195      #if HAVE_SYS_SOCKET_H
1196      # include <sys/socket.h>
1197      #endif])
1198
1199 AC_CHECK_HEADERS([resolv.h],,,
1200     [#include <sys/types.h>
1201      #if HAVE_SYS_SOCKET_H
1202      # include <sys/socket.h>
1203      #endif
1204      #if HAVE_NETINET_IN_H
1205      # include <netinet/in.h>
1206      #endif
1207      #if HAVE_ARPA_NAMESER_H
1208      # include <arpa/nameser.h>
1209      #endif])
1210
1211 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
1212
1213 dnl **** Check for IPX headers (currently Linux only) ****
1214
1215 AC_CACHE_CHECK([for GNU style IPX support], ac_cv_c_ipx_gnu,
1216  AC_TRY_COMPILE(
1217    [#include <sys/types.h>
1218     #ifdef HAVE_SYS_SOCKET_H
1219     # include <sys/socket.h>
1220     #endif
1221     #include <netipx/ipx.h>],
1222    [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1223    [ac_cv_c_ipx_gnu="yes"],
1224    [ac_cv_c_ipx_gnu="no"])
1225  )
1226 if test "$ac_cv_c_ipx_gnu" = "yes"
1227 then
1228     AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
1229 fi
1230
1231 if test "$ac_cv_c_ipx_gnu" = "no"
1232 then
1233  AC_CACHE_CHECK([for linux style IPX support], ac_cv_c_ipx_linux,
1234   AC_TRY_COMPILE(
1235     [#include <sys/types.h>
1236      #ifdef HAVE_SYS_SOCKET_H
1237      # include <sys/socket.h>
1238      #endif
1239      #include <asm/types.h>
1240      #include <linux/ipx.h>],
1241     [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1242     [ac_cv_c_ipx_linux="yes"],
1243     [ac_cv_c_ipx_linux="no"])
1244   )
1245   if test "$ac_cv_c_ipx_linux" = "yes"
1246   then
1247       AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
1248   fi
1249 fi
1250
1251 dnl **** Check for types ****
1252
1253 AC_C_CONST
1254 AC_C_INLINE
1255 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1256 AC_CHECK_TYPES([sigset_t],,,[#include <signal.h>])
1257
1258 AC_CACHE_CHECK([whether linux/input.h is for real],
1259         wine_cv_linux_input_h,
1260         AC_TRY_COMPILE([
1261             #include <linux/input.h>
1262         ] , [
1263             int foo = EVIOCGBIT(EV_ABS,42);
1264             int bar = BTN_PINKIE;
1265             int fortytwo = 42;
1266         ],
1267         wine_cv_linux_input_h=yes,
1268         wine_cv_linux_input_h=no,
1269         no
1270         )
1271     )
1272     if test "$wine_cv_linux_input_h" = "yes"
1273     then
1274         AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
1275                   [Define if we have linux/input.h AND it contains the INPUT event API])
1276     fi
1277
1278 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
1279                AC_TRY_LINK([#include <signal.h>],[sigset_t set; sigaddset(&set,SIGTERM);],
1280                            wine_cv_have_sigaddset=yes,wine_cv_have_sigaddset=no))
1281 if test "$wine_cv_have_sigaddset" = "yes"
1282 then
1283   AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
1284 fi
1285
1286
1287 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1288         wine_cv_linux_gethostbyname_r_6,
1289         AC_TRY_LINK([
1290 #include <netdb.h>
1291         ], [
1292     char *name=NULL;
1293     struct hostent he;
1294     struct hostent *result;
1295     char *buf=NULL;
1296     int bufsize=0;
1297     int res,errnr;
1298     char *addr=NULL;
1299     int addrlen=0;
1300     int addrtype=0;
1301     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1302     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1303     ],
1304         wine_cv_linux_gethostbyname_r_6=yes,
1305         wine_cv_linux_gethostbyname_r_6=no
1306         )
1307    )
1308    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1309    then
1310       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1311                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1312    fi
1313
1314 if test "$ac_cv_header_linux_joystick_h" = "yes"
1315 then
1316    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1317         wine_cv_linux_joystick_22_api,
1318         AC_TRY_COMPILE([
1319         #include <sys/ioctl.h>
1320         #include <linux/joystick.h>
1321
1322         struct js_event blub;
1323         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1324         #error "no 2.2 header"
1325         #endif
1326         ],/*empty*/,
1327         wine_cv_linux_joystick_22_api=yes,
1328         wine_cv_linux_joystick_22_api=no,
1329         wine_cv_linux_joystick_22_api=no
1330         )
1331    )
1332    if test "$wine_cv_linux_joystick_22_api" = "yes"
1333    then
1334       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1335                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1336    fi
1337 fi
1338
1339 dnl **** statfs checks ****
1340
1341 if test "$ac_cv_header_sys_vfs_h" = "yes"
1342 then
1343     AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
1344                     wine_cv_sys_vfs_has_statfs,
1345         AC_TRY_COMPILE([
1346         #include <sys/types.h>
1347         #ifdef HAVE_SYS_PARAM_H
1348         # include <sys/param.h>
1349         #endif
1350         #include <sys/vfs.h>
1351         ],[
1352                 struct statfs stfs;
1353
1354                 memset(&stfs,0,sizeof(stfs));
1355         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1356         )
1357     )
1358     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1359     then
1360       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1361                 [Define if the struct statfs is defined by <sys/vfs.h>])
1362     fi
1363 fi
1364
1365 if test "$ac_cv_header_sys_statfs_h" = "yes"
1366 then
1367     AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1368                     wine_cv_sys_statfs_has_statfs,
1369         AC_TRY_COMPILE([
1370         #include <sys/types.h>
1371         #ifdef HAVE_SYS_PARAM_H
1372         # include <sys/param.h>
1373         #endif
1374         #include <sys/statfs.h>
1375         ],[
1376                 struct statfs stfs;
1377         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1378         )
1379     )
1380     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1381     then
1382       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1383                 [Define if the struct statfs is defined by <sys/statfs.h>])
1384     fi
1385 fi
1386
1387 if test "$ac_cv_header_sys_mount_h" = "yes"
1388 then
1389     AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1390                     wine_cv_sys_mount_has_statfs,
1391         AC_TRY_COMPILE([
1392         #include <sys/types.h>
1393         #ifdef HAVE_SYS_PARAM_H
1394         # include <sys/param.h>
1395         #endif
1396         #include <sys/mount.h>
1397         ],[
1398                 struct statfs stfs;
1399         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1400         )
1401     )
1402     if test "$wine_cv_sys_mount_has_statfs" = "yes"
1403     then
1404       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1405                 [Define if the struct statfs is defined by <sys/mount.h>])
1406     fi
1407 fi
1408
1409 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1410
1411 dnl Check for statfs members
1412 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1413 [#include <sys/types.h>
1414 #ifdef HAVE_SYS_PARAM_H
1415 # include <sys/param.h>
1416 #endif
1417 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1418 # include <sys/mount.h>
1419 #else
1420 # ifdef STATFS_DEFINED_BY_SYS_VFS
1421 #  include <sys/vfs.h>
1422 # else
1423 #  ifdef STATFS_DEFINED_BY_SYS_STATFS
1424 #   include <sys/statfs.h>
1425 #  endif
1426 # endif
1427 #endif])
1428
1429 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1430 [#ifdef HAVE_SYS_STATVFS_H
1431 #include <sys/statvfs.h>
1432 #endif])
1433
1434 dnl Check for socket structure members
1435 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1436 [#include <sys/types.h>
1437 #ifdef HAVE_SYS_SOCKET_H
1438 # include <sys/socket.h>
1439 #endif
1440 #ifdef HAVE_SYS_UN_H
1441 # include <sys/un.h>
1442 #endif])
1443
1444 dnl Check for siginfo_t members
1445 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1446
1447 dnl Check for struct option
1448 AC_CHECK_MEMBERS([struct option.name],,,
1449 [#ifdef HAVE_GETOPT_H
1450 #include <getopt.h>
1451 #endif])
1452
1453 dnl Check for stat.st_blocks
1454 AC_CHECK_MEMBERS([struct stat.st_blocks])
1455
1456 dnl *** check for the need to define platform-specific symbols
1457
1458 case $host_cpu in
1459   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1460   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
1461   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
1462   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
1463 esac
1464
1465 case $host_vendor in
1466   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1467 esac
1468
1469 dnl **** Generate output files ****
1470
1471 AH_TOP([#define __WINE_CONFIG_H])
1472
1473 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/d3ddevice)
1474 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dclipper)
1475 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/ddraw)
1476 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/direct3d)
1477 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dpalette)
1478 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dsurface)
1479 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1480 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1481 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1482 WINE_CONFIG_EXTRA_DIR(dlls/user/dde)
1483 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1484 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1485 WINE_CONFIG_EXTRA_DIR(include/wine)
1486 WINE_CONFIG_EXTRA_DIR(misc)
1487 WINE_CONFIG_EXTRA_DIR(programs/regedit/tests)
1488 WINE_CONFIG_EXTRA_DIR(windows)
1489
1490 MAKE_RULES=Make.rules
1491 AC_SUBST_FILE(MAKE_RULES)
1492
1493 MAKE_DLL_RULES=dlls/Makedll.rules
1494 AC_SUBST_FILE(MAKE_DLL_RULES)
1495
1496 MAKE_TEST_RULES=dlls/Maketest.rules
1497 AC_SUBST_FILE(MAKE_TEST_RULES)
1498
1499 MAKE_LIB_RULES=libs/Makelib.rules
1500 AC_SUBST_FILE(MAKE_LIB_RULES)
1501
1502 MAKE_PROG_RULES=programs/Makeprog.rules
1503 AC_SUBST_FILE(MAKE_PROG_RULES)
1504
1505 AC_CONFIG_FILES([
1506 Make.rules
1507 dlls/Makedll.rules
1508 dlls/Maketest.rules
1509 libs/Makelib.rules
1510 programs/Makeprog.rules
1511 Makefile
1512 dlls/Makefile
1513 dlls/advapi32/Makefile
1514 dlls/advapi32/tests/Makefile
1515 dlls/advpack/Makefile
1516 dlls/advpack/tests/Makefile
1517 dlls/amstream/Makefile
1518 dlls/atl/Makefile
1519 dlls/avicap32/Makefile
1520 dlls/avifil32/Makefile
1521 dlls/cabinet/Makefile
1522 dlls/capi2032/Makefile
1523 dlls/cards/Makefile
1524 dlls/cfgmgr32/Makefile
1525 dlls/comcat/Makefile
1526 dlls/comctl32/Makefile
1527 dlls/comctl32/tests/Makefile
1528 dlls/commdlg/Makefile
1529 dlls/crtdll/Makefile
1530 dlls/crypt32/Makefile
1531 dlls/cryptdll/Makefile
1532 dlls/ctl3d/Makefile
1533 dlls/d3d8/Makefile
1534 dlls/d3d9/Makefile
1535 dlls/d3dim/Makefile
1536 dlls/d3drm/Makefile
1537 dlls/d3dx8/Makefile
1538 dlls/d3dxof/Makefile
1539 dlls/dbghelp/Makefile
1540 dlls/dciman32/Makefile
1541 dlls/ddraw/Makefile
1542 dlls/ddraw/tests/Makefile
1543 dlls/devenum/Makefile
1544 dlls/dinput/Makefile
1545 dlls/dinput8/Makefile
1546 dlls/dmband/Makefile
1547 dlls/dmcompos/Makefile
1548 dlls/dmime/Makefile
1549 dlls/dmloader/Makefile
1550 dlls/dmscript/Makefile
1551 dlls/dmstyle/Makefile
1552 dlls/dmsynth/Makefile
1553 dlls/dmusic/Makefile
1554 dlls/dmusic32/Makefile
1555 dlls/dplay/Makefile
1556 dlls/dplayx/Makefile
1557 dlls/dpnet/Makefile
1558 dlls/dpnhpast/Makefile
1559 dlls/dsound/Makefile
1560 dlls/dsound/tests/Makefile
1561 dlls/dswave/Makefile
1562 dlls/dxdiagn/Makefile
1563 dlls/dxerr8/Makefile
1564 dlls/dxerr9/Makefile
1565 dlls/dxguid/Makefile
1566 dlls/gdi/Makefile
1567 dlls/gdi/tests/Makefile
1568 dlls/glu32/Makefile
1569 dlls/glut32/Makefile
1570 dlls/hhctrl.ocx/Makefile
1571 dlls/iccvid/Makefile
1572 dlls/icmp/Makefile
1573 dlls/ifsmgr.vxd/Makefile
1574 dlls/imagehlp/Makefile
1575 dlls/imm32/Makefile
1576 dlls/iphlpapi/Makefile
1577 dlls/iphlpapi/tests/Makefile
1578 dlls/itss/Makefile
1579 dlls/kernel/Makefile
1580 dlls/kernel/tests/Makefile
1581 dlls/lzexpand/Makefile
1582 dlls/lzexpand/tests/Makefile
1583 dlls/mapi32/Makefile
1584 dlls/mapi32/tests/Makefile
1585 dlls/mlang/Makefile
1586 dlls/mlang/tests/Makefile
1587 dlls/mmdevldr.vxd/Makefile
1588 dlls/monodebg.vxd/Makefile
1589 dlls/mpr/Makefile
1590 dlls/msacm/Makefile
1591 dlls/msacm/imaadp32/Makefile
1592 dlls/msacm/msadp32/Makefile
1593 dlls/msacm/msg711/Makefile
1594 dlls/msacm/winemp3/Makefile
1595 dlls/msacm/tests/Makefile
1596 dlls/mscms/Makefile
1597 dlls/mscms/tests/Makefile
1598 dlls/msdmo/Makefile
1599 dlls/mshtml/Makefile
1600 dlls/msi/Makefile
1601 dlls/msi/tests/Makefile
1602 dlls/msimg32/Makefile
1603 dlls/msisys/Makefile
1604 dlls/msnet32/Makefile
1605 dlls/msrle32/Makefile
1606 dlls/msvcrt/Makefile
1607 dlls/msvcrt/tests/Makefile
1608 dlls/msvcrt20/Makefile
1609 dlls/msvcrt40/Makefile
1610 dlls/msvcrtd/Makefile
1611 dlls/msvcrtd/tests/Makefile
1612 dlls/msvidc32/Makefile
1613 dlls/msvideo/Makefile
1614 dlls/mswsock/Makefile
1615 dlls/netapi32/Makefile
1616 dlls/netapi32/tests/Makefile
1617 dlls/newdev/Makefile
1618 dlls/ntdll/Makefile
1619 dlls/ntdll/tests/Makefile
1620 dlls/odbc32/Makefile
1621 dlls/ole32/Makefile
1622 dlls/ole32/tests/Makefile
1623 dlls/oleacc/Makefile
1624 dlls/oleaut32/Makefile
1625 dlls/oleaut32/tests/Makefile
1626 dlls/olecli/Makefile
1627 dlls/oledlg/Makefile
1628 dlls/olepro32/Makefile
1629 dlls/olesvr/Makefile
1630 dlls/opengl32/Makefile
1631 dlls/psapi/Makefile
1632 dlls/psapi/tests/Makefile
1633 dlls/qcap/Makefile
1634 dlls/quartz/Makefile
1635 dlls/quartz/tests/Makefile
1636 dlls/rasapi32/Makefile
1637 dlls/riched20/Makefile
1638 dlls/richedit/Makefile
1639 dlls/rpcrt4/Makefile
1640 dlls/rpcrt4/tests/Makefile
1641 dlls/rsabase/Makefile
1642 dlls/rsabase/tests/Makefile
1643 dlls/rsaenh/Makefile
1644 dlls/rsaenh/tests/Makefile
1645 dlls/secur32/Makefile
1646 dlls/sensapi/Makefile
1647 dlls/serialui/Makefile
1648 dlls/setupapi/Makefile
1649 dlls/shdocvw/Makefile
1650 dlls/shell32/Makefile
1651 dlls/shell32/tests/Makefile
1652 dlls/shfolder/Makefile
1653 dlls/shlwapi/Makefile
1654 dlls/shlwapi/tests/Makefile
1655 dlls/snmpapi/Makefile
1656 dlls/stdole32.tlb/Makefile
1657 dlls/sti/Makefile
1658 dlls/strmiids/Makefile
1659 dlls/tapi32/Makefile
1660 dlls/ttydrv/Makefile
1661 dlls/twain/Makefile
1662 dlls/unicows/Makefile
1663 dlls/url/Makefile
1664 dlls/urlmon/Makefile
1665 dlls/urlmon/tests/Makefile
1666 dlls/user/Makefile
1667 dlls/user/tests/Makefile
1668 dlls/uuid/Makefile
1669 dlls/uxtheme/Makefile
1670 dlls/vdhcp.vxd/Makefile
1671 dlls/vdmdbg/Makefile
1672 dlls/version/Makefile
1673 dlls/version/tests/Makefile
1674 dlls/vmm.vxd/Makefile
1675 dlls/vnbt.vxd/Makefile
1676 dlls/vnetbios.vxd/Makefile
1677 dlls/vtdapi.vxd/Makefile
1678 dlls/vwin32.vxd/Makefile
1679 dlls/win32s/Makefile
1680 dlls/winaspi/Makefile
1681 dlls/wined3d/Makefile
1682 dlls/winedos/Makefile
1683 dlls/wineps/Makefile
1684 dlls/wininet/Makefile
1685 dlls/wininet/tests/Makefile
1686 dlls/winmm/Makefile
1687 dlls/winmm/joystick/Makefile
1688 dlls/winmm/mcianim/Makefile
1689 dlls/winmm/mciavi/Makefile
1690 dlls/winmm/mcicda/Makefile
1691 dlls/winmm/mciseq/Makefile
1692 dlls/winmm/mciwave/Makefile
1693 dlls/winmm/midimap/Makefile
1694 dlls/winmm/tests/Makefile
1695 dlls/winmm/wavemap/Makefile
1696 dlls/winmm/winealsa/Makefile
1697 dlls/winmm/winearts/Makefile
1698 dlls/winmm/wineaudioio/Makefile
1699 dlls/winmm/winejack/Makefile
1700 dlls/winmm/winenas/Makefile
1701 dlls/winmm/wineoss/Makefile
1702 dlls/winnls/Makefile
1703 dlls/winsock/Makefile
1704 dlls/winsock/tests/Makefile
1705 dlls/winspool/Makefile
1706 dlls/winspool/tests/Makefile
1707 dlls/wintab32/Makefile
1708 dlls/wintrust/Makefile
1709 dlls/wow32/Makefile
1710 dlls/wsock32/Makefile
1711 dlls/wtsapi32/Makefile
1712 dlls/x11drv/Makefile
1713 documentation/Makefile
1714 fonts/Makefile
1715 include/Makefile
1716 libs/Makefile
1717 libs/port/Makefile
1718 libs/unicode/Makefile
1719 libs/wine/Makefile
1720 libs/wpp/Makefile
1721 loader/Makefile
1722 programs/Makefile
1723 programs/avitools/Makefile
1724 programs/clock/Makefile
1725 programs/cmdlgtst/Makefile
1726 programs/control/Makefile
1727 programs/expand/Makefile
1728 programs/msiexec/Makefile
1729 programs/notepad/Makefile
1730 programs/progman/Makefile
1731 programs/regedit/Makefile
1732 programs/regsvr32/Makefile
1733 programs/rpcss/Makefile
1734 programs/rundll32/Makefile
1735 programs/start/Makefile
1736 programs/taskmgr/Makefile
1737 programs/uninstaller/Makefile
1738 programs/view/Makefile
1739 programs/wcmd/Makefile
1740 programs/wineboot/Makefile
1741 programs/winebrowser/Makefile
1742 programs/winecfg/Makefile
1743 programs/wineconsole/Makefile
1744 programs/winedbg/Makefile
1745 programs/winefile/Makefile
1746 programs/winemenubuilder/Makefile
1747 programs/winemine/Makefile
1748 programs/winepath/Makefile
1749 programs/winetest/Makefile
1750 programs/winevdm/Makefile
1751 programs/winhelp/Makefile
1752 programs/winver/Makefile
1753 server/Makefile
1754 tools/Makefile
1755 tools/widl/Makefile
1756 tools/winapi/Makefile
1757 tools/winebuild/Makefile
1758 tools/winedump/Makefile
1759 tools/winegcc/Makefile
1760 tools/wmc/Makefile
1761 tools/wrc/Makefile])
1762
1763 AC_OUTPUT
1764
1765 if test "$have_x" = "no"
1766 then
1767   echo
1768   echo "*** Warning: X development files not found. Wine will be built without"
1769   echo "*** X support, which currently does not work, and would probably not be"
1770   echo "*** what you want anyway. You will need to install devel packages of"
1771   echo "*** Xlib/Xfree86 at the very least."
1772 fi
1773
1774 if test "$wine_cv_opengl_version_OK" = "no"
1775 then
1776   echo
1777   echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1778   echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1779 fi
1780
1781 if test "$wine_cv_msg_freetype" = "yes"
1782 then
1783   echo
1784   echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1785   echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1786   echo "*** freetype-devel package (or its equivalent on your distribution) to"
1787   echo "*** enable Wine to use TrueType fonts."
1788 fi
1789
1790 if test -z "$ALSALIBS" -a -z "$ARTSC_LIBS" -a -z "$AUDIOIOLIBS" -a \
1791         -z "$ac_cv_lib_soname_jack" -a -z "$NASLIBS" -a \
1792         "$ac_cv_c_opensoundsystem" = "no"
1793 then
1794     echo "*** No sound system was found. Windows applications will be silent."
1795     echo "*** The currently supported sound systems are:"
1796     echo "*** ALSA, ARTS, AudioIO, Jack, NAS and OSS"
1797 fi
1798
1799 echo
1800 echo "Configure finished.  Do '${ac_make} depend && ${ac_make}' to compile Wine."
1801 echo
1802
1803 dnl Local Variables:
1804 dnl comment-start: "dnl "
1805 dnl comment-end: ""
1806 dnl comment-start-skip: "\\bdnl\\b\\s *"
1807 dnl compile-command: "autoconf"
1808 dnl End: