git.oblomov.eu Git - wine/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 AC_PREREQ(2.53)
   8 AC_INIT([Wine],WINE_VERSION,[wine-devel@winehq.org])
   9 AC_CONFIG_SRCDIR(server/atom.c)
  10 AC_CONFIG_HEADERS(include/config.h)
  11 AC_CONFIG_AUX_DIR(tools)
  12
  13 dnl **** Command-line arguments ****
  14
  15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
  16 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
  17 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
  18
  19 AC_ARG_WITH(opengl,    AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
  20 AC_ARG_WITH(curses,    AC_HELP_STRING([--without-curses],[do not use curses]))
  21 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
  22
  23 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
  24 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
  25 if test "x$enable_win16" = "xno"
  26 then
  27   WIN16_FILES=""
  28   WIN16_INSTALL=""
  29 fi
  30 if test "x$enable_debug" = "xno"
  31 then
  32     AC_DEFINE(NO_DEBUG_MSGS,1,[Define to disable all debug messages.])
  33 fi
  34 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
  35 then
  36     AC_DEFINE(NO_TRACE_MSGS,1,[Define to disable trace messages.])
  37 fi
  38
  39 dnl **** Check for some programs ****
  40
  41 AC_CANONICAL_HOST
  42 AC_PROG_MAKE_SET
  43 AC_PROG_CC
  44 AC_PROG_CPP
  45
  46 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
  47   [if test -z "$with_wine_tools"; then
  48      if test "$cross_compiling" = "yes"; then
  49        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
  50      else
  51        wine_cv_toolsdir="\$(TOPOBJDIR)"
  52      fi
  53    elif test -d "$with_wine_tools/tools/winebuild"; then
  54      case $with_wine_tools in
  55        /*) wine_cv_toolsdir="$with_wine_tools" ;;
  56        *)  wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
  57      esac
  58    else
  59      AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
  60    fi])
  61 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
  62
  63 AC_PATH_XTRA
  64 AC_PROG_YACC
  65 AC_PROG_LEX
  66
  67 dnl **** Just additional warning checks, since AC_PROG just sets 'yacc' even
  68 dnl **** without one present.
  69 AC_CHECK_PROGS(XYACC,$YACC bison yacc,none)
  70 if test "$XYACC" = "none"
  71 then
  72   AC_MSG_ERROR([no suitable bison/yacc found. Please install the 'bison' package.])
  73 fi
  74 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
  75 if test "$XLEX" = "none"
  76 then
  77   AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
  78 fi
  79
  80 AC_CHECK_TOOLS(AS,[gas as],as)
  81 AC_CHECK_TOOL(LD,ld,ld)
  82 AC_CHECK_TOOL(AR,ar,ar)
  83 AC_PROG_RANLIB
  84 AC_CHECK_TOOL(STRIP,strip,strip)
  85 AC_CHECK_TOOL(WINDRES,windres,false)
  86 AC_PROG_LN_S
  87 WINE_PROG_LN
  88 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
  89 AC_PROG_INSTALL
  90 dnl Prepend src dir to install path dir if it's a relative path
  91 case "$INSTALL" in
  92   [[\\/$]]* | ?:[[\\/]]* ) ;;
  93   *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
  94 esac
  95
  96 dnl Check for lint
  97 AC_CHECK_PROGS(LINT, lclint lint)
  98 if test "$LINT" = "lint"
  99 then
 100   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 101   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 102 fi
 103 AC_SUBST(LINT)
 104 AC_SUBST(LINTFLAGS)
 105
 106 dnl Check for db2html
 107 AC_CHECK_PROGS(DB2HTML, docbook2html db2html, false)
 108 AC_SUBST(DB2HTML)
 109
 110 dnl Check for db2pdf
 111 AC_CHECK_PROGS(DB2PDF, docbook2pdf db2pdf, false)
 112 AC_SUBST(DB2PDF)
 113
 114 dnl Check for db2ps
 115 AC_CHECK_PROGS(DB2PS, docbook2ps db2ps, false)
 116 AC_SUBST(DB2PS)
 117
 118 dnl Check for db2txt
 119 AC_CHECK_PROGS(DB2TXT, docbook2txt db2txt, false)
 120 AC_SUBST(DB2TXT)
 121
 122 dnl **** Check for some libraries ****
 123
 124 dnl Check for -lm
 125 AC_CHECK_LIB(m,sqrt)
 126 dnl Check for -li386 for NetBSD and OpenBSD
 127 AC_CHECK_LIB(i386,i386_set_ldt)
 128 dnl Check for -lossaudio for NetBSD
 129 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 130 dnl Check for -lw for Solaris
 131 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
 132 dnl Check for -lnsl for Solaris
 133 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
 134 dnl Check for -lsocket for Solaris
 135 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
 136 dnl Check for -lresolv for Solaris
 137 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
 138 dnl Check for -lxpg4 for FreeBSD
 139 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
 140 dnl Check for -lpoll for Mac OS X/Darwin
 141 AC_CHECK_LIB(poll,poll)
 142 dnl Check for -lpthread
 143 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
 144
 145 JPEGLIB=""
 146 AC_SUBST(JPEGLIB)
 147 AC_CHECK_HEADERS(jpeglib.h,
 148     AC_CHECK_LIB(jpeg,jpeg_start_decompress,
 149         AC_DEFINE(HAVE_LIBJPEG,1,[Define if you have libjpeg including devel headers])
 150         JPEGLIB="-ljpeg"
 151     )
 152 )
 153
 154 AC_SUBST(GIFLIB,"")
 155 AC_CHECK_HEADERS(gif_lib.h,
 156     AC_CHECK_LIB(ungif,DGifOpen,
 157         [AC_DEFINE(HAVE_LIBGIF,1,[Define if you have libgif/libungif including devel headers])
 158          GIFLIB="-lungif"],
 159         [AC_CHECK_LIB(gif,DGifOpen,
 160                       [AC_DEFINE(HAVE_LIBGIF,1)
 161                        GIFLIB="-lgif"])]))
 162
 163 AC_SUBST(XLIB)
 164 AC_SUBST(XFILES)
 165 XFILES=""
 166 AC_SUBST(OPENGLFILES)
 167 OPENGLFILES=""
 168 AC_SUBST(GLU32FILES)
 169 GLU32FILES=""
 170 AC_SUBST(OPENGL_LIBS)
 171 OPENGL_LIBS=""
 172 if test "$have_x" = "yes"
 173 then
 174     XLIB="-lXext -lX11"
 175     ac_save_CPPFLAGS="$CPPFLAGS"
 176     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 177
 178     dnl *** All of the following tests require X11/Xlib.h
 179     AC_CHECK_HEADERS(X11/Xlib.h,
 180       [
 181         AC_CHECK_HEADERS([X11/XKBlib.h \
 182                           X11/Xutil.h \
 183                           X11/extensions/shape.h \
 184                           X11/extensions/XInput.h \
 185                           X11/extensions/XShm.h \
 186                           X11/extensions/Xrandr.h \
 187                           X11/extensions/Xrender.h \
 188                           X11/extensions/Xvlib.h \
 189                           X11/extensions/xf86dga.h \
 190                           X11/extensions/xf86vmode.h],,,
 191                          [#include <X11/Xlib.h>
 192                           #ifdef HAVE_X11_XUTIL_H
 193                           # include <X11/Xutil.h>
 194                           #endif])
 195
 196         dnl *** Check for X keyboard extension
 197         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 198         then
 199               AC_CHECK_LIB(X11, XkbQueryExtension,
 200               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 201               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 202         fi
 203
 204         dnl *** Check for X Shm extension
 205         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 206         then
 207               AC_CHECK_LIB(Xext, XShmQueryExtension,
 208               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 209               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 210         fi
 211
 212         dnl *** Check for X shape extension
 213         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 214         then
 215               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 216               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 217               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 218         fi
 219
 220         dnl *** Check for XFree86 DGA / DGA 2.0 extension
 221         if test "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
 222         then
 223               AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
 224                 [ dnl *** If found...
 225                   AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
 226                             [Define if you have the Xxf86dga library version 2])
 227                   X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 228                ],
 229                 [ dnl *** If not found, look for XF86DGAQueryExtension()
 230                   dnl *** instead (DGA 2.0 not found)...
 231                   AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
 232                     [ AC_DEFINE(HAVE_LIBXXF86DGA, 1,
 233                                 [Define if you have the Xxf86dga library version 1])
 234                       X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 235                     ],,
 236                     $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 237                   )
 238                 ],
 239                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 240         fi
 241
 242         dnl *** Check for XFree86 VMODE extension
 243         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 244         then
 245                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 246                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 247                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 248                   ],,
 249                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 250         fi
 251
 252         dnl *** Check for X RandR extension
 253         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
 254         then
 255                 AC_CHECK_LIB(Xrandr, XRRSetScreenConfigAndRate,
 256                   [ AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])
 257                      X_PRE_LIBS="$X_PRE_LIBS -lXrandr -lXrender"
 258                   ],,
 259                   $X_LIBS -lXrender -lXext -lX11 $X_EXTRA_LIBS)
 260         fi
 261
 262         dnl *** Check for XVideo extension supporting XvImages
 263         if test "$ac_cv_header_X11_extensions_Xvlib_h" = "yes"
 264         then
 265                 AC_CHECK_LIB(Xv, XvShmCreateImage,
 266                   [ AC_DEFINE(HAVE_XVIDEO, 1, [Define if the X libraries support XVideo])
 267                      X_PRE_LIBS="$X_PRE_LIBS -lXv"
 268                   ],,
 269                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 270         fi
 271       ]
 272     ) dnl *** End of X11/Xlib.h check
 273
 274     dnl Check for the presence of OpenGL
 275     if test "x$with_opengl" != "xno"
 276     then
 277         if test -f /usr/X11R6/lib/libGL.a -a ! -f /usr/X11R6/lib/libGL.so
 278         then
 279             AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
 280 This prevents linking to OpenGL. Delete the file and restart configure.])
 281         fi
 282
 283         AC_CHECK_HEADERS(GL/gl.h GL/glx.h)
 284         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 285         then
 286             AC_CHECK_HEADERS(GL/glext.h,,,[#include <GL/glx.h>])
 287             dnl Check for some problems due to old Mesa versions
 288             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
 289               AC_TRY_COMPILE(
 290                 [#include <GL/gl.h>],
 291                 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 292                 [wine_cv_opengl_version_OK="yes"],
 293                 [wine_cv_opengl_version_OK="no"]
 294               )
 295             )
 296
 297             if test "$wine_cv_opengl_version_OK" = "yes"
 298             then
 299                 dnl Check for the presence of the library
 300                 AC_CHECK_LIB(GL,glXCreateContext,
 301                              OPENGL_LIBS="-lGL"
 302                              ,,
 303                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 304
 305                 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
 306                 then
 307                         OPENGLFILES='$(OPENGLFILES)'
 308                         AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
 309
 310                         AC_CHECK_LIB(GL,glXGetProcAddressARB,
 311                                      AC_DEFINE(HAVE_GLX_GETPROCADDRESS, 1,
 312                                                [Define if the OpenGL library supports the glXGetProcAddressARB call]),,
 313                                      $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 314
 315                         if test "$ac_cv_lib_GL_glXGetProcAddressARB" = "yes"
 316                         then
 317                                AC_CACHE_CHECK([for OpenGL extension functions prototypes], wine_cv_extension_prototypes,
 318                                   [AC_TRY_COMPILE([#include <GL/gl.h>
 319                                                   #ifdef HAVE_GL_GLEXT_H
 320                                                   # include <GL/glext.h>
 321                                                   #endif
 322                                                   ],
 323                                                  [PFNGLCOLORTABLEEXTPROC test_proc;],
 324                                                  [wine_cv_extension_prototypes="yes"],
 325                                                  [wine_cv_extension_prototypes="no"]
 326                                   )]
 327                                 )
 328                                 if test "$wine_cv_extension_prototypes" = "yes"
 329                                 then
 330                                     AC_DEFINE(HAVE_GLEXT_PROTOTYPES, 1,
 331                                               [Define if the OpenGL headers define extension typedefs])
 332                                 fi
 333                         fi
 334
 335                 fi
 336                 dnl Check for GLU32 library.
 337                 AC_CHECK_LIB(GLU,gluLookAt,
 338                              [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
 339                              GLU32FILES='$(GLU32FILES)']
 340                              ,,
 341                              $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
 342                 )
 343              fi
 344
 345              dnl Check for glut32 library.
 346              AC_CHECK_LIB(glut,glutMainLoop,
 347                        [AC_SUBST(GLUT_LIBS,"-lglut -lXmu -lXi")
 348                         AC_SUBST(GLUT32FILES,'$(GLUT32FILES)')],,
 349                         $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXmu -lXi -lX11 $X_EXTRA_LIBS)
 350          fi
 351     fi
 352
 353     dnl **** Check for NAS ****
 354     AC_SUBST(NASLIBS,"")
 355     AC_CHECK_HEADERS(audio/audiolib.h,
 356          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
 357           AC_CHECK_LIB(audio,AuCreateFlow,
 358                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
 359                         NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
 360                        [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 361
 362     CPPFLAGS="$ac_save_CPPFLAGS"
 363     XFILES='$(XFILES)'
 364 else
 365     XLIB=""
 366     X_CFLAGS=""
 367     X_LIBS=""
 368 fi
 369
 370 dnl **** Check which curses lib to use ***
 371 CURSESLIBS=""
 372 if test "x$with_curses" != "xno"
 373 then
 374     AC_CHECK_HEADERS(ncurses.h,
 375         [AC_CHECK_LIB(ncurses,waddch,
 376             [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
 377              CURSESLIBS="-lncurses"],
 378              [AC_CHECK_HEADERS(curses.h,
 379                  [AC_CHECK_LIB(curses,waddch,
 380                      [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
 381                       CURSESLIBS="-lcurses"])])])])
 382     saved_libs="$LIBS"
 383     LIBS="$CURSESLIBS $LIBS"
 384     AC_CHECK_FUNCS(getbkgd resizeterm)
 385     LIBS="$saved_libs"
 386 fi
 387 AC_SUBST(CURSESLIBS)
 388
 389 dnl **** Check for SANE ****
 390 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
 391 if test "$sane_devel" = "no"
 392 then
 393     SANELIBS=""
 394     SANEINCL=""
 395 else
 396     SANELIBS="`$sane_devel --libs`"
 397     SANEINCL="`$sane_devel --cflags`"
 398     ac_save_CPPFLAGS="$CPPFLAGS"
 399     ac_save_LIBS="$LIBS"
 400     CPPFLAGS="$CPPFLAGS $SANEINCL"
 401     LIBS="$LIBS $SANELIBS"
 402     AC_CHECK_HEADER(sane/sane.h,
 403                     [AC_CHECK_LIB(sane,sane_open,
 404                                   [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
 405                                   [SANELIBS=""
 406                                   SANEINCL=""])],
 407                     [SANELIBS=""
 408                     SANEINCL=""])
 409     LIBS="$ac_save_LIBS"
 410     CPPFLAGS="$ac_save_CPPFLAGS"
 411 fi
 412 AC_SUBST(SANELIBS)
 413 AC_SUBST(SANEINCL)
 414
 415 dnl **** Check for the ICU library ****
 416 AC_CHECK_HEADERS(unicode/ubidi.h)
 417 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
 418 then
 419     saved_libs="$LIBS"
 420     ICU_LIB_DIR="${ICU_LIB_DIR-/usr/lib}"
 421     ICUUC_LIB="${ICUUC_LIB-$ICU_LIB_DIR/libicuuc.a}"
 422     ICUDATA_LIB="${ICUDATA_LIB-$ICU_LIB_DIR/libicudata.a}"
 423     LIBS="$LIBS $ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s"
 424     AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
 425                 [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
 426                  AC_SUBST(ICULIBS,"$ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s")])
 427     LIBS="$saved_libs"
 428 fi
 429
 430 dnl **** Check for FreeType 2 ****
 431 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
 432 if test "$ft_lib" = "no"
 433 then
 434     FREETYPEINCL=""
 435     wine_cv_msg_freetype=no
 436 else
 437     AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
 438     if test "$ft_devel" = "no"
 439     then
 440         AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
 441         if test "$ft_devel2" = "freetype2-config"
 442         then
 443                 ft_devel=$ft_devel2
 444         fi
 445     fi
 446     if test "$ft_devel" = "no"
 447     then
 448         FREETYPEINCL=""
 449         wine_cv_msg_freetype=yes
 450     else
 451         FREETYPEINCL=`$ft_devel --cflags`
 452         ac_save_CPPFLAGS="$CPPFLAGS"
 453         CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
 454         AC_CHECK_HEADERS(ft2build.h \
 455                          freetype/freetype.h \
 456                          freetype/ftglyph.h \
 457                          freetype/tttables.h \
 458                          freetype/ftnames.h \
 459                          freetype/ftsnames.h \
 460                          freetype/ttnameid.h \
 461                          freetype/ftoutln.h \
 462                          freetype/internal/sfnt.h,,,
 463                          [#if HAVE_FT2BUILD_H
 464                           #include <ft2build.h>
 465                           #endif])
 466         AC_TRY_CPP([#include <ft2build.h>
 467                     #include <freetype/fttrigon.h>],
 468                     [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
 469           [Define if you have the <freetype/fttrigon.h> header file.])
 470                     wine_cv_fttrigon=yes],
 471                     wine_cv_fttrigon=no)
 472         CPPFLAGS="$ac_save_CPPFLAGS"
 473         dnl Check that we have at least freetype/freetype.h
 474         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
 475         then
 476             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
 477             wine_cv_msg_freetype=no
 478         else
 479             FREETYPEINCL=""
 480             wine_cv_msg_freetype=yes
 481         fi
 482     fi
 483 fi
 484 AC_SUBST(FREETYPEINCL)
 485
 486 dnl **** Check for parport (currently Linux only) ****
 487 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
 488  AC_TRY_COMPILE(
 489    [#include <linux/ppdev.h>],
 490    [ioctl (1,PPCLAIM,0)],
 491    [ac_cv_c_ppdev="yes"],
 492    [ac_cv_c_ppdev="no"])
 493  )
 494 if test "$ac_cv_c_ppdev" = "yes"
 495 then
 496     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
 497 fi
 498
 499 dnl **** Check for va_copy ****
 500 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
 501  AC_TRY_LINK(
 502    [#include <stdarg.h>],
 503    [va_list ap1, ap2;
 504     va_copy(ap1,ap2);
 505    ],
 506    [ac_cv_c_va_copy="yes"],
 507    [ac_cv_c_va_copy="no"])
 508  )
 509 if test "$ac_cv_c_va_copy" = "yes"
 510 then
 511     AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
 512 fi
 513 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
 514  AC_TRY_LINK(
 515    [#include <stdarg.h>],
 516    [va_list ap1, ap2;
 517     __va_copy(ap1,ap2);
 518    ],
 519    [ac_cv_c___va_copy="yes"],
 520    [ac_cv_c___va_copy="no"])
 521  )
 522 if test "$ac_cv_c___va_copy" = "yes"
 523 then
 524     AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
 525 fi
 526
 527 dnl **** Check for sigsetjmp ****
 528 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
 529  AC_TRY_LINK(
 530    [#include <setjmp.h>],
 531    [sigjmp_buf buf;
 532     sigsetjmp( buf, 1 );
 533     siglongjmp( buf, 1 );],
 534    [ac_cv_c_sigsetjmp="yes"],
 535    [ac_cv_c_sigsetjmp="no"])
 536  )
 537 if test "$ac_cv_c_sigsetjmp" = "yes"
 538 then
 539     AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
 540 fi
 541
 542 dnl **** Check for pthread_rwlock_t ****
 543 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
 544 #include <pthread.h>])
 545
 546 dnl **** Check for pthread_getattr_np ****
 547 ac_save_LIBS="$LIBS"
 548 LIBS="$LIBS $LIBPTHREAD"
 549 AC_CHECK_FUNCS(pthread_getattr_np)
 550 LIBS="$ac_save_LIBS"
 551
 552 dnl **** Check for Open Sound System ****
 553 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
 554
 555 AC_CACHE_CHECK([for Open Sound System],
 556         ac_cv_c_opensoundsystem,
 557         AC_TRY_COMPILE([
 558         #if defined(HAVE_SYS_SOUNDCARD_H)
 559                 #include <sys/soundcard.h>
 560         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 561                 #include <machine/soundcard.h>
 562         #elif defined(HAVE_SOUNDCARD_H)
 563                 #include <soundcard.h>
 564         #endif
 565         ],[
 566
 567 /* check for one of the Open Sound System specific SNDCTL_ defines */
 568 #if !defined(SNDCTL_DSP_STEREO)
 569 #error No open sound system
 570 #endif
 571 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
 572
 573 if test "$ac_cv_c_opensoundsystem" = "yes"
 574 then
 575     AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
 576 fi
 577
 578 AC_CACHE_CHECK([for Open Sound System/MIDI interface],
 579         ac_cv_c_opensoundsystem_midi,
 580         AC_TRY_COMPILE([
 581         #if defined(HAVE_SYS_SOUNDCARD_H)
 582                 #include <sys/soundcard.h>
 583         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 584                 #include <machine/soundcard.h>
 585         #elif defined(HAVE_SOUNDCARD_H)
 586                 #include <soundcard.h>
 587         #endif
 588         ],[
 589
 590 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
 591 #if !defined(SNDCTL_SEQ_SYNC)
 592 #error No open sound system MIDI interface
 593 #endif
 594 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
 595
 596 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
 597 then
 598     AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
 599 fi
 600
 601 dnl **** Check for aRts Sound Server ****
 602 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
 603 if test x$ARTSCCONFIG != x -a x$ARTSCCONFIG != x'"$ARTSCCONFIG"';
 604 then
 605     ARTSC_CFLAGS=`$ARTSCCONFIG --cflags`
 606     ARTSC_LIBS=`$ARTSCCONFIG --libs`
 607     save_CFLAGS="$CFLAGS"
 608     CFLAGS="$CFLAGS $ARTSC_CFLAGS"
 609     AC_TRY_COMPILE([#include <artsc.h>],[arts_stream_t stream;],
 610         [AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
 611          AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
 612          AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])])
 613     CFLAGS="$save_CFLAGS"
 614 fi
 615
 616 dnl **** Check for ALSA ****
 617 AC_SUBST(ALSALIBS,"")
 618 AC_CHECK_HEADERS(alsa/asoundlib.h sys/asoundlib.h, break)
 619 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
 620 then
 621     AC_CHECK_LIB(asound,snd_pcm_open,
 622         AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA including devel headers])
 623         ALSALIBS="-lasound")
 624 fi
 625
 626 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
 627
 628 AC_SUBST(AUDIOIOLIBS,"")
 629 AC_CHECK_HEADERS(libaudioio.h,
 630     [AC_CHECK_LIB(audioio,AudioIOGetVersion,
 631                   [AUDIOIOLIBS="-laudioio"
 632                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])])
 633
 634 dnl **** Check for capi4linux ****
 635
 636 AC_CHECK_HEADERS(capi20.h,[
 637         AC_CHECK_HEADERS(linux/capi.h,[
 638                 AC_CHECK_LIB(capi20,capi20_register,[
 639                         AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])
 640                         AC_SUBST(CAPI4LINUXLIBS,"-lcapi20")
 641                 ])
 642         ])
 643 ])
 644
 645 dnl **** Check for broken glibc mmap64 ****
 646
 647 AC_CACHE_CHECK( [whether mmap64 works defined as mmap], ac_cv_mmap64_works,
 648         AC_TRY_RUN([
 649                 #define _FILE_OFFSET_BITS 64
 650                 #include <stdio.h>
 651                 #include <unistd.h>
 652                 #include <fcntl.h>
 653                 #include <sys/mman.h>
 654                 #include <errno.h>
 655
 656                 int main(int argc,char **argv) {
 657                         int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
 658                         if (fd == -1) exit(1);
 659
 660                         unlink("conftest.map");
 661
 662                         write(fd,"test",4);
 663
 664                         if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
 665                             (errno == EINVAL)
 666                         ) {
 667                                 exit(1);
 668                         }
 669                         close(fd);
 670                         fprintf(stderr,"success!\n");
 671                         exit(0);
 672                 }
 673
 674         ],
 675     ac_cv_mmap64_works="yes",
 676     ac_cv_mmap64_works="no",
 677     ac_cv_mmap64_works="no") )
 678
 679 if test "$ac_cv_mmap64_works" = "yes"
 680 then
 681     AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
 682 fi
 683
 684 dnl **** Check for gcc specific options ****
 685
 686 AC_SUBST(EXTRACFLAGS,"")
 687 if test "x${GCC}" = "xyes"
 688 then
 689   EXTRACFLAGS="-Wall -pipe"
 690
 691   dnl Check for strength-reduce bug
 692   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
 693                   AC_TRY_RUN([
 694 int     L[[4]] = {0,1,2,3};
 695 int main(void) {
 696   static int Array[[3]];
 697   unsigned int B = 3;
 698   int i;
 699   for(i=0; i<B; i++) Array[[i]] = i - 3;
 700   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
 701   L[[i]] = 4;
 702
 703   exit( Array[[1]] != -2 || L[[2]] != 3);
 704 }],
 705     ac_cv_c_gcc_strength_bug="no",
 706     ac_cv_c_gcc_strength_bug="yes",
 707     ac_cv_c_gcc_strength_bug="yes") )
 708   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 709   then
 710     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
 711   fi
 712
 713   dnl Check for -mpreferred-stack-boundary
 714   AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support], ac_cv_c_gcc_stack_boundary,
 715       [WINE_TRY_CFLAGS([-mpreferred-stack-boundary=2],
 716                       ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")])
 717   if test "$ac_cv_c_gcc_stack_boundary" = "yes"
 718   then
 719     EXTRACFLAGS="$EXTRACFLAGS -mpreferred-stack-boundary=2"
 720   fi
 721
 722   dnl Check for -fno-strict-aliasing
 723   AC_CACHE_CHECK([for gcc -fno-strict-aliasing support], ac_cv_c_gcc_no_strict_aliasing,
 724       [WINE_TRY_CFLAGS([-fno-strict-aliasing],
 725                       ac_cv_c_gcc_no_strict_aliasing="yes",ac_cv_c_gcc_no_strict_aliasing="no")])
 726   if test "$ac_cv_c_gcc_no_strict_aliasing" = "yes"
 727   then
 728     EXTRACFLAGS="$EXTRACFLAGS -fno-strict-aliasing"
 729   fi
 730
 731   dnl Check for -gstabs+ option
 732   AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
 733       [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
 734   if test "$ac_cv_c_gcc_gstabs" = "yes"
 735   then
 736     EXTRACFLAGS="$EXTRACFLAGS -gstabs+"
 737   fi
 738
 739   dnl Check for noisy string.h
 740   saved_CFLAGS="$CFLAGS"
 741   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
 742   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
 743       AC_TRY_COMPILE([#include <string.h>],[],
 744                      [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
 745   CFLAGS="$saved_CFLAGS"
 746   if test "$ac_cv_c_string_h_warnings" = "no"
 747   then
 748     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
 749   fi
 750 fi
 751
 752 dnl **** Check how to define a function in assembly code ****
 753
 754 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
 755   WINE_TRY_ASM_LINK(
 756       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
 757       ac_cv_asm_func_def=".def",
 758     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
 759       ac_cv_asm_func_def=".type @function",
 760     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
 761       ac_cv_asm_func_def=".type 2",
 762       ac_cv_asm_func_def="unknown")])]))
 763
 764 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
 765 case "$ac_cv_asm_func_def" in
 766   ".def")
 767      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
 768   ".type @function")
 769      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
 770   ".type 2")
 771      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
 772   *)
 773      AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
 774 esac
 775
 776 dnl **** Check for underscore on external symbols ****
 777
 778 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
 779     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
 780                       [extern int ac_test;],
 781                       [if (ac_test) return 1],
 782                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
 783
 784 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
 785 if test "$ac_cv_c_extern_prefix" = "yes"
 786 then
 787   AC_DEFINE([__ASM_NAME(name)], ["_" name])
 788 else
 789   AC_DEFINE([__ASM_NAME(name)], [name])
 790 fi
 791
 792 dnl **** Check how to do strings in assembler ****
 793
 794 AC_CACHE_CHECK([for assembler keyword for ASCII strings], ac_cv_c_asm_string,
 795     WINE_TRY_ASM_LINK([".data\\n\\t.string \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".string",
 796       WINE_TRY_ASM_LINK([".data\\n\\t.asciz \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".asciz",
 797         WINE_TRY_ASM_LINK([".data\\n\\t.ascii \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".ascii",
 798           AC_MSG_ERROR([could not discover how to produce C strings with assembler.])))))
 799
 800 AC_DEFINE_UNQUOTED(__ASM_STRING, ["$ac_cv_c_asm_string"],
 801                    [Define to the assembler keyword used to specify an ASCII string])
 802
 803 dnl **** Check for .short in assembler ****
 804
 805 AC_CACHE_CHECK([for assembler keyword for word values], ac_cv_c_asm_short,
 806     WINE_TRY_ASM_LINK([".data\\n\\t.short 1\\n\\t.text"],,,ac_cv_c_asm_short=".short",
 807       WINE_TRY_ASM_LINK([".data\\n\\t.half 1\\n\\t.text"],,,ac_cv_c_asm_short=".half",
 808         AC_MSG_ERROR([could not discover how to specify word values with assembler.]))))
 809
 810 AC_DEFINE_UNQUOTED(__ASM_SHORT, ["$ac_cv_c_asm_short"],
 811                    [Define to the assembler keyword used to specify a word value])
 812
 813 dnl **** Check for working dll ****
 814
 815 AC_SUBST(DLLEXT,"")
 816 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 817 AC_SUBST(DLLIBS,"")
 818 AC_SUBST(LDSHARED,"")
 819 AC_SUBST(LDDLL,"")
 820 AC_SUBST(LIBEXT,"so")
 821 AC_SUBST(IMPLIBEXT,"def")
 822
 823 case $host_os in
 824   cygwin*|mingw32*)
 825     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 826     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 827     if test "$DLLWRAP" = "false"; then
 828       LIBEXT="a"
 829     else
 830       dnl FIXME - check whether dllwrap works correctly...
 831       LIBEXT="dll"
 832     fi
 833     IMPLIBEXT="a"
 834     ;;
 835   *)
 836     AC_CHECK_HEADERS(dlfcn.h,
 837         [AC_CHECK_FUNCS(dlopen,,
 838             [AC_CHECK_LIB(dl,dlopen,
 839                          [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
 840                           DLLIBS="-ldl"],
 841                          [LIBEXT="a"])])],
 842         [LIBEXT="a"])
 843
 844     if test "$LIBEXT" = "so"
 845     then
 846       DLLFLAGS="$DLLFLAGS -fPIC"
 847       DLLEXT=".so"
 848       AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
 849           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
 850                            ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
 851       if test "$ac_cv_c_dll_gnuelf" = "yes"
 852       then
 853         LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
 854         LDDLL="\$(CC) -shared -Wl,-Bsymbolic"
 855         AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
 856           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
 857                            ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
 858         if test "$ac_cv_c_dll_zdefs" = "yes"
 859         then
 860           LDDLL="$LDDLL,-z,defs"
 861         fi
 862
 863         AC_CACHE_CHECK([whether the linker accepts -init and -fini], ac_cv_c_dll_init_fini,
 864           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
 865                            ac_cv_c_dll_init_fini="yes",ac_cv_c_dll_init_fini="no")])
 866         if test "$ac_cv_c_dll_init_fini" = "yes"
 867         then
 868           AC_DEFINE(HAVE_LINKER_INIT_FINI,1,[Define if the linker supports renaming the init and fini functions])
 869           LDDLL="$LDDLL,-init,__wine_spec_init,-fini,__wine_spec_fini"
 870         fi
 871
 872         AC_CACHE_CHECK([whether the linker accepts --export-dynamic], ac_cv_c_export_dynamic,
 873           [WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
 874                            ac_cv_c_export_dynamic="yes",ac_cv_c_export_dynamic="no")])
 875         if test "$ac_cv_c_export_dynamic" = "yes"
 876         then
 877           AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])
 878         fi
 879
 880         case $host_cpu in
 881           *i[[3456789]]86*)
 882             AC_CACHE_CHECK([whether we can relocate the executable to 0x00110000], ac_cv_ld_reloc_exec,
 883               [saved_CFLAGS="$CFLAGS"
 884                CFLAGS="$CFLAGS -Wl,--section-start,.interp=0x00110400"
 885                AC_TRY_RUN([#include <unistd.h>
 886                            int main() { return (sbrk(32*1024*1024) == (void *)-1); }],
 887                           ac_cv_ld_reloc_exec="yes", ac_cv_ld_reloc_exec="no", ac_cv_ld_reloc_exec="no")
 888                CFLAGS="$saved_CFLAGS"])
 889             if test "$ac_cv_ld_reloc_exec" = "yes"
 890             then
 891               LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x00110400"
 892             fi
 893             ;;
 894         esac
 895
 896       else
 897         AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
 898             [WINE_TRY_CFLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
 899                              ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
 900         if test "$ac_cv_c_dll_unixware" = "yes"
 901         then
 902           LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
 903           LDDLL="\$(CC) -Wl,-G,-B,symbolic"
 904
 905         else
 906           AC_CACHE_CHECK(whether we can build a Mach-O (Mac OS X/Darwin) dll, ac_cv_c_dll_macho,
 907             [WINE_TRY_CFLAGS([-bundle], ac_cv_c_dll_macho="yes", ac_cv_c_dll_macho="no")])
 908           if test "$ac_cv_c_dll_macho" = "yes"
 909           then
 910             LIBEXT="dylib"
 911             LDDLL="\$(CC) -bundle -flat_namespace -undefined suppress"
 912             LDSHARED="\$(CC) -dynamiclib"
 913             CFLAGS="$CFLAGS -ffixed-r13 -no-cpp-precomp"
 914           fi
 915         fi
 916       fi
 917     fi
 918
 919     dnl Check for cross compiler to build test programs
 920     AC_SUBST(CROSSTEST,"")
 921     if test "$cross_compiling" = "no"
 922     then
 923       AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32-gcc mingw-gcc,false)
 924       AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32-dlltool mingw-dlltool,false)
 925       AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32-windres mingw-windres,false)
 926       if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
 927     fi
 928     ;;
 929 esac
 930
 931 if test "$LIBEXT" = "a"; then
 932   AC_MSG_ERROR(
 933 [could not find a way to build shared libraries.
 934 It is currently not possible to build Wine without shared library
 935 (.so) support to allow transparent switch between .so and .dll files.
 936 If you are using Linux, you will need a newer binutils.]
 937 )
 938 fi
 939
 940 case $build_os in
 941   cygwin*|mingw32*)
 942     AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$PATH\"") ;;
 943   darwin*|macosx*)
 944     AC_SUBST(LDPATH,"DYLD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$DYLD_LIBRARY_PATH\"") ;;
 945   *)
 946     AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$LD_LIBRARY_PATH\"") ;;
 947 esac
 948
 949 dnl Mingw needs explicit msvcrt for linking libwine
 950 case $host_os in
 951   mingw32*)
 952     AC_SUBST(CRTLIBS,"-lmsvcrt") ;;
 953 esac
 954
 955 case $host_os in
 956   linux*)
 957     AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread")
 958     AC_SUBST(MAIN_BINARY,"wine-glibc")
 959     ;;
 960   *)
 961     AC_SUBST(WINE_BINARIES,"wine-kthread")
 962     AC_SUBST(MAIN_BINARY,"wine-kthread")
 963     ;;
 964 esac
 965
 966 dnl **** Get the soname for libraries that we load dynamically ****
 967
 968 if test "$LIBEXT" = "so"
 969 then
 970   WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
 971   WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
 972   WINE_GET_SONAME(Xi,XOpenDevice,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 973   WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 974   WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
 975   WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
 976   WINE_GET_SONAME(cups,cupsGetDefault)
 977   WINE_GET_SONAME(jack,jack_client_new)
 978   WINE_GET_SONAME(fontconfig,FcInit)
 979   WINE_GET_SONAME(ssl,SSL_library_init)
 980   WINE_GET_SONAME(crypto,BIO_new_socket)
 981   WINE_GET_SONAME(ncurses,waddch)
 982   WINE_GET_SONAME(curses,waddch)
 983 fi
 984
 985
 986 dnl **** Check for functions ****
 987
 988 AC_FUNC_ALLOCA()
 989 AC_CHECK_FUNCS(\
 990         _lwp_create \
 991         _lwp_self \
 992         _pclose \
 993         _popen \
 994         _snprintf \
 995         _spawnvp \
 996         _stricmp \
 997         _strnicmp \
 998         _vsnprintf \
 999         chsize \
1000         clone \
1001         finite \
1002         fpclass \
1003         ftruncate \
1004         ftruncate64 \
1005         getnetbyaddr \
1006         getnetbyname \
1007         getopt_long \
1008         getpagesize \
1009         getprotobyname \
1010         getprotobynumber \
1011         getpwuid \
1012         getservbyport \
1013         gettid \
1014         gettimeofday \
1015         inet_network \
1016         lseek64 \
1017         lstat \
1018         memmove \
1019         mmap \
1020         pclose \
1021         popen \
1022         pread \
1023         pwrite \
1024         readlink \
1025         rfork \
1026         select \
1027         sendmsg \
1028         settimeofday \
1029         sigaltstack \
1030         snprintf \
1031         spawnvp \
1032         statfs \
1033         strcasecmp \
1034         strerror \
1035         strncasecmp \
1036         tcgetattr \
1037         timegm \
1038         usleep \
1039         vfscanf \
1040         vsnprintf \
1041         wait4 \
1042         waitpid \
1043 )
1044
1045 dnl **** Check for header files ****
1046
1047 AC_CHECK_HEADERS(\
1048         arpa/inet.h \
1049         arpa/nameser.h \
1050         cups/cups.h \
1051         direct.h \
1052         elf.h \
1053         float.h \
1054         fontconfig/fontconfig.h \
1055         getopt.h \
1056         ieeefp.h \
1057         io.h \
1058         jack/jack.h \
1059         libio.h \
1060         libutil.h \
1061         link.h \
1062         linux/cdrom.h \
1063         linux/hdreg.h \
1064         linux/input.h \
1065         linux/joystick.h \
1066         linux/major.h \
1067         linux/param.h \
1068         linux/serial.h \
1069         linux/ucdrom.h \
1070         machine/cpu.h \
1071         netdb.h \
1072         netinet/in.h \
1073         netinet/in_systm.h \
1074         netinet/tcp.h \
1075         netinet/tcp_fsm.h \
1076         openssl/ssl.h \
1077         process.h \
1078         pthread.h \
1079         pty.h \
1080         pwd.h \
1081         regex.h \
1082         sched.h \
1083         scsi/sg.h \
1084         scsi/scsi.h \
1085         scsi/scsi_ioctl.h \
1086         socket.h \
1087         stdint.h \
1088         strings.h \
1089         sys/cdio.h \
1090         sys/errno.h \
1091         sys/file.h \
1092         sys/filio.h \
1093         sys/inttypes.h \
1094         sys/ioctl.h \
1095         sys/ipc.h \
1096         sys/link.h \
1097         sys/lwp.h \
1098         sys/mman.h \
1099         sys/modem.h \
1100         sys/msg.h \
1101         sys/param.h \
1102         sys/poll.h \
1103         sys/ptrace.h \
1104         sys/reg.h \
1105         sys/scsiio.h \
1106         sys/shm.h \
1107         sys/signal.h \
1108         sys/socket.h \
1109         sys/sockio.h \
1110         sys/statfs.h \
1111         sys/strtio.h \
1112         sys/syscall.h \
1113         sys/sysctl.h \
1114         sys/time.h \
1115         sys/times.h \
1116         sys/uio.h \
1117         sys/un.h \
1118         sys/v86.h \
1119         sys/v86intr.h \
1120         sys/vfs.h \
1121         sys/vm86.h \
1122         sys/wait.h \
1123         syscall.h \
1124         termios.h \
1125         unistd.h \
1126         utime.h \
1127         valgrind/memcheck.h
1128 )
1129 AC_HEADER_STAT()
1130
1131 dnl **** Checks for headers that depend on other ones ****
1132
1133 AC_CHECK_HEADERS(sys/mount.h sys/user.h,,,
1134     [#include <sys/types.h>
1135      #if HAVE_SYS_PARAM_H
1136      # include <sys/param.h>
1137      #endif])
1138
1139 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h],,,
1140     [#include <sys/types.h>
1141      #if HAVE_SYS_SOCKET_H
1142      # include <sys/socket.h>
1143      #endif])
1144
1145 AC_CHECK_HEADERS([resolv.h],,,
1146     [#include <sys/types.h>
1147      #if HAVE_SYS_SOCKET_H
1148      # include <sys/socket.h>
1149      #endif
1150      #if HAVE_NETINET_IN_H
1151      # include <netinet/in.h>
1152      #endif
1153      #if HAVE_ARPA_NAMESER_H
1154      # include <arpa/nameser.h>
1155      #endif])
1156
1157 AC_CHECK_HEADERS(netinet/ip.h,,,
1158     [#include <sys/types.h>
1159      #if HAVE_SYS_SOCKET_H
1160      # include <sys/socket.h>
1161      #endif
1162      #if HAVE_NETINET_IN_SYSTM_H
1163      # include <netinet/in_systm.h>
1164      #endif])
1165
1166 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
1167
1168 dnl **** Check for IPX headers (currently Linux only) ****
1169
1170 AC_CACHE_CHECK([for GNU style IPX support], ac_cv_c_ipx_gnu,
1171  AC_TRY_COMPILE(
1172    [#include <sys/types.h>
1173     #ifdef HAVE_SYS_SOCKET_H
1174     # include <sys/socket.h>
1175     #endif
1176     #include <netipx/ipx.h>],
1177    [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1178    [ac_cv_c_ipx_gnu="yes"],
1179    [ac_cv_c_ipx_gnu="no"])
1180  )
1181 if test "$ac_cv_c_ipx_gnu" = "yes"
1182 then
1183     AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
1184 fi
1185
1186 if test "$ac_cv_c_ipx_gnu" = "no"
1187 then
1188  AC_CACHE_CHECK([for linux style IPX support], ac_cv_c_ipx_linux,
1189   AC_TRY_COMPILE(
1190     [#include <sys/types.h>
1191      #ifdef HAVE_SYS_SOCKET_H
1192      # include <sys/socket.h>
1193      #endif
1194      #include <asm/types.h>
1195      #include <linux/ipx.h>],
1196     [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1197     [ac_cv_c_ipx_linux="yes"],
1198     [ac_cv_c_ipx_linux="no"])
1199   )
1200   if test "$ac_cv_c_ipx_linux" = "yes"
1201   then
1202       AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
1203   fi
1204 fi
1205
1206 dnl **** Check for types ****
1207
1208 AC_C_CONST
1209 AC_C_INLINE
1210 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t])
1211 AC_CHECK_SIZEOF(long long,0)
1212
1213 AC_CACHE_CHECK([whether linux/input.h is for real],
1214         wine_cv_linux_input_h,
1215         AC_TRY_COMPILE([
1216             #include <linux/input.h>
1217         ] , [
1218             int foo = EVIOCGBIT(EV_ABS,42);
1219             int bar = BTN_PINKIE;
1220             int fortytwo = 42;
1221         ],
1222         wine_cv_linux_input_h=yes,
1223         wine_cv_linux_input_h=no,
1224         no
1225         )
1226     )
1227     if test "$wine_cv_linux_input_h" = "yes"
1228     then
1229         AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
1230                   [Define if we have linux/input.h AND it contains the INPUT event API])
1231     fi
1232
1233
1234 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1235         wine_cv_linux_gethostbyname_r_6,
1236         AC_TRY_LINK([
1237 #include <netdb.h>
1238         ], [
1239     char *name=NULL;
1240     struct hostent he;
1241     struct hostent *result;
1242     char *buf=NULL;
1243     int bufsize=0;
1244     int res,errnr;
1245     char *addr=NULL;
1246     int addrlen=0;
1247     int addrtype=0;
1248     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1249     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1250     ],
1251         wine_cv_linux_gethostbyname_r_6=yes,
1252         wine_cv_linux_gethostbyname_r_6=no
1253         )
1254    )
1255    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1256    then
1257       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1258                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1259    fi
1260
1261 if test "$ac_cv_header_linux_joystick_h" = "yes"
1262 then
1263    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1264         wine_cv_linux_joystick_22_api,
1265         AC_TRY_COMPILE([
1266         #include <sys/ioctl.h>
1267         #include <linux/joystick.h>
1268
1269         struct js_event blub;
1270         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1271         #error "no 2.2 header"
1272         #endif
1273         ],/*empty*/,
1274         wine_cv_linux_joystick_22_api=yes,
1275         wine_cv_linux_joystick_22_api=no,
1276         wine_cv_linux_joystick_22_api=no
1277         )
1278    )
1279    if test "$wine_cv_linux_joystick_22_api" = "yes"
1280    then
1281       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1282                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1283    fi
1284 fi
1285
1286 dnl **** statfs checks ****
1287
1288 if test "$ac_cv_header_sys_vfs_h" = "yes"
1289 then
1290     AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
1291                     wine_cv_sys_vfs_has_statfs,
1292         AC_TRY_COMPILE([
1293         #include <sys/types.h>
1294         #ifdef HAVE_SYS_PARAM_H
1295         # include <sys/param.h>
1296         #endif
1297         #include <sys/vfs.h>
1298         ],[
1299                 struct statfs stfs;
1300
1301                 memset(&stfs,0,sizeof(stfs));
1302         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1303         )
1304     )
1305     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1306     then
1307       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1308                 [Define if the struct statfs is defined by <sys/vfs.h>])
1309     fi
1310 fi
1311
1312 if test "$ac_cv_header_sys_statfs_h" = "yes"
1313 then
1314     AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1315                     wine_cv_sys_statfs_has_statfs,
1316         AC_TRY_COMPILE([
1317         #include <sys/types.h>
1318         #ifdef HAVE_SYS_PARAM_H
1319         # include <sys/param.h>
1320         #endif
1321         #include <sys/statfs.h>
1322         ],[
1323                 struct statfs stfs;
1324         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1325         )
1326     )
1327     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1328     then
1329       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1330                 [Define if the struct statfs is defined by <sys/statfs.h>])
1331     fi
1332 fi
1333
1334 if test "$ac_cv_header_sys_mount_h" = "yes"
1335 then
1336     AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1337                     wine_cv_sys_mount_has_statfs,
1338         AC_TRY_COMPILE([
1339         #include <sys/types.h>
1340         #ifdef HAVE_SYS_PARAM_H
1341         # include <sys/param.h>
1342         #endif
1343         #include <sys/mount.h>
1344         ],[
1345                 struct statfs stfs;
1346         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1347         )
1348     )
1349     if test "$wine_cv_sys_mount_has_statfs" = "yes"
1350     then
1351       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1352                 [Define if the struct statfs is defined by <sys/mount.h>])
1353     fi
1354 fi
1355
1356 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1357
1358 dnl Check for statfs members
1359 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail],,,
1360 [#include <sys/types.h>
1361 #ifdef HAVE_SYS_PARAM_H
1362 # include <sys/param.h>
1363 #endif
1364 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1365 # include <sys/mount.h>
1366 #else
1367 # ifdef STATFS_DEFINED_BY_SYS_VFS
1368 #  include <sys/vfs.h>
1369 # else
1370 #  ifdef STATFS_DEFINED_BY_SYS_STATFS
1371 #   include <sys/statfs.h>
1372 #  endif
1373 # endif
1374 #endif])
1375
1376 dnl Check for socket structure members
1377 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1378 [#include <sys/types.h>
1379 #ifdef HAVE_SYS_SOCKET_H
1380 # include <sys/socket.h>
1381 #endif
1382 #ifdef HAVE_SYS_UN_H
1383 # include <sys/un.h>
1384 #endif])
1385
1386 dnl Check for siginfo_t members
1387 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1388
1389 dnl Check for struct option
1390 AC_CHECK_MEMBERS([struct option.name],,,
1391 [#ifdef HAVE_GETOPT_H
1392 #include <getopt.h>
1393 #endif])
1394
1395 dnl Check for stat.st_blocks
1396 AC_CHECK_MEMBERS([struct stat.st_blocks])
1397
1398 dnl *** check for the need to define platform-specific symbols
1399
1400 case $host_cpu in
1401   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1402   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
1403   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
1404   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
1405 esac
1406
1407 case $host_vendor in
1408   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1409 esac
1410
1411 dnl **** Generate output files ****
1412
1413 AH_TOP([#define __WINE_CONFIG_H])
1414
1415 WINE_CONFIG_EXTRA_DIR(controls)
1416 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/d3ddevice)
1417 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dclipper)
1418 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/ddraw)
1419 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/direct3d)
1420 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dpalette)
1421 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dsurface)
1422 WINE_CONFIG_EXTRA_DIR(dlls/dinput/joystick)
1423 WINE_CONFIG_EXTRA_DIR(dlls/dinput/keyboard)
1424 WINE_CONFIG_EXTRA_DIR(dlls/dinput/mouse)
1425 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1426 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1427 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1428 WINE_CONFIG_EXTRA_DIR(dlls/user/dde)
1429 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1430 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1431 WINE_CONFIG_EXTRA_DIR(files)
1432 WINE_CONFIG_EXTRA_DIR(graphics)
1433 WINE_CONFIG_EXTRA_DIR(include/wine)
1434 WINE_CONFIG_EXTRA_DIR(misc)
1435 WINE_CONFIG_EXTRA_DIR(objects)
1436 WINE_CONFIG_EXTRA_DIR(programs/regedit/tests)
1437 WINE_CONFIG_EXTRA_DIR(windows)
1438
1439 MAKE_RULES=Make.rules
1440 AC_SUBST_FILE(MAKE_RULES)
1441
1442 MAKE_DLL_RULES=dlls/Makedll.rules
1443 AC_SUBST_FILE(MAKE_DLL_RULES)
1444
1445 MAKE_TEST_RULES=dlls/Maketest.rules
1446 AC_SUBST_FILE(MAKE_TEST_RULES)
1447
1448 MAKE_LIB_RULES=libs/Makelib.rules
1449 AC_SUBST_FILE(MAKE_LIB_RULES)
1450
1451 MAKE_PROG_RULES=programs/Makeprog.rules
1452 AC_SUBST_FILE(MAKE_PROG_RULES)
1453
1454 AC_CONFIG_FILES([
1455 Make.rules
1456 dlls/Makedll.rules
1457 dlls/Maketest.rules
1458 libs/Makelib.rules
1459 programs/Makeprog.rules
1460 Makefile
1461 dlls/Makefile
1462 dlls/advapi32/Makefile
1463 dlls/advapi32/tests/Makefile
1464 dlls/avicap32/Makefile
1465 dlls/avifil32/Makefile
1466 dlls/cabinet/Makefile
1467 dlls/capi2032/Makefile
1468 dlls/cfgmgr32/Makefile
1469 dlls/comcat/Makefile
1470 dlls/comctl32/Makefile
1471 dlls/comctl32/tests/Makefile
1472 dlls/commdlg/Makefile
1473 dlls/crtdll/Makefile
1474 dlls/crypt32/Makefile
1475 dlls/ctl3d/Makefile
1476 dlls/wined3d/Makefile
1477 dlls/d3d8/Makefile
1478 dlls/d3d9/Makefile
1479 dlls/d3dim/Makefile
1480 dlls/d3dx8/Makefile
1481 dlls/dciman32/Makefile
1482 dlls/ddraw/Makefile
1483 dlls/ddraw/tests/Makefile
1484 dlls/devenum/Makefile
1485 dlls/dinput/Makefile
1486 dlls/dinput8/Makefile
1487 dlls/dmband/Makefile
1488 dlls/dmcompos/Makefile
1489 dlls/dmime/Makefile
1490 dlls/dmloader/Makefile
1491 dlls/dmscript/Makefile
1492 dlls/dmstyle/Makefile
1493 dlls/dmsynth/Makefile
1494 dlls/dmusic/Makefile
1495 dlls/dmusic32/Makefile
1496 dlls/dplay/Makefile
1497 dlls/dplayx/Makefile
1498 dlls/dpnhpast/Makefile
1499 dlls/dsound/Makefile
1500 dlls/dsound/tests/Makefile
1501 dlls/dswave/Makefile
1502 dlls/gdi/Makefile
1503 dlls/gdi/tests/Makefile
1504 dlls/glu32/Makefile
1505 dlls/glut32/Makefile
1506 dlls/iccvid/Makefile
1507 dlls/icmp/Makefile
1508 dlls/imagehlp/Makefile
1509 dlls/imm32/Makefile
1510 dlls/iphlpapi/Makefile
1511 dlls/iphlpapi/tests/Makefile
1512 dlls/kernel/Makefile
1513 dlls/kernel/tests/Makefile
1514 dlls/lzexpand/Makefile
1515 dlls/mapi32/Makefile
1516 dlls/mpr/Makefile
1517 dlls/msacm/Makefile
1518 dlls/msacm/imaadp32/Makefile
1519 dlls/msacm/msadp32/Makefile
1520 dlls/msacm/msg711/Makefile
1521 dlls/msacm/winemp3/Makefile
1522 dlls/msdmo/Makefile
1523 dlls/mshtml/Makefile
1524 dlls/msi/Makefile
1525 dlls/msimg32/Makefile
1526 dlls/msisys/Makefile
1527 dlls/msnet32/Makefile
1528 dlls/msvcrt/Makefile
1529 dlls/msvcrt/tests/Makefile
1530 dlls/msvcrt20/Makefile
1531 dlls/msvcrt40/Makefile
1532 dlls/msvcrtd/Makefile
1533 dlls/msvideo/Makefile
1534 dlls/msvideo/msrle32/Makefile
1535 dlls/mswsock/Makefile
1536 dlls/netapi32/Makefile
1537 dlls/netapi32/tests/Makefile
1538 dlls/newdev/Makefile
1539 dlls/ntdll/Makefile
1540 dlls/ntdll/tests/Makefile
1541 dlls/odbc32/Makefile
1542 dlls/ole32/Makefile
1543 dlls/oleacc/Makefile
1544 dlls/oleaut32/Makefile
1545 dlls/oleaut32/tests/Makefile
1546 dlls/olecli/Makefile
1547 dlls/oledlg/Makefile
1548 dlls/olepro32/Makefile
1549 dlls/olesvr/Makefile
1550 dlls/opengl32/Makefile
1551 dlls/psapi/Makefile
1552 dlls/qcap/Makefile
1553 dlls/quartz/Makefile
1554 dlls/rasapi32/Makefile
1555 dlls/richedit/Makefile
1556 dlls/rpcrt4/Makefile
1557 dlls/rpcrt4/tests/Makefile
1558 dlls/serialui/Makefile
1559 dlls/setupapi/Makefile
1560 dlls/shdocvw/Makefile
1561 dlls/shell32/Makefile
1562 dlls/shell32/tests/Makefile
1563 dlls/shfolder/Makefile
1564 dlls/shlwapi/Makefile
1565 dlls/shlwapi/tests/Makefile
1566 dlls/snmpapi/Makefile
1567 dlls/sti/Makefile
1568 dlls/tapi32/Makefile
1569 dlls/ttydrv/Makefile
1570 dlls/twain/Makefile
1571 dlls/unicows/Makefile
1572 dlls/url/Makefile
1573 dlls/urlmon/Makefile
1574 dlls/urlmon/tests/Makefile
1575 dlls/user/Makefile
1576 dlls/user/tests/Makefile
1577 dlls/uxtheme/Makefile
1578 dlls/version/Makefile
1579 dlls/win32s/Makefile
1580 dlls/winaspi/Makefile
1581 dlls/winedos/Makefile
1582 dlls/wineps/Makefile
1583 dlls/wininet/Makefile
1584 dlls/wininet/tests/Makefile
1585 dlls/winmm/Makefile
1586 dlls/winmm/joystick/Makefile
1587 dlls/winmm/mcianim/Makefile
1588 dlls/winmm/mciavi/Makefile
1589 dlls/winmm/mcicda/Makefile
1590 dlls/winmm/mciseq/Makefile
1591 dlls/winmm/mciwave/Makefile
1592 dlls/winmm/midimap/Makefile
1593 dlls/winmm/tests/Makefile
1594 dlls/winmm/wavemap/Makefile
1595 dlls/winmm/winealsa/Makefile
1596 dlls/winmm/winearts/Makefile
1597 dlls/winmm/wineaudioio/Makefile
1598 dlls/winmm/winenas/Makefile
1599 dlls/winmm/winejack/Makefile
1600 dlls/winmm/wineoss/Makefile
1601 dlls/winnls/Makefile
1602 dlls/winsock/Makefile
1603 dlls/winsock/tests/Makefile
1604 dlls/winspool/Makefile
1605 dlls/winspool/tests/Makefile
1606 dlls/wintab32/Makefile
1607 dlls/wintrust/Makefile
1608 dlls/wow32/Makefile
1609 dlls/wsock32/Makefile
1610 dlls/x11drv/Makefile
1611 documentation/Makefile
1612 include/Makefile
1613 libs/Makefile
1614 libs/port/Makefile
1615 libs/unicode/Makefile
1616 libs/uuid/Makefile
1617 libs/wine/Makefile
1618 libs/wpp/Makefile
1619 loader/Makefile
1620 programs/Makefile
1621 programs/avitools/Makefile
1622 programs/clock/Makefile
1623 programs/cmdlgtst/Makefile
1624 programs/control/Makefile
1625 programs/expand/Makefile
1626 programs/notepad/Makefile
1627 programs/progman/Makefile
1628 programs/regedit/Makefile
1629 programs/regsvr32/Makefile
1630 programs/rpcss/Makefile
1631 programs/rundll32/Makefile
1632 programs/start/Makefile
1633 programs/uninstaller/Makefile
1634 programs/view/Makefile
1635 programs/wcmd/Makefile
1636 programs/wineboot/Makefile
1637 programs/winebrowser/Makefile
1638 programs/winecfg/Makefile
1639 programs/wineconsole/Makefile
1640 programs/winedbg/Makefile
1641 programs/winefile/Makefile
1642 programs/winemenubuilder/Makefile
1643 programs/winemine/Makefile
1644 programs/winepath/Makefile
1645 programs/winetest/Makefile
1646 programs/winevdm/Makefile
1647 programs/winhelp/Makefile
1648 programs/winver/Makefile
1649 server/Makefile
1650 tools/Makefile
1651 tools/widl/Makefile
1652 tools/winapi/Makefile
1653 tools/winebuild/Makefile
1654 tools/winedump/Makefile
1655 tools/winegcc/Makefile
1656 tools/wmc/Makefile
1657 tools/wrc/Makefile])
1658
1659 AC_OUTPUT
1660
1661 if test "$have_x" = "no"
1662 then
1663   echo
1664   echo "*** Warning: X development files not found. Wine will be built without"
1665   echo "*** X support, which currently does not work, and would probably not be"
1666   echo "*** what you want anyway. You will need to install devel packages of"
1667   echo "*** Xlib/Xfree86 at the very least."
1668 fi
1669
1670 if test "$wine_cv_opengl_version_OK" = "no"
1671 then
1672   echo
1673   echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1674   echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1675 fi
1676
1677 if test "$wine_cv_msg_freetype" = "yes"
1678 then
1679   echo
1680   echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1681   echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1682   echo "*** freetype-devel package (or its equivalent on your distribution) to"
1683   echo "*** enable Wine to use TrueType fonts."
1684 fi
1685
1686 echo
1687 echo "Configure finished.  Do 'make depend && make' to compile Wine."
1688 echo
1689
1690 dnl Local Variables:
1691 dnl comment-start: "dnl "
1692 dnl comment-end: ""
1693 dnl comment-start-skip: "\\bdnl\\b\\s *"
1694 dnl compile-command: "autoconf"
1695 dnl End: