git.oblomov.eu Git - wine/blob - tools/widl/parser.y

   1 %{
   2 /*
   3  * IDL Compiler
   4  *
   5  * Copyright 2002 Ove Kaaven
   6  *
   7  * This library is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU Lesser General Public
   9  * License as published by the Free Software Foundation; either
  10  * version 2.1 of the License, or (at your option) any later version.
  11  *
  12  * This library is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15  * Lesser General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU Lesser General Public
  18  * License along with this library; if not, write to the Free Software
  19  * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  20  */
  21
  22 #include "config.h"
  23
  24 #include <stdio.h>
  25 #include <stdlib.h>
  26 #include <stdarg.h>
  27 #include <assert.h>
  28 #include <ctype.h>
  29 #include <string.h>
  30 #ifdef HAVE_ALLOCA_H
  31 #include <alloca.h>
  32 #endif
  33
  34 #include "windef.h"
  35
  36 #include "widl.h"
  37 #include "utils.h"
  38 #include "parser.h"
  39 #include "header.h"
  40 #include "typelib.h"
  41
  42 #if defined(YYBYACC)
  43         /* Berkeley yacc (byacc) doesn't seem to know about these */
  44         /* Some *BSD supplied versions do define these though */
  45 # ifndef YYEMPTY
  46 #  define YYEMPTY       (-1)    /* Empty lookahead value of yychar */
  47 # endif
  48 # ifndef YYLEX
  49 #  define YYLEX         yylex()
  50 # endif
  51
  52 #elif defined(YYBISON)
  53         /* Bison was used for original development */
  54         /* #define YYEMPTY -2 */
  55         /* #define YYLEX   yylex() */
  56
  57 #else
  58         /* No yacc we know yet */
  59 # if !defined(YYEMPTY) || !defined(YYLEX)
  60 #  error Yacc version/type unknown. This version needs to be verified for settings of YYEMPTY and YYLEX.
  61 # elif defined(__GNUC__)        /* gcc defines the #warning directive */
  62 #  warning Yacc version/type unknown. It defines YYEMPTY and YYLEX, but is not tested
  63   /* #else we just take a chance that it works... */
  64 # endif
  65 #endif
  66
  67 static str_list_t *append_str(str_list_t *list, char *str);
  68 static attr_list_t *append_attr(attr_list_t *list, attr_t *attr);
  69 static attr_t *make_attr(enum attr_type type);
  70 static attr_t *make_attrv(enum attr_type type, unsigned long val);
  71 static attr_t *make_attrp(enum attr_type type, void *val);
  72 static expr_t *make_expr(enum expr_type type);
  73 static expr_t *make_exprl(enum expr_type type, long val);
  74 static expr_t *make_exprs(enum expr_type type, char *val);
  75 static expr_t *make_exprt(enum expr_type type, type_t *tref, expr_t *expr);
  76 static expr_t *make_expr1(enum expr_type type, expr_t *expr);
  77 static expr_t *make_expr2(enum expr_type type, expr_t *exp1, expr_t *exp2);
  78 static expr_t *make_expr3(enum expr_type type, expr_t *expr1, expr_t *expr2, expr_t *expr3);
  79 static type_t *make_type(unsigned char type, type_t *ref);
  80 static expr_list_t *append_expr(expr_list_t *list, expr_t *expr);
  81 static array_dims_t *append_array(array_dims_t *list, expr_t *expr);
  82 static void set_type(var_t *v, type_t *type, array_dims_t *arr);
  83 static ifref_list_t *append_ifref(ifref_list_t *list, ifref_t *iface);
  84 static ifref_t *make_ifref(type_t *iface);
  85 static var_list_t *append_var(var_list_t *list, var_t *var);
  86 static var_t *make_var(char *name);
  87 static func_list_t *append_func(func_list_t *list, func_t *func);
  88 static func_t *make_func(var_t *def, var_list_t *args);
  89 static type_t *make_class(char *name);
  90 static type_t *make_safearray(type_t *type);
  91 static type_t *make_builtin(char *name);
  92 static type_t *make_int(int sign);
  93
  94 static type_t *reg_type(type_t *type, const char *name, int t);
  95 static type_t *reg_typedefs(type_t *type, var_list_t *names, attr_list_t *attrs);
  96 static type_t *find_type(const char *name, int t);
  97 static type_t *find_type2(char *name, int t);
  98 static type_t *get_type(unsigned char type, char *name, int t);
  99 static type_t *get_typev(unsigned char type, var_t *name, int t);
 100 static int get_struct_type(var_list_t *fields);
 101
 102 static var_t *reg_const(var_t *var);
 103 static var_t *find_const(char *name, int f);
 104
 105 static void write_libid(const char *name, const attr_list_t *attr);
 106 static void write_clsid(type_t *cls);
 107 static void write_diid(type_t *iface);
 108 static void write_iid(type_t *iface);
 109
 110 static int compute_method_indexes(type_t *iface);
 111 static char *gen_name(void);
 112 static void process_typedefs(var_list_t *names);
 113 static void check_arg(var_t *arg);
 114
 115 #define tsENUM   1
 116 #define tsSTRUCT 2
 117 #define tsUNION  3
 118
 119 %}
 120 %union {
 121         attr_t *attr;
 122         attr_list_t *attr_list;
 123         str_list_t *str_list;
 124         expr_t *expr;
 125         expr_list_t *expr_list;
 126         array_dims_t *array_dims;
 127         type_t *type;
 128         var_t *var;
 129         var_list_t *var_list;
 130         func_t *func;
 131         func_list_t *func_list;
 132         ifref_t *ifref;
 133         ifref_list_t *ifref_list;
 134         char *str;
 135         UUID *uuid;
 136         unsigned int num;
 137 }
 138
 139 %token <str> aIDENTIFIER
 140 %token <str> aKNOWNTYPE
 141 %token <num> aNUM aHEXNUM
 142 %token <str> aSTRING
 143 %token <uuid> aUUID
 144 %token aEOF
 145 %token SHL SHR
 146 %token tAGGREGATABLE tALLOCATE tAPPOBJECT tASYNC tASYNCUUID
 147 %token tAUTOHANDLE tBINDABLE tBOOLEAN tBROADCAST tBYTE tBYTECOUNT
 148 %token tCALLAS tCALLBACK tCASE tCDECL tCHAR tCOCLASS tCODE tCOMMSTATUS
 149 %token tCONST tCONTEXTHANDLE tCONTEXTHANDLENOSERIALIZE
 150 %token tCONTEXTHANDLESERIALIZE tCONTROL tCPPQUOTE
 151 %token tDEFAULT
 152 %token tDEFAULTCOLLELEM
 153 %token tDEFAULTVALUE
 154 %token tDEFAULTVTABLE
 155 %token tDISPLAYBIND
 156 %token tDISPINTERFACE
 157 %token tDLLNAME tDOUBLE tDUAL
 158 %token tENDPOINT
 159 %token tENTRY tENUM tERRORSTATUST
 160 %token tEXPLICITHANDLE tEXTERN
 161 %token tFALSE
 162 %token tFLOAT
 163 %token tHANDLE
 164 %token tHANDLET
 165 %token tHELPCONTEXT tHELPFILE
 166 %token tHELPSTRING tHELPSTRINGCONTEXT tHELPSTRINGDLL
 167 %token tHIDDEN
 168 %token tHYPER tID tIDEMPOTENT
 169 %token tIIDIS
 170 %token tIMMEDIATEBIND
 171 %token tIMPLICITHANDLE
 172 %token tIMPORT tIMPORTLIB
 173 %token tIN tINLINE
 174 %token tINPUTSYNC
 175 %token tINT tINT64
 176 %token tINTERFACE
 177 %token tLCID
 178 %token tLENGTHIS tLIBRARY
 179 %token tLOCAL
 180 %token tLONG
 181 %token tMETHODS
 182 %token tMODULE
 183 %token tNONBROWSABLE
 184 %token tNONCREATABLE
 185 %token tNONEXTENSIBLE
 186 %token tOBJECT tODL tOLEAUTOMATION
 187 %token tOPTIONAL
 188 %token tOUT
 189 %token tPOINTERDEFAULT
 190 %token tPROPERTIES
 191 %token tPROPGET tPROPPUT tPROPPUTREF
 192 %token tPTR
 193 %token tPUBLIC
 194 %token tRANGE
 195 %token tREADONLY tREF
 196 %token tREQUESTEDIT
 197 %token tRESTRICTED
 198 %token tRETVAL
 199 %token tSAFEARRAY
 200 %token tSHORT
 201 %token tSIGNED
 202 %token tSINGLE
 203 %token tSIZEIS tSIZEOF
 204 %token tSMALL
 205 %token tSOURCE
 206 %token tSTDCALL
 207 %token tSTRING tSTRUCT
 208 %token tSWITCH tSWITCHIS tSWITCHTYPE
 209 %token tTRANSMITAS
 210 %token tTRUE
 211 %token tTYPEDEF
 212 %token tUNION
 213 %token tUNIQUE
 214 %token tUNSIGNED
 215 %token tUUID
 216 %token tV1ENUM
 217 %token tVARARG
 218 %token tVERSION
 219 %token tVOID
 220 %token tWCHAR tWIREMARSHAL
 221
 222 %type <attr> attribute
 223 %type <attr_list> m_attributes attributes attrib_list
 224 %type <str_list> str_list
 225 %type <expr> m_expr expr expr_const
 226 %type <expr_list> m_exprs /* exprs expr_list */ expr_list_const
 227 %type <array_dims> array array_list
 228 %type <type> inherit interface interfacehdr interfacedef interfacedec
 229 %type <type> dispinterface dispinterfacehdr dispinterfacedef
 230 %type <type> module modulehdr moduledef
 231 %type <type> base_type int_std
 232 %type <type> enumdef structdef uniondef
 233 %type <type> type
 234 %type <ifref> coclass_int
 235 %type <ifref_list> gbl_statements coclass_ints
 236 %type <var> arg field s_field case enum constdef externdef
 237 %type <var_list> m_args no_args args fields cases enums enum_list pident_list dispint_props
 238 %type <var> m_ident t_ident ident p_ident pident
 239 %type <func> funcdef
 240 %type <func_list> int_statements dispint_meths
 241 %type <type> coclass coclasshdr coclassdef
 242 %type <num> pointer_type version
 243 %type <str> libraryhdr
 244
 245 %left ','
 246 %right '?' ':'
 247 %left '|'
 248 %left '&'
 249 %left '-' '+'
 250 %left '*' '/'
 251 %left SHL SHR
 252 %right '~'
 253 %right CAST
 254 %right PPTR
 255 %right NEG
 256
 257 %%
 258
 259 input:   gbl_statements                        { write_proxies($1); write_client($1); write_server($1); }
 260         ;
 261
 262 gbl_statements:                                 { $$ = NULL; }
 263         | gbl_statements interfacedec           { $$ = $1; }
 264         | gbl_statements interfacedef           { $$ = append_ifref( $1, make_ifref($2) ); }
 265         | gbl_statements coclass ';'            { $$ = $1;
 266                                                   reg_type($2, $2->name, 0);
 267                                                   if (!parse_only && do_header) write_coclass_forward($2);
 268                                                 }
 269         | gbl_statements coclassdef             { $$ = $1;
 270                                                   add_typelib_entry($2);
 271                                                   reg_type($2, $2->name, 0);
 272                                                   if (!parse_only && do_header) write_coclass_forward($2);
 273                                                 }
 274         | gbl_statements moduledef              { $$ = $1; add_typelib_entry($2); }
 275         | gbl_statements librarydef             { $$ = $1; }
 276         | gbl_statements statement              { $$ = $1; }
 277         ;
 278
 279 imp_statements:                                 {}
 280         | imp_statements interfacedec           { if (!parse_only) add_typelib_entry($2); }
 281         | imp_statements interfacedef           { if (!parse_only) add_typelib_entry($2); }
 282         | imp_statements coclass ';'            { reg_type($2, $2->name, 0); if (!parse_only && do_header) write_coclass_forward($2); }
 283         | imp_statements coclassdef             { if (!parse_only) add_typelib_entry($2);
 284                                                   reg_type($2, $2->name, 0);
 285                                                   if (!parse_only && do_header) write_coclass_forward($2);
 286                                                 }
 287         | imp_statements moduledef              { if (!parse_only) add_typelib_entry($2); }
 288         | imp_statements statement              {}
 289         | imp_statements importlib              {}
 290         ;
 291
 292 int_statements:                                 { $$ = NULL; }
 293         | int_statements funcdef ';'            { $$ = append_func( $1, $2 ); }
 294         | int_statements statement              { $$ = $1; }
 295         ;
 296
 297 statement: ';'                                  {}
 298         | constdef ';'                          { if (!parse_only && do_header) { write_constdef($1); } }
 299         | cppquote                              {}
 300         | enumdef ';'                           { if (!parse_only && do_header) { write_type(header, $1, NULL, NULL); fprintf(header, ";\n\n"); } }
 301         | externdef ';'                         { if (!parse_only && do_header) { write_externdef($1); } }
 302         | import                                {}
 303         | structdef ';'                         { if (!parse_only && do_header) { write_type(header, $1, NULL, NULL); fprintf(header, ";\n\n"); } }
 304         | typedef ';'                           {}
 305         | uniondef ';'                          { if (!parse_only && do_header) { write_type(header, $1, NULL, NULL); fprintf(header, ";\n\n"); } }
 306         ;
 307
 308 cppquote: tCPPQUOTE '(' aSTRING ')'             { if (!parse_only && do_header) fprintf(header, "%s\n", $3); }
 309         ;
 310 import_start: tIMPORT aSTRING ';'               { assert(yychar == YYEMPTY);
 311                                                   if (!do_import($2)) yychar = aEOF; }
 312         ;
 313 import:   import_start imp_statements aEOF      {}
 314         ;
 315
 316 importlib: tIMPORTLIB '(' aSTRING ')'           { if(!parse_only) add_importlib($3); }
 317         ;
 318
 319 libraryhdr: tLIBRARY aIDENTIFIER                { $$ = $2; }
 320         ;
 321 library_start: attributes libraryhdr '{'        { start_typelib($2, $1);
 322                                                   if (!parse_only && do_header) write_library($2, $1);
 323                                                   if (!parse_only && do_idfile) write_libid($2, $1);
 324                                                 }
 325         ;
 326 librarydef: library_start imp_statements '}'    { end_typelib(); }
 327         ;
 328
 329 m_args:                                         { $$ = NULL; }
 330         | args
 331         ;
 332
 333 no_args:  tVOID                                 { $$ = NULL; }
 334         ;
 335
 336 args:     arg                                   { check_arg($1); $$ = append_var( NULL, $1 ); }
 337         | args ',' arg                          { check_arg($3); $$ = append_var( $1, $3); }
 338         | no_args
 339         ;
 340
 341 /* split into two rules to get bison to resolve a tVOID conflict */
 342 arg:      attributes type pident array          { $$ = $3;
 343                                                   set_type($$, $2, $4);
 344                                                   $$->attrs = $1;
 345                                                 }
 346         | type pident array                     { $$ = $2;
 347                                                   set_type($$, $1, $3);
 348                                                 }
 349         | attributes type pident '(' m_args ')' { $$ = $3;
 350                                                   $$->ptr_level--;
 351                                                   set_type($$, $2, NULL);
 352                                                   $$->attrs = $1;
 353                                                   $$->args = $5;
 354                                                 }
 355         | type pident '(' m_args ')'            { $$ = $2;
 356                                                   $$->ptr_level--;
 357                                                   set_type($$, $1, NULL);
 358                                                   $$->args = $4;
 359                                                 }
 360         ;
 361
 362 array:                                          { $$ = NULL; }
 363         | '[' array_list ']'                    { $$ = $2; }
 364         | '[' '*' ']'                           { $$ = append_array( NULL, make_expr(EXPR_VOID) ); }
 365         ;
 366
 367 array_list: m_expr /* size of first dimension is optional */ { $$ = append_array( NULL, $1 ); }
 368         | array_list ',' expr                   { $$ = append_array( $1, $3 ); }
 369         | array_list ']' '[' expr               { $$ = append_array( $1, $4 ); }
 370         ;
 371
 372 m_attributes:                                   { $$ = NULL; }
 373         | attributes
 374         ;
 375
 376 attributes:
 377           '[' attrib_list ']'                   { $$ = $2;
 378                                                   if (!$$)
 379                                                     yyerror("empty attribute lists unsupported");
 380                                                 }
 381         ;
 382
 383 attrib_list: attribute                          { $$ = append_attr( NULL, $1 ); }
 384         | attrib_list ',' attribute             { $$ = append_attr( $1, $3 ); }
 385         | attrib_list ']' '[' attribute         { $$ = append_attr( $1, $4 ); }
 386         ;
 387
 388 str_list: aSTRING                               { $$ = append_str( NULL, $1 ); }
 389         | str_list ',' aSTRING                  { $$ = append_str( $1, $3 ); }
 390         ;
 391
 392 attribute:                                      { $$ = NULL; }
 393         | tAGGREGATABLE                         { $$ = make_attr(ATTR_AGGREGATABLE); }
 394         | tAPPOBJECT                            { $$ = make_attr(ATTR_APPOBJECT); }
 395         | tASYNC                                { $$ = make_attr(ATTR_ASYNC); }
 396         | tAUTOHANDLE                           { $$ = make_attr(ATTR_AUTO_HANDLE); }
 397         | tBINDABLE                             { $$ = make_attr(ATTR_BINDABLE); }
 398         | tCALLAS '(' ident ')'                 { $$ = make_attrp(ATTR_CALLAS, $3); }
 399         | tCASE '(' expr_list_const ')'         { $$ = make_attrp(ATTR_CASE, $3); }
 400         | tCONTEXTHANDLE                        { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); }
 401         | tCONTEXTHANDLENOSERIALIZE             { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); /* RPC_CONTEXT_HANDLE_DONT_SERIALIZE */ }
 402         | tCONTEXTHANDLESERIALIZE               { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); /* RPC_CONTEXT_HANDLE_SERIALIZE */ }
 403         | tCONTROL                              { $$ = make_attr(ATTR_CONTROL); }
 404         | tDEFAULT                              { $$ = make_attr(ATTR_DEFAULT); }
 405         | tDEFAULTCOLLELEM                      { $$ = make_attr(ATTR_DEFAULTCOLLELEM); }
 406         | tDEFAULTVALUE '(' expr_const ')'      { $$ = make_attrp(ATTR_DEFAULTVALUE_EXPR, $3); }
 407         | tDEFAULTVALUE '(' aSTRING ')'         { $$ = make_attrp(ATTR_DEFAULTVALUE_STRING, $3); }
 408         | tDEFAULTVTABLE                        { $$ = make_attr(ATTR_DEFAULTVTABLE); }
 409         | tDISPLAYBIND                          { $$ = make_attr(ATTR_DISPLAYBIND); }
 410         | tDLLNAME '(' aSTRING ')'              { $$ = make_attrp(ATTR_DLLNAME, $3); }
 411         | tDUAL                                 { $$ = make_attr(ATTR_DUAL); }
 412         | tENDPOINT '(' str_list ')'            { $$ = make_attrp(ATTR_ENDPOINT, $3); }
 413         | tENTRY '(' aSTRING ')'                { $$ = make_attrp(ATTR_ENTRY_STRING, $3); }
 414         | tENTRY '(' expr_const ')'             { $$ = make_attrp(ATTR_ENTRY_ORDINAL, $3); }
 415         | tEXPLICITHANDLE                       { $$ = make_attr(ATTR_EXPLICIT_HANDLE); }
 416         | tHANDLE                               { $$ = make_attr(ATTR_HANDLE); }
 417         | tHELPCONTEXT '(' expr_const ')'       { $$ = make_attrp(ATTR_HELPCONTEXT, $3); }
 418         | tHELPFILE '(' aSTRING ')'             { $$ = make_attrp(ATTR_HELPFILE, $3); }
 419         | tHELPSTRING '(' aSTRING ')'           { $$ = make_attrp(ATTR_HELPSTRING, $3); }
 420         | tHELPSTRINGCONTEXT '(' expr_const ')' { $$ = make_attrp(ATTR_HELPSTRINGCONTEXT, $3); }
 421         | tHELPSTRINGDLL '(' aSTRING ')'        { $$ = make_attrp(ATTR_HELPSTRINGDLL, $3); }
 422         | tHIDDEN                               { $$ = make_attr(ATTR_HIDDEN); }
 423         | tID '(' expr_const ')'                { $$ = make_attrp(ATTR_ID, $3); }
 424         | tIDEMPOTENT                           { $$ = make_attr(ATTR_IDEMPOTENT); }
 425         | tIIDIS '(' ident ')'                  { $$ = make_attrp(ATTR_IIDIS, $3); }
 426         | tIMMEDIATEBIND                        { $$ = make_attr(ATTR_IMMEDIATEBIND); }
 427         | tIMPLICITHANDLE '(' tHANDLET aIDENTIFIER ')'  { $$ = make_attrp(ATTR_IMPLICIT_HANDLE, $4); }
 428         | tIN                                   { $$ = make_attr(ATTR_IN); }
 429         | tINPUTSYNC                            { $$ = make_attr(ATTR_INPUTSYNC); }
 430         | tLENGTHIS '(' m_exprs ')'             { $$ = make_attrp(ATTR_LENGTHIS, $3); }
 431         | tLOCAL                                { $$ = make_attr(ATTR_LOCAL); }
 432         | tNONBROWSABLE                         { $$ = make_attr(ATTR_NONBROWSABLE); }
 433         | tNONCREATABLE                         { $$ = make_attr(ATTR_NONCREATABLE); }
 434         | tNONEXTENSIBLE                        { $$ = make_attr(ATTR_NONEXTENSIBLE); }
 435         | tOBJECT                               { $$ = make_attr(ATTR_OBJECT); }
 436         | tODL                                  { $$ = make_attr(ATTR_ODL); }
 437         | tOLEAUTOMATION                        { $$ = make_attr(ATTR_OLEAUTOMATION); }
 438         | tOPTIONAL                             { $$ = make_attr(ATTR_OPTIONAL); }
 439         | tOUT                                  { $$ = make_attr(ATTR_OUT); }
 440         | tPOINTERDEFAULT '(' pointer_type ')'  { $$ = make_attrv(ATTR_POINTERDEFAULT, $3); }
 441         | tPROPGET                              { $$ = make_attr(ATTR_PROPGET); }
 442         | tPROPPUT                              { $$ = make_attr(ATTR_PROPPUT); }
 443         | tPROPPUTREF                           { $$ = make_attr(ATTR_PROPPUTREF); }
 444         | tPUBLIC                               { $$ = make_attr(ATTR_PUBLIC); }
 445         | tRANGE '(' expr_const ',' expr_const ')' { expr_list_t *list = append_expr( NULL, $3 );
 446                                                      list = append_expr( list, $5 );
 447                                                      $$ = make_attrp(ATTR_RANGE, list); }
 448         | tREADONLY                             { $$ = make_attr(ATTR_READONLY); }
 449         | tREQUESTEDIT                          { $$ = make_attr(ATTR_REQUESTEDIT); }
 450         | tRESTRICTED                           { $$ = make_attr(ATTR_RESTRICTED); }
 451         | tRETVAL                               { $$ = make_attr(ATTR_RETVAL); }
 452         | tSIZEIS '(' m_exprs ')'               { $$ = make_attrp(ATTR_SIZEIS, $3); }
 453         | tSOURCE                               { $$ = make_attr(ATTR_SOURCE); }
 454         | tSTRING                               { $$ = make_attr(ATTR_STRING); }
 455         | tSWITCHIS '(' expr ')'                { $$ = make_attrp(ATTR_SWITCHIS, $3); }
 456         | tSWITCHTYPE '(' type ')'              { $$ = make_attrp(ATTR_SWITCHTYPE, $3); }
 457         | tTRANSMITAS '(' type ')'              { $$ = make_attrp(ATTR_TRANSMITAS, $3); }
 458         | tUUID '(' aUUID ')'                   { $$ = make_attrp(ATTR_UUID, $3); }
 459         | tV1ENUM                               { $$ = make_attr(ATTR_V1ENUM); }
 460         | tVARARG                               { $$ = make_attr(ATTR_VARARG); }
 461         | tVERSION '(' version ')'              { $$ = make_attrv(ATTR_VERSION, $3); }
 462         | tWIREMARSHAL '(' type ')'             { $$ = make_attrp(ATTR_WIREMARSHAL, $3); }
 463         | pointer_type                          { $$ = make_attrv(ATTR_POINTERTYPE, $1); }
 464         ;
 465
 466 callconv:
 467         | tSTDCALL
 468         ;
 469
 470 cases:                                          { $$ = NULL; }
 471         | cases case                            { $$ = append_var( $1, $2 ); }
 472         ;
 473
 474 case:     tCASE expr ':' field                  { attr_t *a = make_attrp(ATTR_CASE, $2);
 475                                                   $$ = $4; if (!$$) $$ = make_var(NULL);
 476                                                   $$->attrs = append_attr( $$->attrs, a );
 477                                                 }
 478         | tDEFAULT ':' field                    { attr_t *a = make_attr(ATTR_DEFAULT);
 479                                                   $$ = $3; if (!$$) $$ = make_var(NULL);
 480                                                   $$->attrs = append_attr( $$->attrs, a );
 481                                                 }
 482         ;
 483
 484 constdef: tCONST type ident '=' expr_const      { $$ = reg_const($3);
 485                                                   set_type($$, $2, NULL);
 486                                                   $$->eval = $5;
 487                                                 }
 488         ;
 489
 490 enums:                                          { $$ = NULL; }
 491         | enum_list ','                         { $$ = $1; }
 492         | enum_list
 493         ;
 494
 495 enum_list: enum                                 { if (!$1->eval)
 496                                                     $1->eval = make_exprl(EXPR_NUM, 0 /* default for first enum entry */);
 497                                                   $$ = append_var( NULL, $1 );
 498                                                 }
 499         | enum_list ',' enum                    { if (!$3->eval)
 500                                                   {
 501                                                     var_t *last = LIST_ENTRY( list_tail($$), var_t, entry );
 502                                                     $3->eval = make_exprl(EXPR_NUM, last->eval->cval + 1);
 503                                                   }
 504                                                   $$ = append_var( $1, $3 );
 505                                                 }
 506         ;
 507
 508 enum:     ident '=' expr_const                  { $$ = reg_const($1);
 509                                                   $$->eval = $3;
 510                                                   $$->type = make_int(0);
 511                                                 }
 512         | ident                                 { $$ = reg_const($1);
 513                                                   $$->type = make_int(0);
 514                                                 }
 515         ;
 516
 517 enumdef: tENUM t_ident '{' enums '}'            { $$ = get_typev(RPC_FC_ENUM16, $2, tsENUM);
 518                                                   $$->kind = TKIND_ENUM;
 519                                                   $$->fields = $4;
 520                                                   $$->defined = TRUE;
 521                                                   if(in_typelib)
 522                                                       add_typelib_entry($$);
 523                                                 }
 524         ;
 525
 526 m_exprs:  m_expr                                { $$ = append_expr( NULL, $1 ); }
 527         | m_exprs ',' m_expr                    { $$ = append_expr( $1, $3 ); }
 528         ;
 529
 530 /*
 531 exprs:                                          { $$ = make_expr(EXPR_VOID); }
 532         | expr_list
 533         ;
 534
 535 expr_list: expr
 536         | expr_list ',' expr                    { LINK($3, $1); $$ = $3; }
 537         ;
 538 */
 539
 540 m_expr:                                         { $$ = make_expr(EXPR_VOID); }
 541         | expr
 542         ;
 543
 544 expr:     aNUM                                  { $$ = make_exprl(EXPR_NUM, $1); }
 545         | aHEXNUM                               { $$ = make_exprl(EXPR_HEXNUM, $1); }
 546         | tFALSE                                { $$ = make_exprl(EXPR_TRUEFALSE, 0); }
 547         | tTRUE                                 { $$ = make_exprl(EXPR_TRUEFALSE, 1); }
 548         | aIDENTIFIER                           { $$ = make_exprs(EXPR_IDENTIFIER, $1); }
 549         | expr '?' expr ':' expr                { $$ = make_expr3(EXPR_COND, $1, $3, $5); }
 550         | expr '|' expr                         { $$ = make_expr2(EXPR_OR , $1, $3); }
 551         | expr '&' expr                         { $$ = make_expr2(EXPR_AND, $1, $3); }
 552         | expr '+' expr                         { $$ = make_expr2(EXPR_ADD, $1, $3); }
 553         | expr '-' expr                         { $$ = make_expr2(EXPR_SUB, $1, $3); }
 554         | expr '*' expr                         { $$ = make_expr2(EXPR_MUL, $1, $3); }
 555         | expr '/' expr                         { $$ = make_expr2(EXPR_DIV, $1, $3); }
 556         | expr SHL expr                         { $$ = make_expr2(EXPR_SHL, $1, $3); }
 557         | expr SHR expr                         { $$ = make_expr2(EXPR_SHR, $1, $3); }
 558         | '~' expr                              { $$ = make_expr1(EXPR_NOT, $2); }
 559         | '-' expr %prec NEG                    { $$ = make_expr1(EXPR_NEG, $2); }
 560         | '*' expr %prec PPTR                   { $$ = make_expr1(EXPR_PPTR, $2); }
 561         | '(' type ')' expr %prec CAST          { $$ = make_exprt(EXPR_CAST, $2, $4); }
 562         | tSIZEOF '(' type ')'                  { $$ = make_exprt(EXPR_SIZEOF, $3, NULL); }
 563         | '(' expr ')'                          { $$ = $2; }
 564         ;
 565
 566 expr_list_const: expr_const                     { $$ = append_expr( NULL, $1 ); }
 567         | expr_list_const ',' expr_const        { $$ = append_expr( $1, $3 ); }
 568         ;
 569
 570 expr_const: expr                                { $$ = $1;
 571                                                   if (!$$->is_const)
 572                                                       yyerror("expression is not constant");
 573                                                 }
 574         ;
 575
 576 externdef: tEXTERN tCONST type ident            { $$ = $4;
 577                                                   set_type($$, $3, NULL);
 578                                                 }
 579         ;
 580
 581 fields:                                         { $$ = NULL; }
 582         | fields field                          { $$ = append_var( $1, $2 ); }
 583         ;
 584
 585 field:    s_field ';'                           { $$ = $1; }
 586         | m_attributes uniondef ';'             { $$ = make_var(NULL); $$->type = $2; $$->attrs = $1; }
 587         | attributes ';'                        { $$ = make_var(NULL); $$->attrs = $1; }
 588         | ';'                                   { $$ = NULL; }
 589         ;
 590
 591 s_field:  m_attributes type pident array        { $$ = $3; set_type($$, $2, $4); $$->attrs = $1; }
 592         ;
 593
 594 funcdef:
 595           m_attributes type callconv pident
 596           '(' m_args ')'                        { set_type($4, $2, NULL);
 597                                                   $4->attrs = $1;
 598                                                   $$ = make_func($4, $6);
 599                                                   if (is_attr($4->attrs, ATTR_IN)) {
 600                                                     yyerror("inapplicable attribute [in] for function '%s'",$$->def->name);
 601                                                   }
 602                                                 }
 603         ;
 604
 605 m_ident:                                        { $$ = NULL; }
 606         | ident
 607         ;
 608
 609 t_ident:                                        { $$ = NULL; }
 610         | aIDENTIFIER                           { $$ = make_var($1); }
 611         | aKNOWNTYPE                            { $$ = make_var($1); }
 612         ;
 613
 614 ident:    aIDENTIFIER                           { $$ = make_var($1); }
 615 /* some "reserved words" used in attributes are also used as field names in some MS IDL files */
 616         | aKNOWNTYPE                            { $$ = make_var($<str>1); }
 617         ;
 618
 619 base_type: tBYTE                                { $$ = make_builtin($<str>1); }
 620         | tWCHAR                                { $$ = make_builtin($<str>1); }
 621         | int_std
 622         | tSIGNED int_std                       { $$ = $2; $$->sign = 1; }
 623         | tUNSIGNED int_std                     { $$ = $2; $$->sign = -1;
 624                                                   switch ($$->type) {
 625                                                   case RPC_FC_CHAR:  break;
 626                                                   case RPC_FC_SMALL: $$->type = RPC_FC_USMALL; break;
 627                                                   case RPC_FC_SHORT: $$->type = RPC_FC_USHORT; break;
 628                                                   case RPC_FC_LONG:  $$->type = RPC_FC_ULONG;  break;
 629                                                   case RPC_FC_HYPER:
 630                                                     if ($$->name[0] == 'h') /* hyper, as opposed to __int64 */
 631                                                     {
 632                                                       $$ = alias($$, "MIDL_uhyper");
 633                                                       $$->sign = 0;
 634                                                     }
 635                                                     break;
 636                                                   default: break;
 637                                                   }
 638                                                 }
 639         | tUNSIGNED                             { $$ = make_int(-1); }
 640         | tFLOAT                                { $$ = make_builtin($<str>1); }
 641         | tSINGLE                               { $$ = duptype(find_type("float", 0), 1); }
 642         | tDOUBLE                               { $$ = make_builtin($<str>1); }
 643         | tBOOLEAN                              { $$ = make_builtin($<str>1); }
 644         | tERRORSTATUST                         { $$ = make_builtin($<str>1); }
 645         | tHANDLET                              { $$ = make_builtin($<str>1); }
 646         ;
 647
 648 m_int:
 649         | tINT
 650         ;
 651
 652 int_std:  tINT                                  { $$ = make_builtin($<str>1); }
 653         | tSHORT m_int                          { $$ = make_builtin($<str>1); }
 654         | tSMALL                                { $$ = make_builtin($<str>1); }
 655         | tLONG m_int                           { $$ = make_builtin($<str>1); }
 656         | tHYPER m_int                          { $$ = make_builtin($<str>1); }
 657         | tINT64                                { $$ = make_builtin($<str>1); }
 658         | tCHAR                                 { $$ = make_builtin($<str>1); }
 659         ;
 660
 661 coclass:  tCOCLASS aIDENTIFIER                  { $$ = make_class($2); }
 662         | tCOCLASS aKNOWNTYPE                   { $$ = find_type($2, 0);
 663                                                   if ($$->defined) yyerror("multiple definition error");
 664                                                   if ($$->kind != TKIND_COCLASS) yyerror("%s was not declared a coclass", $2);
 665                                                 }
 666         ;
 667
 668 coclasshdr: attributes coclass                  { $$ = $2;
 669                                                   $$->attrs = $1;
 670                                                   if (!parse_only && do_header)
 671                                                     write_coclass($$);
 672                                                   if (!parse_only && do_idfile)
 673                                                     write_clsid($$);
 674                                                 }
 675         ;
 676
 677 coclassdef: coclasshdr '{' coclass_ints '}'     { $$ = $1;
 678                                                   $$->ifaces = $3;
 679                                                   $$->defined = TRUE;
 680                                                 }
 681         ;
 682
 683 coclass_ints:                                   { $$ = NULL; }
 684         | coclass_ints coclass_int              { $$ = append_ifref( $1, $2 ); }
 685         ;
 686
 687 coclass_int:
 688           m_attributes interfacedec             { $$ = make_ifref($2); $$->attrs = $1; }
 689         ;
 690
 691 dispinterface: tDISPINTERFACE aIDENTIFIER       { $$ = get_type(0, $2, 0); $$->kind = TKIND_DISPATCH; }
 692         |      tDISPINTERFACE aKNOWNTYPE        { $$ = get_type(0, $2, 0); $$->kind = TKIND_DISPATCH; }
 693         ;
 694
 695 dispinterfacehdr: attributes dispinterface      { attr_t *attrs;
 696                                                   $$ = $2;
 697                                                   if ($$->defined) yyerror("multiple definition error");
 698                                                   attrs = make_attr(ATTR_DISPINTERFACE);
 699                                                   $$->attrs = append_attr( $1, attrs );
 700                                                   $$->ref = find_type("IDispatch", 0);
 701                                                   if (!$$->ref) yyerror("IDispatch is undefined");
 702                                                   $$->defined = TRUE;
 703                                                   if (!parse_only && do_header) write_forward($$);
 704                                                 }
 705         ;
 706
 707 dispint_props: tPROPERTIES ':'                  { $$ = NULL; }
 708         | dispint_props s_field ';'             { $$ = append_var( $1, $2 ); }
 709         ;
 710
 711 dispint_meths: tMETHODS ':'                     { $$ = NULL; }
 712         | dispint_meths funcdef ';'             { $$ = append_func( $1, $2 ); }
 713         ;
 714
 715 dispinterfacedef: dispinterfacehdr '{'
 716           dispint_props
 717           dispint_meths
 718           '}'                                   { $$ = $1;
 719                                                   $$->fields = $3;
 720                                                   $$->funcs = $4;
 721                                                   if (!parse_only && do_header) write_dispinterface($$);
 722                                                   if (!parse_only && do_idfile) write_diid($$);
 723                                                 }
 724         | dispinterfacehdr
 725          '{' interface ';' '}'                  { $$ = $1;
 726                                                   $$->fields = $3->fields;
 727                                                   $$->funcs = $3->funcs;
 728                                                   if (!parse_only && do_header) write_dispinterface($$);
 729                                                   if (!parse_only && do_idfile) write_diid($$);
 730                                                 }
 731         ;
 732
 733 inherit:                                        { $$ = NULL; }
 734         | ':' aKNOWNTYPE                        { $$ = find_type2($2, 0); }
 735         ;
 736
 737 interface: tINTERFACE aIDENTIFIER               { $$ = get_type(RPC_FC_IP, $2, 0); $$->kind = TKIND_INTERFACE; }
 738         |  tINTERFACE aKNOWNTYPE                { $$ = get_type(RPC_FC_IP, $2, 0); $$->kind = TKIND_INTERFACE; }
 739         ;
 740
 741 interfacehdr: attributes interface              { $$ = $2;
 742                                                   if ($$->defined) yyerror("multiple definition error");
 743                                                   $$->attrs = $1;
 744                                                   $$->defined = TRUE;
 745                                                   if (!parse_only && do_header) write_forward($$);
 746                                                 }
 747         ;
 748
 749 interfacedef: interfacehdr inherit
 750           '{' int_statements '}'                { $$ = $1;
 751                                                   $$->ref = $2;
 752                                                   $$->funcs = $4;
 753                                                   compute_method_indexes($$);
 754                                                   if (!parse_only && do_header) write_interface($$);
 755                                                   if (!parse_only && do_idfile) write_iid($$);
 756                                                 }
 757 /* MIDL is able to import the definition of a base class from inside the
 758  * definition of a derived class, I'll try to support it with this rule */
 759         | interfacehdr ':' aIDENTIFIER
 760           '{' import int_statements '}'         { $$ = $1;
 761                                                   $$->ref = find_type2($3, 0);
 762                                                   if (!$$->ref) yyerror("base class '%s' not found in import", $3);
 763                                                   $$->funcs = $6;
 764                                                   compute_method_indexes($$);
 765                                                   if (!parse_only && do_header) write_interface($$);
 766                                                   if (!parse_only && do_idfile) write_iid($$);
 767                                                 }
 768         | dispinterfacedef                      { $$ = $1; }
 769         ;
 770
 771 interfacedec:
 772           interface ';'                         { $$ = $1; if (!parse_only && do_header) write_forward($$); }
 773         | dispinterface ';'                     { $$ = $1; if (!parse_only && do_header) write_forward($$); }
 774         ;
 775
 776 module:   tMODULE aIDENTIFIER                   { $$ = make_type(0, NULL); $$->name = $2; $$->kind = TKIND_MODULE; }
 777         | tMODULE aKNOWNTYPE                    { $$ = make_type(0, NULL); $$->name = $2; $$->kind = TKIND_MODULE; }
 778         ;
 779
 780 modulehdr: attributes module                    { $$ = $2;
 781                                                   $$->attrs = $1;
 782                                                 }
 783         ;
 784
 785 moduledef: modulehdr '{' int_statements '}'     { $$ = $1;
 786                                                   $$->funcs = $3;
 787                                                   /* FIXME: if (!parse_only && do_header) write_module($$); */
 788                                                 }
 789         ;
 790
 791 p_ident:  '*' pident %prec PPTR                 { $$ = $2; $$->ptr_level++; }
 792         | tCONST p_ident                        { $$ = $2; /* FIXME */ }
 793         ;
 794
 795 pident:   ident
 796         | p_ident
 797         | '(' pident ')'                        { $$ = $2; }
 798         ;
 799
 800 pident_list:
 801         pident                                  { $$ = append_var( NULL, $1 ); }
 802         | pident_list ',' pident                { $$ = append_var( $1, $3 ); }
 803         ;
 804
 805 pointer_type:
 806           tREF                                  { $$ = RPC_FC_RP; }
 807         | tUNIQUE                               { $$ = RPC_FC_UP; }
 808         | tPTR                                  { $$ = RPC_FC_FP; }
 809         ;
 810
 811 structdef: tSTRUCT t_ident '{' fields '}'       { $$ = get_typev(RPC_FC_STRUCT, $2, tsSTRUCT);
 812                                                   /* overwrite RPC_FC_STRUCT with a more exact type */
 813                                                   $$->type = get_struct_type( $4 );
 814                                                   $$->kind = TKIND_RECORD;
 815                                                   $$->fields = $4;
 816                                                   $$->defined = TRUE;
 817                                                   if(in_typelib)
 818                                                       add_typelib_entry($$);
 819                                                 }
 820         ;
 821
 822 type:     tVOID                                 { $$ = duptype(find_type("void", 0), 1); }
 823         | aKNOWNTYPE                            { $$ = find_type($1, 0); }
 824         | base_type                             { $$ = $1; }
 825         | tCONST type                           { $$ = duptype($2, 1); $$->is_const = TRUE; }
 826         | enumdef                               { $$ = $1; }
 827         | tENUM aIDENTIFIER                     { $$ = find_type2($2, tsENUM); }
 828         | structdef                             { $$ = $1; }
 829         | tSTRUCT aIDENTIFIER                   { $$ = get_type(RPC_FC_STRUCT, $2, tsSTRUCT); }
 830         | uniondef                              { $$ = $1; }
 831         | tUNION aIDENTIFIER                    { $$ = find_type2($2, tsUNION); }
 832         | tSAFEARRAY '(' type ')'               { $$ = make_safearray($3); }
 833         ;
 834
 835 typedef: tTYPEDEF m_attributes type pident_list { reg_typedefs($3, $4, $2);
 836                                                   process_typedefs($4);
 837                                                 }
 838         ;
 839
 840 uniondef: tUNION t_ident '{' fields '}'         { $$ = get_typev(RPC_FC_NON_ENCAPSULATED_UNION, $2, tsUNION);
 841                                                   $$->kind = TKIND_UNION;
 842                                                   $$->fields = $4;
 843                                                   $$->defined = TRUE;
 844                                                 }
 845         | tUNION t_ident
 846           tSWITCH '(' s_field ')'
 847           m_ident '{' cases '}'                 { var_t *u = $7;
 848                                                   $$ = get_typev(RPC_FC_ENCAPSULATED_UNION, $2, tsUNION);
 849                                                   $$->kind = TKIND_UNION;
 850                                                   if (!u) u = make_var( xstrdup("tagged_union") );
 851                                                   u->type = make_type(RPC_FC_NON_ENCAPSULATED_UNION, NULL);
 852                                                   u->type->kind = TKIND_UNION;
 853                                                   u->type->fields = $9;
 854                                                   u->type->defined = TRUE;
 855                                                   $$->fields = append_var( $$->fields, $5 );
 856                                                   $$->fields = append_var( $$->fields, u );
 857                                                   $$->defined = TRUE;
 858                                                 }
 859         ;
 860
 861 version:
 862           aNUM                                  { $$ = MAKELONG($1, 0); }
 863         | aNUM '.' aNUM                         { $$ = MAKELONG($1, $3); }
 864         ;
 865
 866 %%
 867
 868 static void decl_builtin(const char *name, unsigned char type)
 869 {
 870   type_t *t = make_type(type, NULL);
 871   t->name = xstrdup(name);
 872   reg_type(t, name, 0);
 873 }
 874
 875 static type_t *make_builtin(char *name)
 876 {
 877   /* NAME is strdup'd in the lexer */
 878   type_t *t = duptype(find_type(name, 0), 0);
 879   t->name = name;
 880   return t;
 881 }
 882
 883 static type_t *make_int(int sign)
 884 {
 885   type_t *t = duptype(find_type("int", 0), 1);
 886
 887   t->sign = sign;
 888   if (sign < 0)
 889     t->type = t->type == RPC_FC_LONG ? RPC_FC_ULONG : RPC_FC_USHORT;
 890
 891   return t;
 892 }
 893
 894 void init_types(void)
 895 {
 896   decl_builtin("void", 0);
 897   decl_builtin("byte", RPC_FC_BYTE);
 898   decl_builtin("wchar_t", RPC_FC_WCHAR);
 899   decl_builtin("int", RPC_FC_LONG);     /* win32 */
 900   decl_builtin("short", RPC_FC_SHORT);
 901   decl_builtin("small", RPC_FC_SMALL);
 902   decl_builtin("long", RPC_FC_LONG);
 903   decl_builtin("hyper", RPC_FC_HYPER);
 904   decl_builtin("__int64", RPC_FC_HYPER);
 905   decl_builtin("char", RPC_FC_CHAR);
 906   decl_builtin("float", RPC_FC_FLOAT);
 907   decl_builtin("double", RPC_FC_DOUBLE);
 908   decl_builtin("boolean", RPC_FC_BYTE);
 909   decl_builtin("error_status_t", RPC_FC_ERROR_STATUS_T);
 910   decl_builtin("handle_t", RPC_FC_BIND_PRIMITIVE);
 911 }
 912
 913 static str_list_t *append_str(str_list_t *list, char *str)
 914 {
 915     struct str_list_entry_t *entry;
 916
 917     if (!str) return list;
 918     if (!list)
 919     {
 920         list = xmalloc( sizeof(*list) );
 921         list_init( list );
 922     }
 923     entry = xmalloc( sizeof(*entry) );
 924     entry->str = str;
 925     list_add_tail( list, &entry->entry );
 926     return list;
 927 }
 928
 929 static attr_list_t *append_attr(attr_list_t *list, attr_t *attr)
 930 {
 931     if (!attr) return list;
 932     if (!list)
 933     {
 934         list = xmalloc( sizeof(*list) );
 935         list_init( list );
 936     }
 937     list_add_tail( list, &attr->entry );
 938     return list;
 939 }
 940
 941 static attr_t *make_attr(enum attr_type type)
 942 {
 943   attr_t *a = xmalloc(sizeof(attr_t));
 944   a->type = type;
 945   a->u.ival = 0;
 946   return a;
 947 }
 948
 949 static attr_t *make_attrv(enum attr_type type, unsigned long val)
 950 {
 951   attr_t *a = xmalloc(sizeof(attr_t));
 952   a->type = type;
 953   a->u.ival = val;
 954   return a;
 955 }
 956
 957 static attr_t *make_attrp(enum attr_type type, void *val)
 958 {
 959   attr_t *a = xmalloc(sizeof(attr_t));
 960   a->type = type;
 961   a->u.pval = val;
 962   return a;
 963 }
 964
 965 static expr_t *make_expr(enum expr_type type)
 966 {
 967   expr_t *e = xmalloc(sizeof(expr_t));
 968   e->type = type;
 969   e->ref = NULL;
 970   e->u.lval = 0;
 971   e->is_const = FALSE;
 972   return e;
 973 }
 974
 975 static expr_t *make_exprl(enum expr_type type, long val)
 976 {
 977   expr_t *e = xmalloc(sizeof(expr_t));
 978   e->type = type;
 979   e->ref = NULL;
 980   e->u.lval = val;
 981   e->is_const = FALSE;
 982   /* check for numeric constant */
 983   if (type == EXPR_NUM || type == EXPR_HEXNUM || type == EXPR_TRUEFALSE) {
 984     /* make sure true/false value is valid */
 985     assert(type != EXPR_TRUEFALSE || val == 0 || val == 1);
 986     e->is_const = TRUE;
 987     e->cval = val;
 988   }
 989   return e;
 990 }
 991
 992 static expr_t *make_exprs(enum expr_type type, char *val)
 993 {
 994   expr_t *e;
 995   e = xmalloc(sizeof(expr_t));
 996   e->type = type;
 997   e->ref = NULL;
 998   e->u.sval = val;
 999   e->is_const = FALSE;
1000   /* check for predefined constants */
1001   if (type == EXPR_IDENTIFIER) {
1002     var_t *c = find_const(val, 0);
1003     if (c) {
1004       e->u.sval = c->name;
1005       free(val);
1006       e->is_const = TRUE;
1007       e->cval = c->eval->cval;
1008     }
1009   }
1010   return e;
1011 }
1012
1013 static expr_t *make_exprt(enum expr_type type, type_t *tref, expr_t *expr)
1014 {
1015   expr_t *e;
1016   e = xmalloc(sizeof(expr_t));
1017   e->type = type;
1018   e->ref = expr;
1019   e->u.tref = tref;
1020   e->is_const = FALSE;
1021   /* check for cast of constant expression */
1022   if (type == EXPR_SIZEOF) {
1023     switch (tref->type) {
1024       case RPC_FC_BYTE:
1025       case RPC_FC_CHAR:
1026       case RPC_FC_SMALL:
1027       case RPC_FC_USMALL:
1028         e->is_const = TRUE;
1029         e->cval = 1;
1030         break;
1031       case RPC_FC_WCHAR:
1032       case RPC_FC_USHORT:
1033       case RPC_FC_SHORT:
1034         e->is_const = TRUE;
1035         e->cval = 2;
1036         break;
1037       case RPC_FC_LONG:
1038       case RPC_FC_ULONG:
1039       case RPC_FC_FLOAT:
1040       case RPC_FC_ERROR_STATUS_T:
1041         e->is_const = TRUE;
1042         e->cval = 4;
1043         break;
1044       case RPC_FC_HYPER:
1045       case RPC_FC_DOUBLE:
1046         e->is_const = TRUE;
1047         e->cval = 8;
1048         break;
1049     }
1050   }
1051   if (type == EXPR_CAST && expr->is_const) {
1052     e->is_const = TRUE;
1053     e->cval = expr->cval;
1054   }
1055   return e;
1056 }
1057
1058 static expr_t *make_expr1(enum expr_type type, expr_t *expr)
1059 {
1060   expr_t *e;
1061   e = xmalloc(sizeof(expr_t));
1062   e->type = type;
1063   e->ref = expr;
1064   e->u.lval = 0;
1065   e->is_const = FALSE;
1066   /* check for compile-time optimization */
1067   if (expr->is_const) {
1068     e->is_const = TRUE;
1069     switch (type) {
1070     case EXPR_NEG:
1071       e->cval = -expr->cval;
1072       break;
1073     case EXPR_NOT:
1074       e->cval = ~expr->cval;
1075       break;
1076     default:
1077       e->is_const = FALSE;
1078       break;
1079     }
1080   }
1081   return e;
1082 }
1083
1084 static expr_t *make_expr2(enum expr_type type, expr_t *expr1, expr_t *expr2)
1085 {
1086   expr_t *e;
1087   e = xmalloc(sizeof(expr_t));
1088   e->type = type;
1089   e->ref = expr1;
1090   e->u.ext = expr2;
1091   e->is_const = FALSE;
1092   /* check for compile-time optimization */
1093   if (expr1->is_const && expr2->is_const) {
1094     e->is_const = TRUE;
1095     switch (type) {
1096     case EXPR_ADD:
1097       e->cval = expr1->cval + expr2->cval;
1098       break;
1099     case EXPR_SUB:
1100       e->cval = expr1->cval - expr2->cval;
1101       break;
1102     case EXPR_MUL:
1103       e->cval = expr1->cval * expr2->cval;
1104       break;
1105     case EXPR_DIV:
1106       e->cval = expr1->cval / expr2->cval;
1107       break;
1108     case EXPR_OR:
1109       e->cval = expr1->cval | expr2->cval;
1110       break;
1111     case EXPR_AND:
1112       e->cval = expr1->cval & expr2->cval;
1113       break;
1114     case EXPR_SHL:
1115       e->cval = expr1->cval << expr2->cval;
1116       break;
1117     case EXPR_SHR:
1118       e->cval = expr1->cval >> expr2->cval;
1119       break;
1120     default:
1121       e->is_const = FALSE;
1122       break;
1123     }
1124   }
1125   return e;
1126 }
1127
1128 static expr_t *make_expr3(enum expr_type type, expr_t *expr1, expr_t *expr2, expr_t *expr3)
1129 {
1130   expr_t *e;
1131   e = xmalloc(sizeof(expr_t));
1132   e->type = type;
1133   e->ref = expr1;
1134   e->u.ext = expr2;
1135   e->ext2 = expr3;
1136   e->is_const = FALSE;
1137   /* check for compile-time optimization */
1138   if (expr1->is_const && expr2->is_const && expr3->is_const) {
1139     e->is_const = TRUE;
1140     switch (type) {
1141     case EXPR_COND:
1142       e->cval = expr1->cval ? expr2->cval : expr3->cval;
1143       break;
1144     default:
1145       e->is_const = FALSE;
1146       break;
1147     }
1148   }
1149   return e;
1150 }
1151
1152 static expr_list_t *append_expr(expr_list_t *list, expr_t *expr)
1153 {
1154     if (!expr) return list;
1155     if (!list)
1156     {
1157         list = xmalloc( sizeof(*list) );
1158         list_init( list );
1159     }
1160     list_add_tail( list, &expr->entry );
1161     return list;
1162 }
1163
1164 static array_dims_t *append_array(array_dims_t *list, expr_t *expr)
1165 {
1166     if (!expr) return list;
1167     if (!list)
1168     {
1169         list = xmalloc( sizeof(*list) );
1170         list_init( list );
1171     }
1172     list_add_tail( list, &expr->entry );
1173     return list;
1174 }
1175
1176 static type_t *make_type(unsigned char type, type_t *ref)
1177 {
1178   type_t *t = xmalloc(sizeof(type_t));
1179   t->name = NULL;
1180   t->kind = TKIND_PRIMITIVE;
1181   t->type = type;
1182   t->ref = ref;
1183   t->attrs = NULL;
1184   t->orig = NULL;
1185   t->funcs = NULL;
1186   t->fields = NULL;
1187   t->ifaces = NULL;
1188   t->ignore = parse_only;
1189   t->is_const = FALSE;
1190   t->sign = 0;
1191   t->defined = FALSE;
1192   t->written = FALSE;
1193   t->user_types_registered = FALSE;
1194   t->typelib_idx = -1;
1195   return t;
1196 }
1197
1198 static void set_type(var_t *v, type_t *type, array_dims_t *arr)
1199 {
1200   v->type = type;
1201   v->array = arr;
1202 }
1203
1204 static ifref_list_t *append_ifref(ifref_list_t *list, ifref_t *iface)
1205 {
1206     if (!iface) return list;
1207     if (!list)
1208     {
1209         list = xmalloc( sizeof(*list) );
1210         list_init( list );
1211     }
1212     list_add_tail( list, &iface->entry );
1213     return list;
1214 }
1215
1216 static ifref_t *make_ifref(type_t *iface)
1217 {
1218   ifref_t *l = xmalloc(sizeof(ifref_t));
1219   l->iface = iface;
1220   l->attrs = NULL;
1221   return l;
1222 }
1223
1224 static var_list_t *append_var(var_list_t *list, var_t *var)
1225 {
1226     if (!var) return list;
1227     if (!list)
1228     {
1229         list = xmalloc( sizeof(*list) );
1230         list_init( list );
1231     }
1232     list_add_tail( list, &var->entry );
1233     return list;
1234 }
1235
1236 static var_t *make_var(char *name)
1237 {
1238   var_t *v = xmalloc(sizeof(var_t));
1239   v->name = name;
1240   v->ptr_level = 0;
1241   v->type = NULL;
1242   v->args = NULL;
1243   v->tname = NULL;
1244   v->attrs = NULL;
1245   v->array = NULL;
1246   v->eval = NULL;
1247   return v;
1248 }
1249
1250 static func_list_t *append_func(func_list_t *list, func_t *func)
1251 {
1252     if (!func) return list;
1253     if (!list)
1254     {
1255         list = xmalloc( sizeof(*list) );
1256         list_init( list );
1257     }
1258     list_add_tail( list, &func->entry );
1259     return list;
1260 }
1261
1262 static func_t *make_func(var_t *def, var_list_t *args)
1263 {
1264   func_t *f = xmalloc(sizeof(func_t));
1265   f->def = def;
1266   f->args = args;
1267   f->ignore = parse_only;
1268   f->idx = -1;
1269   return f;
1270 }
1271
1272 static type_t *make_class(char *name)
1273 {
1274   type_t *c = make_type(0, NULL);
1275   c->name = name;
1276   c->kind = TKIND_COCLASS;
1277   return c;
1278 }
1279
1280 static type_t *make_safearray(type_t *type)
1281 {
1282   type_t *sa = duptype(find_type("SAFEARRAY", 0), 1);
1283   type_t *ptr;
1284
1285   sa->ref = type;
1286   ptr = make_type(RPC_FC_FP, sa);
1287   ptr->name = xstrdup("SAFEARRAY");
1288
1289   return ptr;
1290 }
1291
1292 #define HASHMAX 64
1293
1294 static int hash_ident(const char *name)
1295 {
1296   const char *p = name;
1297   int sum = 0;
1298   /* a simple sum hash is probably good enough */
1299   while (*p) {
1300     sum += *p;
1301     p++;
1302   }
1303   return sum & (HASHMAX-1);
1304 }
1305
1306 /***** type repository *****/
1307
1308 struct rtype {
1309   const char *name;
1310   type_t *type;
1311   int t;
1312   struct rtype *next;
1313 };
1314
1315 struct rtype *type_hash[HASHMAX];
1316
1317 static type_t *reg_type(type_t *type, const char *name, int t)
1318 {
1319   struct rtype *nt;
1320   int hash;
1321   if (!name) {
1322     yyerror("registering named type without name");
1323     return type;
1324   }
1325   hash = hash_ident(name);
1326   nt = xmalloc(sizeof(struct rtype));
1327   nt->name = name;
1328   nt->type = type;
1329   nt->t = t;
1330   nt->next = type_hash[hash];
1331   type_hash[hash] = nt;
1332   return type;
1333 }
1334
1335 static type_t *reg_typedefs(type_t *type, var_list_t *names, attr_list_t *attrs)
1336 {
1337   type_t *ptr = type;
1338   const var_t *name;
1339   int ptrc = 0;
1340   int is_str = is_attr(attrs, ATTR_STRING);
1341   unsigned char ptr_type = get_attrv(attrs, ATTR_POINTERTYPE);
1342
1343   if (is_str)
1344   {
1345     type_t *t = type;
1346     unsigned char c;
1347
1348     while (is_ptr(t))
1349       t = t->ref;
1350
1351     c = t->type;
1352     if (c != RPC_FC_CHAR && c != RPC_FC_BYTE && c != RPC_FC_WCHAR)
1353     {
1354       name = LIST_ENTRY( list_head( names ), const var_t, entry );
1355       yyerror("'%s': [string] attribute is only valid on 'char', 'byte', or 'wchar_t' pointers and arrays",
1356               name->name);
1357     }
1358   }
1359
1360   /* We must generate names for tagless enum, struct or union.
1361      Typedef-ing a tagless enum, struct or union means we want the typedef
1362      to be included in a library whether it has other attributes or not,
1363      hence the public attribute.  */
1364   if ((type->kind == TKIND_ENUM || type->kind == TKIND_RECORD
1365        || type->kind == TKIND_UNION) && ! type->name && ! parse_only)
1366   {
1367     if (! is_attr(attrs, ATTR_PUBLIC))
1368       attrs = append_attr( attrs, make_attr(ATTR_PUBLIC) );
1369     type->name = gen_name();
1370   }
1371
1372   LIST_FOR_EACH_ENTRY( name, names, const var_t, entry )
1373   {
1374     if (name->name) {
1375       type_t *cur = ptr;
1376       int cptr = name->ptr_level;
1377       if (cptr > ptrc) {
1378         while (cptr > ptrc) {
1379           cur = ptr = make_type(RPC_FC_RP, cur);
1380           ptrc++;
1381         }
1382       } else {
1383         while (cptr < ptrc) {
1384           cur = cur->ref;
1385           cptr++;
1386         }
1387       }
1388       cur = alias(cur, name->name);
1389       cur->attrs = attrs;
1390       if (ptr_type)
1391       {
1392         if (is_ptr(cur))
1393           cur->type = ptr_type;
1394         else
1395           yyerror("'%s': pointer attribute applied to non-pointer type",
1396                   cur->name);
1397       }
1398       else if (is_str && ! is_ptr(cur))
1399         yyerror("'%s': [string] attribute applied to non-pointer type",
1400                 cur->name);
1401
1402       reg_type(cur, cur->name, 0);
1403     }
1404   }
1405   return type;
1406 }
1407
1408 static type_t *find_type(const char *name, int t)
1409 {
1410   struct rtype *cur = type_hash[hash_ident(name)];
1411   while (cur && (cur->t != t || strcmp(cur->name, name)))
1412     cur = cur->next;
1413   if (!cur) {
1414     yyerror("type '%s' not found", name);
1415     return NULL;
1416   }
1417   return cur->type;
1418 }
1419
1420 static type_t *find_type2(char *name, int t)
1421 {
1422   type_t *tp = find_type(name, t);
1423   free(name);
1424   return tp;
1425 }
1426
1427 int is_type(const char *name)
1428 {
1429   struct rtype *cur = type_hash[hash_ident(name)];
1430   while (cur && (cur->t || strcmp(cur->name, name)))
1431     cur = cur->next;
1432   if (cur) return TRUE;
1433   return FALSE;
1434 }
1435
1436 static type_t *get_type(unsigned char type, char *name, int t)
1437 {
1438   struct rtype *cur = NULL;
1439   type_t *tp;
1440   if (name) {
1441     cur = type_hash[hash_ident(name)];
1442     while (cur && (cur->t != t || strcmp(cur->name, name)))
1443       cur = cur->next;
1444   }
1445   if (cur) {
1446     free(name);
1447     return cur->type;
1448   }
1449   tp = make_type(type, NULL);
1450   tp->name = name;
1451   if (!name) return tp;
1452   return reg_type(tp, name, t);
1453 }
1454
1455 static type_t *get_typev(unsigned char type, var_t *name, int t)
1456 {
1457   char *sname = NULL;
1458   if (name) {
1459     sname = name->name;
1460     free(name);
1461   }
1462   return get_type(type, sname, t);
1463 }
1464
1465 static int get_struct_type(var_list_t *fields)
1466 {
1467   int has_pointer = 0;
1468   int has_conformance = 0;
1469   int has_variance = 0;
1470   var_t *field;
1471
1472   if (fields) LIST_FOR_EACH_ENTRY( field, fields, var_t, entry )
1473   {
1474     type_t *t = field->type;
1475
1476     if (field->ptr_level > 0)
1477     {
1478         has_pointer = 1;
1479         continue;
1480     }
1481
1482     if (is_string_type(field->attrs, 0, field->array))
1483     {
1484         has_conformance = 1;
1485         has_variance = 1;
1486         continue;
1487     }
1488
1489     if (is_array_type(field->attrs, 0, field->array))
1490     {
1491         if (field->array && is_conformant_array(field->array))
1492         {
1493             has_conformance = 1;
1494             if (list_next( fields, &field->entry ))
1495                 yyerror("field '%s' deriving from a conformant array must be the last field in the structure",
1496                         field->name);
1497         }
1498         if (is_attr(field->attrs, ATTR_LENGTHIS))
1499             has_variance = 1;
1500     }
1501
1502     switch (t->type)
1503     {
1504     /*
1505      * RPC_FC_BYTE, RPC_FC_STRUCT, etc
1506      *  Simple types don't effect the type of struct.
1507      *  A struct containing a simple struct is still a simple struct.
1508      *  So long as we can block copy the data, we return RPC_FC_STRUCT.
1509      */
1510     case 0: /* void pointer */
1511     case RPC_FC_BYTE:
1512     case RPC_FC_CHAR:
1513     case RPC_FC_SMALL:
1514     case RPC_FC_USMALL:
1515     case RPC_FC_WCHAR:
1516     case RPC_FC_SHORT:
1517     case RPC_FC_USHORT:
1518     case RPC_FC_LONG:
1519     case RPC_FC_ULONG:
1520     case RPC_FC_INT3264:
1521     case RPC_FC_UINT3264:
1522     case RPC_FC_HYPER:
1523     case RPC_FC_FLOAT:
1524     case RPC_FC_DOUBLE:
1525     case RPC_FC_STRUCT:
1526     case RPC_FC_ENUM16:
1527     case RPC_FC_ENUM32:
1528       break;
1529
1530     case RPC_FC_RP:
1531     case RPC_FC_UP:
1532     case RPC_FC_FP:
1533     case RPC_FC_OP:
1534       has_pointer = 1;
1535       break;
1536     case RPC_FC_CARRAY:
1537       has_conformance = 1;
1538       if (list_next( fields, &field->entry ))
1539           yyerror("field '%s' deriving from a conformant array must be the last field in the structure",
1540                   field->name);
1541       break;
1542
1543     /*
1544      * Propagate member attributes
1545      *  a struct should be at least as complex as its member
1546      */
1547     case RPC_FC_CVSTRUCT:
1548       has_conformance = 1;
1549       has_variance = 1;
1550       has_pointer = 1;
1551       break;
1552
1553     case RPC_FC_CPSTRUCT:
1554       has_conformance = 1;
1555       if (list_next( fields, &field->entry ))
1556           yyerror("field '%s' deriving from a conformant array must be the last field in the structure",
1557                   field->name);
1558       has_pointer = 1;
1559       break;
1560
1561     case RPC_FC_CSTRUCT:
1562       has_conformance = 1;
1563       if (list_next( fields, &field->entry ))
1564           yyerror("field '%s' deriving from a conformant array must be the last field in the structure",
1565                   field->name);
1566       break;
1567
1568     case RPC_FC_PSTRUCT:
1569       has_pointer = 1;
1570       break;
1571
1572     default:
1573       fprintf(stderr,"Unknown struct member %s with type (0x%02x)\n",
1574               field->name, t->type);
1575       /* fallthru - treat it as complex */
1576
1577     /* as soon as we see one of these these members, it's bogus... */
1578     case RPC_FC_IP:
1579     case RPC_FC_ENCAPSULATED_UNION:
1580     case RPC_FC_NON_ENCAPSULATED_UNION:
1581     case RPC_FC_TRANSMIT_AS:
1582     case RPC_FC_REPRESENT_AS:
1583     case RPC_FC_PAD:
1584     case RPC_FC_EMBEDDED_COMPLEX:
1585     case RPC_FC_BOGUS_STRUCT:
1586       return RPC_FC_BOGUS_STRUCT;
1587     }
1588   }
1589
1590   if( has_variance )
1591     return RPC_FC_CVSTRUCT;
1592   if( has_conformance && has_pointer )
1593     return RPC_FC_CPSTRUCT;
1594   if( has_conformance )
1595     return RPC_FC_CSTRUCT;
1596   if( has_pointer )
1597     return RPC_FC_PSTRUCT;
1598   return RPC_FC_STRUCT;
1599 }
1600
1601 /***** constant repository *****/
1602
1603 struct rconst {
1604   char *name;
1605   var_t *var;
1606   struct rconst *next;
1607 };
1608
1609 struct rconst *const_hash[HASHMAX];
1610
1611 static var_t *reg_const(var_t *var)
1612 {
1613   struct rconst *nc;
1614   int hash;
1615   if (!var->name) {
1616     yyerror("registering constant without name");
1617     return var;
1618   }
1619   hash = hash_ident(var->name);
1620   nc = xmalloc(sizeof(struct rconst));
1621   nc->name = var->name;
1622   nc->var = var;
1623   nc->next = const_hash[hash];
1624   const_hash[hash] = nc;
1625   return var;
1626 }
1627
1628 static var_t *find_const(char *name, int f)
1629 {
1630   struct rconst *cur = const_hash[hash_ident(name)];
1631   while (cur && strcmp(cur->name, name))
1632     cur = cur->next;
1633   if (!cur) {
1634     if (f) yyerror("constant '%s' not found", name);
1635     return NULL;
1636   }
1637   return cur->var;
1638 }
1639
1640 static void write_libid(const char *name, const attr_list_t *attr)
1641 {
1642   const UUID *uuid = get_attrp(attr, ATTR_UUID);
1643   write_guid(idfile, "LIBID", name, uuid);
1644 }
1645
1646 static void write_clsid(type_t *cls)
1647 {
1648   const UUID *uuid = get_attrp(cls->attrs, ATTR_UUID);
1649   write_guid(idfile, "CLSID", cls->name, uuid);
1650 }
1651
1652 static void write_diid(type_t *iface)
1653 {
1654   const UUID *uuid = get_attrp(iface->attrs, ATTR_UUID);
1655   write_guid(idfile, "DIID", iface->name, uuid);
1656 }
1657
1658 static void write_iid(type_t *iface)
1659 {
1660   const UUID *uuid = get_attrp(iface->attrs, ATTR_UUID);
1661   write_guid(idfile, "IID", iface->name, uuid);
1662 }
1663
1664 static int compute_method_indexes(type_t *iface)
1665 {
1666   int idx;
1667   func_t *f;
1668
1669   if (iface->ref)
1670     idx = compute_method_indexes(iface->ref);
1671   else
1672     idx = 0;
1673
1674   if (!iface->funcs)
1675     return idx;
1676
1677   LIST_FOR_EACH_ENTRY( f, iface->funcs, func_t, entry )
1678     if (! is_callas(f->def->attrs))
1679       f->idx = idx++;
1680
1681   return idx;
1682 }
1683
1684 static char *gen_name(void)
1685 {
1686   static const char format[] = "__WIDL_%s_generated_name_%08lX";
1687   static unsigned long n = 0;
1688   static const char *file_id;
1689   static size_t size;
1690   char *name;
1691
1692   if (! file_id)
1693   {
1694     char *dst = dup_basename(input_name, ".idl");
1695     file_id = dst;
1696
1697     for (; *dst; ++dst)
1698       if (! isalnum((unsigned char) *dst))
1699         *dst = '_';
1700
1701     size = sizeof format - 7 + strlen(file_id) + 8;
1702   }
1703
1704   name = xmalloc(size);
1705   sprintf(name, format, file_id, n++);
1706   return name;
1707 }
1708
1709 static void process_typedefs(var_list_t *names)
1710 {
1711   var_t *name, *next;
1712
1713   if (!names) return;
1714   LIST_FOR_EACH_ENTRY_SAFE( name, next, names, var_t, entry )
1715   {
1716     type_t *type = find_type(name->name, 0);
1717
1718     if (! parse_only && do_header)
1719       write_typedef(type);
1720     if (in_typelib && type->attrs)
1721       add_typelib_entry(type);
1722
1723     free(name);
1724   }
1725 }
1726
1727 static void check_arg(var_t *arg)
1728 {
1729   type_t *t = arg->type;
1730
1731   if (t->type == 0 && ! is_var_ptr(arg))
1732     yyerror("argument '%s' has void type", arg->name);
1733 }