git.oblomov.eu Git - wine/blob - tools/wrc/parser.l

   1 /* -*-C-*-
   2  *
   3  * Copyright 1998-2000  Bertho A. Stultiens (BS)
   4  *
   5  * This library is free software; you can redistribute it and/or
   6  * modify it under the terms of the GNU Lesser General Public
   7  * License as published by the Free Software Foundation; either
   8  * version 2.1 of the License, or (at your option) any later version.
   9  *
  10  * This library is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13  * Lesser General Public License for more details.
  14  *
  15  * You should have received a copy of the GNU Lesser General Public
  16  * License along with this library; if not, write to the Free Software
  17  * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  18  *
  19  * History:
  20  * 21-May-2000 BS       - Fixed the ident requirement of resource names
  21  *                        which can be keywords.
  22  * 30-Apr-2000 BS       - Reintegration into the wine-tree
  23  * 11-Jan-2000 BS       - Very drastic cleanup because we don't have a
  24  *                        preprocessor in here anymore.
  25  * 02-Jan-2000 BS       - Removed the preprocessor code
  26  * 23-Dec-1999 BS       - Removed the copyright for Martin von Loewis.
  27  *                        There is really nothing left of his code in
  28  *                        this parser.
  29  * 20-Jun-1998 BS       - Changed the filename conversion. Filenames are
  30  *                        case-sensitive inder *nix, but not under dos.
  31  *                        default behaviour is to convert to lower case.
  32  *                      - All backslashes are converted to forward and
  33  *                        both single and double slash is recognized as
  34  *                        MS/Borland does.
  35  *                      - Fixed a bug in 'yywf' case that prevented
  36  *                        double quoted names to be scanned propperly.
  37  *
  38  * 19-May-1998 BS       - Started to build a preprocessor.
  39  *                      - Changed keyword processing completely to
  40  *                        table-lookups.
  41  *
  42  * 20-Apr-1998 BS       - Added ';' comment stripping
  43  *
  44  * 17-Apr-1998 BS       - Made the win32 keywords optional when compiling in
  45  *                        16bit mode
  46  *
  47  * 15-Apr-1998 BS       - Changed string handling to include escapes
  48  *                      - Added unicode string handling (no codepage
  49  *                        translation though).
  50  *                      - 'Borrowed' the main idea of string scanning from
  51  *                        the flex manual pages.
  52  *                      - Added conditional handling of scanning depending
  53  *                        on the state of the parser. This was mainly required
  54  *                        to distinguish a file to load or raw data that
  55  *                        follows. MS's definition of filenames is rather
  56  *                        complex... It can be unquoted or double quoted. If
  57  *                        double quoted, then the '\\' char is not automatically
  58  *                        escaped according to Borland's rc compiler, but it
  59  *                        accepts both "\\path\\file.rc" and "\path\file.rc".
  60  *                        This makes life very hard! I go for the escaped
  61  *                        version, as this seems to be the documented way...
  62  *                      - Single quoted strings are now parsed and converted
  63  *                        here.
  64  *                      - Added comment stripping. The implementation is
  65  *                        'borrowed' from the flex manpages.
  66  *                      - Rebuild string processing so that it may contain
  67  *                        escaped '\0'.
  68  */
  69
  70 /* Exclusive string handling */
  71 %x tkstr
  72 /* Exclusive unicode string handling */
  73 %x tklstr
  74 /* Exclusive rcdata single quoted data handling */
  75 %x tkrcd
  76 /* Exclusive comment eating... */
  77 %x comment
  78 /* Set when stripping c-junk */
  79 %x pp_cstrip
  80 /* Set when scanning #line style directives */
  81 %x pp_line
  82 /* Set when scanning #pragma */
  83 %x pp_pragma
  84 %x pp_code_page
  85
  86 %option stack
  87 %option noinput nounput noyy_top_state noyywrap
  88 %option 8bit never-interactive
  89 %option prefix="parser_"
  90
  91 /* Some shortcut definitions */
  92 ws      [ \f\t\r]
  93 cident  [a-zA-Z_][0-9a-zA-Z_]*
  94
  95 %{
  96
  97 /*#define LEX_DEBUG*/
  98
  99 #include "config.h"
 100
 101 #include <stdio.h>
 102 #include <stdlib.h>
 103 #include <string.h>
 104 #include <ctype.h>
 105 #include <assert.h>
 106 #include <errno.h>
 107 #include <limits.h>
 108
 109 #ifndef HAVE_UNISTD_H
 110 #define YY_NO_UNISTD_H
 111 #endif
 112
 113 #include "wine/unicode.h"
 114 #include "wrc.h"
 115 #include "utils.h"
 116 #include "parser.h"
 117 #include "newstruc.h"
 118
 119 #include "parser.tab.h"
 120
 121 /* Always update the current character position within a line */
 122 #define YY_USER_ACTION  char_number+=yyleng; wanted_id = want_id; want_id = 0;
 123
 124 #define YY_USER_INIT current_codepage = -1;
 125
 126 static void addcchar(char c);
 127 static void addwchar(WCHAR s);
 128 static string_t *get_buffered_cstring(void);
 129 static string_t *get_buffered_wstring(void);
 130 static string_t *make_string(char *s);
 131
 132 static char *cbuffer;           /* Buffers for string collection */
 133 static int cbufidx;
 134 static int cbufalloc = 0;
 135 static WCHAR *wbuffer;
 136 static int wbufidx;
 137 static int wbufalloc = 0;
 138
 139 static int current_codepage = -1;  /* use language default */
 140
 141 /*
 142  * This one is a bit tricky.
 143  * We set 'want_id' in the parser to get the first
 144  * identifier we get across in the scanner, but we
 145  * also want it to be reset at nearly any token we
 146  * see. Exceptions are:
 147  * - newlines
 148  * - comments
 149  * - whitespace
 150  *
 151  * The scanner will automatically reset 'want_id'
 152  * after *each* scanner reduction and puts is value
 153  * into the var below. In this way we can see the
 154  * state after the YY_RULE_SETUP (i.e. the user action;
 155  * see above) and don't have to worry too much when
 156  * it needs to be reset.
 157  */
 158 static int wanted_id = 0;
 159 static int save_wanted_id;      /* To save across comment reductions */
 160
 161 struct keyword {
 162         const char      *keyword;
 163         int             token;
 164         int             isextension;
 165         int             needcase;
 166         int             alwayskw;
 167 };
 168
 169 static struct keyword keywords[] = {
 170         { "ACCELERATORS",       tACCELERATORS,          0, 0, 0},
 171         { "ALT",                tALT,                   0, 0, 0},
 172         { "ASCII",              tASCII,                 0, 0, 0},
 173         { "AUTO3STATE",         tAUTO3STATE,            1, 0, 0},
 174         { "AUTOCHECKBOX",       tAUTOCHECKBOX,          1, 0, 0},
 175         { "AUTORADIOBUTTON",    tAUTORADIOBUTTON,       1, 0, 0},
 176         { "BEGIN",              tBEGIN,                 0, 0, 0},
 177         { "BITMAP",             tBITMAP,                0, 0, 0},
 178         { "BLOCK",              tBLOCK,                 0, 0, 0},
 179         { "BUTTON",             tBUTTON,                1, 0, 0},
 180         { "CAPTION",            tCAPTION,               0, 0, 0},
 181         { "CHARACTERISTICS",    tCHARACTERISTICS,       1, 0, 0},
 182         { "CHECKBOX",           tCHECKBOX,              0, 0, 0},
 183         { "CHECKED",            tCHECKED,               0, 0, 0},
 184         { "CLASS",              tCLASS,                 0, 0, 0},
 185         { "COMBOBOX",           tCOMBOBOX,              0, 0, 0},
 186         { "CONTROL",            tCONTROL,               0, 0, 0},
 187         { "CTEXT",              tCTEXT,                 0, 0, 0},
 188         { "CURSOR",             tCURSOR,                0, 0, 0},
 189         { "DEFPUSHBUTTON",      tDEFPUSHBUTTON,         0, 0, 0},
 190         { "DIALOG",             tDIALOG,                0, 0, 0},
 191         { "DIALOGEX",           tDIALOGEX,              1, 0, 0},
 192         { "DISCARDABLE",        tDISCARDABLE,           0, 0, 0},
 193         { "DLGINIT",            tDLGINIT,               0, 0, 0},
 194         { "EDITTEXT",           tEDITTEXT,              0, 0, 0},
 195         { "END",                tEND,                   0, 0, 0},
 196         { "EXSTYLE",            tEXSTYLE,               0, 0, 0},
 197         { "FILEFLAGS",          tFILEFLAGS,             0, 0, 0},
 198         { "FILEFLAGSMASK",      tFILEFLAGSMASK,         0, 0, 0},
 199         { "FILEOS",             tFILEOS,                0, 0, 0},
 200         { "FILESUBTYPE",        tFILESUBTYPE,           0, 0, 0},
 201         { "FILETYPE",           tFILETYPE,              0, 0, 0},
 202         { "FILEVERSION",        tFILEVERSION,           0, 0, 0},
 203         { "FIXED",              tFIXED,                 0, 0, 0},
 204         { "FONT",               tFONT,                  0, 0, 0},
 205         { "FONTDIR",            tFONTDIR,               0, 0, 0},       /* This is a Borland BRC extension */
 206         { "GRAYED",             tGRAYED,                0, 0, 0},
 207         { "GROUPBOX",           tGROUPBOX,              0, 0, 0},
 208         { "HELP",               tHELP,                  0, 0, 0},
 209         { "HTML",               tHTML,                  0, 0, 0},
 210         { "ICON",               tICON,                  0, 0, 0},
 211         { "IMPURE",             tIMPURE,                0, 0, 0},
 212         { "INACTIVE",           tINACTIVE,              0, 0, 0},
 213         { "LANGUAGE",           tLANGUAGE,              1, 0, 1},
 214         { "LISTBOX",            tLISTBOX,               0, 0, 0},
 215         { "LOADONCALL",         tLOADONCALL,            0, 0, 0},
 216         { "LTEXT",              tLTEXT,                 0, 0, 0},
 217         { "MENU",               tMENU,                  0, 0, 0},
 218         { "MENUBARBREAK",       tMENUBARBREAK,          0, 0, 0},
 219         { "MENUBREAK",          tMENUBREAK,             0, 0, 0},
 220         { "MENUEX",             tMENUEX,                1, 0, 0},
 221         { "MENUITEM",           tMENUITEM,              0, 0, 0},
 222         { "MESSAGETABLE",       tMESSAGETABLE,          1, 0, 0},
 223         { "MOVEABLE",           tMOVEABLE,              0, 0, 0},
 224         { "NOINVERT",           tNOINVERT,              0, 0, 0},
 225         { "NOT",                tNOT,                   0, 0, 0},
 226         { "POPUP",              tPOPUP,                 0, 0, 0},
 227         { "PRELOAD",            tPRELOAD,               0, 0, 0},
 228         { "PRODUCTVERSION",     tPRODUCTVERSION,        0, 0, 0},
 229         { "PURE",               tPURE,                  0, 0, 0},
 230         { "PUSHBUTTON",         tPUSHBUTTON,            0, 0, 0},
 231         { "RADIOBUTTON",        tRADIOBUTTON,           0, 0, 0},
 232         { "RCDATA",             tRCDATA,                0, 0, 0},
 233         { "RTEXT",              tRTEXT,                 0, 0, 0},
 234         { "SCROLLBAR",          tSCROLLBAR,             0, 0, 0},
 235         { "SEPARATOR",          tSEPARATOR,             0, 0, 0},
 236         { "SHIFT",              tSHIFT,                 0, 0, 0},
 237         { "STATE3",             tSTATE3,                1, 0, 0},
 238         { "STRING",             tSTRING,                0, 0, 0},
 239         { "STRINGTABLE",        tSTRINGTABLE,           0, 0, 1},
 240         { "STYLE",              tSTYLE,                 0, 0, 0},
 241         { "TOOLBAR",            tTOOLBAR,               1, 0, 0},
 242         { "VALUE",              tVALUE,                 0, 0, 0},
 243         { "VERSION",            tVERSION,               1, 0, 0},
 244         { "VERSIONINFO",        tVERSIONINFO,           0, 0, 0},
 245         { "VIRTKEY",            tVIRTKEY,               0, 0, 0}
 246 };
 247
 248 #define NKEYWORDS       (sizeof(keywords)/sizeof(keywords[0]))
 249 #define KWP(p)          ((const struct keyword *)(p))
 250 static int kw_cmp_func(const void *s1, const void *s2)
 251 {
 252         int ret;
 253         ret = strcasecmp(KWP(s1)->keyword, KWP(s2)->keyword);
 254         if(!ret && (KWP(s1)->needcase || KWP(s2)->needcase))
 255                 return strcmp(KWP(s1)->keyword, KWP(s2)->keyword);
 256         else
 257                 return ret;
 258 }
 259
 260 #define KW_BSEARCH
 261 #define DO_SORT
 262 static struct keyword *iskeyword(char *kw)
 263 {
 264         struct keyword *kwp;
 265         struct keyword key;
 266         key.keyword = kw;
 267         key.needcase = 0;
 268 #ifdef DO_SORT
 269         {
 270                 /* Make sure that it is sorted for bsearsh */
 271                 static int sorted = 0;
 272                 if(!sorted)
 273                 {
 274                         qsort(keywords, NKEYWORDS, sizeof(keywords[0]), kw_cmp_func);
 275                         sorted = 1;
 276                 }
 277         }
 278 #endif
 279 #ifdef KW_BSEARCH
 280         kwp = bsearch(&key, keywords, NKEYWORDS, sizeof(keywords[0]), kw_cmp_func);
 281 #else
 282         {
 283                 int i;
 284                 for(i = 0; i < NKEYWORDS; i++)
 285                 {
 286                         if(!kw_cmp_func(&key, &keywords[i]))
 287                                 break;
 288                 }
 289                 if(i < NKEYWORDS)
 290                         kwp = &keywords[i];
 291                 else
 292                         kwp = NULL;
 293         }
 294 #endif
 295
 296         if(kwp == NULL || (kwp->isextension && !extensions))
 297                 return NULL;
 298         else
 299                 return kwp;
 300 }
 301
 302 /* converts an integer in string form to an unsigned long and prints an error
 303  * on overflow */
 304 static unsigned long xstrtoul(const char *nptr, char **endptr, int base)
 305 {
 306     unsigned long l;
 307
 308     errno = 0;
 309     l = strtoul(nptr, endptr, base);
 310     if (l == ULONG_MAX && errno == ERANGE)
 311         parser_error("integer constant %s is too large", nptr);
 312     return l;
 313 }
 314
 315 %}
 316
 317 /*
 318  **************************************************************************
 319  * The flexer starts here
 320  **************************************************************************
 321  */
 322 %%
 323         /*
 324          * Catch the GCC-style line statements here and parse them.
 325          * This has the advantage that you can #include at any
 326          * stage in the resource file.
 327          * The preprocessor generates line directives in the format:
 328          * # <linenum> "filename" <codes>
 329          *
 330          * Codes can be a sequence of:
 331          * - 1 start of new file
 332          * - 2 returning to previous
 333          * - 3 system header
 334          * - 4 interpret as C-code
 335          *
 336          * 4 is not used and 1 mutually excludes 2
 337          * Anyhow, we are not really interested in these at all
 338          * because we only want to know the linenumber and
 339          * filename.
 340          */
 341 <INITIAL,pp_cstrip>^{ws}*\#{ws}*pragma{ws}+     yy_push_state(pp_pragma);
 342 <INITIAL,pp_cstrip>^{ws}*\#{ws}*        yy_push_state(pp_line);
 343 <pp_line>[^\n]* {
 344                 int lineno, len;
 345                 char *cptr;
 346                 char *fname;
 347                 yy_pop_state();
 348                 lineno = (int)strtol(yytext, &cptr, 10);
 349                 if(!lineno)
 350                         parser_error("Malformed '#...' line-directive; invalid linenumber");
 351                 fname = strchr(cptr, '"');
 352                 if(!fname)
 353                         parser_error("Malformed '#...' line-directive; missing filename");
 354                 fname++;
 355                 cptr = strchr(fname, '"');
 356                 if(!cptr)
 357                         parser_error("Malformed '#...' line-directive; missing terminating \"");
 358                 *cptr = '\0';
 359                 line_number = lineno - 1;       /* We didn't read the newline */
 360                 input_name = xstrdup(fname);
 361                 /* ignore contents of C include files */
 362                 len = strlen(input_name);
 363                 if (len > 1 && !strcasecmp( input_name + len - 2, ".h" ))
 364                     BEGIN(pp_cstrip);
 365                 else
 366                     BEGIN(INITIAL);
 367         }
 368
 369 <pp_pragma>code_page[^\n]*      yyless(9); yy_pop_state(); yy_push_state(pp_code_page);
 370 <pp_pragma>[^\n]*               yy_pop_state(); if (pedantic) parser_warning("Unrecognized #pragma directive '%s'\n",yytext);
 371
 372 <pp_code_page>\({ws}*default{ws}*\)[^\n]*       current_codepage = -1; yy_pop_state();
 373 <pp_code_page>\({ws}*utf8{ws}*\)[^\n]*          current_codepage = CP_UTF8; yy_pop_state();
 374 <pp_code_page>\({ws}*[0-9]+{ws}*\)[^\n]* {
 375         char *p = yytext;
 376         yy_pop_state();
 377         while (*p < '0' || *p > '9') p++;
 378         current_codepage = strtol( p, NULL, 10 );
 379         if (current_codepage != CP_UTF8 && !wine_cp_get_table( current_codepage ))
 380         {
 381             parser_error("Codepage %d not supported", current_codepage);
 382             current_codepage = 0;
 383         }
 384     }
 385 <pp_code_page>[^\n]*    yy_pop_state(); parser_error("Malformed #pragma code_page directive");
 386
 387         /*
 388          * Strip everything until a ';' taking
 389          * into account braces {} for structures,
 390          * classes and enums.
 391          */
 392 <pp_cstrip>\n                   line_number++; char_number = 1;
 393 <pp_cstrip>.                    ; /* ignore */
 394
 395 \{                      return tBEGIN;
 396 \}                      return tEND;
 397
 398 [0-9]+[lL]?             { parser_lval.num = xstrtoul(yytext,  0, 10); return toupper(yytext[yyleng-1]) == 'L' ? tLNUMBER : tNUMBER; }
 399 0[xX][0-9A-Fa-f]+[lL]?  { parser_lval.num = xstrtoul(yytext,  0, 16); return toupper(yytext[yyleng-1]) == 'L' ? tLNUMBER : tNUMBER; }
 400 0[oO][0-7]+[lL]?        { parser_lval.num = xstrtoul(yytext+2, 0, 8); return toupper(yytext[yyleng-1]) == 'L' ? tLNUMBER : tNUMBER; }
 401
 402         /*
 403          * The next two rules scan identifiers and filenames.
 404          * This is achieved by using the priority ruling
 405          * of the scanner where a '.' is valid in a filename
 406          * and *only* in a filename. In this case, the second
 407          * rule will be reduced because it is longer.
 408          */
 409 [A-Za-z_0-9.]+          {
 410                                 struct keyword *tok = iskeyword(yytext);
 411
 412                                 if(tok)
 413                                 {
 414                                         if(wanted_id && !tok->alwayskw)
 415                                         {
 416                                                 parser_lval.str = make_string(yytext);
 417                                                 return tIDENT;
 418                                         }
 419                                         else
 420                                                 return tok->token;
 421                                 }
 422                                 else
 423                                 {
 424                                         parser_lval.str = make_string(yytext);
 425                                         return tIDENT;
 426                                 }
 427                         }
 428 [A-Za-z_0-9./\\]+               parser_lval.str = make_string(yytext); return tFILENAME;
 429
 430         /*
 431          * Wide string scanning
 432          */
 433 L\"                     {
 434                                 yy_push_state(tklstr);
 435                                 wbufidx = 0;
 436                                 if(!win32)
 437                                         parser_warning("16bit resource contains unicode strings\n");
 438                         }
 439 <tklstr>\"{ws}+ |
 440 <tklstr>\"              {
 441                                 yy_pop_state();
 442                                 parser_lval.str = get_buffered_wstring();
 443                                 return tSTRING;
 444                         }
 445 <tklstr>\\[0-7]{1,6}    { /* octal escape sequence */
 446                                 unsigned int result;
 447                                 result = strtoul(yytext+1, 0, 8);
 448                                 if ( result > 0xffff )
 449                                         parser_error("Character constant out of range");
 450                                 addwchar((WCHAR)result);
 451                         }
 452 <tklstr>\\x[0-9a-fA-F]{4} {  /* hex escape sequence */
 453                                 unsigned int result;
 454                                 result = strtoul(yytext+2, 0, 16);
 455                                 addwchar((WCHAR)result);
 456                         }
 457 <tklstr>\\x[0-9a-fA-F]{1,3} {  parser_error("Invalid hex escape sequence '%s'", yytext); }
 458
 459 <tklstr>\\[0-9]+        parser_error("Bad escape sequence");
 460 <tklstr>\\\n{ws}*       line_number++; char_number = 1; /* backslash at EOL continues string after leading whitespace on next line */
 461 <tklstr>\\a             addwchar('\a');
 462 <tklstr>\\b             addwchar('\b');
 463 <tklstr>\\f             addwchar('\f');
 464 <tklstr>\\n             addwchar('\n');
 465 <tklstr>\\r             addwchar('\r');
 466 <tklstr>\\t             addwchar('\t');
 467 <tklstr>\\v             addwchar('\v');
 468 <tklstr>\\.             addwchar(yytext[1]);
 469 <tklstr>\\\r\n          addwchar(yytext[2]); line_number++; char_number = 1;
 470 <tklstr>\"\"            addwchar('\"');         /* "bla""bla"  -> "bla\"bla" */
 471 <tklstr>\\\"\"          addwchar('\"');         /* "bla\""bla" -> "bla\"bla" */
 472 <tklstr>\"{ws}+\"       ;                       /* "bla" "bla" -> "blabla" */
 473 <tklstr>[^\\\n\"]+      {
 474                                 char *yptr = yytext;
 475                                 while(*yptr)    /* FIXME: codepage translation */
 476                                         addwchar(*yptr++ & 0xff);
 477                         }
 478 <tklstr>\n              parser_error("Unterminated string");
 479
 480         /*
 481          * Normal string scanning
 482          */
 483 \"                      yy_push_state(tkstr); cbufidx = 0;
 484 <tkstr>\"{ws}+  |
 485 <tkstr>\"               {
 486                                 yy_pop_state();
 487                                 parser_lval.str = get_buffered_cstring();
 488                                 return tSTRING;
 489                         }
 490 <tkstr>\\[0-7]{1,3}     { /* octal escape sequence */
 491                                 int result;
 492                                 result = strtol(yytext+1, 0, 8);
 493                                 if ( result > 0xff )
 494                                         parser_error("Character constant out of range");
 495                                 addcchar((char)result);
 496                         }
 497 <tkstr>\\x[0-9a-fA-F]{2} {  /* hex escape sequence */
 498                                 int result;
 499                                 result = strtol(yytext+2, 0, 16);
 500                                 addcchar((char)result);
 501                         }
 502 <tkstr>\\x[0-9a-fA-F]   {  parser_error("Invalid hex escape sequence '%s'", yytext); }
 503
 504 <tkstr>\\[0-9]+         parser_error("Bad escape sequence");
 505 <tkstr>\\\n{ws}*        line_number++; char_number = 1; /* backslash at EOL continues string after leading whitespace on next line */
 506 <tkstr>\\a              addcchar('\a');
 507 <tkstr>\\b              addcchar('\b');
 508 <tkstr>\\f              addcchar('\f');
 509 <tkstr>\\n              addcchar('\n');
 510 <tkstr>\\r              addcchar('\r');
 511 <tkstr>\\t              addcchar('\t');
 512 <tkstr>\\v              addcchar('\v');
 513 <tkstr>\\.              addcchar(yytext[1]);
 514 <tkstr>\\\r\n           addcchar(yytext[2]); line_number++; char_number = 1;
 515 <tkstr>[^\\\n\"]+       {
 516                                 char *yptr = yytext;
 517                                 while(*yptr)
 518                                         addcchar(*yptr++);
 519                         }
 520 <tkstr>\"\"             addcchar('\"');         /* "bla""bla"   -> "bla\"bla" */
 521 <tkstr>\\\"\"           addcchar('\"');         /* "bla\""bla"  -> "bla\"bla" */
 522 <tkstr>\"{ws}+\"        ;                       /* "bla" "bla"  -> "blabla" */
 523 <tkstr>\n               parser_error("Unterminated string");
 524
 525         /*
 526          * Raw data scanning
 527          */
 528 \'                      yy_push_state(tkrcd); cbufidx = 0;
 529 <tkrcd>\'               {
 530                                 yy_pop_state();
 531                                 parser_lval.raw = new_raw_data();
 532                                 parser_lval.raw->size = cbufidx;
 533                                 parser_lval.raw->data = xmalloc(parser_lval.raw->size);
 534                                 memcpy(parser_lval.raw->data, cbuffer, parser_lval.raw->size);
 535                                 return tRAWDATA;
 536                         }
 537 <tkrcd>[0-9a-fA-F]{2}   {
 538                                 int result;
 539                                 result = strtol(yytext, 0, 16);
 540                                 addcchar((char)result);
 541                         }
 542 <tkrcd>{ws}+            ;       /* Ignore space */
 543 <tkrcd>\n               line_number++; char_number = 1;
 544 <tkrcd>.                parser_error("Malformed data-line");
 545
 546         /*
 547          * Comment stripping
 548          * Should never occur after preprocessing
 549          */
 550 <INITIAL,pp_cstrip>"/*" {
 551                                 yy_push_state(comment);
 552                                 save_wanted_id = wanted_id;
 553                                 if(!no_preprocess)
 554                                         parser_warning("Found comments after preprocessing, please report\n");
 555                         }
 556 <comment>[^*\n]*        ;
 557 <comment>"*"+[^*/\n]*   ;
 558 <comment>\n             line_number++; char_number = 1;
 559 <comment>"*"+"/"        yy_pop_state(); want_id = save_wanted_id;
 560
 561 ;[^\n]*                 want_id = wanted_id; /* not really comment, but left-over c-junk */
 562 "//"[^\n]*              want_id = wanted_id; if(!no_preprocess) parser_warning("Found comments after preprocessing, please report\n");
 563
 564 \n                      {
 565                                 want_id = wanted_id;
 566                                 line_number++;
 567                                 char_number = 1;
 568                                 if(want_nl)
 569                                 {
 570                                         want_nl = 0;
 571                                         return tNL;
 572                                 }
 573                         }
 574 {ws}+                   want_id = wanted_id;    /* Eat whitespace */
 575
 576 <INITIAL>[ -~]          return yytext[0];
 577
 578 <*>.|\n                 {
 579                                 /* Catch all rule to find any unmatched text */
 580                                 if(*yytext == '\n')
 581                                 {
 582                                         line_number++;
 583                                         char_number = 1;
 584                                 }
 585                                 parser_error("Unmatched text '%c' (0x%02x) YY_START=%d",
 586                                              isprint((unsigned char)*yytext) ? *yytext : '.', *yytext, YY_START);
 587                         }
 588
 589 <<EOF>>                 current_codepage = -1; yyterminate();
 590 %%
 591
 592 /* These dup functions copy the enclosed '\0' from
 593  * the resource string.
 594  */
 595 static void addcchar(char c)
 596 {
 597         if(cbufidx >= cbufalloc)
 598         {
 599                 cbufalloc += 1024;
 600                 cbuffer = xrealloc(cbuffer, cbufalloc * sizeof(cbuffer[0]));
 601                 if(cbufalloc > 65536)
 602                         parser_warning("Reallocating string buffer larger than 64kB\n");
 603         }
 604         cbuffer[cbufidx++] = c;
 605 }
 606
 607 static void addwchar(WCHAR s)
 608 {
 609         if(wbufidx >= wbufalloc)
 610         {
 611                 wbufalloc += 1024;
 612                 wbuffer = xrealloc(wbuffer, wbufalloc * sizeof(wbuffer[0]));
 613                 if(wbufalloc > 65536)
 614                         parser_warning("Reallocating wide string buffer larger than 64kB\n");
 615         }
 616         wbuffer[wbufidx++] = s;
 617 }
 618
 619 static string_t *get_buffered_cstring(void)
 620 {
 621     string_t *str = new_string();
 622
 623     str->size = cbufidx;
 624     str->type = str_char;
 625     str->str.cstr = xmalloc(cbufidx+1);
 626     memcpy(str->str.cstr, cbuffer, cbufidx);
 627     str->str.cstr[cbufidx] = '\0';
 628
 629     if (!current_codepage || current_codepage == -1 || !win32)  /* store as ANSI string */
 630     {
 631         if (!current_codepage) parser_error("Codepage set to Unicode only, cannot use ASCII string here");
 632         return str;
 633     }
 634     else  /* convert to Unicode before storing */
 635     {
 636         string_t *str_w = convert_string( str, str_unicode, current_codepage );
 637         if (!check_unicode_conversion( str, str_w, current_codepage ))
 638             parser_error("String %s does not convert identically to Unicode and back in codepage %d. "
 639                     "Try using a Unicode string instead", str->str.cstr, current_codepage );
 640         free_string( str );
 641         return str_w;
 642     }
 643 }
 644
 645 static string_t *get_buffered_wstring(void)
 646 {
 647         string_t *str = new_string();
 648         str->size = wbufidx;
 649         str->type = str_unicode;
 650         str->str.wstr = xmalloc((wbufidx+1)*sizeof(WCHAR));
 651         memcpy(str->str.wstr, wbuffer, wbufidx*sizeof(WCHAR));
 652         str->str.wstr[wbufidx] = 0;
 653         return str;
 654 }
 655
 656 static string_t *make_string(char *s)
 657 {
 658         string_t *str = new_string();
 659         str->size = strlen(s);
 660         str->type = str_char;
 661         str->str.cstr = xmalloc(str->size+1);
 662         memcpy(str->str.cstr, s, str->size+1);
 663         return str;
 664 }