git.oblomov.eu Git - wine/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Author: Michael Patra   <micky@marie.physik.tu-berlin.de>
   3 dnl                         <patra@itp1.physik.tu-berlin.de>
   4 AC_REVISION([configure.in 1.00])
   5 AC_INIT(controls/edit.c)
   6 AC_CONFIG_HEADER(include/config.h)
   7 AC_CONFIG_AUX_DIR(tools)
   8
   9 # We want these before the checks, so the checks can modify their values.
  10 LIBS="$LIBS -lm"
  11 test -z "$PROGEXT" && PROGEXT="" AC_SUBST(PROGEXT)
  12
  13 dnl **** Command-line arguments ****
  14
  15 dnl Default values
  16 MAIN_TARGET=emu
  17 LIB_TARGET=libwine.a
  18 ALT_LINK="-L\$(TOPOBJDIR) -lwine"
  19 TRACE_MSGS=yes  # the TRACE() macro
  20 DEBUG_MSGS=yes  # the TRACE(), WARN(), and FIXME() macros.
  21
  22 AC_ARG_ENABLE(emulator,
  23 [  --disable-emulator      build only the Wine library, not the emulator],
  24 [if test "$enableval" = "no"; then MAIN_TARGET="lib"; fi])
  25
  26 AC_ARG_ENABLE(dll,
  27 [  --enable-dll            build the Wine library as a DLL],
  28 [if test "$enableval" = "no"; then : ; else LIB_TARGET="libwine.so.1.0"; fi])
  29
  30 AC_ARG_ENABLE(lib,
  31 [  --disable-lib           build the Wine without building libwine.a],
  32 [if test "$enableval" = "no"; then ALT_LINK="\$(LIBOBJS) \$(X11OBJS)"; LIB_TARGET=""; fi])
  33
  34 dnl AC_ARG_WITH(ipc,
  35 dnl [  --enable-ipc            use inter-process communication for DDE],
  36 dnl [if test "$enableval" = "no"; then : ; else OPTIONS="-DCONFIG_IPC"; fi])
  37
  38 AC_ARG_ENABLE(debug,
  39 [  --disable-debug         compile out all debugging messages],
  40 [if test "$enableval" = "no"; then DEBUG_MSGS="no"; fi])
  41
  42 AC_ARG_ENABLE(trace,
  43 [  --disable-trace         compile out TRACE messages],
  44 [if test "$enableval" = "no"; then TRACE_MSGS="no"; fi])
  45
  46 AC_ARG_WITH(reentrant-x,
  47 [  --without-reentrant-x   compile for use with non-reentrant X libraries])
  48
  49 AC_SUBST(MAIN_TARGET)
  50 AC_SUBST(LIB_TARGET)
  51 AC_SUBST(ALT_LINK)
  52 AC_SUBST(OPTIONS)
  53
  54 if test "$DEBUG_MSGS" = "no"
  55 then
  56     AC_DEFINE(NO_DEBUG_MSGS)
  57     AC_DEFINE(NO_TRACE_MSGS)
  58 else
  59     if test "$TRACE_MSGS" = "no"
  60     then
  61         AC_DEFINE(NO_TRACE_MSGS)
  62     fi
  63 fi
  64
  65 dnl **** Check for some programs ****
  66
  67 AC_PROG_MAKE_SET
  68 AC_PROG_CC
  69 AC_PROG_CPP
  70 AC_PATH_XTRA
  71 AC_PROG_YACC
  72 AC_PROG_LEX
  73 AC_PROG_RANLIB
  74 AC_PROG_INSTALL
  75 AC_PROG_LN_S
  76 AC_CHECK_PROG(C2MAN,c2man,c2man,true)
  77
  78 dnl **** Check for some libraries ****
  79
  80 dnl Check for -li386 for NetBSD and OpenBSD
  81 AC_CHECK_LIB(i386,i386_set_ldt)
  82 dnl Check for -lossaudio for NetBSD
  83 AC_CHECK_LIB(ossaudio,_oss_ioctl)
  84 dnl Check for -lw for Solaris
  85 AC_CHECK_LIB(w,iswalnum)
  86 dnl Check for -lnsl for Solaris
  87 AC_CHECK_FUNCS(gethostbyname)
  88 if test "$ac_cv_func_gethostbyname" = "no"
  89 then
  90     AC_CHECK_LIB(nsl,gethostbyname)
  91 fi
  92 dnl Check for -lxpg4 for FreeBSD
  93 AC_CHECK_LIB(xpg4,setrunelocale)
  94 dnl Check for -ldl
  95 AC_CHECK_LIB(dl,dlopen)
  96 AC_SUBST(XLIB)
  97 if test "$have_x" = "yes"
  98 then
  99     XLIB="-lXpm -lXext -lX11"
 100     dnl Check for -lXpm
 101     dnl FIXME: should be done once we can compile without -lXpm
 102     dnl AC_CHECK_LIB(Xpm,XpmCreatePixmapFromData,AC_DEFINE(HAVE_LIBXXPM) X_PRE_LIBS="$X_PRE_LIBS -lXpm",,$X_LIBS -lXext -lX11)
 103     dnl Check for X Shm extension
 104     AC_CHECK_LIB(Xext,XShmQueryExtension,AC_DEFINE(HAVE_LIBXXSHM),,$X_LIBS -lXext -lX11)
 105     dnl Check for XFree86 DGA extension
 106     AC_CHECK_LIB(Xxf86dga,XF86DGAQueryExtension,AC_DEFINE(HAVE_LIBXXF86DGA) X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga",,$X_LIBS -lXext -lX11)
 107     dnl Check for XFree86 VMODE extension
 108     AC_CHECK_LIB(Xxf86vm,XF86VidModeQueryExtension,AC_DEFINE(HAVE_LIBXXF86VM) X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm",,$X_LIBS -lXext -lX11)
 109     dnl Check for the presence of Mesa
 110     AC_CHECK_LIB(MesaGL,OSMesaCreateContext,AC_DEFINE(HAVE_MESAGL) X_PRE_LIBS="$X_PRE_LIBS -lMesaGL",,$X_LIBS -lXext -lX11 -lm)
 111 else
 112     XLIB=""
 113     X_CFLAGS=""
 114     X_LIBS=""
 115 fi
 116
 117 dnl **** Check which curses lib to use ***
 118 AC_CHECK_LIB(ncurses,waddch)
 119 if test "$ac_cv_lib_ncurses_waddch" = "yes"
 120 then
 121     AC_CHECK_LIB(ncurses,resizeterm,AC_DEFINE(HAVE_RESIZETERM))
 122 else
 123     AC_CHECK_LIB(curses,waddch)
 124     AC_CHECK_LIB(curses,resizeterm,AC_DEFINE(HAVE_RESIZETERM))
 125 fi
 126
 127 dnl **** Check for IPX (currently Linux only) ****
 128 AC_CACHE_CHECK("for GNU style IPX support", ac_cv_c_ipx_gnu,
 129  AC_TRY_COMPILE(
 130    [#include <sys/socket.h>
 131     #include <netipx/ipx.h>],
 132    [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 133    [AC_DEFINE(HAVE_IPX_GNU)
 134     ac_cv_c_ipx_gnu="yes"],
 135    [ac_cv_c_ipx_gnu="no"])
 136  )
 137
 138 if test "$ac_cv_c_ipx_gnu" = "no"
 139 then
 140  AC_CACHE_CHECK("for linux style IPX support", ac_cv_c_ipx_linux,
 141   AC_TRY_COMPILE(
 142     [#include <sys/socket.h>
 143      #include <asm/types.h>
 144      #include <linux/ipx.h>],
 145     [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 146     [AC_DEFINE(HAVE_IPX_LINUX)
 147      ac_cv_c_ipx_linux="yes"],
 148     [ac_cv_c_ipx_linux="no"])
 149   )
 150 fi
 151
 152 dnl **** Check for Open Sound System ****
 153 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
 154
 155 AC_CACHE_CHECK("for Open Sound System",
 156         ac_cv_c_opensoundsystem,
 157         AC_TRY_COMPILE([
 158         #if defined(HAVE_SYS_SOUNDCARD_H)
 159                 #include <sys/soundcard.h>
 160         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 161                 #include <machine/soundcard.h>
 162         #elif defined(HAVE_SOUNDCARD_H)
 163                 #include <soundcard.h>
 164         #endif
 165         ],[
 166
 167 /* check for one of the Open Sound System specific SNDCTL_ defines */
 168 #if !defined(SNDCTL_DSP_STEREO)
 169 #error No open sound system
 170 #endif
 171 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
 172
 173 if test "$ac_cv_c_opensoundsystem" = "yes"
 174 then
 175     AC_DEFINE(HAVE_OSS)
 176 fi
 177
 178 dnl **** Check for union semun ****
 179
 180 AC_CACHE_CHECK("for union semun", ac_cv_c_union_semun,
 181  AC_TRY_COMPILE([#include <sys/types.h>
 182 #include <sys/sem.h>],[union semun foo],
 183                 ac_cv_c_union_semun="yes", ac_cv_c_union_semun="no"))
 184 if test "$ac_cv_c_union_semun" = "yes"
 185 then
 186     AC_DEFINE(HAVE_UNION_SEMUN)
 187 fi
 188
 189 dnl **** If ln -s doesn't work, use cp instead ****
 190 if test "$ac_cv_prog_LN_S" = "ln -s"; then : ; else LN_S=cp ; fi
 191
 192 dnl **** Check for gcc strength-reduce bug ****
 193
 194 if test "x${GCC}" = "xyes"
 195 then
 196   CFLAGS="$CFLAGS -Wall"
 197   AC_CACHE_CHECK( "for gcc strength-reduce bug", ac_cv_c_gcc_strength_bug,
 198                   AC_TRY_RUN([
 199 int main(void) {
 200   static int Array[[3]];
 201   unsigned int B = 3;
 202   int i;
 203   for(i=0; i<B; i++) Array[[i]] = i - 3;
 204   exit( Array[[1]] != -2 );
 205 }],
 206     ac_cv_c_gcc_strength_bug="no",
 207     ac_cv_c_gcc_strength_bug="yes",
 208     ac_cv_c_gcc_strength_bug="yes") )
 209   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 210   then
 211     CFLAGS="$CFLAGS -fno-strength-reduce"
 212   fi
 213 fi
 214
 215 dnl **** Check for underscore on external symbols ****
 216
 217 AC_CACHE_CHECK("whether external symbols need an underscore prefix",
 218                ac_cv_c_extern_prefix,
 219 [saved_libs=$LIBS
 220 LIBS="conftest_asm.s $LIBS"
 221 cat > conftest_asm.s <<EOF
 222         .globl _ac_test
 223 _ac_test:
 224         .long 0
 225 EOF
 226 AC_TRY_LINK([extern int ac_test;],[if (ac_test) return 1],
 227             ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no")
 228 LIBS=$saved_libs])
 229 if test "$ac_cv_c_extern_prefix" = "yes"
 230 then
 231   AC_DEFINE(NEED_UNDERSCORE_PREFIX)
 232 fi
 233
 234 dnl **** Check for .string in assembler ****
 235
 236 AC_CACHE_CHECK("whether assembler accepts .string",
 237                ac_cv_c_asm_string,
 238 [saved_libs=$LIBS
 239 LIBS="conftest_asm.s $LIBS"
 240 cat > conftest_asm.s <<EOF
 241         .string "test"
 242 EOF
 243 AC_TRY_LINK(,,ac_cv_c_asm_string="yes",ac_cv_c_asm_string="no")
 244 LIBS=$saved_libs])
 245 if test "$ac_cv_c_asm_string" = "yes"
 246 then
 247   AC_DEFINE(HAVE_ASM_STRING)
 248 fi
 249
 250 dnl **** Check for working dll ****
 251
 252 DLLFLAGS=""
 253 LDSHARED=""
 254 if test "$LIB_TARGET" = "libwine.so.1.0"
 255 then
 256   AC_CACHE_CHECK("whether we can build a Linux dll",
 257                  ac_cv_c_dll_linux,
 258   [saved_cflags=$CFLAGS
 259   CFLAGS="$CFLAGS -fPIC -shared -Wl,-soname,conftest.so.1.0"
 260   AC_TRY_LINK(,[return 1],ac_cv_c_dll_linux="yes",ac_cv_c_dll_linux="no")
 261   CFLAGS=$saved_cflags
 262   ])
 263   if test "$ac_cv_c_dll_linux" = "yes"
 264   then
 265     DLLFLAGS="-fPIC"
 266     LDSHARED="\$(CC) -shared -Wl,-soname,libwine.so"
 267   else
 268     AC_CACHE_CHECK("whether we can build a NetBSD dll",
 269                    ac_cv_c_dll_netbsd,
 270     [saved_cflags=$CFLAGS
 271     CFLAGS="$CFLAGS -fPIC -Bshareable -Bforcearchive"
 272     AC_TRY_LINK(,[return 1],ac_cv_c_dll_netbsd="yes",ac_cv_c_dll_netbsd="no")
 273     CFLAGS=$saved_cflags
 274     ])
 275     if test "$ac_cv_c_dll_netbsd" = "yes"
 276     then
 277       DLLFLAGS="-fPIC"
 278       LDSHARED="ld -Bshareable -Bforcearchive"
 279     fi
 280   fi
 281   if test "$ac_cv_c_dll_linux" = "no" -a "$ac_cv_c_dll_netbsd" = "no"
 282   then
 283     LIB_TARGET="libwine.a"
 284   fi
 285 fi
 286 AC_SUBST(DLLFLAGS)
 287 AC_SUBST(LDSHARED)
 288
 289 dnl **** Check for reentrant libc ****
 290 dnl
 291 dnl For cross-compiling we blindly assume that libc is reentrant. This is
 292 dnl ok since non-reentrant libc is quite rare (mostly old libc5 versions).
 293
 294 AC_CACHE_CHECK("for reentrant libc", wine_cv_libc_reentrant,
 295   [AC_TRY_RUN([int myerrno = 0;
 296 char buf[256];
 297 int *__errno_location(){return &myerrno;}
 298 main(){connect(0,buf,255); exit(!myerrno);}],
 299   wine_cv_libc_reentrant=yes, wine_cv_libc_reentrant=no,
 300   wine_cv_libc_reentrant=yes ) ] )
 301 if test "$wine_cv_libc_reentrant" = "no"
 302 then
 303   AC_DEFINE(NO_REENTRANT_LIBC)
 304 fi
 305
 306 dnl **** Check for reentrant X libraries ****
 307 dnl
 308 dnl This may fail to determine whether X libraries are reentrant if
 309 dnl AC_PATH_XTRA does not set x_libraries. In this case manual configuration
 310 dnl is possible with the --without-reentrant-x option.
 311
 312 AC_CACHE_CHECK( "for reentrant X libraries", wine_cv_x_reentrant,
 313   [ if test "x$with_reentrant_x" = "xno"
 314     then
 315         wine_cv_x_reentrant=no
 316     else
 317         libX11_ckeck=none
 318         for dir in "$x_libraries" /usr/lib /usr/local/lib /lib; do
 319             if test -r $dir/libX11.so; then
 320                 libX11_check="-D $dir/libX11.so"
 321                 break 1
 322             fi
 323             if test -r $dir/libX11.a; then
 324                 libX11_check="$dir/libX11.a"
 325                 break 1
 326             fi
 327         done
 328         if test "$libX11_check" != "none"; then
 329             if nm $libX11_check | grep __errno_location >/dev/null 2>&1
 330             then
 331                 wine_cv_x_reentrant=yes
 332             else
 333                 wine_cv_x_reentrant=no
 334             fi
 335         else
 336             wine_cv_x_reentrant=unknown
 337         fi
 338     fi ] )
 339 if test "$wine_cv_x_reentrant" = "no"
 340 then
 341   AC_DEFINE(NO_REENTRANT_X11)
 342 fi
 343
 344 dnl **** Check for functions and header files ****
 345
 346 AC_CHECK_FUNCS(clone getpagesize memmove sendmsg sigaltstack strerror stricmp tcgetattr timegm usleep wait4 waitpid vfscanf)
 347 AC_CHECK_HEADERS(wctype.h sys/syscall.h syscall.h sys/param.h sys/vfs.h sys/mount.h sys/statfs.h float.h linux/cdrom.h linux/ucdrom.h sys/cdio.h sys/filio.h sys/modem.h strings.h sys/strtio.h dlfcn.h unistd.h sys/sockio.h net/if.h netinet/in.h sys/file.h libio.h curses.h ncurses.h elf.h)
 348 AC_HEADER_STAT()
 349 AC_C_CONST()
 350 AC_TYPE_SIZE_T()
 351 AC_CHECK_SIZEOF(long long,0)
 352
 353 dnl **** Check for sendmsg in -lsocket if not found above ****
 354
 355 if test $ac_cv_func_sendmsg = no; then
 356     AC_CHECK_LIB(socket,sendmsg)
 357 fi
 358
 359 dnl **** statfs checks ****
 360
 361 if test "$ac_cv_header_sys_vfs_h" = "yes"
 362 then
 363     AC_CACHE_CHECK( "whether sys/vfs.h defines statfs",
 364                     wine_cv_sys_vfs_has_statfs,
 365         AC_TRY_COMPILE([
 366         #include <sys/types.h>
 367         #ifdef HAVE_SYS_PARAM_H
 368         # include <sys/param.h>
 369         #endif
 370         #include <sys/vfs.h>
 371         ],[
 372                 struct statfs stfs;
 373
 374                 memset(&stfs,0,sizeof(stfs));
 375         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
 376         )
 377     )
 378     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
 379     then
 380       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS)
 381     fi
 382 fi
 383
 384 if test "$ac_cv_header_sys_statfs_h" = "yes"
 385 then
 386     AC_CACHE_CHECK( "whether sys/statfs.h defines statfs",
 387                     wine_cv_sys_statfs_has_statfs,
 388         AC_TRY_COMPILE([
 389         #include <sys/types.h>
 390         #ifdef HAVE_SYS_PARAM_H
 391         # include <sys/param.h>
 392         #endif
 393         #include <sys/statfs.h>
 394         ],[
 395                 struct statfs stfs;
 396         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
 397         )
 398     )
 399     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
 400     then
 401       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS)
 402     fi
 403 fi
 404
 405 if test "$ac_cv_header_sys_mount_h" = "yes"
 406 then
 407     AC_CACHE_CHECK( "whether sys/mount.h defines statfs",
 408                     wine_cv_sys_mount_has_statfs,
 409         AC_TRY_COMPILE([
 410         #include <sys/types.h>
 411         #ifdef HAVE_SYS_PARAM_H
 412         # include <sys/param.h>
 413         #endif
 414         #include <sys/mount.h>
 415         ],[
 416                 struct statfs stfs;
 417         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
 418         )
 419     )
 420     if test "$wine_cv_sys_mount_has_statfs" = "yes"
 421     then
 422       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT)
 423     fi
 424 fi
 425
 426 dnl **** FIXME: what about mixed cases, where we need two of them? ***
 427
 428 AC_CACHE_CHECK( "for statfs.f_bfree", wine_cv_statfs_bfree,
 429   [ if test "x$statfs_bfree" = "xno"
 430     then
 431         wine_cv_statfs_bfree=no
 432     else
 433         AC_TRY_COMPILE([
 434         #include <sys/types.h>
 435         #ifdef HAVE_SYS_PARAM_H
 436         # include <sys/param.h>
 437         #endif
 438         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
 439         # include <sys/mount.h>
 440         #else
 441         # ifdef STATFS_DEFINED_BY_SYS_VFS
 442         #  include <sys/vfs.h>
 443         # else
 444         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
 445         #   include <sys/statfs.h>
 446         #  endif
 447         # endif
 448         #endif
 449         ],[
 450                 struct statfs stfs;
 451
 452                 stfs.f_bfree++;
 453         ],wine_cv_statfs_bfree=yes,wine_cv_statfs_bfree=no
 454         )
 455     fi ] )
 456 if test "$wine_cv_statfs_bfree" = "yes"
 457 then
 458   AC_DEFINE(STATFS_HAS_BFREE)
 459 fi
 460
 461 AC_CACHE_CHECK( "for statfs.f_bavail", wine_cv_statfs_bavail,
 462   [ if test "x$statfs_bavail" = "xno"
 463     then
 464         wine_cv_statfs_bavail=no
 465     else
 466         AC_TRY_COMPILE([
 467         #include <sys/types.h>
 468         #ifdef HAVE_SYS_PARAM_H
 469         # include <sys/param.h>
 470         #endif
 471         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
 472         # include <sys/mount.h>
 473         #else
 474         # ifdef STATFS_DEFINED_BY_SYS_VFS
 475         #  include <sys/vfs.h>
 476         # else
 477         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
 478         #   include <sys/statfs.h>
 479         #  endif
 480         # endif
 481         #endif
 482         ],[
 483                 struct statfs stfs;
 484
 485                 stfs.f_bavail++;
 486         ],wine_cv_statfs_bavail=yes,wine_cv_statfs_bavail=no
 487         )
 488     fi ] )
 489 if test "$wine_cv_statfs_bavail" = "yes"
 490 then
 491   AC_DEFINE(STATFS_HAS_BAVAIL)
 492 fi
 493
 494 dnl *** check for working sigaltstack
 495 dnl glibc 2.0x defines it, but it always fails... so it is useless for us.
 496
 497 AC_CACHE_CHECK("for working sigaltstack",
 498         ac_cv_c_working_sigaltstack,
 499         AC_TRY_RUN([
 500         #include <stdio.h>
 501         #include <time.h> /* <sys/time.h> ? bad magic without end */
 502         #include <sys/types.h>
 503         #include <sys/signal.h>
 504         #ifdef HAVE_SYS_PARAM_H
 505         # include <sys/param.h>
 506         #endif
 507         #ifdef HAVE_SYSCALL_H
 508         # include <syscall.h>
 509         #else
 510         # ifdef HAVE_SYS_SYSCALL_H
 511         #  include <sys/syscall.h>
 512         # endif
 513         #endif
 514
 515         unsigned char *xaltstack;
 516
 517         int
 518         main(int argc,char **argv) {
 519             struct sigaltstack  ss;
 520
 521             xaltstack = malloc(16384);
 522             ss.ss_sp    = xaltstack;
 523             ss.ss_size  = 16384;
 524             ss.ss_flags = 0;
 525             if (sigaltstack(&ss, NULL) < 0) {
 526                 /* this catches the glibc case */
 527                 perror("sigaltstack");
 528                 return (1); /* aka exit(1) aka fail */
 529             }
 530             /* assume it works. */
 531             return 0; /* OK */
 532         }
 533         ],
 534         ac_cv_c_working_sigaltstack="yes",
 535         ac_cv_c_working_sigaltstack="no",
 536         ac_cv_c_working_sigaltstack="no"
 537 ))
 538
 539 if test "$ac_cv_c_working_sigaltstack" = "yes"
 540 then
 541     AC_DEFINE(HAVE_WORKING_SIGALTSTACK)
 542 fi
 543
 544
 545 dnl *** check for file descriptor passing with msg_accrights
 546
 547 AC_CACHE_CHECK("for msg_accrights in struct msghdr", ac_cv_c_msg_accrights,
 548  AC_TRY_COMPILE([#include <sys/types.h>
 549 #include <sys/socket.h>],[struct msghdr hdr; hdr.msg_accrights=0],
 550                 ac_cv_c_msg_accrights="yes", ac_cv_c_msg_accrights="no"))
 551 if test "$ac_cv_c_msg_accrights" = "yes"
 552 then
 553     AC_DEFINE(HAVE_MSGHDR_ACCRIGHTS)
 554 fi
 555
 556 dnl **** Generate output files ****
 557
 558 MAKE_RULES=Make.rules
 559 AC_SUBST_FILE(MAKE_RULES)
 560
 561 AC_OUTPUT([
 562 Make.rules
 563 Makefile
 564 console/Makefile
 565 controls/Makefile
 566 debugger/Makefile
 567 dlls/Makefile
 568 dlls/advapi32/Makefile
 569 dlls/comctl32/Makefile
 570 dlls/imagehlp/Makefile
 571 dlls/msacm/Makefile
 572 dlls/msacm32/Makefile
 573 dlls/ntdll/Makefile
 574 dlls/psapi/Makefile
 575 dlls/rasapi32/Makefile
 576 dlls/shell32/Makefile
 577 dlls/winaspi/Makefile
 578 dlls/wnaspi32/Makefile
 579 documentation/Makefile
 580 files/Makefile
 581 graphics/Makefile
 582 graphics/metafiledrv/Makefile
 583 graphics/psdrv/Makefile
 584 graphics/win16drv/Makefile
 585 graphics/x11drv/Makefile
 586 if1632/Makefile
 587 ipc/Makefile
 588 library/Makefile
 589 libtest/Makefile
 590 loader/Makefile
 591 loader/ne/Makefile
 592 loader/dos/Makefile
 593 memory/Makefile
 594 misc/Makefile
 595 miscemu/Makefile
 596 msdos/Makefile
 597 multimedia/Makefile
 598 objects/Makefile
 599 ole/Makefile
 600 programs/Makefile
 601 programs/clock/Makefile
 602 programs/control/Makefile
 603 programs/notepad/Makefile
 604 programs/progman/Makefile
 605 programs/regtest/Makefile
 606 programs/view/Makefile
 607 programs/winhelp/Makefile
 608 programs/winver/Makefile
 609 rc/Makefile
 610 relay32/Makefile
 611 resources/Makefile
 612 scheduler/Makefile
 613 server/Makefile
 614 tools/Makefile
 615 tools/wrc/Makefile
 616 tsx11/Makefile
 617 win32/Makefile
 618 windows/Makefile
 619 windows/ttydrv/Makefile
 620 windows/x11drv/Makefile ])
 621
 622 if test "$have_x" = "no"
 623 then
 624   echo
 625   echo "*** Warning: X development files not found. Wine will be built without"
 626   echo "*** X support, which currently does not work, and would probably not be"
 627   echo "*** what you want anyway. You will need to install devel packages of"
 628   echo "*** Xlib/Xfree86 and Xpm at the very least."
 629 fi
 630
 631 if test "$ac_cv_lib_ncurses_resizeterm" = "no" -a "$ac_cv_lib_ncurses_waddch" = "yes"
 632 then
 633   echo
 634   echo "*** Warning: resizeterm not found in ncurses. Wine will be built without"
 635   echo "*** terminal resize support. Consider upgrading ncurses."
 636 fi
 637
 638 if test "$wine_cv_libc_reentrant" = "no"
 639 then
 640   echo
 641   echo "*** Warning: non-reentrant libc detected. Wine will be build without"
 642   echo "*** thread support. Consider upgrading libc to a more recent"
 643   echo "*** reentrant version of libc."
 644 fi
 645
 646 echo
 647 echo "Configure finished.  Do 'make depend; make' to compile Wine."
 648 echo
 649
 650 dnl Local Variables:
 651 dnl comment-start: "dnl "
 652 dnl comment-end: ""
 653 dnl comment-start-skip: "\\bdnl\\b\\s *"
 654 dnl compile-command: "autoconf"
 655 dnl End: