git.oblomov.eu Git - wine/blob - aclocal.m4

   1 dnl Macros used to build the Wine configure script
   2 dnl
   3 dnl Copyright 2002 Alexandre Julliard
   4 dnl
   5 dnl This library is free software; you can redistribute it and/or
   6 dnl modify it under the terms of the GNU Lesser General Public
   7 dnl License as published by the Free Software Foundation; either
   8 dnl version 2.1 of the License, or (at your option) any later version.
   9 dnl
  10 dnl This library is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 dnl Lesser General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU Lesser General Public
  16 dnl License along with this library; if not, write to the Free Software
  17 dnl Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  18 dnl
  19 dnl As a special exception to the GNU Lesser General Public License,
  20 dnl if you distribute this file as part of a program that contains a
  21 dnl configuration script generated by Autoconf, you may include it
  22 dnl under the same distribution terms that you use for the rest of
  23 dnl that program.
  24
  25 dnl **** Get the ldd program name; used by WINE_GET_SONAME ****
  26 dnl
  27 dnl Usage: WINE_PATH_LDD
  28 dnl
  29 AC_DEFUN([WINE_PATH_LDD],[AC_PATH_PROG(LDD,ldd,true,/sbin:/usr/sbin:$PATH)])
  30
  31 dnl **** Extract the soname of a library ****
  32 dnl
  33 dnl Usage: WINE_GET_SONAME(LIBRARY, FUNCTION, [OTHER_LIBRARIES])
  34 dnl
  35 AC_DEFUN([WINE_GET_SONAME],
  36 [AC_REQUIRE([WINE_PATH_LDD])
  37 AC_CACHE_CHECK([for -l$1 soname], ac_cv_lib_soname_$1,
  38 [ac_get_soname_save_LIBS=$LIBS
  39 LIBS="-l$1 $3 $LIBS"
  40   AC_LINK_IFELSE([AC_LANG_CALL([], [$2])],
  41   [ac_cv_lib_soname_$1=`$ac_cv_path_LDD conftest$ac_exeext | grep lib$1\\.so | sed 's/^[[       ]]*\([[^        ]]*\)[[         ]]*=>.*$/\1/'`
  42   if test "x$ac_cv_lib_soname_$1" = "x"
  43   then
  44      ac_cv_lib_soname_$1="lib$1.so"
  45   fi],
  46   [ac_cv_lib_soname_$1="lib$1.so"])
  47   LIBS=$ac_get_soname_save_LIBS])
  48 if test "x$ac_cv_lib_soname_$1" != xNONE
  49 then AC_DEFINE_UNQUOTED(AS_TR_CPP(SONAME_LIB$1),"$ac_cv_lib_soname_$1",
  50                         [Define to the soname of the lib$1 library.])dnl
  51 fi])
  52
  53 dnl **** Check if a structure contains a specified member ****
  54 dnl
  55 dnl Usage: WINE_CHECK_STRUCT_MEMBER(struct,member,[includes,[action-if-found,[action-if-not-found]]])
  56 dnl
  57 AC_DEFUN([WINE_CHECK_STRUCT_MEMBER],
  58 [AC_CACHE_CHECK([for $2 in struct $1], ac_cv_c_$1_$2,
  59  AC_TRY_COMPILE([$3],[struct $1 s; s.$2 = 0],ac_cv_c_$1_$2="yes",ac_cv_c_$1_$2="no"))
  60 AS_IF([ test "x$ac_cv_c_$1_$2" = "xyes"],[$4],[$5])
  61 ])
  62
  63 dnl **** Check for reentrant libc ****
  64 dnl
  65 dnl Usage: WINE_CHECK_ERRNO(errno-name,[action-if-yes,[action-if-no]])
  66 dnl
  67 dnl For cross-compiling we blindly assume that libc is reentrant. This is
  68 dnl ok since non-reentrant libc is quite rare (mostly old libc5 versions).
  69 dnl
  70 AC_DEFUN([WINE_CHECK_ERRNO],
  71 [AC_CACHE_CHECK([for reentrant libc: $1],[wine_cv_libc_r_$1],
  72   [AC_TRY_RUN([int myerrno = 0;
  73 int *$1(){return &myerrno;}
  74 main(){close(333); close(333); exit(!myerrno);}],
  75   wine_cv_libc_r_$1=yes, wine_cv_libc_r_$1=no,
  76   wine_cv_libc_r_$1=yes)])
  77 AS_IF([test "$wine_cv_libc_r_$1" = "yes"],[$2],[$3])])
  78
  79 dnl **** Link C code with an assembly file ****
  80 dnl
  81 dnl Usage: WINE_TRY_ASM_LINK(asm-code,includes,function,[action-if-found,[action-if-not-found]])
  82 dnl
  83 AC_DEFUN([WINE_TRY_ASM_LINK],
  84 [AC_TRY_LINK([void ac_asm(void) { asm([$1]); }
  85 [$2]],[$3],[$4],[$5])])
  86
  87 dnl **** Check if we can link an empty program with special CFLAGS ****
  88 dnl
  89 dnl Usage: WINE_TRY_CFLAGS(flags,[action-if-yes,[action-if-no]])
  90 dnl
  91 AC_DEFUN([WINE_TRY_CFLAGS],
  92 [ac_wine_try_cflags_saved=$CFLAGS
  93 CFLAGS="$CFLAGS $1"
  94 AC_TRY_LINK([],[],[$2],[$3])
  95 CFLAGS=$ac_wine_try_cflags_saved])
  96
  97 dnl **** Check whether we need to define a symbol on the compiler command line ****
  98 dnl
  99 dnl Usage: WINE_CHECK_DEFINE(name),[action-if-yes,[action-if-no]])
 100 dnl
 101 AC_DEFUN([WINE_CHECK_DEFINE],
 102 [AS_VAR_PUSHDEF([ac_var],[ac_cv_cpp_def_$1])dnl
 103 AC_CACHE_CHECK([whether we need to define $1],ac_var,
 104     AC_EGREP_CPP(yes,[#ifndef $1
 105 yes
 106 #endif],
 107     [AS_VAR_SET(ac_var,yes)],[AS_VAR_SET(ac_var,no)]))
 108 AS_IF([test AS_VAR_GET(ac_var) = yes],
 109       [CFLAGS="$CFLAGS -D$1"
 110   LINTFLAGS="$LINTFLAGS -D$1"])dnl
 111 AS_VAR_POPDEF([ac_var])])
 112
 113 dnl **** Check for ln ****
 114 dnl
 115 dnl Usage: WINE_PROG_LN
 116 dnl
 117 AC_DEFUN([WINE_PROG_LN],
 118 [AC_MSG_CHECKING([whether ln works])
 119 rm -f conf$$ conf$$.file
 120 echo >conf$$.file
 121 if ln conf$$.file conf$$ 2>/dev/null; then
 122   AC_SUBST(LN,ln)
 123   AC_MSG_RESULT([yes])
 124 else
 125   AC_SUBST(LN,["cp -p"])
 126   AC_MSG_RESULT([no, using $LN])
 127 fi
 128 rm -f conf$$ conf$$.file])
 129
 130 dnl **** Create non-existent directories from config.status ****
 131 dnl
 132 dnl Usage: WINE_CONFIG_EXTRA_DIR(dirname)
 133 dnl
 134 AC_DEFUN([WINE_CONFIG_EXTRA_DIR],
 135 [AC_CONFIG_COMMANDS([$1],[test -d "$1" || (AC_MSG_NOTICE([creating $1]) && mkdir "$1")])])