git.oblomov.eu Git - wine/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 AC_PREREQ(2.53b)
   8 AC_INIT([Wine],[WINE_VERSION],[wine-devel@winehq.org])
   9 AC_CONFIG_SRCDIR(server/atom.c)
  10 AC_CONFIG_HEADERS(include/config.h)
  11 AC_CONFIG_AUX_DIR(tools)
  12
  13 dnl **** Command-line arguments ****
  14
  15 AC_ARG_ENABLE(win16, AS_HELP_STRING([--disable-win16],[do not include Win16 support]))
  16 AC_ARG_ENABLE(win64, AS_HELP_STRING([--enable-win64],[build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
  17
  18 AC_ARG_WITH(opengl,    AS_HELP_STRING([--without-opengl],[do not use OpenGL]))
  19 AC_ARG_WITH(wine-tools,AS_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
  20
  21 AC_CANONICAL_HOST
  22 case $host in
  23   x86_64*linux*)
  24     if test "x$enable_win64" != "xyes"
  25     then
  26       test -n "$CC" || CC="gcc -m32"
  27       test -n "$CXX"|| CXX="g++ -m32"
  28       test -n "$LD" || LD="ld -m elf_i386"
  29       test -n "$AS" || AS="as --32"
  30       host_cpu="i386"
  31     fi
  32     ;;
  33 esac
  34
  35 dnl enable_win16 defaults to yes on x86, to no on other CPUs
  36 case $host_cpu in
  37   *i[[3456789]]86*)
  38     if test "x$enable_win16" != "xno"
  39     then
  40       enable_win16="yes"
  41     fi
  42     ;;
  43 esac
  44
  45 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
  46 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
  47 if test "x$enable_win16" != "xyes"
  48 then
  49   WIN16_FILES=""
  50   WIN16_INSTALL=""
  51 fi
  52
  53 dnl check for out of tree build with unclean source tree
  54 case "$srcdir" in
  55  .) ;;
  56  *) if test -f "$srcdir/Makefile" -o -f "$srcdir/include/config.h"; then
  57       AC_MSG_ERROR([you are building out of the source tree, but the source tree contains object files.
  58 You need to run 'make distclean' in the source tree first.])
  59     fi ;;
  60 esac
  61
  62 dnl **** Check for some programs ****
  63
  64 AC_PROG_MAKE_SET
  65 AC_PROG_CC
  66 AC_PROG_CXX
  67 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
  68 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
  69
  70 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
  71   [if test -z "$with_wine_tools"; then
  72      if test "$cross_compiling" = "yes"; then
  73        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
  74      else
  75        wine_cv_toolsdir="\$(TOPOBJDIR)"
  76      fi
  77    elif test -d "$with_wine_tools/tools/winebuild"; then
  78      case $with_wine_tools in
  79        /*) wine_cv_toolsdir="$with_wine_tools" ;;
  80        *)  wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
  81      esac
  82    else
  83      AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
  84    fi])
  85 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
  86
  87 AC_PATH_XTRA
  88
  89 dnl Check for flex
  90 AC_CHECK_PROGS(FLEX,flex,none)
  91 if test "$FLEX" = "none"
  92 then
  93   AC_MSG_ERROR([no suitable flex found. Please install the 'flex' package.])
  94 fi
  95
  96 dnl Check for bison
  97 AC_CHECK_PROGS(BISON,bison,none)
  98 if test "$BISON" = "none"
  99 then
 100   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
 101 fi
 102
 103 AC_CHECK_TOOLS(AS,[gas as],as)
 104 AC_CHECK_TOOL(LD,ld,ld)
 105 AC_CHECK_TOOL(AR,ar,ar)
 106 AC_PROG_RANLIB
 107 AC_CHECK_TOOL(STRIP,strip,strip)
 108 AC_CHECK_TOOL(WINDRES,windres,false)
 109 AC_PROG_LN_S
 110 WINE_PROG_LN
 111 AC_PROG_EGREP
 112 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
 113 AC_PROG_INSTALL
 114 dnl Prepend src dir to install path dir if it's a relative path
 115 case "$INSTALL" in
 116   [[\\/$]]* | ?:[[\\/]]* ) ;;
 117   *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
 118 esac
 119
 120 dnl Check for lint
 121 AC_CHECK_PROGS(LINT, lclint lint)
 122 if test "$LINT" = "lint"
 123 then
 124   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 125   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 126 fi
 127 AC_SUBST(LINT)
 128 AC_SUBST(LINTFLAGS)
 129
 130 dnl Check for various programs
 131 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
 132 AC_CHECK_PROGS(PKG_CONFIG, pkg-config, false)
 133
 134 case $host_cpu in
 135   *i[[3456789]]86*)
 136     AC_PATH_PROG(PRELINK, prelink, false, [/sbin /usr/sbin $PATH])
 137     ;;
 138 esac
 139
 140 dnl **** Check for some libraries ****
 141
 142 dnl Check for -li386 for NetBSD and OpenBSD
 143 AC_CHECK_LIB(i386,i386_set_ldt)
 144 dnl Check for -lossaudio for NetBSD
 145 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 146 dnl Check for -lpthread
 147 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
 148
 149 AC_SUBST(XLIB,"")
 150 AC_SUBST(XFILES,"")
 151 AC_SUBST(OPENGLFILES,"")
 152 AC_SUBST(GLU32FILES,"")
 153 AC_SUBST(OPENGL_LIBS,"")
 154 AC_SUBST(QUARTZFILES,"")
 155
 156 dnl **** Check for header files ****
 157
 158 AC_CHECK_HEADERS(\
 159         AudioUnit/AudioUnit.h \
 160         Carbon/Carbon.h \
 161         CoreAudio/CoreAudio.h \
 162         DiskArbitration/DiskArbitration.h \
 163         IOKit/IOKitLib.h \
 164         alsa/asoundlib.h \
 165         arpa/inet.h \
 166         arpa/nameser.h \
 167         asm/types.h \
 168         capi20.h \
 169         cups/cups.h \
 170         curses.h \
 171         direct.h \
 172         dlfcn.h \
 173         elf.h \
 174         float.h \
 175         fontconfig/fontconfig.h \
 176         getopt.h \
 177         ieeefp.h \
 178         io.h \
 179         jack/jack.h \
 180         jpeglib.h \
 181         lber.h \
 182         lcms.h \
 183         lcms/lcms.h \
 184         ldap.h \
 185         libaudioio.h \
 186         link.h \
 187         linux/cdrom.h \
 188         linux/compiler.h \
 189         linux/hdreg.h \
 190         linux/input.h \
 191         linux/ioctl.h \
 192         linux/joystick.h \
 193         linux/major.h \
 194         linux/param.h \
 195         linux/serial.h \
 196         linux/ucdrom.h \
 197         mach/mach.h \
 198         mach/machine.h \
 199         machine/cpu.h \
 200         machine/limits.h \
 201         machine/soundcard.h \
 202         mntent.h \
 203         ncurses.h \
 204         netdb.h \
 205         netinet/in.h \
 206         netinet/in_systm.h \
 207         netinet/tcp.h \
 208         netinet/tcp_fsm.h \
 209         openssl/err.h \
 210         openssl/ssl.h \
 211         png.h \
 212         poll.h \
 213         process.h \
 214         pthread.h \
 215         pwd.h \
 216         regex.h \
 217         sched.h \
 218         scsi/scsi.h \
 219         scsi/scsi_ioctl.h \
 220         scsi/sg.h \
 221         soundcard.h \
 222         stdint.h \
 223         strings.h \
 224         sys/asoundlib.h \
 225         sys/cdio.h \
 226         sys/elf32.h \
 227         sys/epoll.h \
 228         sys/errno.h \
 229         sys/event.h \
 230         sys/exec_elf.h \
 231         sys/filio.h \
 232         sys/ioctl.h \
 233         sys/ipc.h \
 234         sys/limits.h \
 235         sys/link.h \
 236         sys/lwp.h \
 237         sys/mman.h \
 238         sys/modem.h \
 239         sys/msg.h \
 240         sys/mtio.h \
 241         sys/param.h \
 242         sys/poll.h \
 243         sys/prctl.h \
 244         sys/ptrace.h \
 245         sys/reg.h \
 246         sys/resource.h \
 247         sys/scsiio.h \
 248         sys/shm.h \
 249         sys/signal.h \
 250         sys/socket.h \
 251         sys/socketvar.h \
 252         sys/sockio.h \
 253         sys/soundcard.h \
 254         sys/statvfs.h \
 255         sys/strtio.h \
 256         sys/syscall.h \
 257         sys/sysctl.h \
 258         sys/time.h \
 259         sys/times.h \
 260         sys/uio.h \
 261         sys/un.h \
 262         sys/vm86.h \
 263         sys/wait.h \
 264         syscall.h \
 265         termios.h \
 266         unistd.h \
 267         utime.h \
 268         valgrind/memcheck.h
 269 )
 270 AC_HEADER_STAT()
 271
 272 dnl **** Checks for headers that depend on other ones ****
 273
 274 AC_CHECK_HEADERS([sys/mount.h sys/statfs.h sys/user.h sys/vfs.h],,,
 275     [#include <sys/types.h>
 276      #if HAVE_SYS_PARAM_H
 277      # include <sys/param.h>
 278      #endif])
 279
 280 AC_CHECK_HEADERS([netinet/in_pcb.h netinet/ip_var.h net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h netipx/ipx.h],,,
 281     [#include <sys/types.h>
 282      #if HAVE_SYS_SOCKET_H
 283      # include <sys/socket.h>
 284      #endif
 285      #if HAVE_SYS_SOCKETVAR_H
 286      # include <sys/socketvar.h>
 287      #endif
 288      #if HAVE_NETINET_IN_H
 289      # include <netinet/in.h>
 290      #endif])
 291
 292 AC_CHECK_HEADERS([netinet/tcp_var.h],,,
 293     [#include <sys/types.h>
 294      #if HAVE_SYS_SOCKET_H
 295      # include <sys/socket.h>
 296      #endif
 297      #if HAVE_SYS_SOCKETVAR_H
 298      # include <sys/socketvar.h>
 299      #endif
 300      #if HAVE_NETINET_IN_H
 301      # include <netinet/in.h>
 302      #endif
 303      #ifdef HAVE_NETINET_TCP_H
 304      # include <netinet/tcp.h>
 305      #endif])
 306
 307 AC_CHECK_HEADERS([linux/ipx.h],,,
 308     [#include <sys/types.h>
 309      #ifdef HAVE_ASM_TYPES_H
 310      # include <asm/types.h>
 311      #endif
 312      #if HAVE_SYS_SOCKET_H
 313      # include <sys/socket.h>
 314      #endif])
 315
 316 AC_CHECK_HEADERS([resolv.h],,,
 317     [#include <sys/types.h>
 318      #if HAVE_SYS_SOCKET_H
 319      # include <sys/socket.h>
 320      #endif
 321      #if HAVE_NETINET_IN_H
 322      # include <netinet/in.h>
 323      #endif
 324      #if HAVE_ARPA_NAMESER_H
 325      # include <arpa/nameser.h>
 326      #endif])
 327
 328 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
 329
 330 AC_CHECK_HEADERS([sys/thr.h],,,
 331 [#include <sys/types.h>
 332 #if HAVE_UCONTEXT_H
 333 #include <ucontext.h>
 334 #endif])
 335
 336 AC_CHECK_HEADERS([pthread_np.h],,,
 337 [#ifdef HAVE_PTHREAD_H
 338 #include <pthread.h>
 339 #endif])
 340
 341 AC_CHECK_HEADERS([linux/videodev.h],,,
 342 [#ifdef HAVE_SYS_TIME_H
 343 #include <sys/time.h>
 344 #endif
 345 #include <sys/types.h>
 346 #ifdef HAVE_ASM_TYPES_H
 347 #include <asm/types.h>
 348 #endif])
 349
 350 dnl Check for broken kernel header that doesn't define __user
 351 AC_CHECK_HEADERS([linux/capi.h],,,[#define __user])
 352
 353 dnl **** Check for working dll ****
 354
 355 AC_SUBST(DLLEXT,"")
 356 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 357 AC_SUBST(LDSHARED,"")
 358 AC_SUBST(LDDLLFLAGS,"")
 359 AC_SUBST(LIBEXT,"so")
 360 AC_SUBST(IMPLIBEXT,"def")
 361 AC_SUBST(LDRPATH_INSTALL,"")
 362 AC_SUBST(LDRPATH_LOCAL,"")
 363 WINE_PATH_LDD
 364
 365 case $host_os in
 366   cygwin*|mingw32*)
 367     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 368     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 369     AC_CHECK_TOOL(MINGWAR,ar,false)
 370     if test "$DLLWRAP" = "false"; then
 371       LIBEXT="a"
 372     else
 373       dnl FIXME - check whether dllwrap works correctly...
 374       LIBEXT="dll"
 375     fi
 376     IMPLIBEXT="a"
 377     dnl We can't build 16-bit NE dlls
 378     WIN16_FILES=""
 379     WIN16_INSTALL=""
 380     ;;
 381   darwin*|macosx*)
 382     DLLEXT=".so"
 383     LIBEXT="dylib"
 384     DLLFLAGS="$DLLFLAGS -fPIC"
 385     LDDLLFLAGS="-bundle -multiply_defined suppress"
 386     LIBWINE_LDFLAGS="-multiply_defined suppress"
 387     LDSHARED="\$(CC) -dynamiclib"
 388     STRIP="$STRIP -x"
 389     LDRPATH_LOCAL="&& install_name_tool -change @executable_path/\`\$(RELPATH) \$(bindir) \$(libdir)\`/libwine.1.dylib @executable_path/\$(TOPOBJDIR)/libs/wine/libwine.1.dylib \$@ || \$(RM) \$@"
 390     dnl declare needed frameworks
 391     AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
 392     AC_SUBST(IOKITLIB,"-framework IOKit -framework CoreFoundation")
 393     AC_SUBST(LDEXECFLAGS,["-image_base 0x7bf00000 -Wl,-segaddr,WINE_DOS,0x00000000,-segaddr,WINE_SHARED_HEAP,0x7f000000"])
 394     if test "$ac_cv_header_DiskArbitration_DiskArbitration_h" = "yes"
 395     then
 396         dnl DiskArbitration API is not public on Darwin < 8.0, use it only if header found
 397         AC_SUBST(DISKARBITRATIONLIB,"-framework DiskArbitration -framework CoreFoundation")
 398     fi
 399     if test "$ac_cv_header_CoreAudio_CoreAudio_h" = "yes" -a "$ac_cv_header_AudioUnit_AudioUnit_h" = "yes"
 400     then
 401         dnl CoreServices needed by AudioUnit
 402         AC_SUBST(COREAUDIO,"-framework CoreAudio -framework AudioUnit -framework CoreServices -framework AudioToolbox -framework CoreMIDI")
 403     fi
 404     case $host_cpu in
 405       *powerpc*)
 406         LDDLLFLAGS="$LDDLLFLAGS -read_only_relocs warning"  dnl FIXME
 407         ;;
 408     esac
 409     dnl Enable quartz driver on Mac OS X
 410     if test "$ac_cv_header_Carbon_Carbon_h" = "yes"
 411     then
 412         AC_SUBST(CARBONLIB,"-framework Carbon")
 413         QUARTZFILES='$(QUARTZFILES)'
 414     fi
 415     ;;
 416   *)
 417     DLLFLAGS="$DLLFLAGS -fPIC"
 418     DLLEXT=".so"
 419     AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
 420         [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-Bsymbolic],
 421                               ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
 422     if test "$ac_cv_c_dll_gnuelf" = "yes"
 423     then
 424       LDSHARED="\$(CC) -shared"
 425       LDDLLFLAGS="-shared -Wl,-Bsymbolic"
 426       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,confest.so.1],
 427                       [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"],
 428                       [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-h,confest.so.1],
 429                                        [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-h,%)"])])
 430
 431       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs], [LDDLLFLAGS="$LDDLLFLAGS,-z,defs"])
 432
 433       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
 434                       [LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"])
 435
 436       echo '{ global: *; };' >conftest.map
 437       WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
 438                       [LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"])
 439       rm -f conftest.map
 440
 441       WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
 442                       [AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])])
 443
 444       WINE_TRY_CFLAGS([-fPIC -Wl,--rpath,\$ORIGIN/../lib],
 445                       [LDRPATH_INSTALL="-Wl,--rpath,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 446                        LDRPATH_LOCAL="-Wl,--rpath,\\\$\$ORIGIN/\$(TOPOBJDIR)/libs/wine"],
 447           [WINE_TRY_CFLAGS([-fPIC -Wl,-R,\$ORIGIN/../lib],
 448                            [LDRPATH_INSTALL="-Wl,-R,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 449                             LDRPATH_LOCAL="-Wl,-R,\\\$\$ORIGIN/\$(TOPOBJDIR)/libs/wine"])])
 450
 451       WINE_TRY_CFLAGS([-Wl,--enable-new-dtags],
 452                       [LDRPATH_INSTALL="$LDRPATH_INSTALL -Wl,--enable-new-dtags"])
 453
 454       case $host_cpu in
 455         *i[[3456789]]86* | x86_64)
 456           WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
 457                           [LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400"])
 458           ;;
 459       esac
 460
 461     else
 462       AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
 463           [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
 464                                 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
 465       if test "$ac_cv_c_dll_unixware" = "yes"
 466       then
 467         LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
 468         LDDLLFLAGS="-Wl,-G,-B,symbolic"
 469
 470       else
 471         AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
 472           [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
 473         if test "$ac_cv_c_dll_hpux" = "yes"
 474         then
 475           LIBEXT="sl"
 476           DLLEXT=".sl"
 477           LDDLLFLAGS="-shared -fPIC"
 478           LDSHARED="\$(CC) -shared"
 479         fi
 480       fi
 481     fi
 482
 483     dnl Check for cross compiler to build test programs
 484     AC_SUBST(CROSSTEST,"")
 485     if test "$cross_compiling" = "no"
 486     then
 487       WINE_CHECK_MINGW_PROG(CROSSCC,gcc,false)
 488       WINE_CHECK_MINGW_PROG(DLLTOOL,dlltool,false)
 489       WINE_CHECK_MINGW_PROG(CROSSWINDRES,windres,false)
 490       WINE_CHECK_MINGW_PROG(MINGWAR,ar,false)
 491       if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
 492     fi
 493     ;;
 494 esac
 495
 496 if test "$LIBEXT" = "a"; then
 497   AC_MSG_ERROR(
 498 [could not find a way to build shared libraries.
 499 It is currently not possible to build Wine without shared library
 500 (.so) support to allow transparent switch between .so and .dll files.
 501 If you are using Linux, you will need a newer binutils.]
 502 )
 503 fi
 504
 505 dnl **** Check for X11 ****
 506
 507 if test "$have_x" = "yes"
 508 then
 509     XLIB="-lXext -lX11"
 510     ac_save_CPPFLAGS="$CPPFLAGS"
 511     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 512
 513     WINE_CHECK_SONAME(X11,XCreateWindow,,,[$X_LIBS $X_EXTRA_LIBS])
 514     WINE_CHECK_SONAME(Xext,XextCreateExtension,,,[$X_LIBS -lX11 $X_EXTRA_LIBS])
 515
 516     dnl *** All of the following tests require X11/Xlib.h
 517     AC_CHECK_HEADERS([X11/Xlib.h \
 518                       X11/XKBlib.h \
 519                       X11/Xutil.h \
 520                       X11/Xcursor/Xcursor.h \
 521                       X11/extensions/shape.h \
 522                       X11/extensions/XInput.h \
 523                       X11/extensions/XShm.h \
 524                       X11/extensions/Xcomposite.h \
 525                       X11/extensions/Xinerama.h \
 526                       X11/extensions/Xrandr.h \
 527                       X11/extensions/Xrender.h \
 528                       X11/extensions/xf86vmode.h],,,
 529 [#ifdef HAVE_X11_XLIB_H
 530 # include <X11/Xlib.h>
 531 #endif
 532 #ifdef HAVE_X11_XUTIL_H
 533 # include <X11/Xutil.h>
 534 #endif])
 535
 536         dnl *** Check for X keyboard extension
 537         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 538         then
 539               AC_CHECK_LIB(X11, XkbQueryExtension,
 540               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 541               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 542         fi
 543
 544         dnl *** Check for X cursor
 545         if test "$ac_cv_header_X11_Xcursor_Xcursor_h" = "yes"
 546         then
 547             WINE_CHECK_SONAME(Xcursor,XcursorImageLoadCursor,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 548         fi
 549
 550         dnl *** Check for X input extension
 551         if test "$ac_cv_header_X11_extensions_XInput_h" = "yes"
 552         then
 553             WINE_CHECK_SONAME(Xi,XOpenDevice,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 554         fi
 555
 556         dnl *** Check for X Shm extension
 557         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 558         then
 559               AC_CHECK_LIB(Xext, XShmQueryExtension,
 560               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 561               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 562         fi
 563         WINE_NOTICE_IF([test "$ac_cv_lib_Xext_XShmQueryExtension" != "yes"],[XShm development files not found.
 564 Wine will be built without XShm support. (winex11.drv)])
 565
 566         dnl *** Check for X shape extension
 567         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 568         then
 569               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 570               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 571               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 572         fi
 573         WINE_NOTICE_IF([test "$ac_cv_lib_Xext_XShapeQueryExtension" != "yes"],[XShape development files not found.
 574 Wine will be built without XShape support. (winex11.drv)])
 575
 576         dnl *** Check for XFree86 VMODE extension
 577         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 578         then
 579                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 580                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 581                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 582                   ],,
 583                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 584         fi
 585         WINE_NOTICE_IF([test "$ac_cv_lib_Xxf86vm_XF86VidModeQueryExtension" != "yes"],[Xxf86vm development files not found.
 586 Wine will be built without XF86 Vidmode support. (winex11.drv)])
 587
 588         dnl *** Check for Transform functions in Xrender
 589         if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes" -a "x$ac_cv_lib_soname_X11" != "x" -a "x$ac_cv_lib_soname_Xext" != "x"
 590         then
 591             WINE_CHECK_SONAME(Xrender,XRenderQueryExtension,
 592               [AC_CHECK_LIB(Xrender,XRenderSetPictureTransform,
 593                 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
 594                  [Define if Xrender has the XRenderSetPictureTransform function])],,
 595                 [$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])],,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 596
 597         fi
 598         WINE_NOTICE_IF([test "x$ac_cv_lib_soname_Xrender" = "x"],[XRender development files not found.
 599 Wine will be built without XRender support. (winex11.drv)])
 600
 601         dnl *** Check for X RandR extension
 602         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes" -a "x$ac_cv_lib_soname_Xrender" != "x"
 603         then
 604                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
 605 #include <X11/extensions/Xrandr.h>]], [[static typeof(XRRSetScreenConfigAndRate) * func;]])],
 606                   [WINE_CHECK_SONAME(Xrandr,XRRQueryExtension,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 607         fi
 608         WINE_NOTICE_IF([test "x$ac_cv_lib_soname_Xrandr" = "x"],[XRandr development files not found.
 609 Wine will be built without XRandr support. (winex11.drv)])
 610
 611         dnl *** Check for Xinerama extension
 612         if test "$ac_cv_header_X11_extensions_Xinerama_h" = "yes"
 613         then
 614                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
 615 #include <X11/extensions/Xinerama.h>]], [[static typeof(XineramaQueryScreens) * func;]])],
 616                   [WINE_CHECK_SONAME(Xinerama,XineramaQueryScreens,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 617         fi
 618         WINE_NOTICE_IF([test "x$ac_cv_lib_soname_Xinerama" = "x"],[Xinerama development files not found.
 619 Wine will be built without Xinerama support. (winex11.drv)])
 620
 621         dnl *** Check for X Composite extension
 622         if test "$ac_cv_header_X11_extensions_Xcomposite_h" = "yes"
 623         then
 624             WINE_CHECK_SONAME(Xcomposite,XCompositeRedirectWindow,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 625         fi
 626         WINE_NOTICE_IF([test "x$ac_cv_lib_soname_Xcomposite" = "x"],[XComposite development files not found.
 627 Wine will be built without XComposite support. (winex11.drv)])
 628
 629     dnl *** End of X11/Xlib.h check
 630
 631     dnl Check for the presence of OpenGL
 632     if test "x$with_opengl" != "xno"
 633     then
 634         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h GL/glu.h,,,
 635 [#ifdef HAVE_GL_GLX_H
 636 # include <GL/glx.h>
 637 #endif])
 638         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 639         then
 640             dnl Check for some problems due to old Mesa versions
 641             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_header_version_OK,
 642               AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GL/gl.h>]], [[GLenum test = GL_UNSIGNED_SHORT_5_6_5;]])],
 643                 [wine_cv_opengl_header_version_OK="yes"],
 644                 [wine_cv_opengl_header_version_OK="no"]))
 645
 646             if test "$wine_cv_opengl_header_version_OK" = "yes"
 647             then
 648                 dnl Check for the presence of the library
 649                 WINE_CHECK_SONAME(GL,glXCreateContext,
 650                              [OPENGL_LIBS="-lGL"
 651                              OPENGLFILES='$(OPENGLFILES)'
 652                              AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])],
 653                              [if test -f /usr/X11R6/lib/libGL.a
 654                               then
 655                                   WINE_WARNING([/usr/X11R6/lib/libGL.a is present on your system.
 656 This probably prevents linking to OpenGL. Try deleting the file and restarting configure.])
 657                               else
 658                                   WINE_WARNING([No OpenGL library found on this system.
 659 Wine will be build without OpenGL or Direct3D support.])
 660                               fi],
 661                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 662
 663                 dnl Check for GLU32 library.
 664                 AC_CHECK_LIB(GLU,gluLookAt,
 665                              [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
 666                              GLU32FILES='$(GLU32FILES)']
 667                              ,,
 668                              $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 669              else
 670                  WINE_WARNING([Old Mesa headers detected. Consider upgrading your Mesa libraries (http://www.mesa3d.org/).
 671 Wine will be build without OpenGL or Direct3D support.])
 672              fi
 673          else
 674              WINE_WARNING([OpenGL development headers not found.
 675 Wine will be build without OpenGL or Direct3D support.])
 676          fi
 677     fi
 678
 679     dnl **** Check for NAS ****
 680     AC_SUBST(NASLIBS,"")
 681     AC_CHECK_HEADERS(audio/audiolib.h,
 682          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
 683           AC_CHECK_LIB(audio,AuCreateFlow,
 684                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
 685                         AC_CHECK_LIB(Xau,XauGetBestAuthByAddr,
 686                           [NASLIBS="-lXau -laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],
 687                           [NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],
 688                           [$X_LIBS])
 689                        ],,
 690                        [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 691
 692     CPPFLAGS="$ac_save_CPPFLAGS"
 693     XFILES='$(XFILES)'
 694 else
 695     XLIB=""
 696     X_CFLAGS=""
 697     X_LIBS=""
 698     WINE_WARNING([X development files not found. Wine will be built
 699 without X support, which probably isn't what you want. You will need to install
 700 development packages of Xlib/Xfree86 at the very least.])
 701 fi
 702
 703 dnl **** Check for libxml2 ****
 704
 705 AC_SUBST(XML2LIBS,"")
 706 AC_SUBST(XML2INCL,"")
 707 AC_SUBST(XSLTLIBS,"")
 708 AC_SUBST(XSLTINCL,"")
 709 ac_save_CPPFLAGS="$CPPFLAGS"
 710 if test "$PKG_CONFIG" != "false"
 711 then
 712     ac_xml_libs="`$PKG_CONFIG --libs libxml-2.0 2>/dev/null`"
 713     ac_xml_cflags="`$PKG_CONFIG --cflags libxml-2.0 2>/dev/null`"
 714 else
 715     ac_xml_libs="`xml2-config --libs 2>/dev/null`"
 716     ac_xml_cflags="`xml2-config --cflags  2>/dev/null`"
 717 fi
 718 CPPFLAGS="$CPPFLAGS $ac_xml_cflags"
 719 AC_CHECK_HEADERS(libxml/parser.h,
 720         [AC_CHECK_LIB(xml2, xmlParseMemory,
 721             [AC_DEFINE(HAVE_LIBXML2, 1, [Define if you have the libxml2 library])
 722              XML2LIBS="$ac_xml_libs"
 723              XML2INCL="$ac_xml_cflags"],,$ac_xml_libs)
 724          AC_CHECK_LIB(xml2, xmlReadMemory,
 725             [AC_DEFINE(HAVE_XMLREADMEMORY,1,[Define if libxml2 has the xmlReadMemory function])],,$ac_xml_libs)
 726          AC_CHECK_LIB(xml2, xmlNewDocPI,
 727             [AC_DEFINE(HAVE_XMLNEWDOCPI,1,[Define if libxml2 has the xmlNewDocPI function])],,$ac_xml_libs)
 728     ])
 729 CPPFLAGS="$ac_save_CPPFLAGS"
 730 WINE_NOTICE_IF([test "$ac_cv_lib_xml2_xmlParseMemory" != "yes"],[libxml2 development files not found.
 731 Wine will be built without XML support. (msxml.dll)])
 732
 733 if test "$PKG_CONFIG" != "false"
 734 then
 735     ac_xslt_libs="`$PKG_CONFIG --libs libxslt 2>/dev/null`"
 736     ac_xslt_cflags="`$PKG_CONFIG --cflags libxslt 2>/dev/null`"
 737 else
 738     ac_xslt_libs="`xslt-config --libs 2>/dev/null`"
 739     ac_xslt_cflags="`xslt-config --cflags 2>/dev/null`"
 740 fi
 741 CPPFLAGS="$CPPFLAGS $ac_xslt_cflags"
 742 AC_CHECK_HEADERS([libxslt/pattern.h libxslt/transform.h],
 743         [AC_CHECK_LIB(xslt, xsltCompilePattern,
 744             [AC_DEFINE(HAVE_LIBXSLT, 1, [Define if you have the libxslt library])
 745              XSLTLIBS="$ac_xslt_libs"
 746              XSLTINCL="$ac_xslt_cflags"],,$ac_xslt_libs)
 747         ],,
 748 [#ifdef HAVE_LIBXSLT_PATTERN_H
 749 # include <libxslt/pattern.h>
 750 #endif])
 751 CPPFLAGS="$ac_save_CPPFLAGS"
 752 WINE_NOTICE_IF([test "$ac_cv_lib_xslt_xsltCompilePattern" != "yes"],[libxslt development files not found.
 753 Wine will be built without xslt support. (msxml.dll)])
 754
 755 dnl **** Check for libhal ****
 756 AC_SUBST(HALINCL,"")
 757 if test "$PKG_CONFIG" != "false"
 758 then
 759     ac_save_CPPFLAGS="$CPPFLAGS"
 760     ac_hal_libs="`$PKG_CONFIG --libs hal 2>/dev/null`"
 761     ac_hal_cflags="`$PKG_CONFIG --cflags hal 2>/dev/null`"
 762     CPPFLAGS="$CPPFLAGS $ac_hal_cflags"
 763     AC_CHECK_HEADERS([dbus/dbus.h hal/libhal.h])
 764     if test "$ac_cv_header_dbus_dbus_h" = "yes" -a "$ac_cv_header_hal_libhal_h" = "yes"
 765     then
 766         AC_CHECK_LIB(dbus-1, dbus_connection_close,
 767           [WINE_CHECK_SONAME(hal, libhal_ctx_new,
 768             [HALINCL="$ac_hal_cflags"],,[$ac_hal_libs])],,[$ac_hal_libs])
 769     fi
 770     CPPFLAGS="$ac_save_CPPFLAGS"
 771 fi
 772 WINE_NOTICE_IF([test "x$ac_cv_lib_soname_hal" = "x"],[libhal development files not found.
 773 Wine will be built without dynamic device support. (explorer.exe)])
 774
 775 dnl **** Check which curses lib to use ***
 776 CURSESLIBS=""
 777 if test "$ac_cv_header_ncurses_h" = "yes"
 778 then
 779     WINE_CHECK_SONAME(ncurses,waddch,[CURSESLIBS="-lncurses"])
 780 elif test "$ac_cv_header_curses_h" = "yes"
 781 then
 782     WINE_CHECK_SONAME(curses,waddch,[CURSESLIBS="-lcurses"])
 783 fi
 784 ac_save_LIBS="$LIBS"
 785 LIBS="$LIBS $CURSESLIBS"
 786 AC_CHECK_FUNCS(mousemask)
 787 LIBS="$ac_save_LIBS"
 788 WINE_NOTICE_IF([test "x$ac_cv_lib_soname_curses$ac_cv_lib_soname_ncurses" = "x"],[lib(n)curses development files not found.
 789 Wine will be built without (n)curses support. (wineconsole.exe)])
 790
 791 dnl **** Check for SANE ****
 792 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
 793 if test "$sane_devel" != "no"
 794 then
 795     ac_sane_incl="`$sane_devel --cflags`"
 796     ac_save_CPPFLAGS="$CPPFLAGS"
 797     CPPFLAGS="$CPPFLAGS $ac_sane_incl"
 798     AC_CHECK_HEADER(sane/sane.h,
 799         [WINE_CHECK_SONAME(sane,sane_init,[AC_SUBST(SANEINCL,"$ac_sane_incl")])])
 800     CPPFLAGS="$ac_save_CPPFLAGS"
 801 fi
 802 WINE_NOTICE_IF([test "x$ac_cv_lib_soname_sane" = "x"],[libsane development files not found.
 803 Wine will be built without scanner support. (sane.ds/twain_32.dll)])
 804
 805 dnl **** Check for libgphoto2 ****
 806 AC_CHECK_PROG(gphoto2_devel,gphoto2-config,gphoto2-config,no)
 807 AC_CHECK_PROG(gphoto2port_devel,gphoto2-port-config,gphoto2-port-config,no)
 808 if test "$gphoto2_devel" != "no" -a "$gphoto2port_devel" != "no"
 809 then
 810     ac_gphoto2_incl="`$gphoto2_devel --cflags` `$gphoto2port_devel --cflags`"
 811     ac_gphoto2_libs=""
 812     for i in `$gphoto2_devel --libs` `$gphoto2port_devel --libs`
 813     do
 814       case "$i" in
 815         -L/usr/lib|-L/usr/lib64) ;;
 816         -L*|-l*) ac_gphoto2_libs="$ac_gphoto2_libs $i";;
 817       esac
 818     done
 819     ac_save_CPPFLAGS="$CPPFLAGS"
 820     CPPFLAGS="$CPPFLAGS $ac_gphoto2_incl"
 821     AC_CHECK_HEADER(gphoto2-camera.h,
 822                     [AC_CHECK_LIB(gphoto2,gp_camera_new,
 823                                   [AC_DEFINE(HAVE_GPHOTO2, 1, [Define if we have libgphoto2 development environment])
 824                                    AC_SUBST(GPHOTO2LIBS,"$ac_gphoto2_libs")
 825                                    AC_SUBST(GPHOTO2INCL,"$ac_gphoto2_incl")],,
 826                                   [$GPHOTO2LIBS])])
 827     CPPFLAGS="$ac_save_CPPFLAGS"
 828 fi
 829 WINE_NOTICE_IF([test "$ac_cv_lib_gphoto2_gp_camera_new" != "yes"],[libgphoto2 development files not found.
 830 Wine will be built without Digital Camera support. (gphoto2.ds/twain_32.dll)])
 831
 832
 833 dnl **** Check for resolver library ***
 834 AC_SUBST(RESOLVLIBS,"")
 835 if test "$ac_cv_header_resolv_h" = "yes"
 836 then
 837     AC_CHECK_LIB(resolv, res_query,
 838         [AC_DEFINE(HAVE_RESOLV, 1, [Define if you have the resolver library and header])
 839          RESOLVLIBS="-lresolv"])
 840 fi
 841
 842 dnl **** Check for LittleCMS ***
 843 AC_SUBST(LCMSLIBS,"")
 844 if test "$ac_cv_header_lcms_h" = "yes" -o "$ac_cv_header_lcms_lcms_h" = "yes"
 845 then
 846     AC_CHECK_LIB(lcms, cmsOpenProfileFromFile,
 847         [AC_DEFINE(HAVE_LCMS, 1, [Define if you have the LittleCMS development environment])
 848          LCMSLIBS="-llcms"])
 849 fi
 850 WINE_NOTICE_IF([test "$ac_cv_lib_lcms_cmsOpenProfileFromFile" != "yes"],[liblcms development files not found.
 851 Wine will be built without Color Management support. (mscms.dll)])
 852
 853 dnl **** Check for OpenLDAP ***
 854 AC_SUBST(LDAPLIBS,"")
 855 if test "$ac_cv_header_ldap_h" = "yes" -a "$ac_cv_header_lber_h" = "yes"
 856 then
 857     AC_CHECK_LIB(ldap_r, ldap_initialize,
 858         [AC_CHECK_LIB(lber, ber_init,
 859             [AC_DEFINE(HAVE_LDAP, 1, [Define if you have the OpenLDAP development environment])
 860              LDAPLIBS="-lldap_r -llber"],,
 861              [$LIBPTHREAD])],,
 862              [$LIBPTHREAD])
 863     WINE_CHECK_LIB_FUNCS(\
 864         ldap_count_references \
 865         ldap_first_reference \
 866         ldap_next_reference \
 867         ldap_parse_reference,
 868         [$LDAPLIBS $LIBPTHREAD])
 869 fi
 870 WINE_NOTICE_IF([test "x$LDAPLIBS" = "x"],[libldap (OpenLDAP) development files not found.
 871 Wine will be built without LDAP support. (wldap32.dll)])
 872
 873 dnl **** Check for FreeType 2 ****
 874 AC_CHECK_PROGS(ft_devel,[freetype-config freetype2-config],false)
 875 if test "$ft_devel" != "false"
 876 then
 877     ac_freetype_libs=`$ft_devel --libs`
 878     ac_freetype_incl=`$ft_devel --cflags`
 879     WINE_CHECK_SONAME(freetype,FT_Init_FreeType,[ft_lib=yes],[ft_lib=no],[$ac_freetype_libs])
 880     if test "$ft_lib" = "yes"
 881     then
 882         ac_save_CPPFLAGS="$CPPFLAGS"
 883         CPPFLAGS="$ac_freetype_incl $CPPFLAGS"
 884         AC_CHECK_HEADERS(ft2build.h \
 885                          freetype/freetype.h \
 886                          freetype/ftglyph.h \
 887                          freetype/fttypes.h \
 888                          freetype/tttables.h \
 889                          freetype/ftnames.h \
 890                          freetype/ftsnames.h \
 891                          freetype/ttnameid.h \
 892                          freetype/ftoutln.h \
 893                          freetype/ftwinfnt.h \
 894                          freetype/ftmodapi.h \
 895                          freetype/internal/sfnt.h,,,
 896                          [#if HAVE_FT2BUILD_H
 897                           #include <ft2build.h>
 898                           #endif])
 899         AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <ft2build.h>
 900                     #include <freetype/fttrigon.h>]])],[AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
 901           [Define if you have the <freetype/fttrigon.h> header file.])
 902                     wine_cv_fttrigon=yes],[wine_cv_fttrigon=no])
 903         AC_CHECK_TYPES(FT_TrueTypeEngineType,,,[#include <freetype/ftmodapi.h>])
 904         ac_save_CFLAGS="$CFLAGS"
 905         CFLAGS="$CFLAGS $ac_freetype_libs"
 906         AC_CHECK_FUNCS(FT_Load_Sfnt_Table)
 907         CFLAGS="$ac_save_CFLAGS"
 908         CPPFLAGS="$ac_save_CPPFLAGS"
 909         dnl Check that we have at least freetype/freetype.h
 910         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
 911         then
 912             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
 913             AC_SUBST(FREETYPELIBS,"$ac_freetype_libs")
 914             AC_SUBST(FREETYPEINCL,"$ac_freetype_incl")
 915         fi
 916     fi
 917 fi
 918
 919 dnl Only build the fonts dir if we have both freetype and fontforge
 920 if test "$FONTFORGE" = "false"
 921 then
 922     WINE_WARNING([FontForge is missing.
 923 Fonts will not be built. Dialog text may be invisible or unaligned.])
 924 elif test "x$FREETYPELIBS" = "x"
 925 then
 926     WINE_WARNING([FreeType development files not found.
 927 Fonts will not be built. Dialog text may be invisible or unaligned.])
 928 else
 929   AC_SUBST(FONTSSUBDIRS,"fonts")
 930 fi
 931
 932 dnl **** Check for parport (currently Linux only) ****
 933 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
 934  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <linux/ppdev.h>]], [[ioctl (1,PPCLAIM,0)]])],
 935     [ac_cv_c_ppdev="yes"],[ac_cv_c_ppdev="no"]))
 936 if test "$ac_cv_c_ppdev" = "yes"
 937 then
 938     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
 939 fi
 940
 941 dnl **** Check for va_copy ****
 942 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
 943  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>]], [[va_list ap1, ap2; va_copy(ap1,ap2);]])],
 944     [ac_cv_c_va_copy="yes"],[ac_cv_c_va_copy="no"])
 945  )
 946 if test "$ac_cv_c_va_copy" = "yes"
 947 then
 948     AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
 949 fi
 950 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
 951  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>]], [[va_list ap1, ap2; __va_copy(ap1,ap2);]])],
 952     [ac_cv_c___va_copy="yes"],[ac_cv_c___va_copy="no"])
 953  )
 954 if test "$ac_cv_c___va_copy" = "yes"
 955 then
 956     AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
 957 fi
 958
 959 dnl **** Check for sigsetjmp ****
 960 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
 961  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <setjmp.h>]], [[sigjmp_buf buf;
 962     sigsetjmp( buf, 1 );
 963     siglongjmp( buf, 1 );]])],[ac_cv_c_sigsetjmp="yes"],[ac_cv_c_sigsetjmp="no"])
 964  )
 965 if test "$ac_cv_c_sigsetjmp" = "yes"
 966 then
 967     AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
 968 fi
 969
 970 dnl **** Check for pthread_rwlock_t ****
 971 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
 972 #include <pthread.h>])
 973
 974 dnl **** Check for pthread functions ****
 975 WINE_CHECK_LIB_FUNCS(\
 976         pthread_attr_get_np \
 977         pthread_getattr_np \
 978         pthread_get_stackaddr_np \
 979         pthread_get_stacksize_np,
 980         [$LIBPTHREAD])
 981
 982 dnl **** Check for EsounD ****
 983 AC_PATH_PROG(ESDCONFIG, esd-config)
 984 if test x$ESDCONFIG != x -a x$ESDCONFIG != x'"$ESDCONFIG"';
 985 then
 986     ESD_CFLAGS=""
 987     for i in `$ESDCONFIG --cflags`
 988     do
 989       case "$i" in
 990         -I*) ESD_CFLAGS="$ESD_CFLAGS $i";;
 991       esac
 992     done
 993     ESD_LIBS=`$ESDCONFIG --libs`
 994     save_CFLAGS="$CFLAGS"
 995     CFLAGS="$CFLAGS $ESD_CFLAGS"
 996     AC_CHECK_LIB(esd,esd_open_sound,
 997         [AC_SUBST(ESDLIBS, $ESD_LIBS)
 998          AC_SUBST(ESDINCL, $ESD_CFLAGS)
 999          AC_DEFINE(HAVE_ESD, 1, [Define if you have EsounD sound server])])
1000     CFLAGS="$save_CFLAGS"
1001 fi
1002
1003 dnl **** Check for ALSA 1.x ****
1004 AC_SUBST(ALSALIBS,"")
1005 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
1006 then
1007     AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
1008         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef HAVE_ALSA_ASOUNDLIB_H
1009 #include <alsa/asoundlib.h>
1010 #elif defined(HAVE_SYS_ASOUNDLIB_H)
1011 #include <sys/asoundlib.h>
1012 #endif]], [[int ret = snd_pcm_hw_params_get_access(NULL, NULL)]])],
1013                         [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
1014                          ALSALIBS="-lasound"],[])])
1015 fi
1016
1017 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
1018 AC_SUBST(AUDIOIOLIBS,"")
1019 if test "$ac_cv_header_libaudioio_h" = "yes"
1020 then
1021     AC_CHECK_LIB(audioio,AudioIOGetVersion,
1022                   [AUDIOIOLIBS="-laudioio"
1023                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])
1024 fi
1025
1026 dnl **** Check for capi4linux ****
1027
1028 if test "$ac_cv_header_capi20_h" = "yes" -a "$ac_cv_header_linux_capi_h" = "yes"
1029 then
1030     WINE_CHECK_SONAME(capi20,capi20_register)
1031 fi
1032 WINE_NOTICE_IF([test "x$ac_cv_lib_soname_capi20" = "x"],[libcapi20 development files not found.
1033 Wine will be built without ISDN support. (capi2032.dll)])
1034
1035 dnl **** Check for cups ****
1036 if test "$ac_cv_header_cups_cups_h" = "yes"
1037 then
1038     WINE_CHECK_SONAME(cups,cupsGetDefault)
1039 fi
1040 WINE_NOTICE_IF([test "x$ac_cv_lib_soname_cups" = "x"],[libcups development files not found.
1041 Wine will be built without CUPS support.])
1042
1043 dnl **** Check for jack ****
1044 if test "$ac_cv_header_jack_jack_h" = "yes"
1045 then
1046     WINE_CHECK_SONAME(jack,jack_client_new)
1047 fi
1048
1049 dnl **** Check for fontconfig ****
1050 if test "$ac_cv_header_fontconfig_fontconfig_h" = "yes"
1051 then
1052     WINE_CHECK_SONAME(fontconfig,FcInit)
1053 elif test -n "$X_CFLAGS"
1054 then
1055     dnl fontconfig is in the X directory on Mac OS X
1056     ac_save_CPPFLAGS="$CPPFLAGS"
1057     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
1058     $as_unset ac_cv_header_fontconfig_fontconfig_h
1059     AC_CHECK_HEADERS([fontconfig/fontconfig.h])
1060     CPPFLAGS="$ac_save_CPPFLAGS"
1061     if test "$ac_cv_header_fontconfig_fontconfig_h" = "yes"
1062     then
1063         AC_SUBST(FONTCONFIGINCL,"$X_CFLAGS")
1064         WINE_CHECK_SONAME(fontconfig,FcInit,,,[$X_LIBS])
1065     fi
1066 fi
1067 WINE_NOTICE_IF([test "x$ac_cv_lib_soname_fontconfig" = "x"],[fontconfig development files not found.
1068 Wine will be built without fontconfig support.])
1069
1070 dnl **** Check for SSL ****
1071 if test "$ac_cv_header_openssl_err_h" = "yes" -a "$ac_cv_header_openssl_ssl_h" = "yes"
1072 then
1073     WINE_CHECK_SONAME(ssl,SSL_library_init)
1074     WINE_CHECK_SONAME(crypto,BIO_new_socket)
1075 fi
1076 WINE_NOTICE_IF([test "x$ac_cv_lib_soname_ssl" = "x"],[OpenSSL development files not found.
1077 Wine will be built without SSL support. (wininet.dll)])
1078
1079 dnl **** Check for libjpeg ****
1080 if test "$ac_cv_header_jpeglib_h" = "yes"
1081 then
1082     WINE_CHECK_SONAME(jpeg,jpeg_start_decompress)
1083 fi
1084 WINE_NOTICE_IF([test "x$ac_cv_lib_soname_jpeg" = "x"],[libjpeg development files not found.
1085 Wine will be built without JPEG support. (oleaut32.dll)])
1086
1087 dnl **** Check for libpng ****
1088 if test "$ac_cv_header_png_h" = "yes"
1089 then
1090     WINE_CHECK_SONAME(png,png_create_read_struct,,,,[[libpng[[0-9]]*]])
1091 fi
1092 WINE_NOTICE_IF([test "x$ac_cv_lib_soname_png" = "x"],[libpng development files not found.
1093 Wine will be built without PNG support. (oleaut32.dll)])
1094
1095 dnl **** Check for any sound system ****
1096 WINE_WARNING_IF([test "x$ALSALIBS$AUDIOIOLIBS$COREAUDIO$NASLIBS$ESD_LIBS$ac_cv_lib_soname_jack" = "x" -a \
1097                  "$ac_cv_header_sys_soundcard_h" != "yes" -a \
1098                  "$ac_cv_header_machine_soundcard_h" != "yes" -a \
1099                  "$ac_cv_header_soundcard_h" != "yes"],
1100 [No sound system was found. Windows applications will be silent.])
1101
1102 dnl **** Check for gcc specific options ****
1103
1104 AC_SUBST(EXTRACFLAGS,"")
1105 if test "x${GCC}" = "xyes"
1106 then
1107   EXTRACFLAGS="-Wall -pipe"
1108
1109   dnl Check for strength-reduce bug
1110   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
1111                   AC_RUN_IFELSE([AC_LANG_PROGRAM([[int L[[4]] = {0,1,2,3};]],
1112 [[static int Array[[3]];
1113   unsigned int B = 3;
1114   int i;
1115   for(i=0; i<B; i++) Array[[i]] = i - 3;
1116   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
1117   L[[i]] = 4;
1118   exit( Array[[1]] != -2 || L[[2]] != 3)]])],
1119     [ac_cv_c_gcc_strength_bug="no"],[ac_cv_c_gcc_strength_bug="yes"],[ac_cv_c_gcc_strength_bug="yes"]) )
1120   if test "$ac_cv_c_gcc_strength_bug" = "yes"
1121   then
1122     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
1123   fi
1124
1125   dnl Check for some compiler flags
1126
1127   WINE_TRY_CFLAGS([-fshort-wchar],
1128                   [AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar",
1129                              [Specifies the compiler flag that forces a short wchar_t])])
1130   WINE_TRY_CFLAGS([-fno-strict-aliasing])
1131   WINE_TRY_CFLAGS([-Wdeclaration-after-statement])
1132   WINE_TRY_CFLAGS([-Wwrite-strings])
1133
1134   dnl Check for noisy string.h
1135   saved_CFLAGS="$CFLAGS"
1136   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
1137   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
1138       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string.h>]], [[]])],[ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
1139   CFLAGS="$saved_CFLAGS"
1140   if test "$ac_cv_c_string_h_warnings" = "no"
1141   then
1142     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
1143   fi
1144
1145   AC_SUBST(BUILTINFLAG,"")
1146   saved_CFLAGS="$CFLAGS"
1147   CFLAGS="$CFLAGS -Werror"
1148   AC_CACHE_CHECK([for builtin wchar inlines], ac_cv_c_builtin_wchar_ctype,
1149       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[int iswlower(unsigned short);]])],[ac_cv_c_builtin_wchar_ctype=no],[ac_cv_c_builtin_wchar_ctype=yes]))
1150   CFLAGS="$saved_CFLAGS"
1151   if test "$ac_cv_c_builtin_wchar_ctype" = "yes"
1152   then
1153     BUILTINFLAG="-fno-builtin"
1154   fi
1155 fi
1156
1157 dnl **** Check how to define a function in assembly code ****
1158
1159 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
1160   WINE_TRY_ASM_LINK(
1161       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
1162       ac_cv_asm_func_def=".def",
1163     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
1164       ac_cv_asm_func_def=".type @function",
1165     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
1166       ac_cv_asm_func_def=".type 2",
1167       ac_cv_asm_func_def="unknown")])]))
1168
1169 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
1170 case "$ac_cv_asm_func_def" in
1171   ".def")
1172      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
1173   ".type @function")
1174      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
1175   ".type 2")
1176      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
1177   *)
1178      AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
1179 esac
1180
1181 dnl **** Check for underscore on external symbols ****
1182
1183 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
1184     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
1185                       [extern int ac_test;],
1186                       [if (ac_test) return 1],
1187                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
1188
1189 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
1190 if test "$ac_cv_c_extern_prefix" = "yes"
1191 then
1192   AC_DEFINE([__ASM_NAME(name)], ["_" name])
1193 else
1194   AC_DEFINE([__ASM_NAME(name)], [name])
1195 fi
1196
1197 dnl **** Platform-specific checks ****
1198
1199 AC_SUBST(LDPATH,"")
1200 case $build_os in
1201   cygwin*|mingw32*)
1202     LDPATH="PATH=\"\$(TOOLSDIR)/libs/wine:\$\$PATH\""
1203     ;;
1204   darwin*|macosx*)
1205     ;;
1206   linux*|solaris*)  dnl FIXME: What other platforms support $ORIGIN?
1207     if test -z "$LDRPATH_LOCAL"
1208     then
1209       LDPATH="LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\""
1210     fi
1211     ;;
1212   *)
1213     LDPATH="LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\""
1214     ;;
1215 esac
1216
1217 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1218 case $host_os in
1219   mingw32*)
1220     AC_SUBST(CRTLIBS,"-lmsvcrt")
1221     AC_SUBST(SOCKETLIBS,"-lws2_32")
1222     ;;
1223 esac
1224
1225 AC_SUBST(MAIN_BINARY,"wine-pthread")  dnl Default value
1226 case $host_cpu in
1227   *i[[3456789]]86*)
1228     case $host_os in
1229       linux* | k*bsd*-gnu)
1230         AC_SUBST(MAIN_BINARY,"wine-glibc")
1231         AC_SUBST(EXTRA_BINARIES,"wine-kthread wine-pthread wine-preloader") ;;
1232       freebsd*)
1233         AC_SUBST(MAIN_BINARY,"wine-freebsd")
1234         AC_SUBST(EXTRA_BINARIES,"wine-pthread") ;;
1235     esac
1236     ;;
1237 esac
1238
1239 dnl **** Check for functions ****
1240
1241 AC_CHECK_FUNCS(\
1242         _pclose \
1243         _popen \
1244         _snprintf \
1245         _spawnvp \
1246         _strdup \
1247         _stricmp \
1248         _strnicmp \
1249         _vsnprintf \
1250         asctime_r \
1251         chsize \
1252         clone \
1253         dlopen \
1254         epoll_create \
1255         ffs \
1256         finite \
1257         fork \
1258         fpclass \
1259         fstatfs \
1260         fstatvfs \
1261         ftruncate \
1262         futimes \
1263         futimesat \
1264         getdirentries \
1265         getopt_long \
1266         getpagesize \
1267         getpwuid \
1268         gettid \
1269         gettimeofday \
1270         getuid \
1271         inet_pton \
1272         kqueue \
1273         lstat \
1274         memmove \
1275         mmap \
1276         pclose \
1277         poll \
1278         popen \
1279         prctl \
1280         pread \
1281         pwrite \
1282         readlink \
1283         rfork \
1284         sched_yield \
1285         select \
1286         setrlimit \
1287         settimeofday \
1288         sigaltstack \
1289         sigprocmask \
1290         snprintf \
1291         spawnvp \
1292         statfs \
1293         statvfs \
1294         strcasecmp \
1295         strdup \
1296         strerror \
1297         strncasecmp \
1298         strtold \
1299         tcgetattr \
1300         thr_kill2 \
1301         timegm \
1302         usleep \
1303         vsnprintf \
1304         wait4 \
1305         waitpid \
1306 )
1307
1308 dnl Check for -ldl
1309 if test "$ac_cv_func_dlopen" = no
1310 then
1311     AC_CHECK_LIB(dl,dlopen,[AC_DEFINE(HAVE_DLOPEN,1) AC_SUBST(LIBDL,"-ldl")])
1312 fi
1313 WINE_CHECK_LIB_FUNCS(dladdr,[$LIBDL])
1314
1315 dnl Check for -lpoll for Mac OS X/Darwin
1316 if test "$ac_cv_func_poll" = no
1317 then
1318     AC_CHECK_LIB(poll,poll,[AC_DEFINE(HAVE_POLL,1) AC_SUBST(LIBPOLL,"-lpoll")])
1319 fi
1320
1321 dnl Check for -lnsl for Solaris
1322 AC_SEARCH_LIBS(gethostbyname, nsl)
1323
1324 dnl Check for -lsocket for Solaris
1325 AC_SEARCH_LIBS(connect, socket)
1326
1327 dnl Check for -lresolv for Solaris
1328 AC_SEARCH_LIBS(inet_aton, resolv)
1329
1330 dnl **** Check for functions which may rely on -lsocket on Solaris.
1331 AC_CHECK_FUNCS(\
1332         getaddrinfo \
1333         getnameinfo \
1334         getnetbyname \
1335         getprotobyname \
1336         getprotobynumber \
1337         getservbyport \
1338         inet_network \
1339         sendmsg \
1340 )
1341
1342 dnl **** Check for types ****
1343
1344 AC_C_CONST
1345 AC_C_INLINE
1346 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1347 AC_CHECK_TYPES([sigset_t],,,[#include <signal.h>])
1348 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
1349
1350 AC_CHECK_MEMBERS([struct ff_effect.direction],,,
1351 [#ifdef HAVE_LINUX_INPUT_H
1352 #include <linux/input.h>
1353 #endif])
1354
1355 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
1356                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>]], [[sigset_t set; sigaddset(&set,SIGTERM);]])],[wine_cv_have_sigaddset=yes],[wine_cv_have_sigaddset=no]))
1357 if test "$wine_cv_have_sigaddset" = "yes"
1358 then
1359   AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
1360 fi
1361
1362
1363 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1364         wine_cv_linux_gethostbyname_r_6,
1365         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],[[
1366     char *name=0;
1367     struct hostent he;
1368     struct hostent *result;
1369     char *buf=0;
1370     int bufsize=0;
1371     int res,errnr;
1372     char *addr=0;
1373     int addrlen=0;
1374     int addrtype=0;
1375     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1376     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1377     ]])],[wine_cv_linux_gethostbyname_r_6=yes],[wine_cv_linux_gethostbyname_r_6=no
1378         ])
1379    )
1380    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1381    then
1382       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1383                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1384    fi
1385
1386 if test "$ac_cv_header_linux_joystick_h" = "yes"
1387 then
1388    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1389         wine_cv_linux_joystick_22_api,
1390         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1391         #include <sys/ioctl.h>
1392         #include <sys/types.h>
1393         #include <linux/joystick.h>
1394
1395         struct js_event blub;
1396         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1397         #error "no 2.2 header"
1398         #endif
1399         ]], [[/*empty*/]])],[wine_cv_linux_joystick_22_api=yes],[wine_cv_linux_joystick_22_api=no])
1400    )
1401    if test "$wine_cv_linux_joystick_22_api" = "yes"
1402    then
1403       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1404                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1405    fi
1406 fi
1407
1408 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1409
1410 dnl Check for statfs members
1411 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1412 [#include <sys/types.h>
1413 #ifdef HAVE_SYS_PARAM_H
1414 # include <sys/param.h>
1415 #endif
1416 #ifdef HAVE_SYS_MOUNT_H
1417 # include <sys/mount.h>
1418 #endif
1419 #ifdef HAVE_SYS_VFS_H
1420 # include <sys/vfs.h>
1421 #endif
1422 #ifdef HAVE_SYS_STATFS_H
1423 # include <sys/statfs.h>
1424 #endif])
1425
1426 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1427 [#ifdef HAVE_SYS_STATVFS_H
1428 #include <sys/statvfs.h>
1429 #endif])
1430
1431 dnl Check for socket structure members
1432 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1433 [#include <sys/types.h>
1434 #ifdef HAVE_SYS_SOCKET_H
1435 # include <sys/socket.h>
1436 #endif
1437 #ifdef HAVE_SYS_UN_H
1438 # include <sys/un.h>
1439 #endif])
1440
1441 dnl Check for scsireq_t and sg_io_hdr_t members
1442 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
1443 [#include <sys/types.h>
1444 #ifdef HAVE_SCSI_SG_H
1445 #include <scsi/sg.h>
1446 #endif])
1447
1448 dnl Check for siginfo_t members
1449 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1450
1451 dnl Check for struct mtget members
1452 AC_CHECK_MEMBERS([struct mtget.mt_blksiz, struct mtget.mt_gstat, struct mtget.mt_blkno],,,
1453 [#include <sys/types.h>
1454 #ifdef HAVE_SYS_MTIO_H
1455 #include <sys/mtio.h>
1456 #endif])
1457
1458 dnl Check for struct option
1459 AC_CHECK_MEMBERS([struct option.name],,,
1460 [#ifdef HAVE_GETOPT_H
1461 #include <getopt.h>
1462 #endif])
1463
1464 dnl Check for stat.st_blocks
1465 AC_CHECK_MEMBERS([struct stat.st_blocks])
1466
1467 dnl Check for sin6_scope_id
1468 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_scope_id],,,
1469 [#ifdef HAVE_SYS_TYPES_H
1470 #include <sys/types.h>
1471 #endif
1472 #ifdef HAVE_NETINET_IN_H
1473 #include <netinet/in.h>
1474 #endif])
1475
1476 dnl Check for ns_msg ptr member
1477 AC_CHECK_MEMBERS([ns_msg._msg_ptr],,,
1478 [#ifdef HAVE_SYS_TYPES_H
1479 #include <sys/types.h>
1480 #endif
1481 #ifdef HAVE_NETINET_IN_H
1482 # include <netinet/in.h>
1483 #endif
1484 #ifdef HAVE_ARPA_NAMESER_H
1485 # include <arpa/nameser.h>
1486 #endif])
1487
1488 dnl Check for the external timezone variables timezone and daylight
1489 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
1490                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[timezone = 1]])],[ac_cv_have_timezone="yes"],[ac_cv_have_timezone="no"]))
1491 if test "$ac_cv_have_timezone" = "yes"
1492 then
1493     AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
1494 fi
1495 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
1496                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[daylight = 1]])],[ac_cv_have_daylight="yes"],[ac_cv_have_daylight="no"]))
1497 if test "$ac_cv_have_daylight" = "yes"
1498 then
1499     AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
1500 fi
1501
1502 dnl *** check for the need to define platform-specific symbols
1503
1504 case $host_cpu in
1505   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1506   *x86_64*)         WINE_CHECK_DEFINE([__x86_64__]) ;;
1507   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
1508   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
1509   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
1510 esac
1511
1512 case $host_vendor in
1513   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1514 esac
1515
1516 dnl **** Generate output files ****
1517
1518 dnl autoconf versions before 2.59d need backslashes to escape newlines in subst variables
1519 AC_SUBST(DEPENDENCIES,m4_if(m4_version_compare(m4_defn([m4_PACKAGE_VERSION]), [2.59d]), -1,
1520 ["### Dependencies:\\
1521 \\
1522 .INIT: Makefile\\
1523 .BEGIN: Makefile\\
1524 Makefile: dummy\\
1525         -\$(MAKEDEP) -C\$(SRCDIR) -S\$(TOPSRCDIR) -T\$(TOPOBJDIR) \$(EXTRAINCL) \$(DEPEND_SRCS)\\
1526 \\
1527 \$(OBJS): \$(IDL_GEN_HEADERS)\\
1528 \$(IDL_GEN_C_SRCS:.c=.o): \$(IDL_GEN_C_SRCS)\\
1529 \$(LEX_SRCS:.l=.yy.o): \$(LEX_SRCS:.l=.yy.c)\\
1530 \$(BISON_SRCS:.y=.tab.o): \$(BISON_SRCS:.y=.tab.c)"],
1531 ["### Dependencies:
1532
1533 .INIT: Makefile
1534 .BEGIN: Makefile
1535 Makefile: dummy
1536         -\$(MAKEDEP) -C\$(SRCDIR) -S\$(TOPSRCDIR) -T\$(TOPOBJDIR) \$(EXTRAINCL) \$(DEPEND_SRCS)
1537
1538 \$(OBJS): \$(IDL_GEN_HEADERS)
1539 \$(IDL_GEN_C_SRCS:.c=.o): \$(IDL_GEN_C_SRCS)
1540 \$(LEX_SRCS:.l=.yy.o): \$(LEX_SRCS:.l=.yy.c)
1541 \$(BISON_SRCS:.y=.tab.o): \$(BISON_SRCS:.y=.tab.c)"]))
1542
1543 AH_TOP([#define __WINE_CONFIG_H])
1544
1545 AC_CONFIG_COMMANDS([include/stamp-h], [echo timestamp > include/stamp-h])
1546
1547 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/enhmfdrv)
1548 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/mfdrv)
1549 WINE_CONFIG_EXTRA_DIR(dlls/kernel32/nls)
1550 WINE_CONFIG_EXTRA_DIR(dlls/user32/resources)
1551 WINE_CONFIG_EXTRA_DIR(dlls/wineps.drv/data)
1552 WINE_CONFIG_EXTRA_DIR(include/wine)
1553
1554 MAKE_RULES=Make.rules
1555 AC_SUBST_FILE(MAKE_RULES)
1556
1557 MAKE_DLL_RULES=dlls/Makedll.rules
1558 AC_SUBST_FILE(MAKE_DLL_RULES)
1559
1560 MAKE_IMPLIB_RULES=dlls/Makeimplib.rules
1561 AC_SUBST_FILE(MAKE_IMPLIB_RULES)
1562
1563 MAKE_TEST_RULES=dlls/Maketest.rules
1564 AC_SUBST_FILE(MAKE_TEST_RULES)
1565
1566 MAKE_PROG_RULES=programs/Makeprog.rules
1567 AC_SUBST_FILE(MAKE_PROG_RULES)
1568
1569 AC_CONFIG_FILES([Make.rules])
1570 AC_CONFIG_FILES([dlls/Makedll.rules])
1571 AC_CONFIG_FILES([dlls/Makeimplib.rules])
1572 AC_CONFIG_FILES([dlls/Maketest.rules])
1573 AC_CONFIG_FILES([programs/Makeprog.rules])
1574 AC_CONFIG_FILES([Makefile])
1575 AC_CONFIG_FILES([dlls/Makefile])
1576 AC_CONFIG_FILES([dlls/acledit/Makefile])
1577 AC_CONFIG_FILES([dlls/activeds/Makefile])
1578 AC_CONFIG_FILES([dlls/advapi32/Makefile])
1579 AC_CONFIG_FILES([dlls/advapi32/tests/Makefile])
1580 AC_CONFIG_FILES([dlls/advpack/Makefile])
1581 AC_CONFIG_FILES([dlls/advpack/tests/Makefile])
1582 AC_CONFIG_FILES([dlls/amstream/Makefile])
1583 AC_CONFIG_FILES([dlls/atl/Makefile])
1584 AC_CONFIG_FILES([dlls/avicap32/Makefile])
1585 AC_CONFIG_FILES([dlls/avifil32/Makefile])
1586 AC_CONFIG_FILES([dlls/browseui/Makefile])
1587 AC_CONFIG_FILES([dlls/browseui/tests/Makefile])
1588 AC_CONFIG_FILES([dlls/cabinet/Makefile])
1589 AC_CONFIG_FILES([dlls/cabinet/tests/Makefile])
1590 AC_CONFIG_FILES([dlls/capi2032/Makefile])
1591 AC_CONFIG_FILES([dlls/cards/Makefile])
1592 AC_CONFIG_FILES([dlls/cfgmgr32/Makefile])
1593 AC_CONFIG_FILES([dlls/clusapi/Makefile])
1594 AC_CONFIG_FILES([dlls/comcat/Makefile])
1595 AC_CONFIG_FILES([dlls/comcat/tests/Makefile])
1596 AC_CONFIG_FILES([dlls/comctl32/Makefile])
1597 AC_CONFIG_FILES([dlls/comctl32/tests/Makefile])
1598 AC_CONFIG_FILES([dlls/comdlg32/Makefile])
1599 AC_CONFIG_FILES([dlls/comdlg32/tests/Makefile])
1600 AC_CONFIG_FILES([dlls/compstui/Makefile])
1601 AC_CONFIG_FILES([dlls/credui/Makefile])
1602 AC_CONFIG_FILES([dlls/credui/tests/Makefile])
1603 AC_CONFIG_FILES([dlls/crtdll/Makefile])
1604 AC_CONFIG_FILES([dlls/crypt32/Makefile])
1605 AC_CONFIG_FILES([dlls/crypt32/tests/Makefile])
1606 AC_CONFIG_FILES([dlls/cryptdll/Makefile])
1607 AC_CONFIG_FILES([dlls/cryptnet/Makefile])
1608 AC_CONFIG_FILES([dlls/cryptnet/tests/Makefile])
1609 AC_CONFIG_FILES([dlls/ctapi32/Makefile])
1610 AC_CONFIG_FILES([dlls/ctl3d32/Makefile])
1611 AC_CONFIG_FILES([dlls/d3d10/Makefile])
1612 AC_CONFIG_FILES([dlls/d3d8/Makefile])
1613 AC_CONFIG_FILES([dlls/d3d8/tests/Makefile])
1614 AC_CONFIG_FILES([dlls/d3d9/Makefile])
1615 AC_CONFIG_FILES([dlls/d3d9/tests/Makefile])
1616 AC_CONFIG_FILES([dlls/d3dim/Makefile])
1617 AC_CONFIG_FILES([dlls/d3drm/Makefile])
1618 AC_CONFIG_FILES([dlls/d3drm/tests/Makefile])
1619 AC_CONFIG_FILES([dlls/d3dx8/Makefile])
1620 AC_CONFIG_FILES([dlls/d3dx8/tests/Makefile])
1621 AC_CONFIG_FILES([dlls/d3dxof/Makefile])
1622 AC_CONFIG_FILES([dlls/dbghelp/Makefile])
1623 AC_CONFIG_FILES([dlls/dciman32/Makefile])
1624 AC_CONFIG_FILES([dlls/ddraw/Makefile])
1625 AC_CONFIG_FILES([dlls/ddraw/tests/Makefile])
1626 AC_CONFIG_FILES([dlls/ddrawex/Makefile])
1627 AC_CONFIG_FILES([dlls/devenum/Makefile])
1628 AC_CONFIG_FILES([dlls/dinput/Makefile])
1629 AC_CONFIG_FILES([dlls/dinput/tests/Makefile])
1630 AC_CONFIG_FILES([dlls/dinput8/Makefile])
1631 AC_CONFIG_FILES([dlls/dmband/Makefile])
1632 AC_CONFIG_FILES([dlls/dmcompos/Makefile])
1633 AC_CONFIG_FILES([dlls/dmime/Makefile])
1634 AC_CONFIG_FILES([dlls/dmloader/Makefile])
1635 AC_CONFIG_FILES([dlls/dmscript/Makefile])
1636 AC_CONFIG_FILES([dlls/dmstyle/Makefile])
1637 AC_CONFIG_FILES([dlls/dmsynth/Makefile])
1638 AC_CONFIG_FILES([dlls/dmusic/Makefile])
1639 AC_CONFIG_FILES([dlls/dmusic32/Makefile])
1640 AC_CONFIG_FILES([dlls/dnsapi/Makefile])
1641 AC_CONFIG_FILES([dlls/dnsapi/tests/Makefile])
1642 AC_CONFIG_FILES([dlls/dplay/Makefile])
1643 AC_CONFIG_FILES([dlls/dplayx/Makefile])
1644 AC_CONFIG_FILES([dlls/dplayx/tests/Makefile])
1645 AC_CONFIG_FILES([dlls/dpnaddr/Makefile])
1646 AC_CONFIG_FILES([dlls/dpnet/Makefile])
1647 AC_CONFIG_FILES([dlls/dpnhpast/Makefile])
1648 AC_CONFIG_FILES([dlls/dpnlobby/Makefile])
1649 AC_CONFIG_FILES([dlls/dsound/Makefile])
1650 AC_CONFIG_FILES([dlls/dsound/tests/Makefile])
1651 AC_CONFIG_FILES([dlls/dswave/Makefile])
1652 AC_CONFIG_FILES([dlls/dwmapi/Makefile])
1653 AC_CONFIG_FILES([dlls/dxdiagn/Makefile])
1654 AC_CONFIG_FILES([dlls/dxerr8/Makefile])
1655 AC_CONFIG_FILES([dlls/dxerr9/Makefile])
1656 AC_CONFIG_FILES([dlls/dxguid/Makefile])
1657 AC_CONFIG_FILES([dlls/faultrep/Makefile])
1658 AC_CONFIG_FILES([dlls/gdi32/Makefile])
1659 AC_CONFIG_FILES([dlls/gdi32/tests/Makefile])
1660 AC_CONFIG_FILES([dlls/gdiplus/Makefile])
1661 AC_CONFIG_FILES([dlls/gdiplus/tests/Makefile])
1662 AC_CONFIG_FILES([dlls/glu32/Makefile])
1663 AC_CONFIG_FILES([dlls/gphoto2.ds/Makefile])
1664 AC_CONFIG_FILES([dlls/hal/Makefile])
1665 AC_CONFIG_FILES([dlls/hhctrl.ocx/Makefile])
1666 AC_CONFIG_FILES([dlls/hid/Makefile])
1667 AC_CONFIG_FILES([dlls/hlink/Makefile])
1668 AC_CONFIG_FILES([dlls/hlink/tests/Makefile])
1669 AC_CONFIG_FILES([dlls/hnetcfg/Makefile])
1670 AC_CONFIG_FILES([dlls/iccvid/Makefile])
1671 AC_CONFIG_FILES([dlls/icmp/Makefile])
1672 AC_CONFIG_FILES([dlls/ifsmgr.vxd/Makefile])
1673 AC_CONFIG_FILES([dlls/imaadp32.acm/Makefile])
1674 AC_CONFIG_FILES([dlls/imagehlp/Makefile])
1675 AC_CONFIG_FILES([dlls/imm32/Makefile])
1676 AC_CONFIG_FILES([dlls/inetcomm/Makefile])
1677 AC_CONFIG_FILES([dlls/infosoft/Makefile])
1678 AC_CONFIG_FILES([dlls/infosoft/tests/Makefile])
1679 AC_CONFIG_FILES([dlls/inkobj/Makefile])
1680 AC_CONFIG_FILES([dlls/inseng/Makefile])
1681 AC_CONFIG_FILES([dlls/iphlpapi/Makefile])
1682 AC_CONFIG_FILES([dlls/iphlpapi/tests/Makefile])
1683 AC_CONFIG_FILES([dlls/itss/Makefile])
1684 AC_CONFIG_FILES([dlls/itss/tests/Makefile])
1685 AC_CONFIG_FILES([dlls/kernel32/Makefile])
1686 AC_CONFIG_FILES([dlls/kernel32/tests/Makefile])
1687 AC_CONFIG_FILES([dlls/localspl/Makefile])
1688 AC_CONFIG_FILES([dlls/localspl/tests/Makefile])
1689 AC_CONFIG_FILES([dlls/localui/Makefile])
1690 AC_CONFIG_FILES([dlls/localui/tests/Makefile])
1691 AC_CONFIG_FILES([dlls/lz32/Makefile])
1692 AC_CONFIG_FILES([dlls/lz32/tests/Makefile])
1693 AC_CONFIG_FILES([dlls/mapi32/Makefile])
1694 AC_CONFIG_FILES([dlls/mapi32/tests/Makefile])
1695 AC_CONFIG_FILES([dlls/mciavi32/Makefile])
1696 AC_CONFIG_FILES([dlls/mcicda/Makefile])
1697 AC_CONFIG_FILES([dlls/mciseq/Makefile])
1698 AC_CONFIG_FILES([dlls/mciwave/Makefile])
1699 AC_CONFIG_FILES([dlls/midimap/Makefile])
1700 AC_CONFIG_FILES([dlls/mlang/Makefile])
1701 AC_CONFIG_FILES([dlls/mlang/tests/Makefile])
1702 AC_CONFIG_FILES([dlls/mmdevldr.vxd/Makefile])
1703 AC_CONFIG_FILES([dlls/monodebg.vxd/Makefile])
1704 AC_CONFIG_FILES([dlls/mpr/Makefile])
1705 AC_CONFIG_FILES([dlls/mprapi/Makefile])
1706 AC_CONFIG_FILES([dlls/msacm32.drv/Makefile])
1707 AC_CONFIG_FILES([dlls/msacm32/Makefile])
1708 AC_CONFIG_FILES([dlls/msacm32/tests/Makefile])
1709 AC_CONFIG_FILES([dlls/msadp32.acm/Makefile])
1710 AC_CONFIG_FILES([dlls/mscat32/Makefile])
1711 AC_CONFIG_FILES([dlls/mscms/Makefile])
1712 AC_CONFIG_FILES([dlls/mscms/tests/Makefile])
1713 AC_CONFIG_FILES([dlls/mscoree/Makefile])
1714 AC_CONFIG_FILES([dlls/msdmo/Makefile])
1715 AC_CONFIG_FILES([dlls/msftedit/Makefile])
1716 AC_CONFIG_FILES([dlls/msg711.acm/Makefile])
1717 AC_CONFIG_FILES([dlls/mshtml.tlb/Makefile])
1718 AC_CONFIG_FILES([dlls/mshtml/Makefile])
1719 AC_CONFIG_FILES([dlls/mshtml/tests/Makefile])
1720 AC_CONFIG_FILES([dlls/msi/Makefile])
1721 AC_CONFIG_FILES([dlls/msi/tests/Makefile])
1722 AC_CONFIG_FILES([dlls/msimg32/Makefile])
1723 AC_CONFIG_FILES([dlls/msimtf/Makefile])
1724 AC_CONFIG_FILES([dlls/msisys.ocx/Makefile])
1725 AC_CONFIG_FILES([dlls/msnet32/Makefile])
1726 AC_CONFIG_FILES([dlls/msrle32/Makefile])
1727 AC_CONFIG_FILES([dlls/msvcirt/Makefile])
1728 AC_CONFIG_FILES([dlls/msvcrt/Makefile])
1729 AC_CONFIG_FILES([dlls/msvcrt/tests/Makefile])
1730 AC_CONFIG_FILES([dlls/msvcrt20/Makefile])
1731 AC_CONFIG_FILES([dlls/msvcrt40/Makefile])
1732 AC_CONFIG_FILES([dlls/msvcrtd/Makefile])
1733 AC_CONFIG_FILES([dlls/msvcrtd/tests/Makefile])
1734 AC_CONFIG_FILES([dlls/msvfw32/Makefile])
1735 AC_CONFIG_FILES([dlls/msvidc32/Makefile])
1736 AC_CONFIG_FILES([dlls/mswsock/Makefile])
1737 AC_CONFIG_FILES([dlls/msxml3/Makefile])
1738 AC_CONFIG_FILES([dlls/msxml3/tests/Makefile])
1739 AC_CONFIG_FILES([dlls/nddeapi/Makefile])
1740 AC_CONFIG_FILES([dlls/netapi32/Makefile])
1741 AC_CONFIG_FILES([dlls/netapi32/tests/Makefile])
1742 AC_CONFIG_FILES([dlls/newdev/Makefile])
1743 AC_CONFIG_FILES([dlls/ntdll/Makefile])
1744 AC_CONFIG_FILES([dlls/ntdll/tests/Makefile])
1745 AC_CONFIG_FILES([dlls/ntdsapi/Makefile])
1746 AC_CONFIG_FILES([dlls/ntoskrnl.exe/Makefile])
1747 AC_CONFIG_FILES([dlls/ntprint/Makefile])
1748 AC_CONFIG_FILES([dlls/ntprint/tests/Makefile])
1749 AC_CONFIG_FILES([dlls/objsel/Makefile])
1750 AC_CONFIG_FILES([dlls/odbc32/Makefile])
1751 AC_CONFIG_FILES([dlls/odbccp32/Makefile])
1752 AC_CONFIG_FILES([dlls/odbccp32/tests/Makefile])
1753 AC_CONFIG_FILES([dlls/ole32/Makefile])
1754 AC_CONFIG_FILES([dlls/ole32/tests/Makefile])
1755 AC_CONFIG_FILES([dlls/oleacc/Makefile])
1756 AC_CONFIG_FILES([dlls/oleaut32/Makefile])
1757 AC_CONFIG_FILES([dlls/oleaut32/tests/Makefile])
1758 AC_CONFIG_FILES([dlls/olecli32/Makefile])
1759 AC_CONFIG_FILES([dlls/oledlg/Makefile])
1760 AC_CONFIG_FILES([dlls/olepro32/Makefile])
1761 AC_CONFIG_FILES([dlls/olesvr32/Makefile])
1762 AC_CONFIG_FILES([dlls/olethk32/Makefile])
1763 AC_CONFIG_FILES([dlls/opengl32/Makefile])
1764 AC_CONFIG_FILES([dlls/opengl32/tests/Makefile])
1765 AC_CONFIG_FILES([dlls/pdh/Makefile])
1766 AC_CONFIG_FILES([dlls/pdh/tests/Makefile])
1767 AC_CONFIG_FILES([dlls/powrprof/Makefile])
1768 AC_CONFIG_FILES([dlls/printui/Makefile])
1769 AC_CONFIG_FILES([dlls/psapi/Makefile])
1770 AC_CONFIG_FILES([dlls/psapi/tests/Makefile])
1771 AC_CONFIG_FILES([dlls/pstorec/Makefile])
1772 AC_CONFIG_FILES([dlls/qcap/Makefile])
1773 AC_CONFIG_FILES([dlls/qmgr/Makefile])
1774 AC_CONFIG_FILES([dlls/quartz/Makefile])
1775 AC_CONFIG_FILES([dlls/quartz/tests/Makefile])
1776 AC_CONFIG_FILES([dlls/query/Makefile])
1777 AC_CONFIG_FILES([dlls/rasapi32/Makefile])
1778 AC_CONFIG_FILES([dlls/resutils/Makefile])
1779 AC_CONFIG_FILES([dlls/riched20/Makefile])
1780 AC_CONFIG_FILES([dlls/riched20/tests/Makefile])
1781 AC_CONFIG_FILES([dlls/riched32/Makefile])
1782 AC_CONFIG_FILES([dlls/riched32/tests/Makefile])
1783 AC_CONFIG_FILES([dlls/rpcrt4/Makefile])
1784 AC_CONFIG_FILES([dlls/rpcrt4/tests/Makefile])
1785 AC_CONFIG_FILES([dlls/rsabase/Makefile])
1786 AC_CONFIG_FILES([dlls/rsabase/tests/Makefile])
1787 AC_CONFIG_FILES([dlls/rsaenh/Makefile])
1788 AC_CONFIG_FILES([dlls/rsaenh/tests/Makefile])
1789 AC_CONFIG_FILES([dlls/sane.ds/Makefile])
1790 AC_CONFIG_FILES([dlls/schannel/Makefile])
1791 AC_CONFIG_FILES([dlls/schannel/tests/Makefile])
1792 AC_CONFIG_FILES([dlls/secur32/Makefile])
1793 AC_CONFIG_FILES([dlls/secur32/tests/Makefile])
1794 AC_CONFIG_FILES([dlls/security/Makefile])
1795 AC_CONFIG_FILES([dlls/sensapi/Makefile])
1796 AC_CONFIG_FILES([dlls/serialui/Makefile])
1797 AC_CONFIG_FILES([dlls/serialui/tests/Makefile])
1798 AC_CONFIG_FILES([dlls/setupapi/Makefile])
1799 AC_CONFIG_FILES([dlls/setupapi/tests/Makefile])
1800 AC_CONFIG_FILES([dlls/sfc/Makefile])
1801 AC_CONFIG_FILES([dlls/sfc_os/Makefile])
1802 AC_CONFIG_FILES([dlls/shdoclc/Makefile])
1803 AC_CONFIG_FILES([dlls/shdocvw/Makefile])
1804 AC_CONFIG_FILES([dlls/shdocvw/tests/Makefile])
1805 AC_CONFIG_FILES([dlls/shell32/Makefile])
1806 AC_CONFIG_FILES([dlls/shell32/tests/Makefile])
1807 AC_CONFIG_FILES([dlls/shfolder/Makefile])
1808 AC_CONFIG_FILES([dlls/shlwapi/Makefile])
1809 AC_CONFIG_FILES([dlls/shlwapi/tests/Makefile])
1810 AC_CONFIG_FILES([dlls/snmpapi/Makefile])
1811 AC_CONFIG_FILES([dlls/snmpapi/tests/Makefile])
1812 AC_CONFIG_FILES([dlls/spoolss/Makefile])
1813 AC_CONFIG_FILES([dlls/spoolss/tests/Makefile])
1814 AC_CONFIG_FILES([dlls/stdole2.tlb/Makefile])
1815 AC_CONFIG_FILES([dlls/stdole32.tlb/Makefile])
1816 AC_CONFIG_FILES([dlls/sti/Makefile])
1817 AC_CONFIG_FILES([dlls/strmiids/Makefile])
1818 AC_CONFIG_FILES([dlls/svrapi/Makefile])
1819 AC_CONFIG_FILES([dlls/sxs/Makefile])
1820 AC_CONFIG_FILES([dlls/tapi32/Makefile])
1821 AC_CONFIG_FILES([dlls/twain_32/Makefile])
1822 AC_CONFIG_FILES([dlls/unicows/Makefile])
1823 AC_CONFIG_FILES([dlls/url/Makefile])
1824 AC_CONFIG_FILES([dlls/urlmon/Makefile])
1825 AC_CONFIG_FILES([dlls/urlmon/tests/Makefile])
1826 AC_CONFIG_FILES([dlls/user32/Makefile])
1827 AC_CONFIG_FILES([dlls/user32/tests/Makefile])
1828 AC_CONFIG_FILES([dlls/userenv/Makefile])
1829 AC_CONFIG_FILES([dlls/usp10/Makefile])
1830 AC_CONFIG_FILES([dlls/usp10/tests/Makefile])
1831 AC_CONFIG_FILES([dlls/uuid/Makefile])
1832 AC_CONFIG_FILES([dlls/uxtheme/Makefile])
1833 AC_CONFIG_FILES([dlls/uxtheme/tests/Makefile])
1834 AC_CONFIG_FILES([dlls/vdhcp.vxd/Makefile])
1835 AC_CONFIG_FILES([dlls/vdmdbg/Makefile])
1836 AC_CONFIG_FILES([dlls/version/Makefile])
1837 AC_CONFIG_FILES([dlls/version/tests/Makefile])
1838 AC_CONFIG_FILES([dlls/vmm.vxd/Makefile])
1839 AC_CONFIG_FILES([dlls/vnbt.vxd/Makefile])
1840 AC_CONFIG_FILES([dlls/vnetbios.vxd/Makefile])
1841 AC_CONFIG_FILES([dlls/vtdapi.vxd/Makefile])
1842 AC_CONFIG_FILES([dlls/vwin32.vxd/Makefile])
1843 AC_CONFIG_FILES([dlls/w32skrnl/Makefile])
1844 AC_CONFIG_FILES([dlls/winealsa.drv/Makefile])
1845 AC_CONFIG_FILES([dlls/wineaudioio.drv/Makefile])
1846 AC_CONFIG_FILES([dlls/winecoreaudio.drv/Makefile])
1847 AC_CONFIG_FILES([dlls/winecrt0/Makefile])
1848 AC_CONFIG_FILES([dlls/wined3d/Makefile])
1849 AC_CONFIG_FILES([dlls/winedos/Makefile])
1850 AC_CONFIG_FILES([dlls/wineesd.drv/Makefile])
1851 AC_CONFIG_FILES([dlls/winejack.drv/Makefile])
1852 AC_CONFIG_FILES([dlls/winejoystick.drv/Makefile])
1853 AC_CONFIG_FILES([dlls/winemp3.acm/Makefile])
1854 AC_CONFIG_FILES([dlls/winenas.drv/Makefile])
1855 AC_CONFIG_FILES([dlls/wineoss.drv/Makefile])
1856 AC_CONFIG_FILES([dlls/wineps.drv/Makefile])
1857 AC_CONFIG_FILES([dlls/winequartz.drv/Makefile])
1858 AC_CONFIG_FILES([dlls/winex11.drv/Makefile])
1859 AC_CONFIG_FILES([dlls/wing32/Makefile])
1860 AC_CONFIG_FILES([dlls/winhttp/Makefile])
1861 AC_CONFIG_FILES([dlls/wininet/Makefile])
1862 AC_CONFIG_FILES([dlls/wininet/tests/Makefile])
1863 AC_CONFIG_FILES([dlls/winmm/Makefile])
1864 AC_CONFIG_FILES([dlls/winmm/tests/Makefile])
1865 AC_CONFIG_FILES([dlls/winnls32/Makefile])
1866 AC_CONFIG_FILES([dlls/winscard/Makefile])
1867 AC_CONFIG_FILES([dlls/winspool.drv/Makefile])
1868 AC_CONFIG_FILES([dlls/winspool.drv/tests/Makefile])
1869 AC_CONFIG_FILES([dlls/wintab32/Makefile])
1870 AC_CONFIG_FILES([dlls/wintrust/Makefile])
1871 AC_CONFIG_FILES([dlls/wintrust/tests/Makefile])
1872 AC_CONFIG_FILES([dlls/wldap32/Makefile])
1873 AC_CONFIG_FILES([dlls/wnaspi32/Makefile])
1874 AC_CONFIG_FILES([dlls/wow32/Makefile])
1875 AC_CONFIG_FILES([dlls/ws2_32/Makefile])
1876 AC_CONFIG_FILES([dlls/ws2_32/tests/Makefile])
1877 AC_CONFIG_FILES([dlls/wsock32/Makefile])
1878 AC_CONFIG_FILES([dlls/wtsapi32/Makefile])
1879 AC_CONFIG_FILES([documentation/Makefile])
1880 AC_CONFIG_FILES([fonts/Makefile])
1881 AC_CONFIG_FILES([include/Makefile])
1882 AC_CONFIG_FILES([libs/Makefile])
1883 AC_CONFIG_FILES([libs/port/Makefile])
1884 AC_CONFIG_FILES([libs/wine/Makefile])
1885 AC_CONFIG_FILES([libs/wpp/Makefile])
1886 AC_CONFIG_FILES([loader/Makefile])
1887 AC_CONFIG_FILES([programs/Makefile])
1888 AC_CONFIG_FILES([programs/clock/Makefile])
1889 AC_CONFIG_FILES([programs/cmd/Makefile])
1890 AC_CONFIG_FILES([programs/cmdlgtst/Makefile])
1891 AC_CONFIG_FILES([programs/control/Makefile])
1892 AC_CONFIG_FILES([programs/eject/Makefile])
1893 AC_CONFIG_FILES([programs/expand/Makefile])
1894 AC_CONFIG_FILES([programs/explorer/Makefile])
1895 AC_CONFIG_FILES([programs/hh/Makefile])
1896 AC_CONFIG_FILES([programs/icinfo/Makefile])
1897 AC_CONFIG_FILES([programs/iexplore/Makefile])
1898 AC_CONFIG_FILES([programs/msiexec/Makefile])
1899 AC_CONFIG_FILES([programs/net/Makefile])
1900 AC_CONFIG_FILES([programs/notepad/Makefile])
1901 AC_CONFIG_FILES([programs/oleview/Makefile])
1902 AC_CONFIG_FILES([programs/progman/Makefile])
1903 AC_CONFIG_FILES([programs/regedit/Makefile])
1904 AC_CONFIG_FILES([programs/regsvr32/Makefile])
1905 AC_CONFIG_FILES([programs/rpcss/Makefile])
1906 AC_CONFIG_FILES([programs/rundll32/Makefile])
1907 AC_CONFIG_FILES([programs/spoolsv/Makefile])
1908 AC_CONFIG_FILES([programs/start/Makefile])
1909 AC_CONFIG_FILES([programs/taskmgr/Makefile])
1910 AC_CONFIG_FILES([programs/uninstaller/Makefile])
1911 AC_CONFIG_FILES([programs/view/Makefile])
1912 AC_CONFIG_FILES([programs/wineboot/Makefile])
1913 AC_CONFIG_FILES([programs/winebrowser/Makefile])
1914 AC_CONFIG_FILES([programs/winecfg/Makefile])
1915 AC_CONFIG_FILES([programs/wineconsole/Makefile])
1916 AC_CONFIG_FILES([programs/winedbg/Makefile])
1917 AC_CONFIG_FILES([programs/winedevice/Makefile])
1918 AC_CONFIG_FILES([programs/winefile/Makefile])
1919 AC_CONFIG_FILES([programs/winemenubuilder/Makefile])
1920 AC_CONFIG_FILES([programs/winemine/Makefile])
1921 AC_CONFIG_FILES([programs/winepath/Makefile])
1922 AC_CONFIG_FILES([programs/winetest/Makefile])
1923 AC_CONFIG_FILES([programs/winevdm/Makefile])
1924 AC_CONFIG_FILES([programs/winhelp/Makefile])
1925 AC_CONFIG_FILES([programs/winver/Makefile])
1926 AC_CONFIG_FILES([programs/wordpad/Makefile])
1927 AC_CONFIG_FILES([programs/write/Makefile])
1928 AC_CONFIG_FILES([programs/xcopy/Makefile])
1929 AC_CONFIG_FILES([server/Makefile])
1930 AC_CONFIG_FILES([tools/Makefile])
1931 AC_CONFIG_FILES([tools/widl/Makefile])
1932 AC_CONFIG_FILES([tools/winebuild/Makefile])
1933 AC_CONFIG_FILES([tools/winedump/Makefile])
1934 AC_CONFIG_FILES([tools/winegcc/Makefile])
1935 AC_CONFIG_FILES([tools/wmc/Makefile])
1936 AC_CONFIG_FILES([tools/wrc/Makefile])
1937
1938 AC_OUTPUT
1939
1940 if test "$no_create" = "yes"
1941 then
1942   exit 0
1943 fi
1944
1945 WINE_PRINT_MESSAGES
1946
1947 echo
1948 echo "Configure finished.  Do '${ac_make} depend && ${ac_make}' to compile Wine."
1949 echo
1950
1951 dnl Local Variables:
1952 dnl comment-start: "dnl "
1953 dnl comment-end: ""
1954 dnl comment-start-skip: "\\bdnl\\b\\s *"
1955 dnl compile-command: "autoreconf --warnings=all"
1956 dnl End: