git.oblomov.eu Git - wine/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Author: Michael Patra   <micky@marie.physik.tu-berlin.de>
   3 dnl                         <patra@itp1.physik.tu-berlin.de>
   4 AC_REVISION([configure.in 1.00])
   5 AC_INIT(controls/edit.c)
   6 AC_CONFIG_HEADER(include/config.h)
   7 AC_CONFIG_AUX_DIR(tools)
   8
   9 dnl **** Command-line arguments ****
  10
  11 dnl Default values
  12 LIBEXT=so       # library type .so or .a
  13 TRACE_MSGS=yes  # the TRACE() macro
  14 DEBUG_MSGS=yes  # the TRACE(), WARN(), and FIXME() macros.
  15 CURSES=yes
  16 OPENGL=normal
  17
  18 AC_ARG_ENABLE(debug,
  19 [  --disable-debug         compile out all debugging messages],
  20 [if test "$enableval" = "no"; then DEBUG_MSGS="no"; fi])
  21
  22 AC_ARG_ENABLE(opengl,
  23 [  --enable-opengl         force usage of OpenGL even if the latter is thread-safe via pthread],
  24 [if test "$enableval" = "no"; then OPENGL="no"; elif test "$enableval" = "yes"; then OPENGL="yes"; fi])
  25
  26 AC_ARG_ENABLE(trace,
  27 [  --disable-trace         compile out TRACE messages],
  28 [if test "$enableval" = "no"; then TRACE_MSGS="no"; fi])
  29
  30 AC_ARG_WITH(curses,
  31 [  --without-curses        do not use curses],
  32 [if test "$withval" = "no"; then CURSES="no"; fi])
  33
  34 AC_ARG_WITH(reentrant-x,
  35 [  --without-reentrant-x   compile for use with non-reentrant X libraries])
  36
  37 AC_SUBST(OPTIONS)
  38
  39 if test "$DEBUG_MSGS" = "no"
  40 then
  41     AC_DEFINE(NO_DEBUG_MSGS)
  42     AC_DEFINE(NO_TRACE_MSGS)
  43 else
  44     if test "$TRACE_MSGS" = "no"
  45     then
  46         AC_DEFINE(NO_TRACE_MSGS)
  47     fi
  48 fi
  49
  50 dnl **** Check for some programs ****
  51
  52 AC_PROG_MAKE_SET
  53 AC_PROG_CC
  54 AC_PROG_CPP
  55 AC_PATH_XTRA
  56 AC_PROG_YACC
  57 AC_PROG_LEX
  58 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
  59 if test "$XLEX" = "none"
  60 then
  61         echo "*** Error: No suitable lex found. ***"
  62         echo "    Please install the 'flex' package."
  63         exit 1
  64 fi
  65 AC_DECL_YYTEXT
  66 AC_PROG_RANLIB
  67 AC_PROG_INSTALL
  68 AC_PROG_LN_S
  69 AC_CHECK_PROG(C2MAN,c2man,c2man,\$(TOPSRCDIR)/tools/c2man.pl)
  70 AC_PATH_PROG(LDCONFIG, ldconfig, true, /sbin:/usr/sbin:$PATH)
  71 AC_CYGWIN
  72 AC_CHECK_PROG(DLLWRAP,dllwrap,dllwrap,false)
  73
  74 dnl Check for lint
  75 AC_CHECK_PROGS(LINT, lclint lint)
  76 if test "$LINT" = "lint"
  77 then
  78   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
  79   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
  80 fi
  81 AC_SUBST(LINT)
  82 AC_SUBST(LINTFLAGS)
  83
  84 if test "$CYGWIN" = "yes"
  85 then
  86     LDCOMBINE="ld -r --enable-stdcall-fixup"
  87 else
  88     LDCOMBINE="ld -r"
  89 fi
  90 AC_SUBST(LDCOMBINE)
  91
  92 dnl **** Check for some libraries ****
  93
  94 dnl Check for -lm for BeOS
  95 AC_CHECK_LIB(m,sqrt)
  96 dnl Check for -li386 for NetBSD and OpenBSD
  97 AC_CHECK_LIB(i386,i386_set_ldt)
  98 dnl Check for -lossaudio for NetBSD
  99 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 100 dnl Check for -lw for Solaris
 101 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
 102 dnl Check for -lnsl for Solaris
 103 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
 104 dnl Check for -lsocket for Solaris
 105 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
 106 dnl Check for -lxpg4 for FreeBSD
 107 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
 108 dnl Check for -lmmap for OS/2
 109 AC_CHECK_LIB(mmap,mmap)
 110 dnl Check for openpty
 111 AC_CHECK_FUNCS(openpty,,
 112         AC_CHECK_LIB(util,openpty,
 113                 AC_DEFINE(HAVE_OPENPTY)
 114                 LIBS="$LIBS -lutil"
 115         ))
 116
 117 AC_CHECK_HEADERS(dlfcn.h,
 118         AC_CHECK_FUNCS(dlopen,
 119                 AC_DEFINE(HAVE_DL_API),
 120                 AC_CHECK_LIB(dl,dlopen,
 121                         AC_DEFINE(HAVE_DL_API)
 122                         LIBS="$LIBS -ldl",
 123                         LIBEXT="a"
 124                 )
 125         ),
 126         LIBEXT="a"
 127 )
 128 AC_SUBST(XLIB)
 129 AC_SUBST(X_DLLS)
 130 X_DLLS=""
 131 AC_SUBST(XFILES)
 132 XFILES=""
 133 AC_SUBST(OPENGLFILES)
 134 OPENGLFILES=""
 135 AC_SUBST(OPENGL32_DLL)
 136 OPENGL32_DLL=""
 137 if test "$have_x" = "yes"
 138 then
 139     XLIB="-lXext -lX11"
 140     ac_save_CPPFLAGS="$CPPFLAGS"
 141     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 142
 143     dnl *** Check for -lXpm
 144     AC_CHECK_HEADERS(X11/xpm.h,
 145       [ dnl *** If X11/xpm.h exists...
 146         AC_CHECK_LIB(Xpm, XpmCreatePixmapFromData,
 147           [ AC_DEFINE(HAVE_LIBXXPM) X_PRE_LIBS="$X_PRE_LIBS -lXpm"],,
 148           $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 149         )
 150       ],
 151       [ dnl *** If X11/xpm.h does not exist...
 152         dnl NOTE: autoconf does not allow commas inside the third
 153         dnl       parameter to AC_CHECK_HEADERS, due to some quoting
 154         dnl       magic it does.
 155         echo "Redhat            :       xpm xpm-devel"
 156         echo "Caldera OpenLinux :       xpm xpm-devel xpm-devel-static"
 157         echo "SuSE              :       xpm"
 158         echo "Debian/Corel Linux:       xpm4g xpm4g-dev"
 159         echo
 160         echo "Or get the sources from ftp.x.org and all its mirror sites from "
 161         echo "the directory /contrib/libraries."
 162         echo
 163         exit 1
 164       ]
 165     )
 166
 167     dnl *** All three of the following tests require X11/Xlib.h
 168     AC_CHECK_HEADERS(X11/Xlib.h,
 169       [
 170         dnl *** Check for X keyboard extension
 171         AC_CHECK_HEADERS(X11/XKBlib.h,
 172             [ dnl *** If X11/XKBlib.h exists...
 173               AC_CHECK_LIB(X11, XkbQueryExtension,
 174               AC_DEFINE(HAVE_XKB),,
 175               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 176             ],
 177             AC_MSG_WARN([XKB extension not found!!])
 178         )
 179
 180         dnl *** Check for X Shm extension
 181         AC_CHECK_HEADERS(X11/extensions/XShm.h,
 182             [ dnl *** If X11/extensions/XShm.h exists...
 183               AC_CHECK_LIB(Xext, XShmQueryExtension,
 184               AC_DEFINE(HAVE_LIBXXSHM),,
 185               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 186             ],
 187             AC_MSG_WARN([Xshm extension not found!!])
 188         )
 189
 190         dnl *** Check for X shape extension
 191         AC_CHECK_HEADERS(X11/extensions/shape.h,
 192             [ dnl *** If X11/extensions/shape.h exists...
 193               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 194               AC_DEFINE(HAVE_LIBXSHAPE),,
 195               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 196             ],
 197             AC_MSG_WARN([XShape extension not found!!])
 198         )
 199
 200         dnl *** Check for XFree86 DGA / DGA 2.0 extension
 201         AC_CHECK_HEADERS(X11/extensions/xf86dga.h,
 202             [ dnl *** If X11/extensions/xf86dga.h exists, check
 203               dnl *** for XDGAQueryExtension()...
 204               AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
 205                 [ dnl *** If found...
 206                   AC_DEFINE(HAVE_LIBXXF86DGA2)
 207                   AC_DEFINE(HAVE_LIBXXF86DGA)
 208                   X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 209                ],
 210                 [ dnl *** If not found, look for XF86DGAQueryExtension()
 211                   dnl *** instead (DGA 2.0 not found)...
 212                   AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
 213                     [ AC_DEFINE(HAVE_LIBXXF86DGA)
 214                       X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 215                     ],,
 216                     $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 217                   )
 218                 ],
 219                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 220               )
 221             ],
 222             AC_MSG_WARN([DGA extension not found!!])
 223         )
 224
 225         dnl *** Check for XFree86 VMODE extension
 226         AC_CHECK_HEADERS(X11/extensions/xf86vmode.h,
 227             [ dnl *** If X11/extensions/xf86vmode.h exists...
 228                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 229                   [ AC_DEFINE(HAVE_LIBXXF86VM)
 230                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 231                   ],,
 232                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 233                 )
 234             ],
 235             AC_MSG_WARN([XFree86 VMODE extension not found!!])
 236         )
 237
 238         dnl *** Check for XVideo extension supporting XvImages
 239         AC_CHECK_HEADERS(X11/extensions/Xvlib.h,
 240             [ dnl *** If X11/extensions/Xvlib.h exists...
 241                 AC_CHECK_LIB(Xv, XvShmCreateImage,
 242                   [ AC_DEFINE(HAVE_XVIDEO)
 243                      X_PRE_LIBS="$X_PRE_LIBS -lXv"
 244                   ],,
 245                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 246                 )
 247             ],
 248             AC_MSG_WARN([XVideo extension not found !!])
 249         )
 250
 251       ]
 252     ) dnl *** End of X11/Xlib.h check
 253
 254     dnl Check for the presence of OpenGL
 255     if test $OPENGL = "yes" -o $OPENGL = "normal"
 256     then
 257         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h)
 258         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 259         then
 260             dnl Check for some problems due to old Mesa versions
 261             AC_CACHE_CHECK("for up-to-date OpenGL version", wine_cv_opengl_version_OK,
 262               AC_TRY_COMPILE(
 263                 [#include <GL/gl.h>],
 264                 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 265                 [wine_cv_opengl_version_OK="yes"],
 266                 [wine_cv_opengl_version_OK="no"]
 267               )
 268             )
 269
 270             dnl Check for the thread-safety of the OpenGL library
 271             AC_CACHE_CHECK("for thread-safe OpenGL version",
 272                            wine_cv_opengl_version_threadsafe,
 273               [saved_libs=$LIBS
 274                LIBS="$X_LIBS -lGL"
 275                AC_TRY_LINK([],[pthread_getspecific();],
 276                               [wine_cv_opengl_version_threadsafe="yes"],
 277                               [wine_cv_opengl_version_threadsafe="no"])
 278                LIBS=$saved_libs]
 279             )
 280
 281             if test "$wine_cv_opengl_version_OK" = "yes" -a \( "$wine_cv_opengl_version_threadsafe" = "no" -o $OPENGL = "yes" \)
 282             then
 283                 dnl Check for the presence of the library
 284                 AC_CHECK_LIB(GL,glXCreateContext,
 285                              X_PRE_LIBS="$X_PRE_LIBS -lGL"
 286                              ,,
 287                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 288
 289                 if test $ac_cv_lib_GL_glXCreateContext = "yes"
 290                 then
 291
 292                         OPENGLFILES='$(OPENGLFILES)'
 293                         AC_DEFINE(HAVE_OPENGL)
 294
 295                         AC_CHECK_LIB(GL,glXGetProcAddressARB,AC_DEFINE(HAVE_GLX_GETPROCADDRESS),,$X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 296
 297                         if test $ac_cv_lib_GL_glXGetProcAddressARB = "yes"
 298                         then
 299                                AC_CACHE_CHECK("for OpenGL extension functions prototypes", wine_cv_extension_prototypes,
 300                                   AC_TRY_COMPILE([#include <GL/gl.h>
 301                                                   #ifdef HAVE_GL_GLEXT_H
 302                                                   # include <GL/glext.h>
 303                                                   #endif
 304                                                   ],
 305                                                  [PFNGLCOLORTABLEEXTPROC test_proc;],
 306                                                  [wine_cv_extension_prototypes="yes"],
 307                                                  [wine_cv_extension_prototypes="no"]
 308                                   )
 309                                 )
 310                                 if test $wine_cv_extension_prototypes = "yes"
 311                                 then
 312                                         AC_DEFINE(HAVE_GLEXT_PROTOTYPES)
 313                                 fi
 314
 315                                 OPENGL32_DLL=opengl32
 316                         fi
 317
 318                         AC_CHECK_HEADERS(GL/osmesa.h,
 319                             [ dnl *** If GL/osmesa.h exists...
 320                                 AC_CHECK_LIB(GL, OSMesaCreateContext,
 321                                   AC_DEFINE(HAVE_OSMESA),
 322                                   AC_CHECK_LIB(OSMesa, OSMesaCreateContext,
 323                                   [ AC_DEFINE(HAVE_OSMESA)
 324                                     X_PRE_LIBS="$X_PRE_LIBS -lOSMesa"
 325                                   ],,-lGL $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS),
 326                                   $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
 327                                 )
 328                             ]
 329                         )
 330                 fi
 331              fi
 332          fi
 333     fi
 334
 335     CPPFLAGS="$ac_save_CPPFLAGS"
 336     X_DLLS='$(X_DLLS)'
 337     XFILES='$(XFILES)'
 338 else
 339     XLIB=""
 340     X_CFLAGS=""
 341     X_LIBS=""
 342 fi
 343
 344 dnl **** Check which curses lib to use ***
 345 if test "$CURSES" = "yes"
 346 then
 347     AC_CHECK_HEADERS(ncurses.h)
 348     if test "$ac_cv_header_ncurses_h" = "yes"
 349     then
 350         AC_CHECK_LIB(ncurses,waddch)
 351     fi
 352     if test "$ac_cv_lib_ncurses_waddch" = "yes"
 353     then
 354         AC_CHECK_LIB(ncurses,resizeterm,AC_DEFINE(HAVE_RESIZETERM))
 355         AC_CHECK_LIB(ncurses,getbkgd,AC_DEFINE(HAVE_GETBKGD))
 356     else
 357         AC_CHECK_HEADERS(curses.h)
 358         if test "$ac_cv_header_curses_h" = "yes"
 359         then
 360             AC_CHECK_LIB(curses,waddch)
 361             if test "$ac_cv_lib_curses_waddch" = "yes"
 362             then
 363                 AC_CHECK_LIB(curses,resizeterm,AC_DEFINE(HAVE_RESIZETERM))
 364                 AC_CHECK_LIB(curses,getbkgd,AC_DEFINE(HAVE_GETBKGD))
 365             fi
 366         fi
 367     fi
 368 fi
 369
 370 CUPSLIBS=""
 371 dnl **** Check for CUPS ****
 372 wine_cv_warn_cups_h=no
 373 AC_CHECK_LIB(cups,cupsGetPPD,
 374         AC_CHECK_HEADER(cups/cups.h,
 375             AC_DEFINE(HAVE_CUPS)
 376             CUPSLIBS="-lcups",
 377             wine_cv_warn_cups_h=yes)
 378 )
 379 AC_SUBST(CUPSLIBS)
 380
 381 dnl **** Check for IPX (currently Linux only) ****
 382 AC_CACHE_CHECK("for GNU style IPX support", ac_cv_c_ipx_gnu,
 383  AC_TRY_COMPILE(
 384    [#include <sys/socket.h>
 385     #include <netipx/ipx.h>],
 386    [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 387    [ac_cv_c_ipx_gnu="yes"],
 388    [ac_cv_c_ipx_gnu="no"])
 389  )
 390 if test "$ac_cv_c_ipx_gnu" = "yes"
 391 then
 392     AC_DEFINE(HAVE_IPX_GNU)
 393 fi
 394
 395 if test "$ac_cv_c_ipx_gnu" = "no"
 396 then
 397  AC_CACHE_CHECK("for linux style IPX support", ac_cv_c_ipx_linux,
 398   AC_TRY_COMPILE(
 399     [#include <sys/socket.h>
 400      #include <asm/types.h>
 401      #include <linux/ipx.h>],
 402     [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 403     [ac_cv_c_ipx_linux="yes"],
 404     [ac_cv_c_ipx_linux="no"])
 405   )
 406   if test "$ac_cv_c_ipx_linux" = "yes"
 407   then
 408       AC_DEFINE(HAVE_IPX_LINUX)
 409   fi
 410 fi
 411
 412 dnl **** Check for Open Sound System ****
 413 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
 414
 415 AC_CACHE_CHECK("for Open Sound System",
 416         ac_cv_c_opensoundsystem,
 417         AC_TRY_COMPILE([
 418         #if defined(HAVE_SYS_SOUNDCARD_H)
 419                 #include <sys/soundcard.h>
 420         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 421                 #include <machine/soundcard.h>
 422         #elif defined(HAVE_SOUNDCARD_H)
 423                 #include <soundcard.h>
 424         #endif
 425         ],[
 426
 427 /* check for one of the Open Sound System specific SNDCTL_ defines */
 428 #if !defined(SNDCTL_DSP_STEREO)
 429 #error No open sound system
 430 #endif
 431 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
 432
 433 if test "$ac_cv_c_opensoundsystem" = "yes"
 434 then
 435     AC_DEFINE(HAVE_OSS)
 436 fi
 437
 438 AC_CACHE_CHECK("for Open Sound System/MIDI interface",
 439         ac_cv_c_opensoundsystem_midi,
 440         AC_TRY_COMPILE([
 441         #if defined(HAVE_SYS_SOUNDCARD_H)
 442                 #include <sys/soundcard.h>
 443         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 444                 #include <machine/soundcard.h>
 445         #elif defined(HAVE_SOUNDCARD_H)
 446                 #include <soundcard.h>
 447         #endif
 448         ],[
 449
 450 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
 451 #if !defined(SNDCTL_SEQ_SYNC)
 452 #error No open sound system MIDI interface
 453 #endif
 454 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
 455
 456 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
 457 then
 458     AC_DEFINE(HAVE_OSS_MIDI)
 459 fi
 460
 461 dnl **** If ln -s doesn't work, use cp instead ****
 462 if test "$ac_cv_prog_LN_S" = "ln -s"; then : ; else LN_S=cp ; fi
 463
 464 dnl **** Check for gcc strength-reduce bug ****
 465
 466 if test "x${GCC}" = "xyes"
 467 then
 468   CFLAGS="$CFLAGS -Wall"
 469   AC_CACHE_CHECK( "for gcc strength-reduce bug", ac_cv_c_gcc_strength_bug,
 470                   AC_TRY_RUN([
 471 int     L[[4]] = {0,1,2,3};
 472 int main(void) {
 473   static int Array[[3]];
 474   unsigned int B = 3;
 475   int i;
 476   for(i=0; i<B; i++) Array[[i]] = i - 3;
 477   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
 478   L[[i]] = 4;
 479
 480   exit( Array[[1]] != -2 || L[[2]] != 3);
 481 }],
 482     ac_cv_c_gcc_strength_bug="no",
 483     ac_cv_c_gcc_strength_bug="yes",
 484     ac_cv_c_gcc_strength_bug="yes") )
 485   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 486   then
 487     CFLAGS="$CFLAGS -fno-strength-reduce"
 488   fi
 489
 490   dnl Check for -mpreferred-stack-boundary
 491   AC_CACHE_CHECK("for gcc -mpreferred-stack-boundary=2 support",
 492                  ac_cv_c_gcc_stack_boundary,
 493   [saved_cflags=$CFLAGS
 494   CFLAGS="$CFLAGS -mpreferred-stack-boundary=2"
 495   AC_TRY_COMPILE(,[return 0],ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")
 496   CFLAGS=$saved_cflags
 497   ])
 498   if test "$ac_cv_c_gcc_stack_boundary" = "yes"
 499   then
 500     CFLAGS="$CFLAGS -mpreferred-stack-boundary=2"
 501   fi
 502 fi
 503
 504 dnl **** Check if we need to place .type inside a .def directive ****
 505
 506 AC_CACHE_CHECK("whether .type must sit inside a .def directive",
 507                ac_cv_c_type_in_def,
 508 [saved_libs=$LIBS
 509 LIBS="conftest_asm.s $LIBS"
 510 cat > conftest_asm.s <<EOF
 511         .globl _ac_test
 512         .def _ac_test; .scl 2; .type 32; .endef
 513 _ac_test:
 514         .long 0
 515 EOF
 516 AC_TRY_LINK(,,ac_cv_c_type_in_def="yes",ac_cv_c_type_in_def="no")
 517 LIBS=$saved_libs])
 518 if test "$ac_cv_c_type_in_def" = "yes"
 519 then
 520   AC_DEFINE(NEED_TYPE_IN_DEF)
 521 fi
 522
 523 dnl **** Check for underscore on external symbols ****
 524
 525 AC_CACHE_CHECK("whether external symbols need an underscore prefix",
 526                ac_cv_c_extern_prefix,
 527 [saved_libs=$LIBS
 528 LIBS="conftest_asm.s $LIBS"
 529 cat > conftest_asm.s <<EOF
 530         .globl _ac_test
 531 _ac_test:
 532         .long 0
 533 EOF
 534 AC_TRY_LINK([extern int ac_test;],[if (ac_test) return 1],
 535             ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no")
 536 LIBS=$saved_libs])
 537 if test "$ac_cv_c_extern_prefix" = "yes"
 538 then
 539   AC_DEFINE(NEED_UNDERSCORE_PREFIX)
 540 fi
 541
 542 dnl **** Check for .string in assembler ****
 543
 544 AC_CACHE_CHECK("whether assembler accepts .string",
 545                ac_cv_c_asm_string,
 546 [saved_libs=$LIBS
 547 LIBS="conftest_asm.s $LIBS"
 548 cat > conftest_asm.s <<EOF
 549         .string "test"
 550 EOF
 551 AC_TRY_LINK(,,ac_cv_c_asm_string="yes",ac_cv_c_asm_string="no")
 552 LIBS=$saved_libs])
 553 if test "$ac_cv_c_asm_string" = "yes"
 554 then
 555   AC_DEFINE(HAVE_ASM_STRING)
 556 fi
 557
 558 dnl **** Check for working dll ****
 559
 560 LDSHARED=""
 561 LDDLLFLAGS=""
 562 if test "$LIBEXT" = "so"
 563 then
 564   AC_CACHE_CHECK("whether we can build a Linux dll",
 565                  ac_cv_c_dll_linux,
 566   [saved_cflags=$CFLAGS
 567   CFLAGS="$CFLAGS -fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic"
 568   AC_TRY_LINK(,[return 1],ac_cv_c_dll_linux="yes",ac_cv_c_dll_linux="no")
 569   CFLAGS=$saved_cflags
 570   ])
 571   if test "$ac_cv_c_dll_linux" = "yes"
 572   then
 573     LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%) -Wl,-rpath,\$(libdir)"
 574     LDDLLFLAGS="-Wl,-Bsymbolic"
 575   else
 576     AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll,
 577                  ac_cv_c_dll_unixware,
 578     [saved_cflags=$CFLAGS
 579     CFLAGS="$CFLAGS -fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic"
 580     AC_TRY_LINK(,[return 1],ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")
 581     CFLAGS=$saved_cflags
 582     ])
 583     if test "$ac_cv_c_dll_unixware" = "yes"
 584     then
 585       LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,\$(libdir)/%)"
 586       LDDLLFLAGS="-Wl,-B,symbolic"
 587     else
 588       AC_CACHE_CHECK("whether we can build a NetBSD a.out dll",
 589                    ac_cv_c_dll_netbsd,
 590       [saved_cflags=$CFLAGS
 591       CFLAGS="$CFLAGS -fPIC -Wl,-Bshareable,-Bforcearchive"
 592       AC_TRY_LINK(,[return 1],ac_cv_c_dll_netbsd="yes",ac_cv_c_dll_netbsd="no")
 593       CFLAGS=$saved_cflags
 594       ])
 595       if test "$ac_cv_c_dll_netbsd" = "yes"
 596       then
 597         LDSHARED="\$(CC) -Wl,-Bshareable,-Bforcearchive"
 598         LDDLLFLAGS="" #FIXME
 599       fi
 600     fi
 601   fi
 602   if test "$ac_cv_c_dll_linux" = "no" -a "$ac_cv_c_dll_unixware" = "no" -a "$ac_cv_c_dll_netbsd" = "no"
 603   then
 604     LIBEXT="a"
 605     if test "$DLLWRAP" = "dllwrap"; then
 606       dnl FIXME - check whether dllwrap works correctly...
 607       if test "$CYGWIN" = "yes"; then
 608         echo "*** use dllwrap for building shared library."
 609         LIBEXT="dll"
 610       fi
 611     fi
 612   fi
 613 fi
 614
 615 if test "$LIBEXT" = "a"; then
 616   echo "*** It is currently not possible to build WINE without shared"
 617   echo "*** library (.so) support to allow transparent switch between .so"
 618   echo "*** and .dll files."
 619   echo "*** If you are using Linux, you will need a newer binutils."
 620   exit 1
 621 fi
 622
 623 DLLFLAGS=""
 624 LDPATH=""
 625
 626 if test "$LIBEXT" = "so"; then
 627     DLLFLAGS="-fPIC"
 628     DLL_LINK="-L\$(DLLDIR) \$(IMPORTS:%=-l%) \$(LIBWINE) \$(LIBUNICODE)"
 629     LDPATH="LD_LIBRARY_PATH=\"\$(TOPOBJDIR)/unicode:\$\$LD_LIBRARY_PATH\""
 630 elif test "$LIBEXT" = "dll"; then
 631     #DLLFLAGS="-fPIC" # -fPIC doesn't work(at least in cygwin-b20) - FIXME
 632     DLL_LINK="-L\$(DLLDIR) \$(IMPORTS:%=-l%) \$(LIBWINE) \$(LIBUNICODE)"
 633     LDPATH="PATH=\"\$(TOPOBJDIR)/unicode:\$\$PATH\""
 634 else
 635     DLL_LINK="-L\$(DLLDIR) \$(DLLS:%=-l%) \$(LIBWINE) \$(LIBUNICODE) \$(X_LIBS) \$(XLIB)"
 636     AC_CACHE_CHECK([whether the linker supports --[[no]]-whole-archive (Linux)],
 637                    ac_cv_c_whole_archive,
 638             [saved_cflags=$CFLAGS
 639             CFLAGS="$CFLAGS -Wl,--whole-archive -Wl,--no-whole-archive"
 640             AC_TRY_LINK(,[return 1],ac_cv_c_whole_archive="yes",ac_cv_c_whole_archive="no")
 641             CFLAGS=$saved_cflags
 642             ])
 643     if test "$ac_cv_c_whole_archive" = "yes"
 644     then
 645         DLL_LINK="-Wl,--whole-archive $DLL_LINK -Wl,--no-whole-archive"
 646     else
 647         AC_CACHE_CHECK([whether the linker supports -z {all,default}extract (Linux)],
 648                        ac_cv_c_allextract,
 649                 [saved_cflags=$CFLAGS
 650                 CFLAGS="$CFLAGS -Wl,-z,allextract -Wl,-z,defaultextract"
 651                 AC_TRY_LINK(,[return 1],ac_cv_c_allextract="yes",ac_cv_c_allextract="no")
 652                 CFLAGS=$saved_cflags
 653                 ])
 654         if test "$ac_cv_c_allextract" = "yes"
 655         then
 656             DLL_LINK="-Wl,-z,allextract $DLL_LINK -Wl,-z,defaultextract"
 657         fi
 658     fi
 659 fi
 660
 661 AC_SUBST(DLL_LINK)
 662 AC_SUBST(DLLFLAGS)
 663 AC_SUBST(LDSHARED)
 664 AC_SUBST(LDDLLFLAGS)
 665 AC_SUBST(LIBEXT)
 666 AC_SUBST(LDPATH)
 667
 668 dnl **** Check for reentrant libc ****
 669 dnl
 670 dnl For cross-compiling we blindly assume that libc is reentrant. This is
 671 dnl ok since non-reentrant libc is quite rare (mostly old libc5 versions).
 672
 673 AC_DEFUN(WINE_CHECK_ERRNO,
 674 [
 675   AC_CACHE_CHECK(for reentrant libc: $1, wine_cv_libc_r_$1,
 676   [AC_TRY_RUN([int myerrno = 0;
 677 char buf[256];
 678 int *$1(){return &myerrno;}
 679 main(){connect(0,buf,255); exit(!myerrno);}],
 680   wine_cv_libc_r_$1=yes, wine_cv_libc_r_$1=no,
 681   wine_cv_libc_r_$1=yes )
 682 ])
 683 if test "$wine_cv_libc_r_$1" = "yes"
 684 then
 685     wine_cv_libc_reentrant=$1
 686 fi
 687 ])
 688
 689 wine_cv_libc_reentrant=no
 690 dnl Linux style errno location
 691 WINE_CHECK_ERRNO(__errno_location)
 692 dnl FreeBSD style errno location
 693 WINE_CHECK_ERRNO(__error)
 694 dnl Solaris style errno location
 695 WINE_CHECK_ERRNO(___errno)
 696 dnl UnixWare style errno location
 697 WINE_CHECK_ERRNO(__thr_errno)
 698 dnl NetBSD style errno location
 699 WINE_CHECK_ERRNO(__errno)
 700
 701 if test "$wine_cv_libc_reentrant" != "no"
 702 then
 703   AC_DEFINE_UNQUOTED(ERRNO_LOCATION,$wine_cv_libc_reentrant)
 704 fi
 705
 706 dnl **** Check for reentrant X libraries ****
 707 dnl
 708 dnl This may fail to determine whether X libraries are reentrant if
 709 dnl AC_PATH_XTRA does not set x_libraries. In this case manual configuration
 710 dnl is possible with the --without-reentrant-x option.
 711
 712 if test "$have_x" = "yes" -a "$wine_cv_libc_reentrant" != "no"
 713 then
 714 AC_CACHE_CHECK( "for reentrant X libraries", wine_cv_x_reentrant,
 715   [ if test "x$with_reentrant_x" = "xno"
 716     then
 717         wine_cv_x_reentrant=no
 718     else
 719         libX11_check=none
 720         for dir in "$x_libraries" /usr/lib /usr/local/lib /lib; do
 721             if test -r $dir/libX11.so; then
 722                 libX11_check="-D $dir/libX11.so"
 723                 break 1
 724             fi
 725             if test -r $dir/libX11.a; then
 726                 libX11_check="$dir/libX11.a"
 727                 break 1
 728             fi
 729         done
 730         if test "$libX11_check" != "none"; then
 731             if nm $libX11_check | grep $wine_cv_libc_reentrant >/dev/null 2>&1
 732             then
 733                 wine_cv_x_reentrant=yes
 734             else
 735                 wine_cv_x_reentrant=no
 736             fi
 737         else
 738             wine_cv_x_reentrant=unknown
 739         fi
 740     fi ] )
 741 else
 742     wine_cv_x_reentrant=no
 743 fi
 744 if test "$wine_cv_x_reentrant" = "no"
 745 then
 746   AC_DEFINE(NO_REENTRANT_X11)
 747 fi
 748
 749
 750 dnl **** Check for functions ****
 751
 752 AC_FUNC_ALLOCA()
 753 AC_CHECK_FUNCS(\
 754         __libc_fork \
 755         _lwp_create \
 756         clone \
 757         ecvt \
 758         finite \
 759         fpclass \
 760         getnetbyaddr \
 761         getnetbyname \
 762         getpagesize \
 763         getprotobyname \
 764         getprotobynumber \
 765         getrlimit \
 766         getservbyport \
 767         getsockopt \
 768         inet_network \
 769         lstat \
 770         memmove \
 771         mmap \
 772         rfork \
 773         select \
 774         sendmsg \
 775         settimeofday \
 776         sigaltstack \
 777         statfs \
 778         strcasecmp \
 779         strerror \
 780         strncasecmp \
 781         tcgetattr \
 782         timegm \
 783         usleep \
 784         vfscanf \
 785         wait4 \
 786         waitpid \
 787 )
 788
 789 dnl **** Check for header files ****
 790
 791 AC_CHECK_HEADERS(\
 792         arpa/inet.h \
 793         arpa/nameser.h \
 794         elf.h \
 795         float.h \
 796         ieeefp.h \
 797         libio.h \
 798         libutil.h \
 799         link.h \
 800         linux/cdrom.h \
 801         linux/input.h \
 802         linux/joystick.h \
 803         linux/ucdrom.h \
 804         net/if.h \
 805         netdb.h \
 806         netinet/in.h \
 807         netinet/in_systm.h \
 808         netinet/ip.h \
 809         netinet/tcp.h \
 810         pty.h \
 811         resolv.h \
 812         sched.h \
 813         socket.h \
 814         strings.h \
 815         sys/cdio.h \
 816         sys/errno.h \
 817         sys/file.h \
 818         sys/filio.h \
 819         sys/ipc.h \
 820         sys/lwp.h \
 821         sys/mman.h \
 822         sys/modem.h \
 823         sys/mount.h \
 824         sys/msg.h \
 825         sys/param.h \
 826         sys/ptrace.h \
 827         sys/reg.h \
 828         sys/signal.h \
 829         sys/shm.h \
 830         sys/socket.h \
 831         sys/sockio.h \
 832         sys/statfs.h \
 833         sys/strtio.h \
 834         sys/syscall.h \
 835         sys/user.h \
 836         sys/wait.h \
 837         sys/v86.h \
 838         sys/v86intr.h \
 839         sys/vfs.h \
 840         sys/vm86.h \
 841         syscall.h \
 842         ucontext.h \
 843 )
 844 AC_HEADER_STAT()
 845
 846 dnl **** Check for types ****
 847
 848 AC_C_CONST()
 849 AC_C_INLINE()
 850 AC_TYPE_SIZE_T()
 851 AC_CHECK_SIZEOF(long long,0)
 852
 853 AC_CACHE_CHECK("whether linux/input.h is for real",
 854         wine_cv_linux_input_h,
 855         AC_TRY_COMPILE([
 856             #include <linux/input.h>
 857         ] , [
 858             int foo = EVIOCGBIT(EV_ABS,42);
 859             int bar = BTN_PINKIE;
 860             int fortytwo = 42;
 861         ],
 862         wine_cv_linux_input_h=yes,
 863         wine_cv_linux_input_h=no,
 864         no
 865         )
 866     )
 867     if test "$wine_cv_linux_input_h" = "yes"
 868     then
 869         AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H)
 870     fi
 871
 872
 873 AC_CACHE_CHECK("whether we can use re-entrant gethostbyname_r Linux style",
 874         wine_cv_linux_gethostbyname_r_6,
 875         AC_TRY_COMPILE([
 876 #include <netdb.h>
 877         ], [
 878     char *name=NULL;
 879     struct hostent he;
 880     struct hostent *result;
 881     char *buf=NULL;
 882     int bufsize=0;
 883     int res,errnr;
 884     char *addr=NULL;
 885     int addrlen=0;
 886     int addrtype=0;
 887     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
 888     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
 889     ],
 890         wine_cv_linux_gethostbyname_r_6=yes,
 891         wine_cv_linux_gethostbyname_r_6=no
 892         )
 893    )
 894    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
 895    then
 896       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6)
 897    fi
 898
 899 if test "$ac_cv_header_linux_joystick_h" = "yes"
 900 then
 901    AC_CACHE_CHECK("whether linux/joystick.h uses the Linux 2.2+ API",
 902         wine_cv_linux_joystick_22_api,
 903         AC_TRY_COMPILE([
 904         #include <sys/ioctl.h>
 905         #include <linux/joystick.h>
 906
 907         struct js_event blub;
 908         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
 909         #error "no 2.2 header"
 910         #endif
 911         ],/*empty*/,
 912         wine_cv_linux_joystick_22_api=yes,
 913         wine_cv_linux_joystick_22_api=no,
 914         wine_cv_linux_joystick_22_api=no
 915         )
 916    )
 917    if test "$wine_cv_linux_joystick_22_api" = "yes"
 918    then
 919       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API)
 920    fi
 921 fi
 922
 923 dnl **** statfs checks ****
 924
 925 if test "$ac_cv_header_sys_vfs_h" = "yes"
 926 then
 927     AC_CACHE_CHECK( "whether sys/vfs.h defines statfs",
 928                     wine_cv_sys_vfs_has_statfs,
 929         AC_TRY_COMPILE([
 930         #include <sys/types.h>
 931         #ifdef HAVE_SYS_PARAM_H
 932         # include <sys/param.h>
 933         #endif
 934         #include <sys/vfs.h>
 935         ],[
 936                 struct statfs stfs;
 937
 938                 memset(&stfs,0,sizeof(stfs));
 939         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
 940         )
 941     )
 942     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
 943     then
 944       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS)
 945     fi
 946 fi
 947
 948 if test "$ac_cv_header_sys_statfs_h" = "yes"
 949 then
 950     AC_CACHE_CHECK( "whether sys/statfs.h defines statfs",
 951                     wine_cv_sys_statfs_has_statfs,
 952         AC_TRY_COMPILE([
 953         #include <sys/types.h>
 954         #ifdef HAVE_SYS_PARAM_H
 955         # include <sys/param.h>
 956         #endif
 957         #include <sys/statfs.h>
 958         ],[
 959                 struct statfs stfs;
 960         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
 961         )
 962     )
 963     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
 964     then
 965       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS)
 966     fi
 967 fi
 968
 969 if test "$ac_cv_header_sys_mount_h" = "yes"
 970 then
 971     AC_CACHE_CHECK( "whether sys/mount.h defines statfs",
 972                     wine_cv_sys_mount_has_statfs,
 973         AC_TRY_COMPILE([
 974         #include <sys/types.h>
 975         #ifdef HAVE_SYS_PARAM_H
 976         # include <sys/param.h>
 977         #endif
 978         #include <sys/mount.h>
 979         ],[
 980                 struct statfs stfs;
 981         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
 982         )
 983     )
 984     if test "$wine_cv_sys_mount_has_statfs" = "yes"
 985     then
 986       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT)
 987     fi
 988 fi
 989
 990 dnl **** FIXME: what about mixed cases, where we need two of them? ***
 991
 992 AC_CACHE_CHECK( "for statfs.f_bfree", wine_cv_statfs_bfree,
 993   [ if test "x$statfs_bfree" = "xno"
 994     then
 995         wine_cv_statfs_bfree=no
 996     else
 997         AC_TRY_COMPILE([
 998         #include <sys/types.h>
 999         #ifdef HAVE_SYS_PARAM_H
1000         # include <sys/param.h>
1001         #endif
1002         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1003         # include <sys/mount.h>
1004         #else
1005         # ifdef STATFS_DEFINED_BY_SYS_VFS
1006         #  include <sys/vfs.h>
1007         # else
1008         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
1009         #   include <sys/statfs.h>
1010         #  endif
1011         # endif
1012         #endif
1013         ],[
1014                 struct statfs stfs;
1015
1016                 stfs.f_bfree++;
1017         ],wine_cv_statfs_bfree=yes,wine_cv_statfs_bfree=no
1018         )
1019     fi ] )
1020 if test "$wine_cv_statfs_bfree" = "yes"
1021 then
1022   AC_DEFINE(STATFS_HAS_BFREE)
1023 fi
1024
1025 AC_CACHE_CHECK( "for statfs.f_bavail", wine_cv_statfs_bavail,
1026   [ if test "x$statfs_bavail" = "xno"
1027     then
1028         wine_cv_statfs_bavail=no
1029     else
1030         AC_TRY_COMPILE([
1031         #include <sys/types.h>
1032         #ifdef HAVE_SYS_PARAM_H
1033         # include <sys/param.h>
1034         #endif
1035         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1036         # include <sys/mount.h>
1037         #else
1038         # ifdef STATFS_DEFINED_BY_SYS_VFS
1039         #  include <sys/vfs.h>
1040         # else
1041         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
1042         #   include <sys/statfs.h>
1043         #  endif
1044         # endif
1045         #endif
1046         ],[
1047                 struct statfs stfs;
1048
1049                 stfs.f_bavail++;
1050         ],wine_cv_statfs_bavail=yes,wine_cv_statfs_bavail=no
1051         )
1052     fi ] )
1053 if test "$wine_cv_statfs_bavail" = "yes"
1054 then
1055   AC_DEFINE(STATFS_HAS_BAVAIL)
1056 fi
1057
1058 dnl *** check for file descriptor passing with msg_accrights
1059
1060 AC_CACHE_CHECK("for msg_accrights in struct msghdr", ac_cv_c_msg_accrights,
1061  AC_TRY_COMPILE([#include <sys/types.h>
1062 #include <sys/socket.h>],[struct msghdr hdr; hdr.msg_accrights=0],
1063                 ac_cv_c_msg_accrights="yes", ac_cv_c_msg_accrights="no"))
1064 if test "$ac_cv_c_msg_accrights" = "yes"
1065 then
1066     AC_DEFINE(HAVE_MSGHDR_ACCRIGHTS)
1067 fi
1068
1069 dnl *** Check for the sun_len member in struct sockaddr_un
1070
1071 AC_CACHE_CHECK("for sun_len in struct sockaddr_un", ac_cv_c_sun_len,
1072  AC_TRY_COMPILE([#include <sys/types.h>
1073 #include <sys/socket.h>
1074 #include <sys/un.h>], [static struct sockaddr_un addr; addr.sun_len = 1],
1075                 ac_cv_c_sun_len="yes", ac_cv_c_sun_len="no"))
1076 if test "$ac_cv_c_sun_len" = "yes"
1077 then
1078     AC_DEFINE(HAVE_SOCKADDR_SUN_LEN)
1079 fi
1080
1081 dnl *** check for the need to define __i386__
1082
1083 AC_CACHE_CHECK("whether we need to define __i386__",ac_cv_cpp_def_i386,
1084  AC_EGREP_CPP(yes,[#if (defined(i386) || defined(__i386)) && !defined(__i386__)
1085 yes
1086 #endif],
1087  ac_cv_cpp_def_i386="yes", ac_cv_cpp_def_i386="no"))
1088 if test "$ac_cv_cpp_def_i386" = "yes"
1089 then
1090     CFLAGS="$CFLAGS -D__i386__"
1091     LINTFLAGS="$LINTFLAGS -D__i386__"
1092 fi
1093
1094 dnl $GCC is set by autoconf
1095 GCC_NO_BUILTIN=""
1096 if test "$GCC" = "yes"
1097 then
1098     GCC_NO_BUILTIN="-fno-builtin"
1099 fi
1100 AC_SUBST(GCC_NO_BUILTIN)
1101
1102 dnl **** Generate output files ****
1103
1104 AC_OUTPUT_COMMANDS([
1105 extra_subdirs="\
1106 dlls/ddraw/d3ddevice \
1107 dlls/ddraw/dclipper \
1108 dlls/ddraw/ddraw \
1109 dlls/ddraw/direct3d \
1110 dlls/ddraw/dpalette \
1111 dlls/ddraw/dsurface \
1112 dlls/dinput/joystick \
1113 dlls/dinput/keyboard \
1114 dlls/dinput/mouse \
1115 dlls/kernel/messages \
1116 dlls/user/resources \
1117 "
1118 for i in $extra_subdirs; do [ -d $i ] || (echo "creating $i" && mkdir $i); done ])
1119
1120 MAKE_RULES=Make.rules
1121 AC_SUBST_FILE(MAKE_RULES)
1122
1123 MAKE_DLL_RULES=dlls/Makedll.rules
1124 AC_SUBST_FILE(MAKE_DLL_RULES)
1125
1126 MAKE_PROG_RULES=programs/Makeprog.rules
1127 AC_SUBST_FILE(MAKE_PROG_RULES)
1128
1129 AC_OUTPUT([
1130 Make.rules
1131 dlls/Makedll.rules
1132 programs/Makeprog.rules
1133 Makefile
1134 console/Makefile
1135 controls/Makefile
1136 debugger/Makefile
1137 dlls/Makefile
1138 dlls/advapi32/Makefile
1139 dlls/avifil32/Makefile
1140 dlls/comctl32/Makefile
1141 dlls/commdlg/Makefile
1142 dlls/crtdll/Makefile
1143 dlls/dciman32/Makefile
1144 dlls/ddraw/Makefile
1145 dlls/dinput/Makefile
1146 dlls/dplay/Makefile
1147 dlls/dplayx/Makefile
1148 dlls/dsound/Makefile
1149 dlls/gdi/Makefile
1150 dlls/icmp/Makefile
1151 dlls/imagehlp/Makefile
1152 dlls/imm32/Makefile
1153 dlls/kernel/Makefile
1154 dlls/lzexpand/Makefile
1155 dlls/mpr/Makefile
1156 dlls/msacm/Makefile
1157 dlls/msnet32/Makefile
1158 dlls/msvcrt/Makefile
1159 dlls/msvideo/Makefile
1160 dlls/ntdll/Makefile
1161 dlls/odbc32/Makefile
1162 dlls/ole32/Makefile
1163 dlls/oleaut32/Makefile
1164 dlls/olecli/Makefile
1165 dlls/oledlg/Makefile
1166 dlls/olepro32/Makefile
1167 dlls/olesvr/Makefile
1168 dlls/opengl32/Makefile
1169 dlls/psapi/Makefile
1170 dlls/rasapi32/Makefile
1171 dlls/richedit/Makefile
1172 dlls/rpcrt4/Makefile
1173 dlls/serialui/Makefile
1174 dlls/setupapi/Makefile
1175 dlls/shdocvw/Makefile
1176 dlls/shell32/Makefile
1177 dlls/shfolder/Makefile
1178 dlls/shlwapi/Makefile
1179 dlls/tapi32/Makefile
1180 dlls/ttydrv/Makefile
1181 dlls/urlmon/Makefile
1182 dlls/user/Makefile
1183 dlls/version/Makefile
1184 dlls/win32s/Makefile
1185 dlls/winaspi/Makefile
1186 dlls/winedos/Makefile
1187 dlls/wineps/Makefile
1188 dlls/wininet/Makefile
1189 dlls/winmm/Makefile
1190 dlls/winmm/joystick/Makefile
1191 dlls/winmm/mcianim/Makefile
1192 dlls/winmm/mciavi/Makefile
1193 dlls/winmm/mcicda/Makefile
1194 dlls/winmm/mciseq/Makefile
1195 dlls/winmm/mciwave/Makefile
1196 dlls/winmm/midimap/Makefile
1197 dlls/winmm/wavemap/Makefile
1198 dlls/winmm/wineoss/Makefile
1199 dlls/winnls/Makefile
1200 dlls/winsock/Makefile
1201 dlls/winspool/Makefile
1202 dlls/wintrust/Makefile
1203 dlls/wow32/Makefile
1204 dlls/wsock32/Makefile
1205 dlls/x11drv/Makefile
1206 documentation/Makefile
1207 documentation/wine.conf.man
1208 documentation/wine.man
1209 files/Makefile
1210 graphics/Makefile
1211 graphics/enhmetafiledrv/Makefile
1212 graphics/metafiledrv/Makefile
1213 graphics/win16drv/Makefile
1214 graphics/x11drv/Makefile
1215 if1632/Makefile
1216 include/Makefile
1217 library/Makefile
1218 libtest/Makefile
1219 loader/Makefile
1220 loader/dos/Makefile
1221 loader/ne/Makefile
1222 memory/Makefile
1223 misc/Makefile
1224 miscemu/Makefile
1225 msdos/Makefile
1226 objects/Makefile
1227 ole/Makefile
1228 programs/Makefile
1229 programs/avitools/Makefile
1230 programs/clock/Makefile
1231 programs/cmdlgtst/Makefile
1232 programs/control/Makefile
1233 programs/notepad/Makefile
1234 programs/osversioncheck/Makefile
1235 programs/progman/Makefile
1236 programs/regapi/Makefile
1237 programs/regtest/Makefile
1238 programs/uninstaller/Makefile
1239 programs/view/Makefile
1240 programs/wcmd/Makefile
1241 programs/winemine/Makefile
1242 programs/winetest/Makefile
1243 programs/winhelp/Makefile
1244 programs/winver/Makefile
1245 relay32/Makefile
1246 scheduler/Makefile
1247 server/Makefile
1248 tools/Makefile
1249 tools/cvdump/Makefile
1250 tools/specmaker/Makefile
1251 tools/winebuild/Makefile
1252 tools/winelauncher
1253 tools/wmc/Makefile
1254 tools/wrc/Makefile
1255 tsx11/Makefile
1256 unicode/Makefile
1257 win32/Makefile
1258 windows/Makefile
1259 windows/x11drv/Makefile ])
1260
1261 if test "$have_x" = "no"
1262 then
1263   echo
1264   echo "*** Warning: X development files not found. Wine will be built without"
1265   echo "*** X support, which currently does not work, and would probably not be"
1266   echo "*** what you want anyway. You will need to install devel packages of"
1267   echo "*** Xlib/Xfree86 and Xpm at the very least."
1268 elif test "$ac_cv_lib_Xpm_XpmCreatePixmapFromData" = "no"
1269 then
1270   echo
1271   echo "*** Warning: Xpm development files not found. Wine will be built without"
1272   echo "*** Xpm support, which currently does not work. You will need to install"
1273   echo "*** devel packages of Xpm."
1274 fi
1275
1276 if test "$ac_cv_lib_ncurses_resizeterm" = "no" -a "$ac_cv_lib_ncurses_waddch" = "yes"
1277 then
1278   echo
1279   echo "*** Warning: resizeterm not found in ncurses. Wine will be built without"
1280   echo "*** terminal resize support. Consider upgrading ncurses."
1281 fi
1282
1283 if test "$wine_cv_libc_reentrant" = "no"
1284 then
1285   echo
1286   echo "*** Warning: non-reentrant libc detected. Wine will be build without"
1287   echo "*** thread support. Consider upgrading libc to a more recent"
1288   echo "*** reentrant version of libc."
1289 fi
1290
1291 if test "$wine_cv_opengl_version_OK" = "no"
1292 then
1293   echo
1294   echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1295   echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1296 fi
1297
1298 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a $OPENGL = "normal"
1299 then
1300   echo
1301   echo "*** Warning: the OpenGL version you have installed relies on libpthread for"
1302   echo "*** thread-safety. To prevent crashes, OpenGL support has been removed."
1303   echo "*** A fix for glibc 2.1.3 that seems to work is included in this version of Wine,"
1304   echo "*** start configure with '--enable-opengl' to force OpenGL support."
1305 fi
1306
1307 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a $OPENGL = "yes"
1308 then
1309   echo
1310   echo "*** Warning: you explicitly linked in a thread-safe OpenGL version. If you"
1311   echo "*** experience unusual crashes on DirectDraw games, try first to disable OpenGL"
1312   echo "*** support before reporting bugs."
1313 fi
1314
1315 if test "$wine_cv_warn_cups_h" = "yes"
1316 then
1317   echo
1318   echo "*** Note: You have cups runtime libraries, but no development"
1319   echo "*** libraries. Install the cups-devel package or whichever package"
1320   echo "*** contains cups.h to enable CUPS support in WINE."
1321 fi
1322
1323 echo
1324 echo "Configure finished.  Do 'make depend && make' to compile Wine."
1325 echo
1326
1327 dnl Local Variables:
1328 dnl comment-start: "dnl "
1329 dnl comment-end: ""
1330 dnl comment-start-skip: "\\bdnl\\b\\s *"
1331 dnl compile-command: "autoconf"
1332 dnl End: