git.oblomov.eu Git - wine/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 AC_PREREQ(2.53b)
   8 AC_INIT([Wine],[WINE_VERSION],[wine-devel@winehq.org])
   9 AC_CONFIG_SRCDIR(server/atom.c)
  10 AC_CONFIG_HEADERS(include/config.h)
  11 AC_CONFIG_AUX_DIR(tools)
  12
  13 dnl **** Command-line arguments ****
  14
  15 AC_ARG_ENABLE(win16, AS_HELP_STRING([--disable-win16],[do not include Win16 support]))
  16 AC_ARG_ENABLE(win64, AS_HELP_STRING([--enable-win64],[build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
  17
  18 AC_ARG_WITH(opengl,    AS_HELP_STRING([--without-opengl],[do not use OpenGL]))
  19 AC_ARG_WITH(wine-tools,AS_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
  20
  21 AC_CANONICAL_HOST
  22 case $host in
  23   x86_64*linux*)
  24     if test "x$enable_win64" != "xyes"
  25     then
  26       test -n "$CC" || CC="gcc -m32"
  27       test -n "$LD" || LD="ld -m elf_i386"
  28       test -n "$AS" || AS="as --32"
  29       host_cpu="i386"
  30     fi
  31     ;;
  32 esac
  33
  34 dnl enable_win16 defaults to yes on x86, to no on other CPUs
  35 case $host_cpu in
  36   *i[[3456789]]86*)
  37     if test "x$enable_win16" != "xno"
  38     then
  39       enable_win16="yes"
  40     fi
  41     ;;
  42 esac
  43
  44 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
  45 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
  46 if test "x$enable_win16" != "xyes"
  47 then
  48   WIN16_FILES=""
  49   WIN16_INSTALL=""
  50 fi
  51
  52 dnl check for out of tree build with unclean source tree
  53 case "$srcdir" in
  54  .) ;;
  55  *) if test -f "$srcdir/Makefile" -o -f "$srcdir/include/config.h"; then
  56       AC_MSG_ERROR([you are building out of the source tree, but the source tree contains object files.
  57 You need to run 'make distclean' in the source tree first.])
  58     fi ;;
  59 esac
  60
  61 dnl **** Check for some programs ****
  62
  63 AC_PROG_MAKE_SET
  64 AC_PROG_CC
  65 AC_PROG_CXX
  66 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
  67 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
  68
  69 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
  70   [if test -z "$with_wine_tools"; then
  71      if test "$cross_compiling" = "yes"; then
  72        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
  73      else
  74        wine_cv_toolsdir="\$(TOPOBJDIR)"
  75      fi
  76    elif test -d "$with_wine_tools/tools/winebuild"; then
  77      case $with_wine_tools in
  78        /*) wine_cv_toolsdir="$with_wine_tools" ;;
  79        *)  wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
  80      esac
  81    else
  82      AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
  83    fi])
  84 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
  85
  86 AC_PATH_XTRA
  87
  88 dnl Check for flex
  89 AC_CHECK_PROGS(FLEX,flex,none)
  90 if test "$FLEX" = "none"
  91 then
  92   AC_MSG_ERROR([no suitable flex found. Please install the 'flex' package.])
  93 fi
  94
  95 dnl Check for bison
  96 AC_CHECK_PROGS(BISON,bison,none)
  97 if test "$BISON" = "none"
  98 then
  99   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
 100 fi
 101
 102 AC_CHECK_TOOLS(AS,[gas as],as)
 103 AC_CHECK_TOOL(LD,ld,ld)
 104 AC_CHECK_TOOL(AR,ar,ar)
 105 AC_PROG_RANLIB
 106 AC_CHECK_TOOL(STRIP,strip,strip)
 107 AC_CHECK_TOOL(WINDRES,windres,false)
 108 AC_PROG_LN_S
 109 WINE_PROG_LN
 110 AC_PROG_EGREP
 111 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
 112 AC_PROG_INSTALL
 113 dnl Prepend src dir to install path dir if it's a relative path
 114 case "$INSTALL" in
 115   [[\\/$]]* | ?:[[\\/]]* ) ;;
 116   *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
 117 esac
 118
 119 dnl Check for lint
 120 AC_CHECK_PROGS(LINT, lclint lint)
 121 if test "$LINT" = "lint"
 122 then
 123   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 124   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 125 fi
 126 AC_SUBST(LINT)
 127 AC_SUBST(LINTFLAGS)
 128
 129 dnl Check for various programs
 130 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
 131 AC_CHECK_PROGS(PKG_CONFIG, pkg-config, false)
 132
 133 case $host_cpu in
 134   *i[[3456789]]86*)
 135     AC_PATH_PROG(PRELINK, prelink, false, [/sbin /usr/sbin $PATH])
 136     ;;
 137 esac
 138
 139 dnl **** Check for some libraries ****
 140
 141 dnl Check for -li386 for NetBSD and OpenBSD
 142 AC_CHECK_LIB(i386,i386_set_ldt)
 143 dnl Check for -lossaudio for NetBSD
 144 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 145 dnl Check for -lxpg4 for FreeBSD
 146 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
 147 dnl Check for -lpthread
 148 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
 149
 150 AC_SUBST(XLIB,"")
 151 AC_SUBST(XFILES,"")
 152 AC_SUBST(OPENGLFILES,"")
 153 AC_SUBST(GLU32FILES,"")
 154 AC_SUBST(OPENGL_LIBS,"")
 155 AC_SUBST(QUARTZFILES,"")
 156
 157 dnl **** Check for header files ****
 158
 159 AC_CHECK_HEADERS(\
 160         AudioUnit/AudioUnit.h \
 161         Carbon/Carbon.h \
 162         CoreAudio/CoreAudio.h \
 163         DiskArbitration/DiskArbitration.h \
 164         IOKit/IOKitLib.h \
 165         alsa/asoundlib.h \
 166         arpa/inet.h \
 167         arpa/nameser.h \
 168         asm/types.h \
 169         capi20.h \
 170         cups/cups.h \
 171         curses.h \
 172         direct.h \
 173         dlfcn.h \
 174         elf.h \
 175         float.h \
 176         fontconfig/fontconfig.h \
 177         getopt.h \
 178         ieeefp.h \
 179         io.h \
 180         jack/jack.h \
 181         jpeglib.h \
 182         lber.h \
 183         lcms.h \
 184         lcms/lcms.h \
 185         ldap.h \
 186         libaudioio.h \
 187         link.h \
 188         linux/cdrom.h \
 189         linux/compiler.h \
 190         linux/hdreg.h \
 191         linux/input.h \
 192         linux/ioctl.h \
 193         linux/joystick.h \
 194         linux/major.h \
 195         linux/param.h \
 196         linux/serial.h \
 197         linux/ucdrom.h \
 198         mach/mach.h \
 199         mach/machine.h \
 200         machine/cpu.h \
 201         machine/limits.h \
 202         machine/soundcard.h \
 203         mntent.h \
 204         ncurses.h \
 205         netdb.h \
 206         netinet/in.h \
 207         netinet/in_systm.h \
 208         netinet/tcp.h \
 209         netinet/tcp_fsm.h \
 210         openssl/err.h \
 211         openssl/ssl.h \
 212         png.h \
 213         poll.h \
 214         process.h \
 215         pthread.h \
 216         pwd.h \
 217         regex.h \
 218         sched.h \
 219         scsi/scsi.h \
 220         scsi/scsi_ioctl.h \
 221         scsi/sg.h \
 222         soundcard.h \
 223         stdint.h \
 224         strings.h \
 225         sys/asoundlib.h \
 226         sys/cdio.h \
 227         sys/elf32.h \
 228         sys/epoll.h \
 229         sys/errno.h \
 230         sys/event.h \
 231         sys/exec_elf.h \
 232         sys/filio.h \
 233         sys/ioctl.h \
 234         sys/ipc.h \
 235         sys/limits.h \
 236         sys/link.h \
 237         sys/lwp.h \
 238         sys/mman.h \
 239         sys/modem.h \
 240         sys/msg.h \
 241         sys/mtio.h \
 242         sys/param.h \
 243         sys/poll.h \
 244         sys/prctl.h \
 245         sys/ptrace.h \
 246         sys/reg.h \
 247         sys/resource.h \
 248         sys/scsiio.h \
 249         sys/shm.h \
 250         sys/signal.h \
 251         sys/socket.h \
 252         sys/sockio.h \
 253         sys/soundcard.h \
 254         sys/statvfs.h \
 255         sys/strtio.h \
 256         sys/syscall.h \
 257         sys/sysctl.h \
 258         sys/time.h \
 259         sys/times.h \
 260         sys/uio.h \
 261         sys/un.h \
 262         sys/vm86.h \
 263         sys/wait.h \
 264         syscall.h \
 265         termios.h \
 266         unicode/ubidi.h \
 267         unistd.h \
 268         utime.h \
 269         valgrind/memcheck.h
 270 )
 271 AC_HEADER_STAT()
 272
 273 dnl **** Checks for headers that depend on other ones ****
 274
 275 AC_CHECK_HEADERS([sys/mount.h sys/statfs.h sys/user.h sys/vfs.h],,,
 276     [#include <sys/types.h>
 277      #if HAVE_SYS_PARAM_H
 278      # include <sys/param.h>
 279      #endif])
 280
 281 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h netipx/ipx.h],,,
 282     [#include <sys/types.h>
 283      #if HAVE_SYS_SOCKET_H
 284      # include <sys/socket.h>
 285      #endif])
 286
 287 AC_CHECK_HEADERS([linux/ipx.h],,,
 288     [#include <sys/types.h>
 289      #ifdef HAVE_ASM_TYPES_H
 290      # include <asm/types.h>
 291      #endif
 292      #if HAVE_SYS_SOCKET_H
 293      # include <sys/socket.h>
 294      #endif])
 295
 296 AC_CHECK_HEADERS([resolv.h],,,
 297     [#include <sys/types.h>
 298      #if HAVE_SYS_SOCKET_H
 299      # include <sys/socket.h>
 300      #endif
 301      #if HAVE_NETINET_IN_H
 302      # include <netinet/in.h>
 303      #endif
 304      #if HAVE_ARPA_NAMESER_H
 305      # include <arpa/nameser.h>
 306      #endif])
 307
 308 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
 309
 310 AC_CHECK_HEADERS([pthread_np.h],,,
 311 [#ifdef HAVE_PTHREAD_H
 312 #include <pthread.h>
 313 #endif])
 314
 315 AC_CHECK_HEADERS([linux/videodev.h],,,
 316 [#ifdef HAVE_SYS_TIME_H
 317 #include <sys/time.h>
 318 #endif
 319 #include <sys/types.h>
 320 #ifdef HAVE_ASM_TYPES_H
 321 #include <asm/types.h>
 322 #endif])
 323
 324 dnl Check for broken kernel header that doesn't define __user
 325 AC_CHECK_HEADERS([linux/capi.h],,,[#define __user])
 326
 327 dnl **** Check for working dll ****
 328
 329 AC_SUBST(DLLEXT,"")
 330 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 331 AC_SUBST(LDSHARED,"")
 332 AC_SUBST(LDDLLFLAGS,"")
 333 AC_SUBST(LIBEXT,"so")
 334 AC_SUBST(IMPLIBEXT,"def")
 335 AC_SUBST(LDRPATH_INSTALL,"")
 336 AC_SUBST(LDRPATH_LOCAL,"")
 337 WINE_PATH_LDD
 338
 339 case $host_os in
 340   cygwin*|mingw32*)
 341     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 342     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 343     AC_CHECK_TOOL(MINGWAR,ar,false)
 344     if test "$DLLWRAP" = "false"; then
 345       LIBEXT="a"
 346     else
 347       dnl FIXME - check whether dllwrap works correctly...
 348       LIBEXT="dll"
 349     fi
 350     IMPLIBEXT="a"
 351     dnl We can't build 16-bit NE dlls
 352     WIN16_FILES=""
 353     WIN16_INSTALL=""
 354     ;;
 355   darwin*|macosx*)
 356     DLLEXT=".so"
 357     LIBEXT="dylib"
 358     DLLFLAGS="$DLLFLAGS -fPIC"
 359     LDDLLFLAGS="-bundle -multiply_defined suppress"
 360     LIBWINE_LDFLAGS="-multiply_defined suppress"
 361     LDSHARED="\$(CC) -dynamiclib"
 362     STRIP="$STRIP -x"
 363     LDRPATH_LOCAL="&& install_name_tool -change @executable_path/\`\$(RELPATH) \$(bindir) \$(libdir)\`/libwine.1.dylib @executable_path/\$(TOPOBJDIR)/libs/wine/libwine.1.dylib \$@ || \$(RM) \$@"
 364     dnl declare needed frameworks
 365     AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
 366     AC_SUBST(IOKITLIB,"-framework IOKit -framework CoreFoundation")
 367     AC_SUBST(LDEXECFLAGS,["-image_base 0x7bf00000 -Wl,-segaddr,WINE_DOS,0x00000000,-segaddr,WINE_SHARED_HEAP,0x7f000000"])
 368     if test "$ac_cv_header_DiskArbitration_DiskArbitration_h" = "yes"
 369     then
 370         dnl DiskArbitration API is not public on Darwin < 8.0, use it only if header found
 371         AC_SUBST(DISKARBITRATIONLIB,"-framework DiskArbitration -framework CoreFoundation")
 372     fi
 373     if test "$ac_cv_header_CoreAudio_CoreAudio_h" = "yes" -a "$ac_cv_header_AudioUnit_AudioUnit_h" = "yes"
 374     then
 375         dnl CoreServices needed by AudioUnit
 376         AC_SUBST(COREAUDIO,"-framework CoreAudio -framework AudioUnit -framework CoreServices -framework AudioToolbox -framework CoreMIDI")
 377     fi
 378     case $host_cpu in
 379       *powerpc*)
 380         LDDLLFLAGS="$LDDLLFLAGS -read_only_relocs warning"  dnl FIXME
 381         ;;
 382     esac
 383     dnl Enable quartz driver on Mac OS X
 384     if test "$ac_cv_header_Carbon_Carbon_h" = "yes"
 385     then
 386         AC_SUBST(CARBONLIB,"-framework Carbon")
 387         QUARTZFILES='$(QUARTZFILES)'
 388     fi
 389     ;;
 390   *)
 391     DLLFLAGS="$DLLFLAGS -fPIC"
 392     DLLEXT=".so"
 393     AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
 394         [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-Bsymbolic],
 395                               ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
 396     if test "$ac_cv_c_dll_gnuelf" = "yes"
 397     then
 398       LDSHARED="\$(CC) -shared"
 399       LDDLLFLAGS="-shared -Wl,-Bsymbolic"
 400       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,confest.so.1],
 401                       [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"],
 402                       [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-h,confest.so.1],
 403                                        [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-h,%)"])])
 404
 405       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs], [LDDLLFLAGS="$LDDLLFLAGS,-z,defs"])
 406
 407       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
 408                       [LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"])
 409
 410       echo '{ global: *; };' >conftest.map
 411       WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
 412                       [LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"])
 413       rm -f conftest.map
 414
 415       WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
 416                       [AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])])
 417
 418       WINE_TRY_CFLAGS([-fPIC -Wl,--rpath,\$ORIGIN/../lib],
 419                       [LDRPATH_INSTALL="-Wl,--rpath,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 420                        LDRPATH_LOCAL="-Wl,--rpath,\\\$\$ORIGIN/\$(TOPOBJDIR)/libs/wine"],
 421           [WINE_TRY_CFLAGS([-fPIC -Wl,-R,\$ORIGIN/../lib],
 422                            [LDRPATH_INSTALL="-Wl,-R,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 423                             LDRPATH_LOCAL="-Wl,-R,\\\$\$ORIGIN/\$(TOPOBJDIR)/libs/wine"])])
 424
 425       case $host_cpu in
 426         *i[[3456789]]86* | x86_64)
 427           WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
 428                           [LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400"])
 429           ;;
 430       esac
 431
 432     else
 433       AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
 434           [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
 435                                 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
 436       if test "$ac_cv_c_dll_unixware" = "yes"
 437       then
 438         LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
 439         LDDLLFLAGS="-Wl,-G,-B,symbolic"
 440
 441       else
 442         AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
 443           [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
 444         if test "$ac_cv_c_dll_hpux" = "yes"
 445         then
 446           LIBEXT="sl"
 447           DLLEXT=".sl"
 448           LDDLLFLAGS="-shared -fPIC"
 449           LDSHARED="\$(CC) -shared"
 450         fi
 451       fi
 452     fi
 453
 454     dnl Check for cross compiler to build test programs
 455     AC_SUBST(CROSSTEST,"")
 456     if test "$cross_compiling" = "no"
 457     then
 458       WINE_CHECK_MINGW_PROG(CROSSCC,gcc,false)
 459       WINE_CHECK_MINGW_PROG(DLLTOOL,dlltool,false)
 460       WINE_CHECK_MINGW_PROG(CROSSWINDRES,windres,false)
 461       WINE_CHECK_MINGW_PROG(MINGWAR,ar,false)
 462       if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
 463     fi
 464     ;;
 465 esac
 466
 467 if test "$LIBEXT" = "a"; then
 468   AC_MSG_ERROR(
 469 [could not find a way to build shared libraries.
 470 It is currently not possible to build Wine without shared library
 471 (.so) support to allow transparent switch between .so and .dll files.
 472 If you are using Linux, you will need a newer binutils.]
 473 )
 474 fi
 475
 476 dnl **** Check for X11 ****
 477
 478 if test "$have_x" = "yes"
 479 then
 480     XLIB="-lXext -lX11"
 481     ac_save_CPPFLAGS="$CPPFLAGS"
 482     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 483
 484     dnl *** All of the following tests require X11/Xlib.h
 485     AC_CHECK_HEADERS([X11/Xlib.h \
 486                       X11/XKBlib.h \
 487                       X11/Xutil.h \
 488                       X11/Xcursor/Xcursor.h \
 489                       X11/extensions/shape.h \
 490                       X11/extensions/XInput.h \
 491                       X11/extensions/XShm.h \
 492                       X11/extensions/Xinerama.h \
 493                       X11/extensions/Xrandr.h \
 494                       X11/extensions/Xrender.h \
 495                       X11/extensions/xf86vmode.h],,,
 496 [#ifdef HAVE_X11_XLIB_H
 497 # include <X11/Xlib.h>
 498 #endif
 499 #ifdef HAVE_X11_XUTIL_H
 500 # include <X11/Xutil.h>
 501 #endif])
 502
 503         dnl *** Check for X keyboard extension
 504         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 505         then
 506               AC_CHECK_LIB(X11, XkbQueryExtension,
 507               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 508               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 509         fi
 510
 511         dnl *** Check for X Shm extension
 512         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 513         then
 514               AC_CHECK_LIB(Xext, XShmQueryExtension,
 515               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 516               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 517         fi
 518
 519         dnl *** Check for X shape extension
 520         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 521         then
 522               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 523               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 524               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 525         fi
 526
 527         dnl *** Check for XFree86 VMODE extension
 528         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 529         then
 530                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 531                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 532                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 533                   ],,
 534                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 535         fi
 536
 537         dnl *** Check for X RandR extension
 538         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
 539         then
 540                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
 541 #include <X11/extensions/Xrandr.h>]], [[static typeof(XRRSetScreenConfigAndRate) * func;]])],
 542                   [AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])],[])
 543         fi
 544
 545         dnl *** Check for Transform functions in Xrender
 546         if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes"
 547         then
 548               AC_CHECK_LIB(Xrender, XRenderSetPictureTransform,
 549                 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
 550                  [Define if Xrender has the XRenderSetPictureTransform function])],,
 551                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 552         fi
 553
 554         dnl *** Check for Xinerama extension
 555         if test "$ac_cv_header_X11_extensions_Xinerama_h" = "yes"
 556         then
 557                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
 558 #include <X11/extensions/Xinerama.h>]], [[static typeof(XineramaQueryScreens) * func;]])],
 559                   [AC_DEFINE(HAVE_LIBXINERAMA, 1, [Define if you have the Xinerama library])],[])
 560         fi
 561
 562     dnl *** End of X11/Xlib.h check
 563
 564     dnl Check for the presence of OpenGL
 565     if test "x$with_opengl" != "xno"
 566     then
 567         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h GL/glu.h,,,
 568 [#ifdef HAVE_GL_GLX_H
 569 # include <GL/glx.h>
 570 #endif])
 571         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 572         then
 573             dnl Check for some problems due to old Mesa versions
 574             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_header_version_OK,
 575               AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GL/gl.h>]], [[GLenum test = GL_UNSIGNED_SHORT_5_6_5;]])],
 576                 [wine_cv_opengl_header_version_OK="yes"],
 577                 [wine_cv_opengl_header_version_OK="no"]))
 578
 579             if test "$wine_cv_opengl_header_version_OK" = "yes"
 580             then
 581                 dnl Check for the presence of the library
 582                 WINE_CHECK_SONAME(GL,glXCreateContext,
 583                              [OPENGL_LIBS="-lGL"
 584                              OPENGLFILES='$(OPENGLFILES)'
 585                              AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])]
 586                              ,,
 587                              [$X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS])
 588
 589                 dnl Check for GLU32 library.
 590                 AC_CHECK_LIB(GLU,gluLookAt,
 591                              [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
 592                              GLU32FILES='$(GLU32FILES)']
 593                              ,,
 594                              $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
 595                 )
 596              fi
 597          else
 598              wine_cv_opengl_headers_found="no"
 599          fi
 600     fi
 601     dnl **** Check for NAS ****
 602     AC_SUBST(NASLIBS,"")
 603     AC_CHECK_HEADERS(audio/audiolib.h,
 604          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
 605           AC_CHECK_LIB(audio,AuCreateFlow,
 606                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
 607                         AC_CHECK_LIB(Xau,XauGetBestAuthByAddr,
 608                           [NASLIBS="-lXau -laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],
 609                           [NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],
 610                           [$X_LIBS])
 611                        ],,
 612                        [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 613
 614     CPPFLAGS="$ac_save_CPPFLAGS"
 615     XFILES='$(XFILES)'
 616 else
 617     XLIB=""
 618     X_CFLAGS=""
 619     X_LIBS=""
 620 fi
 621
 622 dnl **** Check for libxml2 ****
 623
 624 AC_SUBST(XML2LIBS,"")
 625 AC_SUBST(XML2INCL,"")
 626 AC_SUBST(XSLTLIBS,"")
 627 AC_SUBST(XSLTINCL,"")
 628 ac_save_CPPFLAGS="$CPPFLAGS"
 629 if test "$PKG_CONFIG" != "false"
 630 then
 631     ac_xml_libs="`$PKG_CONFIG --libs libxml-2.0 2>/dev/null`"
 632     ac_xml_cflags="`$PKG_CONFIG --cflags libxml-2.0 2>/dev/null`"
 633 else
 634     ac_xml_libs="`xml2-config --libs 2>/dev/null`"
 635     ac_xml_cflags="`xml2-config --cflags  2>/dev/null`"
 636 fi
 637 CPPFLAGS="$CPPFLAGS $ac_xml_cflags"
 638 AC_CHECK_HEADERS(libxml/parser.h,
 639         [AC_CHECK_LIB(xml2, xmlParseMemory,
 640             [AC_DEFINE(HAVE_LIBXML2, 1, [Define if you have the libxml2 library])
 641              XML2LIBS="$ac_xml_libs"
 642              XML2INCL="$ac_xml_cflags"],,$ac_xml_libs)
 643          AC_CHECK_LIB(xml2, xmlReadMemory,
 644             [AC_DEFINE(HAVE_XMLREADMEMORY,1,[Define if libxml2 has the xmlReadMemory function])],,$ac_xml_libs)
 645          AC_CHECK_LIB(xml2, xmlNewDocPI,
 646             [AC_DEFINE(HAVE_XMLNEWDOCPI,1,[Define if libxml2 has the xmlNewDocPI function])],,$ac_xml_libs)
 647     ])
 648 CPPFLAGS="$ac_save_CPPFLAGS"
 649 if test "$PKG_CONFIG" != "false"
 650 then
 651     ac_xslt_libs="`$PKG_CONFIG --libs libxslt 2>/dev/null`"
 652     ac_xslt_cflags="`$PKG_CONFIG --cflags libxslt 2>/dev/null`"
 653 else
 654     ac_xslt_libs="`xslt-config --libs 2>/dev/null`"
 655     ac_xslt_cflags="`xslt-config --cflags 2>/dev/null`"
 656 fi
 657 CPPFLAGS="$CPPFLAGS $ac_xslt_cflags"
 658 AC_CHECK_HEADERS([libxslt/pattern.h libxslt/transform.h],
 659         [AC_CHECK_LIB(xslt, xsltCompilePattern,
 660             [AC_DEFINE(HAVE_LIBXSLT, 1, [Define if you have the libxslt library])
 661              XSLTLIBS="$ac_xslt_libs"
 662              XSLTINCL="$ac_xslt_cflags"],,$ac_xslt_libs)
 663         ],,
 664 [#ifdef HAVE_LIBXSLT_PATTERN_H
 665 # include <libxslt/pattern.h>
 666 #endif])
 667 CPPFLAGS="$ac_save_CPPFLAGS"
 668
 669 dnl **** Check for libhal ****
 670 AC_SUBST(HALINCL,"")
 671 if test "$PKG_CONFIG" != "false"
 672 then
 673     ac_save_CPPFLAGS="$CPPFLAGS"
 674     ac_hal_libs="`$PKG_CONFIG --libs hal 2>/dev/null`"
 675     ac_hal_cflags="`$PKG_CONFIG --cflags hal 2>/dev/null`"
 676     CPPFLAGS="$CPPFLAGS $ac_hal_cflags"
 677     AC_CHECK_HEADERS([dbus/dbus.h hal/libhal.h])
 678     if test "$ac_cv_header_dbus_dbus_h" = "yes" -a "$ac_cv_header_hal_libhal_h" = "yes"
 679     then
 680         AC_CHECK_LIB(dbus-1, dbus_connection_close,
 681           [WINE_CHECK_SONAME(hal, libhal_ctx_new,
 682             [HALINCL="$ac_hal_cflags"],,[$ac_hal_libs])],,[$ac_hal_libs])
 683     fi
 684     CPPFLAGS="$ac_save_CPPFLAGS"
 685 fi
 686
 687 dnl **** Check which curses lib to use ***
 688 CURSESLIBS=""
 689 if test "$ac_cv_header_ncurses_h" = "yes"
 690 then
 691     WINE_CHECK_SONAME(ncurses,waddch,[CURSESLIBS="-lncurses"])
 692 elif test "$ac_cv_header_curses_h" = "yes"
 693 then
 694     WINE_CHECK_SONAME(curses,waddch,[CURSESLIBS="-lcurses"])
 695 fi
 696 ac_save_LIBS="$LIBS"
 697 LIBS="$LIBS $CURSESLIBS"
 698 AC_CHECK_FUNCS(mousemask)
 699 LIBS="$ac_save_LIBS"
 700
 701 dnl **** Check for SANE ****
 702 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
 703 if test "$sane_devel" != "no"
 704 then
 705     ac_sane_incl="`$sane_devel --cflags`"
 706     ac_save_CPPFLAGS="$CPPFLAGS"
 707     CPPFLAGS="$CPPFLAGS $ac_sane_incl"
 708     AC_CHECK_HEADER(sane/sane.h,
 709         [WINE_CHECK_SONAME(sane,sane_init,[AC_SUBST(SANEINCL,"$ac_sane_incl")])])
 710     CPPFLAGS="$ac_save_CPPFLAGS"
 711 fi
 712
 713 dnl **** Check for libgphoto2 ****
 714 AC_CHECK_PROG(gphoto2_devel,gphoto2-config,gphoto2-config,no)
 715 AC_CHECK_PROG(gphoto2port_devel,gphoto2-port-config,gphoto2-port-config,no)
 716 AC_SUBST(GPHOTO2LIBS,"")
 717 AC_SUBST(GPHOTO2INCL,"")
 718 if test "$gphoto2_devel" != "no" -a "$gphoto2port_devel" != "no"
 719 then
 720     GPHOTO2INCL="`$gphoto2_devel --cflags` `$gphoto2port_devel --cflags`"
 721     GPHOTO2LIBS=""
 722     for i in `$gphoto2_devel --libs` `$gphoto2port_devel --libs`
 723     do
 724       case "$i" in
 725         -L/usr/lib|-L/usr/lib64) ;;
 726         -L*|-l*) GPHOTO2LIBS="$GPHOTO2LIBS $i";;
 727       esac
 728     done
 729     ac_save_CPPFLAGS="$CPPFLAGS"
 730     ac_save_LIBS="$LIBS"
 731     CPPFLAGS="$CPPFLAGS $GPHOTO2INCL"
 732     LIBS="$LIBS $GPHOTO2LIBS"
 733     AC_CHECK_HEADER(gphoto2-camera.h,
 734                     [AC_CHECK_LIB(gphoto2,gp_camera_new,
 735                                   [AC_DEFINE(HAVE_GPHOTO2, 1, [Define if we have libgphoto2 development environment])],
 736                                   [GPHOTO2LIBS=""
 737                                   GPHOTO2INCL=""])],
 738                     [GPHOTO2LIBS=""
 739                     GPHOTO2INCL=""])
 740     LIBS="$ac_save_LIBS"
 741     CPPFLAGS="$ac_save_CPPFLAGS"
 742 fi
 743
 744 dnl **** Check for the ICU library ****
 745 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
 746 then
 747     saved_libs="$LIBS"
 748     icu_libs="-lsicuuc -lsicudata -lstdc++ -lgcc_s"
 749     if test -n "$ICU_LIB_DIR"
 750     then
 751         icu_libs="-L$ICU_LIB_DIR $icu_libs"
 752     fi
 753     AC_MSG_CHECKING(whether can link with ICU libraries)
 754     LIBS="$saved_libs $icu_libs"
 755     AC_RUN_IFELSE([AC_LANG_PROGRAM([[#include <unicode/ubidi.h>]],[[ubidi_open()]])],
 756                 [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
 757                  AC_SUBST(ICULIBS,"$icu_libs")
 758                  AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)],[AC_MSG_RESULT(no)])
 759     LIBS="$saved_libs"
 760 fi
 761
 762 dnl **** Check for resolver library ***
 763 AC_SUBST(RESOLVLIBS,"")
 764 if test "$ac_cv_header_resolv_h" = "yes"
 765 then
 766     AC_CHECK_LIB(resolv, res_query,
 767         [AC_DEFINE(HAVE_RESOLV, 1, [Define if you have the resolver library and header])
 768          RESOLVLIBS="-lresolv"])
 769 fi
 770
 771 dnl **** Check for LittleCMS ***
 772 AC_SUBST(LCMSLIBS,"")
 773 if test "$ac_cv_header_lcms_h" = "yes" -o "$ac_cv_header_lcms_lcms_h" = "yes"
 774 then
 775     AC_CHECK_LIB(lcms, cmsOpenProfileFromFile,
 776         [AC_DEFINE(HAVE_LCMS, 1, [Define if you have the LittleCMS development environment])
 777          LCMSLIBS="-llcms"])
 778 fi
 779
 780 dnl **** Check for OpenLDAP ***
 781 AC_SUBST(LDAPLIBS,"")
 782 if test "$ac_cv_header_ldap_h" = "yes" -a "$ac_cv_header_lber_h" = "yes"
 783 then
 784     AC_CHECK_LIB(ldap_r, ldap_initialize,
 785         [AC_CHECK_LIB(lber, ber_init,
 786             [AC_DEFINE(HAVE_LDAP, 1, [Define if you have the OpenLDAP development environment])
 787              LDAPLIBS="-lldap_r -llber"],,
 788              [$LIBPTHREAD])],,
 789              [$LIBPTHREAD])
 790     WINE_CHECK_LIB_FUNCS(\
 791         ldap_count_references \
 792         ldap_first_reference \
 793         ldap_next_reference \
 794         ldap_parse_reference,
 795         [$LDAPLIBS $LIBPTHREAD])
 796 fi
 797
 798 dnl **** Check for FreeType 2 ****
 799 AC_SUBST(FREETYPELIBS,"")
 800 AC_SUBST(FREETYPEINCL,"")
 801 AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
 802 if test "$ft_devel" = "no"
 803 then
 804     AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
 805     if test "$ft_devel2" = "freetype2-config"
 806     then
 807         ft_devel=$ft_devel2
 808     fi
 809 fi
 810
 811 if test "$ft_devel" = "no"
 812 then
 813     wine_cv_msg_freetype=yes
 814 else
 815     FREETYPELIBS=`$ft_devel --libs`
 816     FREETYPEINCL=`$ft_devel --cflags`
 817     AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$FREETYPELIBS)
 818     if test "$ft_lib" = "no"
 819     then
 820         wine_cv_msg_freetype=yes
 821         FREETYPELIBS=""
 822         FREETYPEINCL=""
 823     else
 824         ac_save_CPPFLAGS="$CPPFLAGS"
 825         CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
 826         AC_CHECK_HEADERS(ft2build.h \
 827                          freetype/freetype.h \
 828                          freetype/ftglyph.h \
 829                          freetype/tttables.h \
 830                          freetype/ftnames.h \
 831                          freetype/ftsnames.h \
 832                          freetype/ttnameid.h \
 833                          freetype/ftoutln.h \
 834                          freetype/ftwinfnt.h \
 835                          freetype/ftmodapi.h \
 836                          freetype/internal/sfnt.h,,,
 837                          [#if HAVE_FT2BUILD_H
 838                           #include <ft2build.h>
 839                           #endif])
 840         AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <ft2build.h>
 841                     #include <freetype/fttrigon.h>]])],[AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
 842           [Define if you have the <freetype/fttrigon.h> header file.])
 843                     wine_cv_fttrigon=yes],[wine_cv_fttrigon=no])
 844         AC_CHECK_TYPES(FT_TrueTypeEngineType,,,[#include <freetype/ftmodapi.h>])
 845         ac_save_CFLAGS="$CFLAGS"
 846         CFLAGS="$CFLAGS $FREETYPELIBS"
 847         AC_CHECK_FUNCS(FT_Load_Sfnt_Table)
 848         CFLAGS="$ac_save_CFLAGS"
 849         CPPFLAGS="$ac_save_CPPFLAGS"
 850         dnl Check that we have at least freetype/freetype.h
 851         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
 852         then
 853             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
 854             wine_cv_msg_freetype=no
 855         else
 856             FREETYPELIBS=""
 857             FREETYPEINCL=""
 858             wine_cv_msg_freetype=yes
 859         fi
 860     fi
 861 fi
 862
 863 dnl Only build the fonts dir if we have both freetype and fontforge
 864 if test "$FONTFORGE" != "false" -a -n "$FREETYPELIBS"
 865 then
 866   AC_SUBST(FONTSSUBDIRS,"fonts")
 867 fi
 868
 869 dnl **** Check for parport (currently Linux only) ****
 870 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
 871  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <linux/ppdev.h>]], [[ioctl (1,PPCLAIM,0)]])],
 872     [ac_cv_c_ppdev="yes"],[ac_cv_c_ppdev="no"]))
 873 if test "$ac_cv_c_ppdev" = "yes"
 874 then
 875     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
 876 fi
 877
 878 dnl **** Check for va_copy ****
 879 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
 880  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>]], [[va_list ap1, ap2; va_copy(ap1,ap2);]])],
 881     [ac_cv_c_va_copy="yes"],[ac_cv_c_va_copy="no"])
 882  )
 883 if test "$ac_cv_c_va_copy" = "yes"
 884 then
 885     AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
 886 fi
 887 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
 888  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>]], [[va_list ap1, ap2; __va_copy(ap1,ap2);]])],
 889     [ac_cv_c___va_copy="yes"],[ac_cv_c___va_copy="no"])
 890  )
 891 if test "$ac_cv_c___va_copy" = "yes"
 892 then
 893     AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
 894 fi
 895
 896 dnl **** Check for sigsetjmp ****
 897 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
 898  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <setjmp.h>]], [[sigjmp_buf buf;
 899     sigsetjmp( buf, 1 );
 900     siglongjmp( buf, 1 );]])],[ac_cv_c_sigsetjmp="yes"],[ac_cv_c_sigsetjmp="no"])
 901  )
 902 if test "$ac_cv_c_sigsetjmp" = "yes"
 903 then
 904     AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
 905 fi
 906
 907 dnl **** Check for pthread_rwlock_t ****
 908 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
 909 #include <pthread.h>])
 910
 911 dnl **** Check for pthread functions ****
 912 WINE_CHECK_LIB_FUNCS(\
 913         pthread_attr_get_np \
 914         pthread_getattr_np \
 915         pthread_get_stackaddr_np \
 916         pthread_get_stacksize_np,
 917         [$LIBPTHREAD])
 918
 919 dnl **** Check for EsounD ****
 920 AC_PATH_PROG(ESDCONFIG, esd-config)
 921 if test x$ESDCONFIG != x -a x$ESDCONFIG != x'"$ESDCONFIG"';
 922 then
 923     ESD_CFLAGS=""
 924     for i in `$ESDCONFIG --cflags`
 925     do
 926       case "$i" in
 927         -I*) ESD_CFLAGS="$ESD_CFLAGS $i";;
 928       esac
 929     done
 930     ESD_LIBS=`$ESDCONFIG --libs`
 931     save_CFLAGS="$CFLAGS"
 932     CFLAGS="$CFLAGS $ESD_CFLAGS"
 933     AC_CHECK_LIB(esd,esd_open_sound,
 934         [AC_SUBST(ESDLIBS, $ESD_LIBS)
 935          AC_SUBST(ESDINCL, $ESD_CFLAGS)
 936          AC_DEFINE(HAVE_ESD, 1, [Define if you have EsounD sound server])])
 937     CFLAGS="$save_CFLAGS"
 938 fi
 939
 940 dnl **** Check for ALSA 1.x ****
 941 AC_SUBST(ALSALIBS,"")
 942 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
 943 then
 944     AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
 945         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef HAVE_ALSA_ASOUNDLIB_H
 946 #include <alsa/asoundlib.h>
 947 #elif defined(HAVE_SYS_ASOUNDLIB_H)
 948 #include <sys/asoundlib.h>
 949 #endif]], [[int ret = snd_pcm_hw_params_get_access(NULL, NULL)]])],
 950                         [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
 951                          ALSALIBS="-lasound"],[])])
 952 fi
 953
 954 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
 955
 956 AC_SUBST(AUDIOIOLIBS,"")
 957 if test "$ac_cv_header_libaudioio_h" = "yes"
 958 then
 959     AC_CHECK_LIB(audioio,AudioIOGetVersion,
 960                   [AUDIOIOLIBS="-laudioio"
 961                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])
 962 fi
 963
 964 dnl **** Check for capi4linux ****
 965
 966 if test "$ac_cv_header_capi20_h" = "yes" -a "$ac_cv_header_linux_capi_h" = "yes"
 967 then
 968     WINE_CHECK_SONAME(capi20,capi20_register)
 969 fi
 970
 971 dnl **** Check for cups ****
 972 if test "$ac_cv_header_cups_cups_h" = "yes"
 973 then
 974     WINE_CHECK_SONAME(cups,cupsGetDefault)
 975 fi
 976
 977 dnl **** Check for jack ****
 978 if test "$ac_cv_header_jack_jack_h" = "yes"
 979 then
 980     WINE_CHECK_SONAME(jack,jack_client_new)
 981 fi
 982
 983 dnl **** Check for fontconfig ****
 984 if test "$ac_cv_header_fontconfig_fontconfig_h" = "yes"
 985 then
 986     WINE_CHECK_SONAME(fontconfig,FcInit)
 987 fi
 988
 989 dnl **** Check for SSL ****
 990 if test "$ac_cv_header_openssl_err_h" = "yes" -a "$ac_cv_header_openssl_ssl_h" = "yes"
 991 then
 992     WINE_CHECK_SONAME(ssl,SSL_library_init)
 993     WINE_CHECK_SONAME(crypto,BIO_new_socket)
 994 fi
 995
 996 dnl **** Check for libjpeg ****
 997 if test "$ac_cv_header_jpeglib_h" = "yes"
 998 then
 999     WINE_CHECK_SONAME(jpeg,jpeg_start_decompress)
1000 fi
1001
1002 dnl **** Check for libpng ****
1003 if test "$ac_cv_header_png_h" = "yes"
1004 then
1005     WINE_CHECK_SONAME(png,png_create_read_struct,,,,[[libpng[[0-9]]*]])
1006 fi
1007
1008 dnl **** Check for gcc specific options ****
1009
1010 AC_SUBST(EXTRACFLAGS,"")
1011 if test "x${GCC}" = "xyes"
1012 then
1013   EXTRACFLAGS="-Wall -pipe"
1014
1015   dnl Check for strength-reduce bug
1016   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
1017                   AC_RUN_IFELSE([AC_LANG_PROGRAM([[int L[[4]] = {0,1,2,3};]],
1018 [[static int Array[[3]];
1019   unsigned int B = 3;
1020   int i;
1021   for(i=0; i<B; i++) Array[[i]] = i - 3;
1022   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
1023   L[[i]] = 4;
1024   exit( Array[[1]] != -2 || L[[2]] != 3)]])],
1025     [ac_cv_c_gcc_strength_bug="no"],[ac_cv_c_gcc_strength_bug="yes"],[ac_cv_c_gcc_strength_bug="yes"]) )
1026   if test "$ac_cv_c_gcc_strength_bug" = "yes"
1027   then
1028     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
1029   fi
1030
1031   dnl Check for some compiler flags
1032
1033   WINE_TRY_CFLAGS([-fshort-wchar],
1034                   [AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar",
1035                              [Specifies the compiler flag that forces a short wchar_t])])
1036   WINE_TRY_CFLAGS([-fno-strict-aliasing])
1037   WINE_TRY_CFLAGS([-Wdeclaration-after-statement])
1038   WINE_TRY_CFLAGS([-Wwrite-strings])
1039
1040   dnl Check for noisy string.h
1041   saved_CFLAGS="$CFLAGS"
1042   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
1043   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
1044       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string.h>]], [[]])],[ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
1045   CFLAGS="$saved_CFLAGS"
1046   if test "$ac_cv_c_string_h_warnings" = "no"
1047   then
1048     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
1049   fi
1050
1051   AC_SUBST(BUILTINFLAG,"")
1052   saved_CFLAGS="$CFLAGS"
1053   CFLAGS="$CFLAGS -Werror"
1054   AC_CACHE_CHECK([for builtin wchar inlines], ac_cv_c_builtin_wchar_ctype,
1055       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[int iswlower(unsigned short);]])],[ac_cv_c_builtin_wchar_ctype=no],[ac_cv_c_builtin_wchar_ctype=yes]))
1056   CFLAGS="$saved_CFLAGS"
1057   if test "$ac_cv_c_builtin_wchar_ctype" = "yes"
1058   then
1059     BUILTINFLAG="-fno-builtin"
1060   fi
1061 fi
1062
1063 dnl **** Check how to define a function in assembly code ****
1064
1065 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
1066   WINE_TRY_ASM_LINK(
1067       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
1068       ac_cv_asm_func_def=".def",
1069     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
1070       ac_cv_asm_func_def=".type @function",
1071     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
1072       ac_cv_asm_func_def=".type 2",
1073       ac_cv_asm_func_def="unknown")])]))
1074
1075 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
1076 case "$ac_cv_asm_func_def" in
1077   ".def")
1078      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
1079   ".type @function")
1080      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
1081   ".type 2")
1082      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
1083   *)
1084      AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
1085 esac
1086
1087 dnl **** Check for underscore on external symbols ****
1088
1089 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
1090     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
1091                       [extern int ac_test;],
1092                       [if (ac_test) return 1],
1093                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
1094
1095 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
1096 if test "$ac_cv_c_extern_prefix" = "yes"
1097 then
1098   AC_DEFINE([__ASM_NAME(name)], ["_" name])
1099 else
1100   AC_DEFINE([__ASM_NAME(name)], [name])
1101 fi
1102
1103 dnl **** Platform-specific checks ****
1104
1105 AC_SUBST(LDPATH,"")
1106 case $build_os in
1107   cygwin*|mingw32*)
1108     LDPATH="PATH=\"\$(TOOLSDIR)/libs/wine:\$\$PATH\""
1109     ;;
1110   darwin*|macosx*)
1111     ;;
1112   linux*|solaris*)  dnl FIXME: What other platforms support $ORIGIN?
1113     if test -z "$LDRPATH_LOCAL"
1114     then
1115       LDPATH="LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\""
1116     fi
1117     ;;
1118   *)
1119     LDPATH="LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\""
1120     ;;
1121 esac
1122
1123 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1124 case $host_os in
1125   mingw32*)
1126     AC_SUBST(CRTLIBS,"-lmsvcrt")
1127     AC_SUBST(SOCKETLIBS,"-lws2_32")
1128     ;;
1129 esac
1130
1131 AC_SUBST(MAIN_BINARY,"wine-pthread")  dnl Default value
1132 case $host_cpu in
1133   *i[[3456789]]86*)
1134     case $host_os in
1135       linux* | k*bsd*-gnu)
1136         AC_SUBST(MAIN_BINARY,"wine-glibc")
1137         AC_SUBST(EXTRA_BINARIES,"wine-kthread wine-pthread wine-preloader") ;;
1138     esac
1139     ;;
1140 esac
1141
1142 dnl **** Get the soname for libraries that we load dynamically ****
1143
1144 AC_DEFINE_UNQUOTED(SONAME_EXT,[".$LIBEXT"],[Define to the file extension of shared libraries.])
1145
1146 WINE_CHECK_SONAME(X11,XCreateWindow,,,[$X_LIBS $X_EXTRA_LIBS])
1147 WINE_CHECK_SONAME(Xext,XextCreateExtension,,,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1148 WINE_CHECK_SONAME(Xi,XOpenDevice,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1149 WINE_CHECK_SONAME(Xinerama,XineramaQueryScreens,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1150 WINE_CHECK_SONAME(Xrender,XRenderQueryExtension,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1151 WINE_CHECK_SONAME(Xrandr,XRRQueryExtension,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1152 WINE_CHECK_SONAME(Xcursor,XcursorImageLoadCursor,,,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1153 WINE_CHECK_SONAME(freetype,FT_Init_FreeType,,,[$X_LIBS])
1154 WINE_CHECK_SONAME(txc_dxtn,fetch_2d_texel_rgba_dxt1)
1155
1156
1157 dnl **** Check for functions ****
1158
1159 AC_CHECK_FUNCS(\
1160         _pclose \
1161         _popen \
1162         _snprintf \
1163         _spawnvp \
1164         _stricmp \
1165         _strnicmp \
1166         _vsnprintf \
1167         asctime_r \
1168         chsize \
1169         clone \
1170         dlopen \
1171         epoll_create \
1172         ffs \
1173         finite \
1174         fork \
1175         fpclass \
1176         fstatfs \
1177         fstatvfs \
1178         ftruncate \
1179         futimes \
1180         futimesat \
1181         getdirentries \
1182         getopt_long \
1183         getpagesize \
1184         getpwuid \
1185         gettid \
1186         gettimeofday \
1187         getuid \
1188         inet_pton \
1189         kqueue \
1190         lstat \
1191         memmove \
1192         mmap \
1193         pclose \
1194         poll \
1195         popen \
1196         prctl \
1197         pread \
1198         pwrite \
1199         readlink \
1200         rfork \
1201         sched_yield \
1202         select \
1203         setrlimit \
1204         settimeofday \
1205         sigaltstack \
1206         sigprocmask \
1207         snprintf \
1208         spawnvp \
1209         statfs \
1210         statvfs \
1211         strcasecmp \
1212         strerror \
1213         strncasecmp \
1214         strtold \
1215         tcgetattr \
1216         timegm \
1217         usleep \
1218         vsnprintf \
1219         wait4 \
1220         waitpid \
1221 )
1222
1223 dnl Check for -ldl
1224 if test "$ac_cv_func_dlopen" = no
1225 then
1226     AC_CHECK_LIB(dl,dlopen,[AC_DEFINE(HAVE_DLOPEN,1) AC_SUBST(LIBDL,"-ldl")])
1227 fi
1228 WINE_CHECK_LIB_FUNCS(dladdr,[$LIBDL])
1229
1230 dnl Check for -lpoll for Mac OS X/Darwin
1231 if test "$ac_cv_func_poll" = no
1232 then
1233     AC_CHECK_LIB(poll,poll,[AC_DEFINE(HAVE_POLL,1) AC_SUBST(LIBPOLL,"-lpoll")])
1234 fi
1235
1236 dnl Check for -lnsl for Solaris
1237 AC_SEARCH_LIBS(gethostbyname, nsl)
1238
1239 dnl Check for -lsocket for Solaris
1240 AC_SEARCH_LIBS(connect, socket)
1241
1242 dnl Check for -lresolv for Solaris
1243 AC_SEARCH_LIBS(inet_aton, resolv)
1244
1245 dnl **** Check for functions which may rely on -lsocket on Solaris.
1246 AC_CHECK_FUNCS(\
1247         getaddrinfo \
1248         getnameinfo \
1249         getnetbyname \
1250         getprotobyname \
1251         getprotobynumber \
1252         getservbyport \
1253         inet_network \
1254         sendmsg \
1255 )
1256
1257 dnl **** Check for types ****
1258
1259 AC_C_CONST
1260 AC_C_INLINE
1261 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1262 AC_CHECK_TYPES([sigset_t],,,[#include <signal.h>])
1263 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
1264
1265 AC_CHECK_MEMBERS([struct ff_effect.direction],,,
1266 [#ifdef HAVE_LINUX_INPUT_H
1267 #include <linux/input.h>
1268 #endif])
1269
1270 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
1271                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>]], [[sigset_t set; sigaddset(&set,SIGTERM);]])],[wine_cv_have_sigaddset=yes],[wine_cv_have_sigaddset=no]))
1272 if test "$wine_cv_have_sigaddset" = "yes"
1273 then
1274   AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
1275 fi
1276
1277
1278 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1279         wine_cv_linux_gethostbyname_r_6,
1280         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],[[
1281     char *name=NULL;
1282     struct hostent he;
1283     struct hostent *result;
1284     char *buf=NULL;
1285     int bufsize=0;
1286     int res,errnr;
1287     char *addr=NULL;
1288     int addrlen=0;
1289     int addrtype=0;
1290     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1291     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1292     ]])],[wine_cv_linux_gethostbyname_r_6=yes],[wine_cv_linux_gethostbyname_r_6=no
1293         ])
1294    )
1295    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1296    then
1297       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1298                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1299    fi
1300
1301 if test "$ac_cv_header_linux_joystick_h" = "yes"
1302 then
1303    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1304         wine_cv_linux_joystick_22_api,
1305         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1306         #include <sys/ioctl.h>
1307         #include <sys/types.h>
1308         #include <linux/joystick.h>
1309
1310         struct js_event blub;
1311         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1312         #error "no 2.2 header"
1313         #endif
1314         ]], [[/*empty*/]])],[wine_cv_linux_joystick_22_api=yes],[wine_cv_linux_joystick_22_api=no])
1315    )
1316    if test "$wine_cv_linux_joystick_22_api" = "yes"
1317    then
1318       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1319                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1320    fi
1321 fi
1322
1323 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1324
1325 dnl Check for statfs members
1326 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1327 [#include <sys/types.h>
1328 #ifdef HAVE_SYS_PARAM_H
1329 # include <sys/param.h>
1330 #endif
1331 #ifdef HAVE_SYS_MOUNT_H
1332 # include <sys/mount.h>
1333 #endif
1334 #ifdef HAVE_SYS_VFS_H
1335 # include <sys/vfs.h>
1336 #endif
1337 #ifdef HAVE_SYS_STATFS_H
1338 # include <sys/statfs.h>
1339 #endif])
1340
1341 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1342 [#ifdef HAVE_SYS_STATVFS_H
1343 #include <sys/statvfs.h>
1344 #endif])
1345
1346 dnl Check for socket structure members
1347 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1348 [#include <sys/types.h>
1349 #ifdef HAVE_SYS_SOCKET_H
1350 # include <sys/socket.h>
1351 #endif
1352 #ifdef HAVE_SYS_UN_H
1353 # include <sys/un.h>
1354 #endif])
1355
1356 dnl Check for scsireq_t and sg_io_hdr_t members
1357 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
1358 [#include <sys/types.h>
1359 #ifdef HAVE_SCSI_SG_H
1360 #include <scsi/sg.h>
1361 #endif])
1362
1363 dnl Check for siginfo_t members
1364 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1365
1366 dnl Check for struct mtget members
1367 AC_CHECK_MEMBERS([struct mtget.mt_blksiz, struct mtget.mt_gstat, struct mtget.mt_blkno],,,
1368 [#include <sys/types.h>
1369 #ifdef HAVE_SYS_MTIO_H
1370 #include <sys/mtio.h>
1371 #endif])
1372
1373 dnl Check for struct option
1374 AC_CHECK_MEMBERS([struct option.name],,,
1375 [#ifdef HAVE_GETOPT_H
1376 #include <getopt.h>
1377 #endif])
1378
1379 dnl Check for stat.st_blocks
1380 AC_CHECK_MEMBERS([struct stat.st_blocks])
1381
1382 dnl Check for sin6_scope_id
1383 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_scope_id],,,
1384 [#ifdef HAVE_SYS_TYPES_H
1385 #include <sys/types.h>
1386 #endif
1387 #ifdef HAVE_NETINET_IN_H
1388 #include <netinet/in.h>
1389 #endif])
1390
1391 dnl Check for ns_msg ptr member
1392 AC_CHECK_MEMBERS([ns_msg._msg_ptr],,,
1393 [#ifdef HAVE_SYS_TYPES_H
1394 #include <sys/types.h>
1395 #endif
1396 #ifdef HAVE_NETINET_IN_H
1397 # include <netinet/in.h>
1398 #endif
1399 #ifdef HAVE_ARPA_NAMESER_H
1400 # include <arpa/nameser.h>
1401 #endif])
1402
1403 dnl Check for the external timezone variables timezone and daylight
1404 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
1405                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[timezone = 1]])],[ac_cv_have_timezone="yes"],[ac_cv_have_timezone="no"]))
1406 if test "$ac_cv_have_timezone" = "yes"
1407 then
1408     AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
1409 fi
1410 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
1411                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[daylight = 1]])],[ac_cv_have_daylight="yes"],[ac_cv_have_daylight="no"]))
1412 if test "$ac_cv_have_daylight" = "yes"
1413 then
1414     AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
1415 fi
1416
1417 dnl *** check for the need to define platform-specific symbols
1418
1419 case $host_cpu in
1420   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1421   *x86_64*)         WINE_CHECK_DEFINE([__x86_64__]) ;;
1422   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
1423   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
1424   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
1425 esac
1426
1427 case $host_vendor in
1428   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1429 esac
1430
1431 dnl **** Generate output files ****
1432
1433 dnl autoconf versions before 2.59d need backslashes to escape newlines in subst variables
1434 AC_SUBST(DEPENDENCIES,m4_if(m4_version_compare(m4_defn([m4_PACKAGE_VERSION]), [2.59d]), -1,
1435 ["### Dependencies:\\
1436 \\
1437 .INIT: Makefile\\
1438 .BEGIN: Makefile\\
1439 Makefile: dummy\\
1440         -\$(MAKEDEP) -C\$(SRCDIR) -S\$(TOPSRCDIR) -T\$(TOPOBJDIR) \$(EXTRAINCL) \$(DEPEND_SRCS)\\
1441 \\
1442 \$(OBJS): \$(IDL_GEN_HEADERS)\\
1443 \$(IDL_GEN_C_SRCS:.c=.o): \$(IDL_GEN_C_SRCS)\\
1444 \$(LEX_SRCS:.l=.yy.o): \$(LEX_SRCS:.l=.yy.c)\\
1445 \$(BISON_SRCS:.y=.tab.o): \$(BISON_SRCS:.y=.tab.c)"],
1446 ["### Dependencies:
1447
1448 .INIT: Makefile
1449 .BEGIN: Makefile
1450 Makefile: dummy
1451         -\$(MAKEDEP) -C\$(SRCDIR) -S\$(TOPSRCDIR) -T\$(TOPOBJDIR) \$(EXTRAINCL) \$(DEPEND_SRCS)
1452
1453 \$(OBJS): \$(IDL_GEN_HEADERS)
1454 \$(IDL_GEN_C_SRCS:.c=.o): \$(IDL_GEN_C_SRCS)
1455 \$(LEX_SRCS:.l=.yy.o): \$(LEX_SRCS:.l=.yy.c)
1456 \$(BISON_SRCS:.y=.tab.o): \$(BISON_SRCS:.y=.tab.c)"]))
1457
1458 AH_TOP([#define __WINE_CONFIG_H])
1459
1460 AC_CONFIG_COMMANDS([include/stamp-h], [echo timestamp > include/stamp-h])
1461
1462 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/enhmfdrv)
1463 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/mfdrv)
1464 WINE_CONFIG_EXTRA_DIR(dlls/kernel32/nls)
1465 WINE_CONFIG_EXTRA_DIR(dlls/user32/resources)
1466 WINE_CONFIG_EXTRA_DIR(dlls/wineps.drv/data)
1467 WINE_CONFIG_EXTRA_DIR(include/wine)
1468
1469 MAKE_RULES=Make.rules
1470 AC_SUBST_FILE(MAKE_RULES)
1471
1472 MAKE_DLL_RULES=dlls/Makedll.rules
1473 AC_SUBST_FILE(MAKE_DLL_RULES)
1474
1475 MAKE_IMPLIB_RULES=dlls/Makeimplib.rules
1476 AC_SUBST_FILE(MAKE_IMPLIB_RULES)
1477
1478 MAKE_TEST_RULES=dlls/Maketest.rules
1479 AC_SUBST_FILE(MAKE_TEST_RULES)
1480
1481 MAKE_PROG_RULES=programs/Makeprog.rules
1482 AC_SUBST_FILE(MAKE_PROG_RULES)
1483
1484 AC_CONFIG_FILES([Make.rules])
1485 AC_CONFIG_FILES([dlls/Makedll.rules])
1486 AC_CONFIG_FILES([dlls/Makeimplib.rules])
1487 AC_CONFIG_FILES([dlls/Maketest.rules])
1488 AC_CONFIG_FILES([programs/Makeprog.rules])
1489 AC_CONFIG_FILES([Makefile])
1490 AC_CONFIG_FILES([dlls/Makefile])
1491 AC_CONFIG_FILES([dlls/acledit/Makefile])
1492 AC_CONFIG_FILES([dlls/activeds/Makefile])
1493 AC_CONFIG_FILES([dlls/advapi32/Makefile])
1494 AC_CONFIG_FILES([dlls/advapi32/tests/Makefile])
1495 AC_CONFIG_FILES([dlls/advpack/Makefile])
1496 AC_CONFIG_FILES([dlls/advpack/tests/Makefile])
1497 AC_CONFIG_FILES([dlls/amstream/Makefile])
1498 AC_CONFIG_FILES([dlls/atl/Makefile])
1499 AC_CONFIG_FILES([dlls/avicap32/Makefile])
1500 AC_CONFIG_FILES([dlls/avifil32/Makefile])
1501 AC_CONFIG_FILES([dlls/browseui/Makefile])
1502 AC_CONFIG_FILES([dlls/browseui/tests/Makefile])
1503 AC_CONFIG_FILES([dlls/cabinet/Makefile])
1504 AC_CONFIG_FILES([dlls/cabinet/tests/Makefile])
1505 AC_CONFIG_FILES([dlls/capi2032/Makefile])
1506 AC_CONFIG_FILES([dlls/cards/Makefile])
1507 AC_CONFIG_FILES([dlls/cfgmgr32/Makefile])
1508 AC_CONFIG_FILES([dlls/clusapi/Makefile])
1509 AC_CONFIG_FILES([dlls/comcat/Makefile])
1510 AC_CONFIG_FILES([dlls/comcat/tests/Makefile])
1511 AC_CONFIG_FILES([dlls/comctl32/Makefile])
1512 AC_CONFIG_FILES([dlls/comctl32/tests/Makefile])
1513 AC_CONFIG_FILES([dlls/comdlg32/Makefile])
1514 AC_CONFIG_FILES([dlls/comdlg32/tests/Makefile])
1515 AC_CONFIG_FILES([dlls/compstui/Makefile])
1516 AC_CONFIG_FILES([dlls/credui/Makefile])
1517 AC_CONFIG_FILES([dlls/crtdll/Makefile])
1518 AC_CONFIG_FILES([dlls/crypt32/Makefile])
1519 AC_CONFIG_FILES([dlls/crypt32/tests/Makefile])
1520 AC_CONFIG_FILES([dlls/cryptdll/Makefile])
1521 AC_CONFIG_FILES([dlls/cryptnet/Makefile])
1522 AC_CONFIG_FILES([dlls/ctl3d32/Makefile])
1523 AC_CONFIG_FILES([dlls/d3d8/Makefile])
1524 AC_CONFIG_FILES([dlls/d3d8/tests/Makefile])
1525 AC_CONFIG_FILES([dlls/d3d9/Makefile])
1526 AC_CONFIG_FILES([dlls/d3d9/tests/Makefile])
1527 AC_CONFIG_FILES([dlls/d3dim/Makefile])
1528 AC_CONFIG_FILES([dlls/d3drm/Makefile])
1529 AC_CONFIG_FILES([dlls/d3drm/tests/Makefile])
1530 AC_CONFIG_FILES([dlls/d3dx8/Makefile])
1531 AC_CONFIG_FILES([dlls/d3dxof/Makefile])
1532 AC_CONFIG_FILES([dlls/dbghelp/Makefile])
1533 AC_CONFIG_FILES([dlls/dciman32/Makefile])
1534 AC_CONFIG_FILES([dlls/ddraw/Makefile])
1535 AC_CONFIG_FILES([dlls/ddraw/tests/Makefile])
1536 AC_CONFIG_FILES([dlls/ddrawex/Makefile])
1537 AC_CONFIG_FILES([dlls/devenum/Makefile])
1538 AC_CONFIG_FILES([dlls/dinput/Makefile])
1539 AC_CONFIG_FILES([dlls/dinput/tests/Makefile])
1540 AC_CONFIG_FILES([dlls/dinput8/Makefile])
1541 AC_CONFIG_FILES([dlls/dmband/Makefile])
1542 AC_CONFIG_FILES([dlls/dmcompos/Makefile])
1543 AC_CONFIG_FILES([dlls/dmime/Makefile])
1544 AC_CONFIG_FILES([dlls/dmloader/Makefile])
1545 AC_CONFIG_FILES([dlls/dmscript/Makefile])
1546 AC_CONFIG_FILES([dlls/dmstyle/Makefile])
1547 AC_CONFIG_FILES([dlls/dmsynth/Makefile])
1548 AC_CONFIG_FILES([dlls/dmusic/Makefile])
1549 AC_CONFIG_FILES([dlls/dmusic32/Makefile])
1550 AC_CONFIG_FILES([dlls/dnsapi/Makefile])
1551 AC_CONFIG_FILES([dlls/dnsapi/tests/Makefile])
1552 AC_CONFIG_FILES([dlls/dplay/Makefile])
1553 AC_CONFIG_FILES([dlls/dplayx/Makefile])
1554 AC_CONFIG_FILES([dlls/dplayx/tests/Makefile])
1555 AC_CONFIG_FILES([dlls/dpnaddr/Makefile])
1556 AC_CONFIG_FILES([dlls/dpnet/Makefile])
1557 AC_CONFIG_FILES([dlls/dpnhpast/Makefile])
1558 AC_CONFIG_FILES([dlls/dsound/Makefile])
1559 AC_CONFIG_FILES([dlls/dsound/tests/Makefile])
1560 AC_CONFIG_FILES([dlls/dswave/Makefile])
1561 AC_CONFIG_FILES([dlls/dwmapi/Makefile])
1562 AC_CONFIG_FILES([dlls/dxdiagn/Makefile])
1563 AC_CONFIG_FILES([dlls/dxerr8/Makefile])
1564 AC_CONFIG_FILES([dlls/dxerr9/Makefile])
1565 AC_CONFIG_FILES([dlls/dxguid/Makefile])
1566 AC_CONFIG_FILES([dlls/gdi32/Makefile])
1567 AC_CONFIG_FILES([dlls/gdi32/tests/Makefile])
1568 AC_CONFIG_FILES([dlls/gdiplus/Makefile])
1569 AC_CONFIG_FILES([dlls/gdiplus/tests/Makefile])
1570 AC_CONFIG_FILES([dlls/glu32/Makefile])
1571 AC_CONFIG_FILES([dlls/gphoto2.ds/Makefile])
1572 AC_CONFIG_FILES([dlls/hal/Makefile])
1573 AC_CONFIG_FILES([dlls/hhctrl.ocx/Makefile])
1574 AC_CONFIG_FILES([dlls/hid/Makefile])
1575 AC_CONFIG_FILES([dlls/hlink/Makefile])
1576 AC_CONFIG_FILES([dlls/hlink/tests/Makefile])
1577 AC_CONFIG_FILES([dlls/hnetcfg/Makefile])
1578 AC_CONFIG_FILES([dlls/iccvid/Makefile])
1579 AC_CONFIG_FILES([dlls/icmp/Makefile])
1580 AC_CONFIG_FILES([dlls/ifsmgr.vxd/Makefile])
1581 AC_CONFIG_FILES([dlls/imaadp32.acm/Makefile])
1582 AC_CONFIG_FILES([dlls/imagehlp/Makefile])
1583 AC_CONFIG_FILES([dlls/imm32/Makefile])
1584 AC_CONFIG_FILES([dlls/infosoft/Makefile])
1585 AC_CONFIG_FILES([dlls/infosoft/tests/Makefile])
1586 AC_CONFIG_FILES([dlls/inseng/Makefile])
1587 AC_CONFIG_FILES([dlls/iphlpapi/Makefile])
1588 AC_CONFIG_FILES([dlls/iphlpapi/tests/Makefile])
1589 AC_CONFIG_FILES([dlls/itss/Makefile])
1590 AC_CONFIG_FILES([dlls/itss/tests/Makefile])
1591 AC_CONFIG_FILES([dlls/kernel32/Makefile])
1592 AC_CONFIG_FILES([dlls/kernel32/tests/Makefile])
1593 AC_CONFIG_FILES([dlls/localspl/Makefile])
1594 AC_CONFIG_FILES([dlls/localspl/tests/Makefile])
1595 AC_CONFIG_FILES([dlls/localui/Makefile])
1596 AC_CONFIG_FILES([dlls/localui/tests/Makefile])
1597 AC_CONFIG_FILES([dlls/lz32/Makefile])
1598 AC_CONFIG_FILES([dlls/lz32/tests/Makefile])
1599 AC_CONFIG_FILES([dlls/mapi32/Makefile])
1600 AC_CONFIG_FILES([dlls/mapi32/tests/Makefile])
1601 AC_CONFIG_FILES([dlls/mciavi32/Makefile])
1602 AC_CONFIG_FILES([dlls/mcicda/Makefile])
1603 AC_CONFIG_FILES([dlls/mciseq/Makefile])
1604 AC_CONFIG_FILES([dlls/mciwave/Makefile])
1605 AC_CONFIG_FILES([dlls/midimap/Makefile])
1606 AC_CONFIG_FILES([dlls/mlang/Makefile])
1607 AC_CONFIG_FILES([dlls/mlang/tests/Makefile])
1608 AC_CONFIG_FILES([dlls/mmdevldr.vxd/Makefile])
1609 AC_CONFIG_FILES([dlls/monodebg.vxd/Makefile])
1610 AC_CONFIG_FILES([dlls/mpr/Makefile])
1611 AC_CONFIG_FILES([dlls/mprapi/Makefile])
1612 AC_CONFIG_FILES([dlls/msacm32.drv/Makefile])
1613 AC_CONFIG_FILES([dlls/msacm32/Makefile])
1614 AC_CONFIG_FILES([dlls/msacm32/tests/Makefile])
1615 AC_CONFIG_FILES([dlls/msadp32.acm/Makefile])
1616 AC_CONFIG_FILES([dlls/mscms/Makefile])
1617 AC_CONFIG_FILES([dlls/mscms/tests/Makefile])
1618 AC_CONFIG_FILES([dlls/mscoree/Makefile])
1619 AC_CONFIG_FILES([dlls/msdmo/Makefile])
1620 AC_CONFIG_FILES([dlls/msftedit/Makefile])
1621 AC_CONFIG_FILES([dlls/msg711.acm/Makefile])
1622 AC_CONFIG_FILES([dlls/mshtml/Makefile])
1623 AC_CONFIG_FILES([dlls/mshtml/tests/Makefile])
1624 AC_CONFIG_FILES([dlls/msi/Makefile])
1625 AC_CONFIG_FILES([dlls/msi/tests/Makefile])
1626 AC_CONFIG_FILES([dlls/msimg32/Makefile])
1627 AC_CONFIG_FILES([dlls/msisys.ocx/Makefile])
1628 AC_CONFIG_FILES([dlls/msnet32/Makefile])
1629 AC_CONFIG_FILES([dlls/msrle32/Makefile])
1630 AC_CONFIG_FILES([dlls/msvcrt/Makefile])
1631 AC_CONFIG_FILES([dlls/msvcrt/tests/Makefile])
1632 AC_CONFIG_FILES([dlls/msvcrt20/Makefile])
1633 AC_CONFIG_FILES([dlls/msvcrt40/Makefile])
1634 AC_CONFIG_FILES([dlls/msvcrtd/Makefile])
1635 AC_CONFIG_FILES([dlls/msvcrtd/tests/Makefile])
1636 AC_CONFIG_FILES([dlls/msvfw32/Makefile])
1637 AC_CONFIG_FILES([dlls/msvidc32/Makefile])
1638 AC_CONFIG_FILES([dlls/mswsock/Makefile])
1639 AC_CONFIG_FILES([dlls/msxml3/Makefile])
1640 AC_CONFIG_FILES([dlls/msxml3/tests/Makefile])
1641 AC_CONFIG_FILES([dlls/nddeapi/Makefile])
1642 AC_CONFIG_FILES([dlls/netapi32/Makefile])
1643 AC_CONFIG_FILES([dlls/netapi32/tests/Makefile])
1644 AC_CONFIG_FILES([dlls/newdev/Makefile])
1645 AC_CONFIG_FILES([dlls/ntdll/Makefile])
1646 AC_CONFIG_FILES([dlls/ntdll/tests/Makefile])
1647 AC_CONFIG_FILES([dlls/ntdsapi/Makefile])
1648 AC_CONFIG_FILES([dlls/ntoskrnl.exe/Makefile])
1649 AC_CONFIG_FILES([dlls/ntprint/Makefile])
1650 AC_CONFIG_FILES([dlls/ntprint/tests/Makefile])
1651 AC_CONFIG_FILES([dlls/objsel/Makefile])
1652 AC_CONFIG_FILES([dlls/odbc32/Makefile])
1653 AC_CONFIG_FILES([dlls/odbccp32/Makefile])
1654 AC_CONFIG_FILES([dlls/odbccp32/tests/Makefile])
1655 AC_CONFIG_FILES([dlls/ole32/Makefile])
1656 AC_CONFIG_FILES([dlls/ole32/tests/Makefile])
1657 AC_CONFIG_FILES([dlls/oleacc/Makefile])
1658 AC_CONFIG_FILES([dlls/oleaut32/Makefile])
1659 AC_CONFIG_FILES([dlls/oleaut32/tests/Makefile])
1660 AC_CONFIG_FILES([dlls/olecli32/Makefile])
1661 AC_CONFIG_FILES([dlls/oledlg/Makefile])
1662 AC_CONFIG_FILES([dlls/olepro32/Makefile])
1663 AC_CONFIG_FILES([dlls/olesvr32/Makefile])
1664 AC_CONFIG_FILES([dlls/opengl32/Makefile])
1665 AC_CONFIG_FILES([dlls/pdh/Makefile])
1666 AC_CONFIG_FILES([dlls/powrprof/Makefile])
1667 AC_CONFIG_FILES([dlls/printui/Makefile])
1668 AC_CONFIG_FILES([dlls/psapi/Makefile])
1669 AC_CONFIG_FILES([dlls/psapi/tests/Makefile])
1670 AC_CONFIG_FILES([dlls/pstorec/Makefile])
1671 AC_CONFIG_FILES([dlls/qcap/Makefile])
1672 AC_CONFIG_FILES([dlls/quartz/Makefile])
1673 AC_CONFIG_FILES([dlls/quartz/tests/Makefile])
1674 AC_CONFIG_FILES([dlls/query/Makefile])
1675 AC_CONFIG_FILES([dlls/rasapi32/Makefile])
1676 AC_CONFIG_FILES([dlls/resutils/Makefile])
1677 AC_CONFIG_FILES([dlls/riched20/Makefile])
1678 AC_CONFIG_FILES([dlls/riched20/tests/Makefile])
1679 AC_CONFIG_FILES([dlls/riched32/Makefile])
1680 AC_CONFIG_FILES([dlls/rpcrt4/Makefile])
1681 AC_CONFIG_FILES([dlls/rpcrt4/tests/Makefile])
1682 AC_CONFIG_FILES([dlls/rsabase/Makefile])
1683 AC_CONFIG_FILES([dlls/rsabase/tests/Makefile])
1684 AC_CONFIG_FILES([dlls/rsaenh/Makefile])
1685 AC_CONFIG_FILES([dlls/rsaenh/tests/Makefile])
1686 AC_CONFIG_FILES([dlls/sane.ds/Makefile])
1687 AC_CONFIG_FILES([dlls/schannel/Makefile])
1688 AC_CONFIG_FILES([dlls/schannel/tests/Makefile])
1689 AC_CONFIG_FILES([dlls/secur32/Makefile])
1690 AC_CONFIG_FILES([dlls/secur32/tests/Makefile])
1691 AC_CONFIG_FILES([dlls/security/Makefile])
1692 AC_CONFIG_FILES([dlls/sensapi/Makefile])
1693 AC_CONFIG_FILES([dlls/serialui/Makefile])
1694 AC_CONFIG_FILES([dlls/serialui/tests/Makefile])
1695 AC_CONFIG_FILES([dlls/setupapi/Makefile])
1696 AC_CONFIG_FILES([dlls/setupapi/tests/Makefile])
1697 AC_CONFIG_FILES([dlls/sfc/Makefile])
1698 AC_CONFIG_FILES([dlls/sfc_os/Makefile])
1699 AC_CONFIG_FILES([dlls/shdoclc/Makefile])
1700 AC_CONFIG_FILES([dlls/shdocvw/Makefile])
1701 AC_CONFIG_FILES([dlls/shdocvw/tests/Makefile])
1702 AC_CONFIG_FILES([dlls/shell32/Makefile])
1703 AC_CONFIG_FILES([dlls/shell32/tests/Makefile])
1704 AC_CONFIG_FILES([dlls/shfolder/Makefile])
1705 AC_CONFIG_FILES([dlls/shlwapi/Makefile])
1706 AC_CONFIG_FILES([dlls/shlwapi/tests/Makefile])
1707 AC_CONFIG_FILES([dlls/snmpapi/Makefile])
1708 AC_CONFIG_FILES([dlls/snmpapi/tests/Makefile])
1709 AC_CONFIG_FILES([dlls/spoolss/Makefile])
1710 AC_CONFIG_FILES([dlls/stdole2.tlb/Makefile])
1711 AC_CONFIG_FILES([dlls/stdole32.tlb/Makefile])
1712 AC_CONFIG_FILES([dlls/sti/Makefile])
1713 AC_CONFIG_FILES([dlls/strmiids/Makefile])
1714 AC_CONFIG_FILES([dlls/svrapi/Makefile])
1715 AC_CONFIG_FILES([dlls/sxs/Makefile])
1716 AC_CONFIG_FILES([dlls/tapi32/Makefile])
1717 AC_CONFIG_FILES([dlls/twain_32/Makefile])
1718 AC_CONFIG_FILES([dlls/unicows/Makefile])
1719 AC_CONFIG_FILES([dlls/url/Makefile])
1720 AC_CONFIG_FILES([dlls/urlmon/Makefile])
1721 AC_CONFIG_FILES([dlls/urlmon/tests/Makefile])
1722 AC_CONFIG_FILES([dlls/user32/Makefile])
1723 AC_CONFIG_FILES([dlls/user32/tests/Makefile])
1724 AC_CONFIG_FILES([dlls/userenv/Makefile])
1725 AC_CONFIG_FILES([dlls/usp10/Makefile])
1726 AC_CONFIG_FILES([dlls/usp10/tests/Makefile])
1727 AC_CONFIG_FILES([dlls/uuid/Makefile])
1728 AC_CONFIG_FILES([dlls/uxtheme/Makefile])
1729 AC_CONFIG_FILES([dlls/uxtheme/tests/Makefile])
1730 AC_CONFIG_FILES([dlls/vdhcp.vxd/Makefile])
1731 AC_CONFIG_FILES([dlls/vdmdbg/Makefile])
1732 AC_CONFIG_FILES([dlls/version/Makefile])
1733 AC_CONFIG_FILES([dlls/version/tests/Makefile])
1734 AC_CONFIG_FILES([dlls/vmm.vxd/Makefile])
1735 AC_CONFIG_FILES([dlls/vnbt.vxd/Makefile])
1736 AC_CONFIG_FILES([dlls/vnetbios.vxd/Makefile])
1737 AC_CONFIG_FILES([dlls/vtdapi.vxd/Makefile])
1738 AC_CONFIG_FILES([dlls/vwin32.vxd/Makefile])
1739 AC_CONFIG_FILES([dlls/w32skrnl/Makefile])
1740 AC_CONFIG_FILES([dlls/winealsa.drv/Makefile])
1741 AC_CONFIG_FILES([dlls/wineaudioio.drv/Makefile])
1742 AC_CONFIG_FILES([dlls/winecoreaudio.drv/Makefile])
1743 AC_CONFIG_FILES([dlls/winecrt0/Makefile])
1744 AC_CONFIG_FILES([dlls/wined3d/Makefile])
1745 AC_CONFIG_FILES([dlls/winedos/Makefile])
1746 AC_CONFIG_FILES([dlls/wineesd.drv/Makefile])
1747 AC_CONFIG_FILES([dlls/winejack.drv/Makefile])
1748 AC_CONFIG_FILES([dlls/winejoystick.drv/Makefile])
1749 AC_CONFIG_FILES([dlls/winemp3.acm/Makefile])
1750 AC_CONFIG_FILES([dlls/winenas.drv/Makefile])
1751 AC_CONFIG_FILES([dlls/wineoss.drv/Makefile])
1752 AC_CONFIG_FILES([dlls/wineps.drv/Makefile])
1753 AC_CONFIG_FILES([dlls/winequartz.drv/Makefile])
1754 AC_CONFIG_FILES([dlls/winex11.drv/Makefile])
1755 AC_CONFIG_FILES([dlls/wing32/Makefile])
1756 AC_CONFIG_FILES([dlls/wininet/Makefile])
1757 AC_CONFIG_FILES([dlls/wininet/tests/Makefile])
1758 AC_CONFIG_FILES([dlls/winmm/Makefile])
1759 AC_CONFIG_FILES([dlls/winmm/tests/Makefile])
1760 AC_CONFIG_FILES([dlls/winnls32/Makefile])
1761 AC_CONFIG_FILES([dlls/winscard/Makefile])
1762 AC_CONFIG_FILES([dlls/winspool.drv/Makefile])
1763 AC_CONFIG_FILES([dlls/winspool.drv/tests/Makefile])
1764 AC_CONFIG_FILES([dlls/wintab32/Makefile])
1765 AC_CONFIG_FILES([dlls/wintrust/Makefile])
1766 AC_CONFIG_FILES([dlls/wintrust/tests/Makefile])
1767 AC_CONFIG_FILES([dlls/wldap32/Makefile])
1768 AC_CONFIG_FILES([dlls/wnaspi32/Makefile])
1769 AC_CONFIG_FILES([dlls/wow32/Makefile])
1770 AC_CONFIG_FILES([dlls/ws2_32/Makefile])
1771 AC_CONFIG_FILES([dlls/ws2_32/tests/Makefile])
1772 AC_CONFIG_FILES([dlls/wsock32/Makefile])
1773 AC_CONFIG_FILES([dlls/wtsapi32/Makefile])
1774 AC_CONFIG_FILES([documentation/Makefile])
1775 AC_CONFIG_FILES([fonts/Makefile])
1776 AC_CONFIG_FILES([include/Makefile])
1777 AC_CONFIG_FILES([libs/Makefile])
1778 AC_CONFIG_FILES([libs/port/Makefile])
1779 AC_CONFIG_FILES([libs/wine/Makefile])
1780 AC_CONFIG_FILES([libs/wpp/Makefile])
1781 AC_CONFIG_FILES([loader/Makefile])
1782 AC_CONFIG_FILES([programs/Makefile])
1783 AC_CONFIG_FILES([programs/clock/Makefile])
1784 AC_CONFIG_FILES([programs/cmd/Makefile])
1785 AC_CONFIG_FILES([programs/cmdlgtst/Makefile])
1786 AC_CONFIG_FILES([programs/control/Makefile])
1787 AC_CONFIG_FILES([programs/eject/Makefile])
1788 AC_CONFIG_FILES([programs/expand/Makefile])
1789 AC_CONFIG_FILES([programs/explorer/Makefile])
1790 AC_CONFIG_FILES([programs/hh/Makefile])
1791 AC_CONFIG_FILES([programs/icinfo/Makefile])
1792 AC_CONFIG_FILES([programs/iexplore/Makefile])
1793 AC_CONFIG_FILES([programs/msiexec/Makefile])
1794 AC_CONFIG_FILES([programs/net/Makefile])
1795 AC_CONFIG_FILES([programs/notepad/Makefile])
1796 AC_CONFIG_FILES([programs/oleview/Makefile])
1797 AC_CONFIG_FILES([programs/progman/Makefile])
1798 AC_CONFIG_FILES([programs/regedit/Makefile])
1799 AC_CONFIG_FILES([programs/regsvr32/Makefile])
1800 AC_CONFIG_FILES([programs/rpcss/Makefile])
1801 AC_CONFIG_FILES([programs/rundll32/Makefile])
1802 AC_CONFIG_FILES([programs/spoolsv/Makefile])
1803 AC_CONFIG_FILES([programs/start/Makefile])
1804 AC_CONFIG_FILES([programs/taskmgr/Makefile])
1805 AC_CONFIG_FILES([programs/uninstaller/Makefile])
1806 AC_CONFIG_FILES([programs/view/Makefile])
1807 AC_CONFIG_FILES([programs/wineboot/Makefile])
1808 AC_CONFIG_FILES([programs/winebrowser/Makefile])
1809 AC_CONFIG_FILES([programs/winecfg/Makefile])
1810 AC_CONFIG_FILES([programs/wineconsole/Makefile])
1811 AC_CONFIG_FILES([programs/winedbg/Makefile])
1812 AC_CONFIG_FILES([programs/winedevice/Makefile])
1813 AC_CONFIG_FILES([programs/winefile/Makefile])
1814 AC_CONFIG_FILES([programs/winemenubuilder/Makefile])
1815 AC_CONFIG_FILES([programs/winemine/Makefile])
1816 AC_CONFIG_FILES([programs/winepath/Makefile])
1817 AC_CONFIG_FILES([programs/winetest/Makefile])
1818 AC_CONFIG_FILES([programs/winevdm/Makefile])
1819 AC_CONFIG_FILES([programs/winhelp/Makefile])
1820 AC_CONFIG_FILES([programs/winver/Makefile])
1821 AC_CONFIG_FILES([programs/wordpad/Makefile])
1822 AC_CONFIG_FILES([programs/xcopy/Makefile])
1823 AC_CONFIG_FILES([server/Makefile])
1824 AC_CONFIG_FILES([tools/Makefile])
1825 AC_CONFIG_FILES([tools/widl/Makefile])
1826 AC_CONFIG_FILES([tools/winebuild/Makefile])
1827 AC_CONFIG_FILES([tools/winedump/Makefile])
1828 AC_CONFIG_FILES([tools/winegcc/Makefile])
1829 AC_CONFIG_FILES([tools/wmc/Makefile])
1830 AC_CONFIG_FILES([tools/wrc/Makefile])
1831
1832 AC_OUTPUT
1833
1834 dnl **** Display messages about additional packages ***
1835
1836 if test "$no_create" = "yes"
1837 then
1838   exit 0
1839 fi
1840
1841 if test "$verbose" = "yes"
1842 then
1843   dnl **** libcapi20-dev devel package ***
1844   if test "$ac_cv_header_capi20_h" != "yes" -o "$ac_cv_header_linux_capi_h" != "yes"
1845   then
1846     echo >&2
1847     AC_MSG_NOTICE([libcapi20 development files not found.])
1848     AC_MSG_NOTICE([Wine will be built without ISDN support. (capi2032.dll)])
1849   fi
1850
1851   dnl **** libcupsys-dev devel package ***
1852   if test "$ac_cv_header_cups_cups_h" != "yes"
1853   then
1854     echo >&2
1855     AC_MSG_NOTICE([libcups development files not found.])
1856     AC_MSG_NOTICE([Wine will be built without CUPS support.])
1857   fi
1858
1859   dnl **** libcurses devel package: see libncurses ***
1860   dnl **** libdbus-1 devel package ***
1861   dnl **** libdbus-1-dev is required for libhal-dev ***
1862
1863   dnl **** libgphoto2 devel package ***
1864   if test "$ac_cv_header_gphoto2_camera_h" != "yes"
1865   then
1866     echo >&2
1867     AC_MSG_NOTICE([libgphoto2 development files not found.])
1868     if test "$ac_cv_header_sane_sane_h" = "yes"
1869     then
1870       AC_MSG_NOTICE([Wine will be built with limited Digital Camera support. (twain_32.dll)])
1871     else
1872       AC_MSG_NOTICE([Wine will be built without Digital Camera support. (gphoto2.ds/twain_32.dll)])
1873     fi
1874   fi
1875
1876   dnl **** libhal devel package ***
1877   dnl **** libhal-dev depends on libdbus-1-dev ***
1878   if test "$ac_cv_header_hal_libhal_h" != "yes"
1879   then
1880     echo >&2
1881     AC_MSG_NOTICE([libhal development files not found.])
1882     AC_MSG_NOTICE([Wine will be built without dynamic device support. (explorer.exe)])
1883   fi
1884
1885   dnl **** libicu devel package ****
1886   if test "$ac_cv_header_unicode_ubidi_h" != "yes"
1887   then
1888     echo >&2
1889     AC_MSG_NOTICE([libicu development files not found.])
1890     AC_MSG_NOTICE([Wine will be built without bidi (Right to Left) support. (gdi32.dll)])
1891   fi
1892
1893   dnl **** liblcms devel package ****
1894   if test "$ac_cv_header_lcms_h" != "yes" -a "$ac_cv_header_lcms_lcms_h" != "yes"
1895   then
1896     echo >&2
1897     AC_MSG_NOTICE([liblcms development files not found.])
1898     AC_MSG_NOTICE([Wine will be built without Color Management support. (mscms.dll)])
1899   fi
1900
1901   dnl **** libldap devel package ****
1902   if test "$ac_cv_header_ldap_h" != "yes" -o "$ac_cv_header_lber_h" != "yes"
1903   then
1904     echo >&2
1905     AC_MSG_NOTICE([libldap (OpenLDAP) development files not found.])
1906     AC_MSG_NOTICE([Wine will be built without LDAP support. (wldap32.dll)])
1907   fi
1908
1909   dnl **** libncurses / libcurses devel package ***
1910   if test "x$with_curses" != "xno" -a "$ac_cv_header_ncurses_h" != "yes" -a "$ac_cv_header_curses_h" != "yes"
1911   then
1912     echo >&2
1913     AC_MSG_NOTICE([lib(n)curses development files not found.])
1914     AC_MSG_NOTICE([Wine will be built without (n)curses support. (wineconsole.exe)])
1915   fi
1916
1917   dnl **** libsane devel package ***
1918   if test "$ac_cv_header_sane_sane_h" != "yes"
1919   then
1920     echo >&2
1921     AC_MSG_NOTICE([libsane development files not found.])
1922     AC_MSG_NOTICE([Wine will be built without Scanner support. (sane.ds/twain_32.dll)])
1923   fi
1924
1925   dnl **** libX11-dev includes Xlib.h and Xutil.h and depends on ***
1926   dnl **** x11proto-input-dev (extensions/XInput.h) and x11proto-kb-dev (XKBlib.h) ***
1927   if test "$have_x" = "yes"
1928   then
1929     dnl **** libX11 - extension: Xext ***
1930     if test "$ac_cv_header_X11_extensions_shape_h" != "yes" -o "$ac_cv_header_X11_extensions_XShm_h" != "yes"
1931     then
1932       echo >&2
1933       AC_MSG_NOTICE([libxext development files not found.])
1934       AC_MSG_NOTICE([Wine will be built without Shm / Shape support. (winex11.drv)])
1935     fi
1936
1937     dnl **** libX11 - extension: Xrandr ***
1938     if test "$ac_cv_header_X11_extensions_Xrandr_h" != "yes"
1939     then
1940       echo >&2
1941       AC_MSG_NOTICE([libXrandr development files not found.])
1942       AC_MSG_NOTICE([Wine will be built without Xrandr support. (winex11.drv)])
1943     fi
1944
1945     dnl **** libX11 - extension: Xrender ***
1946     if test "$ac_cv_header_X11_extensions_Xrender_h" != "yes"
1947     then
1948       echo >&2
1949       AC_MSG_NOTICE([libXrender development files not found.])
1950       AC_MSG_NOTICE([Wine will be built without Xrender support. (winex11.drv)])
1951     fi
1952
1953     dnl **** libX11 - extension: Xxf86vm ***
1954     if test "$ac_cv_header_X11_extensions_xf86vmode_h" != "yes"
1955     then
1956       echo >&2
1957       AC_MSG_NOTICE([libXxf86vm development files not found.])
1958       AC_MSG_NOTICE([Wine will be built without XFree86-VidMode support. (winex11.drv)])
1959     fi
1960   fi
1961
1962   dnl **** libxml2 devel package ***
1963   if test "$ac_cv_header_libxml_parser_h" != "yes"
1964   then
1965     echo >&2
1966     AC_MSG_NOTICE([libxml2 development files not found.])
1967     AC_MSG_NOTICE([Wine will be built without XML support. (msxml.dll)])
1968   fi
1969
1970   dnl **** libxslt devel package ***
1971   if test "$ac_cv_header_libxslt_pattern_h" != "yes" -o "$ac_cv_header_libxslt_transform_h" != "yes"
1972   then
1973     echo >&2
1974     AC_MSG_NOTICE([libxslt development files not found.])
1975     AC_MSG_NOTICE([Wine will be built without xslt support. (msxml.dll)])
1976   fi
1977 fi
1978
1979
1980 dnl **** Display warnings about important packages ***
1981 if test "$have_x" = "no"
1982 then
1983   echo >&2
1984   AC_MSG_WARN([X development files not found. Wine will be built without])
1985   AC_MSG_WARN([X support, which currently does not work, and probably])
1986   AC_MSG_WARN([isn't what you want anyway. You will need to install devel])
1987   AC_MSG_WARN([ packages of Xlib/Xfree86 at the very least.])
1988 fi
1989
1990 if test -z "$OPENGLFILES"
1991 then
1992   echo >&2
1993   AC_MSG_WARN([Wine will be build without OpenGL or Direct3D support])
1994   AC_MSG_WARN([because something is wrong with the OpenGL setup:])
1995   if test "$wine_cv_opengl_headers_found" = "no"
1996   then
1997     AC_MSG_WARN([No OpenGL development headers were found])
1998   fi
1999   if test "$wine_cv_opengl_header_version_OK" = "no"
2000   then
2001     AC_MSG_WARN([Old Mesa headers detected. Consider upgrading your Mesa libraries (http://www.mesa3d.org/).])
2002   elif test "$ac_cv_lib_GL_glXCreateContext" = "no"
2003   then
2004      if test -f /usr/X11R6/lib/libGL.a
2005      then
2006         AC_MSG_WARN([/usr/X11R6/lib/libGL.a is present on your system.
2007 This probably prevents linking to OpenGL. Try deleting the file and restarting configure.])
2008      else
2009         AC_MSG_WARN([No OpenGL library found on this system.])
2010      fi
2011   fi
2012 fi
2013
2014 if test "$wine_cv_msg_freetype" = "yes"
2015 then
2016   echo >&2
2017   AC_MSG_WARN([Your system appears to have the FreeType 2 runtime libraries])
2018   AC_MSG_WARN([installed, but 'freetype-config' is not in your PATH. Install])
2019   AC_MSG_WARN([the freetype-devel package (or its equivalent on your distribution)])
2020   AC_MSG_WARN([to enable Wine to use TrueType fonts.])
2021 fi
2022
2023 if test -z "$FONTSSUBDIRS"
2024 then
2025   echo >&2
2026   if test "$FONTFORGE" = "false"
2027   then
2028     AC_MSG_WARN([FontForge is missing.])
2029   else
2030     AC_MSG_WARN([FreeType is missing.])
2031   fi
2032   AC_MSG_WARN([Fonts will not be built. Dialog text may be invisible or unaligned.])
2033 fi
2034
2035 if test -z "$ALSALIBS" -a \
2036         -z "$AUDIOIOLIBS" -a \
2037         -z "$NASLIBS" -a \
2038         -z "$ESD_LIBS" -a \
2039         -z "$ac_cv_lib_soname_jack" -a \
2040         "$ac_cv_header_sys_soundcard_h" != "yes" -a \
2041         "$ac_cv_header_machine_soundcard_h" != "yes" -a \
2042         "$ac_cv_header_soundcard_h" != "yes"
2043 then
2044   echo >&2
2045   AC_MSG_WARN([No sound system was found. Windows applications will be silent.])
2046   AC_MSG_WARN([The currently supported sound systems are:])
2047   AC_MSG_WARN([ALSA, EsounD, AudioIO, Jack, NAS and OSS])
2048 fi
2049
2050 echo
2051 echo "Configure finished.  Do '${ac_make} depend && ${ac_make}' to compile Wine."
2052 echo
2053
2054 dnl Local Variables:
2055 dnl comment-start: "dnl "
2056 dnl comment-end: ""
2057 dnl comment-start-skip: "\\bdnl\\b\\s *"
2058 dnl compile-command: "autoreconf --warnings=all"
2059 dnl End: