git.oblomov.eu Git - wine/blob - aclocal.m4

   1 dnl Macros used to build the Wine configure script
   2 dnl
   3 dnl Copyright 2002 Alexandre Julliard
   4 dnl
   5 dnl This library is free software; you can redistribute it and/or
   6 dnl modify it under the terms of the GNU Lesser General Public
   7 dnl License as published by the Free Software Foundation; either
   8 dnl version 2.1 of the License, or (at your option) any later version.
   9 dnl
  10 dnl This library is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 dnl Lesser General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU Lesser General Public
  16 dnl License along with this library; if not, write to the Free Software
  17 dnl Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  18 dnl
  19 dnl As a special exception to the GNU Lesser General Public License,
  20 dnl if you distribute this file as part of a program that contains a
  21 dnl configuration script generated by Autoconf, you may include it
  22 dnl under the same distribution terms that you use for the rest of
  23 dnl that program.
  24
  25 dnl **** Get the ldd program name; used by WINE_GET_SONAME ****
  26 dnl
  27 dnl Usage: WINE_PATH_LDD
  28 dnl
  29 AC_DEFUN([WINE_PATH_LDD],[AC_PATH_PROG(LDD,ldd,true,/sbin:/usr/sbin:$PATH)])
  30
  31 dnl **** Extract the soname of a library ****
  32 dnl
  33 dnl Usage: WINE_GET_SONAME(LIBRARY, FUNCTION, [OTHER_LIBRARIES])
  34 dnl
  35 AC_DEFUN([WINE_GET_SONAME],
  36 [AC_REQUIRE([WINE_PATH_LDD])dnl
  37 AS_VAR_PUSHDEF([ac_Lib],[ac_cv_lib_soname_$1])dnl
  38 AC_CACHE_CHECK([for -l$1 soname], ac_Lib,
  39 [ac_get_soname_save_LIBS=$LIBS
  40 LIBS="-l$1 $3 $LIBS"
  41   AC_LINK_IFELSE([AC_LANG_CALL([], [$2])],
  42   [case "$LIBEXT" in
  43     dylib) AS_VAR_SET(ac_Lib,[`otool -L conftest$ac_exeext | grep lib$1\\.[[0-9A-Za-z.]]*dylib | sed -e "s/^.*\/\(lib$1\.[[0-9A-Za-z.]]*dylib\).*$/\1/"';2,$d'`]) ;;
  44     so) AS_VAR_SET(ac_Lib,[`$ac_cv_path_LDD conftest$ac_exeext | grep lib$1\\.so | sed -e "s/^.*\(lib$1\.so[[^   ]]*\).*$/\1/"';2,$d'`]) ;;
  45   esac
  46   if test "x$ac_Lib" = "x"
  47   then
  48      AS_VAR_SET(ac_Lib,"lib$1.$LIBEXT")
  49   fi],
  50   [AS_VAR_SET(ac_Lib,"lib$1.$LIBEXT")])
  51   LIBS=$ac_get_soname_save_LIBS])
  52 AS_VAR_SET_IF(ac_Lib,[AC_DEFINE_UNQUOTED(AS_TR_CPP(SONAME_LIB$1),["]AS_VAR_GET(ac_Lib)["],
  53                         [Define to the soname of the lib$1 library.])])dnl
  54 AS_VAR_POPDEF([ac_Lib])])
  55
  56 dnl **** Link C code with an assembly file ****
  57 dnl
  58 dnl Usage: WINE_TRY_ASM_LINK(asm-code,includes,function,[action-if-found,[action-if-not-found]])
  59 dnl
  60 AC_DEFUN([WINE_TRY_ASM_LINK],
  61 [AC_LINK_IFELSE(AC_LANG_PROGRAM([[$2]],[[asm($1); $3]]),[$4],[$5])])
  62
  63 dnl **** Check if we can link an empty program with special CFLAGS ****
  64 dnl
  65 dnl Usage: WINE_TRY_CFLAGS(flags,[action-if-yes,[action-if-no]])
  66 dnl
  67 dnl The default action-if-yes is to append the flags to EXTRACFLAGS.
  68 dnl
  69 AC_DEFUN([WINE_TRY_CFLAGS],
  70 [AS_VAR_PUSHDEF([ac_var], ac_cv_cflags_[[$1]])dnl
  71 AC_CACHE_CHECK([whether the compiler supports $1], ac_var,
  72 [ac_wine_try_cflags_saved=$CFLAGS
  73 CFLAGS="$CFLAGS $1"
  74 AC_LINK_IFELSE(AC_LANG_PROGRAM(), [AS_VAR_SET(ac_var,yes)], [AS_VAR_SET(ac_var,no)])
  75 CFLAGS=$ac_wine_try_cflags_saved])
  76 AS_IF([test AS_VAR_GET(ac_var) = yes],
  77       [m4_default([$2], [EXTRACFLAGS="$EXTRACFLAGS $1"])], [$3])dnl
  78 AS_VAR_POPDEF([ac_var])])
  79
  80 dnl **** Check if we can link an empty shared lib (no main) with special CFLAGS ****
  81 dnl
  82 dnl Usage: WINE_TRY_SHLIB_FLAGS(flags,[action-if-yes,[action-if-no]])
  83 dnl
  84 AC_DEFUN([WINE_TRY_SHLIB_FLAGS],
  85 [ac_wine_try_cflags_saved=$CFLAGS
  86 CFLAGS="$CFLAGS $1"
  87 AC_LINK_IFELSE([void myfunc() {}],[$2],[$3])
  88 CFLAGS=$ac_wine_try_cflags_saved])
  89
  90 dnl **** Check whether we need to define a symbol on the compiler command line ****
  91 dnl
  92 dnl Usage: WINE_CHECK_DEFINE(name),[action-if-yes,[action-if-no]])
  93 dnl
  94 AC_DEFUN([WINE_CHECK_DEFINE],
  95 [AS_VAR_PUSHDEF([ac_var],[ac_cv_cpp_def_$1])dnl
  96 AC_CACHE_CHECK([whether we need to define $1],ac_var,
  97     AC_EGREP_CPP(yes,[#ifndef $1
  98 yes
  99 #endif],
 100     [AS_VAR_SET(ac_var,yes)],[AS_VAR_SET(ac_var,no)]))
 101 AS_IF([test AS_VAR_GET(ac_var) = yes],
 102       [CFLAGS="$CFLAGS -D$1"
 103   LINTFLAGS="$LINTFLAGS -D$1"])dnl
 104 AS_VAR_POPDEF([ac_var])])
 105
 106 dnl **** Check for functions with some extra libraries ****
 107 dnl
 108 dnl Usage: WINE_CHECK_LIB_FUNCS(funcs,libs,[action-if-found,[action-if-not-found]])
 109 dnl
 110 AC_DEFUN([WINE_CHECK_LIB_FUNCS],
 111 [ac_wine_check_funcs_save_LIBS="$LIBS"
 112 LIBS="$LIBS $2"
 113 AC_CHECK_FUNCS([$1],[$3],[$4])
 114 LIBS="$ac_wine_check_funcs_save_LIBS"])
 115
 116 dnl **** Check for ln ****
 117 dnl
 118 dnl Usage: WINE_PROG_LN
 119 dnl
 120 AC_DEFUN([WINE_PROG_LN],
 121 [AC_MSG_CHECKING([whether ln works])
 122 rm -f conf$$ conf$$.file
 123 echo >conf$$.file
 124 if ln conf$$.file conf$$ 2>/dev/null; then
 125   AC_SUBST(LN,ln)
 126   AC_MSG_RESULT([yes])
 127 else
 128   AC_SUBST(LN,["cp -p"])
 129   AC_MSG_RESULT([no, using $LN])
 130 fi
 131 rm -f conf$$ conf$$.file])
 132
 133 dnl **** Check for a mingw program, trying the various mingw prefixes ****
 134 dnl
 135 dnl Usage: WINE_CHECK_MINGW_PROG(variable,prog,[value-if-not-found],[path])
 136 dnl
 137 AC_DEFUN([WINE_CHECK_MINGW_PROG],
 138 [AC_CHECK_PROGS([$1],
 139    m4_foreach([ac_wine_prefix],
 140               [i586-mingw32msvc, i386-mingw32msvc, i386-mingw32, mingw32, mingw],
 141               [ac_wine_prefix-$2 ]),
 142    [$3],[$4])])
 143
 144
 145 dnl **** Create nonexistent directories from config.status ****
 146 dnl
 147 dnl Usage: WINE_CONFIG_EXTRA_DIR(dirname)
 148 dnl
 149 AC_DEFUN([WINE_CONFIG_EXTRA_DIR],
 150 [AC_CONFIG_COMMANDS([$1],[test -d "$1" || (AC_MSG_NOTICE([creating $1]) && mkdir "$1")])])